git.chise.org Git - elisp/gnus.git-/blob - lisp/nnheader.el

   1 ;;; nnheader.el --- header access macros for Semi-gnus and its backends
   2
   3 ;; Copyright (C) 1987, 1988, 1989, 1990, 1993, 1994, 1995, 1996,
   4 ;;        1997, 1998, 2000, 2001, 2002, 2003
   5 ;;        Free Software Foundation, Inc.
   6
   7 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   9 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
  10 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
  11 ;; Keywords: mail, news, MIME
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  28 ;; Boston, MA 02111-1307, USA.
  29
  30 ;;; Commentary:
  31
  32 ;;; Code:
  33
  34 (eval-when-compile (require 'cl))
  35 (eval-when-compile (require 'static))
  36
  37 ;; Requiring `gnus-util' at compile time creates a circular
  38 ;; dependency between nnheader.el and gnus-util.el.
  39 ;;(eval-when-compile (require 'gnus-util))
  40
  41 (require 'mail-utils)
  42 (require 'gnus-util)
  43
  44 ;; Reduce the required value of `recursive-load-depth-limit' for Emacs 21.
  45 (require 'pces)
  46 (require 'poem)
  47 (require 'std11)
  48
  49 (require 'mime)
  50 (eval-and-compile
  51   (autoload 'gnus-sorted-intersection "gnus-range")
  52   (autoload 'gnus-intersection "gnus-range")
  53   (autoload 'gnus-sorted-complement "gnus-range")
  54   (autoload 'gnus-sorted-difference "gnus-range"))
  55
  56 (defcustom gnus-verbose-backends 7
  57   "Integer that says how verbose the Gnus backends should be.
  58 The higher the number, the more messages the Gnus backends will flash
  59 to say what it's doing.  At zero, the Gnus backends will be totally
  60 mute; at five, they will display most important messages; and at ten,
  61 they will keep on jabbering all the time."
  62   :group 'gnus-start
  63   :type 'integer)
  64
  65 (defcustom gnus-nov-is-evil nil
  66   "If non-nil, Gnus backends will never output headers in the NOV format."
  67   :group 'gnus-server
  68   :type 'boolean)
  69
  70 (defvar nnheader-max-head-length 4096
  71   "*Max length of the head of articles.
  72
  73 Value is an integer, nil, or t.  nil means read in chunks of a file
  74 indefinitely until a complete head is found\; t means always read the
  75 entire file immediately, disregarding `nnheader-head-chop-length'.
  76
  77 Integer values will in effect be rounded up to the nearest multiple of
  78 `nnheader-head-chop-length'.")
  79
  80 (defvar nnheader-head-chop-length 2048
  81   "*Length of each read operation when trying to fetch HEAD headers.")
  82
  83 (defvar nnheader-read-timeout
  84   (if (string-match "windows-nt\\|os/2\\|emx\\|cygwin"
  85                     (symbol-name system-type))
  86       1.0                               ; why?
  87     0.1)
  88   "How long nntp should wait between checking for the end of output.
  89 Shorter values mean quicker response, but are more CPU intensive.")
  90
  91 (defvar nnheader-file-name-translation-alist
  92   (let ((case-fold-search t))
  93     (cond
  94      ((string-match "windows-nt\\|os/2\\|emx\\|cygwin"
  95                     (symbol-name system-type))
  96       (append (mapcar (lambda (c) (cons c ?_))
  97                       '(?: ?* ?\" ?< ?> ??))
  98               (if (string-match "windows-nt\\|cygwin"
  99                                 (symbol-name system-type))
 100                   nil
 101                 '((?+ . ?-)))))
 102      (t nil)))
 103   "*Alist that says how to translate characters in file names.
 104 For instance, if \":\" is invalid as a file character in file names
 105 on your system, you could say something like:
 106
 107 \(setq nnheader-file-name-translation-alist '((?: . ?_)))")
 108
 109 (defvar nnheader-text-coding-system
 110   (if (memq system-type '(windows-nt ms-dos ms-windows))
 111       'raw-text-dos
 112     'raw-text)
 113   "Text-safe coding system (For removing ^M).
 114 This variable is a substitute for `mm-text-coding-system'.")
 115
 116 (defvar nnheader-text-coding-system-for-write nil
 117   "Text coding system for write.
 118 This variable is a substitute for `mm-text-coding-system-for-write'.")
 119
 120 (defvar nnheader-auto-save-coding-system
 121   (cond
 122    ((not (fboundp 'find-coding-system)) nil)
 123    ((find-coding-system 'emacs-mule)
 124     (if (memq system-type '(windows-nt ms-dos ms-windows))
 125         'emacs-mule-dos 'emacs-mule))
 126    ((find-coding-system 'escape-quoted) 'escape-quoted)
 127    ((find-coding-system 'no-conversion) 'no-conversion)
 128    (t nil))
 129   "Coding system of auto save file.")
 130
 131 (defvar nnheader-directory-separator-character
 132   (string-to-char (substring (file-name-as-directory ".") -1))
 133   "*A character used to a directory separator.")
 134
 135 (eval-and-compile
 136   (autoload 'nnmail-message-id "nnmail")
 137   (autoload 'mail-position-on-field "sendmail")
 138   (autoload 'message-remove-header "message")
 139   (autoload 'gnus-buffer-live-p "gnus-util"))
 140
 141 ;; mm-util stuff.
 142 (unless (featurep 'mm-util)
 143   ;; Should keep track of `mm-image-load-path' in mm-util.el.
 144   (defun nnheader-image-load-path (&optional package)
 145     (let (dir result)
 146       (dolist (path load-path (nreverse result))
 147         (if (file-directory-p
 148              (setq dir (concat (file-name-directory
 149                                 (directory-file-name path))
 150                                "etc/" (or package "gnus/"))))
 151             (push dir result))
 152         (push path result))))
 153   (defalias 'mm-image-load-path 'nnheader-image-load-path)
 154
 155   ;; Should keep track of `mm-read-coding-system' in mm-util.el.
 156   (defalias 'mm-read-coding-system 'read-coding-system)
 157
 158   ;; Should keep track of `mm-%s' in mm-util.el.
 159   (defalias 'mm-multibyte-string-p
 160     (if (fboundp 'multibyte-string-p)
 161         'multibyte-string-p
 162       'ignore))
 163   (defalias 'mm-encode-coding-string 'encode-coding-string)
 164   (defalias 'mm-decode-coding-string 'decode-coding-string)
 165
 166   ;; Should keep track of `mm-detect-coding-region' in mm-util.el.
 167   (defun nnheader-detect-coding-region (start end)
 168     "Like 'detect-coding-region' except returning the best one."
 169     (let ((coding-systems (detect-coding-region (point) (point-max))))
 170       (or (car-safe coding-systems)
 171           coding-systems)))
 172   (defalias 'mm-detect-coding-region 'nnheader-detect-coding-region)
 173
 174   ;; Should keep track of `mm-detect-mime-charset-region' in mm-util.el.
 175   (defun nnheader-detect-mime-charset-region (start end)
 176     "Detect MIME charset of the text in the region between START and END."
 177     (coding-system-to-mime-charset
 178      (nnheader-detect-coding-region start end)))
 179   (defalias 'mm-detect-mime-charset-region
 180     'nnheader-detect-mime-charset-region)
 181
 182   ;; Should keep track of `mm-with-unibyte-buffer' in mm-util.el.
 183   (defmacro nnheader-with-unibyte-buffer (&rest forms)
 184   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 185 Use unibyte mode for this."
 186   `(let (default-enable-multibyte-characters)
 187      (with-temp-buffer ,@forms)))
 188   (put 'nnheader-with-unibyte-buffer 'lisp-indent-function 0)
 189   (put 'nnheader-with-unibyte-buffer 'edebug-form-spec '(body))
 190   (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 191   (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 192   (defalias 'mm-with-unibyte-buffer 'nnheader-with-unibyte-buffer)
 193
 194   ;; Should keep track of `mm-with-unibyte-current-buffer' in mm-util.el.
 195   (defmacro nnheader-with-unibyte-current-buffer (&rest forms)
 196     "Evaluate FORMS with current current buffer temporarily made unibyte.
 197 Also bind `default-enable-multibyte-characters' to nil.
 198 Equivalent to `progn' in XEmacs"
 199     (let ((multibyte (make-symbol "multibyte"))
 200           (buffer (make-symbol "buffer")))
 201       (cond ((featurep 'xemacs)
 202              `(let (default-enable-multibyte-characters)
 203                 ,@forms))
 204             (t
 205              `(let ((,multibyte enable-multibyte-characters)
 206                     (,buffer (current-buffer)))
 207                 (unwind-protect
 208                     (let (default-enable-multibyte-characters)
 209                       (set-buffer-multibyte nil)
 210                       ,@forms)
 211                   (set-buffer ,buffer)
 212                   (set-buffer-multibyte ,multibyte)))))))
 213   (put 'nnheader-with-unibyte-current-buffer 'lisp-indent-function 0)
 214   (put 'nnheader-with-unibyte-current-buffer 'edebug-form-spec '(body))
 215   (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 216   (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 217   (defalias 'mm-with-unibyte-current-buffer
 218     'nnheader-with-unibyte-current-buffer)
 219
 220   ;; Should keep track of `mm-with-unibyte' in mm-util.el.
 221   (defmacro nnheader-with-unibyte (&rest forms)
 222     "Eval the FORMS with the default value of `enable-multibyte-characters'
 223 nil, ."
 224     `(let (default-enable-multibyte-characters)
 225        ,@forms))
 226   (put 'nnheader-with-unibyte 'lisp-indent-function 0)
 227   (put 'nnheader-with-unibyte 'edebug-form-spec '(body))
 228   (put 'mm-with-unibyte 'lisp-indent-function 0)
 229   (put 'mm-with-unibyte 'edebug-form-spec '(body))
 230   (defalias 'mm-with-unibyte 'nnheader-with-unibyte)
 231
 232   ;; Should keep track of `mm-guess-mime-charset' in mm-util.el.
 233   (defun nnheader-guess-mime-charset ()
 234   "Guess the default MIME charset from the language environment."
 235   (let ((language-info
 236          (and (boundp 'current-language-environment)
 237               (assoc current-language-environment
 238                      language-info-alist)))
 239         item)
 240     (cond
 241      ((null language-info)
 242       'iso-8859-1)
 243      ((setq item
 244             (cadr
 245              (or (assq 'coding-priority language-info)
 246                  (assq 'coding-system language-info))))
 247       (if (fboundp 'coding-system-get)
 248           (or (coding-system-get item 'mime-charset)
 249               item)
 250         item))
 251      ((setq item (car (last (assq 'charset language-info))))
 252       (if (eq item 'ascii)
 253           'iso-8859-1
 254          (charsets-to-mime-charset (list item))))
 255      (t
 256       'iso-8859-1))))
 257   (defalias 'mm-guess-mime-charset 'nnheader-guess-mime-charset)
 258
 259   (defalias 'mm-char-int 'char-int)
 260
 261   ;; Should keep track of the same alias in mm-util.el.
 262   (defalias 'mm-multibyte-p
 263     (static-cond ((and (featurep 'xemacs) (featurep 'mule))
 264                   (lambda nil t))
 265                  ((featurep 'xemacs)
 266                   (lambda nil nil))
 267                  (t
 268                   (lambda nil enable-multibyte-characters))))
 269
 270   ;; Should keep track of the same alias in mm-util.el.
 271   (defalias 'mm-make-temp-file
 272     (if (fboundp 'make-temp-file)
 273         'make-temp-file
 274       (lambda (prefix &optional dir-flag)
 275         (let ((file (expand-file-name
 276                      (make-temp-name prefix)
 277                      (if (fboundp 'temp-directory)
 278                          (temp-directory)
 279                        temporary-file-directory))))
 280           (if dir-flag
 281               (make-directory file))
 282           file))))
 283
 284   ;; Should keep track of `mm-coding-system-p' in mm-util.el.
 285   (defun nnheader-coding-system-p (sym)
 286     "Return non-nil if SYM is a coding system."
 287     (or (and (fboundp 'find-coding-system) (find-coding-system sym))
 288         (and (fboundp 'coding-system-p) (coding-system-p sym))))
 289   (defalias 'mm-coding-system-p 'nnheader-coding-system-p))
 290
 291 ;; mail-parse stuff.
 292 (unless (featurep 'mail-parse)
 293   (unless (fboundp 'std11-narrow-to-field)
 294     (defalias 'std11-narrow-to-field
 295       ;; Should keep track of `rfc2047-narrow-to-field' in rfc2047.el.
 296       (lambda ()
 297         "Narrow the buffer to the header on the current line."
 298         (forward-line 0)
 299         (narrow-to-region (point)
 300                           (progn
 301                             (std11-field-end)
 302                             (when (eolp) (forward-line 1))
 303                             (point)))
 304         (goto-char (point-min)))))
 305   (defalias 'mail-header-narrow-to-field 'std11-narrow-to-field)
 306
 307   ;; Should keep track of `ietf-drums-narrow-to-header' in ietf-drums.el.
 308   (defun mail-narrow-to-head ()
 309     "Narrow to the header section in the current buffer."
 310     (narrow-to-region
 311      (goto-char (point-min))
 312      (if (re-search-forward "^\r?$" nil 1)
 313          (match-beginning 0)
 314        (point-max)))
 315     (goto-char (point-min)))
 316
 317   (unless (fboundp 'std11-fold-region)
 318     (defalias 'std11-fold-region
 319       ;; Should keep track of `rfc2047-fold-region' in rfc2047.el.
 320       (lambda (b e)
 321         "Fold long lines in region B to E."
 322         (save-restriction
 323           (narrow-to-region b e)
 324           (goto-char (point-min))
 325           (let ((break nil)
 326                 (qword-break nil)
 327                 (first t)
 328                 (bol (save-restriction
 329                        (widen)
 330                        (point-at-bol))))
 331             (while (not (eobp))
 332               (when (and (or break qword-break)
 333                          (> (- (point) bol) 76))
 334                 (goto-char (or break qword-break))
 335                 (setq break nil
 336                       qword-break nil)
 337                 (if (looking-at "[ \t]")
 338                     (insert "\n")
 339                   (insert "\n "))
 340                 (setq bol (1- (point)))
 341                 ;; Don't break before the first non-LWSP characters.
 342                 (skip-chars-forward " \t")
 343                 (unless (eobp)
 344                   (forward-char 1)))
 345               (cond
 346                ((eq (char-after) ?\n)
 347                 (forward-char 1)
 348                 (setq bol (point)
 349                       break nil
 350                       qword-break nil)
 351                 (skip-chars-forward " \t")
 352                 (unless (or (eobp) (eq (char-after) ?\n))
 353                   (forward-char 1)))
 354                ((eq (char-after) ?\r)
 355                 (forward-char 1))
 356                ((memq (char-after) '(?  ?\t))
 357                 (skip-chars-forward " \t")
 358                 (if first
 359                     ;; Don't break just after the header name.
 360                     (setq first nil)
 361                   (setq break (1- (point)))))
 362                ((not break)
 363                 (if (not (looking-at "=\\?[^=]"))
 364                     (if (eq (char-after) ?=)
 365                         (forward-char 1)
 366                       (skip-chars-forward "^ \t\n\r="))
 367                   (setq qword-break (point))
 368                   (skip-chars-forward "^ \t\n\r")))
 369                (t
 370                 (skip-chars-forward "^ \t\n\r"))))
 371             (when (and (or break qword-break)
 372                        (> (- (point) bol) 76))
 373               (goto-char (or break qword-break))
 374               (setq break nil
 375                     qword-break nil)
 376               (if (looking-at "[ \t]")
 377                   (insert "\n")
 378                 (insert "\n "))
 379               (setq bol (1- (point)))
 380               ;; Don't break before the first non-LWSP characters.
 381               (skip-chars-forward " \t")
 382               (unless (eobp)
 383                 (forward-char 1))))))))
 384
 385   (unless (fboundp 'std11-fold-field)
 386     (defalias 'std11-fold-field
 387       ;; Should keep track of `rfc2047-fold-field' in rfc2047.el.
 388       (lambda ()
 389         "Fold the current line."
 390         (save-excursion
 391           (save-restriction
 392             (std11-narrow-to-field)
 393             (std11-fold-region (point-min) (point-max)))))))
 394   (defalias 'mail-header-fold-field 'std11-fold-field)
 395
 396   (unless (fboundp 'std11-unfold-region)
 397     (defalias 'std11-unfold-region
 398       ;; Should keep track of `rfc2047-unfold-region' in rfc2047.el.
 399       (lambda (b e)
 400         "Unfold lines in region B to E."
 401         (save-restriction
 402           (narrow-to-region b e)
 403           (goto-char (point-min))
 404           (let ((bol (save-restriction
 405                        (widen)
 406                        (point-at-bol)))
 407                 (eol (point-at-eol)))
 408             (forward-line 1)
 409             (while (not (eobp))
 410               (if (and (looking-at "[ \t]")
 411                        (< (- (point-at-eol) bol) 76))
 412                   (delete-region eol (progn
 413                                        (goto-char eol)
 414                                        (skip-chars-forward "\r\n")
 415                                        (point)))
 416                 (setq bol (point-at-bol)))
 417               (setq eol (point-at-eol))
 418               (forward-line 1)))))))
 419
 420   (unless (fboundp 'std11-unfold-field)
 421     (defalias 'std11-unfold-field
 422       ;; Should keep track of `rfc2047-unfold-field' in rfc2047.el.
 423       (lambda ()
 424         "Fold the current line."
 425         (save-excursion
 426           (save-restriction
 427             (std11-narrow-to-field)
 428             (std11-unfold-region (point-min) (point-max)))))))
 429   (defalias 'mail-header-unfold-field 'std11-unfold-field)
 430
 431   (unless (fboundp 'std11-extract-addresses-components)
 432     (defalias 'std11-extract-addresses-components
 433       ;; This is the original function in T-gnus.
 434       (lambda (string)
 435         "Extract a list of full name and canonical address from STRING.  Each
 436 element looks like a list of the form (FULL-NAME CANONICAL-ADDRESS).
 437 If no name can be extracted, FULL-NAME will be nil."
 438         (when string
 439           (let (addresses)
 440             (dolist (structure (std11-parse-addresses-string
 441                                 (std11-unfold-string string))
 442                                addresses)
 443               (push (list (std11-full-name-string structure)
 444                           (std11-address-string structure))
 445                     addresses))
 446             (nreverse addresses))))))
 447
 448   ;; Should keep track of `ietf-drums-parse-addresses' in ietf-drums.el.
 449   (defun mail-header-parse-addresses (string)
 450     "Parse STRING and return a list of MAILBOX / DISPLAY-NAME pairs."
 451     (mapcar (function
 452              (lambda (components)
 453                (cons (nth 1 components) (car components))))
 454             (std11-extract-addresses-components string)))
 455
 456   ;; Should keep track of `rfc2047-field-value' in rfc2047.el.
 457   (defun std11-field-value (&optional dont-include-last-newline)
 458     "Return the value of the field at point.  If the optional argument is
 459 given, the return value will not contain the last newline."
 460     (let ((begin (point))
 461           (inhibit-point-motion-hooks t)
 462           start value)
 463       (beginning-of-line)
 464       (unless (eobp)
 465         (while (and (memq (char-after) '(?\t ?\ ))
 466                     (zerop (forward-line -1))))
 467         (when (looking-at "[^\t\n ]+:[\t\n ]+")
 468           (goto-char (setq start (match-end 0)))
 469           (forward-line 1)
 470           (while (and (memq (char-after) '(?\t ?\ ))
 471                       (zerop (forward-line 1))))
 472           (when dont-include-last-newline
 473             (skip-chars-backward "\t\n " start))
 474           (setq value (buffer-substring start (point)))))
 475       (goto-char begin)
 476       value))
 477   (defalias 'mail-header-field-value 'std11-field-value))
 478
 479 ;; ietf-drums stuff.
 480 (unless (featurep 'ietf-drums)
 481   ;; Should keep track of `ietf-drums-unfold-fws' in ietf-drums.el.
 482   (defun nnheader-unfold-fws ()
 483     "Unfold folding white space in the current buffer."
 484     (goto-char (point-min))
 485     (while (re-search-forward "[ \t]*\n[ \t]+" nil t)
 486       (replace-match " " t t))
 487     (goto-char (point-min)))
 488
 489   (defalias 'ietf-drums-unfold-fws 'nnheader-unfold-fws))
 490
 491 ;;; Header access macros.
 492
 493 ;; These macros may look very much like the ones in GNUS 4.1.  They
 494 ;; are, in a way, but you should note that the indices they use have
 495 ;; been changed from the internal GNUS format to the NOV format.  The
 496 ;; makes it possible to read headers from XOVER much faster.
 497 ;;
 498 ;; The format of a header is now:
 499 ;; [number subject from date id references chars lines xref extra]
 500 ;;
 501 ;; (That next-to-last entry is defined as "misc" in the NOV format,
 502 ;; but Gnus uses it for xrefs.)
 503
 504 (require 'mmgnus)
 505
 506 (defmacro mail-header-number (header)
 507   "Return article number in HEADER."
 508   `(mime-entity-location-internal ,header))
 509
 510 (defmacro mail-header-set-number (header number)
 511   "Set article number of HEADER to NUMBER."
 512   `(mime-entity-set-location-internal ,header ,number))
 513
 514 (defalias 'mail-header-subject 'mime-gnus-entity-subject-internal)
 515 (defalias 'mail-header-set-subject 'mime-gnus-entity-set-subject-internal)
 516
 517 (defalias 'mail-header-from 'mime-gnus-entity-from-internal)
 518 (defalias 'mail-header-set-from 'mime-gnus-entity-set-from-internal)
 519
 520 (defalias 'mail-header-date 'mime-gnus-entity-date-internal)
 521 (defalias 'mail-header-set-date 'mime-gnus-entity-set-date-internal)
 522
 523 (defalias 'mail-header-message-id 'mime-gnus-entity-id-internal)
 524 (defalias 'mail-header-id 'mime-gnus-entity-id-internal)
 525 (defalias 'mail-header-set-message-id 'mime-gnus-entity-set-id-internal)
 526 (defalias 'mail-header-set-id 'mime-gnus-entity-set-id-internal)
 527
 528 (defalias 'mail-header-references 'mime-gnus-entity-references-internal)
 529 (defalias 'mail-header-set-references
 530   'mime-gnus-entity-set-references-internal)
 531
 532 (defalias 'mail-header-chars 'mime-gnus-entity-chars-internal)
 533 (defalias 'mail-header-set-chars 'mime-gnus-entity-set-chars-internal)
 534
 535 (defalias 'mail-header-lines 'mime-gnus-entity-lines-internal)
 536 (defalias 'mail-header-set-lines 'mime-gnus-entity-set-lines-internal)
 537
 538 (defalias 'mail-header-xref 'mime-gnus-entity-xref-internal)
 539 (defalias 'mail-header-set-xref 'mime-gnus-entity-set-xref-internal)
 540
 541 (defalias 'nnheader-decode-subject
 542   (mime-find-field-decoder 'Subject 'nov))
 543 (defalias 'nnheader-decode-from
 544   (mime-find-field-decoder 'From 'nov))
 545
 546 (defalias 'mail-header-extra 'mime-gnus-entity-extra-internal)
 547 (defalias 'mail-header-set-extra 'mime-gnus-entity-set-extra-internal)
 548
 549 (defun nnheader-decode-field-body (field-body field-name
 550                                               &optional mode max-column)
 551   (mime-decode-field-body field-body
 552                           (if (stringp field-name)
 553                               (intern (capitalize field-name))
 554                             field-name)
 555                           mode max-column))
 556
 557 (defsubst make-full-mail-header (&optional number subject from date id
 558                                            references chars lines xref
 559                                            extra)
 560   "Create a new mail header structure initialized with the parameters given."
 561   (luna-make-entity (mm-expand-class-name 'gnus)
 562                     :location number
 563                     :subject (if subject
 564                                  (nnheader-decode-subject subject))
 565                     :from (if from
 566                               (nnheader-decode-from from))
 567                     :date date
 568                     :id id
 569                     :references references
 570                     :chars chars
 571                     :lines lines
 572                     :xref xref
 573                     :original-header (list (cons 'Subject subject)
 574                                            (cons 'From from))
 575                     :extra extra))
 576
 577 (defsubst make-full-mail-header-from-decoded-header
 578   (&optional number subject from date id references chars lines xref extra)
 579   "Create a new mail header structure initialized with the parameters given."
 580   (luna-make-entity (mm-expand-class-name 'gnus)
 581                     :location number
 582                     :subject subject
 583                     :from from
 584                     :date date
 585                     :id id
 586                     :references references
 587                     :chars chars
 588                     :lines lines
 589                     :xref xref
 590                     :extra extra))
 591
 592 (defsubst make-mail-header (&optional init)
 593   "Create a new mail header structure initialized with INIT."
 594   (make-full-mail-header init init init init init
 595                          init init init init init))
 596
 597 ;; fake message-ids: generation and detection
 598
 599 (defvar nnheader-fake-message-id 1)
 600
 601 (defsubst nnheader-generate-fake-message-id ()
 602   (concat "fake+none+" (int-to-string (incf nnheader-fake-message-id))))
 603
 604 (defsubst nnheader-fake-message-id-p (id)
 605   (save-match-data                      ; regular message-id's are <.*>
 606     (string-match "\\`fake\\+none\\+[0-9]+\\'" id)))
 607
 608 ;; Parsing headers and NOV lines.
 609
 610 (defsubst nnheader-remove-cr-followed-by-lf ()
 611   (goto-char (point-max))
 612   (while (search-backward "\r\n" nil t)
 613     (delete-char 1)))
 614
 615 (defsubst nnheader-header-value ()
 616   (let ((pt (point)))
 617     (prog2
 618         (skip-chars-forward " \t")
 619         (buffer-substring (point) (std11-field-end))
 620       (goto-char pt))))
 621
 622 (defun nnheader-parse-naked-head (&optional number)
 623   ;; This function unfolds continuation lines in this buffer
 624   ;; destructively.  When this side effect is unwanted, use
 625   ;; `nnheader-parse-head' instead of this function.
 626   (let ((case-fold-search t)
 627         (buffer-read-only nil)
 628         (cur (current-buffer))
 629         (p (point-min))
 630         in-reply-to lines ref)
 631     (nnheader-remove-cr-followed-by-lf)
 632     (ietf-drums-unfold-fws)
 633     (subst-char-in-region (point-min) (point-max) ?\t ? )
 634     (goto-char p)
 635     (insert "\n")
 636     (prog1
 637         ;; This implementation of this function, with nine
 638         ;; search-forwards instead of the one re-search-forward and a
 639         ;; case (which basically was the old function) is actually
 640         ;; about twice as fast, even though it looks messier.  You
 641         ;; can't have everything, I guess.  Speed and elegance don't
 642         ;; always go hand in hand.
 643         (make-full-mail-header
 644          ;; Number.
 645          (or number 0)
 646          ;; Subject.
 647          (progn
 648            (goto-char p)
 649            (if (search-forward "\nsubject:" nil t)
 650                (nnheader-header-value) "(none)"))
 651          ;; From.
 652          (progn
 653            (goto-char p)
 654            (if (search-forward "\nfrom:" nil t)
 655                (nnheader-header-value) "(nobody)"))
 656          ;; Date.
 657          (progn
 658            (goto-char p)
 659            (if (search-forward "\ndate:" nil t)
 660                (nnheader-header-value) ""))
 661          ;; Message-ID.
 662          (progn
 663            (goto-char p)
 664            (if (search-forward "\nmessage-id:" nil t)
 665                (buffer-substring
 666                 (1- (or (search-forward "<" (point-at-eol) t)
 667                         (point)))
 668                 (or (search-forward ">" (point-at-eol) t) (point)))
 669              ;; If there was no message-id, we just fake one to make
 670              ;; subsequent routines simpler.
 671              (nnheader-generate-fake-message-id)))
 672          ;; References.
 673          (progn
 674            (goto-char p)
 675            (if (search-forward "\nreferences:" nil t)
 676                (nnheader-header-value)
 677              ;; Get the references from the in-reply-to header if
 678              ;; there were no references and the in-reply-to header
 679              ;; looks promising.
 680              (if (and (search-forward "\nin-reply-to:" nil t)
 681                       (setq in-reply-to (nnheader-header-value))
 682                       (string-match "<[^\n>]+>" in-reply-to))
 683                  (let (ref2)
 684                    (setq ref (substring in-reply-to (match-beginning 0)
 685                                         (match-end 0)))
 686                    (while (string-match "<[^\n>]+>"
 687                                         in-reply-to (match-end 0))
 688                      (setq ref2 (substring in-reply-to (match-beginning 0)
 689                                            (match-end 0)))
 690                      (when (> (length ref2) (length ref))
 691                        (setq ref ref2)))
 692                    ref)
 693                nil)))
 694          ;; Chars.
 695          0
 696          ;; Lines.
 697          (progn
 698            (goto-char p)
 699            (if (search-forward "\nlines: " nil t)
 700                (if (numberp (setq lines (read cur)))
 701                    lines 0)
 702              0))
 703          ;; Xref.
 704          (progn
 705            (goto-char p)
 706            (and (search-forward "\nxref:" nil t)
 707                 (nnheader-header-value)))
 708          ;; Extra.
 709          (when nnmail-extra-headers
 710            (let ((extra nnmail-extra-headers)
 711                  out)
 712              (while extra
 713                (goto-char p)
 714                (when (search-forward
 715                       (concat "\n" (symbol-name (car extra)) ":") nil t)
 716                  (push (cons (car extra) (nnheader-header-value))
 717                        out))
 718                (pop extra))
 719              out)))
 720       (goto-char p)
 721       (delete-char 1))))
 722
 723 (defun nnheader-parse-head (&optional naked)
 724   (let ((cur (current-buffer)) num beg end)
 725     (when (if naked
 726               (setq num 0
 727                     beg (point-min)
 728                     end (point-max))
 729             (goto-char (point-min))
 730             ;; Search to the beginning of the next header.  Error
 731             ;; messages do not begin with 2 or 3.
 732             (when (re-search-forward "^[23][0-9]+ " nil t)
 733               (end-of-line)
 734               (setq num (read cur)
 735                     beg (point)
 736                     end (if (search-forward "\n.\n" nil t)
 737                             (- (point) 2)
 738                           (point)))))
 739       (with-temp-buffer
 740         (insert-buffer-substring cur beg end)
 741         (nnheader-parse-naked-head num)))))
 742
 743 (defmacro nnheader-nov-skip-field ()
 744   '(search-forward "\t" eol 'move))
 745
 746 (defmacro nnheader-nov-field ()
 747   '(buffer-substring (point) (if (nnheader-nov-skip-field) (1- (point)) eol)))
 748
 749 (defmacro nnheader-nov-read-integer ()
 750   '(prog1
 751        (if (eq (char-after) ?\t)
 752            0
 753          (let ((num (condition-case nil
 754                         (read (current-buffer))
 755                       (error nil))))
 756            (if (numberp num) num 0)))
 757      (unless (eobp)
 758        (search-forward "\t" eol 'move))))
 759
 760 (defmacro nnheader-nov-parse-extra ()
 761   '(let (out string)
 762      (while (not (memq (char-after) '(?\n nil)))
 763        (setq string (nnheader-nov-field))
 764        (when (string-match "^\\([^ :]+\\): " string)
 765          (push (cons (intern (match-string 1 string))
 766                      (substring string (match-end 0)))
 767                out)))
 768      out))
 769
 770 (defmacro nnheader-nov-read-message-id ()
 771   '(let ((id (nnheader-nov-field)))
 772      (if (string-match "^<[^>]+>$" id)
 773          id
 774        (nnheader-generate-fake-message-id))))
 775
 776 (defun nnheader-parse-nov ()
 777   (let ((eol (point-at-eol)))
 778     (make-full-mail-header
 779      (nnheader-nov-read-integer)        ; number
 780      (nnheader-nov-field)               ; subject
 781      (nnheader-nov-field)               ; from
 782      (nnheader-nov-field)               ; date
 783      (nnheader-nov-read-message-id)     ; id
 784      (nnheader-nov-field)               ; refs
 785      (nnheader-nov-read-integer)        ; chars
 786      (nnheader-nov-read-integer)        ; lines
 787      (if (eq (char-after) ?\n)
 788          nil
 789        (if (looking-at "Xref: ")
 790            (goto-char (match-end 0)))
 791        (nnheader-nov-field))            ; Xref
 792      (nnheader-nov-parse-extra))))      ; extra
 793
 794 (defun nnheader-insert-nov (header)
 795   (princ (mail-header-number header) (current-buffer))
 796   (let ((p (point)))
 797     (insert
 798      "\t"
 799      (or (mime-entity-fetch-field header 'Subject) "(none)") "\t"
 800      (or (mime-entity-fetch-field header 'From) "(nobody)") "\t"
 801      (or (mail-header-date header) "") "\t"
 802      (or (mail-header-id header)
 803          (nnmail-message-id))
 804      "\t"
 805      (or (mail-header-references header) "") "\t")
 806     (princ (or (mail-header-chars header) 0) (current-buffer))
 807     (insert "\t")
 808     (princ (or (mail-header-lines header) 0) (current-buffer))
 809     (insert "\t")
 810     (when (mail-header-xref header)
 811       (insert "Xref: " (mail-header-xref header)))
 812     (when (or (mail-header-xref header)
 813               (mail-header-extra header))
 814       (insert "\t"))
 815     (when (mail-header-extra header)
 816       (let ((extra (mail-header-extra header)))
 817         (while extra
 818           (insert (symbol-name (caar extra))
 819                   ": " (cdar extra) "\t")
 820           (pop extra))))
 821     (insert "\n")
 822     (backward-char 1)
 823     (while (search-backward "\n" p t)
 824       (delete-char 1))
 825     (forward-line 1)))
 826
 827 (defun nnheader-parse-overview-file (file)
 828   "Parse FILE and return a list of headers."
 829   (mm-with-unibyte-buffer
 830     (nnheader-insert-file-contents file)
 831     (goto-char (point-min))
 832     (let (headers)
 833       (while (not (eobp))
 834         (push (nnheader-parse-nov) headers)
 835         (forward-line 1))
 836       (nreverse headers))))
 837
 838 (defun nnheader-write-overview-file (file headers)
 839   "Write HEADERS to FILE."
 840   (with-temp-file file
 841     (mapcar 'nnheader-insert-nov headers)))
 842
 843 (defun nnheader-insert-header (header)
 844   (insert
 845    "Subject: " (or (mail-header-subject header) "(none)") "\n"
 846    "From: " (or (mail-header-from header) "(nobody)") "\n"
 847    "Date: " (or (mail-header-date header) "") "\n"
 848    "Message-ID: " (or (mail-header-id header) (nnmail-message-id)) "\n"
 849    "References: " (or (mail-header-references header) "") "\n"
 850    "Lines: ")
 851   (princ (or (mail-header-lines header) 0) (current-buffer))
 852   (insert "\n\n"))
 853
 854 (defun nnheader-insert-article-line (article)
 855   (goto-char (point-min))
 856   (insert "220 ")
 857   (princ article (current-buffer))
 858   (insert " Article retrieved.\n")
 859   (search-forward "\n\n" nil 'move)
 860   (delete-region (point) (point-max))
 861   (forward-char -1)
 862   (insert "."))
 863
 864 (defun nnheader-nov-delete-outside-range (beg end)
 865   "Delete all NOV lines that lie outside the BEG to END range."
 866   ;; First we find the first wanted line.
 867   (nnheader-find-nov-line beg)
 868   (delete-region (point-min) (point))
 869   ;; Then we find the last wanted line.
 870   (when (nnheader-find-nov-line end)
 871     (forward-line 1))
 872   (delete-region (point) (point-max)))
 873
 874 (defun nnheader-find-nov-line (article)
 875   "Put point at the NOV line that start with ARTICLE.
 876 If ARTICLE doesn't exist, put point where that line
 877 would have been.  The function will return non-nil if
 878 the line could be found."
 879   ;; This function basically does a binary search.
 880   (let ((max (point-max))
 881         (min (goto-char (point-min)))
 882         (cur (current-buffer))
 883         (prev (point-min))
 884         num found)
 885     (while (not found)
 886       (goto-char (+ min (/ (- max min) 2)))
 887       (beginning-of-line)
 888       (if (or (= (point) prev)
 889               (eobp))
 890           (setq found t)
 891         (setq prev (point))
 892         (while (and (not (numberp (setq num (read cur))))
 893                     (not (eobp)))
 894           (gnus-delete-line))
 895         (cond ((> num article)
 896                (setq max (point)))
 897               ((< num article)
 898                (setq min (point)))
 899               (t
 900                (setq found 'yes)))))
 901     ;; We may be at the first line.
 902     (when (and (not num)
 903                (not (eobp)))
 904       (setq num (read cur)))
 905     ;; Now we may have found the article we're looking for, or we
 906     ;; may be somewhere near it.
 907     (when (and (not (eq found 'yes))
 908                (not (eq num article)))
 909       (setq found (point))
 910       (while (and (< (point) max)
 911                   (or (not (numberp num))
 912                       (< num article)))
 913         (forward-line 1)
 914         (setq found (point))
 915         (or (eobp)
 916             (= (setq num (read cur)) article)))
 917       (unless (eq num article)
 918         (goto-char found)))
 919     (beginning-of-line)
 920     (eq num article)))
 921
 922 (defun nnheader-retrieve-headers-from-directory* (articles
 923                                                   directory dependencies
 924                                                   &optional
 925                                                   fetch-old force-new large
 926                                                   backend)
 927   (with-temp-buffer
 928     (let* ((file nil)
 929            (number (length articles))
 930            (count 0)
 931            (file-name-coding-system 'binary)
 932            (case-fold-search t)
 933            (cur (current-buffer))
 934            article
 935            headers header id end ref in-reply-to lines chars ctype)
 936       ;; We don't support fetching by Message-ID.
 937       (if (stringp (car articles))
 938           'headers
 939         (while articles
 940           (when (and (file-exists-p
 941                       (setq file (expand-file-name
 942                                   (int-to-string
 943                                    (setq article (pop articles)))
 944                                   directory)))
 945                      (not (file-directory-p file)))
 946             (erase-buffer)
 947             (nnheader-insert-head file)
 948             (save-restriction
 949               (std11-narrow-to-header)
 950               (setq
 951                header
 952                (make-full-mail-header
 953                 ;; Number.
 954                 article
 955                 ;; Subject.
 956                 (or (std11-fetch-field "Subject")
 957                     "(none)")
 958                 ;; From.
 959                 (or (std11-fetch-field "From")
 960                     "(nobody)")
 961                 ;; Date.
 962                 (or (std11-fetch-field "Date")
 963                     "")
 964                 ;; Message-ID.
 965                 (progn
 966                   (goto-char (point-min))
 967                   (setq id (if (re-search-forward
 968                                 "^Message-ID: *\\(<[^\n\t> ]+>\\)" nil t)
 969                                ;; We do it this way to make sure the Message-ID
 970                                ;; is (somewhat) syntactically valid.
 971                                (buffer-substring (match-beginning 1)
 972                                                  (match-end 1))
 973                              ;; If there was no message-id, we just fake one
 974                              ;; to make subsequent routines simpler.
 975                              (nnheader-generate-fake-message-id))))
 976                 ;; References.
 977                 (progn
 978                   (goto-char (point-min))
 979                   (if (search-forward "\nReferences: " nil t)
 980                       (progn
 981                         (setq end (point))
 982                         (prog1
 983                             (buffer-substring (match-end 0) (std11-field-end))
 984                           (setq ref
 985                                 (buffer-substring
 986                                  (progn
 987                                    ;; (end-of-line)
 988                                    (search-backward ">" end t)
 989                                    (1+ (point)))
 990                                  (progn
 991                                    (search-backward "<" end t)
 992                                    (point))))))
 993                     ;; Get the references from the in-reply-to header if there
 994                     ;; were no references and the in-reply-to header looks
 995                     ;; promising.
 996                     (if (and (search-forward "\nIn-Reply-To: " nil t)
 997                              (setq in-reply-to
 998                                    (buffer-substring (match-end 0)
 999                                                      (std11-field-end)))
1000                              (string-match "<[^>]+>" in-reply-to))
1001                         (let (ref2)
1002                           (setq ref (substring in-reply-to (match-beginning 0)
1003                                                (match-end 0)))
1004                           (while (string-match "<[^>]+>"
1005                                                in-reply-to (match-end 0))
1006                             (setq ref2
1007                                   (substring in-reply-to (match-beginning 0)
1008                                              (match-end 0)))
1009                             (when (> (length ref2) (length ref))
1010                               (setq ref ref2)))
1011                           ref)
1012                       (setq ref nil))))
1013                 ;; Chars.
1014                 (progn
1015                   (goto-char (point-min))
1016                   (if (search-forward "\nChars: " nil t)
1017                       (if (numberp (setq chars (ignore-errors (read cur))))
1018                           chars 0)
1019                     0))
1020                 ;; Lines.
1021                 (progn
1022                   (goto-char (point-min))
1023                   (if (search-forward "\nLines: " nil t)
1024                       (if (numberp (setq lines (ignore-errors (read cur))))
1025                           lines 0)
1026                     0))
1027                 ;; Xref.
1028                 (std11-fetch-field "Xref")
1029                 ))
1030               (goto-char (point-min))
1031               (if (setq ctype (std11-fetch-field "Content-Type"))
1032                   (mime-entity-set-content-type-internal
1033                    header (mime-parse-Content-Type ctype)))
1034               )
1035             (when (setq header
1036                         (gnus-dependencies-add-header
1037                          header dependencies force-new))
1038               (push header headers))
1039             )
1040           (setq count (1+ count))
1041
1042           (and large
1043                (zerop (% count 20))
1044                (nnheader-message 5 "%s: Receiving headers... %d%%"
1045                                  backend
1046                                  (/ (* count 100) number))))
1047
1048         (when large
1049           (nnheader-message 5 "%s: Receiving headers...done" backend))
1050
1051         headers))))
1052
1053 (defun nnheader-retrieve-headers-from-directory (articles
1054                                                  directory dependencies
1055                                                  &optional
1056                                                  fetch-old force-new large
1057                                                  backend)
1058   (cons 'header
1059         (nreverse (nnheader-retrieve-headers-from-directory*
1060                    articles directory dependencies
1061                    fetch-old force-new large backend))))
1062
1063 (defun nnheader-get-newsgroup-headers-xover* (sequence
1064                                               &optional
1065                                               force-new dependencies
1066                                               group)
1067   "Parse the news overview data in the server buffer, and return a
1068 list of headers that match SEQUENCE (see `nntp-retrieve-headers')."
1069   ;; Get the Xref when the users reads the articles since most/some
1070   ;; NNTP servers do not include Xrefs when using XOVER.
1071   ;; (setq gnus-article-internal-prepare-hook '(gnus-article-get-xrefs))
1072   (let ((cur nntp-server-buffer)
1073         number headers header)
1074     (save-excursion
1075       (set-buffer nntp-server-buffer)
1076       ;; Allow the user to mangle the headers before parsing them.
1077       (gnus-run-hooks 'gnus-parse-headers-hook)
1078       (goto-char (point-min))
1079       (while (not (eobp))
1080         (condition-case ()
1081             (while (and sequence (not (eobp)))
1082               (setq number (read cur))
1083               (while (and sequence
1084                           (< (car sequence) number))
1085                 (setq sequence (cdr sequence)))
1086               (and sequence
1087                    (eq number (car sequence))
1088                    (progn
1089                      (setq sequence (cdr sequence))
1090                      (setq header (inline
1091                                     (gnus-nov-parse-line
1092                                      number dependencies force-new))))
1093                    (push header headers))
1094               (forward-line 1))
1095           (error
1096            (gnus-error 4 "Strange nov line (%d)"
1097                        (count-lines (point-min) (point)))))
1098         (forward-line 1))
1099       ;; A common bug in inn is that if you have posted an article and
1100       ;; then retrieves the active file, it will answer correctly --
1101       ;; the new article is included.  However, a NOV entry for the
1102       ;; article may not have been generated yet, so this may fail.
1103       ;; We work around this problem by retrieving the last few
1104       ;; headers using HEAD.
1105       headers)))
1106
1107 ;; Various cruft the backends and Gnus need to communicate.
1108
1109 (defvar nntp-server-buffer nil)
1110 (defvar nntp-process-response nil)
1111 (defvar news-reply-yank-from nil)
1112 (defvar news-reply-yank-message-id nil)
1113
1114 (defvar nnheader-callback-function nil)
1115
1116 (defun nnheader-init-server-buffer ()
1117   "Initialize the Gnus-backend communication buffer."
1118   (save-excursion
1119     (unless (gnus-buffer-live-p nntp-server-buffer)
1120       (setq nntp-server-buffer (get-buffer-create " *nntpd*")))
1121     (set-buffer nntp-server-buffer)
1122     (erase-buffer)
1123     (kill-all-local-variables)
1124     (setq case-fold-search t)           ;Should ignore case.
1125     (set (make-local-variable 'nntp-process-response) nil)
1126     t))
1127
1128 ;;; Various functions the backends use.
1129
1130 (defun nnheader-file-error (file)
1131   "Return a string that says what is wrong with FILE."
1132   (format
1133    (cond
1134     ((not (file-exists-p file))
1135      "%s does not exist")
1136     ((file-directory-p file)
1137      "%s is a directory")
1138     ((not (file-readable-p file))
1139      "%s is not readable"))
1140    file))
1141
1142 (defun nnheader-insert-head (file)
1143   "Insert the head of the article."
1144   (when (file-exists-p file)
1145     (if (eq nnheader-max-head-length t)
1146         ;; Just read the entire file.
1147         (nnheader-insert-file-contents file)
1148       ;; Read 1K blocks until we find a separator.
1149       (let ((beg 0)
1150             format-alist)
1151         (while (and (eq nnheader-head-chop-length
1152                         (nth 1 (nnheader-insert-file-contents
1153                                 file nil beg
1154                                 (incf beg nnheader-head-chop-length))))
1155                     (prog1 (not (search-forward "\n\n" nil t))
1156                       (goto-char (point-max)))
1157                     (or (null nnheader-max-head-length)
1158                         (< beg nnheader-max-head-length))))))
1159     t))
1160
1161 (defun nnheader-article-p ()
1162   "Say whether the current buffer looks like an article."
1163   (goto-char (point-min))
1164   (if (not (search-forward "\n\n" nil t))
1165       nil
1166     (narrow-to-region (point-min) (1- (point)))
1167     (goto-char (point-min))
1168     (while (looking-at "[a-zA-Z][^ \t]+:.*\n\\([ \t].*\n\\)*\\|From .*\n")
1169       (goto-char (match-end 0)))
1170     (prog1
1171         (eobp)
1172       (widen))))
1173
1174 (defun nnheader-insert-references (references message-id)
1175   "Insert a References header based on REFERENCES and MESSAGE-ID."
1176   (if (and (not references) (not message-id))
1177       ;; This is invalid, but not all articles have Message-IDs.
1178       ()
1179     (mail-position-on-field "References")
1180     (let ((begin (point-at-bol))
1181           (fill-column 78)
1182           (fill-prefix "\t"))
1183       (when references
1184         (insert references))
1185       (when (and references message-id)
1186         (insert " "))
1187       (when message-id
1188         (insert message-id))
1189       ;; Fold long References lines to conform to RFC1036 (sort of).
1190       ;; The region must end with a newline to fill the region
1191       ;; without inserting extra newline.
1192       (fill-region-as-paragraph begin (1+ (point))))))
1193
1194 (defun nnheader-replace-header (header new-value)
1195   "Remove HEADER and insert the NEW-VALUE."
1196   (save-excursion
1197     (save-restriction
1198       (nnheader-narrow-to-headers)
1199       (prog1
1200           (message-remove-header header)
1201         (goto-char (point-max))
1202         (insert header ": " new-value "\n")))))
1203
1204 (defun nnheader-narrow-to-headers ()
1205   "Narrow to the head of an article."
1206   (widen)
1207   (narrow-to-region
1208    (goto-char (point-min))
1209    (if (search-forward "\n\n" nil t)
1210        (1- (point))
1211      (point-max)))
1212   (goto-char (point-min)))
1213
1214 (defun nnheader-get-lines-and-char ()
1215   "Return the number of lines and chars in the article body."
1216   (goto-char (point-min))
1217   (if (not (re-search-forward "\n\r?\n" nil t))
1218       (list 0 0)
1219     (list (count-lines (point) (point-max))
1220           (- (point-max) (point)))))
1221
1222 (defun nnheader-remove-body ()
1223   "Remove the body from an article in this current buffer."
1224   (goto-char (point-min))
1225   (when (re-search-forward "\n\r?\n" nil t)
1226     (delete-region (point) (point-max))))
1227
1228 (defun nnheader-set-temp-buffer (name &optional noerase)
1229   "Set-buffer to an empty (possibly new) buffer called NAME with undo disabled."
1230   (set-buffer (get-buffer-create name))
1231   (buffer-disable-undo)
1232   (unless noerase
1233     (erase-buffer))
1234   (current-buffer))
1235
1236 (eval-when-compile (defvar jka-compr-compression-info-list))
1237 (defvar nnheader-numerical-files
1238   (if (boundp 'jka-compr-compression-info-list)
1239       (concat "\\([0-9]+\\)\\("
1240               (mapconcat (lambda (i) (aref i 0))
1241                          jka-compr-compression-info-list "\\|")
1242               "\\)?")
1243     "[0-9]+$")
1244   "Regexp that match numerical files.")
1245
1246 (defvar nnheader-numerical-short-files (concat "^" nnheader-numerical-files)
1247   "Regexp that matches numerical file names.")
1248
1249 (defvar nnheader-numerical-full-files (concat "/" nnheader-numerical-files)
1250   "Regexp that matches numerical full file names.")
1251
1252 (defsubst nnheader-file-to-number (file)
1253   "Take a FILE name and return the article number."
1254   (if (string= nnheader-numerical-short-files "^[0-9]+$")
1255       (string-to-int file)
1256     (string-match nnheader-numerical-short-files file)
1257     (string-to-int (match-string 0 file))))
1258
1259 (defvar nnheader-directory-files-is-safe
1260   (or (eq system-type 'windows-nt)
1261       (not (featurep 'xemacs)))
1262   "If non-nil, Gnus believes `directory-files' is safe.
1263 It has been reported numerous times that `directory-files' fails with
1264 an alarming frequency on NFS mounted file systems. If it is nil,
1265 `nnheader-directory-files-safe' is used.")
1266
1267 (defun nnheader-directory-files-safe (&rest args)
1268   "Execute `directory-files' twice and returns the longer result."
1269   (let ((first (apply 'directory-files args))
1270         (second (apply 'directory-files args)))
1271     (if (> (length first) (length second))
1272         first
1273       second)))
1274
1275 (defun nnheader-directory-articles (dir)
1276   "Return a list of all article files in directory DIR."
1277   (mapcar 'nnheader-file-to-number
1278           (if nnheader-directory-files-is-safe
1279               (directory-files
1280                dir nil nnheader-numerical-short-files t)
1281             (nnheader-directory-files-safe
1282              dir nil nnheader-numerical-short-files t))))
1283
1284 (defun nnheader-article-to-file-alist (dir)
1285   "Return an alist of article/file pairs in DIR."
1286   (mapcar (lambda (file) (cons (nnheader-file-to-number file) file))
1287           (if nnheader-directory-files-is-safe
1288               (directory-files
1289                dir nil nnheader-numerical-short-files t)
1290             (nnheader-directory-files-safe
1291              dir nil nnheader-numerical-short-files t))))
1292
1293 (defun nnheader-fold-continuation-lines ()
1294   "Fold continuation lines in the current buffer."
1295   (nnheader-replace-regexp "\\(\r?\n[ \t]+\\)+" " "))
1296
1297 (defun nnheader-translate-file-chars (file &optional full)
1298   "Translate FILE into something that can be a file name.
1299 If FULL, translate everything."
1300   (if (null nnheader-file-name-translation-alist)
1301       ;; No translation is necessary.
1302       file
1303     (let* ((i 0)
1304            trans leaf path len)
1305       (if full
1306           ;; Do complete translation.
1307           (setq leaf (copy-sequence file)
1308                 path ""
1309                 i (if (and (< 1 (length leaf)) (eq ?: (aref leaf 1)))
1310                       2 0))
1311         ;; We translate -- but only the file name.  We leave the directory
1312         ;; alone.
1313         (if (and (featurep 'xemacs)
1314                  (memq system-type '(cygwin32 win32 w32 mswindows windows-nt
1315                                               cygwin)))
1316             ;; This is needed on NT and stuff, because
1317             ;; file-name-nondirectory is not enough to split
1318             ;; file names, containing ':', e.g.
1319             ;; "d:\\Work\\News\\nntp+news.fido7.ru:fido7.ru.gnu.SCORE"
1320             ;;
1321             ;; we are trying to correctly split such names:
1322             ;; "d:file.name" -> "a:" "file.name"
1323             ;; "aaa:bbb.ccc" -> "" "aaa:bbb.ccc"
1324             ;; "d:aaa\\bbb:ccc"   -> "d:aaa\\" "bbb:ccc"
1325             ;; etc.
1326             ;; to translate then only the file name part.
1327             (progn
1328               (setq leaf file
1329                     path "")
1330               (if (string-match "\\(^\\w:\\|[/\\]\\)\\([^/\\]+\\)$" file)
1331                   (setq leaf (substring file (match-beginning 2))
1332                         path (substring file 0 (match-beginning 2)))))
1333           ;; Emacs DTRT, says andrewi.
1334           (setq leaf (file-name-nondirectory file)
1335                 path (file-name-directory file))))
1336       (setq len (length leaf))
1337       (while (< i len)
1338         (when (setq trans (cdr (assq (aref leaf i)
1339                                      nnheader-file-name-translation-alist)))
1340           (aset leaf i trans))
1341         (incf i))
1342       (concat path leaf))))
1343
1344 (defun nnheader-report (backend &rest args)
1345   "Report an error from the BACKEND.
1346 The first string in ARGS can be a format string."
1347   (set (intern (format "%s-status-string" backend))
1348        (if (< (length args) 2)
1349            (car args)
1350          (apply 'format args)))
1351   nil)
1352
1353 (defun nnheader-get-report (backend)
1354   "Get the most recent report from BACKEND."
1355   (condition-case ()
1356       (nnheader-message 5 "%s" (symbol-value (intern (format "%s-status-string"
1357                                                              backend))))
1358     (error (nnheader-message 5 ""))))
1359
1360 (defun nnheader-insert (format &rest args)
1361   "Clear the communication buffer and insert FORMAT and ARGS into the buffer.
1362 If FORMAT isn't a format string, it and all ARGS will be inserted
1363 without formatting."
1364   (save-excursion
1365     (set-buffer nntp-server-buffer)
1366     (erase-buffer)
1367     (if (string-match "%" format)
1368         (insert (apply 'format format args))
1369       (apply 'insert format args))
1370     t))
1371
1372 (static-if (fboundp 'subst-char-in-string)
1373     (defsubst nnheader-replace-chars-in-string (string from to)
1374       (subst-char-in-string from to string))
1375   (defun nnheader-replace-chars-in-string (string from to)
1376     "Replace characters in STRING from FROM to TO."
1377     (let ((string (substring string 0)) ;Copy string.
1378           (len (length string))
1379           (idx 0))
1380       ;; Replace all occurrences of FROM with TO.
1381       (while (< idx len)
1382         (when (= (aref string idx) from)
1383           (aset string idx to))
1384         (setq idx (1+ idx)))
1385       string)))
1386
1387 (defun nnheader-replace-duplicate-chars-in-string (string from to)
1388   "Replace characters in STRING from FROM to TO."
1389   (let ((string (substring string 0))   ;Copy string.
1390         (len (length string))
1391         (idx 0) prev i)
1392     ;; Replace all occurrences of FROM with TO.
1393     (while (< idx len)
1394       (setq i (aref string idx))
1395       (when (and (eq prev from) (= i from))
1396         (aset string (1- idx) to)
1397         (aset string idx to))
1398       (setq prev i)
1399       (setq idx (1+ idx)))
1400     string))
1401
1402 (defun nnheader-file-to-group (file &optional top)
1403   "Return a group name based on FILE and TOP."
1404   (nnheader-replace-chars-in-string
1405    (if (not top)
1406        file
1407      (condition-case ()
1408          (substring (expand-file-name file)
1409                     (length
1410                      (expand-file-name
1411                       (file-name-as-directory top))))
1412        (error "")))
1413    nnheader-directory-separator-character ?.))
1414
1415 (defun nnheader-message (level &rest args)
1416   "Message if the Gnus backends are talkative."
1417   (if (or (not (numberp gnus-verbose-backends))
1418           (<= level gnus-verbose-backends))
1419       (apply 'message args)
1420     (apply 'format args)))
1421
1422 (defun nnheader-be-verbose (level)
1423   "Return whether the backends should be verbose on LEVEL."
1424   (or (not (numberp gnus-verbose-backends))
1425       (<= level gnus-verbose-backends)))
1426
1427 (defvar nnheader-pathname-coding-system 'binary
1428   "*Coding system for file name.")
1429
1430 (defun nnheader-group-pathname (group dir &optional file)
1431   "Make file name for GROUP."
1432   (concat
1433    (let ((dir (file-name-as-directory (expand-file-name dir))))
1434      ;; If this directory exists, we use it directly.
1435      (file-name-as-directory
1436       (if (file-directory-p (concat dir group))
1437           (expand-file-name group dir)
1438         ;; If not, we translate dots into slashes.
1439         (expand-file-name (encode-coding-string
1440                            (nnheader-replace-chars-in-string group ?. ?/)
1441                            nnheader-pathname-coding-system)
1442                           dir))))
1443    (cond ((null file) "")
1444          ((numberp file) (int-to-string file))
1445          (t file))))
1446
1447 (defun nnheader-concat (dir &rest files)
1448   "Concat DIR as directory to FILES."
1449   (apply 'concat (file-name-as-directory dir) files))
1450
1451 (defun nnheader-ms-strip-cr ()
1452   "Strip ^M from the end of all lines."
1453   (save-excursion
1454     (nnheader-remove-cr-followed-by-lf)))
1455
1456 (defun nnheader-file-size (file)
1457   "Return the file size of FILE or 0."
1458   (or (nth 7 (file-attributes file)) 0))
1459
1460 (defun nnheader-find-etc-directory (package &optional file first)
1461   "Go through `load-path' and find the \"../etc/PACKAGE\" directory.
1462 This function will look in the parent directory of each `load-path'
1463 entry, and look for the \"etc\" directory there.
1464 If FILE, find the \".../etc/PACKAGE\" file instead.
1465 If FIRST is non-nil, return the directory or the file found at the
1466 first.  Otherwise, find the newest one, though it may take a time."
1467   (let ((path load-path)
1468         dir results)
1469     ;; We try to find the dir by looking at the load path,
1470     ;; stripping away the last component and adding "etc/".
1471     (while path
1472       (if (and (car path)
1473                (file-exists-p
1474                 (setq dir (concat
1475                            (file-name-directory
1476                             (directory-file-name (car path)))
1477                            "etc/" package
1478                            (if file "" "/"))))
1479                (or file (file-directory-p dir)))
1480           (progn
1481             (or (member dir results)
1482                 (push dir results))
1483             (setq path (if first nil (cdr path))))
1484         (setq path (cdr path))))
1485     (if (or first (not (cdr results)))
1486         (car results)
1487       (car (sort results 'file-newer-than-file-p)))))
1488
1489 (eval-when-compile
1490   (defvar ange-ftp-path-format)
1491   (defvar efs-path-regexp))
1492 (defun nnheader-re-read-dir (path)
1493   "Re-read directory PATH if PATH is on a remote system."
1494   (if (and (fboundp 'efs-re-read-dir) (boundp 'efs-path-regexp))
1495       (when (string-match efs-path-regexp path)
1496         (efs-re-read-dir path))
1497     (when (and (fboundp 'ange-ftp-re-read-dir) (boundp 'ange-ftp-path-format))
1498       (when (string-match (car ange-ftp-path-format) path)
1499         (ange-ftp-re-read-dir path)))))
1500
1501 (defvar nnheader-file-coding-system 'raw-text
1502   "Coding system used in file backends of Gnus.")
1503
1504 (defun nnheader-insert-file-contents (filename &optional visit beg end replace)
1505   "Like `insert-file-contents', q.v., but only reads in the file.
1506 A buffer may be modified in several ways after reading into the buffer due
1507 to advanced Emacs features, such as file-name-handlers, format decoding,
1508 find-file-hooks, etc.
1509   This function ensures that none of these modifications will take place."
1510   (let ((format-alist nil)
1511         (auto-mode-alist (nnheader-auto-mode-alist))
1512         (default-major-mode 'fundamental-mode)
1513         (enable-local-variables nil)
1514         (after-insert-file-functions nil)
1515         (enable-local-eval nil)
1516         (find-file-hooks nil))
1517     (insert-file-contents-as-coding-system
1518      nnheader-file-coding-system filename visit beg end replace)))
1519
1520 (defun nnheader-insert-nov-file (file first)
1521   (let ((size (nth 7 (file-attributes file)))
1522         (cutoff (* 32 1024)))
1523     (when size
1524       (if (< size cutoff)
1525           ;; If the file is small, we just load it.
1526           (nnheader-insert-file-contents file)
1527         ;; We start on the assumption that FIRST is pretty recent.  If
1528         ;; not, we just insert the rest of the file as well.
1529         (let (current)
1530           (nnheader-insert-file-contents file nil (- size cutoff) size)
1531           (goto-char (point-min))
1532           (delete-region (point) (or (search-forward "\n" nil 'move) (point)))
1533           (setq current (ignore-errors (read (current-buffer))))
1534           (if (and (numberp current)
1535                    (< current first))
1536               t
1537             (delete-region (point-min) (point-max))
1538             (nnheader-insert-file-contents file)))))))
1539
1540 (defun nnheader-find-file-noselect (&rest args)
1541   (let ((format-alist nil)
1542         (auto-mode-alist (nnheader-auto-mode-alist))
1543         (default-major-mode 'fundamental-mode)
1544         (enable-local-variables nil)
1545         (after-insert-file-functions nil)
1546         (enable-local-eval nil)
1547         (find-file-hooks nil))
1548     (apply 'find-file-noselect-as-coding-system
1549            nnheader-file-coding-system args)))
1550
1551 (defun nnheader-auto-mode-alist ()
1552   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
1553   (let ((alist auto-mode-alist)
1554         out)
1555     (while alist
1556       (when (listp (cdar alist))
1557         (push (car alist) out))
1558       (pop alist))
1559     (nreverse out)))
1560
1561 (defun nnheader-directory-regular-files (dir)
1562   "Return a list of all regular files in DIR."
1563   (let ((files (directory-files dir t))
1564         out)
1565     (while files
1566       (when (file-regular-p (car files))
1567         (push (car files) out))
1568       (pop files))
1569     (nreverse out)))
1570
1571 (defun nnheader-directory-files (&rest args)
1572   "Same as `directory-files', but prune \".\" and \"..\"."
1573   (let ((files (apply 'directory-files args))
1574         out)
1575     (while files
1576       (unless (member (file-name-nondirectory (car files)) '("." ".."))
1577         (push (car files) out))
1578       (pop files))
1579     (nreverse out)))
1580
1581 (defmacro nnheader-skeleton-replace (from &optional to regexp)
1582   `(let ((new (generate-new-buffer " *nnheader replace*"))
1583          (cur (current-buffer))
1584          (start (point-min)))
1585      (set-buffer cur)
1586      (goto-char (point-min))
1587      (while (,(if regexp 're-search-forward 'search-forward)
1588              ,from nil t)
1589        (insert-buffer-substring
1590         cur start (prog1 (match-beginning 0) (set-buffer new)))
1591        (goto-char (point-max))
1592        ,(when to `(insert ,to))
1593        (set-buffer cur)
1594        (setq start (point)))
1595      (insert-buffer-substring
1596       cur start (prog1 (point-max) (set-buffer new)))
1597      (copy-to-buffer cur (point-min) (point-max))
1598      (kill-buffer (current-buffer))
1599      (set-buffer cur)))
1600
1601 (defun nnheader-replace-string (from to)
1602   "Do a fast replacement of FROM to TO from point to `point-max'."
1603   (nnheader-skeleton-replace from to))
1604
1605 (defun nnheader-replace-regexp (from to)
1606   "Do a fast regexp replacement of FROM to TO from point to `point-max'."
1607   (nnheader-skeleton-replace from to t))
1608
1609 (defun nnheader-strip-cr ()
1610   "Strip all \r's from the current buffer."
1611   (nnheader-skeleton-replace "\r"))
1612
1613 (defalias 'nnheader-cancel-timer 'cancel-timer)
1614 (defalias 'nnheader-cancel-function-timers 'cancel-function-timers)
1615 (defalias 'nnheader-string-as-multibyte 'string-as-multibyte)
1616
1617 (defun nnheader-Y-or-n-p (prompt)
1618   "Ask user a \"Y/n\" question. Return t if answer is neither \"n\", \"N\" nor \"C-g\"."
1619   (let ((cursor-in-echo-area t)
1620         (echo-keystrokes 0)
1621         (inhibit-quit t)
1622         ans)
1623     (let (message-log-max)
1624       (while (not (memq ans '(?\  ?N ?Y ?\C-g ?\e ?\n ?\r ?n ?y)))
1625         (message "%s(Y/n) " prompt)
1626         (setq ans (read-char-exclusive))))
1627     (if (memq ans '(?\C-g ?N ?n))
1628         (progn
1629           (message "%s(Y/n) No" prompt)
1630           nil)
1631       (message "%s(Y/n) Yes" prompt)
1632       t)))
1633
1634 (defun-maybe shell-command-to-string (command)
1635   "Execute shell command COMMAND and return its output as a string."
1636   (with-output-to-string
1637     (with-current-buffer
1638         standard-output
1639       (call-process shell-file-name nil t nil shell-command-switch command))))
1640
1641 (defun nnheader-accept-process-output (process)
1642   (accept-process-output
1643    process
1644    (truncate nnheader-read-timeout)
1645    (truncate (* (- nnheader-read-timeout
1646                    (truncate nnheader-read-timeout))
1647                 1000))))
1648
1649 (when (featurep 'xemacs)
1650   (require 'nnheaderxm))
1651
1652 (run-hooks 'nnheader-load-hook)
1653
1654 (provide 'nnheader)
1655
1656 ;;; nnheader.el ends here