git.chise.org Git - elisp/gnus.git-/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   6 ;;         Jim Radford <radford@robby.caltech.edu>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Todo, major things:
  29 ;;
  30 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  31 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  32 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  33 ;;   o Sieve
  34 ;;   o MIME (partial article fetches)
  35 ;;   o Split to other backends, different split rules for different
  36 ;;     servers/inboxes
  37 ;;
  38 ;; Todo, minor things:
  39 ;;
  40 ;;   o Don't require half of Gnus -- backends should be standalone
  41 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  42 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  43 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  44 ;;   o What do I do with gnus-newsgroup-*?
  45 ;;   o Tell Gnus about new groups (how can we tell?)
  46 ;;   o Respooling (fix Gnus?) (unnecessary?)
  47 ;;   o Add support for the following: (if applicable)
  48 ;;       request-list-newsgroups, request-regenerate
  49 ;;       list-active-group,
  50 ;;       request-associate-buffer, request-restore-buffer,
  51 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  52 ;;   o Support RFC2221 (Login referrals)
  53 ;;   o IMAP2BIS compatibility? (RFC2061)
  54 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  55 ;;     .newsrc.eld)
  56 ;;   o What about Gnus's article editing, can we support it?  NO!
  57 ;;   o Use \Draft to support the draft group??
  58 ;;   o Duplicate suppression
  59 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  60
  61 ;;; Code:
  62
  63 (eval-when-compile (require 'cl))
  64 (require 'imap)
  65
  66 (require 'nnoo)
  67 (require 'nnmail)
  68 (require 'nnheader)
  69 (require 'gnus)
  70 (require 'gnus-range)
  71 (require 'gnus-start)
  72 (require 'gnus-int)
  73
  74 (eval-when-compile (require 'cl))
  75
  76 (nnoo-declare nnimap)
  77
  78 (defconst nnimap-version "nnimap 1.0")
  79
  80 (defgroup nnimap nil
  81   "Reading IMAP mail with Gnus."
  82   :group 'gnus)
  83
  84 (defvoo nnimap-address nil
  85   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  86
  87 (defvoo nnimap-server-port nil
  88   "Port number on physical IMAP server.
  89 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  90
  91 ;; Splitting variables
  92
  93 (defcustom nnimap-split-crosspost t
  94   "If non-nil, do crossposting if several split methods match the mail.
  95 If nil, the first match found will be used."
  96   :group 'nnimap
  97   :type 'boolean)
  98
  99 (defcustom nnimap-split-inbox nil
 100   "Name of mailbox to split mail from.
 101
 102 Mail is read from this mailbox and split according to rules in
 103 `nnimap-split-rule'.
 104
 105 This can be a string or a list of strings."
 106   :group 'nnimap
 107   :type '(choice (string)
 108                  (repeat string)))
 109
 110 (define-widget 'nnimap-strict-function 'function
 111   "This widget only matches values that are functionp.
 112
 113 Warning: This means that a value that is the symbol of a not yet
 114 loaded function will not match.  Use with care."
 115   :match 'nnimap-strict-function-match)
 116
 117 (defun nnimap-strict-function-match (widget value)
 118   "Ignoring WIDGET, match if VALUE is a function."
 119   (functionp value))
 120
 121 (defcustom nnimap-split-rule nil
 122   "Mail will be split according to these rules.
 123
 124 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 125
 126 If you'd like, for instance, one mail group for mail from the
 127 \"gnus-imap\" mailing list, one group for junk mail and leave
 128 everything else in the incoming mailbox, you could do something like
 129 this:
 130
 131 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 132                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 133
 134 As you can see, `nnimap-split-rule' is a list of lists, where the
 135 first element in each \"rule\" is the name of the IMAP mailbox (or the
 136 symbol `junk' if you want to remove the mail), and the second is a
 137 regexp that nnimap will try to match on the header to find a fit.
 138
 139 The second element can also be a function.  In that case, it will be
 140 called narrowed to the headers with the first element of the rule as
 141 the argument.  It should return a non-nil value if it thinks that the
 142 mail belongs in that group.
 143
 144 This variable can also have a function as its value, the function will
 145 be called with the headers narrowed and should return a group where it
 146 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 147
 148 To allow for different split rules on different virtual servers, and
 149 even different split rules in different inboxes on the same server,
 150 the syntax of this variable have been extended along the lines of:
 151
 152 \(setq nnimap-split-rule
 153       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 154                                   (\"junk\"    \"From:.*Simon\")))
 155         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 156         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 157                                   (\"junk\"    my-junk-func)))))
 158
 159 The virtual server name is in fact a regexp, so that the same rules
 160 may apply to several servers.  In the example, the servers
 161 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 162 the inbox string is also a regexp.  The actual splitting rules are as
 163 before, either a function, or a list with group/regexp or
 164 group/function elements."
 165   :group 'nnimap
 166   :type '(choice :tag "Rule type"
 167                  (repeat :menu-tag "Single-server"
 168                          :tag "Single-server list"
 169                          (list (string :tag "Mailbox")
 170                                (choice :tag "Predicate"
 171                                        (regexp :tag "A regexp")
 172                                        (nnimap-strict-function :tag "A function"))))
 173                  (choice :menu-tag "A function"
 174                          :tag "A function"
 175                          (function-item nnimap-split-fancy)
 176                          (function-item nnmail-split-fancy)
 177                          (nnimap-strict-function :tag "User-defined function"))
 178                  (repeat :menu-tag "Multi-server (extended)"
 179                          :tag "Multi-server list"
 180                          (list (regexp :tag "Server regexp")
 181                                (list (regexp :tag "Incoming Mailbox regexp")
 182                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 183                                              (list (string :tag "Destination mailbox")
 184                                                    (choice :tag "Predicate"
 185                                                            (regexp :tag "A Regexp")
 186                                                            (nnimap-strict-function :tag "A Function")))))))))
 187
 188 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 189   "The predicate used to find articles to split.
 190 If you use another IMAP client to peek on articles but always would
 191 like nnimap to split them once it's started, you could change this to
 192 \"UNDELETED\". Other available predicates are available in
 193 RFC2060 section 6.4.4."
 194   :group 'nnimap
 195   :type 'string)
 196
 197 (defcustom nnimap-split-fancy nil
 198   "Like the variable `nnmail-split-fancy'."
 199   :group 'nnimap
 200   :type 'sexp)
 201
 202 (defvar nnimap-split-download-body-default nil
 203   "Internal variable with default value for `nnimap-split-download-body'.")
 204
 205 (defcustom nnimap-split-download-body 'default
 206   "Whether to download entire articles during splitting.
 207 This is generally not required, and will slow things down considerably.
 208 You may need it if you want to use an advanced splitting function that
 209 analyses the body before splitting the article.
 210 If this variable is nil, bodies will not be downloaded; if this
 211 variable is the symbol `default' the default behaviour is
 212 used (which currently is nil, unless you use a statistical
 213 spam.el test); if this variable is another non-nil value bodies
 214 will be downloaded."
 215   :version "22.1"
 216   :group 'nnimap
 217   :type '(choice (const :tag "Let system decide" deault)
 218                  boolean))
 219
 220 ;; Performance / bug workaround variables
 221
 222 (defcustom nnimap-close-asynchronous t
 223   "Close mailboxes asynchronously in `nnimap-close-group'.
 224 This means that errors caught by nnimap when closing the mailbox will
 225 not prevent Gnus from updating the group status, which may be harmful.
 226 However, it increases speed."
 227   :version "22.1"
 228   :type 'boolean
 229   :group 'nnimap)
 230
 231 (defcustom nnimap-dont-close t
 232   "Never close mailboxes.
 233 This increases the speed of closing mailboxes (quiting group) but may
 234 decrease the speed of selecting another mailbox later.  Re-selecting
 235 the same mailbox will be faster though."
 236   :version "22.1"
 237   :type 'boolean
 238   :group 'nnimap)
 239
 240 (defcustom nnimap-retrieve-groups-asynchronous t
 241   "Send asynchronous STATUS commands for each mailbox before checking mail.
 242 If you have mailboxes that rarely receives mail, this speeds up new
 243 mail checking.  It works by first sending STATUS commands for each
 244 mailbox, and then only checking groups which has a modified UIDNEXT
 245 more carefully for new mail.
 246
 247 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 248 it O(n).  If p is small, then the default is probably faster."
 249   :version "22.1"
 250   :type 'boolean
 251   :group 'nnimap)
 252
 253 (defvoo nnimap-need-unselect-to-notice-new-mail nil
 254   "Unselect mailboxes before looking for new mail in them.
 255 Some servers seem to need this under some circumstances.")
 256
 257 ;; Authorization / Privacy variables
 258
 259 (defvoo nnimap-auth-method nil
 260   "Obsolete.")
 261
 262 (defvoo nnimap-stream nil
 263   "How nnimap will connect to the server.
 264
 265 The default, nil, will try to use the \"best\" method the server can
 266 handle.
 267
 268 Change this if
 269
 270 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 271    with IMAP is suboptimal so you'll have to tell it
 272    specifically.
 273
 274 2) your server is more capable than your environment -- i.e. your
 275    server accept Kerberos login's but you haven't installed the
 276    `imtest' program or your machine isn't configured for Kerberos.
 277
 278 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 279 See also `imap-streams' and `imap-stream-alist'.")
 280
 281 (defvoo nnimap-authenticator nil
 282   "How nnimap authenticate itself to the server.
 283
 284 The default, nil, will try to use the \"best\" method the server can
 285 handle.
 286
 287 There is only one reason for fiddling with this variable, and that is
 288 if your server is more capable than your environment -- i.e. you
 289 connect to a server that accept Kerberos login's but you haven't
 290 installed the `imtest' program or your machine isn't configured for
 291 Kerberos.
 292
 293 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 294 See also `imap-authenticators' and `imap-authenticator-alist'")
 295
 296 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 297   "Directory to keep NOV cache files for nnimap groups.
 298 See also `nnimap-nov-file-name'.")
 299
 300 (defvoo nnimap-nov-file-name "nnimap."
 301   "NOV cache base filename.
 302 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 303 typical complete file name would be
 304 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 305 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 306 `nnmail-use-long-file-names' is nil")
 307
 308 (defvoo nnimap-nov-file-name-suffix ".novcache"
 309   "Suffix for NOV cache base filename.")
 310
 311 (defvoo nnimap-nov-is-evil gnus-agent
 312   "If non-nil, never generate or use a local nov database for this backend.
 313 Using nov databases should speed up header fetching considerably.
 314 However, it will invoke a UID SEARCH UID command on the server, and
 315 some servers implement this command inefficiently by opening each and
 316 every message in the group, thus making it quite slow.
 317 Unlike other backends, you do not need to take special care if you
 318 flip this variable.")
 319
 320 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 321   "Whether to expunge a group when it is closed.
 322 When a IMAP group with articles marked for deletion is closed, this
 323 variable determine if nnimap should actually remove the articles or
 324 not.
 325
 326 If always, nnimap always perform a expunge when closing the group.
 327 If never, nnimap never expunges articles marked for deletion.
 328 If ask, nnimap will ask you if you wish to expunge marked articles.
 329
 330 When setting this variable to `never', you can only expunge articles
 331 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 332
 333 (defvoo nnimap-list-pattern "*"
 334   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 335 See below for available wildcards.
 336
 337 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 338 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 339 semantics of this are server specific, on the University of Washington
 340 server you can specify a directory.
 341
 342 Example:
 343  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 344
 345 There are two wildcards * and %. * matches everything, % matches
 346 everything in the current hierarchy.")
 347
 348 (defvoo nnimap-news-groups nil
 349   "IMAP support a news-like mode, also known as bulletin board mode,
 350 where replies is sent via IMAP instead of SMTP.
 351
 352 This variable should contain a regexp matching groups where you wish
 353 replies to be stored to the mailbox directly.
 354
 355 Example:
 356   '(\"^[^I][^N][^B][^O][^X].*$\")
 357
 358 This will match all groups not beginning with \"INBOX\".
 359
 360 Note that there is nothing technically different between mail-like and
 361 news-like mailboxes.  If you wish to have a group with todo items or
 362 similar which you wouldn't want to set up a mailing list for, you can
 363 use this to make replies go directly to the group.")
 364
 365 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 366   "IMAP search command to use for articles that are to be expired.
 367 The first %s is replaced by a UID set of articles to search on,
 368 and the second %s is replaced by a date criterium.
 369
 370 One useful (and perhaps the only useful) value to change this to would
 371 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 372 instead of the internal date of messages.  See section 6.4.4 of RFC
 373 2060 for more information on valid strings.")
 374
 375 (defvoo nnimap-importantize-dormant t
 376   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 377 Note that within Gnus, dormant articles will still (only) be
 378 marked as ticked.  This is to make \"dormant\" articles stand out,
 379 just like \"ticked\" articles, in other IMAP clients.")
 380
 381 (defvoo nnimap-server-address nil
 382   "Obsolete.  Use `nnimap-address'.")
 383
 384 (defcustom nnimap-authinfo-file "~/.authinfo"
 385   "Authorization information for IMAP servers.  In .netrc format."
 386   :type
 387   '(choice file
 388            (repeat :tag "Entries"
 389                    :menu-tag "Inline"
 390                    (list :format "%v"
 391                          :value ("" ("login" . "") ("password" . ""))
 392                          (string :tag "Host")
 393                          (checklist :inline t
 394                                     (cons :format "%v"
 395                                           (const :format "" "login")
 396                                           (string :format "Login: %v"))
 397                                     (cons :format "%v"
 398                                           (const :format "" "password")
 399                                           (string :format "Password: %v"))))))
 400   :group 'nnimap)
 401
 402 (defcustom nnimap-prune-cache t
 403   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 404   :type 'boolean
 405   :group 'nnimap)
 406
 407 (defvar nnimap-request-list-method 'imap-mailbox-list
 408   "Method to use to request a list of all folders from the server.
 409 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 410 restrict visible folders.")
 411
 412 (defcustom nnimap-id nil
 413   "Plist with client identity to send to server upon login.
 414 Nil means no information is sent, symbol `no' to disable ID query
 415 alltogheter, or plist with identifier-value pairs to send to
 416 server.  RFC 2971 describes the list as follows:
 417
 418    Any string may be sent as a field, but the following are defined to
 419    describe certain values that might be sent.  Implementations are free
 420    to send none, any, or all of these.  Strings are not case-sensitive.
 421    Field strings MUST NOT be longer than 30 octets.  Value strings MUST
 422    NOT be longer than 1024 octets.  Implementations MUST NOT send more
 423    than 30 field-value pairs.
 424
 425      name            Name of the program
 426      version         Version number of the program
 427      os              Name of the operating system
 428      os-version      Version of the operating system
 429      vendor          Vendor of the client/server
 430      support-url     URL to contact for support
 431      address         Postal address of contact/vendor
 432      date            Date program was released, specified as a date-time
 433                        in IMAP4rev1
 434      command         Command used to start the program
 435      arguments       Arguments supplied on the command line, if any
 436                        if any
 437      environment     Description of environment, i.e., UNIX environment
 438                        variables or Windows registry settings
 439
 440    Implementations MUST NOT send the same field name more than once.
 441
 442 An example plist would be '(\"name\" \"Gnus\" \"version\" gnus-version-number
 443 \"os\" system-configuration \"vendor\" \"GNU\")."
 444   :group 'nnimap
 445   :type '(choice (const :tag "No information" nil)
 446                  (const :tag "Disable ID query" no)
 447                  (plist :key-type string :value-type string)))
 448
 449 (defcustom nnimap-debug nil
 450   "If non-nil, random debug spews are placed in *nnimap-debug* buffer.
 451 Note that username, passwords and other privacy sensitive
 452 information (such as e-mail) may be stored in the *nnimap-debug*
 453 buffer.  It is not written to disk, however.  Do not enable this
 454 variable unless you are comfortable with that."
 455   :group 'nnimap
 456   :type 'boolean)
 457
 458 ;; Internal variables:
 459
 460 (defvar nnimap-debug-buffer "*nnimap-debug*")
 461 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 462 (defvar nnimap-current-move-server nil)
 463 (defvar nnimap-current-move-group nil)
 464 (defvar nnimap-current-move-article nil)
 465 (defvar nnimap-length)
 466 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 467 (defvar nnimap-progress-how-often 20)
 468 (defvar nnimap-counter)
 469 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 470 (defvar nnimap-current-server nil)      ;; Current server
 471 (defvar nnimap-server-buffer nil)       ;; Current servers' buffer
 472
 473 \f
 474
 475 (nnoo-define-basics nnimap)
 476
 477 ;; Utility functions:
 478
 479 (defsubst nnimap-get-server-buffer (server)
 480   "Return buffer for SERVER, if nil use current server."
 481   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 482
 483 (defun nnimap-remove-server-from-buffer-alist (server list)
 484   "Remove SERVER from LIST."
 485   (let (l)
 486     (dolist (e list)
 487       (unless (equal server (car-safe e))
 488         (push e l)))
 489     l))
 490
 491 (defun nnimap-possibly-change-server (server)
 492   "Return buffer for SERVER, changing the current server as a side-effect.
 493 If SERVER is nil, uses the current server."
 494   (setq nnimap-current-server (or server nnimap-current-server)
 495         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 496
 497 (defun nnimap-verify-uidvalidity (group server)
 498   "Verify stored uidvalidity match current one in GROUP on SERVER."
 499   (let* ((gnusgroup (gnus-group-prefixed-name
 500                      group (gnus-server-to-method
 501                             (format "nnimap:%s" server))))
 502          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 503          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 504          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 505          (nameuid (nnheader-translate-file-chars
 506                    (concat nnimap-nov-file-name
 507                            (if (equal server "")
 508                                "unnamed"
 509                              server) "." group "." old-uidvalidity
 510                              nnimap-nov-file-name-suffix) t))
 511          (file (if (or nnmail-use-long-file-names
 512                        (file-exists-p (expand-file-name nameuid dir)))
 513                    (expand-file-name nameuid dir)
 514                  (expand-file-name
 515                   (encode-coding-string
 516                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 517                    nnmail-pathname-coding-system)
 518                   dir))))
 519     (if old-uidvalidity
 520         (if (not (equal old-uidvalidity new-uidvalidity))
 521             ;; uidvalidity clash
 522             (gnus-delete-file file)
 523           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 524           t)
 525       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 526       t)))
 527
 528 (defun nnimap-before-find-minmax-bugworkaround ()
 529   "Function called before iterating through mailboxes with
 530 `nnimap-find-minmax-uid'."
 531   (when nnimap-need-unselect-to-notice-new-mail
 532     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 533     ;; currently selected mailbox without a re-select/examine.
 534     (or (null (imap-current-mailbox nnimap-server-buffer))
 535         (imap-mailbox-unselect nnimap-server-buffer))))
 536
 537 (defun nnimap-find-minmax-uid (group &optional examine)
 538   "Find lowest and highest active article number in GROUP.
 539 If EXAMINE is non-nil the group is selected read-only."
 540   (with-current-buffer nnimap-server-buffer
 541     (when (or (string= group (imap-current-mailbox))
 542               (imap-mailbox-select group examine))
 543       (let (minuid maxuid)
 544         (when (> (imap-mailbox-get 'exists) 0)
 545           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 546           (imap-message-map (lambda (uid Uid)
 547                               (setq minuid (if minuid (min minuid uid) uid)
 548                                     maxuid (if maxuid (max maxuid uid) uid)))
 549                             'UID))
 550         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 551
 552 (defun nnimap-possibly-change-group (group &optional server)
 553   "Make GROUP the current group, and SERVER the current server."
 554   (when (nnimap-possibly-change-server server)
 555     (with-current-buffer nnimap-server-buffer
 556       (if (or (null group) (imap-current-mailbox-p group))
 557           imap-current-mailbox
 558         (if (imap-mailbox-select group)
 559             (if (or (nnimap-verify-uidvalidity
 560                      group (or server nnimap-current-server))
 561                     (zerop (imap-mailbox-get 'exists group))
 562                     t ;; for OGnus to see if ignoring uidvalidity
 563                       ;; changes has any bad effects.
 564                     (yes-or-no-p
 565                      (format
 566                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 567                 imap-current-mailbox
 568               (imap-mailbox-unselect)
 569               (error "nnimap: Group %s is not uid-valid" group))
 570           (nnheader-report 'nnimap (imap-error-text)))))))
 571
 572 (defun nnimap-replace-whitespace (string)
 573   "Return STRING with all whitespace replaced with space."
 574   (when string
 575     (while (string-match "[\r\n\t]+" string)
 576       (setq string (replace-match " " t t string)))
 577     string))
 578
 579 ;; Required backend functions
 580
 581 (defun nnimap-retrieve-headers-progress ()
 582   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 583   (and (numberp nnmail-large-newsgroup)
 584        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 585        (> nnimap-length nnmail-large-newsgroup)
 586        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 587                          (nth (/ (% nnimap-counter
 588                                     (* (length nnimap-progress-chars)
 589                                        nnimap-progress-how-often))
 590                                  nnimap-progress-how-often)
 591                               nnimap-progress-chars)))
 592   (with-current-buffer nntp-server-buffer
 593     (let (headers lines chars uid mbx)
 594       (with-current-buffer nnimap-server-buffer
 595         (setq uid imap-current-message
 596               mbx imap-current-mailbox
 597               headers (nnimap-demule
 598                        (if (imap-capability 'IMAP4rev1)
 599                            ;; xxx don't just use car? alist doesn't contain
 600                            ;; anything else now, but it might...
 601                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 602                          (imap-message-get uid 'RFC822.HEADER)))
 603               lines (imap-body-lines (imap-message-body imap-current-message))
 604               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 605       (nnheader-insert-nov
 606        (with-temp-buffer
 607          (buffer-disable-undo)
 608          (insert headers)
 609          (let ((head (nnheader-parse-naked-head uid)))
 610            (mail-header-set-number head uid)
 611            (mail-header-set-chars head chars)
 612            (mail-header-set-lines head lines)
 613            (mail-header-set-xref
 614             head (format "%s %s:%d" (system-name) mbx uid))
 615            head))))))
 616
 617 (defun nnimap-retrieve-which-headers (articles fetch-old)
 618   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 619   (with-current-buffer nnimap-server-buffer
 620     (if (numberp (car-safe articles))
 621         (imap-search
 622          (concat "UID "
 623                  (imap-range-to-message-set
 624                   (gnus-compress-sequence
 625                    (append (gnus-uncompress-sequence
 626                             (and fetch-old
 627                                  (cons (if (numberp fetch-old)
 628                                            (max 1 (- (car articles) fetch-old))
 629                                          1)
 630                                        (1- (car articles)))))
 631                            articles)))))
 632       (mapcar (lambda (msgid)
 633                 (imap-search
 634                  (format "HEADER Message-Id \"%s\"" msgid)))
 635               articles))))
 636
 637 (defun nnimap-group-overview-filename (group server)
 638   "Make file name for GROUP on SERVER."
 639   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 640          (uidvalidity (gnus-group-get-parameter
 641                        (gnus-group-prefixed-name
 642                         group (gnus-server-to-method
 643                                (format "nnimap:%s" server)))
 644                        'uidvalidity))
 645          (name (nnheader-translate-file-chars
 646                 (concat nnimap-nov-file-name
 647                         (if (equal server "")
 648                             "unnamed"
 649                           server) "." group nnimap-nov-file-name-suffix) t))
 650          (nameuid (nnheader-translate-file-chars
 651                    (concat nnimap-nov-file-name
 652                            (if (equal server "")
 653                                "unnamed"
 654                              server) "." group "." uidvalidity
 655                              nnimap-nov-file-name-suffix) t))
 656          (oldfile (if (or nnmail-use-long-file-names
 657                           (file-exists-p (expand-file-name name dir)))
 658                       (expand-file-name name dir)
 659                     (expand-file-name
 660                      (encode-coding-string
 661                       (nnheader-replace-chars-in-string name ?. ?/)
 662                       nnmail-pathname-coding-system)
 663                      dir)))
 664          (newfile (if (or nnmail-use-long-file-names
 665                           (file-exists-p (expand-file-name nameuid dir)))
 666                       (expand-file-name nameuid dir)
 667                     (expand-file-name
 668                      (encode-coding-string
 669                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 670                       nnmail-pathname-coding-system)
 671                      dir))))
 672     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 673       (message "nnimap: Upgrading novcache filename...")
 674       (sit-for 1)
 675       (gnus-make-directory (file-name-directory newfile))
 676       (unless (ignore-errors (rename-file oldfile newfile) t)
 677         (if (ignore-errors (copy-file oldfile newfile) t)
 678             (delete-file oldfile)
 679           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 680     newfile))
 681
 682 (defun nnimap-retrieve-headers-from-file (group server)
 683   (with-current-buffer nntp-server-buffer
 684     (let ((nov (nnimap-group-overview-filename group server)))
 685       (when (file-exists-p nov)
 686         (nnheader-insert-file-contents nov)
 687         (set-buffer-modified-p nil)
 688         (let ((min (ignore-errors (goto-char (point-min))
 689                                   (read (current-buffer))))
 690               (max (ignore-errors (goto-char (point-max))
 691                                   (forward-line -1)
 692                                   (read (current-buffer)))))
 693           (if (and (numberp min) (numberp max))
 694               (cons min max)
 695             ;; junk, remove it, it's saved later
 696             (erase-buffer)
 697             nil))))))
 698
 699 (defun nnimap-retrieve-headers-from-server (articles group server)
 700   (with-current-buffer nnimap-server-buffer
 701     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 702           (nnimap-length (gnus-range-length articles))
 703           (nnimap-counter 0))
 704       (imap-fetch (imap-range-to-message-set articles)
 705                   (concat "(UID RFC822.SIZE BODY "
 706                           (let ((headers
 707                                  (append '(Subject From Date Message-Id
 708                                                    References In-Reply-To Xref)
 709                                          (copy-sequence
 710                                           nnmail-extra-headers))))
 711                             (if (imap-capability 'IMAP4rev1)
 712                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 713                               (format "RFC822.HEADER.LINES %s)" headers)))))
 714       (and (numberp nnmail-large-newsgroup)
 715            (> nnimap-length nnmail-large-newsgroup)
 716            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 717
 718 (defun nnimap-dont-use-nov-p (group server)
 719   (or gnus-nov-is-evil nnimap-nov-is-evil
 720       (unless (and (gnus-make-directory
 721                     (file-name-directory
 722                      (nnimap-group-overview-filename group server)))
 723                    (file-writable-p
 724                     (nnimap-group-overview-filename group server)))
 725         (message "nnimap: Nov cache not writable, %s"
 726                  (nnimap-group-overview-filename group server)))))
 727
 728 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 729   (when (nnimap-possibly-change-group group server)
 730     (with-current-buffer nntp-server-buffer
 731       (erase-buffer)
 732       (if (nnimap-dont-use-nov-p group server)
 733           (nnimap-retrieve-headers-from-server
 734            (gnus-compress-sequence articles) group server)
 735         (let (uids cached low high)
 736           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 737                       low (car uids)
 738                       high (car (last uids)))
 739             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 740                 (progn
 741                   ;; fetch articles with uids before cache block
 742                   (when (< low (car cached))
 743                     (goto-char (point-min))
 744                     (nnimap-retrieve-headers-from-server
 745                      (cons low (1- (car cached))) group server))
 746                   ;; fetch articles with uids after cache block
 747                   (when (> high (cdr cached))
 748                     (goto-char (point-max))
 749                     (nnimap-retrieve-headers-from-server
 750                      (cons (1+ (cdr cached)) high) group server))
 751                   (when nnimap-prune-cache
 752                     ;; remove nov's for articles which has expired on server
 753                     (goto-char (point-min))
 754                     (dolist (uid (gnus-set-difference articles uids))
 755                       (when (re-search-forward (format "^%d\t" uid) nil t)
 756                         (gnus-delete-line)))))
 757               ;; nothing cached, fetch whole range from server
 758               (nnimap-retrieve-headers-from-server
 759                (cons low high) group server))
 760             (when (buffer-modified-p)
 761               (nnmail-write-region
 762                (point-min) (point-max)
 763                (nnimap-group-overview-filename group server) nil 'nomesg))
 764             (nnheader-nov-delete-outside-range low high))))
 765       'nov)))
 766
 767 (defun nnimap-open-connection (server)
 768   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 769                       nnimap-authenticator nnimap-server-buffer))
 770       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 771     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 772                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 773       (imap-close nnimap-server-buffer)
 774       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 775     (let* ((list (netrc-parse nnimap-authinfo-file))
 776            (port (if nnimap-server-port
 777                      (int-to-string nnimap-server-port)
 778                    "imap"))
 779            (user (netrc-machine-user-or-password
 780                   "login"
 781                   list
 782                   (list server
 783                         (or nnimap-server-address
 784                             nnimap-address))
 785                   (list port)
 786                   (list "imap" "imaps")))
 787            (passwd (netrc-machine-user-or-password
 788                     "password"
 789                     list
 790                     (list server
 791                           (or nnimap-server-address
 792                               nnimap-address))
 793                     (list port)
 794                     (list "imap" "imaps"))))
 795       (if (imap-authenticate user passwd nnimap-server-buffer)
 796           (prog2
 797               (setq nnimap-server-buffer-alist
 798                     (nnimap-remove-server-from-buffer-alist
 799                      server
 800                      nnimap-server-buffer-alist))
 801               (push (list server nnimap-server-buffer)
 802                     nnimap-server-buffer-alist)
 803             (imap-id nnimap-id nnimap-server-buffer)
 804             (nnimap-possibly-change-server server))
 805         (imap-close nnimap-server-buffer)
 806         (kill-buffer nnimap-server-buffer)
 807         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 808
 809 (deffoo nnimap-open-server (server &optional defs)
 810   (nnheader-init-server-buffer)
 811   (if (nnimap-server-opened server)
 812       t
 813     (unless (assq 'nnimap-server-buffer defs)
 814       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 815     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 816     ;; for people that configured nnimap with a very old version
 817     (unless (assq 'nnimap-address defs)
 818       (if (assq 'nnimap-server-address defs)
 819           (push (list 'nnimap-address
 820                       (cadr (assq 'nnimap-server-address defs))) defs)
 821         (push (list 'nnimap-address server) defs)))
 822     (nnoo-change-server 'nnimap server defs)
 823     (or nnimap-server-buffer
 824         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 825     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 826       (nnoo-change-server 'nnimap server defs))
 827     (or (and nnimap-server-buffer
 828              (imap-opened nnimap-server-buffer)
 829              (if (with-current-buffer nnimap-server-buffer
 830                    (memq imap-state '(auth select examine)))
 831                  t
 832                (imap-close nnimap-server-buffer)
 833                (nnimap-open-connection server)))
 834         (nnimap-open-connection server))))
 835
 836 (deffoo nnimap-server-opened (&optional server)
 837   "Whether SERVER is opened.
 838 If SERVER is the current virtual server, and the connection to the
 839 physical server is alive, this function return a non-nil value.  If
 840 SERVER is nil, it is treated as the current server."
 841   ;; clean up autologouts??
 842   (and (or server nnimap-current-server)
 843        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 844        (imap-opened (nnimap-get-server-buffer server))))
 845
 846 (deffoo nnimap-close-server (&optional server)
 847   "Close connection to server and free all resources connected to it.
 848 Return nil if the server couldn't be closed for some reason."
 849   (let ((server (or server nnimap-current-server)))
 850     (when (or (nnimap-server-opened server)
 851               (imap-opened (nnimap-get-server-buffer server)))
 852       (imap-close (nnimap-get-server-buffer server))
 853       (kill-buffer (nnimap-get-server-buffer server))
 854       (setq nnimap-server-buffer nil
 855             nnimap-current-server nil
 856             nnimap-server-buffer-alist
 857             (nnimap-remove-server-from-buffer-alist
 858              server
 859              nnimap-server-buffer-alist)))
 860     (nnoo-close-server 'nnimap server)))
 861
 862 (deffoo nnimap-request-close ()
 863   "Close connection to all servers and free all resources that the backend have reserved.
 864 All buffers that have been created by that
 865 backend should be killed.  (Not the nntp-server-buffer, though.) This
 866 function is generally only called when Gnus is shutting down."
 867   (mapc (lambda (server) (nnimap-close-server (car server)))
 868         nnimap-server-buffer-alist)
 869   (setq nnimap-server-buffer-alist nil))
 870
 871 (deffoo nnimap-status-message (&optional server)
 872   "This function returns the last error message from server."
 873   (when (nnimap-possibly-change-server server)
 874     (nnoo-status-message 'nnimap server)))
 875
 876 (defun nnimap-demule (string)
 877   ;; BEWARE: we used to use string-as-multibyte here which is braindead
 878   ;; because it will turn accidental emacs-mule-valid byte sequences
 879   ;; into multibyte chars.  --Stef
 880   ;; Reverted, braindead got 7.5 out of 10 on imdb, so it can't be
 881   ;; that bad. --Simon
 882   (funcall (if (and (fboundp 'string-as-multibyte)
 883                     (subrp (symbol-function 'string-as-multibyte)))
 884                'string-as-multibyte
 885              'identity)
 886            (or string "")))
 887
 888 (defun nnimap-make-callback (article gnus-callback buffer)
 889   "Return a callback function."
 890   `(lambda ()
 891      (nnimap-callback ,article ,gnus-callback ,buffer)))
 892
 893 (defun nnimap-callback (article gnus-callback buffer)
 894   (when (eq article (imap-current-message))
 895     (remove-hook 'imap-fetch-data-hook
 896                  (nnimap-make-callback article gnus-callback buffer))
 897     (with-current-buffer buffer
 898       (insert
 899        (with-current-buffer nnimap-server-buffer
 900          (nnimap-demule
 901           (if (imap-capability 'IMAP4rev1)
 902               ;; xxx don't just use car? alist doesn't contain
 903               ;; anything else now, but it might...
 904               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 905             (imap-message-get article 'RFC822)))))
 906       (nnheader-ms-strip-cr)
 907       (funcall gnus-callback t))))
 908
 909 (defun nnimap-request-article-part (article part prop &optional
 910                                             group server to-buffer detail)
 911   (when (nnimap-possibly-change-group group server)
 912     (let ((article (if (stringp article)
 913                        (car-safe (imap-search
 914                                   (format "HEADER Message-Id \"%s\"" article)
 915                                   nnimap-server-buffer))
 916                      article)))
 917       (when article
 918         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 919                       article (or group imap-current-mailbox
 920                                   gnus-newsgroup-name))
 921         (if (not nnheader-callback-function)
 922             (with-current-buffer (or to-buffer nntp-server-buffer)
 923               (erase-buffer)
 924               (let ((data (imap-fetch article part prop nil
 925                                       nnimap-server-buffer)))
 926                 (when data
 927                   (insert (nnimap-demule (if detail (nth 2 (car data)) data)))
 928                   (nnheader-ms-strip-cr)
 929                   (gnus-message
 930                    10 "nnimap: Fetching (part of) article %d from %s...done"
 931                    article (or group imap-current-mailbox gnus-newsgroup-name))
 932                   (if (bobp)
 933                       (nnheader-report 'nnimap "No such article %d in %s: %s"
 934                                        article (or group imap-current-mailbox
 935                                                    gnus-newsgroup-name)
 936                                        (imap-error-text nnimap-server-buffer))
 937                     (cons group article)))))
 938           (add-hook 'imap-fetch-data-hook
 939                     (nnimap-make-callback article
 940                                           nnheader-callback-function
 941                                           nntp-server-buffer))
 942           (imap-fetch-asynch article part nil nnimap-server-buffer)
 943           (cons group article))))))
 944
 945 (deffoo nnimap-asynchronous-p ()
 946   t)
 947
 948 (deffoo nnimap-request-article (article &optional group server to-buffer)
 949   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 950       (nnimap-request-article-part
 951        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 952     (nnimap-request-article-part
 953      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 954
 955 (deffoo nnimap-request-head (article &optional group server to-buffer)
 956   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 957       (nnimap-request-article-part
 958        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 959     (nnimap-request-article-part
 960      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 961
 962 (deffoo nnimap-request-body (article &optional group server to-buffer)
 963   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 964       (nnimap-request-article-part
 965        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 966     (nnimap-request-article-part
 967      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 968
 969 (deffoo nnimap-request-group (group &optional server fast)
 970   (nnimap-request-update-info-internal
 971    group
 972    (gnus-get-info (gnus-group-prefixed-name
 973                    group (gnus-server-to-method (format "nnimap:%s" server))))
 974    server)
 975   (when (nnimap-possibly-change-group group server)
 976     (nnimap-before-find-minmax-bugworkaround)
 977     (let (info)
 978       (cond (fast group)
 979             ((null (setq info (nnimap-find-minmax-uid group t)))
 980              (nnheader-report 'nnimap "Could not get active info for %s"
 981                               group))
 982             (t
 983              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 984                               (max 1 (or (nth 1 info) 1))
 985                               (or (nth 2 info) 0) group)
 986              (nnheader-report 'nnimap "Group %s selected" group)
 987              t)))))
 988
 989 (defun nnimap-update-unseen (group &optional server)
 990   "Update the unseen count in `nnimap-mailbox-info'."
 991   (gnus-sethash
 992    (gnus-group-prefixed-name group server)
 993    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
 994                                  nnimap-mailbox-info)))
 995      (list (nth 0 old) (nth 1 old)
 996            (imap-mailbox-status group 'unseen nnimap-server-buffer)
 997            (nth 3 old)))
 998    nnimap-mailbox-info))
 999
1000 (defun nnimap-close-group (group &optional server)
1001   (with-current-buffer nnimap-server-buffer
1002     (when (and (imap-opened)
1003                (nnimap-possibly-change-group group server))
1004       (nnimap-update-unseen group server)
1005       (case nnimap-expunge-on-close
1006         (always (progn
1007                   (imap-mailbox-expunge nnimap-close-asynchronous)
1008                   (unless nnimap-dont-close
1009                     (imap-mailbox-close nnimap-close-asynchronous))))
1010         (ask (if (and (imap-search "DELETED")
1011                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
1012                                              imap-current-mailbox)))
1013                  (progn
1014                    (imap-mailbox-expunge nnimap-close-asynchronous)
1015                    (unless nnimap-dont-close
1016                      (imap-mailbox-close nnimap-close-asynchronous)))
1017                (imap-mailbox-unselect)))
1018         (t (imap-mailbox-unselect)))
1019       (not imap-current-mailbox))))
1020
1021 (defun nnimap-pattern-to-list-arguments (pattern)
1022   (mapcar (lambda (p)
1023             (cons (car-safe p) (or (cdr-safe p) p)))
1024           (if (and (listp pattern)
1025                    (listp (cdr pattern)))
1026               pattern
1027             (list pattern))))
1028
1029 (deffoo nnimap-request-list (&optional server)
1030   (when (nnimap-possibly-change-server server)
1031     (with-current-buffer nntp-server-buffer
1032       (erase-buffer))
1033     (gnus-message 5 "nnimap: Generating active list%s..."
1034                   (if (> (length server) 0) (concat " for " server) ""))
1035     (nnimap-before-find-minmax-bugworkaround)
1036     (with-current-buffer nnimap-server-buffer
1037       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
1038         (dolist (mbx (funcall nnimap-request-list-method
1039                               (cdr pattern) (car pattern)))
1040           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
1041               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1042                 (when info
1043                   (with-current-buffer nntp-server-buffer
1044                     (insert (format "\"%s\" %d %d y\n"
1045                                     mbx (or (nth 2 info) 0)
1046                                     (max 1 (or (nth 1 info) 1)))))))))))
1047     (gnus-message 5 "nnimap: Generating active list%s...done"
1048                   (if (> (length server) 0) (concat " for " server) ""))
1049     t))
1050
1051 (deffoo nnimap-request-post (&optional server)
1052   (let ((success t))
1053     (dolist (mbx (message-unquote-tokens
1054                   (message-tokenize-header
1055                    (message-fetch-field "Newsgroups") ", ")) success)
1056       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
1057         (or (gnus-active to-newsgroup)
1058             (gnus-activate-group to-newsgroup)
1059             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
1060                                        to-newsgroup))
1061                 (or (and (gnus-request-create-group
1062                           to-newsgroup gnus-command-method)
1063                          (gnus-activate-group to-newsgroup nil nil
1064                                               gnus-command-method))
1065                     (error "Couldn't create group %s" to-newsgroup)))
1066             (error "No such group: %s" to-newsgroup))
1067         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
1068           (setq success nil))))))
1069
1070 ;; Optional backend functions
1071
1072 (defun nnimap-string-lessp-numerical (s1 s2)
1073   "Return t if first arg string is less than second in numerical order."
1074   (cond ((string= s1 s2)
1075          nil)
1076         ((> (length s1) (length s2))
1077          nil)
1078         ((< (length s1) (length s2))
1079          t)
1080         ((< (string-to-number (substring s1 0 1))
1081             (string-to-number (substring s2 0 1)))
1082          t)
1083         ((> (string-to-number (substring s1 0 1))
1084             (string-to-number (substring s2 0 1)))
1085          nil)
1086         (t
1087          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1088
1089 (deffoo nnimap-retrieve-groups (groups &optional server)
1090   (when (nnimap-possibly-change-server server)
1091     (gnus-message 5 "nnimap: Checking mailboxes...")
1092     (with-current-buffer nntp-server-buffer
1093       (erase-buffer)
1094       (nnimap-before-find-minmax-bugworkaround)
1095       (let (asyncgroups slowgroups)
1096         (if (null nnimap-retrieve-groups-asynchronous)
1097             (setq slowgroups groups)
1098           (dolist (group groups)
1099             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1100             (add-to-list (if (gnus-gethash-safe
1101                               (gnus-group-prefixed-name group server)
1102                               nnimap-mailbox-info)
1103                              'asyncgroups
1104                            'slowgroups)
1105                          (list group (imap-mailbox-status-asynch
1106                                       group '(uidvalidity uidnext unseen)
1107                                       nnimap-server-buffer))))
1108           (dolist (asyncgroup asyncgroups)
1109             (let ((group (nth 0 asyncgroup))
1110                   (tag   (nth 1 asyncgroup))
1111                   new old)
1112               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1113                 (if (or (not (string=
1114                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1115                                                     group server)
1116                                                    nnimap-mailbox-info))
1117                               (imap-mailbox-get 'uidvalidity group
1118                                                 nnimap-server-buffer)))
1119                         (not (string=
1120                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1121                                                     group server)
1122                                                    nnimap-mailbox-info))
1123                               (imap-mailbox-get 'uidnext group
1124                                                 nnimap-server-buffer))))
1125                     (push (list group) slowgroups)
1126                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1127                                                 group server)
1128                                                nnimap-mailbox-info))))))))
1129         (dolist (group slowgroups)
1130           (if nnimap-retrieve-groups-asynchronous
1131               (setq group (car group)))
1132           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1133           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1134           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1135                                                      nnimap-server-buffer))
1136               (let* ((info (nnimap-find-minmax-uid group 'examine))
1137                      (str (format "\"%s\" %d %d y\n" group
1138                                   (or (nth 2 info) 0)
1139                                   (max 1 (or (nth 1 info) 1)))))
1140                 (when (> (or (imap-mailbox-get 'recent group
1141                                                nnimap-server-buffer) 0)
1142                          0)
1143                   (push (list (cons group 0)) nnmail-split-history))
1144                 (insert str)
1145                 (when nnimap-retrieve-groups-asynchronous
1146                   (gnus-sethash
1147                    (gnus-group-prefixed-name group server)
1148                    (list (or (imap-mailbox-get
1149                               'uidvalidity group nnimap-server-buffer)
1150                              (imap-mailbox-status
1151                               group 'uidvalidity nnimap-server-buffer))
1152                          (or (imap-mailbox-get
1153                               'uidnext group nnimap-server-buffer)
1154                              (imap-mailbox-status
1155                               group 'uidnext nnimap-server-buffer))
1156                          (or (imap-mailbox-get
1157                               'unseen group nnimap-server-buffer)
1158                              (imap-mailbox-status
1159                               group 'unseen nnimap-server-buffer))
1160                          str)
1161                    nnimap-mailbox-info)))))))
1162     (gnus-message 5 "nnimap: Checking mailboxes...done")
1163     'active))
1164
1165 (deffoo nnimap-request-update-info-internal (group info &optional server)
1166   (when (nnimap-possibly-change-group group server)
1167     (when info;; xxx what does this mean? should we create a info?
1168       (with-current-buffer nnimap-server-buffer
1169         (gnus-message 5 "nnimap: Updating info for %s..."
1170                       (gnus-info-group info))
1171
1172         (when (nnimap-mark-permanent-p 'read)
1173           (let (seen unseen)
1174             ;; read info could contain articles marked unread by other
1175             ;; imap clients!  we correct this
1176             (setq seen (gnus-uncompress-range (gnus-info-read info))
1177                   unseen (imap-search "UNSEEN UNDELETED")
1178                   seen (gnus-set-difference seen unseen)
1179                   ;; seen might lack articles marked as read by other
1180                   ;; imap clients! we correct this
1181                   seen (append seen (imap-search "SEEN"))
1182                   ;; remove dupes
1183                   seen (sort seen '<)
1184                   seen (gnus-compress-sequence seen t)
1185                   ;; we can't return '(1) since this isn't a "list of ranges",
1186                   ;; and we can't return '((1)) since g-list-of-unread-articles
1187                   ;; is buggy so we return '((1 . 1)).
1188                   seen (if (and (integerp (car seen))
1189                                 (null (cdr seen)))
1190                            (list (cons (car seen) (car seen)))
1191                          seen))
1192             (gnus-info-set-read info seen)))
1193
1194         (mapcar (lambda (pred)
1195                   (when (or (eq (cdr pred) 'recent)
1196                             (and (nnimap-mark-permanent-p (cdr pred))
1197                                  (member (nnimap-mark-to-flag (cdr pred))
1198                                          (imap-mailbox-get 'flags))))
1199                     (gnus-info-set-marks
1200                      info
1201                      (gnus-update-alist-soft
1202                       (cdr pred)
1203                       (gnus-compress-sequence
1204                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
1205                       (gnus-info-marks info))
1206                      t)))
1207                 gnus-article-mark-lists)
1208
1209         (when nnimap-importantize-dormant
1210           ;; nnimap mark dormant article as ticked too (for other clients)
1211           ;; so we remove that mark for gnus since we support dormant
1212           (gnus-info-set-marks
1213            info
1214            (gnus-update-alist-soft
1215             'tick
1216             (gnus-remove-from-range
1217              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1218              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1219             (gnus-info-marks info))
1220            t))
1221
1222         (gnus-message 5 "nnimap: Updating info for %s...done"
1223                       (gnus-info-group info))
1224
1225         info))))
1226
1227 (deffoo nnimap-request-type (group &optional article)
1228   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1229       'news
1230     'mail))
1231
1232 (deffoo nnimap-request-set-mark (group actions &optional server)
1233   (when (nnimap-possibly-change-group group server)
1234     (with-current-buffer nnimap-server-buffer
1235       (let (action)
1236         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1237         (while (setq action (pop actions))
1238           (let ((range (nth 0 action))
1239                 (what  (nth 1 action))
1240                 (cmdmarks (nth 2 action))
1241                 marks)
1242             ;; bookmark can't be stored (not list/range
1243             (setq cmdmarks (delq 'bookmark cmdmarks))
1244             ;; killed can't be stored (not list/range
1245             (setq cmdmarks (delq 'killed cmdmarks))
1246             ;; unsent are for nndraft groups only
1247             (setq cmdmarks (delq 'unsent cmdmarks))
1248             ;; cache flags are pointless on the server
1249             (setq cmdmarks (delq 'cache cmdmarks))
1250             ;; seen flags are local to each gnus
1251             (setq cmdmarks (delq 'seen cmdmarks))
1252             ;; recent marks can't be set
1253             (setq cmdmarks (delq 'recent cmdmarks))
1254             (when nnimap-importantize-dormant
1255               ;; flag dormant articles as ticked
1256               (if (memq 'dormant cmdmarks)
1257                   (setq cmdmarks (cons 'tick cmdmarks))))
1258             ;; remove stuff we are forbidden to store
1259             (mapc (lambda (mark)
1260                     (if (imap-message-flag-permanent-p
1261                          (nnimap-mark-to-flag mark))
1262                         (setq marks (cons mark marks))))
1263                   cmdmarks)
1264             (when (and range marks)
1265               (cond ((eq what 'del)
1266                      (imap-message-flags-del
1267                       (imap-range-to-message-set range)
1268                       (nnimap-mark-to-flag marks nil t)))
1269                     ((eq what 'add)
1270                      (imap-message-flags-add
1271                       (imap-range-to-message-set range)
1272                       (nnimap-mark-to-flag marks nil t)))
1273                     ((eq what 'set)
1274                      (imap-message-flags-set
1275                       (imap-range-to-message-set range)
1276                       (nnimap-mark-to-flag marks nil t)))))))
1277         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1278   nil)
1279
1280 (defun nnimap-split-fancy ()
1281   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1282   (let ((nnmail-split-fancy nnimap-split-fancy))
1283     (nnmail-split-fancy)))
1284
1285 (defun nnimap-split-to-groups (rules)
1286   ;; tries to match all rules in nnimap-split-rule against content of
1287   ;; nntp-server-buffer, returns a list of groups that matched.
1288   (with-current-buffer nntp-server-buffer
1289     ;; Fold continuation lines.
1290     (goto-char (point-min))
1291     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1292       (replace-match " " t t))
1293     (if (functionp rules)
1294         (funcall rules)
1295       (let (to-groups regrepp)
1296         (catch 'split-done
1297           (dolist (rule rules to-groups)
1298             (let ((group (car rule))
1299                   (regexp (cadr rule)))
1300               (goto-char (point-min))
1301               (when (and (if (stringp regexp)
1302                              (progn
1303                                (if (not (stringp group))
1304                                    (setq group (eval group))
1305                                  (setq regrepp
1306                                        (string-match "\\\\[0-9&]" group)))
1307                                (re-search-forward regexp nil t))
1308                            (funcall regexp group))
1309                          ;; Don't enter the article into the same group twice.
1310                          (not (assoc group to-groups)))
1311                 (push (if regrepp
1312                           (nnmail-expand-newtext group)
1313                         group)
1314                       to-groups)
1315                 (or nnimap-split-crosspost
1316                     (throw 'split-done to-groups))))))))))
1317
1318 (defun nnimap-assoc-match (key alist)
1319   (let (element)
1320     (while (and alist (not element))
1321       (if (string-match (car (car alist)) key)
1322           (setq element (car alist)))
1323       (setq alist (cdr alist)))
1324     element))
1325
1326 (defun nnimap-split-find-rule (server inbox)
1327   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1328            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1329       ;; extended format
1330       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1331                                             server nnimap-split-rule))))
1332     nnimap-split-rule))
1333
1334 (defun nnimap-split-find-inbox (server)
1335   (if (listp nnimap-split-inbox)
1336       nnimap-split-inbox
1337     (list nnimap-split-inbox)))
1338
1339 (defun nnimap-split-articles (&optional group server)
1340   (when (nnimap-possibly-change-server server)
1341     (with-current-buffer nnimap-server-buffer
1342       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1343         ;; iterate over inboxes
1344         (while (and (setq inbox (pop inboxes))
1345                     (nnimap-possibly-change-group inbox));; SELECT
1346           ;; find split rule for this server / inbox
1347           (when (setq rule (nnimap-split-find-rule server inbox))
1348             ;; iterate over articles
1349             (dolist (article (imap-search nnimap-split-predicate))
1350               (when (if (if (eq nnimap-split-download-body 'default)
1351                             nnimap-split-download-body-default
1352                           nnimap-split-download-body)
1353                         (and (nnimap-request-article article)
1354                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1355                       (nnimap-request-head article))
1356                 ;; copy article to right group(s)
1357                 (setq removeorig nil)
1358                 (dolist (to-group (nnimap-split-to-groups rule))
1359                   (cond ((eq to-group 'junk)
1360                          (message "IMAP split removed %s:%s:%d" server inbox
1361                                   article)
1362                          (setq removeorig t))
1363                         ((imap-message-copy (number-to-string article)
1364                                             to-group nil 'nocopyuid)
1365                          (message "IMAP split moved %s:%s:%d to %s" server
1366                                   inbox article to-group)
1367                          (setq removeorig t)
1368                          (when nnmail-cache-accepted-message-ids
1369                            (with-current-buffer nntp-server-buffer
1370                              (let (msgid)
1371                                (and (setq msgid
1372                                           (nnmail-fetch-field "message-id"))
1373                                     (nnmail-cache-insert msgid
1374                                                          to-group
1375                                                          (nnmail-fetch-field "subject"))))))
1376                          ;; Add the group-art list to the history list.
1377                          (push (list (cons to-group 0)) nnmail-split-history))
1378                         (t
1379                          (message "IMAP split failed to move %s:%s:%d to %s"
1380                                   server inbox article to-group))))
1381                 (if (if (eq nnimap-split-download-body 'default)
1382                         nnimap-split-download-body-default
1383                       nnimap-split-download-body)
1384                     (widen))
1385                 ;; remove article if it was successfully copied somewhere
1386                 (and removeorig
1387                      (imap-message-flags-add (format "%d" article)
1388                                              "\\Seen \\Deleted")))))
1389           (when (imap-mailbox-select inbox);; just in case
1390             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1391             (imap-mailbox-expunge)
1392             (imap-mailbox-close)))
1393         (when nnmail-cache-accepted-message-ids
1394           (nnmail-cache-close))
1395         t))))
1396
1397 (deffoo nnimap-request-scan (&optional group server)
1398   (nnimap-split-articles group server))
1399
1400 (deffoo nnimap-request-newgroups (date &optional server)
1401   (when (nnimap-possibly-change-server server)
1402     (with-current-buffer nntp-server-buffer
1403       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1404                     (if (> (length server) 0) " on " "") server)
1405       (erase-buffer)
1406       (nnimap-before-find-minmax-bugworkaround)
1407       (dolist (pattern (nnimap-pattern-to-list-arguments
1408                         nnimap-list-pattern))
1409         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1410                                         nnimap-server-buffer))
1411           (or (catch 'found
1412                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1413                                                    nnimap-server-buffer))
1414                   (if (string= (downcase mailbox) "\\noselect")
1415                       (throw 'found t)))
1416                 nil)
1417               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1418                 (when info
1419                   (insert (format "\"%s\" %d %d y\n"
1420                                   mbx (or (nth 2 info) 0)
1421                                   (max 1 (or (nth 1 info) 1)))))))))
1422       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1423                     (if (> (length server) 0) " on " "") server))
1424     t))
1425
1426 (deffoo nnimap-request-create-group (group &optional server args)
1427   (when (nnimap-possibly-change-server server)
1428     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1429         (imap-mailbox-create group nnimap-server-buffer)
1430         (nnheader-report 'nnimap "%S"
1431                          (imap-error-text nnimap-server-buffer)))))
1432
1433 (defun nnimap-time-substract (time1 time2)
1434   "Return TIME for TIME1 - TIME2."
1435   (let* ((ms (- (car time1) (car time2)))
1436          (ls (- (nth 1 time1) (nth 1 time2))))
1437     (if (< ls 0)
1438         (list (- ms 1) (+ (expt 2 16) ls))
1439       (list ms ls))))
1440
1441 (defun nnimap-date-days-ago (daysago)
1442   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1443   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1444          (date (format-time-string
1445                 (format "%%d-%s-%%Y"
1446                         (capitalize (car (rassoc (nth 4 (decode-time time))
1447                                                  parse-time-months))))
1448                 time)))
1449     (if (eq ?0 (string-to-char date))
1450         (substring date 1)
1451       date)))
1452
1453 (defun nnimap-request-expire-articles-progress ()
1454   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1455                 imap-current-message))
1456
1457 (defun nnimap-expiry-target (arts group server)
1458   (unless (eq nnmail-expiry-target 'delete)
1459     (with-temp-buffer
1460       (dolist (art arts)
1461         (nnimap-request-article art group server (current-buffer))
1462         ;; hints for optimization in `nnimap-request-accept-article'
1463         (let ((nnimap-current-move-article art)
1464               (nnimap-current-move-group group)
1465               (nnimap-current-move-server server))
1466           (nnmail-expiry-target-group nnmail-expiry-target group))))
1467     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1468     ;; current group to be changed or not, so we make sure here.
1469     (nnimap-possibly-change-group group server)))
1470
1471 ;; Notice that we don't actually delete anything, we just mark them deleted.
1472 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1473   (let ((artseq (gnus-compress-sequence articles)))
1474     (when (and artseq (nnimap-possibly-change-group group server))
1475       (with-current-buffer nnimap-server-buffer
1476         (let ((days (or (and nnmail-expiry-wait-function
1477                              (funcall nnmail-expiry-wait-function group))
1478                         nnmail-expiry-wait)))
1479           (cond ((or force (eq days 'immediate))
1480                  (let ((oldarts (imap-search
1481                                  (concat "UID "
1482                                          (imap-range-to-message-set artseq)))))
1483                    (when oldarts
1484                      (nnimap-expiry-target oldarts group server)
1485                      (when (imap-message-flags-add
1486                             (imap-range-to-message-set
1487                              (gnus-compress-sequence oldarts)) "\\Deleted")
1488                        (setq articles (gnus-set-difference
1489                                        articles oldarts))))))
1490                 ((numberp days)
1491                  (let ((oldarts (imap-search
1492                                  (format nnimap-expunge-search-string
1493                                          (imap-range-to-message-set artseq)
1494                                          (nnimap-date-days-ago days))))
1495                        (imap-fetch-data-hook
1496                         '(nnimap-request-expire-articles-progress)))
1497                    (when oldarts
1498                      (nnimap-expiry-target oldarts group server)
1499                      (when (imap-message-flags-add
1500                             (imap-range-to-message-set
1501                              (gnus-compress-sequence oldarts)) "\\Deleted")
1502                        (setq articles (gnus-set-difference
1503                                        articles oldarts)))))))))))
1504   ;; return articles not deleted
1505   articles)
1506
1507 (deffoo nnimap-request-move-article (article group server accept-form
1508                                              &optional last move-is-internal)
1509   (when (nnimap-possibly-change-server server)
1510     (save-excursion
1511       (let ((buf (get-buffer-create " *nnimap move*"))
1512             (nnimap-current-move-article article)
1513             (nnimap-current-move-group group)
1514             (nnimap-current-move-server nnimap-current-server)
1515             result)
1516         (gnus-message 10 "nnimap-request-move-article: this is an %s move"
1517                       (if move-is-internal
1518                           "internal"
1519                         "external"))
1520         ;; request the article only when the move is NOT internal
1521         (and (or move-is-internal
1522                  (nnimap-request-article article group server))
1523              (save-excursion
1524                (set-buffer buf)
1525                (buffer-disable-undo (current-buffer))
1526                (insert-buffer-substring nntp-server-buffer)
1527                (setq result (eval accept-form))
1528                (kill-buffer buf)
1529                result)
1530              (imap-message-flags-add
1531               (imap-range-to-message-set (list article))
1532               "\\Deleted" 'silent nnimap-server-buffer))
1533         result))))
1534
1535 (deffoo nnimap-request-accept-article (group &optional server last)
1536   (when (nnimap-possibly-change-server server)
1537     (let (uid)
1538       (if (setq uid
1539                 (if (string= nnimap-current-server nnimap-current-move-server)
1540                     ;; moving article within same server, speed it up...
1541                     (and (nnimap-possibly-change-group
1542                           nnimap-current-move-group)
1543                          (imap-message-copy (number-to-string
1544                                              nnimap-current-move-article)
1545                                             group 'dontcreate nil
1546                                             nnimap-server-buffer))
1547                   (with-current-buffer (current-buffer)
1548                     (goto-char (point-min))
1549                     ;; remove any 'From blabla' lines, some IMAP servers
1550                     ;; reject the entire message otherwise.
1551                     (when (looking-at "^From[^:]")
1552                       (delete-region (point) (progn (forward-line) (point))))
1553                     ;; turn into rfc822 format (\r\n eol's)
1554                     (while (search-forward "\n" nil t)
1555                       (replace-match "\r\n"))
1556                     (when nnmail-cache-accepted-message-ids
1557                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1558                                            group
1559                                            (nnmail-fetch-field "subject"))))
1560                   (when (and last nnmail-cache-accepted-message-ids)
1561                     (nnmail-cache-close))
1562                   ;; this 'or' is for Cyrus server bug
1563                   (or (null (imap-current-mailbox nnimap-server-buffer))
1564                       (imap-mailbox-unselect nnimap-server-buffer))
1565                   (imap-message-append group (current-buffer) nil nil
1566                                        nnimap-server-buffer)))
1567           (cons group (nth 1 uid))
1568         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1569
1570 (deffoo nnimap-request-delete-group (group force &optional server)
1571   (when (nnimap-possibly-change-server server)
1572     (with-current-buffer nnimap-server-buffer
1573       (if force
1574           (or (null (imap-mailbox-status group 'uidvalidity))
1575               (imap-mailbox-delete group))
1576         ;; UNSUBSCRIBE?
1577         t))))
1578
1579 (deffoo nnimap-request-rename-group (group new-name &optional server)
1580   (when (nnimap-possibly-change-server server)
1581     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1582
1583 (defun nnimap-expunge (mailbox server)
1584   (when (nnimap-possibly-change-group mailbox server)
1585     (imap-mailbox-expunge nil nnimap-server-buffer)))
1586
1587 (defun nnimap-acl-get (mailbox server)
1588   (when (nnimap-possibly-change-server server)
1589     (and (imap-capability 'ACL nnimap-server-buffer)
1590          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1591
1592 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1593   (when (nnimap-possibly-change-server (cadr method))
1594     (unless (imap-capability 'ACL nnimap-server-buffer)
1595       (error "Your server does not support ACL editing"))
1596     (with-current-buffer nnimap-server-buffer
1597       ;; delete all removed identifiers
1598       (mapc (lambda (old-acl)
1599               (unless (assoc (car old-acl) new-acls)
1600                 (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1601                     (error "Can't delete ACL for %s" (car old-acl)))))
1602             old-acls)
1603       ;; set all changed acl's
1604       (mapc (lambda (new-acl)
1605               (let ((new-rights (cdr new-acl))
1606                     (old-rights (cdr (assoc (car new-acl) old-acls))))
1607                 (unless (and old-rights new-rights
1608                              (string= old-rights new-rights))
1609                   (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1610                       (error "Can't set ACL for %s to %s" (car new-acl)
1611                              new-rights)))))
1612             new-acls)
1613       t)))
1614
1615 \f
1616 ;;; Internal functions
1617
1618 ;;
1619 ;; This is confusing.
1620 ;;
1621 ;; mark      => read, tick, draft, reply etc
1622 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1623 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1624 ;;
1625 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1626 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1627 ;;
1628
1629 (defconst nnimap-mark-to-predicate-alist
1630   (mapcar
1631    (lambda (pair)                       ; cdr is the mark
1632      (or (assoc (cdr pair)
1633                 '((read . "SEEN")
1634                   (tick . "FLAGGED")
1635                   (draft . "DRAFT")
1636                   (recent . "RECENT")
1637                   (reply . "ANSWERED")))
1638          (cons (cdr pair)
1639                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1640    (cons '(read . read) gnus-article-mark-lists)))
1641
1642 (defun nnimap-mark-to-predicate (pred)
1643   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1644 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1645 to be used within a IMAP SEARCH query."
1646   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1647
1648 (defconst nnimap-mark-to-flag-alist
1649   (mapcar
1650    (lambda (pair)
1651      (or (assoc (cdr pair)
1652                 '((read . "\\Seen")
1653                   (tick . "\\Flagged")
1654                   (draft . "\\Draft")
1655                   (recent . "\\Recent")
1656                   (reply . "\\Answered")))
1657          (cons (cdr pair)
1658                (format "gnus-%s" (symbol-name (cdr pair))))))
1659    (cons '(read . read) gnus-article-mark-lists)))
1660
1661 (defun nnimap-mark-to-flag-1 (preds)
1662   (if (and (not (null preds)) (listp preds))
1663       (cons (nnimap-mark-to-flag (car preds))
1664             (nnimap-mark-to-flag (cdr preds)))
1665     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1666
1667 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1668   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1669 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1670 be used in a STORE FLAGS command."
1671   (let ((result (nnimap-mark-to-flag-1 preds)))
1672     (setq result (if (and (or make-string always-list)
1673                           (not (listp result)))
1674                      (list result)
1675                    result))
1676     (if make-string
1677         (mapconcat (lambda (flag)
1678                      (if (listp flag)
1679                          (mapconcat 'identity flag " ")
1680                        flag))
1681                    result " ")
1682       result)))
1683
1684 (defun nnimap-mark-permanent-p (mark &optional group)
1685   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1686   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1687
1688 (when nnimap-debug
1689   (require 'trace)
1690   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1691   (mapcar (lambda (f) (trace-function-background f nnimap-debug-buffer))
1692           '(
1693             nnimap-possibly-change-server
1694             nnimap-verify-uidvalidity
1695             nnimap-find-minmax-uid
1696             nnimap-before-find-minmax-bugworkaround
1697             nnimap-possibly-change-group
1698             ;;nnimap-replace-whitespace
1699             nnimap-retrieve-headers-progress
1700             nnimap-retrieve-which-headers
1701             nnimap-group-overview-filename
1702             nnimap-retrieve-headers-from-file
1703             nnimap-retrieve-headers-from-server
1704             nnimap-retrieve-headers
1705             nnimap-open-connection
1706             nnimap-open-server
1707             nnimap-server-opened
1708             nnimap-close-server
1709             nnimap-request-close
1710             nnimap-status-message
1711             ;;nnimap-demule
1712             nnimap-request-article-part
1713             nnimap-request-article
1714             nnimap-request-head
1715             nnimap-request-body
1716             nnimap-request-group
1717             nnimap-close-group
1718             nnimap-pattern-to-list-arguments
1719             nnimap-request-list
1720             nnimap-request-post
1721             nnimap-retrieve-groups
1722             nnimap-request-update-info-internal
1723             nnimap-request-type
1724             nnimap-request-set-mark
1725             nnimap-split-to-groups
1726             nnimap-split-find-rule
1727             nnimap-split-find-inbox
1728             nnimap-split-articles
1729             nnimap-request-scan
1730             nnimap-request-newgroups
1731             nnimap-request-create-group
1732             nnimap-time-substract
1733             nnimap-date-days-ago
1734             nnimap-request-expire-articles-progress
1735             nnimap-request-expire-articles
1736             nnimap-request-move-article
1737             nnimap-request-accept-article
1738             nnimap-request-delete-group
1739             nnimap-request-rename-group
1740             gnus-group-nnimap-expunge
1741             gnus-group-nnimap-edit-acl
1742             gnus-group-nnimap-edit-acl-done
1743             nnimap-group-mode-hook
1744             nnimap-mark-to-predicate
1745             nnimap-mark-to-flag-1
1746             nnimap-mark-to-flag
1747             nnimap-mark-permanent-p
1748             )))
1749
1750 (provide 'nnimap)
1751
1752 ;;; nnimap.el ends here