git.chise.org Git - elisp/gnus.git-/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   6 ;;         Jim Radford <radford@robby.caltech.edu>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Todo, major things:
  29 ;;
  30 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  31 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  32 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  33 ;;   o Sieve
  34 ;;   o MIME (partial article fetches)
  35 ;;   o Split to other backends, different split rules for different
  36 ;;     servers/inboxes
  37 ;;
  38 ;; Todo, minor things:
  39 ;;
  40 ;;   o Don't require half of Gnus -- backends should be standalone
  41 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  42 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  43 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  44 ;;   o What do I do with gnus-newsgroup-*?
  45 ;;   o Tell Gnus about new groups (how can we tell?)
  46 ;;   o Respooling (fix Gnus?) (unnecessary?)
  47 ;;   o Add support for the following: (if applicable)
  48 ;;       request-list-newsgroups, request-regenerate
  49 ;;       list-active-group,
  50 ;;       request-associate-buffer, request-restore-buffer,
  51 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  52 ;;   o Support RFC2221 (Login referrals)
  53 ;;   o IMAP2BIS compatibility? (RFC2061)
  54 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  55 ;;     .newsrc.eld)
  56 ;;   o What about Gnus's article editing, can we support it?  NO!
  57 ;;   o Use \Draft to support the draft group??
  58 ;;   o Duplicate suppression
  59 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  60
  61 ;;; Code:
  62
  63 (eval-when-compile (require 'cl))
  64 (require 'imap)
  65
  66 (require 'nnoo)
  67 (require 'nnmail)
  68 (require 'nnheader)
  69 (require 'gnus)
  70 (require 'gnus-range)
  71 (require 'gnus-start)
  72 (require 'gnus-int)
  73
  74 (eval-when-compile (require 'cl))
  75
  76 (nnoo-declare nnimap)
  77
  78 (defconst nnimap-version "nnimap 1.0")
  79
  80 (defgroup nnimap nil
  81   "Reading IMAP mail with Gnus."
  82   :group 'gnus)
  83
  84 (defvoo nnimap-address nil
  85   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  86
  87 (defvoo nnimap-server-port nil
  88   "Port number on physical IMAP server.
  89 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  90
  91 ;; Splitting variables
  92
  93 (defcustom nnimap-split-crosspost t
  94   "If non-nil, do crossposting if several split methods match the mail.
  95 If nil, the first match found will be used."
  96   :group 'nnimap
  97   :type 'boolean)
  98
  99 (defcustom nnimap-split-inbox nil
 100   "Name of mailbox to split mail from.
 101
 102 Mail is read from this mailbox and split according to rules in
 103 `nnimap-split-rule'.
 104
 105 This can be a string or a list of strings."
 106   :group 'nnimap
 107   :type '(choice (string)
 108                  (repeat string)))
 109
 110 (define-widget 'nnimap-strict-function 'function
 111   "This widget only matches values that are functionp.
 112
 113 Warning: This means that a value that is the symbol of a not yet
 114 loaded function will not match.  Use with care."
 115   :match 'nnimap-strict-function-match)
 116
 117 (defun nnimap-strict-function-match (widget value)
 118   "Ignoring WIDGET, match if VALUE is a function."
 119   (functionp value))
 120
 121 (defcustom nnimap-split-rule nil
 122   "Mail will be split according to these rules.
 123
 124 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 125
 126 If you'd like, for instance, one mail group for mail from the
 127 \"gnus-imap\" mailing list, one group for junk mail and leave
 128 everything else in the incoming mailbox, you could do something like
 129 this:
 130
 131 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 132                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 133
 134 As you can see, `nnimap-split-rule' is a list of lists, where the
 135 first element in each \"rule\" is the name of the IMAP mailbox (or the
 136 symbol `junk' if you want to remove the mail), and the second is a
 137 regexp that nnimap will try to match on the header to find a fit.
 138
 139 The second element can also be a function.  In that case, it will be
 140 called narrowed to the headers with the first element of the rule as
 141 the argument.  It should return a non-nil value if it thinks that the
 142 mail belongs in that group.
 143
 144 This variable can also have a function as its value, the function will
 145 be called with the headers narrowed and should return a group where it
 146 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 147
 148 To allow for different split rules on different virtual servers, and
 149 even different split rules in different inboxes on the same server,
 150 the syntax of this variable have been extended along the lines of:
 151
 152 \(setq nnimap-split-rule
 153       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 154                                   (\"junk\"    \"From:.*Simon\")))
 155         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 156         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 157                                   (\"junk\"    my-junk-func)))))
 158
 159 The virtual server name is in fact a regexp, so that the same rules
 160 may apply to several servers.  In the example, the servers
 161 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 162 the inbox string is also a regexp.  The actual splitting rules are as
 163 before, either a function, or a list with group/regexp or
 164 group/function elements."
 165   :group 'nnimap
 166   :type '(choice :tag "Rule type"
 167                  (repeat :menu-tag "Single-server"
 168                          :tag "Single-server list"
 169                          (list (string :tag "Mailbox")
 170                                (choice :tag "Predicate"
 171                                        (regexp :tag "A regexp")
 172                                        (nnimap-strict-function :tag "A function"))))
 173                  (choice :menu-tag "A function"
 174                          :tag "A function"
 175                          (function-item nnimap-split-fancy)
 176                          (function-item nnmail-split-fancy)
 177                          (nnimap-strict-function :tag "User-defined function"))
 178                  (repeat :menu-tag "Multi-server (extended)"
 179                          :tag "Multi-server list"
 180                          (list (regexp :tag "Server regexp")
 181                                (list (regexp :tag "Incoming Mailbox regexp")
 182                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 183                                              (list (string :tag "Destination mailbox")
 184                                                    (choice :tag "Predicate"
 185                                                            (regexp :tag "A Regexp")
 186                                                            (nnimap-strict-function :tag "A Function")))))))))
 187
 188 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 189   "The predicate used to find articles to split.
 190 If you use another IMAP client to peek on articles but always would
 191 like nnimap to split them once it's started, you could change this to
 192 \"UNDELETED\". Other available predicates are available in
 193 RFC2060 section 6.4.4."
 194   :group 'nnimap
 195   :type 'string)
 196
 197 (defcustom nnimap-split-fancy nil
 198   "Like the variable `nnmail-split-fancy'."
 199   :group 'nnimap
 200   :type 'sexp)
 201
 202 (defvar nnimap-split-download-body-default nil
 203   "Internal variable with default value for `nnimap-split-download-body'.")
 204
 205 (defcustom nnimap-split-download-body 'default
 206   "Whether to download entire articles during splitting.
 207 This is generally not required, and will slow things down considerably.
 208 You may need it if you want to use an advanced splitting function that
 209 analyses the body before splitting the article.
 210 If this variable is nil, bodies will not be downloaded; if this
 211 variable is the symbol `default' the default behaviour is
 212 used (which currently is nil, unless you use a statistical
 213 spam.el test); if this variable is another non-nil value bodies
 214 will be downloaded."
 215   :version "21.4"
 216   :group 'nnimap
 217   :type '(choice (const :tag "Let system decide" deault)
 218                  boolean))
 219
 220 ;; Performance / bug workaround variables
 221
 222 (defcustom nnimap-close-asynchronous t
 223   "Close mailboxes asynchronously in `nnimap-close-group'.
 224 This means that errors caught by nnimap when closing the mailbox will
 225 not prevent Gnus from updating the group status, which may be harmful.
 226 However, it increases speed."
 227   :version "21.4"
 228   :type 'boolean
 229   :group 'nnimap)
 230
 231 (defcustom nnimap-dont-close t
 232   "Never close mailboxes.
 233 This increases the speed of closing mailboxes (quiting group) but may
 234 decrease the speed of selecting another mailbox later.  Re-selecting
 235 the same mailbox will be faster though."
 236   :version "21.4"
 237   :type 'boolean
 238   :group 'nnimap)
 239
 240 (defcustom nnimap-retrieve-groups-asynchronous t
 241   "Send asynchronous STATUS commands for each mailbox before checking mail.
 242 If you have mailboxes that rarely receives mail, this speeds up new
 243 mail checking.  It works by first sending STATUS commands for each
 244 mailbox, and then only checking groups which has a modified UIDNEXT
 245 more carefully for new mail.
 246
 247 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 248 it O(n).  If p is small, then the default is probably faster."
 249   :version "21.4"
 250   :type 'boolean
 251   :group 'nnimap)
 252
 253 (defvoo nnimap-need-unselect-to-notice-new-mail nil
 254   "Unselect mailboxes before looking for new mail in them.
 255 Some servers seem to need this under some circumstances.")
 256
 257 ;; Authorization / Privacy variables
 258
 259 (defvoo nnimap-auth-method nil
 260   "Obsolete.")
 261
 262 (defvoo nnimap-stream nil
 263   "How nnimap will connect to the server.
 264
 265 The default, nil, will try to use the \"best\" method the server can
 266 handle.
 267
 268 Change this if
 269
 270 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 271    with IMAP is suboptimal so you'll have to tell it
 272    specifically.
 273
 274 2) your server is more capable than your environment -- i.e. your
 275    server accept Kerberos login's but you haven't installed the
 276    `imtest' program or your machine isn't configured for Kerberos.
 277
 278 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 279 See also `imap-streams' and `imap-stream-alist'.")
 280
 281 (defvoo nnimap-authenticator nil
 282   "How nnimap authenticate itself to the server.
 283
 284 The default, nil, will try to use the \"best\" method the server can
 285 handle.
 286
 287 There is only one reason for fiddling with this variable, and that is
 288 if your server is more capable than your environment -- i.e. you
 289 connect to a server that accept Kerberos login's but you haven't
 290 installed the `imtest' program or your machine isn't configured for
 291 Kerberos.
 292
 293 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 294 See also `imap-authenticators' and `imap-authenticator-alist'")
 295
 296 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 297   "Directory to keep NOV cache files for nnimap groups.
 298 See also `nnimap-nov-file-name'.")
 299
 300 (defvoo nnimap-nov-file-name "nnimap."
 301   "NOV cache base filename.
 302 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 303 typical complete file name would be
 304 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 305 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 306 `nnmail-use-long-file-names' is nil")
 307
 308 (defvoo nnimap-nov-file-name-suffix ".novcache"
 309   "Suffix for NOV cache base filename.")
 310
 311 (defvoo nnimap-nov-is-evil gnus-agent
 312   "If non-nil, never generate or use a local nov database for this backend.
 313 Using nov databases should speed up header fetching considerably.
 314 However, it will invoke a UID SEARCH UID command on the server, and
 315 some servers implement this command inefficiently by opening each and
 316 every message in the group, thus making it quite slow.
 317 Unlike other backends, you do not need to take special care if you
 318 flip this variable.")
 319
 320 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 321   "Whether to expunge a group when it is closed.
 322 When a IMAP group with articles marked for deletion is closed, this
 323 variable determine if nnimap should actually remove the articles or
 324 not.
 325
 326 If always, nnimap always perform a expunge when closing the group.
 327 If never, nnimap never expunges articles marked for deletion.
 328 If ask, nnimap will ask you if you wish to expunge marked articles.
 329
 330 When setting this variable to `never', you can only expunge articles
 331 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 332
 333 (defvoo nnimap-list-pattern "*"
 334   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 335 See below for available wildcards.
 336
 337 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 338 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 339 semantics of this are server specific, on the University of Washington
 340 server you can specify a directory.
 341
 342 Example:
 343  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 344
 345 There are two wildcards * and %. * matches everything, % matches
 346 everything in the current hierarchy.")
 347
 348 (defvoo nnimap-news-groups nil
 349   "IMAP support a news-like mode, also known as bulletin board mode,
 350 where replies is sent via IMAP instead of SMTP.
 351
 352 This variable should contain a regexp matching groups where you wish
 353 replies to be stored to the mailbox directly.
 354
 355 Example:
 356   '(\"^[^I][^N][^B][^O][^X].*$\")
 357
 358 This will match all groups not beginning with \"INBOX\".
 359
 360 Note that there is nothing technically different between mail-like and
 361 news-like mailboxes.  If you wish to have a group with todo items or
 362 similar which you wouldn't want to set up a mailing list for, you can
 363 use this to make replies go directly to the group.")
 364
 365 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 366   "IMAP search command to use for articles that are to be expired.
 367 The first %s is replaced by a UID set of articles to search on,
 368 and the second %s is replaced by a date criterium.
 369
 370 One useful (and perhaps the only useful) value to change this to would
 371 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 372 instead of the internal date of messages.  See section 6.4.4 of RFC
 373 2060 for more information on valid strings.")
 374
 375 (defvoo nnimap-importantize-dormant t
 376   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 377 Note that within Gnus, dormant articles will still (only) be
 378 marked as ticked.  This is to make \"dormant\" articles stand out,
 379 just like \"ticked\" articles, in other IMAP clients.")
 380
 381 (defvoo nnimap-server-address nil
 382   "Obsolete.  Use `nnimap-address'.")
 383
 384 (defcustom nnimap-authinfo-file "~/.authinfo"
 385   "Authorization information for IMAP servers.  In .netrc format."
 386   :type
 387   '(choice file
 388            (repeat :tag "Entries"
 389                    :menu-tag "Inline"
 390                    (list :format "%v"
 391                          :value ("" ("login" . "") ("password" . ""))
 392                          (string :tag "Host")
 393                          (checklist :inline t
 394                                     (cons :format "%v"
 395                                           (const :format "" "login")
 396                                           (string :format "Login: %v"))
 397                                     (cons :format "%v"
 398                                           (const :format "" "password")
 399                                           (string :format "Password: %v"))))))
 400   :group 'nnimap)
 401
 402 (defcustom nnimap-prune-cache t
 403   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 404   :type 'boolean
 405   :group 'nnimap)
 406
 407 (defvar nnimap-request-list-method 'imap-mailbox-list
 408   "Method to use to request a list of all folders from the server.
 409 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 410 restrict visible folders.")
 411
 412 (defcustom nnimap-id nil
 413   "Plist with client identity to send to server upon login.
 414 Nil means no information is sent, symbol `no' to disable ID query
 415 alltogheter, or plist with identifier-value pairs to send to
 416 server.  RFC 2971 describes the list as follows:
 417
 418    Any string may be sent as a field, but the following are defined to
 419    describe certain values that might be sent.  Implementations are free
 420    to send none, any, or all of these.  Strings are not case-sensitive.
 421    Field strings MUST NOT be longer than 30 octets.  Value strings MUST
 422    NOT be longer than 1024 octets.  Implementations MUST NOT send more
 423    than 30 field-value pairs.
 424
 425      name            Name of the program
 426      version         Version number of the program
 427      os              Name of the operating system
 428      os-version      Version of the operating system
 429      vendor          Vendor of the client/server
 430      support-url     URL to contact for support
 431      address         Postal address of contact/vendor
 432      date            Date program was released, specified as a date-time
 433                        in IMAP4rev1
 434      command         Command used to start the program
 435      arguments       Arguments supplied on the command line, if any
 436                        if any
 437      environment     Description of environment, i.e., UNIX environment
 438                        variables or Windows registry settings
 439
 440    Implementations MUST NOT send the same field name more than once.
 441
 442 An example plist would be '(\"name\" \"Gnus\" \"version\" gnus-version-number
 443 \"os\" system-configuration \"vendor\" \"GNU\")."
 444   :group 'nnimap
 445   :type '(choice (const :tag "No information" nil)
 446                  (const :tag "Disable ID query" no)
 447                  (plist :key-type string :value-type string)))
 448
 449 (defcustom nnimap-debug nil
 450   "If non-nil, random debug spews are placed in *nnimap-debug* buffer."
 451   :group 'nnimap
 452   :type 'boolean)
 453
 454 ;; Internal variables:
 455
 456 (defvar nnimap-debug-buffer "*nnimap-debug*")
 457 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 458 (defvar nnimap-current-move-server nil)
 459 (defvar nnimap-current-move-group nil)
 460 (defvar nnimap-current-move-article nil)
 461 (defvar nnimap-length)
 462 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 463 (defvar nnimap-progress-how-often 20)
 464 (defvar nnimap-counter)
 465 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 466 (defvar nnimap-current-server nil)      ;; Current server
 467 (defvar nnimap-server-buffer nil)       ;; Current servers' buffer
 468
 469 \f
 470
 471 (nnoo-define-basics nnimap)
 472
 473 ;; Utility functions:
 474
 475 (defsubst nnimap-get-server-buffer (server)
 476   "Return buffer for SERVER, if nil use current server."
 477   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 478
 479 (defun nnimap-possibly-change-server (server)
 480   "Return buffer for SERVER, changing the current server as a side-effect.
 481 If SERVER is nil, uses the current server."
 482   (setq nnimap-current-server (or server nnimap-current-server)
 483         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 484
 485 (defun nnimap-verify-uidvalidity (group server)
 486   "Verify stored uidvalidity match current one in GROUP on SERVER."
 487   (let* ((gnusgroup (gnus-group-prefixed-name
 488                      group (gnus-server-to-method
 489                             (format "nnimap:%s" server))))
 490          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 491          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 492          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 493          (nameuid (nnheader-translate-file-chars
 494                    (concat nnimap-nov-file-name
 495                            (if (equal server "")
 496                                "unnamed"
 497                              server) "." group "." old-uidvalidity
 498                              nnimap-nov-file-name-suffix) t))
 499          (file (if (or nnmail-use-long-file-names
 500                        (file-exists-p (expand-file-name nameuid dir)))
 501                    (expand-file-name nameuid dir)
 502                  (expand-file-name
 503                   (encode-coding-string
 504                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 505                    nnmail-pathname-coding-system)
 506                   dir))))
 507     (if old-uidvalidity
 508         (if (not (equal old-uidvalidity new-uidvalidity))
 509             ;; uidvalidity clash
 510             (gnus-delete-file file)
 511           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 512           t)
 513       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 514       t)))
 515
 516 (defun nnimap-before-find-minmax-bugworkaround ()
 517   "Function called before iterating through mailboxes with
 518 `nnimap-find-minmax-uid'."
 519   (when nnimap-need-unselect-to-notice-new-mail
 520     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 521     ;; currently selected mailbox without a re-select/examine.
 522     (or (null (imap-current-mailbox nnimap-server-buffer))
 523         (imap-mailbox-unselect nnimap-server-buffer))))
 524
 525 (defun nnimap-find-minmax-uid (group &optional examine)
 526   "Find lowest and highest active article number in GROUP.
 527 If EXAMINE is non-nil the group is selected read-only."
 528   (with-current-buffer nnimap-server-buffer
 529     (when (or (string= group (imap-current-mailbox))
 530               (imap-mailbox-select group examine))
 531       (let (minuid maxuid)
 532         (when (> (imap-mailbox-get 'exists) 0)
 533           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 534           (imap-message-map (lambda (uid Uid)
 535                               (setq minuid (if minuid (min minuid uid) uid)
 536                                     maxuid (if maxuid (max maxuid uid) uid)))
 537                             'UID))
 538         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 539
 540 (defun nnimap-possibly-change-group (group &optional server)
 541   "Make GROUP the current group, and SERVER the current server."
 542   (when (nnimap-possibly-change-server server)
 543     (with-current-buffer nnimap-server-buffer
 544       (if (or (null group) (imap-current-mailbox-p group))
 545           imap-current-mailbox
 546         (if (imap-mailbox-select group)
 547             (if (or (nnimap-verify-uidvalidity
 548                      group (or server nnimap-current-server))
 549                     (zerop (imap-mailbox-get 'exists group))
 550                     t ;; for OGnus to see if ignoring uidvalidity
 551                       ;; changes has any bad effects.
 552                     (yes-or-no-p
 553                      (format
 554                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 555                 imap-current-mailbox
 556               (imap-mailbox-unselect)
 557               (error "nnimap: Group %s is not uid-valid" group))
 558           (nnheader-report 'nnimap (imap-error-text)))))))
 559
 560 (defun nnimap-replace-whitespace (string)
 561   "Return STRING with all whitespace replaced with space."
 562   (when string
 563     (while (string-match "[\r\n\t]+" string)
 564       (setq string (replace-match " " t t string)))
 565     string))
 566
 567 ;; Required backend functions
 568
 569 (defun nnimap-retrieve-headers-progress ()
 570   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 571   (and (numberp nnmail-large-newsgroup)
 572        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 573        (> nnimap-length nnmail-large-newsgroup)
 574        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 575                          (nth (/ (% nnimap-counter
 576                                     (* (length nnimap-progress-chars)
 577                                        nnimap-progress-how-often))
 578                                  nnimap-progress-how-often)
 579                               nnimap-progress-chars)))
 580   (with-current-buffer nntp-server-buffer
 581     (let (headers lines chars uid mbx)
 582       (with-current-buffer nnimap-server-buffer
 583         (setq uid imap-current-message
 584               mbx imap-current-mailbox
 585               headers (nnimap-demule
 586                        (if (imap-capability 'IMAP4rev1)
 587                            ;; xxx don't just use car? alist doesn't contain
 588                            ;; anything else now, but it might...
 589                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 590                          (imap-message-get uid 'RFC822.HEADER)))
 591               lines (imap-body-lines (imap-message-body imap-current-message))
 592               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 593       (nnheader-insert-nov
 594        (with-temp-buffer
 595          (buffer-disable-undo)
 596          (insert headers)
 597          (let ((head (nnheader-parse-naked-head uid)))
 598            (mail-header-set-number head uid)
 599            (mail-header-set-chars head chars)
 600            (mail-header-set-lines head lines)
 601            (mail-header-set-xref
 602             head (format "%s %s:%d" (system-name) mbx uid))
 603            head))))))
 604
 605 (defun nnimap-retrieve-which-headers (articles fetch-old)
 606   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 607   (with-current-buffer nnimap-server-buffer
 608     (if (numberp (car-safe articles))
 609         (imap-search
 610          (concat "UID "
 611                  (imap-range-to-message-set
 612                   (gnus-compress-sequence
 613                    (append (gnus-uncompress-sequence
 614                             (and fetch-old
 615                                  (cons (if (numberp fetch-old)
 616                                            (max 1 (- (car articles) fetch-old))
 617                                          1)
 618                                        (1- (car articles)))))
 619                            articles)))))
 620       (mapcar (lambda (msgid)
 621                 (imap-search
 622                  (format "HEADER Message-Id \"%s\"" msgid)))
 623               articles))))
 624
 625 (defun nnimap-group-overview-filename (group server)
 626   "Make file name for GROUP on SERVER."
 627   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 628          (uidvalidity (gnus-group-get-parameter
 629                        (gnus-group-prefixed-name
 630                         group (gnus-server-to-method
 631                                (format "nnimap:%s" server)))
 632                        'uidvalidity))
 633          (name (nnheader-translate-file-chars
 634                 (concat nnimap-nov-file-name
 635                         (if (equal server "")
 636                             "unnamed"
 637                           server) "." group nnimap-nov-file-name-suffix) t))
 638          (nameuid (nnheader-translate-file-chars
 639                    (concat nnimap-nov-file-name
 640                            (if (equal server "")
 641                                "unnamed"
 642                              server) "." group "." uidvalidity
 643                              nnimap-nov-file-name-suffix) t))
 644          (oldfile (if (or nnmail-use-long-file-names
 645                           (file-exists-p (expand-file-name name dir)))
 646                       (expand-file-name name dir)
 647                     (expand-file-name
 648                      (encode-coding-string
 649                       (nnheader-replace-chars-in-string name ?. ?/)
 650                       nnmail-pathname-coding-system)
 651                      dir)))
 652          (newfile (if (or nnmail-use-long-file-names
 653                           (file-exists-p (expand-file-name nameuid dir)))
 654                       (expand-file-name nameuid dir)
 655                     (expand-file-name
 656                      (encode-coding-string
 657                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 658                       nnmail-pathname-coding-system)
 659                      dir))))
 660     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 661       (message "nnimap: Upgrading novcache filename...")
 662       (sit-for 1)
 663       (gnus-make-directory (file-name-directory newfile))
 664       (unless (ignore-errors (rename-file oldfile newfile) t)
 665         (if (ignore-errors (copy-file oldfile newfile) t)
 666             (delete-file oldfile)
 667           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 668     newfile))
 669
 670 (defun nnimap-retrieve-headers-from-file (group server)
 671   (with-current-buffer nntp-server-buffer
 672     (let ((nov (nnimap-group-overview-filename group server)))
 673       (when (file-exists-p nov)
 674         (nnheader-insert-file-contents nov)
 675         (set-buffer-modified-p nil)
 676         (let ((min (ignore-errors (goto-char (point-min))
 677                                   (read (current-buffer))))
 678               (max (ignore-errors (goto-char (point-max))
 679                                   (forward-line -1)
 680                                   (read (current-buffer)))))
 681           (if (and (numberp min) (numberp max))
 682               (cons min max)
 683             ;; junk, remove it, it's saved later
 684             (erase-buffer)
 685             nil))))))
 686
 687 (defun nnimap-retrieve-headers-from-server (articles group server)
 688   (with-current-buffer nnimap-server-buffer
 689     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 690           (nnimap-length (gnus-range-length articles))
 691           (nnimap-counter 0))
 692       (imap-fetch (imap-range-to-message-set articles)
 693                   (concat "(UID RFC822.SIZE BODY "
 694                           (let ((headers
 695                                  (append '(Subject From Date Message-Id
 696                                                    References In-Reply-To Xref)
 697                                          (copy-sequence
 698                                           nnmail-extra-headers))))
 699                             (if (imap-capability 'IMAP4rev1)
 700                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 701                               (format "RFC822.HEADER.LINES %s)" headers)))))
 702       (and (numberp nnmail-large-newsgroup)
 703            (> nnimap-length nnmail-large-newsgroup)
 704            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 705
 706 (defun nnimap-dont-use-nov-p (group server)
 707   (or gnus-nov-is-evil nnimap-nov-is-evil
 708       (unless (and (gnus-make-directory
 709                     (file-name-directory
 710                      (nnimap-group-overview-filename group server)))
 711                    (file-writable-p
 712                     (nnimap-group-overview-filename group server)))
 713         (message "nnimap: Nov cache not writable, %s"
 714                  (nnimap-group-overview-filename group server)))))
 715
 716 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 717   (when (nnimap-possibly-change-group group server)
 718     (with-current-buffer nntp-server-buffer
 719       (erase-buffer)
 720       (if (nnimap-dont-use-nov-p group server)
 721           (nnimap-retrieve-headers-from-server
 722            (gnus-compress-sequence articles) group server)
 723         (let (uids cached low high)
 724           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 725                       low (car uids)
 726                       high (car (last uids)))
 727             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 728                 (progn
 729                   ;; fetch articles with uids before cache block
 730                   (when (< low (car cached))
 731                     (goto-char (point-min))
 732                     (nnimap-retrieve-headers-from-server
 733                      (cons low (1- (car cached))) group server))
 734                   ;; fetch articles with uids after cache block
 735                   (when (> high (cdr cached))
 736                     (goto-char (point-max))
 737                     (nnimap-retrieve-headers-from-server
 738                      (cons (1+ (cdr cached)) high) group server))
 739                   (when nnimap-prune-cache
 740                     ;; remove nov's for articles which has expired on server
 741                     (goto-char (point-min))
 742                     (dolist (uid (gnus-set-difference articles uids))
 743                       (when (re-search-forward (format "^%d\t" uid) nil t)
 744                         (gnus-delete-line)))))
 745               ;; nothing cached, fetch whole range from server
 746               (nnimap-retrieve-headers-from-server
 747                (cons low high) group server))
 748             (when (buffer-modified-p)
 749               (nnmail-write-region
 750                (point-min) (point-max)
 751                (nnimap-group-overview-filename group server) nil 'nomesg))
 752             (nnheader-nov-delete-outside-range low high))))
 753       'nov)))
 754
 755 (defun nnimap-open-connection (server)
 756   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 757                       nnimap-authenticator nnimap-server-buffer))
 758       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 759     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 760                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 761       (imap-close nnimap-server-buffer)
 762       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 763     (let* ((list (netrc-parse nnimap-authinfo-file))
 764            (port (if nnimap-server-port
 765                      (int-to-string nnimap-server-port)
 766                    "imap"))
 767            (alist (or (netrc-machine list server port "imap")
 768                       (netrc-machine list
 769                                      (or nnimap-server-address
 770                                          nnimap-address)
 771                                      port "imap")
 772                       (netrc-machine list server port "imaps")
 773                       (netrc-machine list
 774                                      (or nnimap-server-address
 775                                          nnimap-address)
 776                                      port "imaps")))
 777            (user (netrc-get alist "login"))
 778            (passwd (netrc-get alist "password")))
 779       (if (imap-authenticate user passwd nnimap-server-buffer)
 780           (prog1
 781               (push (list server nnimap-server-buffer)
 782                     nnimap-server-buffer-alist)
 783             (imap-id nnimap-id nnimap-server-buffer)
 784             (nnimap-possibly-change-server server))
 785         (imap-close nnimap-server-buffer)
 786         (kill-buffer nnimap-server-buffer)
 787         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 788
 789 (deffoo nnimap-open-server (server &optional defs)
 790   (nnheader-init-server-buffer)
 791   (if (nnimap-server-opened server)
 792       t
 793     (unless (assq 'nnimap-server-buffer defs)
 794       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 795     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 796     ;; for people that configured nnimap with a very old version
 797     (unless (assq 'nnimap-address defs)
 798       (if (assq 'nnimap-server-address defs)
 799           (push (list 'nnimap-address
 800                       (cadr (assq 'nnimap-server-address defs))) defs)
 801         (push (list 'nnimap-address server) defs)))
 802     (nnoo-change-server 'nnimap server defs)
 803     (or nnimap-server-buffer
 804         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 805     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 806       (nnoo-change-server 'nnimap server defs))
 807     (or (and nnimap-server-buffer
 808              (imap-opened nnimap-server-buffer)
 809              (if (with-current-buffer nnimap-server-buffer
 810                    (memq imap-state '(auth select examine)))
 811                  t
 812                (imap-close nnimap-server-buffer)
 813                (nnimap-open-connection server)))
 814         (nnimap-open-connection server))))
 815
 816 (deffoo nnimap-server-opened (&optional server)
 817   "Whether SERVER is opened.
 818 If SERVER is the current virtual server, and the connection to the
 819 physical server is alive, this function return a non-nil value.  If
 820 SERVER is nil, it is treated as the current server."
 821   ;; clean up autologouts??
 822   (and (or server nnimap-current-server)
 823        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 824        (imap-opened (nnimap-get-server-buffer server))))
 825
 826 (deffoo nnimap-close-server (&optional server)
 827   "Close connection to server and free all resources connected to it.
 828 Return nil if the server couldn't be closed for some reason."
 829   (let ((server (or server nnimap-current-server)))
 830     (when (or (nnimap-server-opened server)
 831               (imap-opened (nnimap-get-server-buffer server)))
 832       (imap-close (nnimap-get-server-buffer server))
 833       (kill-buffer (nnimap-get-server-buffer server))
 834       (setq nnimap-server-buffer nil
 835             nnimap-current-server nil
 836             nnimap-server-buffer-alist
 837             (delq server nnimap-server-buffer-alist)))
 838     (nnoo-close-server 'nnimap server)))
 839
 840 (deffoo nnimap-request-close ()
 841   "Close connection to all servers and free all resources that the backend have reserved.
 842 All buffers that have been created by that
 843 backend should be killed.  (Not the nntp-server-buffer, though.) This
 844 function is generally only called when Gnus is shutting down."
 845   (mapc (lambda (server) (nnimap-close-server (car server)))
 846         nnimap-server-buffer-alist)
 847   (setq nnimap-server-buffer-alist nil))
 848
 849 (deffoo nnimap-status-message (&optional server)
 850   "This function returns the last error message from server."
 851   (when (nnimap-possibly-change-server server)
 852     (nnoo-status-message 'nnimap server)))
 853
 854 (defun nnimap-demule (string)
 855   ;; BEWARE: we used to use string-as-multibyte here which is braindead
 856   ;; because it will turn accidental emacs-mule-valid byte sequences
 857   ;; into multibyte chars.  --Stef
 858   ;; Reverted, braindead got 7.5 out of 10 on imdb, so it can't be
 859   ;; that bad. --Simon
 860   (funcall (if (and (fboundp 'string-as-multibyte)
 861                     (subrp (symbol-function 'string-as-multibyte)))
 862                'string-as-multibyte
 863              'identity)
 864            (or string "")))
 865
 866 (defun nnimap-make-callback (article gnus-callback buffer)
 867   "Return a callback function."
 868   `(lambda ()
 869      (nnimap-callback ,article ,gnus-callback ,buffer)))
 870
 871 (defun nnimap-callback (article gnus-callback buffer)
 872   (when (eq article (imap-current-message))
 873     (remove-hook 'imap-fetch-data-hook
 874                  (nnimap-make-callback article gnus-callback buffer))
 875     (with-current-buffer buffer
 876       (insert
 877        (with-current-buffer nnimap-server-buffer
 878          (nnimap-demule
 879           (if (imap-capability 'IMAP4rev1)
 880               ;; xxx don't just use car? alist doesn't contain
 881               ;; anything else now, but it might...
 882               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 883             (imap-message-get article 'RFC822)))))
 884       (nnheader-ms-strip-cr)
 885       (funcall gnus-callback t))))
 886
 887 (defun nnimap-request-article-part (article part prop &optional
 888                                             group server to-buffer detail)
 889   (when (nnimap-possibly-change-group group server)
 890     (let ((article (if (stringp article)
 891                        (car-safe (imap-search
 892                                   (format "HEADER Message-Id \"%s\"" article)
 893                                   nnimap-server-buffer))
 894                      article)))
 895       (when article
 896         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 897                       article (or group imap-current-mailbox
 898                                   gnus-newsgroup-name))
 899         (if (not nnheader-callback-function)
 900             (with-current-buffer (or to-buffer nntp-server-buffer)
 901               (erase-buffer)
 902               (let ((data (imap-fetch article part prop nil
 903                                       nnimap-server-buffer)))
 904                 (when data
 905                   (insert (nnimap-demule (if detail (nth 2 (car data)) data)))
 906                   (nnheader-ms-strip-cr)
 907                   (gnus-message
 908                    10 "nnimap: Fetching (part of) article %d from %s...done"
 909                    article (or group imap-current-mailbox gnus-newsgroup-name))
 910                   (if (bobp)
 911                       (nnheader-report 'nnimap "No such article %d in %s: %s"
 912                                        article (or group imap-current-mailbox
 913                                                    gnus-newsgroup-name)
 914                                        (imap-error-text nnimap-server-buffer))
 915                     (cons group article)))))
 916           (add-hook 'imap-fetch-data-hook
 917                     (nnimap-make-callback article
 918                                           nnheader-callback-function
 919                                           nntp-server-buffer))
 920           (imap-fetch-asynch article part nil nnimap-server-buffer)
 921           (cons group article))))))
 922
 923 (deffoo nnimap-asynchronous-p ()
 924   t)
 925
 926 (deffoo nnimap-request-article (article &optional group server to-buffer)
 927   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 928       (nnimap-request-article-part
 929        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 930     (nnimap-request-article-part
 931      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 932
 933 (deffoo nnimap-request-head (article &optional group server to-buffer)
 934   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 935       (nnimap-request-article-part
 936        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 937     (nnimap-request-article-part
 938      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 939
 940 (deffoo nnimap-request-body (article &optional group server to-buffer)
 941   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 942       (nnimap-request-article-part
 943        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 944     (nnimap-request-article-part
 945      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 946
 947 (deffoo nnimap-request-group (group &optional server fast)
 948   (nnimap-request-update-info-internal
 949    group
 950    (gnus-get-info (gnus-group-prefixed-name
 951                    group (gnus-server-to-method (format "nnimap:%s" server))))
 952    server)
 953   (when (nnimap-possibly-change-group group server)
 954     (nnimap-before-find-minmax-bugworkaround)
 955     (let (info)
 956       (cond (fast group)
 957             ((null (setq info (nnimap-find-minmax-uid group t)))
 958              (nnheader-report 'nnimap "Could not get active info for %s"
 959                               group))
 960             (t
 961              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 962                               (max 1 (or (nth 1 info) 1))
 963                               (or (nth 2 info) 0) group)
 964              (nnheader-report 'nnimap "Group %s selected" group)
 965              t)))))
 966
 967 (defun nnimap-update-unseen (group &optional server)
 968   "Update the unseen count in `nnimap-mailbox-info'."
 969   (gnus-sethash
 970    (gnus-group-prefixed-name group server)
 971    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
 972                                  nnimap-mailbox-info)))
 973      (list (nth 0 old) (nth 1 old)
 974            (imap-mailbox-status group 'unseen nnimap-server-buffer)
 975            (nth 3 old)))
 976    nnimap-mailbox-info))
 977
 978 (defun nnimap-close-group (group &optional server)
 979   (with-current-buffer nnimap-server-buffer
 980     (when (and (imap-opened)
 981                (nnimap-possibly-change-group group server))
 982       (nnimap-update-unseen group server)
 983       (case nnimap-expunge-on-close
 984         (always (progn
 985                   (imap-mailbox-expunge nnimap-close-asynchronous)
 986                   (unless nnimap-dont-close
 987                     (imap-mailbox-close nnimap-close-asynchronous))))
 988         (ask (if (and (imap-search "DELETED")
 989                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
 990                                              imap-current-mailbox)))
 991                  (progn
 992                    (imap-mailbox-expunge nnimap-close-asynchronous)
 993                    (unless nnimap-dont-close
 994                      (imap-mailbox-close nnimap-close-asynchronous)))
 995                (imap-mailbox-unselect)))
 996         (t (imap-mailbox-unselect)))
 997       (not imap-current-mailbox))))
 998
 999 (defun nnimap-pattern-to-list-arguments (pattern)
1000   (mapcar (lambda (p)
1001             (cons (car-safe p) (or (cdr-safe p) p)))
1002           (if (and (listp pattern)
1003                    (listp (cdr pattern)))
1004               pattern
1005             (list pattern))))
1006
1007 (deffoo nnimap-request-list (&optional server)
1008   (when (nnimap-possibly-change-server server)
1009     (with-current-buffer nntp-server-buffer
1010       (erase-buffer))
1011     (gnus-message 5 "nnimap: Generating active list%s..."
1012                   (if (> (length server) 0) (concat " for " server) ""))
1013     (nnimap-before-find-minmax-bugworkaround)
1014     (with-current-buffer nnimap-server-buffer
1015       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
1016         (dolist (mbx (funcall nnimap-request-list-method
1017                               (cdr pattern) (car pattern)))
1018           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
1019               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1020                 (when info
1021                   (with-current-buffer nntp-server-buffer
1022                     (insert (format "\"%s\" %d %d y\n"
1023                                     mbx (or (nth 2 info) 0)
1024                                     (max 1 (or (nth 1 info) 1)))))))))))
1025     (gnus-message 5 "nnimap: Generating active list%s...done"
1026                   (if (> (length server) 0) (concat " for " server) ""))
1027     t))
1028
1029 (deffoo nnimap-request-post (&optional server)
1030   (let ((success t))
1031     (dolist (mbx (message-unquote-tokens
1032                   (message-tokenize-header
1033                    (message-fetch-field "Newsgroups") ", ")) success)
1034       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
1035         (or (gnus-active to-newsgroup)
1036             (gnus-activate-group to-newsgroup)
1037             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
1038                                        to-newsgroup))
1039                 (or (and (gnus-request-create-group
1040                           to-newsgroup gnus-command-method)
1041                          (gnus-activate-group to-newsgroup nil nil
1042                                               gnus-command-method))
1043                     (error "Couldn't create group %s" to-newsgroup)))
1044             (error "No such group: %s" to-newsgroup))
1045         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
1046           (setq success nil))))))
1047
1048 ;; Optional backend functions
1049
1050 (defun nnimap-string-lessp-numerical (s1 s2)
1051   "Return t if first arg string is less than second in numerical order."
1052   (cond ((string= s1 s2)
1053          nil)
1054         ((> (length s1) (length s2))
1055          nil)
1056         ((< (length s1) (length s2))
1057          t)
1058         ((< (string-to-number (substring s1 0 1))
1059             (string-to-number (substring s2 0 1)))
1060          t)
1061         ((> (string-to-number (substring s1 0 1))
1062             (string-to-number (substring s2 0 1)))
1063          nil)
1064         (t
1065          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1066
1067 (deffoo nnimap-retrieve-groups (groups &optional server)
1068   (when (nnimap-possibly-change-server server)
1069     (gnus-message 5 "nnimap: Checking mailboxes...")
1070     (with-current-buffer nntp-server-buffer
1071       (erase-buffer)
1072       (nnimap-before-find-minmax-bugworkaround)
1073       (let (asyncgroups slowgroups)
1074         (if (null nnimap-retrieve-groups-asynchronous)
1075             (setq slowgroups groups)
1076           (dolist (group groups)
1077             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1078             (add-to-list (if (gnus-gethash-safe
1079                               (gnus-group-prefixed-name group server)
1080                               nnimap-mailbox-info)
1081                              'asyncgroups
1082                            'slowgroups)
1083                          (list group (imap-mailbox-status-asynch
1084                                       group '(uidvalidity uidnext unseen)
1085                                       nnimap-server-buffer))))
1086           (dolist (asyncgroup asyncgroups)
1087             (let ((group (nth 0 asyncgroup))
1088                   (tag   (nth 1 asyncgroup))
1089                   new old)
1090               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1091                 (if (or (not (string=
1092                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1093                                                     group server)
1094                                                    nnimap-mailbox-info))
1095                               (imap-mailbox-get 'uidvalidity group
1096                                                 nnimap-server-buffer)))
1097                         (not (string=
1098                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1099                                                     group server)
1100                                                    nnimap-mailbox-info))
1101                               (imap-mailbox-get 'uidnext group
1102                                                 nnimap-server-buffer))))
1103                     (push (list group) slowgroups)
1104                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1105                                                 group server)
1106                                                nnimap-mailbox-info))))))))
1107         (dolist (group slowgroups)
1108           (if nnimap-retrieve-groups-asynchronous
1109               (setq group (car group)))
1110           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1111           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1112           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1113                                                      nnimap-server-buffer))
1114               (let* ((info (nnimap-find-minmax-uid group 'examine))
1115                      (str (format "\"%s\" %d %d y\n" group
1116                                   (or (nth 2 info) 0)
1117                                   (max 1 (or (nth 1 info) 1)))))
1118                 (when (> (or (imap-mailbox-get 'recent group
1119                                                nnimap-server-buffer) 0)
1120                          0)
1121                   (push (list (cons group 0)) nnmail-split-history))
1122                 (insert str)
1123                 (when nnimap-retrieve-groups-asynchronous
1124                   (gnus-sethash
1125                    (gnus-group-prefixed-name group server)
1126                    (list (or (imap-mailbox-get
1127                               'uidvalidity group nnimap-server-buffer)
1128                              (imap-mailbox-status
1129                               group 'uidvalidity nnimap-server-buffer))
1130                          (or (imap-mailbox-get
1131                               'uidnext group nnimap-server-buffer)
1132                              (imap-mailbox-status
1133                               group 'uidnext nnimap-server-buffer))
1134                          (or (imap-mailbox-get
1135                               'unseen group nnimap-server-buffer)
1136                              (imap-mailbox-status
1137                               group 'unseen nnimap-server-buffer))
1138                          str)
1139                    nnimap-mailbox-info)))))))
1140     (gnus-message 5 "nnimap: Checking mailboxes...done")
1141     'active))
1142
1143 (deffoo nnimap-request-update-info-internal (group info &optional server)
1144   (when (nnimap-possibly-change-group group server)
1145     (when info;; xxx what does this mean? should we create a info?
1146       (with-current-buffer nnimap-server-buffer
1147         (gnus-message 5 "nnimap: Updating info for %s..."
1148                       (gnus-info-group info))
1149
1150         (when (nnimap-mark-permanent-p 'read)
1151           (let (seen unseen)
1152             ;; read info could contain articles marked unread by other
1153             ;; imap clients!  we correct this
1154             (setq seen (gnus-uncompress-range (gnus-info-read info))
1155                   unseen (imap-search "UNSEEN UNDELETED")
1156                   seen (gnus-set-difference seen unseen)
1157                   ;; seen might lack articles marked as read by other
1158                   ;; imap clients! we correct this
1159                   seen (append seen (imap-search "SEEN"))
1160                   ;; remove dupes
1161                   seen (sort seen '<)
1162                   seen (gnus-compress-sequence seen t)
1163                   ;; we can't return '(1) since this isn't a "list of ranges",
1164                   ;; and we can't return '((1)) since g-list-of-unread-articles
1165                   ;; is buggy so we return '((1 . 1)).
1166                   seen (if (and (integerp (car seen))
1167                                 (null (cdr seen)))
1168                            (list (cons (car seen) (car seen)))
1169                          seen))
1170             (gnus-info-set-read info seen)))
1171
1172         (mapcar (lambda (pred)
1173                   (when (or (eq (cdr pred) 'recent)
1174                             (and (nnimap-mark-permanent-p (cdr pred))
1175                                  (member (nnimap-mark-to-flag (cdr pred))
1176                                          (imap-mailbox-get 'flags))))
1177                     (gnus-info-set-marks
1178                      info
1179                      (gnus-update-alist-soft
1180                       (cdr pred)
1181                       (gnus-compress-sequence
1182                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
1183                       (gnus-info-marks info))
1184                      t)))
1185                 gnus-article-mark-lists)
1186
1187         (when nnimap-importantize-dormant
1188           ;; nnimap mark dormant article as ticked too (for other clients)
1189           ;; so we remove that mark for gnus since we support dormant
1190           (gnus-info-set-marks
1191            info
1192            (gnus-update-alist-soft
1193             'tick
1194             (gnus-remove-from-range
1195              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1196              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1197             (gnus-info-marks info))
1198            t))
1199
1200         (gnus-message 5 "nnimap: Updating info for %s...done"
1201                       (gnus-info-group info))
1202
1203         info))))
1204
1205 (deffoo nnimap-request-type (group &optional article)
1206   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1207       'news
1208     'mail))
1209
1210 (deffoo nnimap-request-set-mark (group actions &optional server)
1211   (when (nnimap-possibly-change-group group server)
1212     (with-current-buffer nnimap-server-buffer
1213       (let (action)
1214         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1215         (while (setq action (pop actions))
1216           (let ((range (nth 0 action))
1217                 (what  (nth 1 action))
1218                 (cmdmarks (nth 2 action))
1219                 marks)
1220             ;; bookmark can't be stored (not list/range
1221             (setq cmdmarks (delq 'bookmark cmdmarks))
1222             ;; killed can't be stored (not list/range
1223             (setq cmdmarks (delq 'killed cmdmarks))
1224             ;; unsent are for nndraft groups only
1225             (setq cmdmarks (delq 'unsent cmdmarks))
1226             ;; cache flags are pointless on the server
1227             (setq cmdmarks (delq 'cache cmdmarks))
1228             ;; seen flags are local to each gnus
1229             (setq cmdmarks (delq 'seen cmdmarks))
1230             ;; recent marks can't be set
1231             (setq cmdmarks (delq 'recent cmdmarks))
1232             (when nnimap-importantize-dormant
1233               ;; flag dormant articles as ticked
1234               (if (memq 'dormant cmdmarks)
1235                   (setq cmdmarks (cons 'tick cmdmarks))))
1236             ;; remove stuff we are forbidden to store
1237             (mapc (lambda (mark)
1238                     (if (imap-message-flag-permanent-p
1239                          (nnimap-mark-to-flag mark))
1240                         (setq marks (cons mark marks))))
1241                   cmdmarks)
1242             (when (and range marks)
1243               (cond ((eq what 'del)
1244                      (imap-message-flags-del
1245                       (imap-range-to-message-set range)
1246                       (nnimap-mark-to-flag marks nil t)))
1247                     ((eq what 'add)
1248                      (imap-message-flags-add
1249                       (imap-range-to-message-set range)
1250                       (nnimap-mark-to-flag marks nil t)))
1251                     ((eq what 'set)
1252                      (imap-message-flags-set
1253                       (imap-range-to-message-set range)
1254                       (nnimap-mark-to-flag marks nil t)))))))
1255         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1256   nil)
1257
1258 (defun nnimap-split-fancy ()
1259   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1260   (let ((nnmail-split-fancy nnimap-split-fancy))
1261     (nnmail-split-fancy)))
1262
1263 (defun nnimap-split-to-groups (rules)
1264   ;; tries to match all rules in nnimap-split-rule against content of
1265   ;; nntp-server-buffer, returns a list of groups that matched.
1266   (with-current-buffer nntp-server-buffer
1267     ;; Fold continuation lines.
1268     (goto-char (point-min))
1269     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1270       (replace-match " " t t))
1271     (if (functionp rules)
1272         (funcall rules)
1273       (let (to-groups regrepp)
1274         (catch 'split-done
1275           (dolist (rule rules to-groups)
1276             (let ((group (car rule))
1277                   (regexp (cadr rule)))
1278               (goto-char (point-min))
1279               (when (and (if (stringp regexp)
1280                              (progn
1281                                (if (not (stringp group))
1282                                    (setq group (eval group))
1283                                  (setq regrepp
1284                                        (string-match "\\\\[0-9&]" group)))
1285                                (re-search-forward regexp nil t))
1286                            (funcall regexp group))
1287                          ;; Don't enter the article into the same group twice.
1288                          (not (assoc group to-groups)))
1289                 (push (if regrepp
1290                           (nnmail-expand-newtext group)
1291                         group)
1292                       to-groups)
1293                 (or nnimap-split-crosspost
1294                     (throw 'split-done to-groups))))))))))
1295
1296 (defun nnimap-assoc-match (key alist)
1297   (let (element)
1298     (while (and alist (not element))
1299       (if (string-match (car (car alist)) key)
1300           (setq element (car alist)))
1301       (setq alist (cdr alist)))
1302     element))
1303
1304 (defun nnimap-split-find-rule (server inbox)
1305   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1306            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1307       ;; extended format
1308       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1309                                             server nnimap-split-rule))))
1310     nnimap-split-rule))
1311
1312 (defun nnimap-split-find-inbox (server)
1313   (if (listp nnimap-split-inbox)
1314       nnimap-split-inbox
1315     (list nnimap-split-inbox)))
1316
1317 (defun nnimap-split-articles (&optional group server)
1318   (when (nnimap-possibly-change-server server)
1319     (with-current-buffer nnimap-server-buffer
1320       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1321         ;; iterate over inboxes
1322         (while (and (setq inbox (pop inboxes))
1323                     (nnimap-possibly-change-group inbox));; SELECT
1324           ;; find split rule for this server / inbox
1325           (when (setq rule (nnimap-split-find-rule server inbox))
1326             ;; iterate over articles
1327             (dolist (article (imap-search nnimap-split-predicate))
1328               (when (if (if (eq nnimap-split-download-body 'default)
1329                             nnimap-split-download-body-default
1330                           nnimap-split-download-body)
1331                         (and (nnimap-request-article article)
1332                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1333                       (nnimap-request-head article))
1334                 ;; copy article to right group(s)
1335                 (setq removeorig nil)
1336                 (dolist (to-group (nnimap-split-to-groups rule))
1337                   (cond ((eq to-group 'junk)
1338                          (message "IMAP split removed %s:%s:%d" server inbox
1339                                   article)
1340                          (setq removeorig t))
1341                         ((imap-message-copy (number-to-string article)
1342                                             to-group nil 'nocopyuid)
1343                          (message "IMAP split moved %s:%s:%d to %s" server
1344                                   inbox article to-group)
1345                          (setq removeorig t)
1346                          (when nnmail-cache-accepted-message-ids
1347                            (with-current-buffer nntp-server-buffer
1348                              (let (msgid)
1349                                (and (setq msgid
1350                                           (nnmail-fetch-field "message-id"))
1351                                     (nnmail-cache-insert msgid
1352                                                          to-group
1353                                                          (nnmail-fetch-field "subject"))))))
1354                          ;; Add the group-art list to the history list.
1355                          (push (list (cons to-group 0)) nnmail-split-history))
1356                         (t
1357                          (message "IMAP split failed to move %s:%s:%d to %s"
1358                                   server inbox article to-group))))
1359                 (if (if (eq nnimap-split-download-body 'default)
1360                         nnimap-split-download-body-default
1361                       nnimap-split-download-body)
1362                     (widen))
1363                 ;; remove article if it was successfully copied somewhere
1364                 (and removeorig
1365                      (imap-message-flags-add (format "%d" article)
1366                                              "\\Seen \\Deleted")))))
1367           (when (imap-mailbox-select inbox);; just in case
1368             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1369             (imap-mailbox-expunge)
1370             (imap-mailbox-close)))
1371         (when nnmail-cache-accepted-message-ids
1372           (nnmail-cache-close))
1373         t))))
1374
1375 (deffoo nnimap-request-scan (&optional group server)
1376   (nnimap-split-articles group server))
1377
1378 (deffoo nnimap-request-newgroups (date &optional server)
1379   (when (nnimap-possibly-change-server server)
1380     (with-current-buffer nntp-server-buffer
1381       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1382                     (if (> (length server) 0) " on " "") server)
1383       (erase-buffer)
1384       (nnimap-before-find-minmax-bugworkaround)
1385       (dolist (pattern (nnimap-pattern-to-list-arguments
1386                         nnimap-list-pattern))
1387         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1388                                         nnimap-server-buffer))
1389           (or (catch 'found
1390                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1391                                                    nnimap-server-buffer))
1392                   (if (string= (downcase mailbox) "\\noselect")
1393                       (throw 'found t)))
1394                 nil)
1395               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1396                 (when info
1397                   (insert (format "\"%s\" %d %d y\n"
1398                                   mbx (or (nth 2 info) 0)
1399                                   (max 1 (or (nth 1 info) 1)))))))))
1400       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1401                     (if (> (length server) 0) " on " "") server))
1402     t))
1403
1404 (deffoo nnimap-request-create-group (group &optional server args)
1405   (when (nnimap-possibly-change-server server)
1406     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1407         (imap-mailbox-create group nnimap-server-buffer)
1408         (nnheader-report 'nnimap "%S"
1409                          (imap-error-text nnimap-server-buffer)))))
1410
1411 (defun nnimap-time-substract (time1 time2)
1412   "Return TIME for TIME1 - TIME2."
1413   (let* ((ms (- (car time1) (car time2)))
1414          (ls (- (nth 1 time1) (nth 1 time2))))
1415     (if (< ls 0)
1416         (list (- ms 1) (+ (expt 2 16) ls))
1417       (list ms ls))))
1418
1419 (defun nnimap-date-days-ago (daysago)
1420   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1421   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1422          (date (format-time-string
1423                 (format "%%d-%s-%%Y"
1424                         (capitalize (car (rassoc (nth 4 (decode-time time))
1425                                                  parse-time-months))))
1426                 time)))
1427     (if (eq ?0 (string-to-char date))
1428         (substring date 1)
1429       date)))
1430
1431 (defun nnimap-request-expire-articles-progress ()
1432   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1433                 imap-current-message))
1434
1435 (defun nnimap-expiry-target (arts group server)
1436   (unless (eq nnmail-expiry-target 'delete)
1437     (with-temp-buffer
1438       (dolist (art arts)
1439         (nnimap-request-article art group server (current-buffer))
1440         ;; hints for optimization in `nnimap-request-accept-article'
1441         (let ((nnimap-current-move-article art)
1442               (nnimap-current-move-group group)
1443               (nnimap-current-move-server server))
1444           (nnmail-expiry-target-group nnmail-expiry-target group))))
1445     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1446     ;; current group to be changed or not, so we make sure here.
1447     (nnimap-possibly-change-group group server)))
1448
1449 ;; Notice that we don't actually delete anything, we just mark them deleted.
1450 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1451   (let ((artseq (gnus-compress-sequence articles)))
1452     (when (and artseq (nnimap-possibly-change-group group server))
1453       (with-current-buffer nnimap-server-buffer
1454         (let ((days (or (and nnmail-expiry-wait-function
1455                              (funcall nnmail-expiry-wait-function group))
1456                         nnmail-expiry-wait)))
1457           (cond ((or force (eq days 'immediate))
1458                  (let ((oldarts (imap-search
1459                                  (concat "UID "
1460                                          (imap-range-to-message-set artseq)))))
1461                    (when oldarts
1462                      (nnimap-expiry-target oldarts group server)
1463                      (when (imap-message-flags-add
1464                             (imap-range-to-message-set
1465                              (gnus-compress-sequence oldarts)) "\\Deleted")
1466                        (setq articles (gnus-set-difference
1467                                        articles oldarts))))))
1468                 ((numberp days)
1469                  (let ((oldarts (imap-search
1470                                  (format nnimap-expunge-search-string
1471                                          (imap-range-to-message-set artseq)
1472                                          (nnimap-date-days-ago days))))
1473                        (imap-fetch-data-hook
1474                         '(nnimap-request-expire-articles-progress)))
1475                    (when oldarts
1476                      (nnimap-expiry-target oldarts group server)
1477                      (when (imap-message-flags-add
1478                             (imap-range-to-message-set
1479                              (gnus-compress-sequence oldarts)) "\\Deleted")
1480                        (setq articles (gnus-set-difference
1481                                        articles oldarts)))))))))))
1482   ;; return articles not deleted
1483   articles)
1484
1485 (deffoo nnimap-request-move-article (article group server
1486                                              accept-form &optional last)
1487   (when (nnimap-possibly-change-server server)
1488     (save-excursion
1489       (let ((buf (get-buffer-create " *nnimap move*"))
1490             (nnimap-current-move-article article)
1491             (nnimap-current-move-group group)
1492             (nnimap-current-move-server nnimap-current-server)
1493             result)
1494         (and (nnimap-request-article article group server)
1495              (save-excursion
1496                (set-buffer buf)
1497                (buffer-disable-undo (current-buffer))
1498                (insert-buffer-substring nntp-server-buffer)
1499                (setq result (eval accept-form))
1500                (kill-buffer buf)
1501                result)
1502              (imap-message-flags-add
1503               (imap-range-to-message-set (list article))
1504               "\\Deleted" 'silent nnimap-server-buffer))
1505         result))))
1506
1507 (deffoo nnimap-request-accept-article (group &optional server last)
1508   (when (nnimap-possibly-change-server server)
1509     (let (uid)
1510       (if (setq uid
1511                 (if (string= nnimap-current-server nnimap-current-move-server)
1512                     ;; moving article within same server, speed it up...
1513                     (and (nnimap-possibly-change-group
1514                           nnimap-current-move-group)
1515                          (imap-message-copy (number-to-string
1516                                              nnimap-current-move-article)
1517                                             group 'dontcreate nil
1518                                             nnimap-server-buffer))
1519                   (with-current-buffer (current-buffer)
1520                     (goto-char (point-min))
1521                     ;; remove any 'From blabla' lines, some IMAP servers
1522                     ;; reject the entire message otherwise.
1523                     (when (looking-at "^From[^:]")
1524                       (delete-region (point) (progn (forward-line) (point))))
1525                     ;; turn into rfc822 format (\r\n eol's)
1526                     (while (search-forward "\n" nil t)
1527                       (replace-match "\r\n"))
1528                     (when nnmail-cache-accepted-message-ids
1529                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1530                                            group
1531                                            (nnmail-fetch-field "subject"))))
1532                   (when (and last nnmail-cache-accepted-message-ids)
1533                     (nnmail-cache-close))
1534                   ;; this 'or' is for Cyrus server bug
1535                   (or (null (imap-current-mailbox nnimap-server-buffer))
1536                       (imap-mailbox-unselect nnimap-server-buffer))
1537                   (imap-message-append group (current-buffer) nil nil
1538                                        nnimap-server-buffer)))
1539           (cons group (nth 1 uid))
1540         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1541
1542 (deffoo nnimap-request-delete-group (group force &optional server)
1543   (when (nnimap-possibly-change-server server)
1544     (with-current-buffer nnimap-server-buffer
1545       (if force
1546           (or (null (imap-mailbox-status group 'uidvalidity))
1547               (imap-mailbox-delete group))
1548         ;; UNSUBSCRIBE?
1549         t))))
1550
1551 (deffoo nnimap-request-rename-group (group new-name &optional server)
1552   (when (nnimap-possibly-change-server server)
1553     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1554
1555 (defun nnimap-expunge (mailbox server)
1556   (when (nnimap-possibly-change-group mailbox server)
1557     (imap-mailbox-expunge nil nnimap-server-buffer)))
1558
1559 (defun nnimap-acl-get (mailbox server)
1560   (when (nnimap-possibly-change-server server)
1561     (and (imap-capability 'ACL nnimap-server-buffer)
1562          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1563
1564 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1565   (when (nnimap-possibly-change-server (cadr method))
1566     (unless (imap-capability 'ACL nnimap-server-buffer)
1567       (error "Your server does not support ACL editing"))
1568     (with-current-buffer nnimap-server-buffer
1569       ;; delete all removed identifiers
1570       (mapc (lambda (old-acl)
1571               (unless (assoc (car old-acl) new-acls)
1572                 (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1573                     (error "Can't delete ACL for %s" (car old-acl)))))
1574             old-acls)
1575       ;; set all changed acl's
1576       (mapc (lambda (new-acl)
1577               (let ((new-rights (cdr new-acl))
1578                     (old-rights (cdr (assoc (car new-acl) old-acls))))
1579                 (unless (and old-rights new-rights
1580                              (string= old-rights new-rights))
1581                   (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1582                       (error "Can't set ACL for %s to %s" (car new-acl)
1583                              new-rights)))))
1584             new-acls)
1585       t)))
1586
1587 \f
1588 ;;; Internal functions
1589
1590 ;;
1591 ;; This is confusing.
1592 ;;
1593 ;; mark      => read, tick, draft, reply etc
1594 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1595 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1596 ;;
1597 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1598 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1599 ;;
1600
1601 (defconst nnimap-mark-to-predicate-alist
1602   (mapcar
1603    (lambda (pair)                       ; cdr is the mark
1604      (or (assoc (cdr pair)
1605                 '((read . "SEEN")
1606                   (tick . "FLAGGED")
1607                   (draft . "DRAFT")
1608                   (recent . "RECENT")
1609                   (reply . "ANSWERED")))
1610          (cons (cdr pair)
1611                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1612    (cons '(read . read) gnus-article-mark-lists)))
1613
1614 (defun nnimap-mark-to-predicate (pred)
1615   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1616 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1617 to be used within a IMAP SEARCH query."
1618   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1619
1620 (defconst nnimap-mark-to-flag-alist
1621   (mapcar
1622    (lambda (pair)
1623      (or (assoc (cdr pair)
1624                 '((read . "\\Seen")
1625                   (tick . "\\Flagged")
1626                   (draft . "\\Draft")
1627                   (recent . "\\Recent")
1628                   (reply . "\\Answered")))
1629          (cons (cdr pair)
1630                (format "gnus-%s" (symbol-name (cdr pair))))))
1631    (cons '(read . read) gnus-article-mark-lists)))
1632
1633 (defun nnimap-mark-to-flag-1 (preds)
1634   (if (and (not (null preds)) (listp preds))
1635       (cons (nnimap-mark-to-flag (car preds))
1636             (nnimap-mark-to-flag (cdr preds)))
1637     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1638
1639 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1640   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1641 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1642 be used in a STORE FLAGS command."
1643   (let ((result (nnimap-mark-to-flag-1 preds)))
1644     (setq result (if (and (or make-string always-list)
1645                           (not (listp result)))
1646                      (list result)
1647                    result))
1648     (if make-string
1649         (mapconcat (lambda (flag)
1650                      (if (listp flag)
1651                          (mapconcat 'identity flag " ")
1652                        flag))
1653                    result " ")
1654       result)))
1655
1656 (defun nnimap-mark-permanent-p (mark &optional group)
1657   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1658   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1659
1660 (when nnimap-debug
1661   (require 'trace)
1662   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1663   (mapcar (lambda (f) (trace-function-background f nnimap-debug-buffer))
1664           '(
1665             nnimap-possibly-change-server
1666             nnimap-verify-uidvalidity
1667             nnimap-find-minmax-uid
1668             nnimap-before-find-minmax-bugworkaround
1669             nnimap-possibly-change-group
1670             ;;nnimap-replace-whitespace
1671             nnimap-retrieve-headers-progress
1672             nnimap-retrieve-which-headers
1673             nnimap-group-overview-filename
1674             nnimap-retrieve-headers-from-file
1675             nnimap-retrieve-headers-from-server
1676             nnimap-retrieve-headers
1677             nnimap-open-connection
1678             nnimap-open-server
1679             nnimap-server-opened
1680             nnimap-close-server
1681             nnimap-request-close
1682             nnimap-status-message
1683             ;;nnimap-demule
1684             nnimap-request-article-part
1685             nnimap-request-article
1686             nnimap-request-head
1687             nnimap-request-body
1688             nnimap-request-group
1689             nnimap-close-group
1690             nnimap-pattern-to-list-arguments
1691             nnimap-request-list
1692             nnimap-request-post
1693             nnimap-retrieve-groups
1694             nnimap-request-update-info-internal
1695             nnimap-request-type
1696             nnimap-request-set-mark
1697             nnimap-split-to-groups
1698             nnimap-split-find-rule
1699             nnimap-split-find-inbox
1700             nnimap-split-articles
1701             nnimap-request-scan
1702             nnimap-request-newgroups
1703             nnimap-request-create-group
1704             nnimap-time-substract
1705             nnimap-date-days-ago
1706             nnimap-request-expire-articles-progress
1707             nnimap-request-expire-articles
1708             nnimap-request-move-article
1709             nnimap-request-accept-article
1710             nnimap-request-delete-group
1711             nnimap-request-rename-group
1712             gnus-group-nnimap-expunge
1713             gnus-group-nnimap-edit-acl
1714             gnus-group-nnimap-edit-acl-done
1715             nnimap-group-mode-hook
1716             nnimap-mark-to-predicate
1717             nnimap-mark-to-flag-1
1718             nnimap-mark-to-flag
1719             nnimap-mark-permanent-p
1720             )))
1721
1722 (provide 'nnimap)
1723
1724 ;;; nnimap.el ends here