git.chise.org Git - elisp/gnus.git-/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   6 ;;         Jim Radford <radford@robby.caltech.edu>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Todo, major things:
  29 ;;
  30 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  31 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  32 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  33 ;;   o Sieve
  34 ;;   o MIME (partial article fetches)
  35 ;;   o Split to other backends, different split rules for different
  36 ;;     servers/inboxes
  37 ;;
  38 ;; Todo, minor things:
  39 ;;
  40 ;;   o Don't require half of Gnus -- backends should be standalone
  41 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  42 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  43 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  44 ;;   o What do I do with gnus-newsgroup-*?
  45 ;;   o Tell Gnus about new groups (how can we tell?)
  46 ;;   o Respooling (fix Gnus?) (unnecessary?)
  47 ;;   o Add support for the following: (if applicable)
  48 ;;       request-list-newsgroups, request-regenerate
  49 ;;       list-active-group,
  50 ;;       request-associate-buffer, request-restore-buffer,
  51 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  52 ;;   o Support RFC2221 (Login referrals)
  53 ;;   o IMAP2BIS compatibility? (RFC2061)
  54 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  55 ;;     .newsrc.eld)
  56 ;;   o What about Gnus's article editing, can we support it?  NO!
  57 ;;   o Use \Draft to support the draft group??
  58 ;;   o Duplicate suppression
  59 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  60
  61 ;;; Code:
  62
  63 (eval-when-compile (require 'cl))
  64 (require 'imap)
  65
  66 (require 'nnoo)
  67 (require 'nnmail)
  68 (require 'nnheader)
  69 (require 'gnus)
  70 (require 'gnus-range)
  71 (require 'gnus-start)
  72 (require 'gnus-int)
  73
  74 (eval-when-compile (require 'cl))
  75
  76 (nnoo-declare nnimap)
  77
  78 (defconst nnimap-version "nnimap 1.0")
  79
  80 (defgroup nnimap nil
  81   "Reading IMAP mail with Gnus."
  82   :group 'gnus)
  83
  84 (defvoo nnimap-address nil
  85   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  86
  87 (defvoo nnimap-server-port nil
  88   "Port number on physical IMAP server.
  89 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  90
  91 ;; Splitting variables
  92
  93 (defcustom nnimap-split-crosspost t
  94   "If non-nil, do crossposting if several split methods match the mail.
  95 If nil, the first match found will be used."
  96   :group 'nnimap
  97   :type 'boolean)
  98
  99 (defcustom nnimap-split-inbox nil
 100   "Name of mailbox to split mail from.
 101
 102 Mail is read from this mailbox and split according to rules in
 103 `nnimap-split-rule'.
 104
 105 This can be a string or a list of strings."
 106   :group 'nnimap
 107   :type '(choice (string)
 108                  (repeat string)))
 109
 110 (define-widget 'nnimap-strict-function 'function
 111   "This widget only matches values that are functionp.
 112
 113 Warning: This means that a value that is the symbol of a not yet
 114 loaded function will not match.  Use with care."
 115   :match 'nnimap-strict-function-match)
 116
 117 (defun nnimap-strict-function-match (widget value)
 118   "Ignoring WIDGET, match if VALUE is a function."
 119   (functionp value))
 120
 121 (defcustom nnimap-split-rule nil
 122   "Mail will be split according to these rules.
 123
 124 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 125
 126 If you'd like, for instance, one mail group for mail from the
 127 \"gnus-imap\" mailing list, one group for junk mail and leave
 128 everything else in the incoming mailbox, you could do something like
 129 this:
 130
 131 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 132                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 133
 134 As you can see, `nnimap-split-rule' is a list of lists, where the
 135 first element in each \"rule\" is the name of the IMAP mailbox (or the
 136 symbol `junk' if you want to remove the mail), and the second is a
 137 regexp that nnimap will try to match on the header to find a fit.
 138
 139 The second element can also be a function.  In that case, it will be
 140 called narrowed to the headers with the first element of the rule as
 141 the argument.  It should return a non-nil value if it thinks that the
 142 mail belongs in that group.
 143
 144 This variable can also have a function as its value, the function will
 145 be called with the headers narrowed and should return a group where it
 146 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 147
 148 To allow for different split rules on different virtual servers, and
 149 even different split rules in different inboxes on the same server,
 150 the syntax of this variable have been extended along the lines of:
 151
 152 \(setq nnimap-split-rule
 153       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 154                                   (\"junk\"    \"From:.*Simon\")))
 155         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 156         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 157                                   (\"junk\"    my-junk-func)))))
 158
 159 The virtual server name is in fact a regexp, so that the same rules
 160 may apply to several servers.  In the example, the servers
 161 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 162 the inbox string is also a regexp.  The actual splitting rules are as
 163 before, either a function, or a list with group/regexp or
 164 group/function elements."
 165   :group 'nnimap
 166   :type '(choice :tag "Rule type"
 167                  (repeat :menu-tag "Single-server"
 168                          :tag "Single-server list"
 169                          (list (string :tag "Mailbox")
 170                                (choice :tag "Predicate"
 171                                        (regexp :tag "A regexp")
 172                                        (nnimap-strict-function :tag "A function"))))
 173                  (choice :menu-tag "A function"
 174                          :tag "A function"
 175                          (function-item nnimap-split-fancy)
 176                          (function-item nnmail-split-fancy)
 177                          (nnimap-strict-function :tag "User-defined function"))
 178                  (repeat :menu-tag "Multi-server (extended)"
 179                          :tag "Multi-server list"
 180                          (list (regexp :tag "Server regexp")
 181                                (list (regexp :tag "Incoming Mailbox regexp")
 182                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 183                                              (list (string :tag "Destination mailbox")
 184                                                    (choice :tag "Predicate"
 185                                                            (regexp :tag "A Regexp")
 186                                                            (nnimap-strict-function :tag "A Function")))))))))
 187
 188 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 189   "The predicate used to find articles to split.
 190 If you use another IMAP client to peek on articles but always would
 191 like nnimap to split them once it's started, you could change this to
 192 \"UNDELETED\". Other available predicates are available in
 193 RFC2060 section 6.4.4."
 194   :group 'nnimap
 195   :type 'string)
 196
 197 (defcustom nnimap-split-fancy nil
 198   "Like the variable `nnmail-split-fancy'."
 199   :group 'nnimap
 200   :type 'sexp)
 201
 202 (defvar nnimap-split-download-body-default nil
 203   "Internal variable with default value for `nnimap-split-download-body'.")
 204
 205 (defcustom nnimap-split-download-body 'default
 206   "Whether to download entire articles during splitting.
 207 This is generally not required, and will slow things down considerably.
 208 You may need it if you want to use an advanced splitting function that
 209 analyses the body before splitting the article.
 210 If this variable is nil, bodies will not be downloaded; if this
 211 variable is the symbol `default' the default behaviour is
 212 used (which currently is nil, unless you use a statistical
 213 spam.el test); if this variable is another non-nil value bodies
 214 will be downloaded."
 215   :group 'nnimap
 216   :type '(choice (const :tag "Let system decide" deault)
 217                  boolean))
 218
 219 ;; Performance / bug workaround variables
 220
 221 (defcustom nnimap-close-asynchronous t
 222   "Close mailboxes asynchronously in `nnimap-close-group'.
 223 This means that errors cought by nnimap when closing the mailbox will
 224 not prevent Gnus from updating the group status, which may be harmful.
 225 However, it increases speed."
 226   :type 'boolean
 227   :group 'nnimap)
 228
 229 (defcustom nnimap-dont-close t
 230   "Never close mailboxes.
 231 This increases the speed of closing mailboxes (quiting group) but may
 232 decrease the speed of selecting another mailbox later.  Re-selecting
 233 the same mailbox will be faster though."
 234   :type 'boolean
 235   :group 'nnimap)
 236
 237 (defcustom nnimap-retrieve-groups-asynchronous t
 238   "Send asynchronous STATUS commands for each mailbox before checking mail.
 239 If you have mailboxes that rarely receives mail, this speeds up new
 240 mail checking.  It works by first sending STATUS commands for each
 241 mailbox, and then only checking groups which has a modified UIDNEXT
 242 more carefully for new mail.
 243
 244 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 245 it O(n).  If p is small, then the default is probably faster."
 246   :type 'boolean
 247   :group 'nnimap)
 248
 249 (defvoo nnimap-need-unselect-to-notice-new-mail nil
 250   "Unselect mailboxes before looking for new mail in them.
 251 Some servers seem to need this under some circumstances.")
 252
 253 ;; Authorization / Privacy variables
 254
 255 (defvoo nnimap-auth-method nil
 256   "Obsolete.")
 257
 258 (defvoo nnimap-stream nil
 259   "How nnimap will connect to the server.
 260
 261 The default, nil, will try to use the \"best\" method the server can
 262 handle.
 263
 264 Change this if
 265
 266 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 267    with IMAP is suboptimal so you'll have to tell it
 268    specifically.
 269
 270 2) your server is more capable than your environment -- i.e. your
 271    server accept Kerberos login's but you haven't installed the
 272    `imtest' program or your machine isn't configured for Kerberos.
 273
 274 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 275 See also `imap-streams' and `imap-stream-alist'.")
 276
 277 (defvoo nnimap-authenticator nil
 278   "How nnimap authenticate itself to the server.
 279
 280 The default, nil, will try to use the \"best\" method the server can
 281 handle.
 282
 283 There is only one reason for fiddling with this variable, and that is
 284 if your server is more capable than your environment -- i.e. you
 285 connect to a server that accept Kerberos login's but you haven't
 286 installed the `imtest' program or your machine isn't configured for
 287 Kerberos.
 288
 289 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 290 See also `imap-authenticators' and `imap-authenticator-alist'")
 291
 292 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 293   "Directory to keep NOV cache files for nnimap groups.
 294 See also `nnimap-nov-file-name'.")
 295
 296 (defvoo nnimap-nov-file-name "nnimap."
 297   "NOV cache base filename.
 298 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 299 typical complete file name would be
 300 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 301 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 302 `nnmail-use-long-file-names' is nil")
 303
 304 (defvoo nnimap-nov-file-name-suffix ".novcache"
 305   "Suffix for NOV cache base filename.")
 306
 307 (defvoo nnimap-nov-is-evil gnus-agent
 308   "If non-nil, never generate or use a local nov database for this backend.
 309 Using nov databases should speed up header fetching considerably.
 310 However, it will invoke a UID SEARCH UID command on the server, and
 311 some servers implement this command inefficiently by opening each and
 312 every message in the group, thus making it quite slow.
 313 Unlike other backends, you do not need to take special care if you
 314 flip this variable.")
 315
 316 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 317   "Whether to expunge a group when it is closed.
 318 When a IMAP group with articles marked for deletion is closed, this
 319 variable determine if nnimap should actually remove the articles or
 320 not.
 321
 322 If always, nnimap always perform a expunge when closing the group.
 323 If never, nnimap never expunges articles marked for deletion.
 324 If ask, nnimap will ask you if you wish to expunge marked articles.
 325
 326 When setting this variable to `never', you can only expunge articles
 327 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 328
 329 (defvoo nnimap-list-pattern "*"
 330   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 331 See below for available wildcards.
 332
 333 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 334 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 335 semantics of this are server specific, on the University of Washington
 336 server you can specify a directory.
 337
 338 Example:
 339  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 340
 341 There are two wildcards * and %. * matches everything, % matches
 342 everything in the current hierarchy.")
 343
 344 (defvoo nnimap-news-groups nil
 345   "IMAP support a news-like mode, also known as bulletin board mode,
 346 where replies is sent via IMAP instead of SMTP.
 347
 348 This variable should contain a regexp matching groups where you wish
 349 replies to be stored to the mailbox directly.
 350
 351 Example:
 352   '(\"^[^I][^N][^B][^O][^X].*$\")
 353
 354 This will match all groups not beginning with \"INBOX\".
 355
 356 Note that there is nothing technically different between mail-like and
 357 news-like mailboxes.  If you wish to have a group with todo items or
 358 similar which you wouldn't want to set up a mailing list for, you can
 359 use this to make replies go directly to the group.")
 360
 361 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 362   "IMAP search command to use for articles that are to be expired.
 363 The first %s is replaced by a UID set of articles to search on,
 364 and the second %s is replaced by a date criterium.
 365
 366 One useful (and perhaps the only useful) value to change this to would
 367 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 368 instead of the internal date of messages.  See section 6.4.4 of RFC
 369 2060 for more information on valid strings.")
 370
 371 (defvoo nnimap-importantize-dormant t
 372   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 373 Note that within Gnus, dormant articles will still (only) be
 374 marked as ticked.  This is to make \"dormant\" articles stand out,
 375 just like \"ticked\" articles, in other IMAP clients.")
 376
 377 (defvoo nnimap-server-address nil
 378   "Obsolete.  Use `nnimap-address'.")
 379
 380 (defcustom nnimap-authinfo-file "~/.authinfo"
 381   "Authorization information for IMAP servers.  In .netrc format."
 382   :type
 383   '(choice file
 384            (repeat :tag "Entries"
 385                    :menu-tag "Inline"
 386                    (list :format "%v"
 387                          :value ("" ("login" . "") ("password" . ""))
 388                          (string :tag "Host")
 389                          (checklist :inline t
 390                                     (cons :format "%v"
 391                                           (const :format "" "login")
 392                                           (string :format "Login: %v"))
 393                                     (cons :format "%v"
 394                                           (const :format "" "password")
 395                                           (string :format "Password: %v")))))))
 396
 397 (defcustom nnimap-prune-cache t
 398   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 399   :type 'boolean)
 400
 401 (defvar nnimap-request-list-method 'imap-mailbox-list
 402   "Method to use to request a list of all folders from the server.
 403 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 404 restrict visible folders.")
 405
 406 (defcustom nnimap-id nil
 407   "Plist with client identity to send to server upon login.
 408 Nil means no information is sent, symbol `no' to disable ID query
 409 alltogheter, or plist with identifier-value pairs to send to
 410 server.  RFC 2971 describes the list as follows:
 411
 412    Any string may be sent as a field, but the following are defined to
 413    describe certain values that might be sent.  Implementations are free
 414    to send none, any, or all of these.  Strings are not case-sensitive.
 415    Field strings MUST NOT be longer than 30 octets.  Value strings MUST
 416    NOT be longer than 1024 octets.  Implementations MUST NOT send more
 417    than 30 field-value pairs.
 418
 419      name            Name of the program
 420      version         Version number of the program
 421      os              Name of the operating system
 422      os-version      Version of the operating system
 423      vendor          Vendor of the client/server
 424      support-url     URL to contact for support
 425      address         Postal address of contact/vendor
 426      date            Date program was released, specified as a date-time
 427                        in IMAP4rev1
 428      command         Command used to start the program
 429      arguments       Arguments supplied on the command line, if any
 430                        if any
 431      environment     Description of environment, i.e., UNIX environment
 432                        variables or Windows registry settings
 433
 434    Implementations MUST NOT send the same field name more than once.
 435
 436 An example plist would be '(\"name\" \"Gnus\" \"version\" gnus-version-number
 437 \"os\" system-configuration \"vendor\" \"GNU\")."
 438   :group 'nnimap
 439   :type '(choice (const :tag "No information" nil)
 440                  (const :tag "Disable ID query" no)
 441                  (plist :key-type string :value-type string)))
 442
 443 (defcustom nnimap-debug nil
 444   "If non-nil, random debug spews are placed in *nnimap-debug* buffer."
 445   :group 'nnimap
 446   :type 'boolean)
 447
 448 ;; Internal variables:
 449
 450 (defvar nnimap-debug-buffer "*nnimap-debug*")
 451 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 452 (defvar nnimap-current-move-server nil)
 453 (defvar nnimap-current-move-group nil)
 454 (defvar nnimap-current-move-article nil)
 455 (defvar nnimap-length)
 456 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 457 (defvar nnimap-progress-how-often 20)
 458 (defvar nnimap-counter)
 459 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 460 (defvar nnimap-current-server nil)      ;; Current server
 461 (defvar nnimap-server-buffer nil)       ;; Current servers' buffer
 462
 463 \f
 464
 465 (nnoo-define-basics nnimap)
 466
 467 ;; Utility functions:
 468
 469 (defsubst nnimap-get-server-buffer (server)
 470   "Return buffer for SERVER, if nil use current server."
 471   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 472
 473 (defun nnimap-possibly-change-server (server)
 474   "Return buffer for SERVER, changing the current server as a side-effect.
 475 If SERVER is nil, uses the current server."
 476   (setq nnimap-current-server (or server nnimap-current-server)
 477         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 478
 479 (defun nnimap-verify-uidvalidity (group server)
 480   "Verify stored uidvalidity match current one in GROUP on SERVER."
 481   (let* ((gnusgroup (gnus-group-prefixed-name
 482                      group (gnus-server-to-method
 483                             (format "nnimap:%s" server))))
 484          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 485          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 486          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 487          (nameuid (nnheader-translate-file-chars
 488                    (concat nnimap-nov-file-name
 489                            (if (equal server "")
 490                                "unnamed"
 491                              server) "." group "." old-uidvalidity
 492                              nnimap-nov-file-name-suffix) t))
 493          (file (if (or nnmail-use-long-file-names
 494                        (file-exists-p (expand-file-name nameuid dir)))
 495                    (expand-file-name nameuid dir)
 496                  (expand-file-name
 497                   (encode-coding-string
 498                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 499                    nnmail-pathname-coding-system)
 500                   dir))))
 501     (if old-uidvalidity
 502         (if (not (equal old-uidvalidity new-uidvalidity))
 503             ;; uidvalidity clash
 504             (gnus-delete-file file)
 505           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 506           t)
 507       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 508       t)))
 509
 510 (defun nnimap-before-find-minmax-bugworkaround ()
 511   "Function called before iterating through mailboxes with
 512 `nnimap-find-minmax-uid'."
 513   (when nnimap-need-unselect-to-notice-new-mail
 514     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 515     ;; currently selected mailbox without a re-select/examine.
 516     (or (null (imap-current-mailbox nnimap-server-buffer))
 517         (imap-mailbox-unselect nnimap-server-buffer))))
 518
 519 (defun nnimap-find-minmax-uid (group &optional examine)
 520   "Find lowest and highest active article number in GROUP.
 521 If EXAMINE is non-nil the group is selected read-only."
 522   (with-current-buffer nnimap-server-buffer
 523     (when (or (string= group (imap-current-mailbox))
 524               (imap-mailbox-select group examine))
 525       (let (minuid maxuid)
 526         (when (> (imap-mailbox-get 'exists) 0)
 527           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 528           (imap-message-map (lambda (uid Uid)
 529                               (setq minuid (if minuid (min minuid uid) uid)
 530                                     maxuid (if maxuid (max maxuid uid) uid)))
 531                             'UID))
 532         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 533
 534 (defun nnimap-possibly-change-group (group &optional server)
 535   "Make GROUP the current group, and SERVER the current server."
 536   (when (nnimap-possibly-change-server server)
 537     (with-current-buffer nnimap-server-buffer
 538       (if (or (null group) (imap-current-mailbox-p group))
 539           imap-current-mailbox
 540         (if (imap-mailbox-select group)
 541             (if (or (nnimap-verify-uidvalidity
 542                      group (or server nnimap-current-server))
 543                     (zerop (imap-mailbox-get 'exists group))
 544                     t ;; for OGnus to see if ignoring uidvalidity
 545                       ;; changes has any bad effects.
 546                     (yes-or-no-p
 547                      (format
 548                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 549                 imap-current-mailbox
 550               (imap-mailbox-unselect)
 551               (error "nnimap: Group %s is not uid-valid" group))
 552           (nnheader-report 'nnimap (imap-error-text)))))))
 553
 554 (defun nnimap-replace-whitespace (string)
 555   "Return STRING with all whitespace replaced with space."
 556   (when string
 557     (while (string-match "[\r\n\t]+" string)
 558       (setq string (replace-match " " t t string)))
 559     string))
 560
 561 ;; Required backend functions
 562
 563 (defun nnimap-retrieve-headers-progress ()
 564   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 565   (and (numberp nnmail-large-newsgroup)
 566        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 567        (> nnimap-length nnmail-large-newsgroup)
 568        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 569                          (nth (/ (% nnimap-counter
 570                                     (* (length nnimap-progress-chars)
 571                                        nnimap-progress-how-often))
 572                                  nnimap-progress-how-often)
 573                               nnimap-progress-chars)))
 574   (with-current-buffer nntp-server-buffer
 575     (let (headers lines chars uid mbx)
 576       (with-current-buffer nnimap-server-buffer
 577         (setq uid imap-current-message
 578               mbx imap-current-mailbox
 579               headers (nnimap-demule
 580                        (if (imap-capability 'IMAP4rev1)
 581                            ;; xxx don't just use car? alist doesn't contain
 582                            ;; anything else now, but it might...
 583                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 584                          (imap-message-get uid 'RFC822.HEADER)))
 585               lines (imap-body-lines (imap-message-body imap-current-message))
 586               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 587       (nnheader-insert-nov
 588        (with-temp-buffer
 589          (buffer-disable-undo)
 590          (insert headers)
 591          (let ((head (nnheader-parse-naked-head)))
 592            (mail-header-set-number head uid)
 593            (mail-header-set-chars head chars)
 594            (mail-header-set-lines head lines)
 595            (mail-header-set-xref
 596             head (format "%s %s:%d" (system-name) mbx uid))
 597            head))))))
 598
 599 (defun nnimap-retrieve-which-headers (articles fetch-old)
 600   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 601   (with-current-buffer nnimap-server-buffer
 602     (if (numberp (car-safe articles))
 603         (imap-search
 604          (concat "UID "
 605                  (imap-range-to-message-set
 606                   (gnus-compress-sequence
 607                    (append (gnus-uncompress-sequence
 608                             (and fetch-old
 609                                  (cons (if (numberp fetch-old)
 610                                            (max 1 (- (car articles) fetch-old))
 611                                          1)
 612                                        (1- (car articles)))))
 613                            articles)))))
 614       (mapcar (lambda (msgid)
 615                 (imap-search
 616                  (format "HEADER Message-Id \"%s\"" msgid)))
 617               articles))))
 618
 619 (defun nnimap-group-overview-filename (group server)
 620   "Make file name for GROUP on SERVER."
 621   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 622          (uidvalidity (gnus-group-get-parameter
 623                        (gnus-group-prefixed-name
 624                         group (gnus-server-to-method
 625                                (format "nnimap:%s" server)))
 626                        'uidvalidity))
 627          (name (nnheader-translate-file-chars
 628                 (concat nnimap-nov-file-name
 629                         (if (equal server "")
 630                             "unnamed"
 631                           server) "." group nnimap-nov-file-name-suffix) t))
 632          (nameuid (nnheader-translate-file-chars
 633                    (concat nnimap-nov-file-name
 634                            (if (equal server "")
 635                                "unnamed"
 636                              server) "." group "." uidvalidity
 637                              nnimap-nov-file-name-suffix) t))
 638          (oldfile (if (or nnmail-use-long-file-names
 639                           (file-exists-p (expand-file-name name dir)))
 640                       (expand-file-name name dir)
 641                     (expand-file-name
 642                      (encode-coding-string
 643                       (nnheader-replace-chars-in-string name ?. ?/)
 644                       nnmail-pathname-coding-system)
 645                      dir)))
 646          (newfile (if (or nnmail-use-long-file-names
 647                           (file-exists-p (expand-file-name nameuid dir)))
 648                       (expand-file-name nameuid dir)
 649                     (expand-file-name
 650                      (encode-coding-string
 651                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 652                       nnmail-pathname-coding-system)
 653                      dir))))
 654     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 655       (message "nnimap: Upgrading novcache filename...")
 656       (sit-for 1)
 657       (gnus-make-directory (file-name-directory newfile))
 658       (unless (ignore-errors (rename-file oldfile newfile) t)
 659         (if (ignore-errors (copy-file oldfile newfile) t)
 660             (delete-file oldfile)
 661           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 662     newfile))
 663
 664 (defun nnimap-retrieve-headers-from-file (group server)
 665   (with-current-buffer nntp-server-buffer
 666     (let ((nov (nnimap-group-overview-filename group server)))
 667       (when (file-exists-p nov)
 668         (nnheader-insert-file-contents nov)
 669         (set-buffer-modified-p nil)
 670         (let ((min (ignore-errors (goto-char (point-min))
 671                                   (read (current-buffer))))
 672               (max (ignore-errors (goto-char (point-max))
 673                                   (forward-line -1)
 674                                   (read (current-buffer)))))
 675           (if (and (numberp min) (numberp max))
 676               (cons min max)
 677             ;; junk, remove it, it's saved later
 678             (erase-buffer)
 679             nil))))))
 680
 681 (defun nnimap-retrieve-headers-from-server (articles group server)
 682   (with-current-buffer nnimap-server-buffer
 683     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 684           (nnimap-length (gnus-range-length articles))
 685           (nnimap-counter 0))
 686       (imap-fetch (imap-range-to-message-set articles)
 687                   (concat "(UID RFC822.SIZE BODY "
 688                           (let ((headers
 689                                  (append '(Subject From Date Message-Id
 690                                                    References In-Reply-To Xref)
 691                                          (copy-sequence
 692                                           nnmail-extra-headers))))
 693                             (if (imap-capability 'IMAP4rev1)
 694                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 695                               (format "RFC822.HEADER.LINES %s)" headers)))))
 696       (and (numberp nnmail-large-newsgroup)
 697            (> nnimap-length nnmail-large-newsgroup)
 698            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 699
 700 (defun nnimap-dont-use-nov-p (group server)
 701   (or gnus-nov-is-evil nnimap-nov-is-evil
 702       (unless (and (gnus-make-directory
 703                     (file-name-directory
 704                      (nnimap-group-overview-filename group server)))
 705                    (file-writable-p
 706                     (nnimap-group-overview-filename group server)))
 707         (message "nnimap: Nov cache not writable, %s"
 708                  (nnimap-group-overview-filename group server)))))
 709
 710 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 711   (when (nnimap-possibly-change-group group server)
 712     (with-current-buffer nntp-server-buffer
 713       (erase-buffer)
 714       (if (nnimap-dont-use-nov-p group server)
 715           (nnimap-retrieve-headers-from-server
 716            (gnus-compress-sequence articles) group server)
 717         (let (uids cached low high)
 718           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 719                       low (car uids)
 720                       high (car (last uids)))
 721             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 722                 (progn
 723                   ;; fetch articles with uids before cache block
 724                   (when (< low (car cached))
 725                     (goto-char (point-min))
 726                     (nnimap-retrieve-headers-from-server
 727                      (cons low (1- (car cached))) group server))
 728                   ;; fetch articles with uids after cache block
 729                   (when (> high (cdr cached))
 730                     (goto-char (point-max))
 731                     (nnimap-retrieve-headers-from-server
 732                      (cons (1+ (cdr cached)) high) group server))
 733                   (when nnimap-prune-cache
 734                     ;; remove nov's for articles which has expired on server
 735                     (goto-char (point-min))
 736                     (dolist (uid (gnus-set-difference articles uids))
 737                       (when (re-search-forward (format "^%d\t" uid) nil t)
 738                         (gnus-delete-line)))))
 739               ;; nothing cached, fetch whole range from server
 740               (nnimap-retrieve-headers-from-server
 741                (cons low high) group server))
 742             (when (buffer-modified-p)
 743               (nnmail-write-region
 744                (point-min) (point-max)
 745                (nnimap-group-overview-filename group server) nil 'nomesg))
 746             (nnheader-nov-delete-outside-range low high))))
 747       'nov)))
 748
 749 (defun nnimap-open-connection (server)
 750   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 751                       nnimap-authenticator nnimap-server-buffer))
 752       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 753     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 754                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 755       (imap-close nnimap-server-buffer)
 756       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 757     (let* ((list (gnus-parse-netrc nnimap-authinfo-file))
 758            (port (if nnimap-server-port
 759                      (int-to-string nnimap-server-port)
 760                    "imap"))
 761            (alist (or (gnus-netrc-machine list server port "imap")
 762                       (gnus-netrc-machine list
 763                                           (or nnimap-server-address
 764                                               nnimap-address)
 765                                           port "imap")))
 766            (user (gnus-netrc-get alist "login"))
 767            (passwd (gnus-netrc-get alist "password")))
 768       (if (imap-authenticate user passwd nnimap-server-buffer)
 769           (prog1
 770               (push (list server nnimap-server-buffer)
 771                     nnimap-server-buffer-alist)
 772             (imap-id nnimap-id nnimap-server-buffer)
 773             (nnimap-possibly-change-server server))
 774         (imap-close nnimap-server-buffer)
 775         (kill-buffer nnimap-server-buffer)
 776         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 777
 778 (deffoo nnimap-open-server (server &optional defs)
 779   (nnheader-init-server-buffer)
 780   (if (nnimap-server-opened server)
 781       t
 782     (unless (assq 'nnimap-server-buffer defs)
 783       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 784     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 785     ;; for people that configured nnimap with a very old version
 786     (unless (assq 'nnimap-address defs)
 787       (if (assq 'nnimap-server-address defs)
 788           (push (list 'nnimap-address
 789                       (cadr (assq 'nnimap-server-address defs))) defs)
 790         (push (list 'nnimap-address server) defs)))
 791     (nnoo-change-server 'nnimap server defs)
 792     (or nnimap-server-buffer
 793         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 794     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 795       (nnoo-change-server 'nnimap server defs))
 796     (or (and nnimap-server-buffer
 797              (imap-opened nnimap-server-buffer)
 798              (if (with-current-buffer nnimap-server-buffer
 799                    (memq imap-state '(auth select examine)))
 800                  t
 801                (imap-close nnimap-server-buffer)
 802                (nnimap-open-connection server)))
 803         (nnimap-open-connection server))))
 804
 805 (deffoo nnimap-server-opened (&optional server)
 806   "Whether SERVER is opened.
 807 If SERVER is the current virtual server, and the connection to the
 808 physical server is alive, this function return a non-nil value.  If
 809 SERVER is nil, it is treated as the current server."
 810   ;; clean up autologouts??
 811   (and (or server nnimap-current-server)
 812        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 813        (imap-opened (nnimap-get-server-buffer server))))
 814
 815 (deffoo nnimap-close-server (&optional server)
 816   "Close connection to server and free all resources connected to it.
 817 Return nil if the server couldn't be closed for some reason."
 818   (let ((server (or server nnimap-current-server)))
 819     (when (or (nnimap-server-opened server)
 820               (imap-opened (nnimap-get-server-buffer server)))
 821       (imap-close (nnimap-get-server-buffer server))
 822       (kill-buffer (nnimap-get-server-buffer server))
 823       (setq nnimap-server-buffer nil
 824             nnimap-current-server nil
 825             nnimap-server-buffer-alist
 826             (delq server nnimap-server-buffer-alist)))
 827     (nnoo-close-server 'nnimap server)))
 828
 829 (deffoo nnimap-request-close ()
 830   "Close connection to all servers and free all resources that the backend have reserved.
 831 All buffers that have been created by that
 832 backend should be killed.  (Not the nntp-server-buffer, though.) This
 833 function is generally only called when Gnus is shutting down."
 834   (mapcar (lambda (server) (nnimap-close-server (car server)))
 835           nnimap-server-buffer-alist)
 836   (setq nnimap-server-buffer-alist nil))
 837
 838 (deffoo nnimap-status-message (&optional server)
 839   "This function returns the last error message from server."
 840   (when (nnimap-possibly-change-server server)
 841     (nnoo-status-message 'nnimap server)))
 842
 843 (defun nnimap-demule (string)
 844   (funcall (if (and (fboundp 'string-as-multibyte)
 845                     (subrp (symbol-function 'string-as-multibyte)))
 846                'string-as-multibyte
 847              'identity)
 848            (or string "")))
 849
 850 (defun nnimap-make-callback (article gnus-callback buffer)
 851   "Return a callback function."
 852   `(lambda ()
 853      (nnimap-callback ,article ,gnus-callback ,buffer)))
 854
 855 (defun nnimap-callback (article gnus-callback buffer)
 856   (when (eq article (imap-current-message))
 857     (remove-hook 'imap-fetch-data-hook
 858                  (nnimap-make-callback article gnus-callback buffer))
 859     (with-current-buffer buffer
 860       (insert
 861        (with-current-buffer nnimap-server-buffer
 862          (nnimap-demule
 863           (if (imap-capability 'IMAP4rev1)
 864               ;; xxx don't just use car? alist doesn't contain
 865               ;; anything else now, but it might...
 866               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 867             (imap-message-get article 'RFC822)))))
 868       (nnheader-ms-strip-cr)
 869       (funcall gnus-callback t))))
 870
 871 (defun nnimap-request-article-part (article part prop &optional
 872                                             group server to-buffer detail)
 873   (when (nnimap-possibly-change-group group server)
 874     (let ((article (if (stringp article)
 875                        (car-safe (imap-search
 876                                   (format "HEADER Message-Id \"%s\"" article)
 877                                   nnimap-server-buffer))
 878                      article)))
 879       (when article
 880         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 881                       article (or group imap-current-mailbox
 882                                   gnus-newsgroup-name))
 883         (if (not nnheader-callback-function)
 884             (with-current-buffer (or to-buffer nntp-server-buffer)
 885               (erase-buffer)
 886               (let ((data (imap-fetch article part prop nil
 887                                       nnimap-server-buffer)))
 888                 (when data
 889                   (insert (nnimap-demule (if detail (nth 2 (car data)) data)))
 890                   (nnheader-ms-strip-cr)
 891                   (gnus-message
 892                    10 "nnimap: Fetching (part of) article %d from %s...done"
 893                    article (or group imap-current-mailbox gnus-newsgroup-name))
 894                   (if (bobp)
 895                       (nnheader-report 'nnimap "No such article %d in %s: %s"
 896                                        article (or group imap-current-mailbox
 897                                                    gnus-newsgroup-name)
 898                                        (imap-error-text nnimap-server-buffer))
 899                     (cons group article)))))
 900           (add-hook 'imap-fetch-data-hook
 901                     (nnimap-make-callback article
 902                                           nnheader-callback-function
 903                                           nntp-server-buffer))
 904           (imap-fetch-asynch article part nil nnimap-server-buffer)
 905           (cons group article))))))
 906
 907 (deffoo nnimap-asynchronous-p ()
 908   t)
 909
 910 (deffoo nnimap-request-article (article &optional group server to-buffer)
 911   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 912       (nnimap-request-article-part
 913        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 914     (nnimap-request-article-part
 915      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 916
 917 (deffoo nnimap-request-head (article &optional group server to-buffer)
 918   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 919       (nnimap-request-article-part
 920        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 921     (nnimap-request-article-part
 922      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 923
 924 (deffoo nnimap-request-body (article &optional group server to-buffer)
 925   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 926       (nnimap-request-article-part
 927        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 928     (nnimap-request-article-part
 929      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 930
 931 (deffoo nnimap-request-group (group &optional server fast)
 932   (nnimap-request-update-info-internal
 933    group
 934    (gnus-get-info (gnus-group-prefixed-name
 935                    group (gnus-server-to-method (format "nnimap:%s" server))))
 936    server)
 937   (when (nnimap-possibly-change-group group server)
 938     (nnimap-before-find-minmax-bugworkaround)
 939     (let (info)
 940       (cond (fast group)
 941             ((null (setq info (nnimap-find-minmax-uid group t)))
 942              (nnheader-report 'nnimap "Could not get active info for %s"
 943                               group))
 944             (t
 945              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 946                               (max 1 (or (nth 1 info) 1))
 947                               (or (nth 2 info) 0) group)
 948              (nnheader-report 'nnimap "Group %s selected" group)
 949              t)))))
 950
 951 (defun nnimap-update-unseen (group &optional server)
 952   "Update the unseen count in `nnimap-mailbox-info'."
 953   (gnus-sethash
 954    (gnus-group-prefixed-name group server)
 955    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
 956                                  nnimap-mailbox-info)))
 957      (list (nth 0 old) (nth 1 old)
 958            (imap-mailbox-status group 'unseen nnimap-server-buffer)
 959            (nth 3 old)))
 960    nnimap-mailbox-info))
 961
 962 (defun nnimap-close-group (group &optional server)
 963   (with-current-buffer nnimap-server-buffer
 964     (when (and (imap-opened)
 965                (nnimap-possibly-change-group group server))
 966       (nnimap-update-unseen group server)
 967       (case nnimap-expunge-on-close
 968         (always (progn
 969                   (imap-mailbox-expunge nnimap-close-asynchronous)
 970                   (unless nnimap-dont-close
 971                     (imap-mailbox-close nnimap-close-asynchronous))))
 972         (ask (if (and (imap-search "DELETED")
 973                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
 974                                              imap-current-mailbox)))
 975                  (progn
 976                    (imap-mailbox-expunge nnimap-close-asynchronous)
 977                    (unless nnimap-dont-close
 978                      (imap-mailbox-close nnimap-close-asynchronous)))
 979                (imap-mailbox-unselect)))
 980         (t (imap-mailbox-unselect)))
 981       (not imap-current-mailbox))))
 982
 983 (defun nnimap-pattern-to-list-arguments (pattern)
 984   (mapcar (lambda (p)
 985             (cons (car-safe p) (or (cdr-safe p) p)))
 986           (if (and (listp pattern)
 987                    (listp (cdr pattern)))
 988               pattern
 989             (list pattern))))
 990
 991 (deffoo nnimap-request-list (&optional server)
 992   (when (nnimap-possibly-change-server server)
 993     (with-current-buffer nntp-server-buffer
 994       (erase-buffer))
 995     (gnus-message 5 "nnimap: Generating active list%s..."
 996                   (if (> (length server) 0) (concat " for " server) ""))
 997     (nnimap-before-find-minmax-bugworkaround)
 998     (with-current-buffer nnimap-server-buffer
 999       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
1000         (dolist (mbx (funcall nnimap-request-list-method
1001                               (cdr pattern) (car pattern)))
1002           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
1003               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1004                 (when info
1005                   (with-current-buffer nntp-server-buffer
1006                     (insert (format "\"%s\" %d %d y\n"
1007                                     mbx (or (nth 2 info) 0)
1008                                     (max 1 (or (nth 1 info) 1)))))))))))
1009     (gnus-message 5 "nnimap: Generating active list%s...done"
1010                   (if (> (length server) 0) (concat " for " server) ""))
1011     t))
1012
1013 (deffoo nnimap-request-post (&optional server)
1014   (let ((success t))
1015     (dolist (mbx (message-unquote-tokens
1016                   (message-tokenize-header
1017                    (message-fetch-field "Newsgroups") ", ")) success)
1018       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
1019         (or (gnus-active to-newsgroup)
1020             (gnus-activate-group to-newsgroup)
1021             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
1022                                        to-newsgroup))
1023                 (or (and (gnus-request-create-group
1024                           to-newsgroup gnus-command-method)
1025                          (gnus-activate-group to-newsgroup nil nil
1026                                               gnus-command-method))
1027                     (error "Couldn't create group %s" to-newsgroup)))
1028             (error "No such group: %s" to-newsgroup))
1029         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
1030           (setq success nil))))))
1031
1032 ;; Optional backend functions
1033
1034 (defun nnimap-string-lessp-numerical (s1 s2)
1035   "Return t if first arg string is less than second in numerical order."
1036   (cond ((string= s1 s2)
1037          nil)
1038         ((> (length s1) (length s2))
1039          nil)
1040         ((< (length s1) (length s2))
1041          t)
1042         ((< (string-to-number (substring s1 0 1))
1043             (string-to-number (substring s2 0 1)))
1044          t)
1045         ((> (string-to-number (substring s1 0 1))
1046             (string-to-number (substring s2 0 1)))
1047          nil)
1048         (t
1049          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1050
1051 (deffoo nnimap-retrieve-groups (groups &optional server)
1052   (when (nnimap-possibly-change-server server)
1053     (gnus-message 5 "nnimap: Checking mailboxes...")
1054     (with-current-buffer nntp-server-buffer
1055       (erase-buffer)
1056       (nnimap-before-find-minmax-bugworkaround)
1057       (let (asyncgroups slowgroups)
1058         (if (null nnimap-retrieve-groups-asynchronous)
1059             (setq slowgroups groups)
1060           (dolist (group groups)
1061             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1062             (add-to-list (if (gnus-gethash-safe
1063                               (gnus-group-prefixed-name group server)
1064                               nnimap-mailbox-info)
1065                              'asyncgroups
1066                            'slowgroups)
1067                          (list group (imap-mailbox-status-asynch
1068                                       group '(uidvalidity uidnext unseen)
1069                                       nnimap-server-buffer))))
1070           (dolist (asyncgroup asyncgroups)
1071             (let ((group (nth 0 asyncgroup))
1072                   (tag   (nth 1 asyncgroup))
1073                   new old)
1074               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1075                 (if (or (not (string=
1076                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1077                                                     group server)
1078                                                    nnimap-mailbox-info))
1079                               (imap-mailbox-get 'uidvalidity group
1080                                                 nnimap-server-buffer)))
1081                         (not (string=
1082                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1083                                                     group server)
1084                                                    nnimap-mailbox-info))
1085                               (imap-mailbox-get 'uidnext group
1086                                                 nnimap-server-buffer))))
1087                     (push (list group) slowgroups)
1088                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1089                                                 group server)
1090                                                nnimap-mailbox-info))))))))
1091         (dolist (group slowgroups)
1092           (if nnimap-retrieve-groups-asynchronous
1093               (setq group (car group)))
1094           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1095           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1096           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1097                                                      nnimap-server-buffer))
1098               (let* ((info (nnimap-find-minmax-uid group 'examine))
1099                      (str (format "\"%s\" %d %d y\n" group
1100                                   (or (nth 2 info) 0)
1101                                   (max 1 (or (nth 1 info) 1)))))
1102                 (when (> (or (imap-mailbox-get 'recent group
1103                                                nnimap-server-buffer) 0)
1104                          0)
1105                   (push (list (cons group 0)) nnmail-split-history))
1106                 (insert str)
1107                 (when nnimap-retrieve-groups-asynchronous
1108                   (gnus-sethash
1109                    (gnus-group-prefixed-name group server)
1110                    (list (or (imap-mailbox-get
1111                               'uidvalidity group nnimap-server-buffer)
1112                              (imap-mailbox-status
1113                               group 'uidvalidity nnimap-server-buffer))
1114                          (or (imap-mailbox-get
1115                               'uidnext group nnimap-server-buffer)
1116                              (imap-mailbox-status
1117                               group 'uidnext nnimap-server-buffer))
1118                          (or (imap-mailbox-get
1119                               'unseen group nnimap-server-buffer)
1120                              (imap-mailbox-status
1121                               group 'unseen nnimap-server-buffer))
1122                          str)
1123                    nnimap-mailbox-info)))))))
1124     (gnus-message 5 "nnimap: Checking mailboxes...done")
1125     'active))
1126
1127 (deffoo nnimap-request-update-info-internal (group info &optional server)
1128   (when (nnimap-possibly-change-group group server)
1129     (when info;; xxx what does this mean? should we create a info?
1130       (with-current-buffer nnimap-server-buffer
1131         (gnus-message 5 "nnimap: Updating info for %s..."
1132                       (gnus-info-group info))
1133
1134         (when (nnimap-mark-permanent-p 'read)
1135           (let (seen unseen)
1136             ;; read info could contain articles marked unread by other
1137             ;; imap clients!  we correct this
1138             (setq seen (gnus-uncompress-range (gnus-info-read info))
1139                   unseen (imap-search "UNSEEN UNDELETED")
1140                   seen (gnus-set-difference seen unseen)
1141                   ;; seen might lack articles marked as read by other
1142                   ;; imap clients! we correct this
1143                   seen (append seen (imap-search "SEEN"))
1144                   ;; remove dupes
1145                   seen (sort seen '<)
1146                   seen (gnus-compress-sequence seen t)
1147                   ;; we can't return '(1) since this isn't a "list of ranges",
1148                   ;; and we can't return '((1)) since g-list-of-unread-articles
1149                   ;; is buggy so we return '((1 . 1)).
1150                   seen (if (and (integerp (car seen))
1151                                 (null (cdr seen)))
1152                            (list (cons (car seen) (car seen)))
1153                          seen))
1154             (gnus-info-set-read info seen)))
1155
1156         (mapcar (lambda (pred)
1157                   (when (or (eq (cdr pred) 'recent)
1158                             (and (nnimap-mark-permanent-p (cdr pred))
1159                                  (member (nnimap-mark-to-flag (cdr pred))
1160                                          (imap-mailbox-get 'flags))))
1161                     (gnus-info-set-marks
1162                      info
1163                      (gnus-update-alist-soft
1164                       (cdr pred)
1165                       (gnus-compress-sequence
1166                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
1167                       (gnus-info-marks info))
1168                      t)))
1169                 gnus-article-mark-lists)
1170
1171         (when nnimap-importantize-dormant
1172           ;; nnimap mark dormant article as ticked too (for other clients)
1173           ;; so we remove that mark for gnus since we support dormant
1174           (gnus-info-set-marks
1175            info
1176            (gnus-update-alist-soft
1177             'tick
1178             (gnus-remove-from-range
1179              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1180              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1181             (gnus-info-marks info))
1182            t))
1183
1184         (gnus-message 5 "nnimap: Updating info for %s...done"
1185                       (gnus-info-group info))
1186
1187         info))))
1188
1189 (deffoo nnimap-request-type (group &optional article)
1190   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1191       'news
1192     'mail))
1193
1194 (deffoo nnimap-request-set-mark (group actions &optional server)
1195   (when (nnimap-possibly-change-group group server)
1196     (with-current-buffer nnimap-server-buffer
1197       (let (action)
1198         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1199         (while (setq action (pop actions))
1200           (let ((range (nth 0 action))
1201                 (what  (nth 1 action))
1202                 (cmdmarks (nth 2 action))
1203                 marks)
1204             ;; bookmark can't be stored (not list/range
1205             (setq cmdmarks (delq 'bookmark cmdmarks))
1206             ;; killed can't be stored (not list/range
1207             (setq cmdmarks (delq 'killed cmdmarks))
1208             ;; unsent are for nndraft groups only
1209             (setq cmdmarks (delq 'unsent cmdmarks))
1210             ;; cache flags are pointless on the server
1211             (setq cmdmarks (delq 'cache cmdmarks))
1212             ;; seen flags are local to each gnus
1213             (setq cmdmarks (delq 'seen cmdmarks))
1214             ;; recent marks can't be set
1215             (setq cmdmarks (delq 'recent cmdmarks))
1216             (when nnimap-importantize-dormant
1217               ;; flag dormant articles as ticked
1218               (if (memq 'dormant cmdmarks)
1219                   (setq cmdmarks (cons 'tick cmdmarks))))
1220             ;; remove stuff we are forbidden to store
1221             (mapcar (lambda (mark)
1222                       (if (imap-message-flag-permanent-p
1223                            (nnimap-mark-to-flag mark))
1224                           (setq marks (cons mark marks))))
1225                     cmdmarks)
1226             (when (and range marks)
1227               (cond ((eq what 'del)
1228                      (imap-message-flags-del
1229                       (imap-range-to-message-set range)
1230                       (nnimap-mark-to-flag marks nil t)))
1231                     ((eq what 'add)
1232                      (imap-message-flags-add
1233                       (imap-range-to-message-set range)
1234                       (nnimap-mark-to-flag marks nil t)))
1235                     ((eq what 'set)
1236                      (imap-message-flags-set
1237                       (imap-range-to-message-set range)
1238                       (nnimap-mark-to-flag marks nil t)))))))
1239         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1240   nil)
1241
1242 (defun nnimap-split-fancy ()
1243   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1244   (let ((nnmail-split-fancy nnimap-split-fancy))
1245     (nnmail-split-fancy)))
1246
1247 (defun nnimap-split-to-groups (rules)
1248   ;; tries to match all rules in nnimap-split-rule against content of
1249   ;; nntp-server-buffer, returns a list of groups that matched.
1250   (with-current-buffer nntp-server-buffer
1251     ;; Fold continuation lines.
1252     (goto-char (point-min))
1253     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1254       (replace-match " " t t))
1255     (if (functionp rules)
1256         (funcall rules)
1257       (let (to-groups regrepp)
1258         (catch 'split-done
1259           (dolist (rule rules to-groups)
1260             (let ((group (car rule))
1261                   (regexp (cadr rule)))
1262               (goto-char (point-min))
1263               (when (and (if (stringp regexp)
1264                              (progn
1265                                (if (not (stringp group))
1266                                    (setq group (eval group))
1267                                  (setq regrepp
1268                                        (string-match "\\\\[0-9&]" group)))
1269                                (re-search-forward regexp nil t))
1270                            (funcall regexp group))
1271                          ;; Don't enter the article into the same group twice.
1272                          (not (assoc group to-groups)))
1273                 (push (if regrepp
1274                           (nnmail-expand-newtext group)
1275                         group)
1276                       to-groups)
1277                 (or nnimap-split-crosspost
1278                     (throw 'split-done to-groups))))))))))
1279
1280 (defun nnimap-assoc-match (key alist)
1281   (let (element)
1282     (while (and alist (not element))
1283       (if (string-match (car (car alist)) key)
1284           (setq element (car alist)))
1285       (setq alist (cdr alist)))
1286     element))
1287
1288 (defun nnimap-split-find-rule (server inbox)
1289   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1290            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1291       ;; extended format
1292       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1293                                             server nnimap-split-rule))))
1294     nnimap-split-rule))
1295
1296 (defun nnimap-split-find-inbox (server)
1297   (if (listp nnimap-split-inbox)
1298       nnimap-split-inbox
1299     (list nnimap-split-inbox)))
1300
1301 (defun nnimap-split-articles (&optional group server)
1302   (when (nnimap-possibly-change-server server)
1303     (with-current-buffer nnimap-server-buffer
1304       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1305         ;; iterate over inboxes
1306         (while (and (setq inbox (pop inboxes))
1307                     (nnimap-possibly-change-group inbox));; SELECT
1308           ;; find split rule for this server / inbox
1309           (when (setq rule (nnimap-split-find-rule server inbox))
1310             ;; iterate over articles
1311             (dolist (article (imap-search nnimap-split-predicate))
1312               (when (if (if (eq nnimap-split-download-body 'default)
1313                             nnimap-split-download-body-default
1314                           nnimap-split-download-body)
1315                         (and (nnimap-request-article article)
1316                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1317                       (nnimap-request-head article))
1318                 ;; copy article to right group(s)
1319                 (setq removeorig nil)
1320                 (dolist (to-group (nnimap-split-to-groups rule))
1321                   (cond ((eq to-group 'junk)
1322                          (message "IMAP split removed %s:%s:%d" server inbox
1323                                   article)
1324                          (setq removeorig t))
1325                         ((imap-message-copy (number-to-string article)
1326                                             to-group nil 'nocopyuid)
1327                          (message "IMAP split moved %s:%s:%d to %s" server
1328                                   inbox article to-group)
1329                          (setq removeorig t)
1330                          (when nnmail-cache-accepted-message-ids
1331                            (with-current-buffer nntp-server-buffer
1332                              (let (msgid)
1333                                (and (setq msgid
1334                                           (nnmail-fetch-field "message-id"))
1335                                     (nnmail-cache-insert msgid
1336                                                          to-group
1337                                                          (nnmail-fetch-field "subject"))))))
1338                          ;; Add the group-art list to the history list.
1339                          (push (list (cons to-group 0)) nnmail-split-history))
1340                         (t
1341                          (message "IMAP split failed to move %s:%s:%d to %s"
1342                                   server inbox article to-group))))
1343                 (if (if (eq nnimap-split-download-body 'default)
1344                         nnimap-split-download-body-default
1345                       nnimap-split-download-body)
1346                     (widen))
1347                 ;; remove article if it was successfully copied somewhere
1348                 (and removeorig
1349                      (imap-message-flags-add (format "%d" article)
1350                                              "\\Seen \\Deleted")))))
1351           (when (imap-mailbox-select inbox);; just in case
1352             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1353             (imap-mailbox-expunge)
1354             (imap-mailbox-close)))
1355         (when nnmail-cache-accepted-message-ids
1356           (nnmail-cache-close))
1357         t))))
1358
1359 (deffoo nnimap-request-scan (&optional group server)
1360   (nnimap-split-articles group server))
1361
1362 (deffoo nnimap-request-newgroups (date &optional server)
1363   (when (nnimap-possibly-change-server server)
1364     (with-current-buffer nntp-server-buffer
1365       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1366                     (if (> (length server) 0) " on " "") server)
1367       (erase-buffer)
1368       (nnimap-before-find-minmax-bugworkaround)
1369       (dolist (pattern (nnimap-pattern-to-list-arguments
1370                         nnimap-list-pattern))
1371         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1372                                         nnimap-server-buffer))
1373           (or (catch 'found
1374                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1375                                                    nnimap-server-buffer))
1376                   (if (string= (downcase mailbox) "\\noselect")
1377                       (throw 'found t)))
1378                 nil)
1379               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1380                 (when info
1381                   (insert (format "\"%s\" %d %d y\n"
1382                                   mbx (or (nth 2 info) 0)
1383                                   (max 1 (or (nth 1 info) 1)))))))))
1384       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1385                     (if (> (length server) 0) " on " "") server))
1386     t))
1387
1388 (deffoo nnimap-request-create-group (group &optional server args)
1389   (when (nnimap-possibly-change-server server)
1390     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1391         (imap-mailbox-create group nnimap-server-buffer)
1392         (nnheader-report 'nnimap "%S"
1393                          (imap-error-text nnimap-server-buffer)))))
1394
1395 (defun nnimap-time-substract (time1 time2)
1396   "Return TIME for TIME1 - TIME2."
1397   (let* ((ms (- (car time1) (car time2)))
1398          (ls (- (nth 1 time1) (nth 1 time2))))
1399     (if (< ls 0)
1400         (list (- ms 1) (+ (expt 2 16) ls))
1401       (list ms ls))))
1402
1403 (defun nnimap-date-days-ago (daysago)
1404   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1405   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1406          (date (format-time-string
1407                 (format "%%d-%s-%%Y"
1408                         (capitalize (car (rassoc (nth 4 (decode-time time))
1409                                                  parse-time-months))))
1410                 time)))
1411     (if (eq ?0 (string-to-char date))
1412         (substring date 1)
1413       date)))
1414
1415 (defun nnimap-request-expire-articles-progress ()
1416   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1417                 imap-current-message))
1418
1419 (defun nnimap-expiry-target (arts group server)
1420   (unless (eq nnmail-expiry-target 'delete)
1421     (with-temp-buffer
1422       (dolist (art arts)
1423         (nnimap-request-article art group server (current-buffer))
1424         ;; hints for optimization in `nnimap-request-accept-article'
1425         (let ((nnimap-current-move-article art)
1426               (nnimap-current-move-group group)
1427               (nnimap-current-move-server server))
1428           (nnmail-expiry-target-group nnmail-expiry-target group))))
1429     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1430     ;; current group to be changed or not, so we make sure here.
1431     (nnimap-possibly-change-group group server)))
1432
1433 ;; Notice that we don't actually delete anything, we just mark them deleted.
1434 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1435   (let ((artseq (gnus-compress-sequence articles)))
1436     (when (and artseq (nnimap-possibly-change-group group server))
1437       (with-current-buffer nnimap-server-buffer
1438         (let ((days (or (and nnmail-expiry-wait-function
1439                              (funcall nnmail-expiry-wait-function group))
1440                         nnmail-expiry-wait)))
1441           (cond ((or force (eq days 'immediate))
1442                  (let ((oldarts (imap-search
1443                                  (concat "UID "
1444                                          (imap-range-to-message-set artseq)))))
1445                    (when oldarts
1446                      (nnimap-expiry-target oldarts group server)
1447                      (when (imap-message-flags-add
1448                             (imap-range-to-message-set
1449                              (gnus-compress-sequence oldarts)) "\\Deleted")
1450                        (setq articles (gnus-set-difference
1451                                        articles oldarts))))))
1452                 ((numberp days)
1453                  (let ((oldarts (imap-search
1454                                  (format nnimap-expunge-search-string
1455                                          (imap-range-to-message-set artseq)
1456                                          (nnimap-date-days-ago days))))
1457                        (imap-fetch-data-hook
1458                         '(nnimap-request-expire-articles-progress)))
1459                    (when oldarts
1460                      (nnimap-expiry-target oldarts group server)
1461                      (when (imap-message-flags-add
1462                             (imap-range-to-message-set
1463                              (gnus-compress-sequence oldarts)) "\\Deleted")
1464                        (setq articles (gnus-set-difference
1465                                        articles oldarts)))))))))))
1466   ;; return articles not deleted
1467   articles)
1468
1469 (deffoo nnimap-request-move-article (article group server
1470                                              accept-form &optional last)
1471   (when (nnimap-possibly-change-server server)
1472     (save-excursion
1473       (let ((buf (get-buffer-create " *nnimap move*"))
1474             (nnimap-current-move-article article)
1475             (nnimap-current-move-group group)
1476             (nnimap-current-move-server nnimap-current-server)
1477             result)
1478         (and (nnimap-request-article article group server)
1479              (save-excursion
1480                (set-buffer buf)
1481                (buffer-disable-undo (current-buffer))
1482                (insert-buffer-substring nntp-server-buffer)
1483                (setq result (eval accept-form))
1484                (kill-buffer buf)
1485                result)
1486              (imap-message-flags-add
1487               (imap-range-to-message-set (list article))
1488               "\\Deleted" 'silent nnimap-server-buffer))
1489         result))))
1490
1491 (deffoo nnimap-request-accept-article (group &optional server last)
1492   (when (nnimap-possibly-change-server server)
1493     (let (uid)
1494       (if (setq uid
1495                 (if (string= nnimap-current-server nnimap-current-move-server)
1496                     ;; moving article within same server, speed it up...
1497                     (and (nnimap-possibly-change-group
1498                           nnimap-current-move-group)
1499                          (imap-message-copy (number-to-string
1500                                              nnimap-current-move-article)
1501                                             group 'dontcreate nil
1502                                             nnimap-server-buffer))
1503                   (with-current-buffer (current-buffer)
1504                     (goto-char (point-min))
1505                     ;; remove any 'From blabla' lines, some IMAP servers
1506                     ;; reject the entire message otherwise.
1507                     (when (looking-at "^From[^:]")
1508                       (delete-region (point) (progn (forward-line) (point))))
1509                     ;; turn into rfc822 format (\r\n eol's)
1510                     (while (search-forward "\n" nil t)
1511                       (replace-match "\r\n"))
1512                     (when nnmail-cache-accepted-message-ids
1513                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1514                                            group
1515                                            (nnmail-fetch-field "subject"))))
1516                   (when (and last nnmail-cache-accepted-message-ids)
1517                     (nnmail-cache-close))
1518                   ;; this 'or' is for Cyrus server bug
1519                   (or (null (imap-current-mailbox nnimap-server-buffer))
1520                       (imap-mailbox-unselect nnimap-server-buffer))
1521                   (imap-message-append group (current-buffer) nil nil
1522                                        nnimap-server-buffer)))
1523           (cons group (nth 1 uid))
1524         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1525
1526 (deffoo nnimap-request-delete-group (group force &optional server)
1527   (when (nnimap-possibly-change-server server)
1528     (with-current-buffer nnimap-server-buffer
1529       (if force
1530           (or (null (imap-mailbox-status group 'uidvalidity))
1531               (imap-mailbox-delete group))
1532         ;; UNSUBSCRIBE?
1533         t))))
1534
1535 (deffoo nnimap-request-rename-group (group new-name &optional server)
1536   (when (nnimap-possibly-change-server server)
1537     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1538
1539 (defun nnimap-expunge (mailbox server)
1540   (when (nnimap-possibly-change-group mailbox server)
1541     (imap-mailbox-expunge nil nnimap-server-buffer)))
1542
1543 (defun nnimap-acl-get (mailbox server)
1544   (when (nnimap-possibly-change-server server)
1545     (and (imap-capability 'ACL nnimap-server-buffer)
1546          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1547
1548 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1549   (when (nnimap-possibly-change-server (cadr method))
1550     (unless (imap-capability 'ACL nnimap-server-buffer)
1551       (error "Your server does not support ACL editing"))
1552     (with-current-buffer nnimap-server-buffer
1553       ;; delete all removed identifiers
1554       (mapcar (lambda (old-acl)
1555                 (unless (assoc (car old-acl) new-acls)
1556                   (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1557                       (error "Can't delete ACL for %s" (car old-acl)))))
1558               old-acls)
1559       ;; set all changed acl's
1560       (mapcar (lambda (new-acl)
1561                 (let ((new-rights (cdr new-acl))
1562                       (old-rights (cdr (assoc (car new-acl) old-acls))))
1563                   (unless (and old-rights new-rights
1564                                (string= old-rights new-rights))
1565                     (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1566                         (error "Can't set ACL for %s to %s" (car new-acl)
1567                                new-rights)))))
1568               new-acls)
1569       t)))
1570
1571 \f
1572 ;;; Internal functions
1573
1574 ;;
1575 ;; This is confusing.
1576 ;;
1577 ;; mark      => read, tick, draft, reply etc
1578 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1579 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1580 ;;
1581 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1582 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1583 ;;
1584
1585 (defconst nnimap-mark-to-predicate-alist
1586   (mapcar
1587    (lambda (pair)                       ; cdr is the mark
1588      (or (assoc (cdr pair)
1589                 '((read . "SEEN")
1590                   (tick . "FLAGGED")
1591                   (draft . "DRAFT")
1592                   (recent . "RECENT")
1593                   (reply . "ANSWERED")))
1594          (cons (cdr pair)
1595                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1596    (cons '(read . read) gnus-article-mark-lists)))
1597
1598 (defun nnimap-mark-to-predicate (pred)
1599   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1600 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1601 to be used within a IMAP SEARCH query."
1602   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1603
1604 (defconst nnimap-mark-to-flag-alist
1605   (mapcar
1606    (lambda (pair)
1607      (or (assoc (cdr pair)
1608                 '((read . "\\Seen")
1609                   (tick . "\\Flagged")
1610                   (draft . "\\Draft")
1611                   (recent . "\\Recent")
1612                   (reply . "\\Answered")))
1613          (cons (cdr pair)
1614                (format "gnus-%s" (symbol-name (cdr pair))))))
1615    (cons '(read . read) gnus-article-mark-lists)))
1616
1617 (defun nnimap-mark-to-flag-1 (preds)
1618   (if (and (not (null preds)) (listp preds))
1619       (cons (nnimap-mark-to-flag (car preds))
1620             (nnimap-mark-to-flag (cdr preds)))
1621     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1622
1623 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1624   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1625 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1626 be used in a STORE FLAGS command."
1627   (let ((result (nnimap-mark-to-flag-1 preds)))
1628     (setq result (if (and (or make-string always-list)
1629                           (not (listp result)))
1630                      (list result)
1631                    result))
1632     (if make-string
1633         (mapconcat (lambda (flag)
1634                      (if (listp flag)
1635                          (mapconcat 'identity flag " ")
1636                        flag))
1637                    result " ")
1638       result)))
1639
1640 (defun nnimap-mark-permanent-p (mark &optional group)
1641   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1642   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1643
1644 (when nnimap-debug
1645   (require 'trace)
1646   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1647   (mapcar (lambda (f) (trace-function-background f nnimap-debug-buffer))
1648           '(
1649             nnimap-possibly-change-server
1650             nnimap-verify-uidvalidity
1651             nnimap-find-minmax-uid
1652             nnimap-before-find-minmax-bugworkaround
1653             nnimap-possibly-change-group
1654             ;;nnimap-replace-whitespace
1655             nnimap-retrieve-headers-progress
1656             nnimap-retrieve-which-headers
1657             nnimap-group-overview-filename
1658             nnimap-retrieve-headers-from-file
1659             nnimap-retrieve-headers-from-server
1660             nnimap-retrieve-headers
1661             nnimap-open-connection
1662             nnimap-open-server
1663             nnimap-server-opened
1664             nnimap-close-server
1665             nnimap-request-close
1666             nnimap-status-message
1667             ;;nnimap-demule
1668             nnimap-request-article-part
1669             nnimap-request-article
1670             nnimap-request-head
1671             nnimap-request-body
1672             nnimap-request-group
1673             nnimap-close-group
1674             nnimap-pattern-to-list-arguments
1675             nnimap-request-list
1676             nnimap-request-post
1677             nnimap-retrieve-groups
1678             nnimap-request-update-info-internal
1679             nnimap-request-type
1680             nnimap-request-set-mark
1681             nnimap-split-to-groups
1682             nnimap-split-find-rule
1683             nnimap-split-find-inbox
1684             nnimap-split-articles
1685             nnimap-request-scan
1686             nnimap-request-newgroups
1687             nnimap-request-create-group
1688             nnimap-time-substract
1689             nnimap-date-days-ago
1690             nnimap-request-expire-articles-progress
1691             nnimap-request-expire-articles
1692             nnimap-request-move-article
1693             nnimap-request-accept-article
1694             nnimap-request-delete-group
1695             nnimap-request-rename-group
1696             gnus-group-nnimap-expunge
1697             gnus-group-nnimap-edit-acl
1698             gnus-group-nnimap-edit-acl-done
1699             nnimap-group-mode-hook
1700             nnimap-mark-to-predicate
1701             nnimap-mark-to-flag-1
1702             nnimap-mark-to-flag
1703             nnimap-mark-permanent-p
1704             )))
1705
1706 (provide 'nnimap)
1707
1708 ;;; nnimap.el ends here