git.chise.org Git - elisp/gnus.git-/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   6 ;;         Jim Radford <radford@robby.caltech.edu>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Todo, major things:
  29 ;;
  30 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  31 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  32 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  33 ;;   o Sieve
  34 ;;   o MIME (partial article fetches)
  35 ;;   o Split to other backends, different split rules for different
  36 ;;     servers/inboxes
  37 ;;
  38 ;; Todo, minor things:
  39 ;;
  40 ;;   o Don't require half of Gnus -- backends should be standalone
  41 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  42 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  43 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  44 ;;   o What do I do with gnus-newsgroup-*?
  45 ;;   o Tell Gnus about new groups (how can we tell?)
  46 ;;   o Respooling (fix Gnus?) (unnecessary?)
  47 ;;   o Add support for the following: (if applicable)
  48 ;;       request-list-newsgroups, request-regenerate
  49 ;;       list-active-group,
  50 ;;       request-associate-buffer, request-restore-buffer,
  51 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  52 ;;   o Support RFC2221 (Login referrals)
  53 ;;   o IMAP2BIS compatibility? (RFC2061)
  54 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  55 ;;     .newsrc.eld)
  56 ;;   o What about Gnus's article editing, can we support it?  NO!
  57 ;;   o Use \Draft to support the draft group??
  58 ;;   o Duplicate suppression
  59 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  60
  61 ;;; Code:
  62
  63 (eval-when-compile (require 'cl))
  64 (require 'imap)
  65
  66 (require 'nnoo)
  67 (require 'nnmail)
  68 (require 'nnheader)
  69 (require 'gnus)
  70 (require 'gnus-range)
  71 (require 'gnus-start)
  72 (require 'gnus-int)
  73
  74 (eval-when-compile (require 'cl))
  75
  76 (nnoo-declare nnimap)
  77
  78 (defconst nnimap-version "nnimap 1.0")
  79
  80 (defgroup nnimap nil
  81   "Reading IMAP mail with Gnus."
  82   :group 'gnus)
  83
  84 (defvoo nnimap-address nil
  85   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  86
  87 (defvoo nnimap-server-port nil
  88   "Port number on physical IMAP server.
  89 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  90
  91 ;; Splitting variables
  92
  93 (defcustom nnimap-split-crosspost t
  94   "If non-nil, do crossposting if several split methods match the mail.
  95 If nil, the first match found will be used."
  96   :group 'nnimap
  97   :type 'boolean)
  98
  99 (defcustom nnimap-split-inbox nil
 100   "Name of mailbox to split mail from.
 101
 102 Mail is read from this mailbox and split according to rules in
 103 `nnimap-split-rule'.
 104
 105 This can be a string or a list of strings."
 106   :group 'nnimap
 107   :type '(choice (string)
 108                  (repeat string)))
 109
 110 (define-widget 'nnimap-strict-function 'function
 111   "This widget only matches values that are functionp.
 112
 113 Warning: This means that a value that is the symbol of a not yet
 114 loaded function will not match.  Use with care."
 115   :match 'nnimap-strict-function-match)
 116
 117 (defun nnimap-strict-function-match (widget value)
 118   "Ignoring WIDGET, match if VALUE is a function."
 119   (functionp value))
 120
 121 (defcustom nnimap-split-rule nil
 122   "Mail will be split according to these rules.
 123
 124 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 125
 126 If you'd like, for instance, one mail group for mail from the
 127 \"gnus-imap\" mailing list, one group for junk mail and leave
 128 everything else in the incoming mailbox, you could do something like
 129 this:
 130
 131 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 132                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 133
 134 As you can see, `nnimap-split-rule' is a list of lists, where the
 135 first element in each \"rule\" is the name of the IMAP mailbox (or the
 136 symbol `junk' if you want to remove the mail), and the second is a
 137 regexp that nnimap will try to match on the header to find a fit.
 138
 139 The second element can also be a function.  In that case, it will be
 140 called narrowed to the headers with the first element of the rule as
 141 the argument.  It should return a non-nil value if it thinks that the
 142 mail belongs in that group.
 143
 144 This variable can also have a function as its value, the function will
 145 be called with the headers narrowed and should return a group where it
 146 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 147
 148 To allow for different split rules on different virtual servers, and
 149 even different split rules in different inboxes on the same server,
 150 the syntax of this variable have been extended along the lines of:
 151
 152 \(setq nnimap-split-rule
 153       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 154                                   (\"junk\"    \"From:.*Simon\")))
 155         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 156         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 157                                   (\"junk\"    my-junk-func)))))
 158
 159 The virtual server name is in fact a regexp, so that the same rules
 160 may apply to several servers.  In the example, the servers
 161 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 162 the inbox string is also a regexp.  The actual splitting rules are as
 163 before, either a function, or a list with group/regexp or
 164 group/function elements."
 165   :group 'nnimap
 166   :type '(choice :tag "Rule type"
 167                  (repeat :menu-tag "Single-server"
 168                          :tag "Single-server list"
 169                          (list (string :tag "Mailbox")
 170                                (choice :tag "Predicate"
 171                                        (regexp :tag "A regexp")
 172                                        (nnimap-strict-function :tag "A function"))))
 173                  (choice :menu-tag "A function"
 174                          :tag "A function"
 175                          (function-item nnimap-split-fancy)
 176                          (function-item nnmail-split-fancy)
 177                          (nnimap-strict-function :tag "User-defined function"))
 178                  (repeat :menu-tag "Multi-server (extended)"
 179                          :tag "Multi-server list"
 180                          (list (regexp :tag "Server regexp")
 181                                (list (regexp :tag "Incoming Mailbox regexp")
 182                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 183                                              (list (string :tag "Destination mailbox")
 184                                                    (choice :tag "Predicate"
 185                                                            (regexp :tag "A Regexp")
 186                                                            (nnimap-strict-function :tag "A Function")))))))))
 187
 188 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 189   "The predicate used to find articles to split.
 190 If you use another IMAP client to peek on articles but always would
 191 like nnimap to split them once it's started, you could change this to
 192 \"UNDELETED\". Other available predicates are available in
 193 RFC2060 section 6.4.4."
 194   :group 'nnimap
 195   :type 'string)
 196
 197 (defcustom nnimap-split-fancy nil
 198   "Like the variable `nnmail-split-fancy'."
 199   :group 'nnimap
 200   :type 'sexp)
 201
 202 (defvar nnimap-split-download-body-default nil
 203   "Internal variable with default value for `nnimap-split-download-body'.")
 204
 205 (defcustom nnimap-split-download-body 'default
 206   "Whether to download entire articles during splitting.
 207 This is generally not required, and will slow things down considerably.
 208 You may need it if you want to use an advanced splitting function that
 209 analyses the body before splitting the article.
 210 If this variable is nil, bodies will not be downloaded; if this
 211 variable is the symbol `default' the default behaviour is
 212 used (which currently is nil, unless you use a statistical
 213 spam.el test); if this variable is another non-nil value bodies
 214 will be downloaded."
 215   :version "22.1"
 216   :group 'nnimap
 217   :type '(choice (const :tag "Let system decide" deault)
 218                  boolean))
 219
 220 ;; Performance / bug workaround variables
 221
 222 (defcustom nnimap-close-asynchronous t
 223   "Close mailboxes asynchronously in `nnimap-close-group'.
 224 This means that errors caught by nnimap when closing the mailbox will
 225 not prevent Gnus from updating the group status, which may be harmful.
 226 However, it increases speed."
 227   :version "22.1"
 228   :type 'boolean
 229   :group 'nnimap)
 230
 231 (defcustom nnimap-dont-close t
 232   "Never close mailboxes.
 233 This increases the speed of closing mailboxes (quiting group) but may
 234 decrease the speed of selecting another mailbox later.  Re-selecting
 235 the same mailbox will be faster though."
 236   :version "22.1"
 237   :type 'boolean
 238   :group 'nnimap)
 239
 240 (defcustom nnimap-retrieve-groups-asynchronous t
 241   "Send asynchronous STATUS commands for each mailbox before checking mail.
 242 If you have mailboxes that rarely receives mail, this speeds up new
 243 mail checking.  It works by first sending STATUS commands for each
 244 mailbox, and then only checking groups which has a modified UIDNEXT
 245 more carefully for new mail.
 246
 247 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 248 it O(n).  If p is small, then the default is probably faster."
 249   :version "22.1"
 250   :type 'boolean
 251   :group 'nnimap)
 252
 253 (defvoo nnimap-need-unselect-to-notice-new-mail nil
 254   "Unselect mailboxes before looking for new mail in them.
 255 Some servers seem to need this under some circumstances.")
 256
 257 ;; Authorization / Privacy variables
 258
 259 (defvoo nnimap-auth-method nil
 260   "Obsolete.")
 261
 262 (defvoo nnimap-stream nil
 263   "How nnimap will connect to the server.
 264
 265 The default, nil, will try to use the \"best\" method the server can
 266 handle.
 267
 268 Change this if
 269
 270 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 271    with IMAP is suboptimal so you'll have to tell it
 272    specifically.
 273
 274 2) your server is more capable than your environment -- i.e. your
 275    server accept Kerberos login's but you haven't installed the
 276    `imtest' program or your machine isn't configured for Kerberos.
 277
 278 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 279 See also `imap-streams' and `imap-stream-alist'.")
 280
 281 (defvoo nnimap-authenticator nil
 282   "How nnimap authenticate itself to the server.
 283
 284 The default, nil, will try to use the \"best\" method the server can
 285 handle.
 286
 287 There is only one reason for fiddling with this variable, and that is
 288 if your server is more capable than your environment -- i.e. you
 289 connect to a server that accept Kerberos login's but you haven't
 290 installed the `imtest' program or your machine isn't configured for
 291 Kerberos.
 292
 293 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 294 See also `imap-authenticators' and `imap-authenticator-alist'")
 295
 296 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 297   "Directory to keep NOV cache files for nnimap groups.
 298 See also `nnimap-nov-file-name'.")
 299
 300 (defvoo nnimap-nov-file-name "nnimap."
 301   "NOV cache base filename.
 302 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 303 typical complete file name would be
 304 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 305 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 306 `nnmail-use-long-file-names' is nil")
 307
 308 (defvoo nnimap-nov-file-name-suffix ".novcache"
 309   "Suffix for NOV cache base filename.")
 310
 311 (defvoo nnimap-nov-is-evil gnus-agent
 312   "If non-nil, never generate or use a local nov database for this backend.
 313 Using nov databases should speed up header fetching considerably.
 314 However, it will invoke a UID SEARCH UID command on the server, and
 315 some servers implement this command inefficiently by opening each and
 316 every message in the group, thus making it quite slow.
 317 Unlike other backends, you do not need to take special care if you
 318 flip this variable.")
 319
 320 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 321   "Whether to expunge a group when it is closed.
 322 When a IMAP group with articles marked for deletion is closed, this
 323 variable determine if nnimap should actually remove the articles or
 324 not.
 325
 326 If always, nnimap always perform a expunge when closing the group.
 327 If never, nnimap never expunges articles marked for deletion.
 328 If ask, nnimap will ask you if you wish to expunge marked articles.
 329
 330 When setting this variable to `never', you can only expunge articles
 331 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 332
 333 (defvoo nnimap-list-pattern "*"
 334   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 335 See below for available wildcards.
 336
 337 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 338 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 339 semantics of this are server specific, on the University of Washington
 340 server you can specify a directory.
 341
 342 Example:
 343  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 344
 345 There are two wildcards * and %. * matches everything, % matches
 346 everything in the current hierarchy.")
 347
 348 (defvoo nnimap-news-groups nil
 349   "IMAP support a news-like mode, also known as bulletin board mode,
 350 where replies is sent via IMAP instead of SMTP.
 351
 352 This variable should contain a regexp matching groups where you wish
 353 replies to be stored to the mailbox directly.
 354
 355 Example:
 356   '(\"^[^I][^N][^B][^O][^X].*$\")
 357
 358 This will match all groups not beginning with \"INBOX\".
 359
 360 Note that there is nothing technically different between mail-like and
 361 news-like mailboxes.  If you wish to have a group with todo items or
 362 similar which you wouldn't want to set up a mailing list for, you can
 363 use this to make replies go directly to the group.")
 364
 365 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 366   "IMAP search command to use for articles that are to be expired.
 367 The first %s is replaced by a UID set of articles to search on,
 368 and the second %s is replaced by a date criterium.
 369
 370 One useful (and perhaps the only useful) value to change this to would
 371 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 372 instead of the internal date of messages.  See section 6.4.4 of RFC
 373 2060 for more information on valid strings.")
 374
 375 (defvoo nnimap-importantize-dormant t
 376   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 377 Note that within Gnus, dormant articles will still (only) be
 378 marked as ticked.  This is to make \"dormant\" articles stand out,
 379 just like \"ticked\" articles, in other IMAP clients.")
 380
 381 (defvoo nnimap-server-address nil
 382   "Obsolete.  Use `nnimap-address'.")
 383
 384 (defcustom nnimap-authinfo-file "~/.authinfo"
 385   "Authorization information for IMAP servers.  In .netrc format."
 386   :type
 387   '(choice file
 388            (repeat :tag "Entries"
 389                    :menu-tag "Inline"
 390                    (list :format "%v"
 391                          :value ("" ("login" . "") ("password" . ""))
 392                          (string :tag "Host")
 393                          (checklist :inline t
 394                                     (cons :format "%v"
 395                                           (const :format "" "login")
 396                                           (string :format "Login: %v"))
 397                                     (cons :format "%v"
 398                                           (const :format "" "password")
 399                                           (string :format "Password: %v"))))))
 400   :group 'nnimap)
 401
 402 (defcustom nnimap-prune-cache t
 403   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 404   :type 'boolean
 405   :group 'nnimap)
 406
 407 (defvar nnimap-request-list-method 'imap-mailbox-list
 408   "Method to use to request a list of all folders from the server.
 409 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 410 restrict visible folders.")
 411
 412 (defcustom nnimap-id nil
 413   "Plist with client identity to send to server upon login.
 414 Nil means no information is sent, symbol `no' to disable ID query
 415 alltogheter, or plist with identifier-value pairs to send to
 416 server.  RFC 2971 describes the list as follows:
 417
 418    Any string may be sent as a field, but the following are defined to
 419    describe certain values that might be sent.  Implementations are free
 420    to send none, any, or all of these.  Strings are not case-sensitive.
 421    Field strings MUST NOT be longer than 30 octets.  Value strings MUST
 422    NOT be longer than 1024 octets.  Implementations MUST NOT send more
 423    than 30 field-value pairs.
 424
 425      name            Name of the program
 426      version         Version number of the program
 427      os              Name of the operating system
 428      os-version      Version of the operating system
 429      vendor          Vendor of the client/server
 430      support-url     URL to contact for support
 431      address         Postal address of contact/vendor
 432      date            Date program was released, specified as a date-time
 433                        in IMAP4rev1
 434      command         Command used to start the program
 435      arguments       Arguments supplied on the command line, if any
 436                        if any
 437      environment     Description of environment, i.e., UNIX environment
 438                        variables or Windows registry settings
 439
 440    Implementations MUST NOT send the same field name more than once.
 441
 442 An example plist would be '(\"name\" \"Gnus\" \"version\" gnus-version-number
 443 \"os\" system-configuration \"vendor\" \"GNU\")."
 444   :group 'nnimap
 445   :type '(choice (const :tag "No information" nil)
 446                  (const :tag "Disable ID query" no)
 447                  (plist :key-type string :value-type string)))
 448
 449 (defcustom nnimap-debug nil
 450   "If non-nil, random debug spews are placed in *nnimap-debug* buffer."
 451   :group 'nnimap
 452   :type 'boolean)
 453
 454 ;; Internal variables:
 455
 456 (defvar nnimap-debug-buffer "*nnimap-debug*")
 457 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 458 (defvar nnimap-current-move-server nil)
 459 (defvar nnimap-current-move-group nil)
 460 (defvar nnimap-current-move-article nil)
 461 (defvar nnimap-length)
 462 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 463 (defvar nnimap-progress-how-often 20)
 464 (defvar nnimap-counter)
 465 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 466 (defvar nnimap-current-server nil)      ;; Current server
 467 (defvar nnimap-server-buffer nil)       ;; Current servers' buffer
 468
 469 \f
 470
 471 (nnoo-define-basics nnimap)
 472
 473 ;; Utility functions:
 474
 475 (defsubst nnimap-get-server-buffer (server)
 476   "Return buffer for SERVER, if nil use current server."
 477   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 478
 479 (defun nnimap-remove-server-from-buffer-alist (server list)
 480   "Remove SERVER from LIST."
 481   (let (l)
 482     (dolist (e list)
 483       (unless (equal server (car-safe e))
 484         (push e l)))
 485     l))
 486
 487 (defun nnimap-possibly-change-server (server)
 488   "Return buffer for SERVER, changing the current server as a side-effect.
 489 If SERVER is nil, uses the current server."
 490   (setq nnimap-current-server (or server nnimap-current-server)
 491         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 492
 493 (defun nnimap-verify-uidvalidity (group server)
 494   "Verify stored uidvalidity match current one in GROUP on SERVER."
 495   (let* ((gnusgroup (gnus-group-prefixed-name
 496                      group (gnus-server-to-method
 497                             (format "nnimap:%s" server))))
 498          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 499          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 500          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 501          (nameuid (nnheader-translate-file-chars
 502                    (concat nnimap-nov-file-name
 503                            (if (equal server "")
 504                                "unnamed"
 505                              server) "." group "." old-uidvalidity
 506                              nnimap-nov-file-name-suffix) t))
 507          (file (if (or nnmail-use-long-file-names
 508                        (file-exists-p (expand-file-name nameuid dir)))
 509                    (expand-file-name nameuid dir)
 510                  (expand-file-name
 511                   (encode-coding-string
 512                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 513                    nnmail-pathname-coding-system)
 514                   dir))))
 515     (if old-uidvalidity
 516         (if (not (equal old-uidvalidity new-uidvalidity))
 517             ;; uidvalidity clash
 518             (gnus-delete-file file)
 519           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 520           t)
 521       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 522       t)))
 523
 524 (defun nnimap-before-find-minmax-bugworkaround ()
 525   "Function called before iterating through mailboxes with
 526 `nnimap-find-minmax-uid'."
 527   (when nnimap-need-unselect-to-notice-new-mail
 528     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 529     ;; currently selected mailbox without a re-select/examine.
 530     (or (null (imap-current-mailbox nnimap-server-buffer))
 531         (imap-mailbox-unselect nnimap-server-buffer))))
 532
 533 (defun nnimap-find-minmax-uid (group &optional examine)
 534   "Find lowest and highest active article number in GROUP.
 535 If EXAMINE is non-nil the group is selected read-only."
 536   (with-current-buffer nnimap-server-buffer
 537     (when (or (string= group (imap-current-mailbox))
 538               (imap-mailbox-select group examine))
 539       (let (minuid maxuid)
 540         (when (> (imap-mailbox-get 'exists) 0)
 541           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 542           (imap-message-map (lambda (uid Uid)
 543                               (setq minuid (if minuid (min minuid uid) uid)
 544                                     maxuid (if maxuid (max maxuid uid) uid)))
 545                             'UID))
 546         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 547
 548 (defun nnimap-possibly-change-group (group &optional server)
 549   "Make GROUP the current group, and SERVER the current server."
 550   (when (nnimap-possibly-change-server server)
 551     (with-current-buffer nnimap-server-buffer
 552       (if (or (null group) (imap-current-mailbox-p group))
 553           imap-current-mailbox
 554         (if (imap-mailbox-select group)
 555             (if (or (nnimap-verify-uidvalidity
 556                      group (or server nnimap-current-server))
 557                     (zerop (imap-mailbox-get 'exists group))
 558                     t ;; for OGnus to see if ignoring uidvalidity
 559                       ;; changes has any bad effects.
 560                     (yes-or-no-p
 561                      (format
 562                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 563                 imap-current-mailbox
 564               (imap-mailbox-unselect)
 565               (error "nnimap: Group %s is not uid-valid" group))
 566           (nnheader-report 'nnimap (imap-error-text)))))))
 567
 568 (defun nnimap-replace-whitespace (string)
 569   "Return STRING with all whitespace replaced with space."
 570   (when string
 571     (while (string-match "[\r\n\t]+" string)
 572       (setq string (replace-match " " t t string)))
 573     string))
 574
 575 ;; Required backend functions
 576
 577 (defun nnimap-retrieve-headers-progress ()
 578   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 579   (and (numberp nnmail-large-newsgroup)
 580        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 581        (> nnimap-length nnmail-large-newsgroup)
 582        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 583                          (nth (/ (% nnimap-counter
 584                                     (* (length nnimap-progress-chars)
 585                                        nnimap-progress-how-often))
 586                                  nnimap-progress-how-often)
 587                               nnimap-progress-chars)))
 588   (with-current-buffer nntp-server-buffer
 589     (let (headers lines chars uid mbx)
 590       (with-current-buffer nnimap-server-buffer
 591         (setq uid imap-current-message
 592               mbx imap-current-mailbox
 593               headers (nnimap-demule
 594                        (if (imap-capability 'IMAP4rev1)
 595                            ;; xxx don't just use car? alist doesn't contain
 596                            ;; anything else now, but it might...
 597                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 598                          (imap-message-get uid 'RFC822.HEADER)))
 599               lines (imap-body-lines (imap-message-body imap-current-message))
 600               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 601       (nnheader-insert-nov
 602        (with-temp-buffer
 603          (buffer-disable-undo)
 604          (insert headers)
 605          (let ((head (nnheader-parse-naked-head uid)))
 606            (mail-header-set-number head uid)
 607            (mail-header-set-chars head chars)
 608            (mail-header-set-lines head lines)
 609            (mail-header-set-xref
 610             head (format "%s %s:%d" (system-name) mbx uid))
 611            head))))))
 612
 613 (defun nnimap-retrieve-which-headers (articles fetch-old)
 614   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 615   (with-current-buffer nnimap-server-buffer
 616     (if (numberp (car-safe articles))
 617         (imap-search
 618          (concat "UID "
 619                  (imap-range-to-message-set
 620                   (gnus-compress-sequence
 621                    (append (gnus-uncompress-sequence
 622                             (and fetch-old
 623                                  (cons (if (numberp fetch-old)
 624                                            (max 1 (- (car articles) fetch-old))
 625                                          1)
 626                                        (1- (car articles)))))
 627                            articles)))))
 628       (mapcar (lambda (msgid)
 629                 (imap-search
 630                  (format "HEADER Message-Id \"%s\"" msgid)))
 631               articles))))
 632
 633 (defun nnimap-group-overview-filename (group server)
 634   "Make file name for GROUP on SERVER."
 635   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 636          (uidvalidity (gnus-group-get-parameter
 637                        (gnus-group-prefixed-name
 638                         group (gnus-server-to-method
 639                                (format "nnimap:%s" server)))
 640                        'uidvalidity))
 641          (name (nnheader-translate-file-chars
 642                 (concat nnimap-nov-file-name
 643                         (if (equal server "")
 644                             "unnamed"
 645                           server) "." group nnimap-nov-file-name-suffix) t))
 646          (nameuid (nnheader-translate-file-chars
 647                    (concat nnimap-nov-file-name
 648                            (if (equal server "")
 649                                "unnamed"
 650                              server) "." group "." uidvalidity
 651                              nnimap-nov-file-name-suffix) t))
 652          (oldfile (if (or nnmail-use-long-file-names
 653                           (file-exists-p (expand-file-name name dir)))
 654                       (expand-file-name name dir)
 655                     (expand-file-name
 656                      (encode-coding-string
 657                       (nnheader-replace-chars-in-string name ?. ?/)
 658                       nnmail-pathname-coding-system)
 659                      dir)))
 660          (newfile (if (or nnmail-use-long-file-names
 661                           (file-exists-p (expand-file-name nameuid dir)))
 662                       (expand-file-name nameuid dir)
 663                     (expand-file-name
 664                      (encode-coding-string
 665                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 666                       nnmail-pathname-coding-system)
 667                      dir))))
 668     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 669       (message "nnimap: Upgrading novcache filename...")
 670       (sit-for 1)
 671       (gnus-make-directory (file-name-directory newfile))
 672       (unless (ignore-errors (rename-file oldfile newfile) t)
 673         (if (ignore-errors (copy-file oldfile newfile) t)
 674             (delete-file oldfile)
 675           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 676     newfile))
 677
 678 (defun nnimap-retrieve-headers-from-file (group server)
 679   (with-current-buffer nntp-server-buffer
 680     (let ((nov (nnimap-group-overview-filename group server)))
 681       (when (file-exists-p nov)
 682         (nnheader-insert-file-contents nov)
 683         (set-buffer-modified-p nil)
 684         (let ((min (ignore-errors (goto-char (point-min))
 685                                   (read (current-buffer))))
 686               (max (ignore-errors (goto-char (point-max))
 687                                   (forward-line -1)
 688                                   (read (current-buffer)))))
 689           (if (and (numberp min) (numberp max))
 690               (cons min max)
 691             ;; junk, remove it, it's saved later
 692             (erase-buffer)
 693             nil))))))
 694
 695 (defun nnimap-retrieve-headers-from-server (articles group server)
 696   (with-current-buffer nnimap-server-buffer
 697     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 698           (nnimap-length (gnus-range-length articles))
 699           (nnimap-counter 0))
 700       (imap-fetch (imap-range-to-message-set articles)
 701                   (concat "(UID RFC822.SIZE BODY "
 702                           (let ((headers
 703                                  (append '(Subject From Date Message-Id
 704                                                    References In-Reply-To Xref)
 705                                          (copy-sequence
 706                                           nnmail-extra-headers))))
 707                             (if (imap-capability 'IMAP4rev1)
 708                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 709                               (format "RFC822.HEADER.LINES %s)" headers)))))
 710       (and (numberp nnmail-large-newsgroup)
 711            (> nnimap-length nnmail-large-newsgroup)
 712            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 713
 714 (defun nnimap-dont-use-nov-p (group server)
 715   (or gnus-nov-is-evil nnimap-nov-is-evil
 716       (unless (and (gnus-make-directory
 717                     (file-name-directory
 718                      (nnimap-group-overview-filename group server)))
 719                    (file-writable-p
 720                     (nnimap-group-overview-filename group server)))
 721         (message "nnimap: Nov cache not writable, %s"
 722                  (nnimap-group-overview-filename group server)))))
 723
 724 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 725   (when (nnimap-possibly-change-group group server)
 726     (with-current-buffer nntp-server-buffer
 727       (erase-buffer)
 728       (if (nnimap-dont-use-nov-p group server)
 729           (nnimap-retrieve-headers-from-server
 730            (gnus-compress-sequence articles) group server)
 731         (let (uids cached low high)
 732           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 733                       low (car uids)
 734                       high (car (last uids)))
 735             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 736                 (progn
 737                   ;; fetch articles with uids before cache block
 738                   (when (< low (car cached))
 739                     (goto-char (point-min))
 740                     (nnimap-retrieve-headers-from-server
 741                      (cons low (1- (car cached))) group server))
 742                   ;; fetch articles with uids after cache block
 743                   (when (> high (cdr cached))
 744                     (goto-char (point-max))
 745                     (nnimap-retrieve-headers-from-server
 746                      (cons (1+ (cdr cached)) high) group server))
 747                   (when nnimap-prune-cache
 748                     ;; remove nov's for articles which has expired on server
 749                     (goto-char (point-min))
 750                     (dolist (uid (gnus-set-difference articles uids))
 751                       (when (re-search-forward (format "^%d\t" uid) nil t)
 752                         (gnus-delete-line)))))
 753               ;; nothing cached, fetch whole range from server
 754               (nnimap-retrieve-headers-from-server
 755                (cons low high) group server))
 756             (when (buffer-modified-p)
 757               (nnmail-write-region
 758                (point-min) (point-max)
 759                (nnimap-group-overview-filename group server) nil 'nomesg))
 760             (nnheader-nov-delete-outside-range low high))))
 761       'nov)))
 762
 763 (defun nnimap-open-connection (server)
 764   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 765                       nnimap-authenticator nnimap-server-buffer))
 766       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 767     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 768                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 769       (imap-close nnimap-server-buffer)
 770       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 771     (let* ((list (netrc-parse nnimap-authinfo-file))
 772            (port (if nnimap-server-port
 773                      (int-to-string nnimap-server-port)
 774                    "imap"))
 775            (user (netrc-machine-user-or-password
 776                   "login"
 777                   list
 778                   (list server
 779                         (or nnimap-server-address
 780                             nnimap-address))
 781                   (list port)
 782                   (list "imap" "imaps")))
 783            (passwd (netrc-machine-user-or-password
 784                     "password"
 785                     list
 786                     (list server
 787                           (or nnimap-server-address
 788                               nnimap-address))
 789                     (list port)
 790                     (list "imap" "imaps"))))
 791       (if (imap-authenticate user passwd nnimap-server-buffer)
 792           (prog2
 793               (setq nnimap-server-buffer-alist
 794                     (nnimap-remove-server-from-buffer-alist
 795                      server
 796                      nnimap-server-buffer-alist))
 797               (push (list server nnimap-server-buffer)
 798                     nnimap-server-buffer-alist)
 799             (imap-id nnimap-id nnimap-server-buffer)
 800             (nnimap-possibly-change-server server))
 801         (imap-close nnimap-server-buffer)
 802         (kill-buffer nnimap-server-buffer)
 803         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 804
 805 (deffoo nnimap-open-server (server &optional defs)
 806   (nnheader-init-server-buffer)
 807   (if (nnimap-server-opened server)
 808       t
 809     (unless (assq 'nnimap-server-buffer defs)
 810       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 811     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 812     ;; for people that configured nnimap with a very old version
 813     (unless (assq 'nnimap-address defs)
 814       (if (assq 'nnimap-server-address defs)
 815           (push (list 'nnimap-address
 816                       (cadr (assq 'nnimap-server-address defs))) defs)
 817         (push (list 'nnimap-address server) defs)))
 818     (nnoo-change-server 'nnimap server defs)
 819     (or nnimap-server-buffer
 820         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 821     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 822       (nnoo-change-server 'nnimap server defs))
 823     (or (and nnimap-server-buffer
 824              (imap-opened nnimap-server-buffer)
 825              (if (with-current-buffer nnimap-server-buffer
 826                    (memq imap-state '(auth select examine)))
 827                  t
 828                (imap-close nnimap-server-buffer)
 829                (nnimap-open-connection server)))
 830         (nnimap-open-connection server))))
 831
 832 (deffoo nnimap-server-opened (&optional server)
 833   "Whether SERVER is opened.
 834 If SERVER is the current virtual server, and the connection to the
 835 physical server is alive, this function return a non-nil value.  If
 836 SERVER is nil, it is treated as the current server."
 837   ;; clean up autologouts??
 838   (and (or server nnimap-current-server)
 839        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 840        (imap-opened (nnimap-get-server-buffer server))))
 841
 842 (deffoo nnimap-close-server (&optional server)
 843   "Close connection to server and free all resources connected to it.
 844 Return nil if the server couldn't be closed for some reason."
 845   (let ((server (or server nnimap-current-server)))
 846     (when (or (nnimap-server-opened server)
 847               (imap-opened (nnimap-get-server-buffer server)))
 848       (imap-close (nnimap-get-server-buffer server))
 849       (kill-buffer (nnimap-get-server-buffer server))
 850       (setq nnimap-server-buffer nil
 851             nnimap-current-server nil
 852             nnimap-server-buffer-alist
 853             (nnimap-remove-server-from-buffer-alist
 854              server
 855              nnimap-server-buffer-alist)))
 856     (nnoo-close-server 'nnimap server)))
 857
 858 (deffoo nnimap-request-close ()
 859   "Close connection to all servers and free all resources that the backend have reserved.
 860 All buffers that have been created by that
 861 backend should be killed.  (Not the nntp-server-buffer, though.) This
 862 function is generally only called when Gnus is shutting down."
 863   (mapc (lambda (server) (nnimap-close-server (car server)))
 864         nnimap-server-buffer-alist)
 865   (setq nnimap-server-buffer-alist nil))
 866
 867 (deffoo nnimap-status-message (&optional server)
 868   "This function returns the last error message from server."
 869   (when (nnimap-possibly-change-server server)
 870     (nnoo-status-message 'nnimap server)))
 871
 872 (defun nnimap-demule (string)
 873   ;; BEWARE: we used to use string-as-multibyte here which is braindead
 874   ;; because it will turn accidental emacs-mule-valid byte sequences
 875   ;; into multibyte chars.  --Stef
 876   ;; Reverted, braindead got 7.5 out of 10 on imdb, so it can't be
 877   ;; that bad. --Simon
 878   (funcall (if (and (fboundp 'string-as-multibyte)
 879                     (subrp (symbol-function 'string-as-multibyte)))
 880                'string-as-multibyte
 881              'identity)
 882            (or string "")))
 883
 884 (defun nnimap-make-callback (article gnus-callback buffer)
 885   "Return a callback function."
 886   `(lambda ()
 887      (nnimap-callback ,article ,gnus-callback ,buffer)))
 888
 889 (defun nnimap-callback (article gnus-callback buffer)
 890   (when (eq article (imap-current-message))
 891     (remove-hook 'imap-fetch-data-hook
 892                  (nnimap-make-callback article gnus-callback buffer))
 893     (with-current-buffer buffer
 894       (insert
 895        (with-current-buffer nnimap-server-buffer
 896          (nnimap-demule
 897           (if (imap-capability 'IMAP4rev1)
 898               ;; xxx don't just use car? alist doesn't contain
 899               ;; anything else now, but it might...
 900               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 901             (imap-message-get article 'RFC822)))))
 902       (nnheader-ms-strip-cr)
 903       (funcall gnus-callback t))))
 904
 905 (defun nnimap-request-article-part (article part prop &optional
 906                                             group server to-buffer detail)
 907   (when (nnimap-possibly-change-group group server)
 908     (let ((article (if (stringp article)
 909                        (car-safe (imap-search
 910                                   (format "HEADER Message-Id \"%s\"" article)
 911                                   nnimap-server-buffer))
 912                      article)))
 913       (when article
 914         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 915                       article (or group imap-current-mailbox
 916                                   gnus-newsgroup-name))
 917         (if (not nnheader-callback-function)
 918             (with-current-buffer (or to-buffer nntp-server-buffer)
 919               (erase-buffer)
 920               (let ((data (imap-fetch article part prop nil
 921                                       nnimap-server-buffer)))
 922                 (when data
 923                   (insert (nnimap-demule (if detail (nth 2 (car data)) data)))
 924                   (nnheader-ms-strip-cr)
 925                   (gnus-message
 926                    10 "nnimap: Fetching (part of) article %d from %s...done"
 927                    article (or group imap-current-mailbox gnus-newsgroup-name))
 928                   (if (bobp)
 929                       (nnheader-report 'nnimap "No such article %d in %s: %s"
 930                                        article (or group imap-current-mailbox
 931                                                    gnus-newsgroup-name)
 932                                        (imap-error-text nnimap-server-buffer))
 933                     (cons group article)))))
 934           (add-hook 'imap-fetch-data-hook
 935                     (nnimap-make-callback article
 936                                           nnheader-callback-function
 937                                           nntp-server-buffer))
 938           (imap-fetch-asynch article part nil nnimap-server-buffer)
 939           (cons group article))))))
 940
 941 (deffoo nnimap-asynchronous-p ()
 942   t)
 943
 944 (deffoo nnimap-request-article (article &optional group server to-buffer)
 945   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 946       (nnimap-request-article-part
 947        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 948     (nnimap-request-article-part
 949      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 950
 951 (deffoo nnimap-request-head (article &optional group server to-buffer)
 952   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 953       (nnimap-request-article-part
 954        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 955     (nnimap-request-article-part
 956      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 957
 958 (deffoo nnimap-request-body (article &optional group server to-buffer)
 959   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 960       (nnimap-request-article-part
 961        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 962     (nnimap-request-article-part
 963      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 964
 965 (deffoo nnimap-request-group (group &optional server fast)
 966   (nnimap-request-update-info-internal
 967    group
 968    (gnus-get-info (gnus-group-prefixed-name
 969                    group (gnus-server-to-method (format "nnimap:%s" server))))
 970    server)
 971   (when (nnimap-possibly-change-group group server)
 972     (nnimap-before-find-minmax-bugworkaround)
 973     (let (info)
 974       (cond (fast group)
 975             ((null (setq info (nnimap-find-minmax-uid group t)))
 976              (nnheader-report 'nnimap "Could not get active info for %s"
 977                               group))
 978             (t
 979              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 980                               (max 1 (or (nth 1 info) 1))
 981                               (or (nth 2 info) 0) group)
 982              (nnheader-report 'nnimap "Group %s selected" group)
 983              t)))))
 984
 985 (defun nnimap-update-unseen (group &optional server)
 986   "Update the unseen count in `nnimap-mailbox-info'."
 987   (gnus-sethash
 988    (gnus-group-prefixed-name group server)
 989    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
 990                                  nnimap-mailbox-info)))
 991      (list (nth 0 old) (nth 1 old)
 992            (imap-mailbox-status group 'unseen nnimap-server-buffer)
 993            (nth 3 old)))
 994    nnimap-mailbox-info))
 995
 996 (defun nnimap-close-group (group &optional server)
 997   (with-current-buffer nnimap-server-buffer
 998     (when (and (imap-opened)
 999                (nnimap-possibly-change-group group server))
1000       (nnimap-update-unseen group server)
1001       (case nnimap-expunge-on-close
1002         (always (progn
1003                   (imap-mailbox-expunge nnimap-close-asynchronous)
1004                   (unless nnimap-dont-close
1005                     (imap-mailbox-close nnimap-close-asynchronous))))
1006         (ask (if (and (imap-search "DELETED")
1007                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
1008                                              imap-current-mailbox)))
1009                  (progn
1010                    (imap-mailbox-expunge nnimap-close-asynchronous)
1011                    (unless nnimap-dont-close
1012                      (imap-mailbox-close nnimap-close-asynchronous)))
1013                (imap-mailbox-unselect)))
1014         (t (imap-mailbox-unselect)))
1015       (not imap-current-mailbox))))
1016
1017 (defun nnimap-pattern-to-list-arguments (pattern)
1018   (mapcar (lambda (p)
1019             (cons (car-safe p) (or (cdr-safe p) p)))
1020           (if (and (listp pattern)
1021                    (listp (cdr pattern)))
1022               pattern
1023             (list pattern))))
1024
1025 (deffoo nnimap-request-list (&optional server)
1026   (when (nnimap-possibly-change-server server)
1027     (with-current-buffer nntp-server-buffer
1028       (erase-buffer))
1029     (gnus-message 5 "nnimap: Generating active list%s..."
1030                   (if (> (length server) 0) (concat " for " server) ""))
1031     (nnimap-before-find-minmax-bugworkaround)
1032     (with-current-buffer nnimap-server-buffer
1033       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
1034         (dolist (mbx (funcall nnimap-request-list-method
1035                               (cdr pattern) (car pattern)))
1036           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
1037               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1038                 (when info
1039                   (with-current-buffer nntp-server-buffer
1040                     (insert (format "\"%s\" %d %d y\n"
1041                                     mbx (or (nth 2 info) 0)
1042                                     (max 1 (or (nth 1 info) 1)))))))))))
1043     (gnus-message 5 "nnimap: Generating active list%s...done"
1044                   (if (> (length server) 0) (concat " for " server) ""))
1045     t))
1046
1047 (deffoo nnimap-request-post (&optional server)
1048   (let ((success t))
1049     (dolist (mbx (message-unquote-tokens
1050                   (message-tokenize-header
1051                    (message-fetch-field "Newsgroups") ", ")) success)
1052       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
1053         (or (gnus-active to-newsgroup)
1054             (gnus-activate-group to-newsgroup)
1055             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
1056                                        to-newsgroup))
1057                 (or (and (gnus-request-create-group
1058                           to-newsgroup gnus-command-method)
1059                          (gnus-activate-group to-newsgroup nil nil
1060                                               gnus-command-method))
1061                     (error "Couldn't create group %s" to-newsgroup)))
1062             (error "No such group: %s" to-newsgroup))
1063         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
1064           (setq success nil))))))
1065
1066 ;; Optional backend functions
1067
1068 (defun nnimap-string-lessp-numerical (s1 s2)
1069   "Return t if first arg string is less than second in numerical order."
1070   (cond ((string= s1 s2)
1071          nil)
1072         ((> (length s1) (length s2))
1073          nil)
1074         ((< (length s1) (length s2))
1075          t)
1076         ((< (string-to-number (substring s1 0 1))
1077             (string-to-number (substring s2 0 1)))
1078          t)
1079         ((> (string-to-number (substring s1 0 1))
1080             (string-to-number (substring s2 0 1)))
1081          nil)
1082         (t
1083          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1084
1085 (deffoo nnimap-retrieve-groups (groups &optional server)
1086   (when (nnimap-possibly-change-server server)
1087     (gnus-message 5 "nnimap: Checking mailboxes...")
1088     (with-current-buffer nntp-server-buffer
1089       (erase-buffer)
1090       (nnimap-before-find-minmax-bugworkaround)
1091       (let (asyncgroups slowgroups)
1092         (if (null nnimap-retrieve-groups-asynchronous)
1093             (setq slowgroups groups)
1094           (dolist (group groups)
1095             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1096             (add-to-list (if (gnus-gethash-safe
1097                               (gnus-group-prefixed-name group server)
1098                               nnimap-mailbox-info)
1099                              'asyncgroups
1100                            'slowgroups)
1101                          (list group (imap-mailbox-status-asynch
1102                                       group '(uidvalidity uidnext unseen)
1103                                       nnimap-server-buffer))))
1104           (dolist (asyncgroup asyncgroups)
1105             (let ((group (nth 0 asyncgroup))
1106                   (tag   (nth 1 asyncgroup))
1107                   new old)
1108               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1109                 (if (or (not (string=
1110                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1111                                                     group server)
1112                                                    nnimap-mailbox-info))
1113                               (imap-mailbox-get 'uidvalidity group
1114                                                 nnimap-server-buffer)))
1115                         (not (string=
1116                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1117                                                     group server)
1118                                                    nnimap-mailbox-info))
1119                               (imap-mailbox-get 'uidnext group
1120                                                 nnimap-server-buffer))))
1121                     (push (list group) slowgroups)
1122                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1123                                                 group server)
1124                                                nnimap-mailbox-info))))))))
1125         (dolist (group slowgroups)
1126           (if nnimap-retrieve-groups-asynchronous
1127               (setq group (car group)))
1128           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1129           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1130           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1131                                                      nnimap-server-buffer))
1132               (let* ((info (nnimap-find-minmax-uid group 'examine))
1133                      (str (format "\"%s\" %d %d y\n" group
1134                                   (or (nth 2 info) 0)
1135                                   (max 1 (or (nth 1 info) 1)))))
1136                 (when (> (or (imap-mailbox-get 'recent group
1137                                                nnimap-server-buffer) 0)
1138                          0)
1139                   (push (list (cons group 0)) nnmail-split-history))
1140                 (insert str)
1141                 (when nnimap-retrieve-groups-asynchronous
1142                   (gnus-sethash
1143                    (gnus-group-prefixed-name group server)
1144                    (list (or (imap-mailbox-get
1145                               'uidvalidity group nnimap-server-buffer)
1146                              (imap-mailbox-status
1147                               group 'uidvalidity nnimap-server-buffer))
1148                          (or (imap-mailbox-get
1149                               'uidnext group nnimap-server-buffer)
1150                              (imap-mailbox-status
1151                               group 'uidnext nnimap-server-buffer))
1152                          (or (imap-mailbox-get
1153                               'unseen group nnimap-server-buffer)
1154                              (imap-mailbox-status
1155                               group 'unseen nnimap-server-buffer))
1156                          str)
1157                    nnimap-mailbox-info)))))))
1158     (gnus-message 5 "nnimap: Checking mailboxes...done")
1159     'active))
1160
1161 (deffoo nnimap-request-update-info-internal (group info &optional server)
1162   (when (nnimap-possibly-change-group group server)
1163     (when info;; xxx what does this mean? should we create a info?
1164       (with-current-buffer nnimap-server-buffer
1165         (gnus-message 5 "nnimap: Updating info for %s..."
1166                       (gnus-info-group info))
1167
1168         (when (nnimap-mark-permanent-p 'read)
1169           (let (seen unseen)
1170             ;; read info could contain articles marked unread by other
1171             ;; imap clients!  we correct this
1172             (setq seen (gnus-uncompress-range (gnus-info-read info))
1173                   unseen (imap-search "UNSEEN UNDELETED")
1174                   seen (gnus-set-difference seen unseen)
1175                   ;; seen might lack articles marked as read by other
1176                   ;; imap clients! we correct this
1177                   seen (append seen (imap-search "SEEN"))
1178                   ;; remove dupes
1179                   seen (sort seen '<)
1180                   seen (gnus-compress-sequence seen t)
1181                   ;; we can't return '(1) since this isn't a "list of ranges",
1182                   ;; and we can't return '((1)) since g-list-of-unread-articles
1183                   ;; is buggy so we return '((1 . 1)).
1184                   seen (if (and (integerp (car seen))
1185                                 (null (cdr seen)))
1186                            (list (cons (car seen) (car seen)))
1187                          seen))
1188             (gnus-info-set-read info seen)))
1189
1190         (mapcar (lambda (pred)
1191                   (when (or (eq (cdr pred) 'recent)
1192                             (and (nnimap-mark-permanent-p (cdr pred))
1193                                  (member (nnimap-mark-to-flag (cdr pred))
1194                                          (imap-mailbox-get 'flags))))
1195                     (gnus-info-set-marks
1196                      info
1197                      (gnus-update-alist-soft
1198                       (cdr pred)
1199                       (gnus-compress-sequence
1200                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
1201                       (gnus-info-marks info))
1202                      t)))
1203                 gnus-article-mark-lists)
1204
1205         (when nnimap-importantize-dormant
1206           ;; nnimap mark dormant article as ticked too (for other clients)
1207           ;; so we remove that mark for gnus since we support dormant
1208           (gnus-info-set-marks
1209            info
1210            (gnus-update-alist-soft
1211             'tick
1212             (gnus-remove-from-range
1213              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1214              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1215             (gnus-info-marks info))
1216            t))
1217
1218         (gnus-message 5 "nnimap: Updating info for %s...done"
1219                       (gnus-info-group info))
1220
1221         info))))
1222
1223 (deffoo nnimap-request-type (group &optional article)
1224   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1225       'news
1226     'mail))
1227
1228 (deffoo nnimap-request-set-mark (group actions &optional server)
1229   (when (nnimap-possibly-change-group group server)
1230     (with-current-buffer nnimap-server-buffer
1231       (let (action)
1232         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1233         (while (setq action (pop actions))
1234           (let ((range (nth 0 action))
1235                 (what  (nth 1 action))
1236                 (cmdmarks (nth 2 action))
1237                 marks)
1238             ;; bookmark can't be stored (not list/range
1239             (setq cmdmarks (delq 'bookmark cmdmarks))
1240             ;; killed can't be stored (not list/range
1241             (setq cmdmarks (delq 'killed cmdmarks))
1242             ;; unsent are for nndraft groups only
1243             (setq cmdmarks (delq 'unsent cmdmarks))
1244             ;; cache flags are pointless on the server
1245             (setq cmdmarks (delq 'cache cmdmarks))
1246             ;; seen flags are local to each gnus
1247             (setq cmdmarks (delq 'seen cmdmarks))
1248             ;; recent marks can't be set
1249             (setq cmdmarks (delq 'recent cmdmarks))
1250             (when nnimap-importantize-dormant
1251               ;; flag dormant articles as ticked
1252               (if (memq 'dormant cmdmarks)
1253                   (setq cmdmarks (cons 'tick cmdmarks))))
1254             ;; remove stuff we are forbidden to store
1255             (mapc (lambda (mark)
1256                     (if (imap-message-flag-permanent-p
1257                          (nnimap-mark-to-flag mark))
1258                         (setq marks (cons mark marks))))
1259                   cmdmarks)
1260             (when (and range marks)
1261               (cond ((eq what 'del)
1262                      (imap-message-flags-del
1263                       (imap-range-to-message-set range)
1264                       (nnimap-mark-to-flag marks nil t)))
1265                     ((eq what 'add)
1266                      (imap-message-flags-add
1267                       (imap-range-to-message-set range)
1268                       (nnimap-mark-to-flag marks nil t)))
1269                     ((eq what 'set)
1270                      (imap-message-flags-set
1271                       (imap-range-to-message-set range)
1272                       (nnimap-mark-to-flag marks nil t)))))))
1273         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1274   nil)
1275
1276 (defun nnimap-split-fancy ()
1277   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1278   (let ((nnmail-split-fancy nnimap-split-fancy))
1279     (nnmail-split-fancy)))
1280
1281 (defun nnimap-split-to-groups (rules)
1282   ;; tries to match all rules in nnimap-split-rule against content of
1283   ;; nntp-server-buffer, returns a list of groups that matched.
1284   (with-current-buffer nntp-server-buffer
1285     ;; Fold continuation lines.
1286     (goto-char (point-min))
1287     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1288       (replace-match " " t t))
1289     (if (functionp rules)
1290         (funcall rules)
1291       (let (to-groups regrepp)
1292         (catch 'split-done
1293           (dolist (rule rules to-groups)
1294             (let ((group (car rule))
1295                   (regexp (cadr rule)))
1296               (goto-char (point-min))
1297               (when (and (if (stringp regexp)
1298                              (progn
1299                                (if (not (stringp group))
1300                                    (setq group (eval group))
1301                                  (setq regrepp
1302                                        (string-match "\\\\[0-9&]" group)))
1303                                (re-search-forward regexp nil t))
1304                            (funcall regexp group))
1305                          ;; Don't enter the article into the same group twice.
1306                          (not (assoc group to-groups)))
1307                 (push (if regrepp
1308                           (nnmail-expand-newtext group)
1309                         group)
1310                       to-groups)
1311                 (or nnimap-split-crosspost
1312                     (throw 'split-done to-groups))))))))))
1313
1314 (defun nnimap-assoc-match (key alist)
1315   (let (element)
1316     (while (and alist (not element))
1317       (if (string-match (car (car alist)) key)
1318           (setq element (car alist)))
1319       (setq alist (cdr alist)))
1320     element))
1321
1322 (defun nnimap-split-find-rule (server inbox)
1323   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1324            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1325       ;; extended format
1326       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1327                                             server nnimap-split-rule))))
1328     nnimap-split-rule))
1329
1330 (defun nnimap-split-find-inbox (server)
1331   (if (listp nnimap-split-inbox)
1332       nnimap-split-inbox
1333     (list nnimap-split-inbox)))
1334
1335 (defun nnimap-split-articles (&optional group server)
1336   (when (nnimap-possibly-change-server server)
1337     (with-current-buffer nnimap-server-buffer
1338       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1339         ;; iterate over inboxes
1340         (while (and (setq inbox (pop inboxes))
1341                     (nnimap-possibly-change-group inbox));; SELECT
1342           ;; find split rule for this server / inbox
1343           (when (setq rule (nnimap-split-find-rule server inbox))
1344             ;; iterate over articles
1345             (dolist (article (imap-search nnimap-split-predicate))
1346               (when (if (if (eq nnimap-split-download-body 'default)
1347                             nnimap-split-download-body-default
1348                           nnimap-split-download-body)
1349                         (and (nnimap-request-article article)
1350                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1351                       (nnimap-request-head article))
1352                 ;; copy article to right group(s)
1353                 (setq removeorig nil)
1354                 (dolist (to-group (nnimap-split-to-groups rule))
1355                   (cond ((eq to-group 'junk)
1356                          (message "IMAP split removed %s:%s:%d" server inbox
1357                                   article)
1358                          (setq removeorig t))
1359                         ((imap-message-copy (number-to-string article)
1360                                             to-group nil 'nocopyuid)
1361                          (message "IMAP split moved %s:%s:%d to %s" server
1362                                   inbox article to-group)
1363                          (setq removeorig t)
1364                          (when nnmail-cache-accepted-message-ids
1365                            (with-current-buffer nntp-server-buffer
1366                              (let (msgid)
1367                                (and (setq msgid
1368                                           (nnmail-fetch-field "message-id"))
1369                                     (nnmail-cache-insert msgid
1370                                                          to-group
1371                                                          (nnmail-fetch-field "subject"))))))
1372                          ;; Add the group-art list to the history list.
1373                          (push (list (cons to-group 0)) nnmail-split-history))
1374                         (t
1375                          (message "IMAP split failed to move %s:%s:%d to %s"
1376                                   server inbox article to-group))))
1377                 (if (if (eq nnimap-split-download-body 'default)
1378                         nnimap-split-download-body-default
1379                       nnimap-split-download-body)
1380                     (widen))
1381                 ;; remove article if it was successfully copied somewhere
1382                 (and removeorig
1383                      (imap-message-flags-add (format "%d" article)
1384                                              "\\Seen \\Deleted")))))
1385           (when (imap-mailbox-select inbox);; just in case
1386             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1387             (imap-mailbox-expunge)
1388             (imap-mailbox-close)))
1389         (when nnmail-cache-accepted-message-ids
1390           (nnmail-cache-close))
1391         t))))
1392
1393 (deffoo nnimap-request-scan (&optional group server)
1394   (nnimap-split-articles group server))
1395
1396 (deffoo nnimap-request-newgroups (date &optional server)
1397   (when (nnimap-possibly-change-server server)
1398     (with-current-buffer nntp-server-buffer
1399       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1400                     (if (> (length server) 0) " on " "") server)
1401       (erase-buffer)
1402       (nnimap-before-find-minmax-bugworkaround)
1403       (dolist (pattern (nnimap-pattern-to-list-arguments
1404                         nnimap-list-pattern))
1405         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1406                                         nnimap-server-buffer))
1407           (or (catch 'found
1408                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1409                                                    nnimap-server-buffer))
1410                   (if (string= (downcase mailbox) "\\noselect")
1411                       (throw 'found t)))
1412                 nil)
1413               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1414                 (when info
1415                   (insert (format "\"%s\" %d %d y\n"
1416                                   mbx (or (nth 2 info) 0)
1417                                   (max 1 (or (nth 1 info) 1)))))))))
1418       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1419                     (if (> (length server) 0) " on " "") server))
1420     t))
1421
1422 (deffoo nnimap-request-create-group (group &optional server args)
1423   (when (nnimap-possibly-change-server server)
1424     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1425         (imap-mailbox-create group nnimap-server-buffer)
1426         (nnheader-report 'nnimap "%S"
1427                          (imap-error-text nnimap-server-buffer)))))
1428
1429 (defun nnimap-time-substract (time1 time2)
1430   "Return TIME for TIME1 - TIME2."
1431   (let* ((ms (- (car time1) (car time2)))
1432          (ls (- (nth 1 time1) (nth 1 time2))))
1433     (if (< ls 0)
1434         (list (- ms 1) (+ (expt 2 16) ls))
1435       (list ms ls))))
1436
1437 (defun nnimap-date-days-ago (daysago)
1438   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1439   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1440          (date (format-time-string
1441                 (format "%%d-%s-%%Y"
1442                         (capitalize (car (rassoc (nth 4 (decode-time time))
1443                                                  parse-time-months))))
1444                 time)))
1445     (if (eq ?0 (string-to-char date))
1446         (substring date 1)
1447       date)))
1448
1449 (defun nnimap-request-expire-articles-progress ()
1450   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1451                 imap-current-message))
1452
1453 (defun nnimap-expiry-target (arts group server)
1454   (unless (eq nnmail-expiry-target 'delete)
1455     (with-temp-buffer
1456       (dolist (art arts)
1457         (nnimap-request-article art group server (current-buffer))
1458         ;; hints for optimization in `nnimap-request-accept-article'
1459         (let ((nnimap-current-move-article art)
1460               (nnimap-current-move-group group)
1461               (nnimap-current-move-server server))
1462           (nnmail-expiry-target-group nnmail-expiry-target group))))
1463     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1464     ;; current group to be changed or not, so we make sure here.
1465     (nnimap-possibly-change-group group server)))
1466
1467 ;; Notice that we don't actually delete anything, we just mark them deleted.
1468 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1469   (let ((artseq (gnus-compress-sequence articles)))
1470     (when (and artseq (nnimap-possibly-change-group group server))
1471       (with-current-buffer nnimap-server-buffer
1472         (let ((days (or (and nnmail-expiry-wait-function
1473                              (funcall nnmail-expiry-wait-function group))
1474                         nnmail-expiry-wait)))
1475           (cond ((or force (eq days 'immediate))
1476                  (let ((oldarts (imap-search
1477                                  (concat "UID "
1478                                          (imap-range-to-message-set artseq)))))
1479                    (when oldarts
1480                      (nnimap-expiry-target oldarts group server)
1481                      (when (imap-message-flags-add
1482                             (imap-range-to-message-set
1483                              (gnus-compress-sequence oldarts)) "\\Deleted")
1484                        (setq articles (gnus-set-difference
1485                                        articles oldarts))))))
1486                 ((numberp days)
1487                  (let ((oldarts (imap-search
1488                                  (format nnimap-expunge-search-string
1489                                          (imap-range-to-message-set artseq)
1490                                          (nnimap-date-days-ago days))))
1491                        (imap-fetch-data-hook
1492                         '(nnimap-request-expire-articles-progress)))
1493                    (when oldarts
1494                      (nnimap-expiry-target oldarts group server)
1495                      (when (imap-message-flags-add
1496                             (imap-range-to-message-set
1497                              (gnus-compress-sequence oldarts)) "\\Deleted")
1498                        (setq articles (gnus-set-difference
1499                                        articles oldarts)))))))))))
1500   ;; return articles not deleted
1501   articles)
1502
1503 (deffoo nnimap-request-move-article (article group server
1504                                              accept-form &optional last)
1505   (when (nnimap-possibly-change-server server)
1506     (save-excursion
1507       (let ((buf (get-buffer-create " *nnimap move*"))
1508             (nnimap-current-move-article article)
1509             (nnimap-current-move-group group)
1510             (nnimap-current-move-server nnimap-current-server)
1511             result)
1512         (and (nnimap-request-article article group server)
1513              (save-excursion
1514                (set-buffer buf)
1515                (buffer-disable-undo (current-buffer))
1516                (insert-buffer-substring nntp-server-buffer)
1517                (setq result (eval accept-form))
1518                (kill-buffer buf)
1519                result)
1520              (imap-message-flags-add
1521               (imap-range-to-message-set (list article))
1522               "\\Deleted" 'silent nnimap-server-buffer))
1523         result))))
1524
1525 (deffoo nnimap-request-accept-article (group &optional server last)
1526   (when (nnimap-possibly-change-server server)
1527     (let (uid)
1528       (if (setq uid
1529                 (if (string= nnimap-current-server nnimap-current-move-server)
1530                     ;; moving article within same server, speed it up...
1531                     (and (nnimap-possibly-change-group
1532                           nnimap-current-move-group)
1533                          (imap-message-copy (number-to-string
1534                                              nnimap-current-move-article)
1535                                             group 'dontcreate nil
1536                                             nnimap-server-buffer))
1537                   (with-current-buffer (current-buffer)
1538                     (goto-char (point-min))
1539                     ;; remove any 'From blabla' lines, some IMAP servers
1540                     ;; reject the entire message otherwise.
1541                     (when (looking-at "^From[^:]")
1542                       (delete-region (point) (progn (forward-line) (point))))
1543                     ;; turn into rfc822 format (\r\n eol's)
1544                     (while (search-forward "\n" nil t)
1545                       (replace-match "\r\n"))
1546                     (when nnmail-cache-accepted-message-ids
1547                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1548                                            group
1549                                            (nnmail-fetch-field "subject"))))
1550                   (when (and last nnmail-cache-accepted-message-ids)
1551                     (nnmail-cache-close))
1552                   ;; this 'or' is for Cyrus server bug
1553                   (or (null (imap-current-mailbox nnimap-server-buffer))
1554                       (imap-mailbox-unselect nnimap-server-buffer))
1555                   (imap-message-append group (current-buffer) nil nil
1556                                        nnimap-server-buffer)))
1557           (cons group (nth 1 uid))
1558         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1559
1560 (deffoo nnimap-request-delete-group (group force &optional server)
1561   (when (nnimap-possibly-change-server server)
1562     (with-current-buffer nnimap-server-buffer
1563       (if force
1564           (or (null (imap-mailbox-status group 'uidvalidity))
1565               (imap-mailbox-delete group))
1566         ;; UNSUBSCRIBE?
1567         t))))
1568
1569 (deffoo nnimap-request-rename-group (group new-name &optional server)
1570   (when (nnimap-possibly-change-server server)
1571     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1572
1573 (defun nnimap-expunge (mailbox server)
1574   (when (nnimap-possibly-change-group mailbox server)
1575     (imap-mailbox-expunge nil nnimap-server-buffer)))
1576
1577 (defun nnimap-acl-get (mailbox server)
1578   (when (nnimap-possibly-change-server server)
1579     (and (imap-capability 'ACL nnimap-server-buffer)
1580          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1581
1582 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1583   (when (nnimap-possibly-change-server (cadr method))
1584     (unless (imap-capability 'ACL nnimap-server-buffer)
1585       (error "Your server does not support ACL editing"))
1586     (with-current-buffer nnimap-server-buffer
1587       ;; delete all removed identifiers
1588       (mapc (lambda (old-acl)
1589               (unless (assoc (car old-acl) new-acls)
1590                 (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1591                     (error "Can't delete ACL for %s" (car old-acl)))))
1592             old-acls)
1593       ;; set all changed acl's
1594       (mapc (lambda (new-acl)
1595               (let ((new-rights (cdr new-acl))
1596                     (old-rights (cdr (assoc (car new-acl) old-acls))))
1597                 (unless (and old-rights new-rights
1598                              (string= old-rights new-rights))
1599                   (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1600                       (error "Can't set ACL for %s to %s" (car new-acl)
1601                              new-rights)))))
1602             new-acls)
1603       t)))
1604
1605 \f
1606 ;;; Internal functions
1607
1608 ;;
1609 ;; This is confusing.
1610 ;;
1611 ;; mark      => read, tick, draft, reply etc
1612 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1613 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1614 ;;
1615 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1616 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1617 ;;
1618
1619 (defconst nnimap-mark-to-predicate-alist
1620   (mapcar
1621    (lambda (pair)                       ; cdr is the mark
1622      (or (assoc (cdr pair)
1623                 '((read . "SEEN")
1624                   (tick . "FLAGGED")
1625                   (draft . "DRAFT")
1626                   (recent . "RECENT")
1627                   (reply . "ANSWERED")))
1628          (cons (cdr pair)
1629                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1630    (cons '(read . read) gnus-article-mark-lists)))
1631
1632 (defun nnimap-mark-to-predicate (pred)
1633   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1634 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1635 to be used within a IMAP SEARCH query."
1636   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1637
1638 (defconst nnimap-mark-to-flag-alist
1639   (mapcar
1640    (lambda (pair)
1641      (or (assoc (cdr pair)
1642                 '((read . "\\Seen")
1643                   (tick . "\\Flagged")
1644                   (draft . "\\Draft")
1645                   (recent . "\\Recent")
1646                   (reply . "\\Answered")))
1647          (cons (cdr pair)
1648                (format "gnus-%s" (symbol-name (cdr pair))))))
1649    (cons '(read . read) gnus-article-mark-lists)))
1650
1651 (defun nnimap-mark-to-flag-1 (preds)
1652   (if (and (not (null preds)) (listp preds))
1653       (cons (nnimap-mark-to-flag (car preds))
1654             (nnimap-mark-to-flag (cdr preds)))
1655     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1656
1657 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1658   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1659 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1660 be used in a STORE FLAGS command."
1661   (let ((result (nnimap-mark-to-flag-1 preds)))
1662     (setq result (if (and (or make-string always-list)
1663                           (not (listp result)))
1664                      (list result)
1665                    result))
1666     (if make-string
1667         (mapconcat (lambda (flag)
1668                      (if (listp flag)
1669                          (mapconcat 'identity flag " ")
1670                        flag))
1671                    result " ")
1672       result)))
1673
1674 (defun nnimap-mark-permanent-p (mark &optional group)
1675   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1676   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1677
1678 (when nnimap-debug
1679   (require 'trace)
1680   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1681   (mapcar (lambda (f) (trace-function-background f nnimap-debug-buffer))
1682           '(
1683             nnimap-possibly-change-server
1684             nnimap-verify-uidvalidity
1685             nnimap-find-minmax-uid
1686             nnimap-before-find-minmax-bugworkaround
1687             nnimap-possibly-change-group
1688             ;;nnimap-replace-whitespace
1689             nnimap-retrieve-headers-progress
1690             nnimap-retrieve-which-headers
1691             nnimap-group-overview-filename
1692             nnimap-retrieve-headers-from-file
1693             nnimap-retrieve-headers-from-server
1694             nnimap-retrieve-headers
1695             nnimap-open-connection
1696             nnimap-open-server
1697             nnimap-server-opened
1698             nnimap-close-server
1699             nnimap-request-close
1700             nnimap-status-message
1701             ;;nnimap-demule
1702             nnimap-request-article-part
1703             nnimap-request-article
1704             nnimap-request-head
1705             nnimap-request-body
1706             nnimap-request-group
1707             nnimap-close-group
1708             nnimap-pattern-to-list-arguments
1709             nnimap-request-list
1710             nnimap-request-post
1711             nnimap-retrieve-groups
1712             nnimap-request-update-info-internal
1713             nnimap-request-type
1714             nnimap-request-set-mark
1715             nnimap-split-to-groups
1716             nnimap-split-find-rule
1717             nnimap-split-find-inbox
1718             nnimap-split-articles
1719             nnimap-request-scan
1720             nnimap-request-newgroups
1721             nnimap-request-create-group
1722             nnimap-time-substract
1723             nnimap-date-days-ago
1724             nnimap-request-expire-articles-progress
1725             nnimap-request-expire-articles
1726             nnimap-request-move-article
1727             nnimap-request-accept-article
1728             nnimap-request-delete-group
1729             nnimap-request-rename-group
1730             gnus-group-nnimap-expunge
1731             gnus-group-nnimap-edit-acl
1732             gnus-group-nnimap-edit-acl-done
1733             nnimap-group-mode-hook
1734             nnimap-mark-to-predicate
1735             nnimap-mark-to-flag-1
1736             nnimap-mark-to-flag
1737             nnimap-mark-permanent-p
1738             )))
1739
1740 (provide 'nnimap)
1741
1742 ;;; nnimap.el ends here