git.chise.org Git - elisp/gnus.git-/blob - lisp/nnkiboze.el

   1 ;;; nnkiboze.el --- select virtual news access for Gnus
   2 ;; Copyright (C) 1995,96,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; The other access methods (nntp, nnspool, etc) are general news
  27 ;; access methods.  This module relies on Gnus and can't be used
  28 ;; separately.
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33 (eval-when-compile (require 'gnus-clfns))
  34
  35 (require 'nntp)
  36 (require 'nnheader)
  37 (require 'gnus)
  38 (require 'gnus-score)
  39 (require 'nnoo)
  40
  41 (nnoo-declare nnkiboze)
  42 (defvoo nnkiboze-directory (nnheader-concat gnus-directory "kiboze/")
  43   "nnkiboze will put its files in this directory.")
  44
  45 (defvoo nnkiboze-level 9
  46   "The maximum level to be searched for articles.")
  47
  48 (defvoo nnkiboze-remove-read-articles t
  49   "If non-nil, nnkiboze will remove read articles from the kiboze group.")
  50
  51 (defvoo nnkiboze-ephemeral nil
  52   "If non-nil, don't store any data anywhere.")
  53
  54 (defvoo nnkiboze-scores nil
  55   "Score rules for generating the nnkiboze group.")
  56
  57 (defvoo nnkiboze-regexp nil
  58   "Regexp for matching component groups.")
  59
  60 \f
  61
  62 (defconst nnkiboze-version "nnkiboze 1.0")
  63
  64 (defvoo nnkiboze-current-group nil)
  65 (defvoo nnkiboze-status-string "")
  66
  67 (defvoo nnkiboze-headers nil)
  68
  69 \f
  70
  71 ;;; Interface functions.
  72
  73 (nnoo-define-basics nnkiboze)
  74
  75 (deffoo nnkiboze-retrieve-headers (articles &optional group server fetch-old)
  76   (nnkiboze-possibly-change-group group)
  77   (unless gnus-nov-is-evil
  78     (if (stringp (car articles))
  79         'headers
  80       (let ((nov (nnkiboze-nov-file-name)))
  81         (when (file-exists-p nov)
  82           (save-excursion
  83             (set-buffer nntp-server-buffer)
  84             (erase-buffer)
  85             (nnheader-insert-file-contents nov)
  86             (nnheader-nov-delete-outside-range
  87              (car articles) (car (last articles)))
  88             'nov))))))
  89
  90 (deffoo nnkiboze-request-article (article &optional newsgroup server buffer)
  91   (nnkiboze-possibly-change-group newsgroup)
  92   (if (not (numberp article))
  93       ;; This is a real kludge.  It might not work at times, but it
  94       ;; does no harm I think.  The only alternative is to offer no
  95       ;; article fetching by message-id at all.
  96       (nntp-request-article article newsgroup gnus-nntp-server buffer)
  97     (let* ((header (gnus-summary-article-header article))
  98            (xref (mail-header-xref header)))
  99       (unless xref
 100         (error "nnkiboze: No xref"))
 101       (unless (string-match " \\([^ ]+\\):\\([0-9]+\\)" xref)
 102         (error "nnkiboze: Malformed xref"))
 103       (gnus-request-article (string-to-int (match-string 2 xref))
 104                             (match-string 1 xref)
 105                             buffer))))
 106
 107 (deffoo nnkiboze-request-scan (&optional group server)
 108   (nnkiboze-generate-group (concat "nnkiboze:" group)))
 109
 110 (deffoo nnkiboze-request-group (group &optional server dont-check)
 111   "Make GROUP the current newsgroup."
 112   (nnkiboze-possibly-change-group group)
 113   (if dont-check
 114       t
 115     (let ((nov-file (nnkiboze-nov-file-name))
 116           beg end total)
 117       (save-excursion
 118         (set-buffer nntp-server-buffer)
 119         (erase-buffer)
 120         (unless (file-exists-p nov-file)
 121           (nnkiboze-request-scan group))
 122         (if (not (file-exists-p nov-file))
 123             (nnheader-report 'nnkiboze "Can't select group %s" group)
 124           (nnheader-insert-file-contents nov-file)
 125           (if (zerop (buffer-size))
 126               (nnheader-insert "211 0 0 0 %s\n" group)
 127             (goto-char (point-min))
 128             (when (looking-at "[0-9]+")
 129               (setq beg (read (current-buffer))))
 130             (goto-char (point-max))
 131             (when (re-search-backward "^[0-9]" nil t)
 132               (setq end (read (current-buffer))))
 133             (setq total (count-lines (point-min) (point-max)))
 134             (nnheader-insert "211 %d %d %d %s\n" total beg end group)))))))
 135
 136 (deffoo nnkiboze-close-group (group &optional server)
 137   (nnkiboze-possibly-change-group group)
 138   ;; Remove NOV lines of articles that are marked as read.
 139   (when (and (file-exists-p (nnkiboze-nov-file-name))
 140              nnkiboze-remove-read-articles)
 141     (with-temp-file (nnkiboze-nov-file-name)
 142       (let ((cur (current-buffer)))
 143         (nnheader-insert-file-contents (nnkiboze-nov-file-name))
 144         (goto-char (point-min))
 145         (while (not (eobp))
 146           (if (not (gnus-article-read-p (read cur)))
 147               (forward-line 1)
 148             (gnus-delete-line))))))
 149   (setq nnkiboze-current-group nil))
 150
 151 (deffoo nnkiboze-open-server (server &optional defs)
 152   (unless (assq 'nnkiboze-regexp defs)
 153     (push `(nnkiboze-regexp ,server)
 154           defs))
 155   (nnoo-change-server 'nnkiboze server defs))
 156
 157 (deffoo nnkiboze-request-delete-group (group &optional force server)
 158   (nnkiboze-possibly-change-group group)
 159   (when force
 160     (let ((files (nconc
 161                   (nnkiboze-score-file group)
 162                   (list (nnkiboze-nov-file-name)
 163                         (nnkiboze-nov-file-name ".newsrc")))))
 164       (while files
 165         (and (file-exists-p (car files))
 166              (file-writable-p (car files))
 167              (delete-file (car files)))
 168         (setq files (cdr files)))))
 169   (setq nnkiboze-current-group nil)
 170   t)
 171
 172 (nnoo-define-skeleton nnkiboze)
 173
 174 \f
 175 ;;; Internal functions.
 176
 177 (defun nnkiboze-possibly-change-group (group)
 178   (setq nnkiboze-current-group group))
 179
 180 (defun nnkiboze-prefixed-name (group)
 181   (gnus-group-prefixed-name group '(nnkiboze "")))
 182
 183 ;;;###autoload
 184 (defun nnkiboze-generate-groups ()
 185   "\"Usage: emacs -batch -l nnkiboze -f nnkiboze-generate-groups\".
 186 Finds out what articles are to be part of the nnkiboze groups."
 187   (interactive)
 188   (let ((nnmail-spool-file nil)
 189         (gnus-use-dribble-file nil)
 190         (gnus-read-active-file t)
 191         (gnus-expert-user t))
 192     (gnus))
 193   (let* ((gnus-newsrc-alist (gnus-copy-sequence gnus-newsrc-alist))
 194          (newsrc (cdr gnus-newsrc-alist))
 195          gnus-newsrc-hashtb info)
 196     (gnus-make-hashtable-from-newsrc-alist)
 197     ;; We have copied all the newsrc alist info over to local copies
 198     ;; so that we can mess all we want with these lists.
 199     (while (setq info (pop newsrc))
 200       (when (string-match "nnkiboze" (gnus-info-group info))
 201         ;; For each kiboze group, we call this function to generate
 202         ;; it.
 203         (nnkiboze-generate-group (gnus-info-group info))))))
 204
 205 (defun nnkiboze-score-file (group)
 206   (list (expand-file-name
 207          (concat (file-name-as-directory gnus-kill-files-directory)
 208                  (nnheader-translate-file-chars
 209                   (concat (nnkiboze-prefixed-name nnkiboze-current-group)
 210                           "." gnus-score-file-suffix))))))
 211
 212 (defun nnkiboze-generate-group (group)
 213   (let* ((info (nth 2 (gnus-gethash group gnus-newsrc-hashtb)))
 214          (newsrc-file (concat nnkiboze-directory
 215                               (nnheader-translate-file-chars
 216                                (concat group ".newsrc"))))
 217          (nov-file (concat nnkiboze-directory
 218                            (nnheader-translate-file-chars
 219                             (concat group ".nov"))))
 220          method nnkiboze-newsrc gname newsrc active
 221          ginfo lowest glevel orig-info nov-buffer
 222          ;; Bind various things to nil to make group entry faster.
 223          (gnus-expert-user t)
 224          (gnus-large-newsgroup nil)
 225          (gnus-score-find-score-files-function 'nnkiboze-score-file)
 226          (gnus-verbose (min gnus-verbose 3))
 227          gnus-select-group-hook gnus-summary-prepare-hook
 228          gnus-thread-sort-functions gnus-show-threads
 229          gnus-visual gnus-suppress-duplicates num-unread)
 230     (unless info
 231       (error "No such group: %s" group))
 232     ;; Load the kiboze newsrc file for this group.
 233     (when (file-exists-p newsrc-file)
 234       (load newsrc-file))
 235     (with-temp-file nov-file
 236       (when (file-exists-p nov-file)
 237         (nnheader-insert-file-contents nov-file))
 238       (setq nov-buffer (current-buffer))
 239       ;; Go through the active hashtb and add new all groups that match the
 240       ;; kiboze regexp.
 241       (mapatoms
 242        (lambda (group)
 243          (and (string-match nnkiboze-regexp
 244                             (setq gname (symbol-name group))) ; Match
 245               (not (assoc gname nnkiboze-newsrc)) ; It isn't registered
 246               (numberp (car (symbol-value group))) ; It is active
 247               (or (> nnkiboze-level 7)
 248                   (and (setq glevel (nth 1 (nth 2 (gnus-gethash
 249                                                    gname gnus-newsrc-hashtb))))
 250                        (>= nnkiboze-level glevel)))
 251               (not (string-match "^nnkiboze:" gname)) ; Exclude kibozes
 252               (push (cons gname (1- (car (symbol-value group))))
 253                     nnkiboze-newsrc)))
 254        gnus-active-hashtb)
 255       ;; `newsrc' is set to the list of groups that possibly are
 256       ;; component groups to this kiboze group.  This list has elements
 257       ;; on the form `(GROUP . NUMBER)', where NUMBER is the highest
 258       ;; number that has been kibozed in GROUP in this kiboze group.
 259       (setq newsrc nnkiboze-newsrc)
 260       (while newsrc
 261         (if (not (setq active (gnus-gethash
 262                                (caar newsrc) gnus-active-hashtb)))
 263             ;; This group isn't active after all, so we remove it from
 264             ;; the list of component groups.
 265             (setq nnkiboze-newsrc (delq (car newsrc) nnkiboze-newsrc))
 266           (setq lowest (cdar newsrc))
 267           ;; Ok, we have a valid component group, so we jump to it.
 268           (switch-to-buffer gnus-group-buffer)
 269           (gnus-group-jump-to-group (caar newsrc))
 270           (gnus-message 3 "nnkiboze: Checking %s..." (caar newsrc))
 271           (setq ginfo (gnus-get-info (gnus-group-group-name))
 272                 orig-info (gnus-copy-sequence ginfo)
 273                 num-unread (car (gnus-gethash (caar newsrc)
 274                                               gnus-newsrc-hashtb)))
 275           (unwind-protect
 276               (progn
 277                 ;; We set all list of article marks to nil.  Since we operate
 278                 ;; on copies of the real lists, we can destroy anything we
 279                 ;; want here.
 280                 (when (nth 3 ginfo)
 281                   (setcar (nthcdr 3 ginfo) nil))
 282                 ;; We set the list of read articles to be what we expect for
 283                 ;; this kiboze group -- either nil or `(1 . LOWEST)'.
 284                 (when ginfo
 285                   (setcar (nthcdr 2 ginfo)
 286                           (and (not (= lowest 1)) (cons 1 lowest))))
 287                 (when (and (or (not ginfo)
 288                                (> (length (gnus-list-of-unread-articles
 289                                            (car ginfo)))
 290                                   0))
 291                            (progn
 292                              (ignore-errors
 293                                (gnus-group-select-group nil))
 294                              (eq major-mode 'gnus-summary-mode)))
 295                   ;; We are now in the group where we want to be.
 296                   (setq method (gnus-find-method-for-group
 297                                 gnus-newsgroup-name))
 298                   (when (eq method gnus-select-method)
 299                     (setq method nil))
 300                   ;; We go through the list of scored articles.
 301                   (while gnus-newsgroup-scored
 302                     (when (> (caar gnus-newsgroup-scored) lowest)
 303                       ;; If it has a good score, then we enter this article
 304                       ;; into the kiboze group.
 305                       (nnkiboze-enter-nov
 306                        nov-buffer
 307                        (gnus-summary-article-header
 308                         (caar gnus-newsgroup-scored))
 309                        gnus-newsgroup-name))
 310                     (setq gnus-newsgroup-scored (cdr gnus-newsgroup-scored)))
 311                   ;; That's it.  We exit this group.
 312                   (when (eq major-mode 'gnus-summary-mode)
 313                     (kill-buffer (current-buffer)))))
 314             ;; Restore the proper info.
 315             (when ginfo
 316               (setcdr ginfo (cdr orig-info)))
 317             (setcar (gnus-gethash (caar newsrc) gnus-newsrc-hashtb)
 318                     num-unread)))
 319         (setcdr (car newsrc) (car active))
 320         (gnus-message 3 "nnkiboze: Checking %s...done" (caar newsrc))
 321         (setq newsrc (cdr newsrc))))
 322     ;; We save the kiboze newsrc for this group.
 323     (with-temp-file newsrc-file
 324       (insert "(setq nnkiboze-newsrc '")
 325       (gnus-prin1 nnkiboze-newsrc)
 326       (insert ")\n")))
 327   (save-excursion
 328     (set-buffer gnus-group-buffer)
 329     (gnus-group-list-groups))
 330   t)
 331
 332 (defun nnkiboze-enter-nov (buffer header group)
 333   (save-excursion
 334     (set-buffer buffer)
 335     (goto-char (point-max))
 336     (let ((prefix (gnus-group-real-prefix group))
 337           (oheader (copy-sequence header))
 338           article)
 339       (if (zerop (forward-line -1))
 340           (progn
 341             (setq article (1+ (read (current-buffer))))
 342             (forward-line 1))
 343         (setq article 1))
 344       (mail-header-set-number oheader article)
 345       (nnheader-insert-nov oheader)
 346       (search-backward "\t" nil t 2)
 347       (if (re-search-forward " [^ ]+:[0-9]+" nil t)
 348           (goto-char (match-beginning 0))
 349         (forward-char 1))
 350       ;; The first Xref has to be the group this article
 351       ;; really came for - this is the article nnkiboze
 352       ;; will request when it is asked for the article.
 353       (insert " " group ":"
 354               (int-to-string (mail-header-number header)) " ")
 355       (while (re-search-forward " [^ ]+:[0-9]+" nil t)
 356         (goto-char (1+ (match-beginning 0)))
 357         (insert prefix)))))
 358
 359 (defun nnkiboze-nov-file-name (&optional suffix)
 360   (concat (file-name-as-directory nnkiboze-directory)
 361           (nnheader-translate-file-chars
 362            (concat (nnkiboze-prefixed-name nnkiboze-current-group)
 363                    (or suffix ".nov")))))
 364
 365 (provide 'nnkiboze)
 366
 367 ;;; nnkiboze.el ends here