git.chise.org Git - elisp/gnus.git-/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;         Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; Keywords: news, mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  29 ;; For an overview of what the interface functions do, please see the
  30 ;; Gnus sources.
  31
  32 ;;; Code:
  33
  34 (eval-when-compile (require 'cl))
  35 (eval-when-compile (require 'gnus-clfns))
  36
  37 (require 'nnheader)
  38 (require 'nnmail)
  39 (require 'gnus-start)
  40 (require 'nnoo)
  41
  42 (nnoo-declare nnmh)
  43
  44 (defvoo nnmh-directory message-directory
  45   "*Mail spool directory.")
  46
  47 (defvoo nnmh-get-new-mail t
  48   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  49
  50 (defvoo nnmh-prepare-save-mail-hook nil
  51   "*Hook run narrowed to an article before saving.")
  52
  53 (defvoo nnmh-be-safe nil
  54   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.
  55 Go through the .nnmh-articles file and compare with the actual
  56 articles in this folder.  The articles that are \"new\" will be marked
  57 as unread by Gnus.")
  58
  59 \f
  60
  61 (defconst nnmh-version "nnmh 1.0"
  62   "nnmh version.")
  63
  64 (defvoo nnmh-current-directory nil
  65   "Current news group directory.")
  66
  67 (defvoo nnmh-status-string "")
  68 (defvoo nnmh-group-alist nil)
  69 ;; Don't even think about setting this variable.  It does not exist.
  70 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  71 ;; dynamically by certain functions in nndraft.
  72 (defvar nnmh-allow-delete-final nil)
  73
  74 \f
  75
  76 ;;; Interface functions.
  77
  78 (nnoo-define-basics nnmh)
  79
  80 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  81   (save-excursion
  82     (set-buffer nntp-server-buffer)
  83     (erase-buffer)
  84     (let* ((file nil)
  85            (number (length articles))
  86            (large (and (numberp nnmail-large-newsgroup)
  87                        (> number nnmail-large-newsgroup)))
  88            (count 0)
  89            (file-name-coding-system nnmail-pathname-coding-system)
  90            (pathname-coding-system nnmail-pathname-coding-system)
  91            beg article)
  92       (nnmh-possibly-change-directory newsgroup server)
  93       ;; We don't support fetching by Message-ID.
  94       (if (stringp (car articles))
  95           'headers
  96         (while articles
  97           (when (and (file-exists-p
  98                       (setq file (concat (file-name-as-directory
  99                                           nnmh-current-directory)
 100                                          (int-to-string
 101                                           (setq article (pop articles))))))
 102                      (not (file-directory-p file)))
 103             (insert (format "221 %d Article retrieved.\n" article))
 104             (setq beg (point))
 105             (nnheader-insert-head file)
 106             (goto-char beg)
 107             (if (search-forward "\n\n" nil t)
 108                 (forward-char -1)
 109               (goto-char (point-max))
 110               (insert "\n\n"))
 111             (insert ".\n")
 112             (delete-region (point) (point-max)))
 113           (setq count (1+ count))
 114
 115           (and large
 116                (zerop (% count 20))
 117                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 118                                  (/ (* count 100) number))))
 119
 120         (when large
 121           (nnheader-message 5 "nnmh: Receiving headers...done"))
 122
 123         ;; (nnheader-fold-continuation-lines)
 124         'headers))))
 125
 126 (deffoo nnmh-retrieve-parsed-headers (articles
 127                                       dependencies
 128                                       &optional newsgroup server fetch-old
 129                                       force-new)
 130   (save-excursion
 131     (set-buffer nntp-server-buffer)
 132     (let* ((file nil)
 133            (number (length articles))
 134            (large (and (numberp nnmail-large-newsgroup)
 135                        (> number nnmail-large-newsgroup)))
 136            (count 0)
 137            (file-name-coding-system 'binary)
 138            (pathname-coding-system 'binary)
 139            (case-fold-search t)
 140            ;;beg
 141            article
 142            headers header id end ref lines chars ctype in-reply-to
 143            (cur (current-buffer)))
 144       (nnmh-possibly-change-directory newsgroup server)
 145       ;; We don't support fetching by Message-ID.
 146       (nnheader-retrieve-headers-from-directory
 147        articles nnmh-current-directory dependencies
 148        fetch-old force-new large "nnmh")
 149       )))
 150
 151 (deffoo nnmh-open-server (server &optional defs)
 152   (nnoo-change-server 'nnmh server defs)
 153   (when (not (file-exists-p nnmh-directory))
 154     (condition-case ()
 155         (make-directory nnmh-directory t)
 156       (error t)))
 157   (cond
 158    ((not (file-exists-p nnmh-directory))
 159     (nnmh-close-server)
 160     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 161    ((not (file-directory-p (file-truename nnmh-directory)))
 162     (nnmh-close-server)
 163     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 164    (t
 165     (nnheader-report 'nnmh "Opened server %s using directory %s"
 166                      server nnmh-directory)
 167     t)))
 168
 169 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 170   (nnmh-possibly-change-directory newsgroup server)
 171   (let ((file (if (stringp id)
 172                   nil
 173                 (concat nnmh-current-directory (int-to-string id))))
 174         (file-name-coding-system nnmail-pathname-coding-system)
 175         (pathname-coding-system nnmail-pathname-coding-system)
 176         (nntp-server-buffer (or buffer nntp-server-buffer)))
 177     (and (stringp file)
 178          (file-exists-p file)
 179          (not (file-directory-p file))
 180          (save-excursion (nnmail-find-file file))
 181          (string-to-int (file-name-nondirectory file)))))
 182
 183 (deffoo nnmh-request-group (group &optional server dont-check)
 184   (nnheader-init-server-buffer)
 185   (nnmh-possibly-change-directory group server)
 186   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 187         (file-name-coding-system nnmail-pathname-coding-system)
 188         (pathname-coding-system nnmail-pathname-coding-system)
 189         dir)
 190     (cond
 191      ((not (file-directory-p pathname))
 192       (nnheader-report
 193        'nnmh "Can't select group (no such directory): %s" group))
 194      (t
 195       (setq nnmh-current-directory pathname)
 196       (and nnmh-get-new-mail
 197            nnmh-be-safe
 198            (nnmh-update-gnus-unreads group))
 199       (cond
 200        (dont-check
 201         (nnheader-report 'nnmh "Selected group %s" group)
 202         t)
 203        (t
 204         ;; Re-scan the directory if it's on a foreign system.
 205         (nnheader-re-read-dir pathname)
 206         (setq dir
 207               (sort
 208                (mapcar (lambda (name) (string-to-int name))
 209                        (directory-files pathname nil "^[0-9]+$" t))
 210                '<))
 211         (cond
 212          (dir
 213           (setq nnmh-group-alist
 214                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 215           (push (list group (cons (car dir) (car (last dir))))
 216                 nnmh-group-alist)
 217           (nnheader-report 'nnmh "Selected group %s" group)
 218           (nnheader-insert
 219            "211 %d %d %d %s\n" (length dir) (car dir)
 220            (car (last dir)) group))
 221          (t
 222           (nnheader-report 'nnmh "Empty group %s" group)
 223           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 224
 225 (deffoo nnmh-request-scan (&optional group server)
 226   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 227
 228 (deffoo nnmh-request-list (&optional server dir)
 229   (nnheader-insert "")
 230   (nnmh-possibly-change-directory nil server)
 231   (let ((file-name-coding-system nnmail-pathname-coding-system)
 232         (pathname-coding-system nnmail-pathname-coding-system)
 233         (nnmh-toplev
 234          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 235     (nnmh-request-list-1 nnmh-toplev))
 236   (setq nnmh-group-alist (nnmail-get-active))
 237   t)
 238
 239 (defvar nnmh-toplev)
 240 (defun nnmh-request-list-1 (dir)
 241   (setq dir (expand-file-name dir))
 242   ;; Recurse down all directories.
 243   (let ((dirs (and (file-readable-p dir)
 244                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 245                    (nnheader-directory-files dir t nil t)))
 246         rdir)
 247     ;; Recurse down directories.
 248     (while (setq rdir (pop dirs))
 249       (when (and (file-directory-p rdir)
 250                  (file-readable-p rdir)
 251                  (not (equal (file-truename rdir)
 252                              (file-truename dir))))
 253         (nnmh-request-list-1 rdir))))
 254   ;; For each directory, generate an active file line.
 255   (unless (string= (expand-file-name nnmh-toplev) dir)
 256     (let ((files (mapcar
 257                   (lambda (name) (string-to-int name))
 258                   (directory-files dir nil "^[0-9]+$" t))))
 259       (when files
 260         (save-excursion
 261           (set-buffer nntp-server-buffer)
 262           (goto-char (point-max))
 263           (insert
 264            (format
 265             "%s %d %d y\n"
 266             (progn
 267               (string-match
 268                (regexp-quote
 269                 (file-truename (file-name-as-directory
 270                                 (expand-file-name nnmh-toplev))))
 271                dir)
 272               (nnheader-replace-chars-in-string
 273                (decode-coding-string (substring dir (match-end 0))
 274                                      nnmail-pathname-coding-system)
 275                ?/ ?.))
 276             (apply 'max files)
 277             (apply 'min files)))))))
 278   t)
 279
 280 (deffoo nnmh-request-newgroups (date &optional server)
 281   (nnmh-request-list server))
 282
 283 (deffoo nnmh-request-expire-articles (articles newsgroup
 284                                                &optional server force)
 285   (nnmh-possibly-change-directory newsgroup server)
 286   (let* ((is-old t)
 287          article rest mod-time)
 288     (nnheader-init-server-buffer)
 289
 290     (while (and articles is-old)
 291       (setq article (concat nnmh-current-directory
 292                             (int-to-string (car articles))))
 293       (when (setq mod-time (nth 5 (file-attributes article)))
 294         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 295                  (setq is-old
 296                        (nnmail-expired-article-p newsgroup mod-time force)))
 297             (progn
 298               (nnheader-message 5 "Deleting article %s in %s..."
 299                                 article newsgroup)
 300               (condition-case ()
 301                   (funcall nnmail-delete-file-function article)
 302                 (file-error
 303                  (nnheader-message 1 "Couldn't delete article %s in %s"
 304                                    article newsgroup)
 305                  (push (car articles) rest))))
 306           (push (car articles) rest)))
 307       (setq articles (cdr articles)))
 308     (nnheader-message 5 "")
 309     (nconc rest articles)))
 310
 311 (deffoo nnmh-close-group (group &optional server)
 312   t)
 313
 314 (deffoo nnmh-request-move-article
 315     (article group server accept-form &optional last)
 316   (let ((buf (get-buffer-create " *nnmh move*"))
 317         result)
 318     (and
 319      (nnmh-deletable-article-p group article)
 320      (nnmh-request-article article group server)
 321      (save-excursion
 322        (set-buffer buf)
 323        (erase-buffer)
 324        (insert-buffer-substring nntp-server-buffer)
 325        (setq result (eval accept-form))
 326        (kill-buffer (current-buffer))
 327        result)
 328      (progn
 329        (nnmh-possibly-change-directory group server)
 330        (condition-case ()
 331            (funcall nnmail-delete-file-function
 332                     (concat nnmh-current-directory (int-to-string article)))
 333          (file-error nil))))
 334     result))
 335
 336 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 337   (nnmh-possibly-change-directory group server)
 338   (if (and (not (equal group "queue"))
 339            (not (equal group "draft")))
 340       (nnmail-check-syntax))
 341   (when nnmail-cache-accepted-message-ids
 342     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 343   (nnheader-init-server-buffer)
 344   (prog1
 345       (if (stringp group)
 346           (if noinsert
 347               (nnmh-active-number group)
 348             (car (nnmh-save-mail
 349                   (list (cons group (nnmh-active-number group)))
 350                   noinsert)))
 351         (let ((res (nnmail-article-group 'nnmh-active-number)))
 352           (if (and (null res)
 353                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 354               'junk
 355             (car (nnmh-save-mail res noinsert)))))
 356     (when (and last nnmail-cache-accepted-message-ids)
 357       (nnmail-cache-close))))
 358
 359 (deffoo nnmh-request-replace-article (article group buffer)
 360   (nnmh-possibly-change-directory group)
 361   (save-excursion
 362     (set-buffer buffer)
 363     (nnmh-possibly-create-directory group)
 364     (ignore-errors
 365       (nnmail-write-region
 366        (point-min) (point-max)
 367        (concat nnmh-current-directory (int-to-string article))
 368        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 369       t)))
 370
 371 (deffoo nnmh-request-create-group (group &optional server args)
 372   (nnheader-init-server-buffer)
 373   (unless (assoc group nnmh-group-alist)
 374     (let (active)
 375       (push (list group (setq active (cons 1 0)))
 376             nnmh-group-alist)
 377       (nnmh-possibly-create-directory group)
 378       (nnmh-possibly-change-directory group server)
 379       (let ((articles (mapcar
 380                        (lambda (file)
 381                          (string-to-int file))
 382                        (directory-files
 383                         nnmh-current-directory nil "^[0-9]+$"))))
 384         (when articles
 385           (setcar active (apply 'min articles))
 386           (setcdr active (apply 'max articles))))))
 387   t)
 388
 389 (deffoo nnmh-request-delete-group (group &optional force server)
 390   (nnmh-possibly-change-directory group server)
 391   ;; Delete all articles in GROUP.
 392   (if (not force)
 393       ()                                ; Don't delete the articles.
 394     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 395       (while articles
 396         (when (file-writable-p (car articles))
 397           (nnheader-message 5 "Deleting article %s in %s..."
 398                             (car articles) group)
 399           (funcall nnmail-delete-file-function (car articles)))
 400         (setq articles (cdr articles))))
 401     ;; Try to delete the directory itself.
 402     (ignore-errors
 403       (delete-directory nnmh-current-directory)))
 404   ;; Remove the group from all structures.
 405   (setq nnmh-group-alist
 406         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 407         nnmh-current-directory nil)
 408   t)
 409
 410 (deffoo nnmh-request-rename-group (group new-name &optional server)
 411   (nnmh-possibly-change-directory group server)
 412   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 413         (old-dir (nnmail-group-pathname group nnmh-directory)))
 414     (when (ignore-errors
 415             (make-directory new-dir t)
 416             t)
 417       ;; We move the articles file by file instead of renaming
 418       ;; the directory -- there may be subgroups in this group.
 419       ;; One might be more clever, I guess.
 420       (let ((files (nnheader-article-to-file-alist old-dir)))
 421         (while files
 422           (rename-file
 423            (concat old-dir (cdar files))
 424            (concat new-dir (cdar files)))
 425           (pop files)))
 426       (when (<= (length (directory-files old-dir)) 2)
 427         (ignore-errors
 428           (delete-directory old-dir)))
 429       ;; That went ok, so we change the internal structures.
 430       (let ((entry (assoc group nnmh-group-alist)))
 431         (when entry
 432           (setcar entry new-name))
 433         (setq nnmh-current-directory nil)
 434         t))))
 435
 436 (nnoo-define-skeleton nnmh)
 437
 438 \f
 439 ;;; Internal functions.
 440
 441 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 442   (when (and server
 443              (not (nnmh-server-opened server)))
 444     (nnmh-open-server server))
 445   (when newsgroup
 446     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 447           (file-name-coding-system nnmail-pathname-coding-system)
 448           (pathname-coding-system nnmail-pathname-coding-system))
 449       (if (file-directory-p pathname)
 450           (setq nnmh-current-directory pathname)
 451         (error "No such newsgroup: %s" newsgroup)))))
 452
 453 (defun nnmh-possibly-create-directory (group)
 454   (let (dir dirs)
 455     (setq dir (nnmail-group-pathname group nnmh-directory))
 456     (while (not (file-directory-p dir))
 457       (push dir dirs)
 458       (setq dir (file-name-directory (directory-file-name dir))))
 459     (while dirs
 460       (when (make-directory (directory-file-name (car dirs)))
 461         (error "Could not create directory %s" (car dirs)))
 462       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 463       (setq dirs (cdr dirs)))))
 464
 465 (defun nnmh-save-mail (group-art &optional noinsert)
 466   "Called narrowed to an article."
 467   (unless noinsert
 468     (nnmail-insert-lines)
 469     (nnmail-insert-xref group-art))
 470   (run-hooks 'nnmail-prepare-save-mail-hook)
 471   (run-hooks 'nnmh-prepare-save-mail-hook)
 472   (goto-char (point-min))
 473   (while (looking-at "From ")
 474     (replace-match "X-From-Line: ")
 475     (forward-line 1))
 476   ;; We save the article in all the newsgroups it belongs in.
 477   (let ((ga group-art)
 478         first)
 479     (while ga
 480       (nnmh-possibly-create-directory (caar ga))
 481       (let ((file (concat (nnmail-group-pathname
 482                            (caar ga) nnmh-directory)
 483                           (int-to-string (cdar ga)))))
 484         (if first
 485             ;; It was already saved, so we just make a hard link.
 486             (funcall nnmail-crosspost-link-function first file t)
 487           ;; Save the article.
 488           (nnmail-write-region (point-min) (point-max) file nil nil)
 489           (setq first file)))
 490       (setq ga (cdr ga))))
 491   group-art)
 492
 493 (defun nnmh-active-number (group)
 494   "Compute the next article number in GROUP."
 495   (let ((active (cadr (assoc group nnmh-group-alist)))
 496         (dir (nnmail-group-pathname group nnmh-directory))
 497         (file-name-coding-system nnmail-pathname-coding-system)
 498         (pathname-coding-system nnmail-pathname-coding-system)
 499         file)
 500     (unless active
 501       ;; The group wasn't known to nnmh, so we just create an active
 502       ;; entry for it.
 503       (setq active (cons 1 0))
 504       (push (list group active) nnmh-group-alist)
 505       (unless (file-exists-p dir)
 506         (gnus-make-directory dir))
 507       ;; Find the highest number in the group.
 508       (let ((files (sort
 509                     (mapcar
 510                      (lambda (f)
 511                        (string-to-int f))
 512                      (directory-files dir nil "^[0-9]+$"))
 513                     '>)))
 514         (when files
 515           (setcdr active (car files)))))
 516     (setcdr active (1+ (cdr active)))
 517     (while (or
 518             ;; See whether the file exists...
 519             (file-exists-p
 520              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 521                                 (int-to-string (cdr active)))))
 522             ;; ... or there is a buffer that will make that file exist
 523             ;; in the future.
 524             (get-file-buffer file))
 525       ;; Skip past that file.
 526       (setcdr active (1+ (cdr active))))
 527     (cdr active)))
 528
 529 (defun nnmh-update-gnus-unreads (group)
 530   ;; Go through the .nnmh-articles file and compare with the actual
 531   ;; articles in this folder.  The articles that are "new" will be
 532   ;; marked as unread by Gnus.
 533   (let* ((dir nnmh-current-directory)
 534          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 535                               (directory-files nnmh-current-directory
 536                                                nil "^[0-9]+$" t))
 537                       '<))
 538          (nnmh-file (concat dir ".nnmh-articles"))
 539          new articles)
 540     ;; Load the .nnmh-articles file.
 541     (when (file-exists-p nnmh-file)
 542       (setq articles
 543             (let (nnmh-newsgroup-articles)
 544               (ignore-errors (load nnmh-file nil t t))
 545               nnmh-newsgroup-articles)))
 546     ;; Add all new articles to the `new' list.
 547     (let ((art files))
 548       (while art
 549         (unless (assq (car art) articles)
 550           (push (car art) new))
 551         (setq art (cdr art))))
 552     ;; Remove all deleted articles.
 553     (let ((art articles))
 554       (while art
 555         (unless (memq (caar art) files)
 556           (setq articles (delq (car art) articles)))
 557         (setq art (cdr art))))
 558     ;; Check whether the articles really are the ones that Gnus thinks
 559     ;; they are by looking at the time-stamps.
 560     (let ((arts articles)
 561           art)
 562       (while (setq art (pop arts))
 563         (when (not (equal
 564                     (nth 5 (file-attributes
 565                             (concat dir (int-to-string (car art)))))
 566                     (cdr art)))
 567           (setq articles (delq art articles))
 568           (push (car art) new))))
 569     ;; Go through all the new articles and add them, and their
 570     ;; time-stamps, to the list.
 571     (setq articles
 572           (nconc articles
 573                  (mapcar
 574                   (lambda (art)
 575                     (cons art
 576                           (nth 5 (file-attributes
 577                                   (concat dir (int-to-string art))))))
 578                   new)))
 579     ;; Make Gnus mark all new articles as unread.
 580     (when new
 581       (gnus-make-articles-unread
 582        (gnus-group-prefixed-name group (list 'nnmh ""))
 583        (setq new (sort new '<))))
 584     ;; Sort the article list with highest numbers first.
 585     (setq articles (sort articles (lambda (art1 art2)
 586                                     (> (car art1) (car art2)))))
 587     ;; Finally write this list back to the .nnmh-articles file.
 588     (with-temp-file nnmh-file
 589       (insert ";; Gnus article active file for " group "\n\n")
 590       (insert "(setq nnmh-newsgroup-articles '")
 591       (gnus-prin1 articles)
 592       (insert ")\n"))))
 593
 594 (defun nnmh-deletable-article-p (group article)
 595   "Say whether ARTICLE in GROUP can be deleted."
 596   (let ((path (concat nnmh-current-directory (int-to-string article))))
 597     ;; Writable.
 598     (and (file-writable-p path)
 599          (or
 600           ;; We can never delete the last article in the group.
 601           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 602                    article))
 603           ;; Well, we can.
 604           nnmh-allow-delete-final))))
 605
 606 (provide 'nnmh)
 607
 608 ;;; nnmh.el ends here