git.chise.org Git - elisp/gnus.git-/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.
  52 Go through the .nnmh-articles file and compare with the actual
  53 articles in this folder.  The articles that are \"new\" will be marked
  54 as unread by Gnus.")
  55
  56 \f
  57
  58 (defconst nnmh-version "nnmh 1.0"
  59   "nnmh version.")
  60
  61 (defvoo nnmh-current-directory nil
  62   "Current news group directory.")
  63
  64 (defvoo nnmh-status-string "")
  65 (defvoo nnmh-group-alist nil)
  66 ;; Don't even think about setting this variable.  It does not exist.
  67 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  68 ;; dynamically by certain functions in nndraft.
  69 (defvar nnmh-allow-delete-final nil)
  70
  71 \f
  72
  73 ;;; Interface functions.
  74
  75 (nnoo-define-basics nnmh)
  76
  77 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  78   (save-excursion
  79     (set-buffer nntp-server-buffer)
  80     (erase-buffer)
  81     (let* ((file nil)
  82            (number (length articles))
  83            (large (and (numberp nnmail-large-newsgroup)
  84                        (> number nnmail-large-newsgroup)))
  85            (count 0)
  86            (pathname-coding-system 'binary)
  87            beg article)
  88       (nnmh-possibly-change-directory newsgroup server)
  89       ;; We don't support fetching by Message-ID.
  90       (if (stringp (car articles))
  91           'headers
  92         (while articles
  93           (when (and (file-exists-p
  94                       (setq file (concat (file-name-as-directory
  95                                           nnmh-current-directory)
  96                                          (int-to-string
  97                                           (setq article (pop articles))))))
  98                      (not (file-directory-p file)))
  99             (insert (format "221 %d Article retrieved.\n" article))
 100             (setq beg (point))
 101             (nnheader-insert-head file)
 102             (goto-char beg)
 103             (if (search-forward "\n\n" nil t)
 104                 (forward-char -1)
 105               (goto-char (point-max))
 106               (insert "\n\n"))
 107             (insert ".\n")
 108             (delete-region (point) (point-max)))
 109           (setq count (1+ count))
 110
 111           (and large
 112                (zerop (% count 20))
 113                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 114                                  (/ (* count 100) number))))
 115
 116         (when large
 117           (nnheader-message 5 "nnmh: Receiving headers...done"))
 118
 119         (nnheader-fold-continuation-lines)
 120         'headers))))
 121
 122 (deffoo nnmh-open-server (server &optional defs)
 123   (nnoo-change-server 'nnmh server defs)
 124   (when (not (file-exists-p nnmh-directory))
 125     (condition-case ()
 126         (make-directory nnmh-directory t)
 127       (error t)))
 128   (cond
 129    ((not (file-exists-p nnmh-directory))
 130     (nnmh-close-server)
 131     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 132    ((not (file-directory-p (file-truename nnmh-directory)))
 133     (nnmh-close-server)
 134     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 135    (t
 136     (nnheader-report 'nnmh "Opened server %s using directory %s"
 137                      server nnmh-directory)
 138     t)))
 139
 140 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 141   (nnmh-possibly-change-directory newsgroup server)
 142   (let ((file (if (stringp id)
 143                   nil
 144                 (concat nnmh-current-directory (int-to-string id))))
 145         (pathname-coding-system 'binary)
 146         (nntp-server-buffer (or buffer nntp-server-buffer)))
 147     (and (stringp file)
 148          (file-exists-p file)
 149          (not (file-directory-p file))
 150          (save-excursion (nnmail-find-file file))
 151          (string-to-int (file-name-nondirectory file)))))
 152
 153 (deffoo nnmh-request-group (group &optional server dont-check)
 154   (nnheader-init-server-buffer)
 155   (nnmh-possibly-change-directory group server)
 156   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 157         (pathname-coding-system 'binary)
 158         dir)
 159     (cond
 160      ((not (file-directory-p pathname))
 161       (nnheader-report
 162        'nnmh "Can't select group (no such directory): %s" group))
 163      (t
 164       (setq nnmh-current-directory pathname)
 165       (and nnmh-get-new-mail
 166            nnmh-be-safe
 167            (nnmh-update-gnus-unreads group))
 168       (cond
 169        (dont-check
 170         (nnheader-report 'nnmh "Selected group %s" group)
 171         t)
 172        (t
 173         ;; Re-scan the directory if it's on a foreign system.
 174         (nnheader-re-read-dir pathname)
 175         (setq dir
 176               (sort
 177                (mapcar (lambda (name) (string-to-int name))
 178                        (directory-files pathname nil "^[0-9]+$" t))
 179                '<))
 180         (cond
 181          (dir
 182           (setq nnmh-group-alist
 183                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 184           (push (list group (cons (car dir) (car (last dir))))
 185                 nnmh-group-alist)
 186           (nnheader-report 'nnmh "Selected group %s" group)
 187           (nnheader-insert
 188            "211 %d %d %d %s\n" (length dir) (car dir)
 189            (car (last dir)) group))
 190          (t
 191           (nnheader-report 'nnmh "Empty group %s" group)
 192           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 193
 194 (deffoo nnmh-request-scan (&optional group server)
 195   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 196
 197 (deffoo nnmh-request-list (&optional server dir)
 198   (nnheader-insert "")
 199   (nnmh-possibly-change-directory nil server)
 200   (let ((pathname-coding-system 'binary)
 201         (nnmh-toplev
 202          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 203     (nnmh-request-list-1 nnmh-toplev))
 204   (setq nnmh-group-alist (nnmail-get-active))
 205   t)
 206
 207 (defvar nnmh-toplev)
 208 (defun nnmh-request-list-1 (dir)
 209   (setq dir (expand-file-name dir))
 210   ;; Recurse down all directories.
 211   (let ((dirs (and (file-readable-p dir)
 212                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 213                    (nnheader-directory-files dir t nil t)))
 214         rdir)
 215     ;; Recurse down directories.
 216     (while (setq rdir (pop dirs))
 217       (when (and (file-directory-p rdir)
 218                  (file-readable-p rdir)
 219                  (not (equal (file-truename rdir)
 220                              (file-truename dir))))
 221         (nnmh-request-list-1 rdir))))
 222   ;; For each directory, generate an active file line.
 223   (unless (string= (expand-file-name nnmh-toplev) dir)
 224     (let ((files (mapcar
 225                   (lambda (name) (string-to-int name))
 226                   (directory-files dir nil "^[0-9]+$" t))))
 227       (when files
 228         (save-excursion
 229           (set-buffer nntp-server-buffer)
 230           (goto-char (point-max))
 231           (insert
 232            (format
 233             "%s %d %d y\n"
 234             (progn
 235               (string-match
 236                (regexp-quote
 237                 (file-truename (file-name-as-directory
 238                                 (expand-file-name nnmh-toplev))))
 239                dir)
 240               (nnheader-replace-chars-in-string
 241                (mm-decode-coding-string (substring dir (match-end 0))
 242                                         nnmail-pathname-coding-system)
 243                ?/ ?.))
 244             (apply 'max files)
 245             (apply 'min files)))))))
 246   t)
 247
 248 (deffoo nnmh-request-newgroups (date &optional server)
 249   (nnmh-request-list server))
 250
 251 (deffoo nnmh-request-expire-articles (articles newsgroup
 252                                                &optional server force)
 253   (nnmh-possibly-change-directory newsgroup server)
 254   (let* ((is-old t)
 255          article rest mod-time)
 256     (nnheader-init-server-buffer)
 257
 258     (while (and articles is-old)
 259       (setq article (concat nnmh-current-directory
 260                             (int-to-string (car articles))))
 261       (when (setq mod-time (nth 5 (file-attributes article)))
 262         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 263                  (setq is-old
 264                        (nnmail-expired-article-p newsgroup mod-time force)))
 265             (progn
 266               (nnheader-message 5 "Deleting article %s in %s..."
 267                                 article newsgroup)
 268               (condition-case ()
 269                   (funcall nnmail-delete-file-function article)
 270                 (file-error
 271                  (nnheader-message 1 "Couldn't delete article %s in %s"
 272                                    article newsgroup)
 273                  (push (car articles) rest))))
 274           (push (car articles) rest)))
 275       (setq articles (cdr articles)))
 276     (nnheader-message 5 "")
 277     (nconc rest articles)))
 278
 279 (deffoo nnmh-close-group (group &optional server)
 280   t)
 281
 282 (deffoo nnmh-request-move-article
 283     (article group server accept-form &optional last)
 284   (let ((buf (get-buffer-create " *nnmh move*"))
 285         result)
 286     (and
 287      (nnmh-deletable-article-p group article)
 288      (nnmh-request-article article group server)
 289      (save-excursion
 290        (set-buffer buf)
 291        (erase-buffer)
 292        (insert-buffer-substring nntp-server-buffer)
 293        (setq result (eval accept-form))
 294        (kill-buffer (current-buffer))
 295        result)
 296      (progn
 297        (nnmh-possibly-change-directory group server)
 298        (condition-case ()
 299            (funcall nnmail-delete-file-function
 300                     (concat nnmh-current-directory (int-to-string article)))
 301          (file-error nil))))
 302     result))
 303
 304 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 305   (nnmh-possibly-change-directory group server)
 306   (if (and (not (equal group "queue"))
 307            (not (equal group "draft")))
 308       (nnmail-check-syntax))
 309   (when nnmail-cache-accepted-message-ids
 310     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 311   (nnheader-init-server-buffer)
 312   (prog1
 313       (if (stringp group)
 314           (if noinsert
 315               (nnmh-active-number group)
 316             (car (nnmh-save-mail
 317                   (list (cons group (nnmh-active-number group)))
 318                   noinsert)))
 319         (let ((res (nnmail-article-group 'nnmh-active-number)))
 320           (if (and (null res)
 321                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 322               'junk
 323             (car (nnmh-save-mail res noinsert)))))
 324     (when (and last nnmail-cache-accepted-message-ids)
 325       (nnmail-cache-close))))
 326
 327 (deffoo nnmh-request-replace-article (article group buffer)
 328   (nnmh-possibly-change-directory group)
 329   (save-excursion
 330     (set-buffer buffer)
 331     (nnmh-possibly-create-directory group)
 332     (ignore-errors
 333       (nnmail-write-region
 334        (point-min) (point-max)
 335        (concat nnmh-current-directory (int-to-string article))
 336        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 337       t)))
 338
 339 (deffoo nnmh-request-create-group (group &optional server args)
 340   (nnheader-init-server-buffer)
 341   (unless (assoc group nnmh-group-alist)
 342     (let (active)
 343       (push (list group (setq active (cons 1 0)))
 344             nnmh-group-alist)
 345       (nnmh-possibly-create-directory group)
 346       (nnmh-possibly-change-directory group server)
 347       (let ((articles (mapcar
 348                        (lambda (file)
 349                          (string-to-int file))
 350                        (directory-files
 351                         nnmh-current-directory nil "^[0-9]+$"))))
 352         (when articles
 353           (setcar active (apply 'min articles))
 354           (setcdr active (apply 'max articles))))))
 355   t)
 356
 357 (deffoo nnmh-request-delete-group (group &optional force server)
 358   (nnmh-possibly-change-directory group server)
 359   ;; Delete all articles in GROUP.
 360   (if (not force)
 361       ()                                ; Don't delete the articles.
 362     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 363       (while articles
 364         (when (file-writable-p (car articles))
 365           (nnheader-message 5 "Deleting article %s in %s..."
 366                             (car articles) group)
 367           (funcall nnmail-delete-file-function (car articles)))
 368         (setq articles (cdr articles))))
 369     ;; Try to delete the directory itself.
 370     (ignore-errors
 371       (delete-directory nnmh-current-directory)))
 372   ;; Remove the group from all structures.
 373   (setq nnmh-group-alist
 374         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 375         nnmh-current-directory nil)
 376   t)
 377
 378 (deffoo nnmh-request-rename-group (group new-name &optional server)
 379   (nnmh-possibly-change-directory group server)
 380   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 381         (old-dir (nnmail-group-pathname group nnmh-directory)))
 382     (when (ignore-errors
 383             (make-directory new-dir t)
 384             t)
 385       ;; We move the articles file by file instead of renaming
 386       ;; the directory -- there may be subgroups in this group.
 387       ;; One might be more clever, I guess.
 388       (let ((files (nnheader-article-to-file-alist old-dir)))
 389         (while files
 390           (rename-file
 391            (concat old-dir (cdar files))
 392            (concat new-dir (cdar files)))
 393           (pop files)))
 394       (when (<= (length (directory-files old-dir)) 2)
 395         (ignore-errors
 396           (delete-directory old-dir)))
 397       ;; That went ok, so we change the internal structures.
 398       (let ((entry (assoc group nnmh-group-alist)))
 399         (when entry
 400           (setcar entry new-name))
 401         (setq nnmh-current-directory nil)
 402         t))))
 403
 404 (nnoo-define-skeleton nnmh)
 405
 406 \f
 407 ;;; Internal functions.
 408
 409 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 410   (when (and server
 411              (not (nnmh-server-opened server)))
 412     (nnmh-open-server server))
 413   (when newsgroup
 414     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 415           (pathname-coding-system 'binary))
 416       (if (file-directory-p pathname)
 417           (setq nnmh-current-directory pathname)
 418         (error "No such newsgroup: %s" newsgroup)))))
 419
 420 (defun nnmh-possibly-create-directory (group)
 421   (let (dir dirs)
 422     (setq dir (nnmail-group-pathname group nnmh-directory))
 423     (while (not (file-directory-p dir))
 424       (push dir dirs)
 425       (setq dir (file-name-directory (directory-file-name dir))))
 426     (while dirs
 427       (when (make-directory (directory-file-name (car dirs)))
 428         (error "Could not create directory %s" (car dirs)))
 429       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 430       (setq dirs (cdr dirs)))))
 431
 432 (defun nnmh-save-mail (group-art &optional noinsert)
 433   "Called narrowed to an article."
 434   (unless noinsert
 435     (nnmail-insert-lines)
 436     (nnmail-insert-xref group-art))
 437   (run-hooks 'nnmail-prepare-save-mail-hook)
 438   (run-hooks 'nnmh-prepare-save-mail-hook)
 439   (goto-char (point-min))
 440   (while (looking-at "From ")
 441     (replace-match "X-From-Line: ")
 442     (forward-line 1))
 443   ;; We save the article in all the newsgroups it belongs in.
 444   (let ((ga group-art)
 445         first)
 446     (while ga
 447       (nnmh-possibly-create-directory (caar ga))
 448       (let ((file (concat (nnmail-group-pathname
 449                            (caar ga) nnmh-directory)
 450                           (int-to-string (cdar ga)))))
 451         (if first
 452             ;; It was already saved, so we just make a hard link.
 453             (funcall nnmail-crosspost-link-function first file t)
 454           ;; Save the article.
 455           (nnmail-write-region (point-min) (point-max) file nil nil)
 456           (setq first file)))
 457       (setq ga (cdr ga))))
 458   group-art)
 459
 460 (defun nnmh-active-number (group)
 461   "Compute the next article number in GROUP."
 462   (let ((active (cadr (assoc group nnmh-group-alist)))
 463         (dir (nnmail-group-pathname group nnmh-directory))
 464         (pathname-coding-system 'binary)
 465         file)
 466     (unless active
 467       ;; The group wasn't known to nnmh, so we just create an active
 468       ;; entry for it.
 469       (setq active (cons 1 0))
 470       (push (list group active) nnmh-group-alist)
 471       (unless (file-exists-p dir)
 472         (gnus-make-directory dir))
 473       ;; Find the highest number in the group.
 474       (let ((files (sort
 475                     (mapcar
 476                      (lambda (f)
 477                        (string-to-int f))
 478                      (directory-files dir nil "^[0-9]+$"))
 479                     '>)))
 480         (when files
 481           (setcdr active (car files)))))
 482     (setcdr active (1+ (cdr active)))
 483     (while (or
 484             ;; See whether the file exists...
 485             (file-exists-p
 486              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 487                                 (int-to-string (cdr active)))))
 488             ;; ... or there is a buffer that will make that file exist
 489             ;; in the future.
 490             (get-file-buffer file))
 491       ;; Skip past that file.
 492       (setcdr active (1+ (cdr active))))
 493     (cdr active)))
 494
 495 (defun nnmh-update-gnus-unreads (group)
 496   ;; Go through the .nnmh-articles file and compare with the actual
 497   ;; articles in this folder.  The articles that are "new" will be
 498   ;; marked as unread by Gnus.
 499   (let* ((dir nnmh-current-directory)
 500          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 501                               (directory-files nnmh-current-directory
 502                                                nil "^[0-9]+$" t))
 503                       '<))
 504          (nnmh-file (concat dir ".nnmh-articles"))
 505          new articles)
 506     ;; Load the .nnmh-articles file.
 507     (when (file-exists-p nnmh-file)
 508       (setq articles
 509             (let (nnmh-newsgroup-articles)
 510               (ignore-errors (load nnmh-file nil t t))
 511               nnmh-newsgroup-articles)))
 512     ;; Add all new articles to the `new' list.
 513     (let ((art files))
 514       (while art
 515         (unless (assq (car art) articles)
 516           (push (car art) new))
 517         (setq art (cdr art))))
 518     ;; Remove all deleted articles.
 519     (let ((art articles))
 520       (while art
 521         (unless (memq (caar art) files)
 522           (setq articles (delq (car art) articles)))
 523         (setq art (cdr art))))
 524     ;; Check whether the articles really are the ones that Gnus thinks
 525     ;; they are by looking at the time-stamps.
 526     (let ((arts articles)
 527           art)
 528       (while (setq art (pop arts))
 529         (when (not (equal
 530                     (nth 5 (file-attributes
 531                             (concat dir (int-to-string (car art)))))
 532                     (cdr art)))
 533           (setq articles (delq art articles))
 534           (push (car art) new))))
 535     ;; Go through all the new articles and add them, and their
 536     ;; time-stamps, to the list.
 537     (setq articles
 538           (nconc articles
 539                  (mapcar
 540                   (lambda (art)
 541                     (cons art
 542                           (nth 5 (file-attributes
 543                                   (concat dir (int-to-string art))))))
 544                   new)))
 545     ;; Make Gnus mark all new articles as unread.
 546     (when new
 547       (gnus-make-articles-unread
 548        (gnus-group-prefixed-name group (list 'nnmh ""))
 549        (setq new (sort new '<))))
 550     ;; Sort the article list with highest numbers first.
 551     (setq articles (sort articles (lambda (art1 art2)
 552                                     (> (car art1) (car art2)))))
 553     ;; Finally write this list back to the .nnmh-articles file.
 554     (with-temp-file nnmh-file
 555       (insert ";; Gnus article active file for " group "\n\n")
 556       (insert "(setq nnmh-newsgroup-articles '")
 557       (gnus-prin1 articles)
 558       (insert ")\n"))))
 559
 560 (defun nnmh-deletable-article-p (group article)
 561   "Say whether ARTICLE in GROUP can be deleted."
 562   (let ((path (concat nnmh-current-directory (int-to-string article))))
 563     ;; Writable.
 564     (and (file-writable-p path)
 565          (or
 566           ;; We can never delete the last article in the group.
 567           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 568                    article))
 569           ;; Well, we can.
 570           nnmh-allow-delete-final))))
 571
 572 (provide 'nnmh)
 573
 574 ;;; nnmh.el ends here