git.chise.org Git - elisp/gnus.git-/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;         Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   9 ;; Keywords: news, mail
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  31 ;; For an overview of what the interface functions do, please see the
  32 ;; Gnus sources.
  33
  34 ;;; Code:
  35
  36 (eval-when-compile (require 'cl))
  37 (eval-when-compile (require 'gnus-clfns))
  38
  39 (require 'nnheader)
  40 (require 'nnmail)
  41 (require 'gnus-start)
  42 (require 'nnoo)
  43
  44 (nnoo-declare nnmh)
  45
  46 (defvoo nnmh-directory message-directory
  47   "*Mail spool directory.")
  48
  49 (defvoo nnmh-get-new-mail t
  50   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  51
  52 (defvoo nnmh-prepare-save-mail-hook nil
  53   "*Hook run narrowed to an article before saving.")
  54
  55 (defvoo nnmh-be-safe nil
  56   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.
  57 Go through the .nnmh-articles file and compare with the actual
  58 articles in this folder.  The articles that are \"new\" will be marked
  59 as unread by Gnus.")
  60
  61 \f
  62
  63 (defconst nnmh-version "nnmh 1.0"
  64   "nnmh version.")
  65
  66 (defvoo nnmh-current-directory nil
  67   "Current news group directory.")
  68
  69 (defvoo nnmh-status-string "")
  70 (defvoo nnmh-group-alist nil)
  71 ;; Don't even think about setting this variable.  It does not exist.
  72 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  73 ;; dynamically by certain functions in nndraft.
  74 (defvar nnmh-allow-delete-final nil)
  75
  76 \f
  77
  78 ;;; Interface functions.
  79
  80 (nnoo-define-basics nnmh)
  81
  82 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  83   (save-excursion
  84     (set-buffer nntp-server-buffer)
  85     (erase-buffer)
  86     (let* ((file nil)
  87            (number (length articles))
  88            (large (and (numberp nnmail-large-newsgroup)
  89                        (> number nnmail-large-newsgroup)))
  90            (count 0)
  91            (file-name-coding-system nnmail-pathname-coding-system)
  92            (pathname-coding-system nnmail-pathname-coding-system)
  93            beg article)
  94       (nnmh-possibly-change-directory newsgroup server)
  95       ;; We don't support fetching by Message-ID.
  96       (if (stringp (car articles))
  97           'headers
  98         (while articles
  99           (when (and (file-exists-p
 100                       (setq file (concat (file-name-as-directory
 101                                           nnmh-current-directory)
 102                                          (int-to-string
 103                                           (setq article (pop articles))))))
 104                      (not (file-directory-p file)))
 105             (insert (format "221 %d Article retrieved.\n" article))
 106             (setq beg (point))
 107             (nnheader-insert-head file)
 108             (goto-char beg)
 109             (if (search-forward "\n\n" nil t)
 110                 (forward-char -1)
 111               (goto-char (point-max))
 112               (insert "\n\n"))
 113             (insert ".\n")
 114             (delete-region (point) (point-max)))
 115           (setq count (1+ count))
 116
 117           (and large
 118                (zerop (% count 20))
 119                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 120                                  (/ (* count 100) number))))
 121
 122         (when large
 123           (nnheader-message 5 "nnmh: Receiving headers...done"))
 124
 125         ;; (nnheader-fold-continuation-lines)
 126         'headers))))
 127
 128 (deffoo nnmh-open-server (server &optional defs)
 129   (nnoo-change-server 'nnmh server defs)
 130   (when (not (file-exists-p nnmh-directory))
 131     (condition-case ()
 132         (make-directory nnmh-directory t)
 133       (error t)))
 134   (cond
 135    ((not (file-exists-p nnmh-directory))
 136     (nnmh-close-server)
 137     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 138    ((not (file-directory-p (file-truename nnmh-directory)))
 139     (nnmh-close-server)
 140     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 141    (t
 142     (nnheader-report 'nnmh "Opened server %s using directory %s"
 143                      server nnmh-directory)
 144     t)))
 145
 146 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 147   (nnmh-possibly-change-directory newsgroup server)
 148   (let ((file (if (stringp id)
 149                   nil
 150                 (concat nnmh-current-directory (int-to-string id))))
 151         (file-name-coding-system nnmail-pathname-coding-system)
 152         (pathname-coding-system nnmail-pathname-coding-system)
 153         (nntp-server-buffer (or buffer nntp-server-buffer)))
 154     (and (stringp file)
 155          (file-exists-p file)
 156          (not (file-directory-p file))
 157          (save-excursion (nnmail-find-file file))
 158          (string-to-int (file-name-nondirectory file)))))
 159
 160 (deffoo nnmh-request-group (group &optional server dont-check)
 161   (nnheader-init-server-buffer)
 162   (nnmh-possibly-change-directory group server)
 163   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 164         (file-name-coding-system nnmail-pathname-coding-system)
 165         (pathname-coding-system nnmail-pathname-coding-system)
 166         dir)
 167     (cond
 168      ((not (file-directory-p pathname))
 169       (nnheader-report
 170        'nnmh "Can't select group (no such directory): %s" group))
 171      (t
 172       (setq nnmh-current-directory pathname)
 173       (and nnmh-get-new-mail
 174            nnmh-be-safe
 175            (nnmh-update-gnus-unreads group))
 176       (cond
 177        (dont-check
 178         (nnheader-report 'nnmh "Selected group %s" group)
 179         t)
 180        (t
 181         ;; Re-scan the directory if it's on a foreign system.
 182         (nnheader-re-read-dir pathname)
 183         (setq dir
 184               (sort
 185                (mapcar (lambda (name) (string-to-int name))
 186                        (directory-files pathname nil "^[0-9]+$" t))
 187                '<))
 188         (cond
 189          (dir
 190           (setq nnmh-group-alist
 191                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 192           (push (list group (cons (car dir) (car (last dir))))
 193                 nnmh-group-alist)
 194           (nnheader-report 'nnmh "Selected group %s" group)
 195           (nnheader-insert
 196            "211 %d %d %d %s\n" (length dir) (car dir)
 197            (car (last dir)) group))
 198          (t
 199           (nnheader-report 'nnmh "Empty group %s" group)
 200           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 201
 202 (deffoo nnmh-request-scan (&optional group server)
 203   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 204
 205 (deffoo nnmh-request-list (&optional server dir)
 206   (nnheader-insert "")
 207   (nnmh-possibly-change-directory nil server)
 208   (let ((file-name-coding-system nnmail-pathname-coding-system)
 209         (pathname-coding-system nnmail-pathname-coding-system)
 210         (nnmh-toplev
 211          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 212     (nnmh-request-list-1 nnmh-toplev))
 213   (setq nnmh-group-alist (nnmail-get-active))
 214   t)
 215
 216 (defvar nnmh-toplev)
 217 (defun nnmh-request-list-1 (dir)
 218   (setq dir (expand-file-name dir))
 219   ;; Recurse down all directories.
 220   (let ((dirs (and (file-readable-p dir)
 221                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 222                    (nnheader-directory-files dir t nil t)))
 223         rdir)
 224     ;; Recurse down directories.
 225     (while (setq rdir (pop dirs))
 226       (when (and (file-directory-p rdir)
 227                  (file-readable-p rdir)
 228                  (not (equal (file-truename rdir)
 229                              (file-truename dir))))
 230         (nnmh-request-list-1 rdir))))
 231   ;; For each directory, generate an active file line.
 232   (unless (string= (expand-file-name nnmh-toplev) dir)
 233     (let ((files (mapcar
 234                   (lambda (name) (string-to-int name))
 235                   (directory-files dir nil "^[0-9]+$" t))))
 236       (when files
 237         (save-excursion
 238           (set-buffer nntp-server-buffer)
 239           (goto-char (point-max))
 240           (insert
 241            (format
 242             "%s %d %d y\n"
 243             (progn
 244               (string-match
 245                (regexp-quote
 246                 (file-truename (file-name-as-directory
 247                                 (expand-file-name nnmh-toplev))))
 248                dir)
 249               (nnheader-replace-chars-in-string
 250                (decode-coding-string (substring dir (match-end 0))
 251                                      nnmail-pathname-coding-system)
 252                ?/ ?.))
 253             (apply 'max files)
 254             (apply 'min files)))))))
 255   t)
 256
 257 (deffoo nnmh-request-newgroups (date &optional server)
 258   (nnmh-request-list server))
 259
 260 (deffoo nnmh-request-expire-articles (articles newsgroup
 261                                                &optional server force)
 262   (nnmh-possibly-change-directory newsgroup server)
 263   (let* ((is-old t)
 264          article rest mod-time)
 265     (nnheader-init-server-buffer)
 266
 267     (while (and articles is-old)
 268       (setq article (concat nnmh-current-directory
 269                             (int-to-string (car articles))))
 270       (when (setq mod-time (nth 5 (file-attributes article)))
 271         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 272                  (setq is-old
 273                        (nnmail-expired-article-p newsgroup mod-time force)))
 274             (progn
 275               ;; Allow a special target group. -- jcn
 276               (unless (eq nnmail-expiry-target 'delete)
 277                 (with-temp-buffer
 278                   (nnmh-request-article (car articles)
 279                                         newsgroup server (current-buffer))
 280                   (nnmail-expiry-target-group
 281                    nnmail-expiry-target newsgroup)))
 282               (nnheader-message 5 "Deleting article %s in %s..."
 283                                 article newsgroup)
 284               (condition-case ()
 285                   (funcall nnmail-delete-file-function article)
 286                 (file-error
 287                  (nnheader-message 1 "Couldn't delete article %s in %s"
 288                                    article newsgroup)
 289                  (push (car articles) rest))))
 290           (push (car articles) rest)))
 291       (setq articles (cdr articles)))
 292     (nnheader-message 5 "")
 293     (nconc rest articles)))
 294
 295 (deffoo nnmh-close-group (group &optional server)
 296   t)
 297
 298 (deffoo nnmh-request-move-article
 299     (article group server accept-form &optional last)
 300   (let ((buf (get-buffer-create " *nnmh move*"))
 301         result)
 302     (and
 303      (nnmh-deletable-article-p group article)
 304      (nnmh-request-article article group server)
 305      (save-excursion
 306        (set-buffer buf)
 307        (erase-buffer)
 308        (insert-buffer-substring nntp-server-buffer)
 309        (setq result (eval accept-form))
 310        (kill-buffer (current-buffer))
 311        result)
 312      (progn
 313        (nnmh-possibly-change-directory group server)
 314        (condition-case ()
 315            (funcall nnmail-delete-file-function
 316                     (concat nnmh-current-directory (int-to-string article)))
 317          (file-error nil))))
 318     result))
 319
 320 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 321   (nnmh-possibly-change-directory group server)
 322   (if (and (not (equal group "queue"))
 323            (not (equal group "draft")))
 324       (nnmail-check-syntax))
 325   (when nnmail-cache-accepted-message-ids
 326     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 327   (nnheader-init-server-buffer)
 328   (prog1
 329       (if (stringp group)
 330           (if noinsert
 331               (nnmh-active-number group)
 332             (car (nnmh-save-mail
 333                   (list (cons group (nnmh-active-number group)))
 334                   noinsert)))
 335         (let ((res (nnmail-article-group 'nnmh-active-number)))
 336           (if (and (null res)
 337                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 338               'junk
 339             (car (nnmh-save-mail res noinsert)))))
 340     (when (and last nnmail-cache-accepted-message-ids)
 341       (nnmail-cache-close))))
 342
 343 (deffoo nnmh-request-replace-article (article group buffer)
 344   (nnmh-possibly-change-directory group)
 345   (save-excursion
 346     (set-buffer buffer)
 347     (nnmh-possibly-create-directory group)
 348     (ignore-errors
 349       (nnmail-write-region
 350        (point-min) (point-max)
 351        (concat nnmh-current-directory (int-to-string article))
 352        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 353       t)))
 354
 355 (deffoo nnmh-request-create-group (group &optional server args)
 356   (nnheader-init-server-buffer)
 357   (unless (assoc group nnmh-group-alist)
 358     (let (active)
 359       (push (list group (setq active (cons 1 0)))
 360             nnmh-group-alist)
 361       (nnmh-possibly-create-directory group)
 362       (nnmh-possibly-change-directory group server)
 363       (let ((articles (mapcar
 364                        (lambda (file)
 365                          (string-to-int file))
 366                        (directory-files
 367                         nnmh-current-directory nil "^[0-9]+$"))))
 368         (when articles
 369           (setcar active (apply 'min articles))
 370           (setcdr active (apply 'max articles))))))
 371   t)
 372
 373 (deffoo nnmh-request-delete-group (group &optional force server)
 374   (nnmh-possibly-change-directory group server)
 375   ;; Delete all articles in GROUP.
 376   (if (not force)
 377       ()                                ; Don't delete the articles.
 378     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 379       (while articles
 380         (when (file-writable-p (car articles))
 381           (nnheader-message 5 "Deleting article %s in %s..."
 382                             (car articles) group)
 383           (funcall nnmail-delete-file-function (car articles)))
 384         (setq articles (cdr articles))))
 385     ;; Try to delete the directory itself.
 386     (ignore-errors
 387       (delete-directory nnmh-current-directory)))
 388   ;; Remove the group from all structures.
 389   (setq nnmh-group-alist
 390         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 391         nnmh-current-directory nil)
 392   t)
 393
 394 (deffoo nnmh-request-rename-group (group new-name &optional server)
 395   (nnmh-possibly-change-directory group server)
 396   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 397         (old-dir (nnmail-group-pathname group nnmh-directory)))
 398     (when (ignore-errors
 399             (make-directory new-dir t)
 400             t)
 401       ;; We move the articles file by file instead of renaming
 402       ;; the directory -- there may be subgroups in this group.
 403       ;; One might be more clever, I guess.
 404       (let ((files (nnheader-article-to-file-alist old-dir)))
 405         (while files
 406           (rename-file
 407            (concat old-dir (cdar files))
 408            (concat new-dir (cdar files)))
 409           (pop files)))
 410       (when (<= (length (directory-files old-dir)) 2)
 411         (ignore-errors
 412           (delete-directory old-dir)))
 413       ;; That went ok, so we change the internal structures.
 414       (let ((entry (assoc group nnmh-group-alist)))
 415         (when entry
 416           (setcar entry new-name))
 417         (setq nnmh-current-directory nil)
 418         t))))
 419
 420 (nnoo-define-skeleton nnmh)
 421
 422 \f
 423 ;;; Internal functions.
 424
 425 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 426   (when (and server
 427              (not (nnmh-server-opened server)))
 428     (nnmh-open-server server))
 429   (when newsgroup
 430     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 431           (file-name-coding-system nnmail-pathname-coding-system)
 432           (pathname-coding-system nnmail-pathname-coding-system))
 433       (if (file-directory-p pathname)
 434           (setq nnmh-current-directory pathname)
 435         (error "No such newsgroup: %s" newsgroup)))))
 436
 437 (defun nnmh-possibly-create-directory (group)
 438   (let (dir dirs)
 439     (setq dir (nnmail-group-pathname group nnmh-directory))
 440     (while (not (file-directory-p dir))
 441       (push dir dirs)
 442       (setq dir (file-name-directory (directory-file-name dir))))
 443     (while dirs
 444       (when (make-directory (directory-file-name (car dirs)))
 445         (error "Could not create directory %s" (car dirs)))
 446       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 447       (setq dirs (cdr dirs)))))
 448
 449 (defun nnmh-save-mail (group-art &optional noinsert)
 450   "Called narrowed to an article."
 451   (unless noinsert
 452     (nnmail-insert-lines)
 453     (nnmail-insert-xref group-art))
 454   (run-hooks 'nnmail-prepare-save-mail-hook)
 455   (run-hooks 'nnmh-prepare-save-mail-hook)
 456   (goto-char (point-min))
 457   (while (looking-at "From ")
 458     (replace-match "X-From-Line: ")
 459     (forward-line 1))
 460   ;; We save the article in all the newsgroups it belongs in.
 461   (let ((ga group-art)
 462         first)
 463     (while ga
 464       (nnmh-possibly-create-directory (caar ga))
 465       (let ((file (concat (nnmail-group-pathname
 466                            (caar ga) nnmh-directory)
 467                           (int-to-string (cdar ga)))))
 468         (if first
 469             ;; It was already saved, so we just make a hard link.
 470             (funcall nnmail-crosspost-link-function first file t)
 471           ;; Save the article.
 472           (nnmail-write-region (point-min) (point-max) file nil nil)
 473           (setq first file)))
 474       (setq ga (cdr ga))))
 475   group-art)
 476
 477 (defun nnmh-active-number (group)
 478   "Compute the next article number in GROUP."
 479   (let ((active (cadr (assoc group nnmh-group-alist)))
 480         (dir (nnmail-group-pathname group nnmh-directory))
 481         (file-name-coding-system nnmail-pathname-coding-system)
 482         (pathname-coding-system nnmail-pathname-coding-system)
 483         file)
 484     (unless active
 485       ;; The group wasn't known to nnmh, so we just create an active
 486       ;; entry for it.
 487       (setq active (cons 1 0))
 488       (push (list group active) nnmh-group-alist)
 489       (unless (file-exists-p dir)
 490         (gnus-make-directory dir))
 491       ;; Find the highest number in the group.
 492       (let ((files (sort
 493                     (mapcar
 494                      (lambda (f)
 495                        (string-to-int f))
 496                      (directory-files dir nil "^[0-9]+$"))
 497                     '>)))
 498         (when files
 499           (setcdr active (car files)))))
 500     (setcdr active (1+ (cdr active)))
 501     (while (or
 502             ;; See whether the file exists...
 503             (file-exists-p
 504              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 505                                 (int-to-string (cdr active)))))
 506             ;; ... or there is a buffer that will make that file exist
 507             ;; in the future.
 508             (get-file-buffer file))
 509       ;; Skip past that file.
 510       (setcdr active (1+ (cdr active))))
 511     (cdr active)))
 512
 513 (defun nnmh-update-gnus-unreads (group)
 514   ;; Go through the .nnmh-articles file and compare with the actual
 515   ;; articles in this folder.  The articles that are "new" will be
 516   ;; marked as unread by Gnus.
 517   (let* ((dir nnmh-current-directory)
 518          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 519                               (directory-files nnmh-current-directory
 520                                                nil "^[0-9]+$" t))
 521                       '<))
 522          (nnmh-file (concat dir ".nnmh-articles"))
 523          new articles)
 524     ;; Load the .nnmh-articles file.
 525     (when (file-exists-p nnmh-file)
 526       (setq articles
 527             (let (nnmh-newsgroup-articles)
 528               (ignore-errors (load nnmh-file nil t t))
 529               nnmh-newsgroup-articles)))
 530     ;; Add all new articles to the `new' list.
 531     (let ((art files))
 532       (while art
 533         (unless (assq (car art) articles)
 534           (push (car art) new))
 535         (setq art (cdr art))))
 536     ;; Remove all deleted articles.
 537     (let ((art articles))
 538       (while art
 539         (unless (memq (caar art) files)
 540           (setq articles (delq (car art) articles)))
 541         (setq art (cdr art))))
 542     ;; Check whether the articles really are the ones that Gnus thinks
 543     ;; they are by looking at the time-stamps.
 544     (let ((arts articles)
 545           art)
 546       (while (setq art (pop arts))
 547         (when (not (equal
 548                     (nth 5 (file-attributes
 549                             (concat dir (int-to-string (car art)))))
 550                     (cdr art)))
 551           (setq articles (delq art articles))
 552           (push (car art) new))))
 553     ;; Go through all the new articles and add them, and their
 554     ;; time-stamps, to the list.
 555     (setq articles
 556           (nconc articles
 557                  (mapcar
 558                   (lambda (art)
 559                     (cons art
 560                           (nth 5 (file-attributes
 561                                   (concat dir (int-to-string art))))))
 562                   new)))
 563     ;; Make Gnus mark all new articles as unread.
 564     (when new
 565       (gnus-make-articles-unread
 566        (gnus-group-prefixed-name group (list 'nnmh ""))
 567        (setq new (sort new '<))))
 568     ;; Sort the article list with highest numbers first.
 569     (setq articles (sort articles (lambda (art1 art2)
 570                                     (> (car art1) (car art2)))))
 571     ;; Finally write this list back to the .nnmh-articles file.
 572     (with-temp-file nnmh-file
 573       (insert ";; Gnus article active file for " group "\n\n")
 574       (insert "(setq nnmh-newsgroup-articles '")
 575       (gnus-prin1 articles)
 576       (insert ")\n"))))
 577
 578 (defun nnmh-deletable-article-p (group article)
 579   "Say whether ARTICLE in GROUP can be deleted."
 580   (let ((path (concat nnmh-current-directory (int-to-string article))))
 581     ;; Writable.
 582     (and (file-writable-p path)
 583          (or
 584           ;; We can never delete the last article in the group.
 585           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 586                    article))
 587           ;; Well, we can.
 588           nnmh-allow-delete-final))))
 589
 590 (provide 'nnmh)
 591
 592 ;;; nnmh.el ends here