git.chise.org Git - elisp/gnus.git-/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;         Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   9 ;; Keywords: news, mail
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  31 ;; For an overview of what the interface functions do, please see the
  32 ;; Gnus sources.
  33
  34 ;;; Code:
  35
  36 (eval-when-compile (require 'cl))
  37 (eval-when-compile (require 'gnus-clfns))
  38
  39 (require 'nnheader)
  40 (require 'nnmail)
  41 (require 'gnus-start)
  42 (require 'nnoo)
  43
  44 (nnoo-declare nnmh)
  45
  46 (defvoo nnmh-directory message-directory
  47   "Mail spool directory.")
  48
  49 (defvoo nnmh-get-new-mail t
  50   "If non-nil, nnmh will check the incoming mail file and split the mail.")
  51
  52 (defvoo nnmh-prepare-save-mail-hook nil
  53   "Hook run narrowed to an article before saving.")
  54
  55 (defvoo nnmh-be-safe nil
  56   "If non-nil, nnmh will check all articles to make sure whether they are new or not.
  57 Go through the .nnmh-articles file and compare with the actual
  58 articles in this folder.  The articles that are \"new\" will be marked
  59 as unread by Gnus.")
  60
  61 \f
  62
  63 (defconst nnmh-version "nnmh 1.0"
  64   "nnmh version.")
  65
  66 (defvoo nnmh-current-directory nil
  67   "Current news group directory.")
  68
  69 (defvoo nnmh-status-string "")
  70 (defvoo nnmh-group-alist nil)
  71 ;; Don't even think about setting this variable.  It does not exist.
  72 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  73 ;; dynamically by certain functions in nndraft.
  74 (defvar nnmh-allow-delete-final nil)
  75
  76 \f
  77
  78 ;;; Interface functions.
  79
  80 (nnoo-define-basics nnmh)
  81
  82 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  83   (save-excursion
  84     (set-buffer nntp-server-buffer)
  85     (erase-buffer)
  86     (let* ((file nil)
  87            (number (length articles))
  88            (large (and (numberp nnmail-large-newsgroup)
  89                        (> number nnmail-large-newsgroup)))
  90            (count 0)
  91            (file-name-coding-system nnmail-pathname-coding-system)
  92            (pathname-coding-system nnmail-pathname-coding-system)
  93            beg article)
  94       (nnmh-possibly-change-directory newsgroup server)
  95       ;; We don't support fetching by Message-ID.
  96       (if (stringp (car articles))
  97           'headers
  98         (while articles
  99           (when (and (file-exists-p
 100                       (setq file (concat (file-name-as-directory
 101                                           nnmh-current-directory)
 102                                          (int-to-string
 103                                           (setq article (pop articles))))))
 104                      (not (file-directory-p file)))
 105             (insert (format "221 %d Article retrieved.\n" article))
 106             (setq beg (point))
 107             (nnheader-insert-head file)
 108             (goto-char beg)
 109             (if (search-forward "\n\n" nil t)
 110                 (forward-char -1)
 111               (goto-char (point-max))
 112               (insert "\n\n"))
 113             (insert ".\n")
 114             (delete-region (point) (point-max)))
 115           (setq count (1+ count))
 116
 117           (and large
 118                (zerop (% count 20))
 119                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 120                                  (/ (* count 100) number))))
 121
 122         (when large
 123           (nnheader-message 5 "nnmh: Receiving headers...done"))
 124
 125         ;; (nnheader-fold-continuation-lines)
 126         'headers))))
 127
 128 (deffoo nnmh-open-server (server &optional defs)
 129   (nnoo-change-server 'nnmh server defs)
 130   (when (not (file-exists-p nnmh-directory))
 131     (condition-case ()
 132         (make-directory nnmh-directory t)
 133       (error t)))
 134   (cond
 135    ((not (file-exists-p nnmh-directory))
 136     (nnmh-close-server)
 137     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 138    ((not (file-directory-p (file-truename nnmh-directory)))
 139     (nnmh-close-server)
 140     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 141    (t
 142     (nnheader-report 'nnmh "Opened server %s using directory %s"
 143                      server nnmh-directory)
 144     t)))
 145
 146 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 147   (nnmh-possibly-change-directory newsgroup server)
 148   (let ((file (if (stringp id)
 149                   nil
 150                 (concat nnmh-current-directory (int-to-string id))))
 151         (file-name-coding-system nnmail-pathname-coding-system)
 152         (pathname-coding-system nnmail-pathname-coding-system)
 153         (nntp-server-buffer (or buffer nntp-server-buffer)))
 154     (and (stringp file)
 155          (file-exists-p file)
 156          (not (file-directory-p file))
 157          (save-excursion (nnmail-find-file file))
 158          (string-to-int (file-name-nondirectory file)))))
 159
 160 (deffoo nnmh-request-group (group &optional server dont-check)
 161   (nnheader-init-server-buffer)
 162   (nnmh-possibly-change-directory group server)
 163   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 164         (file-name-coding-system nnmail-pathname-coding-system)
 165         (pathname-coding-system nnmail-pathname-coding-system)
 166         dir)
 167     (cond
 168      ((not (file-directory-p pathname))
 169       (nnheader-report
 170        'nnmh "Can't select group (no such directory): %s" group))
 171      (t
 172       (setq nnmh-current-directory pathname)
 173       (and nnmh-get-new-mail
 174            nnmh-be-safe
 175            (nnmh-update-gnus-unreads group))
 176       (cond
 177        (dont-check
 178         (nnheader-report 'nnmh "Selected group %s" group)
 179         t)
 180        (t
 181         ;; Re-scan the directory if it's on a foreign system.
 182         (nnheader-re-read-dir pathname)
 183         (setq dir
 184               (sort
 185                (mapcar (lambda (name) (string-to-int name))
 186                        (directory-files pathname nil "^[0-9]+$" t))
 187                '<))
 188         (cond
 189          (dir
 190           (setq nnmh-group-alist
 191                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 192           (push (list group (cons (car dir) (car (last dir))))
 193                 nnmh-group-alist)
 194           (nnheader-report 'nnmh "Selected group %s" group)
 195           (nnheader-insert
 196            "211 %d %d %d %s\n" (length dir) (car dir)
 197            (car (last dir)) group))
 198          (t
 199           (nnheader-report 'nnmh "Empty group %s" group)
 200           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 201
 202 (deffoo nnmh-request-scan (&optional group server)
 203   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 204
 205 (deffoo nnmh-request-list (&optional server dir)
 206   (nnheader-insert "")
 207   (nnmh-possibly-change-directory nil server)
 208   (let ((file-name-coding-system nnmail-pathname-coding-system)
 209         (pathname-coding-system nnmail-pathname-coding-system)
 210         (nnmh-toplev
 211          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 212     (nnmh-request-list-1 nnmh-toplev))
 213   (setq nnmh-group-alist (nnmail-get-active))
 214   t)
 215
 216 (defvar nnmh-toplev)
 217 (defun nnmh-request-list-1 (dir)
 218   (setq dir (expand-file-name dir))
 219   ;; Recurse down all directories.
 220   (let ((dirs (and (file-readable-p dir)
 221                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 222                    (nnheader-directory-files dir t nil t)))
 223         rdir)
 224     ;; Recurse down directories.
 225     (while (setq rdir (pop dirs))
 226       (when (and (file-directory-p rdir)
 227                  (file-readable-p rdir)
 228                  (not (equal (file-truename rdir)
 229                              (file-truename dir))))
 230         (nnmh-request-list-1 rdir))))
 231   ;; For each directory, generate an active file line.
 232   (unless (string= (expand-file-name nnmh-toplev) dir)
 233     (let ((files (mapcar
 234                   (lambda (name) (string-to-int name))
 235                   (directory-files dir nil "^[0-9]+$" t))))
 236       (when files
 237         (save-excursion
 238           (set-buffer nntp-server-buffer)
 239           (goto-char (point-max))
 240           (insert
 241            (format
 242             "%s %.0f %.0f y\n"
 243             (progn
 244               (string-match
 245                (regexp-quote
 246                 (file-truename (file-name-as-directory
 247                                 (expand-file-name nnmh-toplev))))
 248                dir)
 249               (string-as-multibyte
 250                (encode-coding-string
 251                 (nnheader-replace-chars-in-string
 252                  (substring dir (match-end 0))
 253                  ?/ ?.)
 254                 nnmail-pathname-coding-system)))
 255             (apply 'max files)
 256             (apply 'min files)))))))
 257   t)
 258
 259 (deffoo nnmh-request-newgroups (date &optional server)
 260   (nnmh-request-list server))
 261
 262 (deffoo nnmh-request-expire-articles (articles newsgroup
 263                                                &optional server force)
 264   (nnmh-possibly-change-directory newsgroup server)
 265   (let* ((is-old t)
 266          article rest mod-time)
 267     (nnheader-init-server-buffer)
 268
 269     (while (and articles is-old)
 270       (setq article (concat nnmh-current-directory
 271                             (int-to-string (car articles))))
 272       (when (setq mod-time (nth 5 (file-attributes article)))
 273         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 274                  (setq is-old
 275                        (nnmail-expired-article-p newsgroup mod-time force)))
 276             (progn
 277               ;; Allow a special target group. -- jcn
 278               (unless (eq nnmail-expiry-target 'delete)
 279                 (with-temp-buffer
 280                   (nnmh-request-article (car articles)
 281                                         newsgroup server (current-buffer))
 282                   (nnmail-expiry-target-group
 283                    nnmail-expiry-target newsgroup)))
 284               (nnheader-message 5 "Deleting article %s in %s..."
 285                                 article newsgroup)
 286               (condition-case ()
 287                   (funcall nnmail-delete-file-function article)
 288                 (file-error
 289                  (nnheader-message 1 "Couldn't delete article %s in %s"
 290                                    article newsgroup)
 291                  (push (car articles) rest))))
 292           (push (car articles) rest)))
 293       (setq articles (cdr articles)))
 294     (nnheader-message 5 "")
 295     (nconc rest articles)))
 296
 297 (deffoo nnmh-close-group (group &optional server)
 298   t)
 299
 300 (deffoo nnmh-request-move-article (article group server
 301                                            accept-form &optional last)
 302   (let ((buf (get-buffer-create " *nnmh move*"))
 303         result)
 304     (and
 305      (nnmh-deletable-article-p group article)
 306      (nnmh-request-article article group server)
 307      (save-excursion
 308        (set-buffer buf)
 309        (erase-buffer)
 310        (insert-buffer-substring nntp-server-buffer)
 311        (setq result (eval accept-form))
 312        (kill-buffer (current-buffer))
 313        result)
 314      (progn
 315        (nnmh-possibly-change-directory group server)
 316        (condition-case ()
 317            (funcall nnmail-delete-file-function
 318                     (concat nnmh-current-directory (int-to-string article)))
 319          (file-error nil))))
 320     result))
 321
 322 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 323   (nnmh-possibly-change-directory group server)
 324   (if (and (not (equal group "queue"))
 325            (not (equal group "draft")))
 326       (nnmail-check-syntax))
 327   (when nnmail-cache-accepted-message-ids
 328     (nnmail-cache-insert (nnmail-fetch-field "message-id")
 329                          group
 330                          (nnmail-fetch-field "subject")
 331                          (nnmail-fetch-field "from")))
 332   (nnheader-init-server-buffer)
 333   (prog1
 334       (if (stringp group)
 335           (if noinsert
 336               (nnmh-active-number group)
 337             (car (nnmh-save-mail
 338                   (list (cons group (nnmh-active-number group)))
 339                   noinsert)))
 340         (let ((res (nnmail-article-group 'nnmh-active-number)))
 341           (if (and (null res)
 342                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 343               'junk
 344             (car (nnmh-save-mail res noinsert)))))
 345     (when (and last nnmail-cache-accepted-message-ids)
 346       (nnmail-cache-close))))
 347
 348 (deffoo nnmh-request-replace-article (article group buffer)
 349   (nnmh-possibly-change-directory group)
 350   (save-excursion
 351     (set-buffer buffer)
 352     (nnmh-possibly-create-directory group)
 353     (ignore-errors
 354       (nnmail-write-region
 355        (point-min) (point-max)
 356        (concat nnmh-current-directory (int-to-string article))
 357        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 358       t)))
 359
 360 (deffoo nnmh-request-create-group (group &optional server args)
 361   (nnheader-init-server-buffer)
 362   (unless (assoc group nnmh-group-alist)
 363     (let (active)
 364       (push (list group (setq active (cons 1 0)))
 365             nnmh-group-alist)
 366       (nnmh-possibly-create-directory group)
 367       (nnmh-possibly-change-directory group server)
 368       (let ((articles (mapcar
 369                        (lambda (file)
 370                          (string-to-int file))
 371                        (directory-files
 372                         nnmh-current-directory nil "^[0-9]+$"))))
 373         (when articles
 374           (setcar active (apply 'min articles))
 375           (setcdr active (apply 'max articles))))))
 376   t)
 377
 378 (deffoo nnmh-request-delete-group (group &optional force server)
 379   (nnmh-possibly-change-directory group server)
 380   ;; Delete all articles in GROUP.
 381   (if (not force)
 382       ()                                ; Don't delete the articles.
 383     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 384       (while articles
 385         (when (file-writable-p (car articles))
 386           (nnheader-message 5 "Deleting article %s in %s..."
 387                             (car articles) group)
 388           (funcall nnmail-delete-file-function (car articles)))
 389         (setq articles (cdr articles))))
 390     ;; Try to delete the directory itself.
 391     (ignore-errors
 392       (delete-directory nnmh-current-directory)))
 393   ;; Remove the group from all structures.
 394   (setq nnmh-group-alist
 395         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 396         nnmh-current-directory nil)
 397   t)
 398
 399 (deffoo nnmh-request-rename-group (group new-name &optional server)
 400   (nnmh-possibly-change-directory group server)
 401   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 402         (old-dir (nnmail-group-pathname group nnmh-directory)))
 403     (when (ignore-errors
 404             (make-directory new-dir t)
 405             t)
 406       ;; We move the articles file by file instead of renaming
 407       ;; the directory -- there may be subgroups in this group.
 408       ;; One might be more clever, I guess.
 409       (let ((files (nnheader-article-to-file-alist old-dir)))
 410         (while files
 411           (rename-file
 412            (concat old-dir (cdar files))
 413            (concat new-dir (cdar files)))
 414           (pop files)))
 415       (when (<= (length (directory-files old-dir)) 2)
 416         (ignore-errors
 417           (delete-directory old-dir)))
 418       ;; That went ok, so we change the internal structures.
 419       (let ((entry (assoc group nnmh-group-alist)))
 420         (when entry
 421           (setcar entry new-name))
 422         (setq nnmh-current-directory nil)
 423         t))))
 424
 425 (nnoo-define-skeleton nnmh)
 426
 427 \f
 428 ;;; Internal functions.
 429
 430 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 431   (when (and server
 432              (not (nnmh-server-opened server)))
 433     (nnmh-open-server server))
 434   (when newsgroup
 435     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 436           (file-name-coding-system nnmail-pathname-coding-system)
 437           (pathname-coding-system nnmail-pathname-coding-system))
 438       (if (file-directory-p pathname)
 439           (setq nnmh-current-directory pathname)
 440         (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory)))))
 441
 442 (defun nnmh-possibly-create-directory (group)
 443   (let (dir dirs)
 444     (setq dir (nnmail-group-pathname group nnmh-directory))
 445     (while (not (file-directory-p dir))
 446       (push dir dirs)
 447       (setq dir (file-name-directory (directory-file-name dir))))
 448     (while dirs
 449       (when (make-directory (directory-file-name (car dirs)))
 450         (error "Could not create directory %s" (car dirs)))
 451       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 452       (setq dirs (cdr dirs)))))
 453
 454 (defun nnmh-save-mail (group-art &optional noinsert)
 455   "Called narrowed to an article."
 456   (unless noinsert
 457     (nnmail-insert-lines)
 458     (nnmail-insert-xref group-art))
 459   (run-hooks 'nnmail-prepare-save-mail-hook)
 460   (run-hooks 'nnmh-prepare-save-mail-hook)
 461   (goto-char (point-min))
 462   (while (looking-at "From ")
 463     (replace-match "X-From-Line: ")
 464     (forward-line 1))
 465   ;; We save the article in all the newsgroups it belongs in.
 466   (let ((ga group-art)
 467         first)
 468     (while ga
 469       (nnmh-possibly-create-directory (caar ga))
 470       (let ((file (concat (nnmail-group-pathname
 471                            (caar ga) nnmh-directory)
 472                           (int-to-string (cdar ga)))))
 473         (if first
 474             ;; It was already saved, so we just make a hard link.
 475             (funcall nnmail-crosspost-link-function first file t)
 476           ;; Save the article.
 477           (nnmail-write-region (point-min) (point-max) file nil nil)
 478           (setq first file)))
 479       (setq ga (cdr ga))))
 480   group-art)
 481
 482 (defun nnmh-active-number (group)
 483   "Compute the next article number in GROUP."
 484   (let ((active (cadr (assoc group nnmh-group-alist)))
 485         (dir (nnmail-group-pathname group nnmh-directory))
 486         (file-name-coding-system nnmail-pathname-coding-system)
 487         (pathname-coding-system nnmail-pathname-coding-system)
 488         file)
 489     (unless active
 490       ;; The group wasn't known to nnmh, so we just create an active
 491       ;; entry for it.
 492       (setq active (cons 1 0))
 493       (push (list group active) nnmh-group-alist)
 494       (unless (file-exists-p dir)
 495         (gnus-make-directory dir))
 496       ;; Find the highest number in the group.
 497       (let ((files (sort
 498                     (mapcar
 499                      (lambda (f)
 500                        (string-to-int f))
 501                      (directory-files dir nil "^[0-9]+$"))
 502                     '>)))
 503         (when files
 504           (setcdr active (car files)))))
 505     (setcdr active (1+ (cdr active)))
 506     (while (or
 507             ;; See whether the file exists...
 508             (file-exists-p
 509              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 510                                 (int-to-string (cdr active)))))
 511             ;; ... or there is a buffer that will make that file exist
 512             ;; in the future.
 513             (get-file-buffer file))
 514       ;; Skip past that file.
 515       (setcdr active (1+ (cdr active))))
 516     (cdr active)))
 517
 518 (defun nnmh-update-gnus-unreads (group)
 519   ;; Go through the .nnmh-articles file and compare with the actual
 520   ;; articles in this folder.  The articles that are "new" will be
 521   ;; marked as unread by Gnus.
 522   (let* ((dir nnmh-current-directory)
 523          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 524                               (directory-files nnmh-current-directory
 525                                                nil "^[0-9]+$" t))
 526                       '<))
 527          (nnmh-file (concat dir ".nnmh-articles"))
 528          new articles)
 529     ;; Load the .nnmh-articles file.
 530     (when (file-exists-p nnmh-file)
 531       (setq articles
 532             (let (nnmh-newsgroup-articles)
 533               (ignore-errors (load nnmh-file nil t t))
 534               nnmh-newsgroup-articles)))
 535     ;; Add all new articles to the `new' list.
 536     (let ((art files))
 537       (while art
 538         (unless (assq (car art) articles)
 539           (push (car art) new))
 540         (setq art (cdr art))))
 541     ;; Remove all deleted articles.
 542     (let ((art articles))
 543       (while art
 544         (unless (memq (caar art) files)
 545           (setq articles (delq (car art) articles)))
 546         (setq art (cdr art))))
 547     ;; Check whether the articles really are the ones that Gnus thinks
 548     ;; they are by looking at the time-stamps.
 549     (let ((arts articles)
 550           art)
 551       (while (setq art (pop arts))
 552         (when (not (equal
 553                     (nth 5 (file-attributes
 554                             (concat dir (int-to-string (car art)))))
 555                     (cdr art)))
 556           (setq articles (delq art articles))
 557           (push (car art) new))))
 558     ;; Go through all the new articles and add them, and their
 559     ;; time-stamps, to the list.
 560     (setq articles
 561           (nconc articles
 562                  (mapcar
 563                   (lambda (art)
 564                     (cons art
 565                           (nth 5 (file-attributes
 566                                   (concat dir (int-to-string art))))))
 567                   new)))
 568     ;; Make Gnus mark all new articles as unread.
 569     (when new
 570       (gnus-make-articles-unread
 571        (gnus-group-prefixed-name group (list 'nnmh ""))
 572        (setq new (sort new '<))))
 573     ;; Sort the article list with highest numbers first.
 574     (setq articles (sort articles (lambda (art1 art2)
 575                                     (> (car art1) (car art2)))))
 576     ;; Finally write this list back to the .nnmh-articles file.
 577     (with-temp-file nnmh-file
 578       (insert ";; Gnus article active file for " group "\n\n")
 579       (insert "(setq nnmh-newsgroup-articles '")
 580       (gnus-prin1 articles)
 581       (insert ")\n"))))
 582
 583 (defun nnmh-deletable-article-p (group article)
 584   "Say whether ARTICLE in GROUP can be deleted."
 585   (let ((path (concat nnmh-current-directory (int-to-string article))))
 586     ;; Writable.
 587     (and (file-writable-p path)
 588          (or
 589           ;; We can never delete the last article in the group.
 590           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 591                    article))
 592           ;; Well, we can.
 593           nnmh-allow-delete-final))))
 594
 595 (provide 'nnmh)
 596
 597 ;;; nnmh.el ends here