git.chise.org Git - elisp/gnus.git-/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus-start)
  36 (require 'nnoo)
  37 (eval-when-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.")
  52
  53 \f
  54
  55 (defconst nnmh-version "nnmh 1.0"
  56   "nnmh version.")
  57
  58 (defvoo nnmh-current-directory nil
  59   "Current news group directory.")
  60
  61 (defvoo nnmh-status-string "")
  62 (defvoo nnmh-group-alist nil)
  63 (defvoo nnmh-allow-delete-final nil)
  64
  65 \f
  66
  67 ;;; Interface functions.
  68
  69 (nnoo-define-basics nnmh)
  70
  71 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  72   (save-excursion
  73     (set-buffer nntp-server-buffer)
  74     (erase-buffer)
  75     (let* ((file nil)
  76            (number (length articles))
  77            (large (and (numberp nnmail-large-newsgroup)
  78                        (> number nnmail-large-newsgroup)))
  79            (count 0)
  80            (pathname-coding-system 'binary)
  81            beg article)
  82       (nnmh-possibly-change-directory newsgroup server)
  83       ;; We don't support fetching by Message-ID.
  84       (if (stringp (car articles))
  85           'headers
  86         (while articles
  87           (when (and (file-exists-p
  88                       (setq file (concat (file-name-as-directory
  89                                           nnmh-current-directory)
  90                                          (int-to-string
  91                                           (setq article (pop articles))))))
  92                      (not (file-directory-p file)))
  93             (insert (format "221 %d Article retrieved.\n" article))
  94             (setq beg (point))
  95             (nnheader-insert-head file)
  96             (goto-char beg)
  97             (if (search-forward "\n\n" nil t)
  98                 (forward-char -1)
  99               (goto-char (point-max))
 100               (insert "\n\n"))
 101             (insert ".\n")
 102             (delete-region (point) (point-max)))
 103           (setq count (1+ count))
 104
 105           (and large
 106                (zerop (% count 20))
 107                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 108                         (/ (* count 100) number))))
 109
 110         (when large
 111           (nnheader-message 5 "nnmh: Receiving headers...done"))
 112
 113         (nnheader-fold-continuation-lines)
 114         'headers))))
 115
 116 (deffoo nnmh-open-server (server &optional defs)
 117   (nnoo-change-server 'nnmh server defs)
 118   (when (not (file-exists-p nnmh-directory))
 119     (condition-case ()
 120         (make-directory nnmh-directory t)
 121       (error t)))
 122   (cond
 123    ((not (file-exists-p nnmh-directory))
 124     (nnmh-close-server)
 125     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 126    ((not (file-directory-p (file-truename nnmh-directory)))
 127     (nnmh-close-server)
 128     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 129    (t
 130     (nnheader-report 'nnmh "Opened server %s using directory %s"
 131                      server nnmh-directory)
 132     t)))
 133
 134 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 135   (nnmh-possibly-change-directory newsgroup server)
 136   (let ((file (if (stringp id)
 137                   nil
 138                 (concat nnmh-current-directory (int-to-string id))))
 139         (pathname-coding-system 'binary)
 140         (nntp-server-buffer (or buffer nntp-server-buffer)))
 141     (and (stringp file)
 142          (file-exists-p file)
 143          (not (file-directory-p file))
 144          (save-excursion (nnmail-find-file file))
 145          (string-to-int (file-name-nondirectory file)))))
 146
 147 (deffoo nnmh-request-group (group &optional server dont-check)
 148   (nnheader-init-server-buffer)
 149   (nnmh-possibly-change-directory group server)
 150   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 151         (pathname-coding-system 'binary)
 152         dir)
 153     (cond
 154      ((not (file-directory-p pathname))
 155       (nnheader-report
 156        'nnmh "Can't select group (no such directory): %s" group))
 157      (t
 158       (setq nnmh-current-directory pathname)
 159       (and nnmh-get-new-mail
 160            nnmh-be-safe
 161            (nnmh-update-gnus-unreads group))
 162       (cond
 163        (dont-check
 164         (nnheader-report 'nnmh "Selected group %s" group)
 165         t)
 166        (t
 167         ;; Re-scan the directory if it's on a foreign system.
 168         (nnheader-re-read-dir pathname)
 169         (setq dir
 170               (sort
 171                (mapcar (lambda (name) (string-to-int name))
 172                        (directory-files pathname nil "^[0-9]+$" t))
 173                '<))
 174           (cond
 175            (dir
 176             (nnheader-report 'nnmh "Selected group %s" group)
 177             (nnheader-insert
 178              "211 %d %d %d %s\n" (length dir) (car dir)
 179              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 180              group))
 181            (t
 182             (nnheader-report 'nnmh "Empty group %s" group)
 183             (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 184
 185 (deffoo nnmh-request-scan (&optional group server)
 186   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 187
 188 (deffoo nnmh-request-list (&optional server dir)
 189   (nnheader-insert "")
 190   (nnmh-possibly-change-directory nil server)
 191   (let ((pathname-coding-system 'binary)
 192         (nnmh-toplev
 193          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 194     (nnmh-request-list-1 nnmh-toplev))
 195   (setq nnmh-group-alist (nnmail-get-active))
 196   t)
 197
 198 (defvar nnmh-toplev)
 199 (defun nnmh-request-list-1 (dir)
 200   (setq dir (expand-file-name dir))
 201   ;; Recurse down all directories.
 202   (let ((dirs (and (file-readable-p dir)
 203                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 204                    (nnheader-directory-files dir t nil t)))
 205         rdir)
 206     ;; Recurse down directories.
 207     (while (setq rdir (pop dirs))
 208       (when (and (file-directory-p rdir)
 209                  (file-readable-p rdir)
 210                  (not (equal (file-truename rdir)
 211                              (file-truename dir))))
 212         (nnmh-request-list-1 rdir))))
 213   ;; For each directory, generate an active file line.
 214   (unless (string= (expand-file-name nnmh-toplev) dir)
 215     (let ((files (mapcar
 216                   (lambda (name) (string-to-int name))
 217                   (directory-files dir nil "^[0-9]+$" t))))
 218       (when files
 219         (save-excursion
 220           (set-buffer nntp-server-buffer)
 221           (goto-char (point-max))
 222           (insert
 223            (format
 224             "%s %d %d y\n"
 225             (progn
 226               (string-match
 227                (regexp-quote
 228                 (file-truename (file-name-as-directory
 229                                 (expand-file-name nnmh-toplev))))
 230                dir)
 231               (nnheader-replace-chars-in-string
 232                (decode-coding-string (substring dir (match-end 0))
 233                                      nnmail-pathname-coding-system)
 234                ?/ ?.))
 235             (apply 'max files)
 236             (apply 'min files)))))))
 237   t)
 238
 239 (deffoo nnmh-request-newgroups (date &optional server)
 240   (nnmh-request-list server))
 241
 242 (deffoo nnmh-request-expire-articles (articles newsgroup
 243                                                &optional server force)
 244   (nnmh-possibly-change-directory newsgroup server)
 245   (let* ((is-old t)
 246          article rest mod-time)
 247     (nnheader-init-server-buffer)
 248
 249     (while (and articles is-old)
 250       (setq article (concat nnmh-current-directory
 251                             (int-to-string (car articles))))
 252       (when (setq mod-time (nth 5 (file-attributes article)))
 253         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 254                  (setq is-old
 255                        (nnmail-expired-article-p newsgroup mod-time force)))
 256             (progn
 257               (nnheader-message 5 "Deleting article %s in %s..."
 258                                 article newsgroup)
 259               (condition-case ()
 260                   (funcall nnmail-delete-file-function article)
 261                 (file-error
 262                  (nnheader-message 1 "Couldn't delete article %s in %s"
 263                                    article newsgroup)
 264                  (push (car articles) rest))))
 265           (push (car articles) rest)))
 266       (setq articles (cdr articles)))
 267     (nnheader-message 5 "")
 268     (nconc rest articles)))
 269
 270 (deffoo nnmh-close-group (group &optional server)
 271   t)
 272
 273 (deffoo nnmh-request-move-article
 274   (article group server accept-form &optional last)
 275   (let ((buf (get-buffer-create " *nnmh move*"))
 276         result)
 277     (and
 278      (nnmh-deletable-article-p group article)
 279      (nnmh-request-article article group server)
 280      (save-excursion
 281        (set-buffer buf)
 282        (erase-buffer)
 283        (insert-buffer-substring nntp-server-buffer)
 284        (setq result (eval accept-form))
 285        (kill-buffer (current-buffer))
 286        result)
 287      (progn
 288        (nnmh-possibly-change-directory group server)
 289        (condition-case ()
 290            (funcall nnmail-delete-file-function
 291                     (concat nnmh-current-directory (int-to-string article)))
 292          (file-error nil))))
 293     result))
 294
 295 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 296   (nnmh-possibly-change-directory group server)
 297   (if (and (not (equal group "queue"))
 298            (not (equal group "draft")))
 299       (nnmail-check-syntax))
 300   (when nnmail-cache-accepted-message-ids
 301     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 302   (nnheader-init-server-buffer)
 303   (prog1
 304       (if (stringp group)
 305           (if noinsert
 306               (nnmh-active-number group)
 307             (car (nnmh-save-mail
 308                   (list (cons group (nnmh-active-number group)))
 309                   noinsert)))
 310         (let ((res (nnmail-article-group 'nnmh-active-number)))
 311           (if (and (null res)
 312                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 313               'junk
 314             (car (nnmh-save-mail res noinsert)))))
 315     (when (and last nnmail-cache-accepted-message-ids)
 316       (nnmail-cache-close))))
 317
 318 (deffoo nnmh-request-replace-article (article group buffer)
 319   (nnmh-possibly-change-directory group)
 320   (save-excursion
 321     (set-buffer buffer)
 322     (nnmh-possibly-create-directory group)
 323     (ignore-errors
 324       (nnmail-write-region
 325        (point-min) (point-max)
 326        (concat nnmh-current-directory (int-to-string article))
 327        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 328       t)))
 329
 330 (deffoo nnmh-request-create-group (group &optional server args)
 331   (nnheader-init-server-buffer)
 332   (unless (assoc group nnmh-group-alist)
 333     (let (active)
 334       (push (list group (setq active (cons 1 0)))
 335             nnmh-group-alist)
 336       (nnmh-possibly-create-directory group)
 337       (nnmh-possibly-change-directory group server)
 338       (let ((articles (mapcar
 339                        (lambda (file)
 340                          (string-to-int file))
 341                        (directory-files
 342                         nnmh-current-directory nil "^[0-9]+$"))))
 343         (when articles
 344           (setcar active (apply 'min articles))
 345           (setcdr active (apply 'max articles))))))
 346   t)
 347
 348 (deffoo nnmh-request-delete-group (group &optional force server)
 349   (nnmh-possibly-change-directory group server)
 350   ;; Delete all articles in GROUP.
 351   (if (not force)
 352       ()                                ; Don't delete the articles.
 353     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 354       (while articles
 355         (when (file-writable-p (car articles))
 356           (nnheader-message 5 "Deleting article %s in %s..."
 357                             (car articles) group)
 358           (funcall nnmail-delete-file-function (car articles)))
 359         (setq articles (cdr articles))))
 360     ;; Try to delete the directory itself.
 361     (ignore-errors
 362       (delete-directory nnmh-current-directory)))
 363   ;; Remove the group from all structures.
 364   (setq nnmh-group-alist
 365         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 366         nnmh-current-directory nil)
 367   t)
 368
 369 (deffoo nnmh-request-rename-group (group new-name &optional server)
 370   (nnmh-possibly-change-directory group server)
 371   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 372         (old-dir (nnmail-group-pathname group nnmh-directory)))
 373     (when (ignore-errors
 374             (make-directory new-dir t)
 375             t)
 376       ;; We move the articles file by file instead of renaming
 377       ;; the directory -- there may be subgroups in this group.
 378       ;; One might be more clever, I guess.
 379       (let ((files (nnheader-article-to-file-alist old-dir)))
 380         (while files
 381           (rename-file
 382            (concat old-dir (cdar files))
 383            (concat new-dir (cdar files)))
 384           (pop files)))
 385       (when (<= (length (directory-files old-dir)) 2)
 386         (ignore-errors
 387           (delete-directory old-dir)))
 388       ;; That went ok, so we change the internal structures.
 389       (let ((entry (assoc group nnmh-group-alist)))
 390         (when entry
 391           (setcar entry new-name))
 392         (setq nnmh-current-directory nil)
 393         t))))
 394
 395 (nnoo-define-skeleton nnmh)
 396
 397 \f
 398 ;;; Internal functions.
 399
 400 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 401   (when (and server
 402              (not (nnmh-server-opened server)))
 403     (nnmh-open-server server))
 404   (when newsgroup
 405     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 406           (pathname-coding-system 'binary))
 407       (if (file-directory-p pathname)
 408           (setq nnmh-current-directory pathname)
 409         (error "No such newsgroup: %s" newsgroup)))))
 410
 411 (defun nnmh-possibly-create-directory (group)
 412   (let (dir dirs)
 413     (setq dir (nnmail-group-pathname group nnmh-directory))
 414     (while (not (file-directory-p dir))
 415       (push dir dirs)
 416       (setq dir (file-name-directory (directory-file-name dir))))
 417     (while dirs
 418       (when (make-directory (directory-file-name (car dirs)))
 419         (error "Could not create directory %s" (car dirs)))
 420       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 421       (setq dirs (cdr dirs)))))
 422
 423 (defun nnmh-save-mail (group-art &optional noinsert)
 424   "Called narrowed to an article."
 425   (unless noinsert
 426     (nnmail-insert-lines)
 427     (nnmail-insert-xref group-art))
 428   (run-hooks 'nnmail-prepare-save-mail-hook)
 429   (run-hooks 'nnmh-prepare-save-mail-hook)
 430   (goto-char (point-min))
 431   (while (looking-at "From ")
 432     (replace-match "X-From-Line: ")
 433     (forward-line 1))
 434   ;; We save the article in all the newsgroups it belongs in.
 435   (let ((ga group-art)
 436         first)
 437     (while ga
 438       (nnmh-possibly-create-directory (caar ga))
 439       (let ((file (concat (nnmail-group-pathname
 440                            (caar ga) nnmh-directory)
 441                           (int-to-string (cdar ga)))))
 442         (if first
 443             ;; It was already saved, so we just make a hard link.
 444             (funcall nnmail-crosspost-link-function first file t)
 445           ;; Save the article.
 446           (nnmail-write-region (point-min) (point-max) file nil nil)
 447           (setq first file)))
 448       (setq ga (cdr ga))))
 449   group-art)
 450
 451 (defun nnmh-active-number (group)
 452   "Compute the next article number in GROUP."
 453   (let ((active (cadr (assoc group nnmh-group-alist)))
 454         (dir (nnmail-group-pathname group nnmh-directory))
 455         (pathname-coding-system 'binary))
 456     (unless active
 457       ;; The group wasn't known to nnmh, so we just create an active
 458       ;; entry for it.
 459       (setq active (cons 1 0))
 460       (push (list group active) nnmh-group-alist)
 461       (unless (file-exists-p dir)
 462         (gnus-make-directory dir))
 463       ;; Find the highest number in the group.
 464       (let ((files (sort
 465                     (mapcar
 466                      (lambda (f)
 467                        (string-to-int f))
 468                      (directory-files dir nil "^[0-9]+$"))
 469                     '>)))
 470         (when files
 471           (setcdr active (car files)))))
 472     (setcdr active (1+ (cdr active)))
 473     (while (file-exists-p
 474             (concat (nnmail-group-pathname group nnmh-directory)
 475                     (int-to-string (cdr active))))
 476       (setcdr active (1+ (cdr active))))
 477     (cdr active)))
 478
 479 (defun nnmh-update-gnus-unreads (group)
 480   ;; Go through the .nnmh-articles file and compare with the actual
 481   ;; articles in this folder.  The articles that are "new" will be
 482   ;; marked as unread by Gnus.
 483   (let* ((dir nnmh-current-directory)
 484          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 485                               (directory-files nnmh-current-directory
 486                                                nil "^[0-9]+$" t))
 487                       '<))
 488          (nnmh-file (concat dir ".nnmh-articles"))
 489          new articles)
 490     ;; Load the .nnmh-articles file.
 491     (when (file-exists-p nnmh-file)
 492       (setq articles
 493             (let (nnmh-newsgroup-articles)
 494               (ignore-errors (load nnmh-file nil t t))
 495               nnmh-newsgroup-articles)))
 496     ;; Add all new articles to the `new' list.
 497     (let ((art files))
 498       (while art
 499         (unless (assq (car art) articles)
 500           (push (car art) new))
 501         (setq art (cdr art))))
 502     ;; Remove all deleted articles.
 503     (let ((art articles))
 504       (while art
 505         (unless (memq (caar art) files)
 506           (setq articles (delq (car art) articles)))
 507         (setq art (cdr art))))
 508     ;; Check whether the articles really are the ones that Gnus thinks
 509     ;; they are by looking at the time-stamps.
 510     (let ((arts articles)
 511           art)
 512       (while (setq art (pop arts))
 513         (when (not (equal
 514                     (nth 5 (file-attributes
 515                             (concat dir (int-to-string (car art)))))
 516                     (cdr art)))
 517           (setq articles (delq art articles))
 518           (push (car art) new))))
 519     ;; Go through all the new articles and add them, and their
 520     ;; time-stamps, to the list.
 521     (setq articles
 522           (nconc articles
 523                  (mapcar
 524                   (lambda (art)
 525                     (cons art
 526                           (nth 5 (file-attributes
 527                                   (concat dir (int-to-string art))))))
 528                   new)))
 529     ;; Make Gnus mark all new articles as unread.
 530     (when new
 531       (gnus-make-articles-unread
 532        (gnus-group-prefixed-name group (list 'nnmh ""))
 533        (setq new (sort new '<))))
 534     ;; Sort the article list with highest numbers first.
 535     (setq articles (sort articles (lambda (art1 art2)
 536                                     (> (car art1) (car art2)))))
 537     ;; Finally write this list back to the .nnmh-articles file.
 538     (with-temp-file nnmh-file
 539       (insert ";; Gnus article active file for " group "\n\n")
 540       (insert "(setq nnmh-newsgroup-articles '")
 541       (gnus-prin1 articles)
 542       (insert ")\n"))))
 543
 544 (defun nnmh-deletable-article-p (group article)
 545   "Say whether ARTICLE in GROUP can be deleted."
 546   (let ((path (concat nnmh-current-directory (int-to-string article))))
 547     ;; Writable.
 548     (and (file-writable-p path)
 549          (or
 550           ;; We can never delete the last article in the group.
 551           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 552                    article))
 553           ;; Well, we can.
 554           nnmh-allow-delete-final))))
 555
 556 (provide 'nnmh)
 557
 558 ;;; nnmh.el ends here