git.chise.org Git - elisp/gnus.git-/blob - lisp/nnml.el

   1 ;;; nnml.el --- mail spool access for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org> (adding MARKS)
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  30 ;; For an overview of what the interface functions do, please see the
  31 ;; Gnus sources.
  32
  33 ;;; Code:
  34
  35 (eval-when-compile (require 'cl))
  36 (eval-when-compile (require 'gnus-clfns))
  37
  38 (require 'gnus)
  39 (require 'nnheader)
  40 (require 'nnmail)
  41 (require 'nnoo)
  42
  43 (eval-and-compile
  44   (autoload 'gnus-article-unpropagatable-p "gnus-sum"))
  45
  46 (nnoo-declare nnml)
  47
  48 (defvoo nnml-directory message-directory
  49   "Spool directory for the nnml mail backend.")
  50
  51 (defvoo nnml-active-file
  52     (expand-file-name "active" nnml-directory)
  53   "Mail active file.")
  54
  55 (defvoo nnml-newsgroups-file
  56     (expand-file-name "newsgroups" nnml-directory)
  57   "Mail newsgroups description file.")
  58
  59 (defvoo nnml-get-new-mail t
  60   "If non-nil, nnml will check the incoming mail file and split the mail.")
  61
  62 (defvoo nnml-nov-is-evil nil
  63   "If non-nil, Gnus will never generate and use nov databases for mail spools.
  64 Using nov databases will speed up header fetching considerably.
  65 This variable shouldn't be flipped much.  If you have, for some reason,
  66 set this to t, and want to set it to nil again, you should always run
  67 the `nnml-generate-nov-databases' command.  The function will go
  68 through all nnml directories and generate nov databases for them
  69 all.  This may very well take some time.")
  70
  71 (defvoo nnml-marks-is-evil nil
  72   "If non-nil, Gnus will never generate and use marks file for mail spools.
  73 Using marks files makes it possible to backup and restore mail groups
  74 separately from `.newsrc.eld'.  If you have, for some reason, set this
  75 to t, and want to set it to nil again, you should always remove the
  76 corresponding marks file (usually named `.marks' in the nnml group
  77 directory, but see `nnml-marks-file-name') for the group.  Then the
  78 marks file will be regenerated properly by Gnus.")
  79
  80 (defvoo nnml-prepare-save-mail-hook nil
  81   "Hook run narrowed to an article before saving.")
  82
  83 (defvoo nnml-inhibit-expiry nil
  84   "If non-nil, inhibit expiry.")
  85
  86 (defvoo nnml-use-compressed-files nil
  87   "If non-nil, allow using compressed message files.")
  88
  89 \f
  90
  91 (defconst nnml-version "nnml 1.0"
  92   "nnml version.")
  93
  94 (defvoo nnml-nov-file-name ".overview")
  95 (defvoo nnml-marks-file-name ".marks")
  96
  97 (defvoo nnml-current-directory nil)
  98 (defvoo nnml-current-group nil)
  99 (defvoo nnml-status-string "")
 100 (defvoo nnml-nov-buffer-alist nil)
 101 (defvoo nnml-group-alist nil)
 102 (defvoo nnml-active-timestamp nil)
 103 (defvoo nnml-article-file-alist nil)
 104
 105 (defvoo nnml-generate-active-function 'nnml-generate-active-info)
 106
 107 (defvar nnml-nov-buffer-file-name nil)
 108
 109 (defvoo nnml-file-coding-system nnmail-file-coding-system)
 110
 111 (defvoo nnml-marks nil)
 112
 113 (defvar nnml-marks-modtime (gnus-make-hashtable))
 114
 115 \f
 116 ;;; Interface functions.
 117
 118 (nnoo-define-basics nnml)
 119
 120 (deffoo nnml-retrieve-headers (sequence &optional group server fetch-old)
 121   (when (nnml-possibly-change-directory group server)
 122     (save-excursion
 123       (set-buffer nntp-server-buffer)
 124       (erase-buffer)
 125       (let* ((file nil)
 126              (number (length sequence))
 127              (count 0)
 128              (file-name-coding-system nnmail-pathname-coding-system)
 129              beg article)
 130         (if (stringp (car sequence))
 131             'headers
 132           (if (nnml-retrieve-headers-with-nov sequence fetch-old)
 133               'nov
 134             (while sequence
 135               (setq article (car sequence))
 136               (setq file (nnml-article-to-file article))
 137               (when (and file
 138                          (file-exists-p file)
 139                          (not (file-directory-p file)))
 140                 (insert (format "221 %d Article retrieved.\n" article))
 141                 (setq beg (point))
 142                 (nnheader-insert-head file)
 143                 (goto-char beg)
 144                 (if (re-search-forward "\n\r?\n" nil t)
 145                     (forward-char -1)
 146                   (goto-char (point-max))
 147                   (insert "\n\n"))
 148                 (insert ".\n")
 149                 (delete-region (point) (point-max)))
 150               (setq sequence (cdr sequence))
 151               (setq count (1+ count))
 152               (and (numberp nnmail-large-newsgroup)
 153                    (> number nnmail-large-newsgroup)
 154                    (zerop (% count 20))
 155                    (nnheader-message 6 "nnml: Receiving headers... %d%%"
 156                                      (/ (* count 100) number))))
 157
 158             (and (numberp nnmail-large-newsgroup)
 159                  (> number nnmail-large-newsgroup)
 160                  (nnheader-message 6 "nnml: Receiving headers...done"))
 161
 162             (nnheader-fold-continuation-lines)
 163             'headers))))))
 164
 165 (deffoo nnml-open-server (server &optional defs)
 166   (nnoo-change-server 'nnml server defs)
 167   (when (not (file-exists-p nnml-directory))
 168     (ignore-errors (make-directory nnml-directory t)))
 169   (cond
 170    ((not (file-exists-p nnml-directory))
 171     (nnml-close-server)
 172     (nnheader-report 'nnml "Couldn't create directory: %s" nnml-directory))
 173    ((not (file-directory-p (file-truename nnml-directory)))
 174     (nnml-close-server)
 175     (nnheader-report 'nnml "Not a directory: %s" nnml-directory))
 176    (t
 177     (nnheader-report 'nnml "Opened server %s using directory %s"
 178                      server nnml-directory)
 179     t)))
 180
 181 (deffoo nnml-request-regenerate (server)
 182   (nnml-possibly-change-directory nil server)
 183   (nnml-generate-nov-databases server)
 184   t)
 185
 186 (deffoo nnml-request-article (id &optional group server buffer)
 187   (nnml-possibly-change-directory group server)
 188   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 189          (file-name-coding-system nnmail-pathname-coding-system)
 190          path gpath group-num)
 191     (if (stringp id)
 192         (when (and (setq group-num (nnml-find-group-number id))
 193                    (cdr
 194                     (assq (cdr group-num)
 195                           (nnheader-article-to-file-alist
 196                            (setq gpath
 197                                  (nnmail-group-pathname
 198                                   (car group-num)
 199                                   nnml-directory))))))
 200           (setq path (concat gpath (int-to-string (cdr group-num)))))
 201       (setq path (nnml-article-to-file id)))
 202     (cond
 203      ((not path)
 204       (nnheader-report 'nnml "No such article: %s" id))
 205      ((not (file-exists-p path))
 206       (nnheader-report 'nnml "No such file: %s" path))
 207      ((file-directory-p path)
 208       (nnheader-report 'nnml "File is a directory: %s" path))
 209      ((not (save-excursion (let ((nnmail-file-coding-system
 210                                   nnml-file-coding-system))
 211                              (nnmail-find-file path))))
 212       (nnheader-report 'nnml "Couldn't read file: %s" path))
 213      (t
 214       (nnheader-report 'nnml "Article %s retrieved" id)
 215       ;; We return the article number.
 216       (cons (if group-num (car group-num) group)
 217             (string-to-int (file-name-nondirectory path)))))))
 218
 219 (deffoo nnml-request-group (group &optional server dont-check)
 220   (let ((file-name-coding-system nnmail-pathname-coding-system))
 221     (cond
 222      ((not (nnml-possibly-change-directory group server))
 223       (nnheader-report 'nnml "Invalid group (no such directory)"))
 224      ((not (file-exists-p nnml-current-directory))
 225       (nnheader-report 'nnml "Directory %s does not exist"
 226                        nnml-current-directory))
 227      ((not (file-directory-p nnml-current-directory))
 228       (nnheader-report 'nnml "%s is not a directory" nnml-current-directory))
 229      (dont-check
 230       (nnheader-report 'nnml "Group %s selected" group)
 231       t)
 232      (t
 233       (nnheader-re-read-dir nnml-current-directory)
 234       (nnmail-activate 'nnml)
 235       (let ((active (nth 1 (assoc group nnml-group-alist))))
 236         (if (not active)
 237             (nnheader-report 'nnml "No such group: %s" group)
 238           (nnheader-report 'nnml "Selected group %s" group)
 239           (nnheader-insert "211 %d %d %d %s\n"
 240                            (max (1+ (- (cdr active) (car active))) 0)
 241                            (car active) (cdr active) group)))))))
 242
 243 (deffoo nnml-request-scan (&optional group server)
 244   (setq nnml-article-file-alist nil)
 245   (nnml-possibly-change-directory group server)
 246   (nnmail-get-new-mail 'nnml 'nnml-save-nov nnml-directory group))
 247
 248 (deffoo nnml-close-group (group &optional server)
 249   (setq nnml-article-file-alist nil)
 250   t)
 251
 252 (deffoo nnml-request-create-group (group &optional server args)
 253   (nnml-possibly-change-directory nil server)
 254   (nnmail-activate 'nnml)
 255   (cond
 256    ((assoc group nnml-group-alist)
 257     t)
 258    ((and (file-exists-p (nnmail-group-pathname group nnml-directory))
 259          (not (file-directory-p (nnmail-group-pathname group nnml-directory))))
 260     (nnheader-report 'nnml "%s is a file"
 261                      (nnmail-group-pathname group nnml-directory)))
 262    (t
 263     (let (active)
 264       (push (list group (setq active (cons 1 0)))
 265             nnml-group-alist)
 266       (nnml-possibly-create-directory group)
 267       (nnml-possibly-change-directory group server)
 268       (let ((articles (nnml-directory-articles nnml-current-directory)))
 269         (when articles
 270           (setcar active (apply 'min articles))
 271           (setcdr active (apply 'max articles))))
 272       (nnmail-save-active nnml-group-alist nnml-active-file)
 273       t))))
 274
 275 (deffoo nnml-request-list (&optional server)
 276   (save-excursion
 277     (let ((nnmail-file-coding-system nnmail-active-file-coding-system)
 278           (file-name-coding-system nnmail-pathname-coding-system))
 279       (nnmail-find-file nnml-active-file))
 280     (setq nnml-group-alist (nnmail-get-active))
 281     t))
 282
 283 (deffoo nnml-request-newgroups (date &optional server)
 284   (nnml-request-list server))
 285
 286 (deffoo nnml-request-list-newsgroups (&optional server)
 287   (save-excursion
 288     (nnmail-find-file nnml-newsgroups-file)))
 289
 290 (deffoo nnml-request-expire-articles (articles group &optional server force)
 291   (nnml-possibly-change-directory group server)
 292   (let ((active-articles
 293          (nnml-directory-articles nnml-current-directory))
 294         (is-old t)
 295         article rest mod-time number)
 296     (nnmail-activate 'nnml)
 297
 298     (setq active-articles (sort active-articles '<))
 299     ;; Articles not listed in active-articles are already gone,
 300     ;; so don't try to expire them.
 301     (setq articles (gnus-sorted-intersection articles active-articles))
 302
 303     (while (and articles is-old)
 304       (if (and (setq article (nnml-article-to-file
 305                               (setq number (pop articles))))
 306                (setq mod-time (nth 5 (file-attributes article)))
 307                (nnml-deletable-article-p group number)
 308                (setq is-old (nnmail-expired-article-p group mod-time force
 309                                                       nnml-inhibit-expiry)))
 310           (progn
 311             ;; Allow a special target group.
 312             (unless (eq nnmail-expiry-target 'delete)
 313               (with-temp-buffer
 314                 (nnml-request-article number group server (current-buffer))
 315                 (let (nnml-current-directory
 316                       nnml-current-group
 317                       nnml-article-file-alist)
 318                   (nnmail-expiry-target-group nnmail-expiry-target group)))
 319               ;; Maybe directory is changed during nnmail-expiry-target-group.
 320               (nnml-possibly-change-directory group server))
 321             (nnheader-message 5 "Deleting article %s in %s"
 322                               number group)
 323             (condition-case ()
 324                 (funcall nnmail-delete-file-function article)
 325               (file-error
 326                (push number rest)))
 327             (setq active-articles (delq number active-articles))
 328             (nnml-nov-delete-article group number))
 329         (push number rest)))
 330     (let ((active (nth 1 (assoc group nnml-group-alist))))
 331       (when active
 332         (setcar active (or (and active-articles
 333                                 (apply 'min active-articles))
 334                            (1+ (cdr active)))))
 335       (nnmail-save-active nnml-group-alist nnml-active-file))
 336     (nnml-save-nov)
 337     (nconc rest articles)))
 338
 339 (deffoo nnml-request-move-article
 340     (article group server accept-form &optional last)
 341   (let ((buf (get-buffer-create " *nnml move*"))
 342         result)
 343     (nnml-possibly-change-directory group server)
 344     (nnml-update-file-alist)
 345     (and
 346      (nnml-deletable-article-p group article)
 347      (nnml-request-article article group server)
 348      (let (nnml-current-directory
 349            nnml-current-group
 350            nnml-article-file-alist)
 351        (save-excursion
 352          (set-buffer buf)
 353          (insert-buffer-substring nntp-server-buffer)
 354          (setq result (eval accept-form))
 355          (kill-buffer (current-buffer))
 356          result))
 357      (progn
 358        (nnml-possibly-change-directory group server)
 359        (condition-case ()
 360            (funcall nnmail-delete-file-function
 361                     (nnml-article-to-file  article))
 362          (file-error nil))
 363        (nnml-nov-delete-article group article)
 364        (when last
 365          (nnml-save-nov)
 366          (nnmail-save-active nnml-group-alist nnml-active-file))))
 367     result))
 368
 369 (deffoo nnml-request-accept-article (group &optional server last)
 370   (nnml-possibly-change-directory group server)
 371   (nnmail-check-syntax)
 372   (let (result)
 373     (when nnmail-cache-accepted-message-ids
 374       (nnmail-cache-insert (nnmail-fetch-field "message-id")
 375                            group
 376                            (nnmail-fetch-field "subject")
 377                            (nnmail-fetch-field "from")))
 378     (if (stringp group)
 379         (and
 380          (nnmail-activate 'nnml)
 381          (setq result (car (nnml-save-mail
 382                             (list (cons group (nnml-active-number group))))))
 383          (progn
 384            (nnmail-save-active nnml-group-alist nnml-active-file)
 385            (and last (nnml-save-nov))))
 386       (and
 387        (nnmail-activate 'nnml)
 388        (if (and (not (setq result (nnmail-article-group 'nnml-active-number)))
 389                 (yes-or-no-p "Moved to `junk' group; delete article? "))
 390            (setq result 'junk)
 391          (setq result (car (nnml-save-mail result))))
 392        (when last
 393          (nnmail-save-active nnml-group-alist nnml-active-file)
 394          (when nnmail-cache-accepted-message-ids
 395            (nnmail-cache-close))
 396          (nnml-save-nov))))
 397     result))
 398
 399 (deffoo nnml-request-post (&optional server)
 400   (nnmail-do-request-post 'nnml-request-accept-article server))
 401
 402 (deffoo nnml-request-replace-article (article group buffer)
 403   (nnml-possibly-change-directory group)
 404   (save-excursion
 405     (set-buffer buffer)
 406     (nnml-possibly-create-directory group)
 407     (let ((chars (nnmail-insert-lines))
 408           (art (concat (int-to-string article) "\t"))
 409           headers)
 410       (when (ignore-errors
 411               (nnmail-write-region
 412                (point-min) (point-max)
 413                (or (nnml-article-to-file article)
 414                    (expand-file-name (int-to-string article)
 415                                      nnml-current-directory))
 416                nil (if (nnheader-be-verbose 5) nil 'nomesg))
 417               t)
 418         (setq headers (nnml-parse-head chars article))
 419         ;; Replace the NOV line in the NOV file.
 420         (save-excursion
 421           (set-buffer (nnml-open-nov group))
 422           (goto-char (point-min))
 423           (if (or (looking-at art)
 424                   (search-forward (concat "\n" art) nil t))
 425               ;; Delete the old NOV line.
 426               (gnus-delete-line)
 427             ;; The line isn't here, so we have to find out where
 428             ;; we should insert it.  (This situation should never
 429             ;; occur, but one likes to make sure...)
 430             (while (and (looking-at "[0-9]+\t")
 431                         (< (string-to-int
 432                             (buffer-substring
 433                              (match-beginning 0) (match-end 0)))
 434                            article)
 435                         (zerop (forward-line 1)))))
 436           (beginning-of-line)
 437           (nnheader-insert-nov headers)
 438           (nnml-save-nov)
 439           t)))))
 440
 441 (deffoo nnml-request-delete-group (group &optional force server)
 442   (nnml-possibly-change-directory group server)
 443   (when force
 444     ;; Delete all articles in GROUP.
 445     (let ((articles
 446            (directory-files
 447             nnml-current-directory t
 448             (concat nnheader-numerical-short-files
 449                     "\\|" (regexp-quote nnml-nov-file-name) "$"
 450                     "\\|" (regexp-quote nnml-marks-file-name) "$")))
 451           article)
 452       (while articles
 453         (setq article (pop articles))
 454         (when (file-writable-p article)
 455           (nnheader-message 5 "Deleting article %s in %s..." article group)
 456           (funcall nnmail-delete-file-function article))))
 457     ;; Try to delete the directory itself.
 458     (ignore-errors (delete-directory nnml-current-directory)))
 459   ;; Remove the group from all structures.
 460   (setq nnml-group-alist
 461         (delq (assoc group nnml-group-alist) nnml-group-alist)
 462         nnml-current-group nil
 463         nnml-current-directory nil)
 464   ;; Save the active file.
 465   (nnmail-save-active nnml-group-alist nnml-active-file)
 466   t)
 467
 468 (deffoo nnml-request-rename-group (group new-name &optional server)
 469   (nnml-possibly-change-directory group server)
 470   (let ((new-dir (nnmail-group-pathname new-name nnml-directory))
 471         (old-dir (nnmail-group-pathname group nnml-directory)))
 472     (when (ignore-errors
 473             (make-directory new-dir t)
 474             t)
 475       ;; We move the articles file by file instead of renaming
 476       ;; the directory -- there may be subgroups in this group.
 477       ;; One might be more clever, I guess.
 478       (let ((files (nnheader-article-to-file-alist old-dir)))
 479         (while files
 480           (rename-file
 481            (concat old-dir (cdar files))
 482            (concat new-dir (cdar files)))
 483           (pop files)))
 484       ;; Move .overview file.
 485       (let ((overview (concat old-dir nnml-nov-file-name)))
 486         (when (file-exists-p overview)
 487           (rename-file overview (concat new-dir nnml-nov-file-name))))
 488       ;; Move .marks file.
 489       (let ((marks (concat old-dir nnml-marks-file-name)))
 490         (when (file-exists-p marks)
 491           (rename-file marks (concat new-dir nnml-marks-file-name))))
 492       (when (<= (length (directory-files old-dir)) 2)
 493         (ignore-errors (delete-directory old-dir)))
 494       ;; That went ok, so we change the internal structures.
 495       (let ((entry (assoc group nnml-group-alist)))
 496         (when entry
 497           (setcar entry new-name))
 498         (setq nnml-current-directory nil
 499               nnml-current-group nil)
 500         ;; Save the new group alist.
 501         (nnmail-save-active nnml-group-alist nnml-active-file)
 502         t))))
 503
 504 (deffoo nnml-set-status (article name value &optional group server)
 505   (nnml-possibly-change-directory group server)
 506   (let ((file (nnml-article-to-file article)))
 507     (cond
 508      ((not (file-exists-p file))
 509       (nnheader-report 'nnml "File %s does not exist" file))
 510      (t
 511       (with-temp-file file
 512         (nnheader-insert-file-contents file)
 513         (nnmail-replace-status name value))
 514       t))))
 515
 516 \f
 517 ;;; Internal functions.
 518
 519 (defun nnml-article-to-file (article)
 520   (nnml-update-file-alist)
 521   (let (file)
 522     (if (setq file
 523               (if nnml-use-compressed-files
 524                   (cdr (assq article nnml-article-file-alist))
 525                 (number-to-string article)))
 526         (expand-file-name file nnml-current-directory)
 527       (when (not nnheader-directory-files-is-safe)
 528         ;; Just to make sure nothing went wrong when reading over NFS --
 529         ;; check once more.
 530         (when (file-exists-p
 531                (setq file (expand-file-name (number-to-string article)
 532                                             nnml-current-directory)))
 533           (nnml-update-file-alist t)
 534           file)))))
 535
 536 (defun nnml-deletable-article-p (group article)
 537   "Say whether ARTICLE in GROUP can be deleted."
 538   (let (path)
 539     (when (setq path (nnml-article-to-file article))
 540       (when (file-writable-p path)
 541         (or (not nnmail-keep-last-article)
 542             (not (eq (cdr (nth 1 (assoc group nnml-group-alist)))
 543                      article)))))))
 544
 545 ;; Find an article number in the current group given the Message-ID.
 546 (defun nnml-find-group-number (id)
 547   (save-excursion
 548     (set-buffer (get-buffer-create " *nnml id*"))
 549     (let ((alist nnml-group-alist)
 550           number)
 551       ;; We want to look through all .overview files, but we want to
 552       ;; start with the one in the current directory.  It seems most
 553       ;; likely that the article we are looking for is in that group.
 554       (if (setq number (nnml-find-id nnml-current-group id))
 555           (cons nnml-current-group number)
 556         ;; It wasn't there, so we look through the other groups as well.
 557         (while (and (not number)
 558                     alist)
 559           (or (string= (caar alist) nnml-current-group)
 560               (setq number (nnml-find-id (caar alist) id)))
 561           (or number
 562               (setq alist (cdr alist))))
 563         (and number
 564              (cons (caar alist) number))))))
 565
 566 (defun nnml-find-id (group id)
 567   (erase-buffer)
 568   (let ((nov (expand-file-name nnml-nov-file-name
 569                                (nnmail-group-pathname group nnml-directory)))
 570         number found)
 571     (when (file-exists-p nov)
 572       (nnheader-insert-file-contents nov)
 573       (while (and (not found)
 574                   (search-forward id nil t)) ; We find the ID.
 575         ;; And the id is in the fourth field.
 576         (if (not (and (search-backward "\t" nil t 4)
 577                       (not (search-backward"\t" (gnus-point-at-bol) t))))
 578             (forward-line 1)
 579           (beginning-of-line)
 580           (setq found t)
 581           ;; We return the article number.
 582           (setq number
 583                 (ignore-errors (read (current-buffer))))))
 584       number)))
 585
 586 (defun nnml-retrieve-headers-with-nov (articles &optional fetch-old)
 587   (if (or gnus-nov-is-evil nnml-nov-is-evil)
 588       nil
 589     (let ((nov (expand-file-name nnml-nov-file-name nnml-current-directory)))
 590       (when (file-exists-p nov)
 591         (save-excursion
 592           (set-buffer nntp-server-buffer)
 593           (erase-buffer)
 594           (nnheader-insert-file-contents nov)
 595           (if (and fetch-old
 596                    (not (numberp fetch-old)))
 597               t                         ; Don't remove anything.
 598             (nnheader-nov-delete-outside-range
 599              (if fetch-old (max 1 (- (car articles) fetch-old))
 600                (car articles))
 601              (car (last articles)))
 602             t))))))
 603
 604 (defun nnml-possibly-change-directory (group &optional server)
 605   (when (and server
 606              (not (nnml-server-opened server)))
 607     (nnml-open-server server))
 608   (if (not group)
 609       t
 610     (let ((pathname (nnmail-group-pathname group nnml-directory))
 611           (file-name-coding-system nnmail-pathname-coding-system))
 612       (when (not (equal pathname nnml-current-directory))
 613         (setq nnml-current-directory pathname
 614               nnml-current-group group
 615               nnml-article-file-alist nil))
 616       (file-exists-p nnml-current-directory))))
 617
 618 (defun nnml-possibly-create-directory (group)
 619   (let ((dir (nnmail-group-pathname group nnml-directory)))
 620     (unless (file-exists-p dir)
 621       (make-directory (directory-file-name dir) t)
 622       (nnheader-message 5 "Creating mail directory %s" dir))))
 623
 624 (defun nnml-save-mail (group-art)
 625   "Called narrowed to an article."
 626   (let (chars headers extension)
 627     (setq chars (nnmail-insert-lines))
 628     (setq extension
 629          (and nnml-use-compressed-files
 630               (> chars 1000)
 631               ".gz"))
 632     (nnmail-insert-xref group-art)
 633     (run-hooks 'nnmail-prepare-save-mail-hook)
 634     (run-hooks 'nnml-prepare-save-mail-hook)
 635     (goto-char (point-min))
 636     (while (looking-at "From ")
 637       (replace-match "X-From-Line: ")
 638       (forward-line 1))
 639     ;; We save the article in all the groups it belongs in.
 640     (let ((ga group-art)
 641           first)
 642       (while ga
 643         (nnml-possibly-create-directory (caar ga))
 644         (let ((file (concat (nnmail-group-pathname
 645                              (caar ga) nnml-directory)
 646                             (int-to-string (cdar ga))
 647                             extension)))
 648           (if first
 649               ;; It was already saved, so we just make a hard link.
 650               (funcall nnmail-crosspost-link-function first file t)
 651             ;; Save the article.
 652             (nnmail-write-region (point-min) (point-max) file nil
 653                                  (if (nnheader-be-verbose 5) nil 'nomesg))
 654             (setq first file)))
 655         (setq ga (cdr ga))))
 656     ;; Generate a nov line for this article.  We generate the nov
 657     ;; line after saving, because nov generation destroys the
 658     ;; header.
 659     (setq headers (nnml-parse-head chars))
 660     ;; Output the nov line to all nov databases that should have it.
 661     (let ((ga group-art))
 662       (while ga
 663         (nnml-add-nov (caar ga) (cdar ga) headers)
 664         (setq ga (cdr ga))))
 665     group-art))
 666
 667 (defun nnml-active-number (group)
 668   "Compute the next article number in GROUP."
 669   (let ((active (cadr (assoc group nnml-group-alist))))
 670     ;; The group wasn't known to nnml, so we just create an active
 671     ;; entry for it.
 672     (unless active
 673       ;; Perhaps the active file was corrupt?  See whether
 674       ;; there are any articles in this group.
 675       (nnml-possibly-create-directory group)
 676       (nnml-possibly-change-directory group)
 677       (unless nnml-article-file-alist
 678         (setq nnml-article-file-alist
 679               (sort
 680                (nnml-current-group-article-to-file-alist)
 681                'car-less-than-car)))
 682       (setq active
 683             (if nnml-article-file-alist
 684                 (cons (caar nnml-article-file-alist)
 685                       (caar (last nnml-article-file-alist)))
 686               (cons 1 0)))
 687       (push (list group active) nnml-group-alist))
 688     (setcdr active (1+ (cdr active)))
 689     (while (file-exists-p
 690             (expand-file-name (int-to-string (cdr active))
 691                               (nnmail-group-pathname group nnml-directory)))
 692       (setcdr active (1+ (cdr active))))
 693     (cdr active)))
 694
 695 (defun nnml-add-nov (group article headers)
 696   "Add a nov line for the GROUP base."
 697   (save-excursion
 698     (set-buffer (nnml-open-nov group))
 699     (goto-char (point-max))
 700     (mail-header-set-number headers article)
 701     (nnheader-insert-nov headers)))
 702
 703 (defsubst nnml-header-value ()
 704   (buffer-substring (match-end 0) (gnus-point-at-eol)))
 705
 706 (defun nnml-parse-head (chars &optional number)
 707   "Parse the head of the current buffer."
 708   (save-excursion
 709     (save-restriction
 710       (unless (zerop (buffer-size))
 711         (narrow-to-region
 712          (goto-char (point-min))
 713          (if (re-search-forward "\n\r?\n" nil t)
 714              (1- (point))
 715            (point-max))))
 716       (let ((headers (nnheader-parse-naked-head)))
 717         (mail-header-set-chars headers chars)
 718         (mail-header-set-number headers number)
 719         headers))))
 720
 721 (defun nnml-get-nov-buffer (group)
 722   (let ((buffer (get-buffer-create (format " *nnml overview %s*" group))))
 723     (save-excursion
 724       (set-buffer buffer)
 725       (set (make-local-variable 'nnml-nov-buffer-file-name)
 726            (expand-file-name
 727             nnml-nov-file-name
 728             (nnmail-group-pathname group nnml-directory)))
 729       (erase-buffer)
 730       (when (file-exists-p nnml-nov-buffer-file-name)
 731         (nnheader-insert-file-contents nnml-nov-buffer-file-name)))
 732     buffer))
 733
 734 (defun nnml-open-nov (group)
 735   (or (cdr (assoc group nnml-nov-buffer-alist))
 736       (let ((buffer (nnml-get-nov-buffer group)))
 737         (push (cons group buffer) nnml-nov-buffer-alist)
 738         buffer)))
 739
 740 (defun nnml-save-nov ()
 741   (save-excursion
 742     (while nnml-nov-buffer-alist
 743       (when (buffer-name (cdar nnml-nov-buffer-alist))
 744         (set-buffer (cdar nnml-nov-buffer-alist))
 745         (when (buffer-modified-p)
 746           (nnmail-write-region (point-min) (point-max)
 747                                nnml-nov-buffer-file-name nil 'nomesg))
 748         (set-buffer-modified-p nil)
 749         (kill-buffer (current-buffer)))
 750       (setq nnml-nov-buffer-alist (cdr nnml-nov-buffer-alist)))))
 751
 752 ;;;###autoload
 753 (defun nnml-generate-nov-databases (&optional server)
 754   "Generate NOV databases in all nnml directories."
 755   (interactive (list (or (nnoo-current-server 'nnml) "")))
 756   ;; Read the active file to make sure we don't re-use articles
 757   ;; numbers in empty groups.
 758   (nnmail-activate 'nnml)
 759   (unless (nnml-server-opened server)
 760     (nnml-open-server server))
 761   (setq nnml-directory (expand-file-name nnml-directory))
 762   ;; Recurse down the directories.
 763   (nnml-generate-nov-databases-1 nnml-directory nil t)
 764   ;; Save the active file.
 765   (nnmail-save-active nnml-group-alist nnml-active-file))
 766
 767 (defun nnml-generate-nov-databases-1 (dir &optional seen no-active)
 768   "Regenerate the NOV database in DIR."
 769   (interactive "DRegenerate NOV in: ")
 770   (setq dir (file-name-as-directory dir))
 771   ;; Only scan this sub-tree if we haven't been here yet.
 772   (unless (member (file-truename dir) seen)
 773     (push (file-truename dir) seen)
 774     ;; We descend recursively
 775     (let ((dirs (directory-files dir t nil t))
 776           dir)
 777       (while (setq dir (pop dirs))
 778         (when (and (not (string-match "^\\." (file-name-nondirectory dir)))
 779                    (file-directory-p dir))
 780           (nnml-generate-nov-databases-1 dir seen))))
 781     ;; Do this directory.
 782     (let ((files (sort (nnheader-article-to-file-alist dir)
 783                        'car-less-than-car)))
 784       (if (not files)
 785           (let* ((group (nnheader-file-to-group
 786                          (directory-file-name dir) nnml-directory))
 787                  (info (cadr (assoc group nnml-group-alist))))
 788             (when info
 789               (setcar info (1+ (cdr info)))))
 790         (funcall nnml-generate-active-function dir)
 791         ;; Generate the nov file.
 792         (nnml-generate-nov-file dir files)
 793         (unless no-active
 794           (nnmail-save-active nnml-group-alist nnml-active-file))))))
 795
 796 (eval-when-compile (defvar files))
 797 (defun nnml-generate-active-info (dir)
 798   ;; Update the active info for this group.
 799   (let* ((group (nnheader-file-to-group
 800                  (directory-file-name dir) nnml-directory))
 801          (entry (assoc group nnml-group-alist))
 802          (last (or (caadr entry) 0)))
 803     (setq nnml-group-alist (delq entry nnml-group-alist))
 804     (push (list group
 805                 (cons (or (caar files) (1+ last))
 806                       (max last
 807                            (or (let ((f files))
 808                                  (while (cdr f) (setq f (cdr f)))
 809                                  (caar f))
 810                                0))))
 811           nnml-group-alist)))
 812
 813 (defun nnml-generate-nov-file (dir files)
 814   (let* ((dir (file-name-as-directory dir))
 815          (nov (concat dir nnml-nov-file-name))
 816          (nov-buffer (get-buffer-create " *nov*"))
 817          chars file headers)
 818     (save-excursion
 819       ;; Init the nov buffer.
 820       (set-buffer nov-buffer)
 821       (buffer-disable-undo)
 822       (erase-buffer)
 823       (set-buffer nntp-server-buffer)
 824       ;; Delete the old NOV file.
 825       (when (file-exists-p nov)
 826         (funcall nnmail-delete-file-function nov))
 827       (while files
 828         (unless (file-directory-p (setq file (concat dir (cdar files))))
 829           (erase-buffer)
 830           (nnheader-insert-file-contents file)
 831           (narrow-to-region
 832            (goto-char (point-min))
 833            (progn
 834              (re-search-forward "\n\r?\n" nil t)
 835              (setq chars (- (point-max) (point)))
 836              (max (point-min) (1- (point)))))
 837           (unless (zerop (buffer-size))
 838             (goto-char (point-min))
 839             (setq headers (nnml-parse-head chars (caar files)))
 840             (save-excursion
 841               (set-buffer nov-buffer)
 842               (goto-char (point-max))
 843               (nnheader-insert-nov headers)))
 844           (widen))
 845         (setq files (cdr files)))
 846       (save-excursion
 847         (set-buffer nov-buffer)
 848         (nnmail-write-region (point-min) (point-max) nov nil 'nomesg)
 849         (kill-buffer (current-buffer))))))
 850
 851 (defun nnml-nov-delete-article (group article)
 852   (save-excursion
 853     (set-buffer (nnml-open-nov group))
 854     (when (nnheader-find-nov-line article)
 855       (delete-region (point) (progn (forward-line 1) (point)))
 856       (when (bobp)
 857         (let ((active (cadr (assoc group nnml-group-alist)))
 858               num)
 859           (when active
 860             (if (eobp)
 861                 (setf (car active) (1+ (cdr active)))
 862               (when (and (setq num (ignore-errors (read (current-buffer))))
 863                          (numberp num))
 864                 (setf (car active) num)))))))
 865     t))
 866
 867 (defun nnml-update-file-alist (&optional force)
 868   (when nnml-use-compressed-files
 869     (when (or (not nnml-article-file-alist)
 870               force)
 871       (setq nnml-article-file-alist
 872             (nnml-current-group-article-to-file-alist)))))
 873
 874 (defun nnml-directory-articles (dir)
 875   "Return a list of all article files in a directory.
 876 Use the nov database for that directory if available."
 877   (if (or gnus-nov-is-evil nnml-nov-is-evil
 878           (not (file-exists-p
 879                 (expand-file-name nnml-nov-file-name dir))))
 880       (nnheader-directory-articles dir)
 881     ;; build list from .overview if available
 882     ;; We would use nnml-open-nov, except that nnml-nov-buffer-alist is
 883     ;; defvoo'd, and we might get called when it hasn't been swapped in.
 884     (save-excursion
 885       (let ((list nil)
 886             art
 887             (buffer (nnml-get-nov-buffer nnml-current-group)))
 888         (set-buffer buffer)
 889         (goto-char (point-min))
 890         (while (not (eobp))
 891           (setq art (read (current-buffer)))
 892           (push art list)
 893           (forward-line 1))
 894         list))))
 895
 896 (defun nnml-current-group-article-to-file-alist ()
 897   "Return an alist of article/file pairs in the current group.
 898 Use the nov database for the current group if available."
 899   (if (or nnml-use-compressed-files
 900           gnus-nov-is-evil
 901           nnml-nov-is-evil
 902           (not (file-exists-p
 903                 (expand-file-name nnml-nov-file-name
 904                                   nnml-current-directory))))
 905       (nnheader-article-to-file-alist nnml-current-directory)
 906     ;; build list from .overview if available
 907     (save-excursion
 908       (let ((alist nil)
 909             (buffer (nnml-get-nov-buffer nnml-current-group))
 910             art)
 911         (set-buffer buffer)
 912         (goto-char (point-min))
 913         (while (not (eobp))
 914           (setq art (read (current-buffer)))
 915           ;; assume file name is unadorned (ie. not compressed etc)
 916           (push (cons art (int-to-string art)) alist)
 917           (forward-line 1))
 918         alist))))
 919
 920 (deffoo nnml-request-set-mark (group actions &optional server)
 921   (nnml-possibly-change-directory group server)
 922   (unless nnml-marks-is-evil
 923     (nnml-open-marks group server)
 924     (dolist (action actions)
 925       (let ((range (nth 0 action))
 926             (what  (nth 1 action))
 927             (marks (nth 2 action)))
 928         (assert (or (eq what 'add) (eq what 'del)) t
 929                 "Unknown request-set-mark action: %s" what)
 930         (dolist (mark marks)
 931           (setq nnml-marks (gnus-update-alist-soft
 932                             mark
 933                             (funcall (if (eq what 'add) 'gnus-range-add
 934                                        'gnus-remove-from-range)
 935                                      (cdr (assoc mark nnml-marks)) range)
 936                             nnml-marks)))))
 937     (nnml-save-marks group server))
 938   nil)
 939
 940 (deffoo nnml-request-update-info (group info &optional server)
 941   (nnml-possibly-change-directory group server)
 942   (when (and (not nnml-marks-is-evil) (nnml-marks-changed-p group))
 943     (nnheader-message 8 "Updating marks for %s..." group)
 944     (nnml-open-marks group server)
 945     ;; Update info using `nnml-marks'.
 946     (mapcar (lambda (pred)
 947               (unless (memq (cdr pred) gnus-article-unpropagated-mark-lists)
 948                 (gnus-info-set-marks
 949                  info
 950                  (gnus-update-alist-soft
 951                   (cdr pred)
 952                   (cdr (assq (cdr pred) nnml-marks))
 953                   (gnus-info-marks info))
 954                  t)))
 955             gnus-article-mark-lists)
 956     (let ((seen (cdr (assq 'read nnml-marks))))
 957       (gnus-info-set-read info
 958                           (if (and (integerp (car seen))
 959                                    (null (cdr seen)))
 960                               (list (cons (car seen) (car seen)))
 961                             seen)))
 962     (nnheader-message 8 "Updating marks for %s...done" group))
 963   info)
 964
 965 (defun nnml-marks-changed-p (group)
 966   (let ((file (expand-file-name nnml-marks-file-name
 967                                 (nnmail-group-pathname group nnml-directory))))
 968     (if (null (gnus-gethash file nnml-marks-modtime))
 969         t ;; never looked at marks file, assume it has changed
 970       (not (equal (gnus-gethash file nnml-marks-modtime)
 971                   (nth 5 (file-attributes file)))))))
 972
 973 (defun nnml-save-marks (group server)
 974   (let ((file-name-coding-system nnmail-pathname-coding-system)
 975         (file (expand-file-name nnml-marks-file-name
 976                                 (nnmail-group-pathname group nnml-directory))))
 977     (condition-case err
 978         (progn
 979           (nnml-possibly-create-directory group)
 980           (with-temp-file file
 981             (erase-buffer)
 982             (gnus-prin1 nnml-marks)
 983             (insert "\n"))
 984           (gnus-sethash file
 985                         (nth 5 (file-attributes file))
 986                         nnml-marks-modtime))
 987       (error (or (gnus-yes-or-no-p
 988                   (format "Could not write to %s (%s).  Continue? " file err))
 989                  (error "Cannot write to %s (%s)" err))))))
 990
 991 (defun nnml-open-marks (group server)
 992   (let ((file (expand-file-name
 993                nnml-marks-file-name
 994                (nnmail-group-pathname group nnml-directory))))
 995     (if (file-exists-p file)
 996         (condition-case err
 997             (with-temp-buffer
 998               (gnus-sethash file (nth 5 (file-attributes file))
 999                             nnml-marks-modtime)
1000               (nnheader-insert-file-contents file)
1001               (setq nnml-marks (read (current-buffer)))
1002               (dolist (el gnus-article-unpropagated-mark-lists)
1003                 (setq nnml-marks (gnus-remassoc el nnml-marks))))
1004           (error (or (gnus-yes-or-no-p
1005                       (format "Error reading nnml marks file %s (%s).  Continuing will use marks from .newsrc.eld.  Continue? " file err))
1006                      (error "Cannot read nnml marks file %s (%s)" file err))))
1007       ;; User didn't have a .marks file.  Probably first time
1008       ;; user of the .marks stuff.  Bootstrap it from .newsrc.eld.
1009       (let ((info (gnus-get-info
1010                    (gnus-group-prefixed-name
1011                     group
1012                     (gnus-server-to-method (format "nnml:%s" server))))))
1013         (nnheader-message 7 "Bootstrapping marks for %s..." group)
1014         (setq nnml-marks (gnus-info-marks info))
1015         (push (cons 'read (gnus-info-read info)) nnml-marks)
1016         (dolist (el gnus-article-unpropagated-mark-lists)
1017           (setq nnml-marks (gnus-remassoc el nnml-marks)))
1018         (nnml-save-marks group server)
1019         (nnheader-message 7 "Bootstrapping marks for %s...done" group)))))
1020
1021 (provide 'nnml)
1022
1023 ;;; nnml.el ends here