Synch with Oort Gnus.
[elisp/gnus.git-] / lisp / nnslashdot.el
1 ;;; nnslashdot.el --- interfacing with Slashdot
2 ;; Copyright (C) 1999, 2000, 2001 Free Software Foundation, Inc.
3
4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
5 ;; Keywords: news
6
7 ;; This file is part of GNU Emacs.
8
9 ;; GNU Emacs is free software; you can redistribute it and/or modify
10 ;; it under the terms of the GNU General Public License as published by
11 ;; the Free Software Foundation; either version 2, or (at your option)
12 ;; any later version.
13
14 ;; GNU Emacs is distributed in the hope that it will be useful,
15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17 ;; GNU General Public License for more details.
18
19 ;; You should have received a copy of the GNU General Public License
20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
22 ;; Boston, MA 02111-1307, USA.
23
24 ;;; Commentary:
25
26 ;; Note: You need to have `url' and `w3' installed for this
27 ;; backend to work.
28
29 ;;; Code:
30
31 (eval-when-compile (require 'cl))
32 (eval-when-compile (require 'gnus-clfns))
33
34 (require 'nnoo)
35 (require 'message)
36 (require 'gnus-util)
37 (require 'gnus)
38 (require 'nnmail)
39 (require 'mm-util)
40 (require 'mm-url)
41
42 (nnoo-declare nnslashdot)
43
44 (defvoo nnslashdot-directory (nnheader-concat gnus-directory "slashdot/")
45   "Where nnslashdot will save its files.")
46
47 (defvoo nnslashdot-active-url "http://slashdot.org/search.pl?section=&min=%d"
48   "Where nnslashdot will fetch the active file from.")
49
50 (defvoo nnslashdot-comments-url "http://slashdot.org/comments.pl?sid=%s&threshold=%d&commentsort=%d&mode=flat&startat=%d"
51   "Where nnslashdot will fetch comments from.")
52
53 (defvoo nnslashdot-article-url
54     "http://slashdot.org/article.pl?sid=%s&mode=nocomment"
55   "Where nnslashdot will fetch the article from.")
56
57 (defvoo nnslashdot-backslash-url "http://slashdot.org/slashdot.xml"
58   "Where nnslashdot will fetch the stories from.")
59
60 (defvoo nnslashdot-threshold -1
61   "The article threshold.")
62
63 (defvoo nnslashdot-threaded t
64   "Whether the nnslashdot groups should be threaded or not.")
65
66 (defvoo nnslashdot-group-number 0
67   "The number of non-fresh groups to keep updated.")
68
69 (defvoo nnslashdot-login-name ""
70   "The login name to use when posting.")
71
72 (defvoo nnslashdot-password ""
73   "The password to use when posting.")
74
75 ;;; Internal variables
76
77 (defvar nnslashdot-groups nil)
78 (defvar nnslashdot-buffer nil)
79 (defvar nnslashdot-headers nil)
80
81 ;;; Interface functions
82
83 (nnoo-define-basics nnslashdot)
84
85 (deffoo nnslashdot-retrieve-headers (articles &optional group server fetch-old)
86   (nnslashdot-possibly-change-server group server)
87   (condition-case why
88       (unless gnus-nov-is-evil
89         (nnslashdot-retrieve-headers-1 articles group))
90     (search-failed (nnslashdot-lose why))))
91
92 (deffoo nnslashdot-retrieve-headers-1 (articles group)
93   (let* ((last (car (last articles)))
94          (start (if nnslashdot-threaded 1 (pop articles)))
95          (entry (assoc group nnslashdot-groups))
96          (sid (nth 2 entry))
97          (first-comments t)
98          headers article subject score from date lines parent point cid 
99          s startats changed)
100     (save-excursion
101       (set-buffer nnslashdot-buffer)
102       (let ((case-fold-search t))
103         (erase-buffer)
104         (when (= start 1)
105           (mm-url-insert (format nnslashdot-article-url
106                                 (nnslashdot-sid-strip sid)) t)
107           (goto-char (point-min))
108           (re-search-forward "Posted by[ \t\r\n]+")
109           (when (looking-at "\\(<a[^>]+>\\)?[ \t\r\n]*\\([^<\r\n]+\\)")
110             (setq from (mm-url-decode-entities-string (match-string 2))))
111           (search-forward "on ")
112           (setq date (nnslashdot-date-to-date
113                       (buffer-substring (point) (1- (search-forward "<")))))
114           (setq lines (/ (- (point)
115                             (progn (forward-line 1) (point)))
116                          60))
117           (push
118            (cons
119             1
120             (make-full-mail-header
121              1 group from date
122              (concat "<" (nnslashdot-sid-strip sid) "%1@slashdot>")
123              "" 0 lines nil nil))
124            headers)
125           (setq start (if nnslashdot-threaded 2 (pop articles))))
126         (while (and start (<= start last))
127           (setq point (goto-char (point-max)))
128           (mm-url-insert
129            (format nnslashdot-comments-url
130                    (nnslashdot-sid-strip sid)
131                    nnslashdot-threshold 0 (- start 2))
132            t)
133           (when (and nnslashdot-threaded first-comments)
134             (setq first-comments nil)
135             (goto-char (point-max))
136             (while (re-search-backward "startat=\\([0-9]+\\)" nil t)
137               (setq s (string-to-number (match-string 1)))
138               (unless (memq s startats)
139                 (push s startats)))
140             (setq startats (sort startats '<)))
141           (setq article (if (and article (< start article)) article start))
142           (goto-char point)
143           (while (re-search-forward
144                   "<a name=\"\\([0-9]+\\)\"><\\(b\\|H4\\)>\\([^<]+\\)</\\(b\\|H4\\)>.*score:\\([^)]+\\))"
145                   nil t)
146             (setq cid (match-string 1)
147                   subject (match-string 3)
148                   score (match-string 5))
149             (unless (assq article (nth 4 entry))
150               (setcar (nthcdr 4 entry) (cons (cons article cid) (nth 4 entry)))
151               (setq changed t))
152             (when (string-match "^Re: *" subject)
153               (setq subject (concat "Re: " (substring subject (match-end 0)))))
154             (setq subject (mm-url-decode-entities-string subject))
155             (search-forward "<BR>")
156             (if (looking-at
157                  "by[ \t\n]+<a[^>]+>\\([^<]+\\)</a>[ \t\n]*(\\(<[^>]+>\\)*\\([^<>)]+\\))")
158                 (progn
159                   (goto-char (- (match-end 0) 5))
160                   (setq from (concat
161                               (mm-url-decode-entities-string (match-string 1))
162                               " <" (match-string 3) ">")))
163               (setq from "")
164               (when (looking-at "by \\([^<>]*\\) on ")
165                 (goto-char (- (match-end 0) 5))
166                 (setq from (mm-url-decode-entities-string (match-string 1)))))
167             (search-forward " on ")
168             (setq date
169                   (nnslashdot-date-to-date
170                    (buffer-substring (point) (progn (skip-chars-forward "^()<>\n\r") (point)))))
171             (setq lines (/ (abs (- (search-forward "<td")
172                                    (search-forward "</td>")))
173                            70))
174             (if (not
175                  (re-search-forward ".*cid=\\([0-9]+\\)\">Parent</A>" nil t))
176                 (setq parent nil)
177               (setq parent (match-string 1))
178               (when (string= parent "0")
179                 (setq parent nil)))
180             (push
181              (cons
182               article
183               (make-full-mail-header
184                article
185                (concat subject " (" score ")")
186                from date
187                (concat "<" (nnslashdot-sid-strip sid) "%" cid "@slashdot>")
188                (if parent
189                    (concat "<" (nnslashdot-sid-strip sid) "%" 
190                            parent "@slashdot>")
191                  "")
192                0 lines nil nil))
193              headers)
194             (while (and articles (<= (car articles) article))
195               (pop articles))
196             (setq article (1+ article)))
197           (if nnslashdot-threaded 
198               (progn
199                 (setq start (pop startats))
200                 (if start (setq start (+ start 2))))
201             (setq start (pop articles))))))
202     (if changed (nnslashdot-write-groups))
203     (setq nnslashdot-headers (sort headers 'car-less-than-car))
204     (save-excursion
205       (set-buffer nntp-server-buffer)
206       (erase-buffer)
207       (mm-with-unibyte-current-buffer
208         (dolist (header nnslashdot-headers)
209           (nnheader-insert-nov (cdr header)))))
210     'nov))
211
212 (deffoo nnslashdot-request-group (group &optional server dont-check)
213   (nnslashdot-possibly-change-server nil server)
214   (let ((elem (assoc group nnslashdot-groups)))
215     (cond
216      ((not elem)
217       (nnheader-report 'nnslashdot "Group does not exist"))
218      (t
219       (nnheader-report 'nnslashdot "Opened group %s" group)
220       (nnheader-insert
221        "211 %d %d %d %s\n" (cadr elem) 1 (cadr elem)
222        (prin1-to-string group))))))
223
224 (deffoo nnslashdot-close-group (group &optional server)
225   (nnslashdot-possibly-change-server group server)
226   (when (gnus-buffer-live-p nnslashdot-buffer)
227     (save-excursion
228       (set-buffer nnslashdot-buffer)
229       (kill-buffer nnslashdot-buffer)))
230   t)
231
232 (deffoo nnslashdot-request-article (article &optional group server buffer)
233   (nnslashdot-possibly-change-server group server)
234   (let (contents cid)
235     (condition-case why
236         (save-excursion
237           (set-buffer nnslashdot-buffer)
238           (let ((case-fold-search t))
239             (goto-char (point-min))
240             (when (and (stringp article)
241                        (string-match "%\\([0-9]+\\)@" article))
242               (setq cid (match-string 1 article))
243               (let ((map (nth 4 (assoc group nnslashdot-groups))))
244                 (while map
245                   (if (equal (cdar map) cid)
246                       (setq article (caar map)
247                             map nil)
248                     (setq map (cdr map))))))
249             (when (numberp article)
250               (if (= article 1)
251                   (progn
252                     (re-search-forward 
253                      "Posted by")
254                     (search-forward "<BR>")
255                     (setq contents
256                           (buffer-substring
257                            (point)
258                            (progn
259                              (re-search-forward
260                               "&lt;&nbsp;[ \t\r\n]*<A HREF=\"\\(\\(http:\\)?//slashdot\\.org\\)?/article")
261                              (match-beginning 0)))))
262                 (setq cid (cdr (assq article 
263                                      (nth 4 (assoc group nnslashdot-groups)))))
264                 (search-forward (format "<a name=\"%s\">" cid))
265                 (setq contents
266                       (buffer-substring
267                        (re-search-forward "<td[^>]*>")
268                        (search-forward "</td>")))))))
269       (search-failed (nnslashdot-lose why)))
270
271     (when contents
272       (save-excursion
273         (set-buffer (or buffer nntp-server-buffer))
274         (erase-buffer)
275         (mm-with-unibyte-current-buffer
276           (insert contents)
277           (goto-char (point-min))
278           (while (re-search-forward "\\(<br>\r?\\)+" nil t)
279             (replace-match "<p>" t t))
280           (goto-char (point-min))
281           (insert "Content-Type: text/html\nMIME-Version: 1.0\n")
282           (insert "Newsgroups: " (caddr (assoc group nnslashdot-groups))
283                   "\n")
284           (let ((header (cdr (assq article nnslashdot-headers))))
285             (nnheader-insert-header header))
286           (nnheader-report 'nnslashdot "Fetched article %s" article))
287         (cons group article)))))
288
289 (deffoo nnslashdot-close-server (&optional server)
290   (when (and (nnslashdot-server-opened server)
291              (gnus-buffer-live-p nnslashdot-buffer))
292     (save-excursion
293       (set-buffer nnslashdot-buffer)
294       (kill-buffer nnslashdot-buffer)))
295   (nnoo-close-server 'nnslashdot server))
296
297 (deffoo nnslashdot-request-list (&optional server)
298   (nnslashdot-possibly-change-server nil server)
299   (let ((number 0)
300         sid elem description articles gname)
301     (condition-case why
302         ;; First we do the Ultramode to get info on all the latest groups.
303         (progn
304           (mm-with-unibyte-buffer
305             (mm-url-insert nnslashdot-backslash-url t)
306             (goto-char (point-min))
307             (while (search-forward "<story>" nil t)
308               (narrow-to-region (point) (search-forward "</story>"))
309               (goto-char (point-min))
310               (re-search-forward "<title>\\([^<]+\\)</title>")
311               (setq description
312                     (mm-url-decode-entities-string (match-string 1)))
313               (re-search-forward "<url>\\([^<]+\\)</url>")
314               (setq sid (match-string 1))
315               (string-match "sid=\\([0-9/]+\\)\\(.shtml\\|$\\)" sid)
316               (setq sid (match-string 1 sid))
317               (re-search-forward "<comments>\\([^<]+\\)</comments>")
318               (setq articles (string-to-number (match-string 1)))
319               (setq gname (concat description " (" sid ")"))
320               (if (setq elem (assoc gname nnslashdot-groups))
321                   (setcar (cdr elem) articles)
322                 (push (list gname articles sid (current-time) nil)
323                       nnslashdot-groups))
324               (goto-char (point-max))
325               (widen)))
326           ;; Then do the older groups.
327           (while (> (- nnslashdot-group-number number) 0)
328             (mm-with-unibyte-buffer
329               (let ((case-fold-search t))
330                 (mm-url-insert (format nnslashdot-active-url number) t)
331                 (goto-char (point-min))
332                 (while (re-search-forward
333                         "article.pl\\?sid=\\([^&]+\\).*<b>\\([^<]+\\)</b>"
334                         nil t)
335                   (setq sid (match-string 1)
336                         description
337                         (mm-url-decode-entities-string (match-string 2)))
338                   (forward-line 1)
339                   (when (re-search-forward "<b>\\([0-9]+\\)</b>" nil t)
340                     (setq articles (string-to-number (match-string 1))))
341                   (setq gname (concat description " (" sid ")"))
342                   (if (setq elem (assoc gname nnslashdot-groups))
343                       (setcar (cdr elem) articles)
344                     (push (list gname articles sid (current-time) nil)
345                           nnslashdot-groups)))))
346             (incf number 30)))
347       (search-failed (nnslashdot-lose why)))
348     (nnslashdot-write-groups)
349     (nnslashdot-generate-active)
350     t))
351
352 (deffoo nnslashdot-request-newgroups (date &optional server)
353   (nnslashdot-possibly-change-server nil server)
354   (nnslashdot-generate-active)
355   t)
356
357 (deffoo nnslashdot-request-post (&optional server)
358   (require 'nnweb)
359   (nnslashdot-possibly-change-server nil server)
360   (let ((sid (nnslashdot-sid-strip (message-fetch-field "newsgroups")))
361         (subject (message-fetch-field "subject"))
362         (references (car (last (split-string
363                                 (message-fetch-field "references")))))
364         body quoted pid)
365     (string-match "%\\([0-9]+\\)@slashdot" references)
366     (setq pid (match-string 1 references))
367     (message-goto-body)
368     (narrow-to-region (point) (progn (message-goto-signature) (point)))
369     (goto-char (point-min))
370     (while (not (eobp))
371       (if (looking-at "> ")
372           (progn
373             (delete-region (point) (+ (point) 2))
374             (unless quoted
375               (insert "<blockquote>\n"))
376             (setq quoted t))
377         (when quoted
378           (insert "</blockquote>\n")
379           (setq quoted nil)))
380       (forward-line 1))
381     (goto-char (point-min))
382     (while (re-search-forward "^ *\n" nil t)
383       (replace-match "<p>\n"))
384     (widen)
385     (when (message-goto-signature)
386       (forward-line -1)
387       (insert "<p>\n")
388       (while (not (eobp))
389         (end-of-line)
390         (insert "<br>")
391         (forward-line 1)))
392     (message-goto-body)
393     (setq body (buffer-substring (point) (point-max)))
394     (erase-buffer)
395     (nnweb-fetch-form
396      "http://slashdot.org/comments.pl"
397      `(("sid" . ,sid)
398        ("pid" . ,pid)
399        ("rlogin" . "userlogin")
400        ("unickname" . ,nnslashdot-login-name)
401        ("upasswd" . ,nnslashdot-password)
402        ("postersubj" . ,subject)
403        ("op" . "Submit")
404        ("postercomment" . ,body)
405        ("posttype" . "html")))))
406
407 (deffoo nnslashdot-request-delete-group (group &optional force server)
408   (nnslashdot-possibly-change-server group server)
409   (setq nnslashdot-groups (delq (assoc group nnslashdot-groups)
410                                 nnslashdot-groups))
411   (nnslashdot-write-groups))
412
413 (deffoo nnslashdot-request-close ()
414   (setq nnslashdot-headers nil
415         nnslashdot-groups nil))
416
417 (deffoo nnslashdot-request-expire-articles
418     (articles group &optional server force)
419   (nnslashdot-possibly-change-server group server)
420   (let ((item (assoc group nnslashdot-groups)))
421     (when item
422       (if (fourth item)
423           (when (and (>= (length articles) (cadr item)) ;; All are expirable.
424                      (nnmail-expired-article-p
425                       group
426                       (fourth item)
427                       force))
428             (setq nnslashdot-groups (delq item nnslashdot-groups))
429             (nnslashdot-write-groups)
430             (setq articles nil)) ;; all expired.
431         (setcdr (cddr item) (list (current-time)))
432         (nnslashdot-write-groups))))
433   articles)
434
435 (nnoo-define-skeleton nnslashdot)
436
437 ;;; Internal functions
438
439 (defun nnslashdot-possibly-change-server (&optional group server)
440   (nnslashdot-init server)
441   (when (and server
442              (not (nnslashdot-server-opened server)))
443     (nnslashdot-open-server server))
444   (unless nnslashdot-groups
445     (nnslashdot-read-groups)))
446
447 (defun nnslashdot-make-tuple (tuple n)
448   (prog1
449       tuple
450     (while (> n 1)
451       (unless (cdr tuple)
452         (setcdr tuple (list nil)))
453       (setq tuple (cdr tuple)
454             n (1- n)))))
455
456 (defun nnslashdot-read-groups ()
457   (let ((file (expand-file-name "groups" nnslashdot-directory)))
458     (when (file-exists-p file)
459       (mm-with-unibyte-buffer
460         (insert-file-contents file)
461         (goto-char (point-min))
462         (setq nnslashdot-groups (read (current-buffer))))
463       (if (and nnslashdot-groups (< (length (car nnslashdot-groups)) 5))
464           (let ((groups nnslashdot-groups))
465             (while groups
466               (nnslashdot-make-tuple (car groups) 5)
467               (setq groups (cdr groups))))))))
468
469 (defun nnslashdot-write-groups ()
470   (with-temp-file (expand-file-name "groups" nnslashdot-directory)
471     (gnus-prin1 nnslashdot-groups)))
472
473 (defun nnslashdot-init (server)
474   "Initialize buffers and such."
475   (unless (file-exists-p nnslashdot-directory)
476     (gnus-make-directory nnslashdot-directory))
477   (unless (gnus-buffer-live-p nnslashdot-buffer)
478     (setq nnslashdot-buffer
479           (save-excursion
480             (nnheader-set-temp-buffer
481              (format " *nnslashdot %s*" server))))
482     (push nnslashdot-buffer gnus-buffers)))
483
484 (defun nnslashdot-date-to-date (sdate)
485   (condition-case err
486       (let ((elem (delete "" (split-string sdate))))
487         (concat (substring (nth 0 elem) 0 3) " "
488                 (substring (nth 1 elem) 0 3) " "
489                 (substring (nth 2 elem) 0 2) " "
490                 (substring (nth 3 elem) 1 6) " "
491                 (format-time-string "%Y") " "
492                 (nth 4 elem)))
493     (error "")))
494
495 (defun nnslashdot-generate-active ()
496   (save-excursion
497     (set-buffer nntp-server-buffer)
498     (erase-buffer)
499     (dolist (elem nnslashdot-groups)
500       (insert (prin1-to-string (car elem))
501               " " (number-to-string (cadr elem)) " 1 y\n"))))
502
503 (defun nnslashdot-lose (why)
504   (error "Slashdot HTML has changed; please get a new version of nnslashdot"))
505
506 ;(defun nnslashdot-sid-strip (sid)
507 ;  (if (string-match "^00/" sid)
508 ;      (substring sid (match-end 0))
509 ;    sid))
510
511 (defalias 'nnslashdot-sid-strip 'identity)
512
513 (provide 'nnslashdot)
514
515 ;;; nnslashdot.el ends here