git.chise.org Git - elisp/gnus.git-/blob - lisp/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2 ;; Copyright (C) 1988,89,90,93,94,95,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nntp)
  31 (require 'timezone)
  32 (require 'nnoo)
  33 (eval-when-compile (require 'cl))
  34
  35 (nnoo-declare nnspool)
  36
  37 (defvoo nnspool-inews-program news-inews-program
  38   "Program to post news.
  39 This is most commonly `inews' or `injnews'.")
  40
  41 (defvoo nnspool-inews-switches '("-h" "-S")
  42   "Switches for nnspool-request-post to pass to `inews' for posting news.
  43 If you are using Cnews, you probably should set this variable to nil.")
  44
  45 (defvoo nnspool-spool-directory (file-name-as-directory news-path)
  46   "Local news spool directory.")
  47
  48 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  49   "Local news nov directory.")
  50
  51 (defvoo nnspool-lib-dir "/usr/lib/news/"
  52   "Where the local news library files are stored.")
  53
  54 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  55   "Local news active file.")
  56
  57 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  58   "Local news newsgroups file.")
  59
  60 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  61   "Local news distributions file.")
  62
  63 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  64   "Local news history file.")
  65
  66 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  67   "Local news active date file.")
  68
  69 (defvoo nnspool-large-newsgroup 50
  70   "The number of the articles which indicates a large newsgroup.
  71 If the number of the articles is greater than the value, verbose
  72 messages will be shown to indicate the current status.")
  73
  74 (defvoo nnspool-nov-is-evil nil
  75   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  76
  77 (defconst nnspool-sift-nov-with-sed nil
  78   "If non-nil, use sed to get the relevant portion from the overview file.
  79 If nil, nnspool will load the entire file into a buffer and process it
  80 there.")
  81
  82 (defvoo nnspool-rejected-article-hook nil
  83   "*A hook that will be run when an article has been rejected by the server.")
  84
  85 \f
  86
  87 (defconst nnspool-version "nnspool 2.0"
  88   "Version numbers of this version of NNSPOOL.")
  89
  90 (defvoo nnspool-current-directory nil
  91   "Current news group directory.")
  92
  93 (defvoo nnspool-current-group nil)
  94 (defvoo nnspool-status-string "")
  95
  96 \f
  97 ;;; Interface functions.
  98
  99 (nnoo-define-basics nnspool)
 100
 101 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 102   "Retrieve the headers of ARTICLES."
 103   (save-excursion
 104     (set-buffer nntp-server-buffer)
 105     (erase-buffer)
 106     (when (nnspool-possibly-change-directory group)
 107       (let* ((number (length articles))
 108              (count 0)
 109              (default-directory nnspool-current-directory)
 110              (do-message (and (numberp nnspool-large-newsgroup)
 111                               (> number nnspool-large-newsgroup)))
 112              file beg article ag)
 113         (if (and (numberp (car articles))
 114                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 115             ;; We successfully retrieved the NOV headers.
 116             'nov
 117           ;; No NOV headers here, so we do it the hard way.
 118           (while (setq article (pop articles))
 119             (if (stringp article)
 120                 ;; This is a Message-ID.
 121                 (setq ag (nnspool-find-id article)
 122                       file (and ag (nnspool-article-pathname
 123                                     (car ag) (cdr ag)))
 124                       article (cdr ag))
 125               ;; This is an article in the current group.
 126               (setq file (int-to-string article)))
 127             ;; Insert the head of the article.
 128             (when (and file
 129                        (file-exists-p file))
 130               (insert "221 ")
 131               (princ article (current-buffer))
 132               (insert " Article retrieved.\n")
 133               (setq beg (point))
 134               (inline (nnheader-insert-head file))
 135               (goto-char beg)
 136               (if (search-forward "\n\n" nil t)
 137                   (progn (forward-char -1)
 138                          (insert ".\n"))
 139                 (goto-char (point-max))
 140                 (if (bolp)
 141                     (insert ".\n")
 142                   (insert "\n.\n")))
 143               (delete-region (point) (point-max)))
 144
 145             (and do-message
 146                  (zerop (% (incf count) 20))
 147                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 148                           (/ (* count 100) number))))
 149
 150           (when do-message
 151             (nnheader-message 5 "nnspool: Receiving headers...done"))
 152
 153           ;; Fold continuation lines.
 154           (nnheader-fold-continuation-lines)
 155           'headers)))))
 156
 157 (deffoo nnspool-open-server (server &optional defs)
 158   (nnoo-change-server 'nnspool server defs)
 159   (cond
 160    ((not (file-exists-p nnspool-spool-directory))
 161     (nnspool-close-server)
 162     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 163                      nnspool-spool-directory))
 164    ((not (file-directory-p
 165           (directory-file-name
 166            (file-truename nnspool-spool-directory))))
 167     (nnspool-close-server)
 168     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 169    ((not (file-exists-p nnspool-active-file))
 170     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 171                      nnspool-active-file))
 172    (t
 173     (nnheader-report 'nnspool "Opened server %s using directory %s"
 174                      server nnspool-spool-directory)
 175     t)))
 176
 177 (deffoo nnspool-request-article (id &optional group server buffer)
 178   "Select article by message ID (or number)."
 179   (nnspool-possibly-change-directory group)
 180   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 181         file ag)
 182     (if (stringp id)
 183         ;; This is a Message-ID.
 184         (when (setq ag (nnspool-find-id id))
 185           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 186       (setq file (nnspool-article-pathname nnspool-current-group id)))
 187     (and file
 188          (file-exists-p file)
 189          (not (file-directory-p file))
 190          (save-excursion (nnspool-find-file file))
 191          ;; We return the article number and group name.
 192          (if (numberp id)
 193              (cons nnspool-current-group id)
 194            ag))))
 195
 196 (deffoo nnspool-request-body (id &optional group server)
 197   "Select article body by message ID (or number)."
 198   (nnspool-possibly-change-directory group)
 199   (let ((res (nnspool-request-article id)))
 200     (when res
 201       (save-excursion
 202         (set-buffer nntp-server-buffer)
 203         (goto-char (point-min))
 204         (when (search-forward "\n\n" nil t)
 205           (delete-region (point-min) (point)))
 206         res))))
 207
 208 (deffoo nnspool-request-head (id &optional group server)
 209   "Select article head by message ID (or number)."
 210   (nnspool-possibly-change-directory group)
 211   (let ((res (nnspool-request-article id)))
 212     (when res
 213       (save-excursion
 214         (set-buffer nntp-server-buffer)
 215         (goto-char (point-min))
 216         (when (search-forward "\n\n" nil t)
 217           (delete-region (1- (point)) (point-max)))
 218         (nnheader-fold-continuation-lines)))
 219     res))
 220
 221 (deffoo nnspool-request-group (group &optional server dont-check)
 222   "Select news GROUP."
 223   (let ((pathname (nnspool-article-pathname group))
 224         dir)
 225     (if (not (file-directory-p pathname))
 226         (nnheader-report
 227          'nnspool "Invalid group name (no such directory): %s" group)
 228       (setq nnspool-current-directory pathname)
 229       (nnheader-report 'nnspool "Selected group %s" group)
 230       (if dont-check
 231           (progn
 232             (nnheader-report 'nnspool "Selected group %s" group)
 233             t)
 234         ;; Yes, completely empty spool directories *are* possible.
 235         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 236         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 237           (setq dir
 238                 (sort (mapcar (lambda (name) (string-to-int name)) dir) '<)))
 239         (if dir
 240             (nnheader-insert
 241              "211 %d %d %d %s\n" (length dir) (car dir)
 242              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 243              group)
 244           (nnheader-report 'nnspool "Empty group %s" group)
 245           (nnheader-insert "211 0 0 0 %s\n" group))))))
 246
 247 (deffoo nnspool-request-type (group &optional article)
 248   'news)
 249
 250 (deffoo nnspool-close-group (group &optional server)
 251   t)
 252
 253 (deffoo nnspool-request-list (&optional server)
 254   "List active newsgroups."
 255   (save-excursion
 256     (or (nnspool-find-file nnspool-active-file)
 257         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 258
 259 (deffoo nnspool-request-list-newsgroups (&optional server)
 260   "List newsgroups (defined in NNTP2)."
 261   (save-excursion
 262     (or (nnspool-find-file nnspool-newsgroups-file)
 263         (nnheader-report 'nnspool (nnheader-file-error
 264                                    nnspool-newsgroups-file)))))
 265
 266 (deffoo nnspool-request-list-distributions (&optional server)
 267   "List distributions (defined in NNTP2)."
 268   (save-excursion
 269     (or (nnspool-find-file nnspool-distributions-file)
 270         (nnheader-report 'nnspool (nnheader-file-error
 271                                    nnspool-distributions-file)))))
 272
 273 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 274 (deffoo nnspool-request-newgroups (date &optional server)
 275   "List groups created after DATE."
 276   (if (nnspool-find-file nnspool-active-times-file)
 277       (save-excursion
 278         ;; Find the last valid line.
 279         (goto-char (point-max))
 280         (while (and (not (looking-at
 281                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 282                     (zerop (forward-line -1))))
 283         (let ((seconds (nnspool-seconds-since-epoch date))
 284               groups)
 285           ;; Go through lines and add the latest groups to a list.
 286           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 287                       (progn
 288                         ;; We insert a .0 to make the list reader
 289                         ;; interpret the number as a float.  It is far
 290                         ;; too big to be stored in a lisp integer.
 291                         (goto-char (1- (match-end 0)))
 292                         (insert ".0")
 293                         (> (progn
 294                              (goto-char (match-end 1))
 295                              (read (current-buffer)))
 296                            seconds))
 297                       (push (buffer-substring
 298                                           (match-beginning 1) (match-end 1))
 299                                          groups)
 300                       (zerop (forward-line -1))))
 301           (erase-buffer)
 302           (while groups
 303             (insert (car groups) " 0 0 y\n")
 304             (setq groups (cdr groups))))
 305         t)
 306     nil))
 307
 308 (deffoo nnspool-request-post (&optional server)
 309   "Post a new news in current buffer."
 310   (save-excursion
 311     (let* ((process-connection-type nil) ; t bugs out on Solaris
 312            (inews-buffer (generate-new-buffer " *nnspool post*"))
 313            (proc
 314             (condition-case err
 315                 (apply 'start-process "*nnspool inews*" inews-buffer
 316                        nnspool-inews-program nnspool-inews-switches)
 317               (error
 318                (nnheader-report 'nnspool "inews error: %S" err)))))
 319       (if (not proc)
 320           ;; The inews program failed.
 321           ()
 322         (nnheader-report 'nnspool "")
 323         (set-process-sentinel proc 'nnspool-inews-sentinel)
 324         (process-send-region proc (point-min) (point-max))
 325         ;; We slap a condition-case around this, because the process may
 326         ;; have exited already...
 327         (ignore-errors
 328           (process-send-eof proc))
 329         t))))
 330
 331
 332 \f
 333 ;;; Internal functions.
 334
 335 (defun nnspool-inews-sentinel (proc status)
 336   (save-excursion
 337     (set-buffer (process-buffer proc))
 338     (goto-char (point-min))
 339     (if (or (zerop (buffer-size))
 340             (search-forward "spooled" nil t))
 341         (kill-buffer (current-buffer))
 342       ;; Make status message by folding lines.
 343       (while (re-search-forward "[ \t\n]+" nil t)
 344         (replace-match " " t t))
 345       (nnheader-report 'nnspool "%s" (buffer-string))
 346       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 347       (ding)
 348       (run-hooks 'nnspool-rejected-article-hook))))
 349
 350 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 351   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 352       nil
 353     (let ((nov (nnheader-group-pathname
 354                 nnspool-current-group nnspool-nov-directory ".overview"))
 355           (arts articles)
 356           last)
 357       (if (not (file-exists-p nov))
 358           ()
 359         (save-excursion
 360           (set-buffer nntp-server-buffer)
 361           (erase-buffer)
 362           (if nnspool-sift-nov-with-sed
 363               (nnspool-sift-nov-with-sed articles nov)
 364             (nnheader-insert-file-contents nov)
 365             (if (and fetch-old
 366                      (not (numberp fetch-old)))
 367                 t                       ; We want all the headers.
 368               (ignore-errors
 369                 ;; Delete unwanted NOV lines.
 370                 (nnheader-nov-delete-outside-range
 371                  (if fetch-old (max 1 (- (car articles) fetch-old))
 372                    (car articles))
 373                  (car (last articles)))
 374                 ;; If the buffer is empty, this wasn't very successful.
 375                 (unless (zerop (buffer-size))
 376                   ;; We check what the last article number was.
 377                   ;; The NOV file may be out of sync with the articles
 378                   ;; in the group.
 379                   (forward-line -1)
 380                   (setq last (read (current-buffer)))
 381                   (if (= last (car articles))
 382                       ;; Yup, it's all there.
 383                       t
 384                     ;; Perhaps not.  We try to find the missing articles.
 385                     (while (and arts
 386                                 (<= last (car arts)))
 387                       (pop arts))
 388                     ;; The articles in `arts' are missing from the buffer.
 389                     (while arts
 390                       (nnspool-insert-nov-head (pop arts)))
 391                     t))))))))))
 392
 393 (defun nnspool-insert-nov-head (article)
 394   "Read the head of ARTICLE, convert to NOV headers, and insert."
 395   (save-excursion
 396     (let ((cur (current-buffer))
 397           buf)
 398       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 399       (when (nnheader-insert-head
 400              (nnspool-article-pathname nnspool-current-group article))
 401         (nnheader-insert-article-line article)
 402         (let ((headers (nnheader-parse-head)))
 403           (set-buffer cur)
 404           (goto-char (point-max))
 405           (nnheader-insert-nov headers)))
 406       (kill-buffer buf))))
 407
 408 (defun nnspool-sift-nov-with-sed (articles file)
 409   (let ((first (car articles))
 410         (last (progn (while (cdr articles) (setq articles (cdr articles)))
 411                      (car articles))))
 412     (call-process "awk" nil t nil
 413                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 414                           (1- first) (1+ last))
 415                   file)))
 416
 417 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 418 ;; Find out what group an article identified by a Message-ID is in.
 419 (defun nnspool-find-id (id)
 420   (save-excursion
 421     (set-buffer (get-buffer-create " *nnspool work*"))
 422     (buffer-disable-undo (current-buffer))
 423     (erase-buffer)
 424     (ignore-errors
 425       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 426     (goto-char (point-min))
 427     (prog1
 428         (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 429           (cons (match-string 1) (string-to-int (match-string 2))))
 430       (kill-buffer (current-buffer)))))
 431
 432 (defun nnspool-find-file (file)
 433   "Insert FILE in server buffer safely."
 434   (set-buffer nntp-server-buffer)
 435   (erase-buffer)
 436   (condition-case ()
 437       (progn
 438         (nnheader-insert-file-contents file)
 439         t)
 440     (file-error nil)))
 441
 442 (defun nnspool-possibly-change-directory (group)
 443   (if (not group)
 444       t
 445     (let ((pathname (nnspool-article-pathname group)))
 446       (if (file-directory-p pathname)
 447           (setq nnspool-current-directory pathname
 448                 nnspool-current-group group)
 449         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 450
 451 (defun nnspool-article-pathname (group &optional article)
 452   "Find the path for GROUP."
 453   (nnheader-group-pathname group nnspool-spool-directory article))
 454
 455 (defun nnspool-seconds-since-epoch (date)
 456   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 457                         (timezone-parse-date date)))
 458          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 459                         (timezone-parse-time
 460                          (aref (timezone-parse-date date) 3))))
 461          (unix (encode-time (nth 2 ttime) (nth 1 ttime) (nth 0 ttime)
 462                             (nth 2 tdate) (nth 1 tdate) (nth 0 tdate)
 463                             (nth 4 tdate))))
 464     (+ (* (car unix) 65536.0)
 465        (cadr unix))))
 466
 467 (provide 'nnspool)
 468
 469 ;;; nnspool.el ends here