git.chise.org Git - elisp/gnus.git-/blob - lisp/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2 ;; Copyright (C) 198,998,89,90,93,94,95,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30 (require 'nnheader)
  31 (require 'nntp)
  32 (require 'nnoo)
  33
  34 (nnoo-declare nnspool)
  35
  36 (defvoo nnspool-inews-program news-inews-program
  37   "Program to post news.
  38 This is most commonly `inews' or `injnews'.")
  39
  40 (defvoo nnspool-inews-switches '("-h" "-S")
  41   "Switches for nnspool-request-post to pass to `inews' for posting news.
  42 If you are using Cnews, you probably should set this variable to nil.")
  43
  44 (defvoo nnspool-spool-directory (file-name-as-directory news-path)
  45   "Local news spool directory.")
  46
  47 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  48   "Local news nov directory.")
  49
  50 (defvoo nnspool-lib-dir "/usr/lib/news/"
  51   "Where the local news library files are stored.")
  52
  53 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  54   "Local news active file.")
  55
  56 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  57   "Local news newsgroups file.")
  58
  59 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  60   "Local news distributions file.")
  61
  62 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  63   "Local news history file.")
  64
  65 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  66   "Local news active date file.")
  67
  68 (defvoo nnspool-large-newsgroup 50
  69   "The number of the articles which indicates a large newsgroup.
  70 If the number of the articles is greater than the value, verbose
  71 messages will be shown to indicate the current status.")
  72
  73 (defvoo nnspool-nov-is-evil nil
  74   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  75
  76 (defconst nnspool-sift-nov-with-sed nil
  77   "If non-nil, use sed to get the relevant portion from the overview file.
  78 If nil, nnspool will load the entire file into a buffer and process it
  79 there.")
  80
  81 (defvoo nnspool-rejected-article-hook nil
  82   "*A hook that will be run when an article has been rejected by the server.")
  83
  84 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  85   "Coding system for nnspool.")
  86
  87 \f
  88
  89 (defconst nnspool-version "nnspool 2.0"
  90   "Version numbers of this version of NNSPOOL.")
  91
  92 (defvoo nnspool-current-directory nil
  93   "Current news group directory.")
  94
  95 (defvoo nnspool-current-group nil)
  96 (defvoo nnspool-status-string "")
  97
  98 \f
  99 ;;; Interface functions.
 100
 101 (nnoo-define-basics nnspool)
 102
 103 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 104   "Retrieve the headers of ARTICLES."
 105   (save-excursion
 106     (set-buffer nntp-server-buffer)
 107     (erase-buffer)
 108     (when (nnspool-possibly-change-directory group)
 109       (let* ((number (length articles))
 110              (count 0)
 111              (default-directory nnspool-current-directory)
 112              (do-message (and (numberp nnspool-large-newsgroup)
 113                               (> number nnspool-large-newsgroup)))
 114              (nnheader-file-coding-system nnspool-file-coding-system)
 115              file beg article ag)
 116         (if (and (numberp (car articles))
 117                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 118             ;; We successfully retrieved the NOV headers.
 119             'nov
 120           ;; No NOV headers here, so we do it the hard way.
 121           (while (setq article (pop articles))
 122             (if (stringp article)
 123                 ;; This is a Message-ID.
 124                 (setq ag (nnspool-find-id article)
 125                       file (and ag (nnspool-article-pathname
 126                                     (car ag) (cdr ag)))
 127                       article (cdr ag))
 128               ;; This is an article in the current group.
 129               (setq file (int-to-string article)))
 130             ;; Insert the head of the article.
 131             (when (and file
 132                        (file-exists-p file))
 133               (insert "221 ")
 134               (princ article (current-buffer))
 135               (insert " Article retrieved.\n")
 136               (setq beg (point))
 137               (inline (nnheader-insert-head file))
 138               (goto-char beg)
 139               (if (search-forward "\n\n" nil t)
 140                   (progn (forward-char -1)
 141                          (insert ".\n"))
 142                 (goto-char (point-max))
 143                 (if (bolp)
 144                     (insert ".\n")
 145                   (insert "\n.\n")))
 146               (delete-region (point) (point-max)))
 147
 148             (and do-message
 149                  (zerop (% (incf count) 20))
 150                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 151                           (/ (* count 100) number))))
 152
 153           (when do-message
 154             (nnheader-message 5 "nnspool: Receiving headers...done"))
 155
 156           ;; Fold continuation lines.
 157           (nnheader-fold-continuation-lines)
 158           'headers)))))
 159
 160 (deffoo nnspool-open-server (server &optional defs)
 161   (nnoo-change-server 'nnspool server defs)
 162   (cond
 163    ((not (file-exists-p nnspool-spool-directory))
 164     (nnspool-close-server)
 165     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 166                      nnspool-spool-directory))
 167    ((not (file-directory-p
 168           (directory-file-name
 169            (file-truename nnspool-spool-directory))))
 170     (nnspool-close-server)
 171     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 172    ((not (file-exists-p nnspool-active-file))
 173     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 174                      nnspool-active-file))
 175    (t
 176     (nnheader-report 'nnspool "Opened server %s using directory %s"
 177                      server nnspool-spool-directory)
 178     t)))
 179
 180 (deffoo nnspool-request-article (id &optional group server buffer)
 181   "Select article by message ID (or number)."
 182   (nnspool-possibly-change-directory group)
 183   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 184         file ag)
 185     (if (stringp id)
 186         ;; This is a Message-ID.
 187         (when (setq ag (nnspool-find-id id))
 188           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 189       (setq file (nnspool-article-pathname nnspool-current-group id)))
 190     (and file
 191          (file-exists-p file)
 192          (not (file-directory-p file))
 193          (save-excursion (nnspool-find-file file))
 194          ;; We return the article number and group name.
 195          (if (numberp id)
 196              (cons nnspool-current-group id)
 197            ag))))
 198
 199 (deffoo nnspool-request-body (id &optional group server)
 200   "Select article body by message ID (or number)."
 201   (nnspool-possibly-change-directory group)
 202   (let ((res (nnspool-request-article id)))
 203     (when res
 204       (save-excursion
 205         (set-buffer nntp-server-buffer)
 206         (goto-char (point-min))
 207         (when (search-forward "\n\n" nil t)
 208           (delete-region (point-min) (point)))
 209         res))))
 210
 211 (deffoo nnspool-request-head (id &optional group server)
 212   "Select article head by message ID (or number)."
 213   (nnspool-possibly-change-directory group)
 214   (let ((res (nnspool-request-article id)))
 215     (when res
 216       (save-excursion
 217         (set-buffer nntp-server-buffer)
 218         (goto-char (point-min))
 219         (when (search-forward "\n\n" nil t)
 220           (delete-region (1- (point)) (point-max)))
 221         (nnheader-fold-continuation-lines)))
 222     res))
 223
 224 (deffoo nnspool-request-group (group &optional server dont-check)
 225   "Select news GROUP."
 226   (let ((pathname (nnspool-article-pathname group))
 227         dir)
 228     (if (not (file-directory-p pathname))
 229         (nnheader-report
 230          'nnspool "Invalid group name (no such directory): %s" group)
 231       (setq nnspool-current-directory pathname)
 232       (nnheader-report 'nnspool "Selected group %s" group)
 233       (if dont-check
 234           (progn
 235             (nnheader-report 'nnspool "Selected group %s" group)
 236             t)
 237         ;; Yes, completely empty spool directories *are* possible.
 238         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 239         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 240           (setq dir
 241                 (sort (mapcar (lambda (name) (string-to-int name)) dir) '<)))
 242         (if dir
 243             (nnheader-insert
 244              "211 %d %d %d %s\n" (length dir) (car dir)
 245              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 246              group)
 247           (nnheader-report 'nnspool "Empty group %s" group)
 248           (nnheader-insert "211 0 0 0 %s\n" group))))))
 249
 250 (deffoo nnspool-request-type (group &optional article)
 251   'news)
 252
 253 (deffoo nnspool-close-group (group &optional server)
 254   t)
 255
 256 (deffoo nnspool-request-list (&optional server)
 257   "List active newsgroups."
 258   (save-excursion
 259     (or (nnspool-find-file nnspool-active-file)
 260         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 261
 262 (deffoo nnspool-request-list-newsgroups (&optional server)
 263   "List newsgroups (defined in NNTP2)."
 264   (save-excursion
 265     (or (nnspool-find-file nnspool-newsgroups-file)
 266         (nnheader-report 'nnspool (nnheader-file-error
 267                                    nnspool-newsgroups-file)))))
 268
 269 (deffoo nnspool-request-list-distributions (&optional server)
 270   "List distributions (defined in NNTP2)."
 271   (save-excursion
 272     (or (nnspool-find-file nnspool-distributions-file)
 273         (nnheader-report 'nnspool (nnheader-file-error
 274                                    nnspool-distributions-file)))))
 275
 276 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 277 (deffoo nnspool-request-newgroups (date &optional server)
 278   "List groups created after DATE."
 279   (if (nnspool-find-file nnspool-active-times-file)
 280       (save-excursion
 281         ;; Find the last valid line.
 282         (goto-char (point-max))
 283         (while (and (not (looking-at
 284                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 285                     (zerop (forward-line -1))))
 286         (let ((seconds (time-to-seconds (date-to-time date)))
 287               groups)
 288           ;; Go through lines and add the latest groups to a list.
 289           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 290                       (progn
 291                         ;; We insert a .0 to make the list reader
 292                         ;; interpret the number as a float.  It is far
 293                         ;; too big to be stored in a lisp integer.
 294                         (goto-char (1- (match-end 0)))
 295                         (insert ".0")
 296                         (> (progn
 297                              (goto-char (match-end 1))
 298                              (read (current-buffer)))
 299                            seconds))
 300                       (push (buffer-substring
 301                                           (match-beginning 1) (match-end 1))
 302                                          groups)
 303                       (zerop (forward-line -1))))
 304           (erase-buffer)
 305           (while groups
 306             (insert (car groups) " 0 0 y\n")
 307             (setq groups (cdr groups))))
 308         t)
 309     nil))
 310
 311 (deffoo nnspool-request-post (&optional server)
 312   "Post a new news in current buffer."
 313   (save-excursion
 314     (let* ((process-connection-type nil) ; t bugs out on Solaris
 315            (inews-buffer (generate-new-buffer " *nnspool post*"))
 316            (proc
 317             (condition-case err
 318                 (apply 'start-process "*nnspool inews*" inews-buffer
 319                        nnspool-inews-program nnspool-inews-switches)
 320               (error
 321                (nnheader-report 'nnspool "inews error: %S" err)))))
 322       (if (not proc)
 323           ;; The inews program failed.
 324           ()
 325         (nnheader-report 'nnspool "")
 326         (set-process-sentinel proc 'nnspool-inews-sentinel)
 327         (process-send-region proc (point-min) (point-max))
 328         ;; We slap a condition-case around this, because the process may
 329         ;; have exited already...
 330         (ignore-errors
 331           (process-send-eof proc))
 332         t))))
 333
 334
 335 \f
 336 ;;; Internal functions.
 337
 338 (defun nnspool-inews-sentinel (proc status)
 339   (save-excursion
 340     (set-buffer (process-buffer proc))
 341     (goto-char (point-min))
 342     (if (or (zerop (buffer-size))
 343             (search-forward "spooled" nil t))
 344         (kill-buffer (current-buffer))
 345       ;; Make status message by folding lines.
 346       (while (re-search-forward "[ \t\n]+" nil t)
 347         (replace-match " " t t))
 348       (nnheader-report 'nnspool "%s" (buffer-string))
 349       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 350       (ding)
 351       (run-hooks 'nnspool-rejected-article-hook))))
 352
 353 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 354   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 355       nil
 356     (let ((nov (nnheader-group-pathname
 357                 nnspool-current-group nnspool-nov-directory ".overview"))
 358           (arts articles)
 359           (nnheader-file-coding-system nnspool-file-coding-system)
 360           last)
 361       (if (not (file-exists-p nov))
 362           ()
 363         (save-excursion
 364           (set-buffer nntp-server-buffer)
 365           (erase-buffer)
 366           (if nnspool-sift-nov-with-sed
 367               (nnspool-sift-nov-with-sed articles nov)
 368             (nnheader-insert-file-contents nov)
 369             (if (and fetch-old
 370                      (not (numberp fetch-old)))
 371                 t                       ; We want all the headers.
 372               (ignore-errors
 373                 ;; Delete unwanted NOV lines.
 374                 (nnheader-nov-delete-outside-range
 375                  (if fetch-old (max 1 (- (car articles) fetch-old))
 376                    (car articles))
 377                  (car (last articles)))
 378                 ;; If the buffer is empty, this wasn't very successful.
 379                 (unless (zerop (buffer-size))
 380                   ;; We check what the last article number was.
 381                   ;; The NOV file may be out of sync with the articles
 382                   ;; in the group.
 383                   (forward-line -1)
 384                   (setq last (read (current-buffer)))
 385                   (if (= last (car articles))
 386                       ;; Yup, it's all there.
 387                       t
 388                     ;; Perhaps not.  We try to find the missing articles.
 389                     (while (and arts
 390                                 (<= last (car arts)))
 391                       (pop arts))
 392                     ;; The articles in `arts' are missing from the buffer.
 393                     (while arts
 394                       (nnspool-insert-nov-head (pop arts)))
 395                     t))))))))))
 396
 397 (defun nnspool-insert-nov-head (article)
 398   "Read the head of ARTICLE, convert to NOV headers, and insert."
 399   (save-excursion
 400     (let ((cur (current-buffer))
 401           buf)
 402       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 403       (when (nnheader-insert-head
 404              (nnspool-article-pathname nnspool-current-group article))
 405         (nnheader-insert-article-line article)
 406         (let ((headers (nnheader-parse-head)))
 407           (set-buffer cur)
 408           (goto-char (point-max))
 409           (nnheader-insert-nov headers)))
 410       (kill-buffer buf))))
 411
 412 (defun nnspool-sift-nov-with-sed (articles file)
 413   (let ((first (car articles))
 414         (last (progn (while (cdr articles) (setq articles (cdr articles)))
 415                      (car articles))))
 416     (call-process "awk" nil t nil
 417                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 418                           (1- first) (1+ last))
 419                   file)))
 420
 421 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 422 ;; Find out what group an article identified by a Message-ID is in.
 423 (defun nnspool-find-id (id)
 424   (save-excursion
 425     (set-buffer (get-buffer-create " *nnspool work*"))
 426     (erase-buffer)
 427     (ignore-errors
 428       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 429     (goto-char (point-min))
 430     (prog1
 431         (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 432           (cons (match-string 1) (string-to-int (match-string 2))))
 433       (kill-buffer (current-buffer)))))
 434
 435 (defun nnspool-find-file (file)
 436   "Insert FILE in server buffer safely."
 437   (set-buffer nntp-server-buffer)
 438   (erase-buffer)
 439   (condition-case ()
 440       (let ((nnheader-file-coding-system nnspool-file-coding-system))
 441         (nnheader-insert-file-contents file)
 442         t)
 443     (file-error nil)))
 444
 445 (defun nnspool-possibly-change-directory (group)
 446   (if (not group)
 447       t
 448     (let ((pathname (nnspool-article-pathname group)))
 449       (if (file-directory-p pathname)
 450           (setq nnspool-current-directory pathname
 451                 nnspool-current-group group)
 452         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 453
 454 (defun nnspool-article-pathname (group &optional article)
 455   "Find the path for GROUP."
 456   (nnheader-group-pathname group nnspool-spool-directory article))
 457
 458 (provide 'nnspool)
 459
 460 ;;; nnspool.el ends here