git.chise.org Git - elisp/gnus.git-/blob - lisp/nntp.el

   1 ;;; nntp.el --- nntp access for Gnus
   2 ;;; Copyright (C) 1987-90,92-98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'nnheader)
  28 (require 'nnoo)
  29 (require 'gnus-util)
  30
  31 (nnoo-declare nntp)
  32
  33 (eval-when-compile (require 'cl))
  34
  35 (defvoo nntp-address nil
  36   "Address of the physical nntp server.")
  37
  38 (defvoo nntp-port-number "nntp"
  39   "Port number on the physical nntp server.")
  40
  41 (defvoo nntp-server-opened-hook '(nntp-send-mode-reader)
  42   "*Hook used for sending commands to the server at startup.
  43 The default value is `nntp-send-mode-reader', which makes an innd
  44 server spawn an nnrpd server.")
  45
  46 (defvoo nntp-authinfo-function 'nntp-send-authinfo
  47   "Function used to send AUTHINFO to the server.
  48 It is called with no parameters.")
  49
  50 (defvoo nntp-server-action-alist
  51   '(("nntpd 1\\.5\\.11t"
  52      (remove-hook 'nntp-server-opened-hook 'nntp-send-mode-reader))
  53     ("NNRP server Netscape"
  54      (setq nntp-server-list-active-group nil)))
  55   "Alist of regexps to match on server types and actions to be taken.
  56 For instance, if you want Gnus to beep every time you connect
  57 to innd, you could say something like:
  58
  59 \(setq nntp-server-action-alist
  60        '((\"innd\" (ding))))
  61
  62 You probably don't want to do that, though.")
  63
  64 (defvoo nntp-open-connection-function 'nntp-open-network-stream
  65   "*Function used for connecting to a remote system.
  66 It will be called with the buffer to output in.
  67
  68 Two pre-made functions are `nntp-open-network-stream', which is the
  69 default, and simply connects to some port or other on the remote
  70 system (see nntp-port-number).  The other are `nntp-open-rlogin',
  71 which does an rlogin on the remote system, and then does a telnet to
  72 the NNTP server available there (see nntp-rlogin-parameters) and
  73 `nntp-open-telnet' which telnets to a remote system, logs in and does
  74 the same.")
  75
  76 (defvoo nntp-rlogin-program "rsh"
  77   "*Program used to log in on remote machines.
  78 The default is \"rsh\", but \"ssh\" is a popular alternative.")
  79
  80 (defvoo nntp-rlogin-parameters '("telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  81   "*Parameters to `nntp-open-rlogin'.
  82 That function may be used as `nntp-open-connection-function'.  In that
  83 case, this list will be used as the parameter list given to rsh.")
  84
  85 (defvoo nntp-rlogin-user-name nil
  86   "*User name on remote system when using the rlogin connect method.")
  87
  88 (defvoo nntp-telnet-parameters '("exec" "telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  89   "*Parameters to `nntp-open-telnet'.
  90 That function may be used as `nntp-open-connection-function'.  In that
  91 case, this list will be executed as a command after logging in
  92 via telnet.")
  93
  94 (defvoo nntp-telnet-user-name nil
  95   "User name to log in via telnet with.")
  96
  97 (defvoo nntp-telnet-passwd nil
  98   "Password to use to log in via telnet with.")
  99
 100 (defvoo nntp-open-telnet-envuser nil
 101   "*If non-nil, telnet session (client and server both) will support the ENVIRON option and not prompt for login name.")
 102
 103 (defvoo nntp-telnet-shell-prompt "bash\\|\$ *\r?$\\|> *\r?"
 104   "*Regular expression to match the shell prompt on the remote machine.")
 105
 106 (defvoo nntp-telnet-command "telnet"
 107   "Command used to start telnet.")
 108
 109 (defvoo nntp-telnet-switches '("-8")
 110   "Switches given to the telnet command.")
 111
 112 (defvoo nntp-end-of-line "\r\n"
 113   "String to use on the end of lines when talking to the NNTP server.
 114 This is \"\\r\\n\" by default, but should be \"\\n\" when
 115 using rlogin or telnet to communicate with the server.")
 116
 117 (defvoo nntp-large-newsgroup 50
 118   "*The number of the articles which indicates a large newsgroup.
 119 If the number of the articles is greater than the value, verbose
 120 messages will be shown to indicate the current status.")
 121
 122 (defvoo nntp-maximum-request 400
 123   "*The maximum number of the requests sent to the NNTP server at one time.
 124 If Emacs hangs up while retrieving headers, set the variable to a
 125 lower value.")
 126
 127 (defvoo nntp-nov-is-evil nil
 128   "*If non-nil, nntp will never attempt to use XOVER when talking to the server.")
 129
 130 (defvoo nntp-xover-commands '("XOVER" "XOVERVIEW")
 131   "*List of strings that are used as commands to fetch NOV lines from a server.
 132 The strings are tried in turn until a positive response is gotten.  If
 133 none of the commands are successful, nntp will just grab headers one
 134 by one.")
 135
 136 (defvoo nntp-nov-gap 5
 137   "*Maximum allowed gap between two articles.
 138 If the gap between two consecutive articles is bigger than this
 139 variable, split the XOVER request into two requests.")
 140
 141 (defvoo nntp-prepare-server-hook nil
 142   "*Hook run before a server is opened.
 143 If can be used to set up a server remotely, for instance.  Say you
 144 have an account at the machine \"other.machine\".  This machine has
 145 access to an NNTP server that you can't access locally.  You could
 146 then use this hook to rsh to the remote machine and start a proxy NNTP
 147 server there that you can connect to.  See also
 148 `nntp-open-connection-function'")
 149
 150 (defvoo nntp-warn-about-losing-connection t
 151   "*If non-nil, beep when a server closes connection.")
 152
 153 (defvoo nntp-coding-system-for-read 'binary
 154   "*Coding system to read from NNTP.")
 155
 156 (defvoo nntp-coding-system-for-write 'binary
 157   "*Coding system to write to NNTP.")
 158
 159 (defcustom nntp-authinfo-file "~/.authinfo"
 160   ".netrc-like file that holds nntp authinfo passwords."
 161   :type
 162   '(choice file
 163            (repeat :tag "Entries"
 164                    :menu-tag "Inline"
 165                    (list :format "%v"
 166                          :value ("" ("login" . "") ("password" . ""))
 167                          (string :tag "Host")
 168                          (checklist :inline t
 169                                     (cons :format "%v"
 170                                           (const :format "" "login")
 171                                           (string :format "Login: %v"))
 172                                     (cons :format "%v"
 173                                           (const :format "" "password")
 174                                           (string :format "Password: %v")))))))
 175
 176 \f
 177
 178 (defvoo nntp-connection-timeout nil
 179   "*Number of seconds to wait before an nntp connection times out.
 180 If this variable is nil, which is the default, no timers are set.")
 181
 182 ;;; Internal variables.
 183
 184 (defvar nntp-record-commands nil
 185   "*If non-nil, nntp will record all commands in the \"*nntp-log*\" buffer.")
 186
 187 (defvar nntp-have-messaged nil)
 188
 189 (defvar nntp-process-wait-for nil)
 190 (defvar nntp-process-to-buffer nil)
 191 (defvar nntp-process-callback nil)
 192 (defvar nntp-process-decode nil)
 193 (defvar nntp-process-start-point nil)
 194 (defvar nntp-inside-change-function nil)
 195 (defvoo nntp-last-command-time nil)
 196 (defvoo nntp-last-command nil)
 197 (defvoo nntp-authinfo-password nil)
 198 (defvoo nntp-authinfo-user nil)
 199
 200 (defvar nntp-connection-list nil)
 201
 202 (defvoo nntp-server-type nil)
 203 (defvoo nntp-connection-alist nil)
 204 (defvoo nntp-status-string "")
 205 (defconst nntp-version "nntp 5.0")
 206 (defvoo nntp-inhibit-erase nil)
 207 (defvoo nntp-inhibit-output nil)
 208
 209 (defvoo nntp-server-xover 'try)
 210 (defvoo nntp-server-list-active-group 'try)
 211
 212 (eval-and-compile
 213   (autoload 'nnmail-read-passwd "nnmail")
 214   (autoload 'open-ssl-stream "ssl"))
 215
 216 \f
 217
 218 ;;; Internal functions.
 219
 220 (defsubst nntp-send-string (process string)
 221   "Send STRING to PROCESS."
 222   ;; We need to store the time to provide timeouts, and
 223   ;; to store the command so the we can replay the command
 224   ;; if the server gives us an AUTHINFO challenge.
 225   (setq nntp-last-command-time (current-time)
 226         nntp-last-command string)
 227   (when nntp-record-commands
 228     (nntp-record-command string))
 229   (process-send-string process (concat string nntp-end-of-line)))
 230
 231 (defun nntp-record-command (string)
 232   "Record the command STRING."
 233   (save-excursion
 234     (set-buffer (get-buffer-create "*nntp-log*"))
 235     (goto-char (point-max))
 236     (let ((time (current-time)))
 237       (insert (format-time-string "%Y%m%dT%H%M%S" time)
 238               "." (format "%03d" (/ (nth 2 time) 1000))
 239               " " nntp-address " " string "\n"))))
 240
 241 (defsubst nntp-wait-for (process wait-for buffer &optional decode discard)
 242   "Wait for WAIT-FOR to arrive from PROCESS."
 243   (save-excursion
 244     (set-buffer (process-buffer process))
 245     (goto-char (point-min))
 246     (while (and (or (not (memq (char-after (point)) '(?2 ?3 ?4 ?5)))
 247                     (looking-at "480"))
 248                 (memq (process-status process) '(open run)))
 249       (when (looking-at "480")
 250         (nntp-handle-authinfo process))
 251       (nntp-accept-process-output process)
 252       (goto-char (point-min)))
 253     (prog1
 254         (cond
 255          ((looking-at "[45]")
 256           (progn
 257             (nntp-snarf-error-message)
 258             nil))
 259          ((not (memq (process-status process) '(open run)))
 260           (nnheader-report 'nntp "Server closed connection"))
 261          (t
 262           (goto-char (point-max))
 263           (let ((limit (point-min)))
 264             (while (not (re-search-backward wait-for limit t))
 265               (nntp-accept-process-output process)
 266               ;; We assume that whatever we wait for is less than 1000
 267               ;; characters long.
 268               (setq limit (max (- (point-max) 1000) (point-min)))
 269               (goto-char (point-max))))
 270           (nntp-decode-text (not decode))
 271           (unless discard
 272             (save-excursion
 273               (set-buffer buffer)
 274               (goto-char (point-max))
 275               (insert-buffer-substring (process-buffer process))
 276               ;; Nix out "nntp reading...." message.
 277               (when nntp-have-messaged
 278                 (setq nntp-have-messaged nil)
 279                 (nnheader-message 5 ""))
 280               t))))
 281       (unless discard
 282         (erase-buffer)))))
 283
 284 (defsubst nntp-find-connection (buffer)
 285   "Find the connection delivering to BUFFER."
 286   (let ((alist nntp-connection-alist)
 287         (buffer (if (stringp buffer) (get-buffer buffer) buffer))
 288         process entry)
 289     (while (setq entry (pop alist))
 290       (when (eq buffer (cadr entry))
 291         (setq process (car entry)
 292               alist nil)))
 293     (when process
 294       (if (memq (process-status process) '(open run))
 295           process
 296         (when (buffer-name (process-buffer process))
 297           (kill-buffer (process-buffer process)))
 298         (setq nntp-connection-alist (delq entry nntp-connection-alist))
 299         nil))))
 300
 301 (defsubst nntp-find-connection-entry (buffer)
 302   "Return the entry for the connection to BUFFER."
 303   (assq (nntp-find-connection buffer) nntp-connection-alist))
 304
 305 (defun nntp-find-connection-buffer (buffer)
 306   "Return the process connection buffer tied to BUFFER."
 307   (let ((process (nntp-find-connection buffer)))
 308     (when process
 309       (process-buffer process))))
 310
 311 (defsubst nntp-retrieve-data (command address port buffer
 312                                       &optional wait-for callback decode)
 313   "Use COMMAND to retrieve data into BUFFER from PORT on ADDRESS."
 314   (let ((process (or (nntp-find-connection buffer)
 315                      (nntp-open-connection buffer))))
 316     (if (not process)
 317         (nnheader-report 'nntp "Couldn't open connection to %s" address)
 318       (unless (or nntp-inhibit-erase nnheader-callback-function)
 319         (save-excursion
 320           (set-buffer (process-buffer process))
 321           (erase-buffer)))
 322       (when command
 323         (nntp-send-string process command))
 324       (cond
 325        ((eq callback 'ignore)
 326         t)
 327        ((and callback wait-for)
 328         (save-excursion
 329           (set-buffer (process-buffer process))
 330           (unless nntp-inside-change-function
 331             (erase-buffer))
 332           (setq nntp-process-decode decode
 333                 nntp-process-to-buffer buffer
 334                 nntp-process-wait-for wait-for
 335                 nntp-process-callback callback
 336                 nntp-process-start-point (point-max)
 337                 after-change-functions
 338                 (list 'nntp-after-change-function-callback)))
 339         t)
 340        (wait-for
 341         (nntp-wait-for process wait-for buffer decode))
 342        (t t)))))
 343
 344 (defsubst nntp-send-command (wait-for &rest strings)
 345   "Send STRINGS to server and wait until WAIT-FOR returns."
 346   (when (and (not nnheader-callback-function)
 347              (not nntp-inhibit-output))
 348     (save-excursion
 349       (set-buffer nntp-server-buffer)
 350       (erase-buffer)))
 351   (nntp-retrieve-data
 352    (mapconcat 'identity strings " ")
 353    nntp-address nntp-port-number nntp-server-buffer
 354    wait-for nnheader-callback-function))
 355
 356 (defun nntp-send-command-nodelete (wait-for &rest strings)
 357   "Send STRINGS to server and wait until WAIT-FOR returns."
 358   (nntp-retrieve-data
 359    (mapconcat 'identity strings " ")
 360    nntp-address nntp-port-number nntp-server-buffer
 361    wait-for nnheader-callback-function))
 362
 363 (defun nntp-send-command-and-decode (wait-for &rest strings)
 364   "Send STRINGS to server and wait until WAIT-FOR returns."
 365   (when (and (not nnheader-callback-function)
 366              (not nntp-inhibit-output))
 367     (save-excursion
 368       (set-buffer nntp-server-buffer)
 369       (erase-buffer)))
 370   (nntp-retrieve-data
 371    (mapconcat 'identity strings " ")
 372    nntp-address nntp-port-number nntp-server-buffer
 373    wait-for nnheader-callback-function t))
 374
 375 (defun nntp-send-buffer (wait-for)
 376   "Send the current buffer to server and wait until WAIT-FOR returns."
 377   (when (and (not nnheader-callback-function)
 378              (not nntp-inhibit-output))
 379     (save-excursion
 380       (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 381       (erase-buffer)))
 382   (nntp-encode-text)
 383   (process-send-region (nntp-find-connection nntp-server-buffer)
 384                        (point-min) (point-max))
 385   (nntp-retrieve-data
 386    nil nntp-address nntp-port-number nntp-server-buffer
 387    wait-for nnheader-callback-function))
 388
 389 \f
 390
 391 ;;; Interface functions.
 392
 393 (nnoo-define-basics nntp)
 394
 395 (defsubst nntp-next-result-arrived-p ()
 396   (cond
 397    ;; A result that starts with a 2xx code is terminated by
 398    ;; a line with only a "." on it.
 399    ((eq (char-after) ?2)
 400     (if (re-search-forward "\n\\.\r?\n" nil t)
 401         t
 402       nil))
 403    ;; A result that starts with a 3xx or 4xx code is terminated
 404    ;; by a newline.
 405    ((looking-at "[34]")
 406     (if (search-forward "\n" nil t)
 407         t
 408       nil))
 409    ;; No result here.
 410    (t
 411     nil)))
 412
 413 (deffoo nntp-retrieve-headers (articles &optional group server fetch-old)
 414   "Retrieve the headers of ARTICLES."
 415   (nntp-possibly-change-group group server)
 416   (save-excursion
 417     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 418     (erase-buffer)
 419     (if (and (not gnus-nov-is-evil)
 420              (not nntp-nov-is-evil)
 421              (nntp-retrieve-headers-with-xover articles fetch-old))
 422         ;; We successfully retrieved the headers via XOVER.
 423         'nov
 424       ;; XOVER didn't work, so we do it the hard, slow and inefficient
 425       ;; way.
 426       (let ((number (length articles))
 427             (count 0)
 428             (received 0)
 429             (last-point (point-min))
 430             (buf (nntp-find-connection-buffer nntp-server-buffer))
 431             (nntp-inhibit-erase t)
 432             article)
 433         ;; Send HEAD commands.
 434       (while (setq article (pop articles))
 435         (nntp-send-command
 436          nil
 437          "HEAD" (if (numberp article)
 438                     (int-to-string article)
 439                   ;; `articles' is either a list of article numbers
 440                   ;; or a list of article IDs.
 441                   article))
 442         (incf count)
 443         ;; Every 400 requests we have to read the stream in
 444         ;; order to avoid deadlocks.
 445         (when (or (null articles)       ;All requests have been sent.
 446                   (zerop (% count nntp-maximum-request)))
 447           (nntp-accept-response)
 448           (while (progn
 449                    (set-buffer buf)
 450                    (goto-char last-point)
 451                    ;; Count replies.
 452                    (while (nntp-next-result-arrived-p)
 453                      (setq last-point (point))
 454                      (incf received))
 455                    (< received count))
 456             ;; If number of headers is greater than 100, give
 457             ;;  informative messages.
 458             (and (numberp nntp-large-newsgroup)
 459                  (> number nntp-large-newsgroup)
 460                  (zerop (% received 20))
 461                  (nnheader-message 6 "NNTP: Receiving headers... %d%%"
 462                                    (/ (* received 100) number)))
 463             (nntp-accept-response))))
 464         (and (numberp nntp-large-newsgroup)
 465              (> number nntp-large-newsgroup)
 466              (nnheader-message 6 "NNTP: Receiving headers...done"))
 467
 468         ;; Now all of replies are received.  Fold continuation lines.
 469         (nnheader-fold-continuation-lines)
 470         ;; Remove all "\r"'s.
 471         (nnheader-strip-cr)
 472         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 473         'headers))))
 474
 475 (deffoo nntp-retrieve-groups (groups &optional server)
 476   "Retrieve group info on GROUPS."
 477   (nntp-possibly-change-group nil server)
 478   (save-excursion
 479     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 480     ;; The first time this is run, this variable is `try'.  So we
 481     ;; try.
 482     (when (eq nntp-server-list-active-group 'try)
 483       (nntp-try-list-active (car groups)))
 484     (erase-buffer)
 485     (let ((count 0)
 486           (received 0)
 487           (last-point (point-min))
 488           (nntp-inhibit-erase t)
 489           (command (if nntp-server-list-active-group "LIST ACTIVE" "GROUP")))
 490       (while groups
 491         ;; Send the command to the server.
 492         (nntp-send-command nil command (pop groups))
 493         (incf count)
 494         ;; Every 400 requests we have to read the stream in
 495         ;; order to avoid deadlocks.
 496         (when (or (null groups)         ;All requests have been sent.
 497                   (zerop (% count nntp-maximum-request)))
 498           (nntp-accept-response)
 499           (while (progn
 500                    (goto-char last-point)
 501                    ;; Count replies.
 502                    (while (re-search-forward "^[0-9]" nil t)
 503                      (incf received))
 504                    (setq last-point (point))
 505                    (< received count))
 506             (nntp-accept-response))))
 507
 508       ;; Wait for the reply from the final command.
 509       (goto-char (point-max))
 510       (re-search-backward "^[0-9]" nil t)
 511       (when (looking-at "^[23]")
 512         (while (progn
 513                  (goto-char (point-max))
 514                  (if (not nntp-server-list-active-group)
 515                      (not (re-search-backward "\r?\n" (- (point) 3) t))
 516                    (not (re-search-backward "^\\.\r?\n" (- (point) 4) t))))
 517           (nntp-accept-response)))
 518
 519       ;; Now all replies are received.  We remove CRs.
 520       (goto-char (point-min))
 521       (while (search-forward "\r" nil t)
 522         (replace-match "" t t))
 523
 524       (if (not nntp-server-list-active-group)
 525           (progn
 526             (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 527             'group)
 528         ;; We have read active entries, so we just delete the
 529         ;; superfluous gunk.
 530         (goto-char (point-min))
 531         (while (re-search-forward "^[.2-5]" nil t)
 532           (delete-region (match-beginning 0)
 533                          (progn (forward-line 1) (point))))
 534         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 535         'active))))
 536
 537 (deffoo nntp-retrieve-articles (articles &optional group server)
 538   (nntp-possibly-change-group group server)
 539   (save-excursion
 540     (let ((number (length articles))
 541           (count 0)
 542           (received 0)
 543           (last-point (point-min))
 544           (buf (nntp-find-connection-buffer nntp-server-buffer))
 545           (nntp-inhibit-erase t)
 546           (map (apply 'vector articles))
 547           (point 1)
 548           article)
 549       (set-buffer buf)
 550       (erase-buffer)
 551       ;; Send ARTICLE command.
 552       (while (setq article (pop articles))
 553         (nntp-send-command
 554          nil
 555          "ARTICLE" (if (numberp article)
 556                        (int-to-string article)
 557                      ;; `articles' is either a list of article numbers
 558                      ;; or a list of article IDs.
 559                      article))
 560         (incf count)
 561         ;; Every 400 requests we have to read the stream in
 562         ;; order to avoid deadlocks.
 563         (when (or (null articles)       ;All requests have been sent.
 564                   (zerop (% count nntp-maximum-request)))
 565           (nntp-accept-response)
 566           (while (progn
 567                    (set-buffer buf)
 568                    (goto-char last-point)
 569                    ;; Count replies.
 570                    (while (nntp-next-result-arrived-p)
 571                      (aset map received (cons (aref map received) (point)))
 572                      (setq last-point (point))
 573                      (incf received))
 574                    (< received count))
 575             ;; If number of headers is greater than 100, give
 576             ;;  informative messages.
 577             (and (numberp nntp-large-newsgroup)
 578                  (> number nntp-large-newsgroup)
 579                  (zerop (% received 20))
 580                  (nnheader-message 6 "NNTP: Receiving articles... %d%%"
 581                                    (/ (* received 100) number)))
 582             (nntp-accept-response))))
 583       (and (numberp nntp-large-newsgroup)
 584            (> number nntp-large-newsgroup)
 585            (nnheader-message 6 "NNTP: Receiving articles...done"))
 586
 587       ;; Now we have all the responses.  We go through the results,
 588       ;; wash it and copy it over to the server buffer.
 589       (set-buffer nntp-server-buffer)
 590       (erase-buffer)
 591       (setq last-point (point-min))
 592       (mapcar
 593        (lambda (entry)
 594          (narrow-to-region
 595           (setq point (goto-char (point-max)))
 596           (progn
 597             (insert-buffer-substring buf last-point (cdr entry))
 598             (point-max)))
 599          (setq last-point (cdr entry))
 600          (nntp-decode-text)
 601          (widen)
 602          (cons (car entry) point))
 603        map))))
 604
 605 (defun nntp-try-list-active (group)
 606   (nntp-list-active-group group)
 607   (save-excursion
 608     (set-buffer nntp-server-buffer)
 609     (goto-char (point-min))
 610     (cond ((or (eobp)
 611                (looking-at "5[0-9]+"))
 612            (setq nntp-server-list-active-group nil))
 613           (t
 614            (setq nntp-server-list-active-group t)))))
 615
 616 (deffoo nntp-list-active-group (group &optional server)
 617   "Return the active info on GROUP (which can be a regexp)."
 618   (nntp-possibly-change-group nil server)
 619   (nntp-send-command "^\\.*\r?\n" "LIST ACTIVE" group))
 620
 621 (deffoo nntp-request-group-articles (group &optional server)
 622   "Return the list of existing articles in GROUP."
 623   (nntp-possibly-change-group nil server)
 624   (nntp-send-command "^\\.*\r?\n" "LISTGROUP" group))
 625
 626 (deffoo nntp-request-article (article &optional group server buffer command)
 627   (nntp-possibly-change-group group server)
 628   (when (nntp-send-command-and-decode
 629          "\r?\n\\.\r?\n" "ARTICLE"
 630          (if (numberp article) (int-to-string article) article))
 631     (if (and buffer
 632              (not (equal buffer nntp-server-buffer)))
 633         (save-excursion
 634           (set-buffer nntp-server-buffer)
 635           (copy-to-buffer buffer (point-min) (point-max))
 636           (nntp-find-group-and-number))
 637       (nntp-find-group-and-number))))
 638
 639 (deffoo nntp-request-head (article &optional group server)
 640   (nntp-possibly-change-group group server)
 641   (when (nntp-send-command
 642          "\r?\n\\.\r?\n" "HEAD"
 643          (if (numberp article) (int-to-string article) article))
 644     (prog1
 645         (nntp-find-group-and-number)
 646       (nntp-decode-text))))
 647
 648 (deffoo nntp-request-body (article &optional group server)
 649   (nntp-possibly-change-group group server)
 650   (nntp-send-command-and-decode
 651    "\r?\n\\.\r?\n" "BODY"
 652    (if (numberp article) (int-to-string article) article)))
 653
 654 (deffoo nntp-request-group (group &optional server dont-check)
 655   (nntp-possibly-change-group nil server)
 656   (when (nntp-send-command "^[245].*\n" "GROUP" group)
 657     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 658       (setcar (cddr entry) group))))
 659
 660 (deffoo nntp-close-group (group &optional server)
 661   t)
 662
 663 (deffoo nntp-server-opened (&optional server)
 664   "Say whether a connection to SERVER has been opened."
 665   (and (nnoo-current-server-p 'nntp server)
 666        nntp-server-buffer
 667        (gnus-buffer-live-p nntp-server-buffer)
 668        (nntp-find-connection nntp-server-buffer)))
 669
 670 (deffoo nntp-open-server (server &optional defs connectionless)
 671   (nnheader-init-server-buffer)
 672   (if (nntp-server-opened server)
 673       t
 674     (when (or (stringp (car defs))
 675               (numberp (car defs)))
 676       (setq defs (cons (list 'nntp-port-number (car defs)) (cdr defs))))
 677     (unless (assq 'nntp-address defs)
 678       (setq defs (append defs (list (list 'nntp-address server)))))
 679     (nnoo-change-server 'nntp server defs)
 680     (unless connectionless
 681       (or (nntp-find-connection nntp-server-buffer)
 682           (nntp-open-connection nntp-server-buffer)))))
 683
 684 (deffoo nntp-close-server (&optional server)
 685   (nntp-possibly-change-group nil server t)
 686   (let ((process (nntp-find-connection nntp-server-buffer)))
 687     (while process
 688       (when (memq (process-status process) '(open run))
 689         (ignore-errors
 690           (nntp-send-string process "QUIT")
 691           (unless (eq nntp-open-connection-function 'nntp-open-network-stream)
 692             ;; Ok, this is evil, but when using telnet and stuff
 693             ;; as the connection method, it's important that the
 694             ;; QUIT command actually is sent out before we kill
 695             ;; the process.
 696             (sleep-for 1))))
 697       (when (buffer-name (process-buffer process))
 698         (kill-buffer (process-buffer process)))
 699       (setq process (car (pop nntp-connection-alist))))
 700     (nnoo-close-server 'nntp)))
 701
 702 (deffoo nntp-request-close ()
 703   (let (process)
 704     (while (setq process (pop nntp-connection-list))
 705       (when (memq (process-status process) '(open run))
 706         (ignore-errors
 707           (nntp-send-string process "QUIT")
 708           (unless (eq nntp-open-connection-function 'nntp-open-network-stream)
 709             ;; Ok, this is evil, but when using telnet and stuff
 710             ;; as the connection method, it's important that the
 711             ;; QUIT command actually is sent out before we kill
 712             ;; the process.
 713             (sleep-for 1))))
 714       (when (buffer-name (process-buffer process))
 715         (kill-buffer (process-buffer process))))))
 716
 717 (deffoo nntp-request-list (&optional server)
 718   (nntp-possibly-change-group nil server)
 719   (nntp-send-command-and-decode "\r?\n\\.\r?\n" "LIST"))
 720
 721 (deffoo nntp-request-list-newsgroups (&optional server)
 722   (nntp-possibly-change-group nil server)
 723   (nntp-send-command "\r?\n\\.\r?\n" "LIST NEWSGROUPS"))
 724
 725 (deffoo nntp-request-newgroups (date &optional server)
 726   (nntp-possibly-change-group nil server)
 727   (save-excursion
 728     (set-buffer nntp-server-buffer)
 729     (prog1
 730         (nntp-send-command
 731          "^\\.\r?\n" "NEWGROUPS"
 732          (format-time-string "%y%m%d %H%M%S" (date-to-time date)))
 733       (nntp-decode-text))))
 734
 735 (deffoo nntp-request-post (&optional server)
 736   (nntp-possibly-change-group nil server)
 737   (when (nntp-send-command "^[23].*\r?\n" "POST")
 738     (nntp-send-buffer "^[23].*\n")))
 739
 740 (deffoo nntp-request-type (group article)
 741   'news)
 742
 743 (deffoo nntp-asynchronous-p ()
 744   t)
 745
 746 ;;; Hooky functions.
 747
 748 (defun nntp-send-mode-reader ()
 749   "Send the MODE READER command to the nntp server.
 750 This function is supposed to be called from `nntp-server-opened-hook'.
 751 It will make innd servers spawn an nnrpd process to allow actual article
 752 reading."
 753   (nntp-send-command "^.*\n" "MODE READER"))
 754
 755 (defun nntp-send-authinfo (&optional send-if-force)
 756   "Send the AUTHINFO to the nntp server.
 757 It will look in the \"~/.authinfo\" file for matching entries.  If
 758 nothing suitable is found there, it will prompt for a user name
 759 and a password.
 760
 761 If SEND-IF-FORCE, only send authinfo to the server if the
 762 .authinfo file has the FORCE token."
 763   (let* ((list (gnus-parse-netrc nntp-authinfo-file))
 764          (alist (gnus-netrc-machine list nntp-address))
 765          (force (gnus-netrc-get alist "force"))
 766          (user (or (gnus-netrc-get alist "login") nntp-authinfo-user))
 767          (passwd (gnus-netrc-get alist "password")))
 768     (when (or (not send-if-force)
 769               force)
 770       (unless user
 771         (setq user (read-string (format "NNTP (%s) user name: " nntp-address))
 772               nntp-authinfo-user user))
 773       (unless (member user '(nil ""))
 774         (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" user)
 775         (when t                         ;???Should check if AUTHINFO succeeded
 776       (nntp-send-command
 777        "^2.*\r?\n" "AUTHINFO PASS"
 778        (or passwd
 779            nntp-authinfo-password
 780            (setq nntp-authinfo-password
 781                      (nnmail-read-passwd (format "NNTP (%s@%s) password: "
 782                                                  user nntp-address))))))))))
 783
 784 (defun nntp-send-nosy-authinfo ()
 785   "Send the AUTHINFO to the nntp server."
 786   (let ((user (read-string (format "NNTP (%s) user name: " nntp-address))))
 787     (unless (member user '(nil ""))
 788       (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" user)
 789       (when t                           ;???Should check if AUTHINFO succeeded
 790         (nntp-send-command "^2.*\r?\n" "AUTHINFO PASS"
 791                            (nnmail-read-passwd "NNTP (%s@%s) password: "
 792                                                user nntp-address))))))
 793
 794 (defun nntp-send-authinfo-from-file ()
 795   "Send the AUTHINFO to the nntp server.
 796
 797 The authinfo login name is taken from the user's login name and the
 798 password contained in '~/.nntp-authinfo'."
 799   (when (file-exists-p "~/.nntp-authinfo")
 800     (with-temp-buffer
 801       (insert-file-contents "~/.nntp-authinfo")
 802       (goto-char (point-min))
 803       (nntp-send-command "^3.*\r?\n" "AUTHINFO USER" (user-login-name))
 804       (nntp-send-command
 805        "^2.*\r?\n" "AUTHINFO PASS"
 806        (buffer-substring (point) (progn (end-of-line) (point)))))))
 807
 808 ;;; Internal functions.
 809
 810 (defun nntp-handle-authinfo (process)
 811   "Take care of an authinfo response from the server."
 812   (let ((last nntp-last-command))
 813     (funcall nntp-authinfo-function)
 814     ;; We have to re-send the function that was interrupted by
 815     ;; the authinfo request.
 816     (save-excursion
 817       (set-buffer nntp-server-buffer)
 818       (erase-buffer))
 819     (nntp-send-string process last)))
 820
 821 (defun nntp-make-process-buffer (buffer)
 822   "Create a new, fresh buffer usable for nntp process connections."
 823   (save-excursion
 824     (set-buffer
 825      (generate-new-buffer
 826       (format " *server %s %s %s*"
 827               nntp-address nntp-port-number
 828               (gnus-buffer-exists-p buffer))))
 829     (set (make-local-variable 'after-change-functions) nil)
 830     (set (make-local-variable 'nntp-process-wait-for) nil)
 831     (set (make-local-variable 'nntp-process-callback) nil)
 832     (set (make-local-variable 'nntp-process-to-buffer) nil)
 833     (set (make-local-variable 'nntp-process-start-point) nil)
 834     (set (make-local-variable 'nntp-process-decode) nil)
 835     (current-buffer)))
 836
 837 (defun nntp-open-connection (buffer)
 838   "Open a connection to PORT on ADDRESS delivering output to BUFFER."
 839   (run-hooks 'nntp-prepare-server-hook)
 840   (let* ((pbuffer (nntp-make-process-buffer buffer))
 841          (timer
 842           (and nntp-connection-timeout
 843                (nnheader-run-at-time
 844                 nntp-connection-timeout nil
 845                 `(lambda ()
 846                    (when (buffer-name ,pbuffer)
 847                      (kill-buffer ,pbuffer))))))
 848          (process
 849           (condition-case ()
 850               (let ((coding-system-for-read nntp-coding-system-for-read)
 851                     (coding-system-for-write nntp-coding-system-for-write))
 852                 (funcall nntp-open-connection-function pbuffer))
 853             (error nil)
 854             (quit nil))))
 855     (when timer
 856       (nnheader-cancel-timer timer))
 857     (when (and (buffer-name pbuffer)
 858                process)
 859       (process-kill-without-query process)
 860       (nntp-wait-for process "^.*\n" buffer nil t)
 861       (if (memq (process-status process) '(open run))
 862           (prog1
 863               (caar (push (list process buffer nil) nntp-connection-alist))
 864             (push process nntp-connection-list)
 865             (save-excursion
 866               (set-buffer pbuffer)
 867               (nntp-read-server-type)
 868               (erase-buffer)
 869               (set-buffer nntp-server-buffer)
 870               (let ((nnheader-callback-function nil))
 871                 (run-hooks 'nntp-server-opened-hook)
 872                 (nntp-send-authinfo t))))
 873         (when (buffer-name (process-buffer process))
 874           (kill-buffer (process-buffer process)))
 875         nil))))
 876
 877 (defun nntp-open-network-stream (buffer)
 878   (open-network-stream "nntpd" buffer nntp-address nntp-port-number))
 879
 880 (defun nntp-open-ssl-stream (buffer)
 881   (let* ((ssl-program-arguments '("-connect" (concat host ":" service)))
 882          (proc (open-ssl-stream "nntpd" buffer nntp-address nntp-port-number)))
 883     (save-excursion
 884       (set-buffer buffer)
 885       (nntp-wait-for-string "^\r*20[01]")
 886       (beginning-of-line)
 887       (delete-region (point-min) (point))
 888       proc)))
 889
 890 (defun nntp-read-server-type ()
 891   "Find out what the name of the server we have connected to is."
 892   ;; Wait for the status string to arrive.
 893   (setq nntp-server-type (buffer-string))
 894   (let ((alist nntp-server-action-alist)
 895         (case-fold-search t)
 896         entry)
 897     ;; Run server-specific commands.
 898     (while alist
 899       (setq entry (pop alist))
 900       (when (string-match (car entry) nntp-server-type)
 901         (if (and (listp (cadr entry))
 902                  (not (eq 'lambda (caadr entry))))
 903             (eval (cadr entry))
 904           (funcall (cadr entry)))))))
 905
 906 (defun nntp-after-change-function-callback (beg end len)
 907   (unwind-protect
 908       (when nntp-process-callback
 909         (save-match-data
 910           (if (and (= beg (point-min))
 911                    (memq (char-after beg) '(?4 ?5)))
 912               ;; Report back error messages.
 913               (save-excursion
 914                 (goto-char beg)
 915                 (if (looking-at "480")
 916                     (nntp-handle-authinfo nntp-process-to-buffer)
 917                   (nntp-snarf-error-message)
 918                   (funcall nntp-process-callback nil)))
 919             (goto-char end)
 920             (when (and (> (point) nntp-process-start-point)
 921                        (re-search-backward nntp-process-wait-for
 922                                            nntp-process-start-point t))
 923               (when (gnus-buffer-exists-p nntp-process-to-buffer)
 924                 (let ((cur (current-buffer))
 925                       (start nntp-process-start-point))
 926                   (save-excursion
 927                     (set-buffer nntp-process-to-buffer)
 928                     (goto-char (point-max))
 929                     (let ((b (point)))
 930                       (insert-buffer-substring cur start)
 931                       (narrow-to-region b (point-max))
 932                       (nntp-decode-text)
 933                       (widen)))))
 934               (goto-char end)
 935               (let ((callback nntp-process-callback)
 936                     (nntp-inside-change-function t))
 937                 (setq nntp-process-callback nil)
 938                 (save-excursion
 939                   (funcall callback (buffer-name
 940                                      (get-buffer nntp-process-to-buffer)))))))))
 941
 942     ;; any throw from after-change-functions will leave it
 943     ;; set to nil.  so we reset it here, if necessary.
 944     (when quit-flag
 945       (setq after-change-functions
 946             (list 'nntp-after-change-function-callback)))))
 947
 948 (defun nntp-snarf-error-message ()
 949   "Save the error message in the current buffer."
 950   (let ((message (buffer-string)))
 951     (while (string-match "[\r\n]+" message)
 952       (setq message (replace-match " " t t message)))
 953     (nnheader-report 'nntp message)
 954     message))
 955
 956 (defun nntp-accept-process-output (process)
 957   "Wait for output from PROCESS and message some dots."
 958   (save-excursion
 959     (set-buffer (or (nntp-find-connection-buffer nntp-server-buffer)
 960                     nntp-server-buffer))
 961     (let ((len (/ (point-max) 1024))
 962           message-log-max)
 963       (unless (< len 10)
 964         (setq nntp-have-messaged t)
 965         (nnheader-message 7 "nntp read: %dk" len)))
 966     (accept-process-output process 1)))
 967
 968 (defun nntp-accept-response ()
 969   "Wait for output from the process that outputs to BUFFER."
 970   (nntp-accept-process-output (nntp-find-connection nntp-server-buffer)))
 971
 972 (defun nntp-possibly-change-group (group server &optional connectionless)
 973   (let ((nnheader-callback-function nil))
 974     (when server
 975       (or (nntp-server-opened server)
 976           (nntp-open-server server nil connectionless)))
 977
 978     (unless connectionless
 979       (or (nntp-find-connection nntp-server-buffer)
 980           (nntp-open-connection nntp-server-buffer))))
 981
 982   (when group
 983     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 984       (when (not (equal group (caddr entry)))
 985         (save-excursion
 986           (set-buffer (process-buffer (car entry)))
 987           (erase-buffer)
 988           (nntp-send-string (car entry) (concat "GROUP " group))
 989           ;; allow for unexpected responses, since this can be called
 990           ;; from a timer with quit inhibited
 991           (nntp-wait-for-string "^[245].*\n")
 992           (setcar (cddr entry) group)
 993           (erase-buffer))))))
 994
 995 (defun nntp-decode-text (&optional cr-only)
 996   "Decode the text in the current buffer."
 997   (goto-char (point-min))
 998   (while (search-forward "\r" nil t)
 999     (delete-char -1))
1000   (unless cr-only
1001     ;; Remove trailing ".\n" end-of-transfer marker.
1002     (goto-char (point-max))
1003     (forward-line -1)
1004     (when (looking-at ".\n")
1005       (delete-char 2))
1006     ;; Delete status line.
1007     (goto-char (point-min))
1008     (delete-region (point) (progn (forward-line 1) (point)))
1009     ;; Remove "." -> ".." encoding.
1010     (while (search-forward "\n.." nil t)
1011       (delete-char -1))))
1012
1013 (defun nntp-encode-text ()
1014   "Encode the text in the current buffer."
1015   (save-excursion
1016     ;; Replace "." at beginning of line with "..".
1017     (goto-char (point-min))
1018     (while (re-search-forward "^\\." nil t)
1019       (insert "."))
1020     (goto-char (point-max))
1021     ;; Insert newline at the end of the buffer.
1022     (unless (bolp)
1023       (insert "\n"))
1024     ;; Insert `.' at end of buffer (end of text mark).
1025     (goto-char (point-max))
1026     (insert ".\n")
1027     (goto-char (point-min))
1028     (while (not (eobp))
1029       (end-of-line)
1030       (delete-char 1)
1031       (insert nntp-end-of-line))))
1032
1033 (defun nntp-retrieve-headers-with-xover (articles &optional fetch-old)
1034   (set-buffer nntp-server-buffer)
1035   (erase-buffer)
1036   (cond
1037
1038    ;; This server does not talk NOV.
1039    ((not nntp-server-xover)
1040     nil)
1041
1042    ;; We don't care about gaps.
1043    ((or (not nntp-nov-gap)
1044         fetch-old)
1045     (nntp-send-xover-command
1046      (if fetch-old
1047          (if (numberp fetch-old)
1048              (max 1 (- (car articles) fetch-old))
1049            1)
1050        (car articles))
1051      (car (last articles)) 'wait)
1052
1053     (goto-char (point-min))
1054     (when (looking-at "[1-5][0-9][0-9] ")
1055       (delete-region (point) (progn (forward-line 1) (point))))
1056     (while (search-forward "\r" nil t)
1057       (replace-match "" t t))
1058     (goto-char (point-max))
1059     (forward-line -1)
1060     (when (looking-at "\\.")
1061       (delete-region (point) (progn (forward-line 1) (point)))))
1062
1063    ;; We do it the hard way.  For each gap, an XOVER command is sent
1064    ;; to the server.  We do not wait for a reply from the server, we
1065    ;; just send them off as fast as we can.  That means that we have
1066    ;; to count the number of responses we get back to find out when we
1067    ;; have gotten all we asked for.
1068    ((numberp nntp-nov-gap)
1069     (let ((count 0)
1070           (received 0)
1071           (last-point (point-min))
1072           (buf nntp-server-buffer)
1073           ;;(process-buffer (nntp-find-connection (current-buffer))))
1074           first)
1075       ;; We have to check `nntp-server-xover'.  If it gets set to nil,
1076       ;; that means that the server does not understand XOVER, but we
1077       ;; won't know that until we try.
1078       (while (and nntp-server-xover articles)
1079         (setq first (car articles))
1080         ;; Search forward until we find a gap, or until we run out of
1081         ;; articles.
1082         (while (and (cdr articles)
1083                     (< (- (nth 1 articles) (car articles)) nntp-nov-gap))
1084           (setq articles (cdr articles)))
1085
1086         (when (nntp-send-xover-command first (car articles))
1087           (setq articles (cdr articles)
1088                 count (1+ count))
1089
1090           ;; Every 400 requests we have to read the stream in
1091           ;; order to avoid deadlocks.
1092           (when (or (null articles)     ;All requests have been sent.
1093                     (zerop (% count nntp-maximum-request)))
1094             (accept-process-output)
1095             ;; On some Emacs versions the preceding function has
1096             ;; a tendency to change the buffer.  Perhaps.  It's
1097             ;; quite difficult to reproduce, because it only
1098             ;; seems to happen once in a blue moon.
1099             (set-buffer buf)
1100             (while (progn
1101                      (goto-char last-point)
1102                      ;; Count replies.
1103                      (while (re-search-forward "^[0-9][0-9][0-9] " nil t)
1104                        (setq received (1+ received)))
1105                      (setq last-point (point))
1106                      (< received count))
1107               (accept-process-output)
1108               (set-buffer buf)))))
1109
1110       (when nntp-server-xover
1111         ;; Wait for the reply from the final command.
1112         (goto-char (point-max))
1113         (re-search-backward "^[0-9][0-9][0-9] " nil t)
1114         (when (looking-at "^[23]")
1115           (while (progn
1116                    (goto-char (point-max))
1117                    (forward-line -1)
1118                    (not (looking-at "^\\.\r?\n")))
1119             (nntp-accept-response)))
1120
1121         ;; We remove any "." lines and status lines.
1122         (goto-char (point-min))
1123         (while (search-forward "\r" nil t)
1124           (delete-char -1))
1125         (goto-char (point-min))
1126         (delete-matching-lines "^\\.$\\|^[1-5][0-9][0-9] ")
1127         t))))
1128
1129   nntp-server-xover)
1130
1131 (defun nntp-send-xover-command (beg end &optional wait-for-reply)
1132   "Send the XOVER command to the server."
1133   (let ((range (format "%d-%d" beg end))
1134         (nntp-inhibit-erase t))
1135     (if (stringp nntp-server-xover)
1136         ;; If `nntp-server-xover' is a string, then we just send this
1137         ;; command.
1138         (if wait-for-reply
1139             (nntp-send-command-nodelete
1140              "\r?\n\\.\r?\n" nntp-server-xover range)
1141           ;; We do not wait for the reply.
1142           (nntp-send-command-nodelete "\r?\n\\.\r?\n" nntp-server-xover range))
1143       (let ((commands nntp-xover-commands))
1144         ;; `nntp-xover-commands' is a list of possible XOVER commands.
1145         ;; We try them all until we get at positive response.
1146         (while (and commands (eq nntp-server-xover 'try))
1147           (nntp-send-command-nodelete "\r?\n\\.\r?\n" (car commands) range)
1148           (save-excursion
1149             (set-buffer nntp-server-buffer)
1150             (goto-char (point-min))
1151             (and (looking-at "[23]")    ; No error message.
1152                  ;; We also have to look at the lines.  Some buggy
1153                  ;; servers give back simple lines with just the
1154                  ;; article number.  How... helpful.
1155                  (progn
1156                    (forward-line 1)
1157                    (looking-at "[0-9]+\t...")) ; More text after number.
1158                  (setq nntp-server-xover (car commands))))
1159           (setq commands (cdr commands)))
1160         ;; If none of the commands worked, we disable XOVER.
1161         (when (eq nntp-server-xover 'try)
1162           (save-excursion
1163             (set-buffer nntp-server-buffer)
1164             (erase-buffer)
1165             (setq nntp-server-xover nil)))
1166         nntp-server-xover))))
1167
1168 ;;; Alternative connection methods.
1169
1170 (defun nntp-wait-for-string (regexp)
1171   "Wait until string arrives in the buffer."
1172   (let ((buf (current-buffer)))
1173     (goto-char (point-min))
1174     (while (not (re-search-forward regexp nil t))
1175       (accept-process-output (nntp-find-connection nntp-server-buffer))
1176       (set-buffer buf)
1177       (goto-char (point-min)))))
1178
1179 (defun nntp-open-telnet (buffer)
1180   (save-excursion
1181     (set-buffer buffer)
1182     (erase-buffer)
1183     (let ((proc (apply
1184                  'start-process
1185                  "nntpd" buffer nntp-telnet-command nntp-telnet-switches))
1186           (case-fold-search t))
1187       (when (memq (process-status proc) '(open run))
1188         (process-send-string proc "set escape \^X\n")
1189         (cond
1190          ((and nntp-open-telnet-envuser nntp-telnet-user-name)
1191           (process-send-string proc (concat "open " "-l" nntp-telnet-user-name
1192                                             nntp-address "\n")))
1193          (t
1194           (process-send-string proc (concat "open " nntp-address "\n"))))
1195         (cond
1196          ((not nntp-open-telnet-envuser)
1197           (nntp-wait-for-string "^\r*.?login:")
1198           (process-send-string
1199            proc (concat
1200                  (or nntp-telnet-user-name
1201                      (setq nntp-telnet-user-name (read-string "login: ")))
1202                  "\n"))))
1203         (nntp-wait-for-string "^\r*.?password:")
1204         (process-send-string
1205          proc (concat
1206                (or nntp-telnet-passwd
1207                    (setq nntp-telnet-passwd
1208                          (nnmail-read-passwd "Password: ")))
1209                "\n"))
1210         (erase-buffer)
1211         (nntp-wait-for-string nntp-telnet-shell-prompt)
1212         (process-send-string
1213          proc (concat (mapconcat 'identity nntp-telnet-parameters " ") "\n"))
1214         (nntp-wait-for-string "^\r*20[01]")
1215         (beginning-of-line)
1216         (delete-region (point-min) (point))
1217         (process-send-string proc "\^]")
1218         (nntp-wait-for-string "^telnet")
1219         (process-send-string proc "mode character\n")
1220         (accept-process-output proc 1)
1221         (sit-for 1)
1222         (goto-char (point-min))
1223         (forward-line 1)
1224         (delete-region (point) (point-max)))
1225       proc)))
1226
1227 (defun nntp-open-rlogin (buffer)
1228   "Open a connection to SERVER using rsh."
1229   (let ((proc (if nntp-rlogin-user-name
1230                   (apply 'start-process
1231                          "nntpd" buffer nntp-rlogin-program
1232                          nntp-address "-l" nntp-rlogin-user-name
1233                          nntp-rlogin-parameters)
1234                 (apply 'start-process
1235                        "nntpd" buffer nntp-rlogin-program nntp-address
1236                        nntp-rlogin-parameters))))
1237     (save-excursion
1238       (set-buffer buffer)
1239       (nntp-wait-for-string "^\r*20[01]")
1240       (beginning-of-line)
1241       (delete-region (point-min) (point))
1242       proc)))
1243
1244 (defun nntp-find-group-and-number ()
1245   (save-excursion
1246     (save-restriction
1247       (set-buffer nntp-server-buffer)
1248       (narrow-to-region (goto-char (point-min))
1249                         (or (search-forward "\n\n" nil t) (point-max)))
1250       (goto-char (point-min))
1251       ;; We first find the number by looking at the status line.
1252       (let ((number (and (looking-at "2[0-9][0-9] +\\([0-9]+\\) ")
1253                          (string-to-int
1254                           (buffer-substring (match-beginning 1)
1255                                             (match-end 1)))))
1256             group newsgroups xref)
1257         (and number (zerop number) (setq number nil))
1258         ;; Then we find the group name.
1259         (setq group
1260               (cond
1261                ;; If there is only one group in the Newsgroups header,
1262                ;; then it seems quite likely that this article comes
1263                ;; from that group, I'd say.
1264                ((and (setq newsgroups (mail-fetch-field "newsgroups"))
1265                      (not (string-match "," newsgroups)))
1266                 newsgroups)
1267                ;; If there is more than one group in the Newsgroups
1268                ;; header, then the Xref header should be filled out.
1269                ;; We hazard a guess that the group that has this
1270                ;; article number in the Xref header is the one we are
1271                ;; looking for.  This might very well be wrong if this
1272                ;; article happens to have the same number in several
1273                ;; groups, but that's life.
1274                ((and (setq xref (mail-fetch-field "xref"))
1275                      number
1276                      (string-match (format "\\([^ :]+\\):%d" number) xref))
1277                 (substring xref (match-beginning 1) (match-end 1)))
1278                (t "")))
1279         (when (string-match "\r" group)
1280           (setq group (substring group 0 (match-beginning 0))))
1281         (cons group number)))))
1282
1283 (provide 'nntp)
1284
1285 ;;; nntp.el ends here