git.chise.org Git - elisp/gnus.git-/blob - lisp/nnweb.el

   1 ;;; nnweb.el --- retrieving articles via web search engines
   2 ;; Copyright (C) 1996,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Note: You need to have `url' and `w3' installed for this
  27 ;; backend to work.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'nnoo)
  33 (require 'message)
  34 (require 'gnus-util)
  35 (require 'gnus)
  36 (require 'nnmail)
  37 (eval-when-compile
  38   (ignore-errors
  39     (require 'w3)
  40     (require 'url)
  41     (require 'w3-forms)))
  42 ;; Report failure to find w3 at load time if appropriate.
  43 (eval '(progn
  44          (require 'w3)
  45          (require 'url)
  46          (require 'w3-forms)))
  47
  48 (nnoo-declare nnweb)
  49
  50 (defvoo nnweb-directory (nnheader-concat gnus-directory "nnweb/")
  51   "Where nnweb will save its files.")
  52
  53 (defvoo nnweb-type 'dejanews
  54   "What search engine type is being used.
  55 Valid types include `dejanews', `dejanewsold', `reference',
  56 and `altavista'.")
  57
  58 (defvar nnweb-type-definition
  59   '((dejanews
  60      (article . ignore)
  61      (id . "http://search.dejanews.com/msgid.xp?MID=%s&fmt=text")
  62      (map . nnweb-dejanews-create-mapping)
  63      (search . nnweb-dejanews-search)
  64      (address . "http://www.deja.com/=dnc/qs.xp")
  65      (identifier . nnweb-dejanews-identity))
  66     (dejanewsold
  67      (article . ignore)
  68      (map . nnweb-dejanews-create-mapping)
  69      (search . nnweb-dejanewsold-search)
  70      (address . "http://www.deja.com/dnquery.xp")
  71      (identifier . nnweb-dejanews-identity))
  72     (reference
  73      (article . nnweb-reference-wash-article)
  74      (map . nnweb-reference-create-mapping)
  75      (search . nnweb-reference-search)
  76      (address . "http://www.reference.com/cgi-bin/pn/go")
  77      (identifier . identity))
  78     (altavista
  79      (article . nnweb-altavista-wash-article)
  80      (map . nnweb-altavista-create-mapping)
  81      (search . nnweb-altavista-search)
  82      (address . "http://www.altavista.digital.com/cgi-bin/query")
  83      (id . "/cgi-bin/news?id@%s")
  84      (identifier . identity)))
  85   "Type-definition alist.")
  86
  87 (defvoo nnweb-search nil
  88   "Search string to feed to DejaNews.")
  89
  90 (defvoo nnweb-max-hits 999
  91   "Maximum number of hits to display.")
  92
  93 (defvoo nnweb-ephemeral-p nil
  94   "Whether this nnweb server is ephemeral.")
  95
  96 ;;; Internal variables
  97
  98 (defvoo nnweb-articles nil)
  99 (defvoo nnweb-buffer nil)
 100 (defvoo nnweb-group-alist nil)
 101 (defvoo nnweb-group nil)
 102 (defvoo nnweb-hashtb nil)
 103
 104 ;;; Interface functions
 105
 106 (nnoo-define-basics nnweb)
 107
 108 (deffoo nnweb-retrieve-headers (articles &optional group server fetch-old)
 109   (nnweb-possibly-change-server group server)
 110   (save-excursion
 111     (set-buffer nntp-server-buffer)
 112     (erase-buffer)
 113     (let (article header)
 114       (mm-with-unibyte-current-buffer
 115         (while (setq article (pop articles))
 116           (when (setq header (cadr (assq article nnweb-articles)))
 117             (nnheader-insert-nov header))))
 118       'nov)))
 119
 120 (deffoo nnweb-request-scan (&optional group server)
 121   (nnweb-possibly-change-server group server)
 122   (setq nnweb-hashtb (gnus-make-hashtable 4095))
 123   (funcall (nnweb-definition 'map))
 124   (unless nnweb-ephemeral-p
 125     (nnweb-write-active)
 126     (nnweb-write-overview group)))
 127
 128 (deffoo nnweb-request-group (group &optional server dont-check)
 129   (nnweb-possibly-change-server nil server)
 130   (when (and group
 131              (not (equal group nnweb-group))
 132              (not nnweb-ephemeral-p))
 133     (let ((info (assoc group nnweb-group-alist)))
 134       (when info
 135         (setq nnweb-group group)
 136         (setq nnweb-type (nth 2 info))
 137         (setq nnweb-search (nth 3 info))
 138         (unless dont-check
 139           (nnweb-read-overview group)))))
 140   (unless dont-check
 141     (nnweb-request-scan group))
 142   (cond
 143    ((not nnweb-articles)
 144     (nnheader-report 'nnweb "No matching articles"))
 145    (t
 146     (let ((active (if nnweb-ephemeral-p
 147                       (cons (caar nnweb-articles)
 148                             (caar (last nnweb-articles)))
 149                     (cadr (assoc group nnweb-group-alist)))))
 150       (nnheader-report 'nnweb "Opened group %s" group)
 151       (nnheader-insert
 152        "211 %d %d %d %s\n" (length nnweb-articles)
 153        (car active) (cdr active) group)))))
 154
 155 (deffoo nnweb-close-group (group &optional server)
 156   (nnweb-possibly-change-server group server)
 157   (when (gnus-buffer-live-p nnweb-buffer)
 158     (save-excursion
 159       (set-buffer nnweb-buffer)
 160       (set-buffer-modified-p nil)
 161       (kill-buffer nnweb-buffer)))
 162   t)
 163
 164 (deffoo nnweb-request-article (article &optional group server buffer)
 165   (nnweb-possibly-change-server group server)
 166   (save-excursion
 167     (set-buffer (or buffer nntp-server-buffer))
 168     (let* ((header (cadr (assq article nnweb-articles)))
 169            (url (and header (mail-header-xref header))))
 170       (when (or (and url
 171                      (mm-with-unibyte-current-buffer
 172                        (nnweb-fetch-url url)))
 173                 (and (stringp article)
 174                      (nnweb-definition 'id t)
 175                      (let ((fetch (nnweb-definition 'id))
 176                            art)
 177                        (when (string-match "^<\\(.*\\)>$" article)
 178                          (setq art (match-string 1 article)))
 179                        (and fetch
 180                             art
 181                             (mm-with-unibyte-current-buffer
 182                               (nnweb-fetch-url
 183                                (format fetch article)))))))
 184         (unless nnheader-callback-function
 185           (funcall (nnweb-definition 'article))
 186           (nnweb-decode-entities))
 187         (nnheader-report 'nnweb "Fetched article %s" article)
 188         t))))
 189
 190 (deffoo nnweb-close-server (&optional server)
 191   (when (and (nnweb-server-opened server)
 192              (gnus-buffer-live-p nnweb-buffer))
 193     (save-excursion
 194       (set-buffer nnweb-buffer)
 195       (set-buffer-modified-p nil)
 196       (kill-buffer nnweb-buffer)))
 197   (nnoo-close-server 'nnweb server))
 198
 199 (deffoo nnweb-request-list (&optional server)
 200   (nnweb-possibly-change-server nil server)
 201   (save-excursion
 202     (set-buffer nntp-server-buffer)
 203     (nnmail-generate-active nnweb-group-alist)
 204     t))
 205
 206 (deffoo nnweb-request-update-info (group info &optional server)
 207   (nnweb-possibly-change-server group server)
 208   ;;(setcar (cddr info) nil)
 209   )
 210
 211 (deffoo nnweb-asynchronous-p ()
 212   t)
 213
 214 (deffoo nnweb-request-create-group (group &optional server args)
 215   (nnweb-possibly-change-server nil server)
 216   (nnweb-request-delete-group group)
 217   (push `(,group ,(cons 1 0) ,@args) nnweb-group-alist)
 218   (nnweb-write-active)
 219   t)
 220
 221 (deffoo nnweb-request-delete-group (group &optional force server)
 222   (nnweb-possibly-change-server group server)
 223   (gnus-pull group nnweb-group-alist t)
 224   (nnweb-write-active)
 225   (gnus-delete-file (nnweb-overview-file group))
 226   t)
 227
 228 (nnoo-define-skeleton nnweb)
 229
 230 ;;; Internal functions
 231
 232 (defun nnweb-read-overview (group)
 233   "Read the overview of GROUP and build the map."
 234   (when (file-exists-p (nnweb-overview-file group))
 235     (mm-with-unibyte-buffer
 236       (nnheader-insert-file-contents (nnweb-overview-file group))
 237       (goto-char (point-min))
 238       (let (header)
 239         (while (not (eobp))
 240           (setq header (nnheader-parse-nov))
 241           (forward-line 1)
 242           (push (list (mail-header-number header)
 243                       header (mail-header-xref header))
 244                 nnweb-articles)
 245           (nnweb-set-hashtb header (car nnweb-articles)))))))
 246
 247 (defun nnweb-write-overview (group)
 248   "Write the overview file for GROUP."
 249   (with-temp-file (nnweb-overview-file group)
 250     (let ((articles nnweb-articles))
 251       (while articles
 252         (nnheader-insert-nov (cadr (pop articles)))))))
 253
 254 (defun nnweb-set-hashtb (header data)
 255   (gnus-sethash (nnweb-identifier (mail-header-xref header))
 256                 data nnweb-hashtb))
 257
 258 (defun nnweb-get-hashtb (url)
 259   (gnus-gethash (nnweb-identifier url) nnweb-hashtb))
 260
 261 (defun nnweb-identifier (ident)
 262   (funcall (nnweb-definition 'identifier) ident))
 263
 264 (defun nnweb-overview-file (group)
 265   "Return the name of the overview file of GROUP."
 266   (nnheader-concat nnweb-directory group ".overview"))
 267
 268 (defun nnweb-write-active ()
 269   "Save the active file."
 270   (gnus-make-directory nnweb-directory)
 271   (with-temp-file (nnheader-concat nnweb-directory "active")
 272     (prin1 `(setq nnweb-group-alist ',nnweb-group-alist) (current-buffer))))
 273
 274 (defun nnweb-read-active ()
 275   "Read the active file."
 276   (load (nnheader-concat nnweb-directory "active") t t t))
 277
 278 (defun nnweb-definition (type &optional noerror)
 279   "Return the definition of TYPE."
 280   (let ((def (cdr (assq type (assq nnweb-type nnweb-type-definition)))))
 281     (when (and (not def)
 282                (not noerror))
 283       (error "Undefined definition %s" type))
 284     def))
 285
 286 (defun nnweb-possibly-change-server (&optional group server)
 287   (nnweb-init server)
 288   (when server
 289     (unless (nnweb-server-opened server)
 290       (nnweb-open-server server)))
 291   (unless nnweb-group-alist
 292     (nnweb-read-active))
 293   (when group
 294     (when (and (not nnweb-ephemeral-p)
 295                (not (equal group nnweb-group)))
 296       (nnweb-request-group group nil t))))
 297
 298 (defun nnweb-init (server)
 299   "Initialize buffers and such."
 300   (unless (gnus-buffer-live-p nnweb-buffer)
 301     (setq nnweb-buffer
 302           (save-excursion
 303             (let ((multibyte (default-value 'enable-multibyte-characters)))
 304               (unwind-protect
 305                   (progn
 306                     (setq-default enable-multibyte-characters nil)
 307                     (nnheader-set-temp-buffer
 308                      (format " *nnweb %s %s %s*"
 309                              nnweb-type nnweb-search server)))
 310                 (setq-default enable-multibyte-characters multibyte))
 311               (current-buffer))))))
 312
 313 (defun nnweb-fetch-url (url)
 314   (let (buf)
 315     (save-excursion
 316       (if (not nnheader-callback-function)
 317           (progn
 318             (with-temp-buffer
 319               (mm-enable-multibyte)
 320               (let ((coding-system-for-read 'binary)
 321                     (coding-system-for-write 'binary)
 322                     (default-process-coding-system 'binary))
 323                 (nnweb-insert url))
 324               (setq buf (buffer-string)))
 325             (erase-buffer)
 326             (insert buf)
 327             t)
 328         (nnweb-url-retrieve-asynch
 329          url 'nnweb-callback (current-buffer) nnheader-callback-function)
 330         t))))
 331
 332 (defun nnweb-callback (buffer callback)
 333   (when (gnus-buffer-live-p url-working-buffer)
 334     (save-excursion
 335       (set-buffer url-working-buffer)
 336       (funcall (nnweb-definition 'article))
 337       (nnweb-decode-entities)
 338       (set-buffer buffer)
 339       (goto-char (point-max))
 340       (insert-buffer-substring url-working-buffer))
 341     (funcall callback t)
 342     (gnus-kill-buffer url-working-buffer)))
 343
 344 (defun nnweb-url-retrieve-asynch (url callback &rest data)
 345   (let ((url-request-method "GET")
 346         (old-asynch url-be-asynchronous)
 347         (url-request-data nil)
 348         (url-request-extra-headers nil)
 349         (url-working-buffer (generate-new-buffer-name " *nnweb*")))
 350     (setq-default url-be-asynchronous t)
 351     (save-excursion
 352       (set-buffer (get-buffer-create url-working-buffer))
 353       (setq url-current-callback-data data
 354             url-be-asynchronous t
 355             url-current-callback-func callback)
 356       (url-retrieve url))
 357     (setq-default url-be-asynchronous old-asynch)))
 358
 359 ;;;
 360 ;;; DejaNews functions.
 361 ;;;
 362
 363 (defun nnweb-dejanews-create-mapping ()
 364   "Perform the search and create an number-to-url alist."
 365   (save-excursion
 366     (set-buffer nnweb-buffer)
 367     (erase-buffer)
 368     (when (funcall (nnweb-definition 'search) nnweb-search)
 369       (let ((i 0)
 370             (more t)
 371             (case-fold-search t)
 372             (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 373                         (cons 1 0)))
 374             subject date from
 375             map url parse a table group text)
 376         (while more
 377           ;; Go through all the article hits on this page.
 378           (goto-char (point-min))
 379           (setq parse (w3-parse-buffer (current-buffer))
 380                 table (nth 1 (nnweb-parse-find-all 'table parse)))
 381           (dolist (row (nth 2 (car (nth 2 table))))
 382             (setq a (nnweb-parse-find 'a row)
 383                   url (cdr (assq 'href (nth 1 a)))
 384                   text (nreverse (nnweb-text row)))
 385             (when a
 386               (setq subject (nth 4 text)
 387                     group (nth 2 text)
 388                     date (nth 1 text)
 389                     from (nth 0 text))
 390               (if (string-match "\\([0-9]+\\)/\\([0-9]+\\)/\\([0-9]+\\)" date)
 391                   (setq date (format "%s %s 00:00:00 %s"
 392                                      (car (rassq (string-to-number
 393                                                   (match-string 2 date))
 394                                                  parse-time-months))
 395                                      (match-string 3 date)
 396                                      (match-string 1 date)))
 397                 (setq date "Jan 1 00:00:00 0000"))
 398               (incf i)
 399               (setq url (concat url "&fmt=text"))
 400               (unless (nnweb-get-hashtb url)
 401                 (push
 402                  (list
 403                   (incf (cdr active))
 404                   (make-full-mail-header
 405                    (cdr active) (concat subject " (" group ")") from date
 406                    (concat "<" (nnweb-identifier url) "@dejanews>")
 407                    nil 0 0 url))
 408                  map)
 409                 (nnweb-set-hashtb (cadar map) (car map)))))
 410           ;; See whether there is a "Get next 20 hits" button here.
 411           (goto-char (point-min))
 412           (if (or (not (re-search-forward
 413                         "HREF=\"\\([^\"]+\\)\"[<>b]+Next result" nil t))
 414                   (>= i nnweb-max-hits))
 415               (setq more nil)
 416             ;; Yup -- fetch it.
 417             (setq more (match-string 1))
 418             (erase-buffer)
 419             (url-insert-file-contents more)))
 420         ;; Return the articles in the right order.
 421         (setq nnweb-articles
 422               (sort (nconc nnweb-articles map) 'car-less-than-car))))))
 423
 424 (defun nnweb-dejanews-search (search)
 425   (nnweb-insert
 426    (concat
 427     (nnweb-definition 'address)
 428     "?"
 429     (nnweb-encode-www-form-urlencoded
 430      `(("ST" . "PS")
 431        ("svcclass" . "dnyr")
 432        ("QRY" . ,search)
 433        ("defaultOp" . "AND")
 434        ("DBS" . "1")
 435        ("OP" . "dnquery.xp")
 436        ("LNG" . "ALL")
 437        ("maxhits" . "100")
 438        ("threaded" . "0")
 439        ("format" . "verbose2")
 440        ("showsort" . "date")
 441        ("agesign" . "1")
 442        ("ageweight" . "1")))))
 443   t)
 444
 445 (defun nnweb-dejanewsold-search (search)
 446   (nnweb-fetch-form
 447    (nnweb-definition 'address)
 448    `(("query" . ,search)
 449      ("defaultOp" . "AND")
 450      ("svcclass" . "dnold")
 451      ("maxhits" . "100")
 452      ("format" . "verbose2")
 453      ("threaded" . "0")
 454      ("showsort" . "date")
 455      ("agesign" . "1")
 456      ("ageweight" . "1")))
 457   t)
 458
 459 (defun nnweb-dejanews-identity (url)
 460   "Return an unique identifier based on URL."
 461   (if (string-match "AN=\\([0-9]+\\)" url)
 462       (match-string 1 url)
 463     url))
 464
 465 ;;;
 466 ;;; InReference
 467 ;;;
 468
 469 (defun nnweb-reference-create-mapping ()
 470   "Perform the search and create an number-to-url alist."
 471   (save-excursion
 472     (set-buffer nnweb-buffer)
 473     (erase-buffer)
 474     (when (funcall (nnweb-definition 'search) nnweb-search)
 475       (let ((i 0)
 476             (more t)
 477             (case-fold-search t)
 478             (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 479                         (cons 1 0)))
 480             Subject Score Date Newsgroups From Message-ID
 481             map url)
 482         (while more
 483           ;; Go through all the article hits on this page.
 484           (goto-char (point-min))
 485           (search-forward "</pre><hr>" nil t)
 486           (delete-region (point-min) (point))
 487                                         ;(nnweb-decode-entities)
 488           (goto-char (point-min))
 489           (while (re-search-forward "^ +[0-9]+\\." nil t)
 490             (narrow-to-region
 491              (point)
 492              (if (re-search-forward "^$" nil t)
 493                  (match-beginning 0)
 494                (point-max)))
 495             (goto-char (point-min))
 496             (when (looking-at ".*href=\"\\([^\"]+\\)\"")
 497               (setq url (match-string 1)))
 498             (nnweb-remove-markup)
 499             (goto-char (point-min))
 500             (while (search-forward "\t" nil t)
 501               (replace-match " "))
 502             (goto-char (point-min))
 503             (while (re-search-forward "^\\([^:]+\\): \\(.*\\)$" nil t)
 504               (set (intern (match-string 1)) (match-string 2)))
 505             (widen)
 506             (search-forward "</pre>" nil t)
 507             (incf i)
 508             (unless (nnweb-get-hashtb url)
 509               (push
 510                (list
 511                 (incf (cdr active))
 512                 (make-full-mail-header
 513                  (cdr active) (concat  "(" Newsgroups ") " Subject) From Date
 514                  Message-ID
 515                  nil 0 (string-to-int Score) url))
 516                map)
 517               (nnweb-set-hashtb (cadar map) (car map))))
 518           (setq more nil))
 519         ;; Return the articles in the right order.
 520         (setq nnweb-articles
 521               (sort (nconc nnweb-articles map) 'car-less-than-car))))))
 522
 523 (defun nnweb-reference-wash-article ()
 524   (let ((case-fold-search t))
 525     (goto-char (point-min))
 526     (re-search-forward "^</center><hr>" nil t)
 527     (delete-region (point-min) (point))
 528     (search-forward "<pre>" nil t)
 529     (forward-line -1)
 530     (let ((body (point-marker)))
 531       (search-forward "</pre>" nil t)
 532       (delete-region (point) (point-max))
 533       (nnweb-remove-markup)
 534       (goto-char (point-min))
 535       (while (looking-at " *$")
 536         (gnus-delete-line))
 537       (narrow-to-region (point-min) body)
 538       (while (and (re-search-forward "^$" nil t)
 539                   (not (eobp)))
 540         (gnus-delete-line))
 541       (goto-char (point-min))
 542       (while (looking-at "\\(^[^ ]+:\\) *")
 543         (replace-match "\\1 " t)
 544         (forward-line 1))
 545       (goto-char (point-min))
 546       (when (re-search-forward "^References:" nil t)
 547         (narrow-to-region
 548          (point) (if (re-search-forward "^$\\|^[^:]+:" nil t)
 549                      (match-beginning 0)
 550                    (point-max)))
 551         (goto-char (point-min))
 552         (while (not (eobp))
 553           (unless (looking-at "References")
 554             (insert "\t")
 555             (forward-line 1)))
 556         (goto-char (point-min))
 557         (while (search-forward "," nil t)
 558           (replace-match " " t t)))
 559       (widen)
 560       (set-marker body nil))))
 561
 562 (defun nnweb-reference-search (search)
 563   (url-insert-file-contents
 564    (concat
 565     (nnweb-definition 'address)
 566     "?"
 567     (nnweb-encode-www-form-urlencoded
 568      `(("search" . "advanced")
 569        ("querytext" . ,search)
 570        ("subj" . "")
 571        ("name" . "")
 572        ("login" . "")
 573        ("host" . "")
 574        ("organization" . "")
 575        ("groups" . "")
 576        ("keywords" . "")
 577        ("choice" . "Search")
 578        ("startmonth" . "Jul")
 579        ("startday" . "25")
 580        ("startyear" . "1996")
 581        ("endmonth" . "Aug")
 582        ("endday" . "24")
 583        ("endyear" . "1996")
 584        ("mode" . "Quick")
 585        ("verbosity" . "Verbose")
 586        ("ranking" . "Relevance")
 587        ("first" . "1")
 588        ("last" . "25")
 589        ("score" . "50")))))
 590   (setq buffer-file-name nil)
 591   t)
 592
 593 ;;;
 594 ;;; Alta Vista
 595 ;;;
 596
 597 (defun nnweb-altavista-create-mapping ()
 598   "Perform the search and create an number-to-url alist."
 599   (save-excursion
 600     (set-buffer nnweb-buffer)
 601     (erase-buffer)
 602     (let ((part 0))
 603       (when (funcall (nnweb-definition 'search) nnweb-search part)
 604         (let ((i 0)
 605               (more t)
 606               (case-fold-search t)
 607               (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 608                           (cons 1 0)))
 609               subject date from id group
 610               map url)
 611           (while more
 612             ;; Go through all the article hits on this page.
 613             (goto-char (point-min))
 614             (search-forward "<dt>" nil t)
 615             (delete-region (point-min) (match-beginning 0))
 616             (goto-char (point-min))
 617             (while (search-forward "<dt>" nil t)
 618               (replace-match "\n<blubb>"))
 619             (nnweb-decode-entities)
 620             (goto-char (point-min))
 621             (while (re-search-forward "<blubb>.*href=\"\\([^\"]+\\)\"><strong>\\([^>]*\\)</strong></a><dd>\\([^-]+\\)- <b>\\([^<]+\\)<.*href=\"news:\\([^\"]+\\)\">.*\">\\(.+\\)</a><P>"
 622                                       nil t)
 623               (setq url (match-string 1)
 624                     subject (match-string 2)
 625                     date (match-string 3)
 626                     group (match-string 4)
 627                     id (concat "<" (match-string 5) ">")
 628                     from (match-string 6))
 629               (incf i)
 630               (unless (nnweb-get-hashtb url)
 631                 (push
 632                  (list
 633                   (incf (cdr active))
 634                   (make-full-mail-header
 635                    (cdr active) (concat  "(" group ") " subject) from date
 636                    id nil 0 0 url))
 637                  map)
 638                 (nnweb-set-hashtb (cadar map) (car map))))
 639             ;; See if we want more.
 640             (when (or (not nnweb-articles)
 641                       (>= i nnweb-max-hits)
 642                       (not (funcall (nnweb-definition 'search)
 643                                     nnweb-search (incf part))))
 644               (setq more nil)))
 645           ;; Return the articles in the right order.
 646           (setq nnweb-articles
 647                 (sort (nconc nnweb-articles map) 'car-less-than-car)))))))
 648
 649 (defun nnweb-altavista-wash-article ()
 650   (goto-char (point-min))
 651   (let ((case-fold-search t))
 652     (when (re-search-forward "^<strong>" nil t)
 653       (delete-region (point-min) (match-beginning 0)))
 654     (goto-char (point-min))
 655     (while (looking-at "<strong>\\([^ ]+\\) +</strong> +\\(.*\\)$")
 656       (replace-match "\\1: \\2" t)
 657       (forward-line 1))
 658     (when (re-search-backward "^References:" nil t)
 659       (narrow-to-region (point) (progn (forward-line 1) (point)))
 660       (goto-char (point-min))
 661       (while (re-search-forward "<A.*\\?id@\\([^\"]+\\)\">[0-9]+</A>" nil t)
 662         (replace-match "&lt;\\1&gt; " t)))
 663     (widen)
 664     (nnweb-remove-markup)))
 665
 666 (defun nnweb-altavista-search (search &optional part)
 667   (url-insert-file-contents
 668    (concat
 669     (nnweb-definition 'address)
 670     "?"
 671     (nnweb-encode-www-form-urlencoded
 672      `(("pg" . "aq")
 673        ("what" . "news")
 674        ,@(when part `(("stq" . ,(int-to-string (* part 30)))))
 675        ("fmt" . "d")
 676        ("q" . ,search)
 677        ("r" . "")
 678        ("d0" . "")
 679        ("d1" . "")))))
 680   (setq buffer-file-name nil)
 681   t)
 682
 683 ;;;
 684 ;;; General web/w3 interface utility functions
 685 ;;;
 686
 687 (defun nnweb-insert-html (parse)
 688   "Insert HTML based on a w3 parse tree."
 689   (if (stringp parse)
 690       (insert parse)
 691     (insert "<" (symbol-name (car parse)) " ")
 692     (insert (mapconcat
 693              (lambda (param)
 694                (concat (symbol-name (car param)) "="
 695                        (prin1-to-string
 696                         (if (consp (cdr param))
 697                             (cadr param)
 698                           (cdr param)))))
 699              (nth 1 parse)
 700              " "))
 701     (insert ">\n")
 702     (mapcar 'nnweb-insert-html (nth 2 parse))
 703     (insert "</" (symbol-name (car parse)) ">\n")))
 704
 705 (defun nnweb-encode-www-form-urlencoded (pairs)
 706   "Return PAIRS encoded for forms."
 707   (mapconcat
 708    (function
 709     (lambda (data)
 710       (concat (w3-form-encode-xwfu (car data)) "="
 711               (w3-form-encode-xwfu (cdr data)))))
 712    pairs "&"))
 713
 714 (defun nnweb-fetch-form (url pairs)
 715   "Fetch a form from URL with PAIRS as the data using the POST method."
 716   (let ((url-request-data (nnweb-encode-www-form-urlencoded pairs))
 717         (url-request-method "POST")
 718         (url-request-extra-headers
 719          '(("Content-type" . "application/x-www-form-urlencoded"))))
 720     (url-insert-file-contents url)
 721     (setq buffer-file-name nil))
 722   t)
 723
 724 (defun nnweb-decode-entities ()
 725   "Decode all HTML entities."
 726   (goto-char (point-min))
 727   (while (re-search-forward "&\\([a-z]+\\);" nil t)
 728     (replace-match (char-to-string (or (cdr (assq (intern (match-string 1))
 729                                                   w3-html-entities))
 730                                        ?#))
 731                    t t)))
 732
 733 (defun nnweb-remove-markup ()
 734   "Remove all HTML markup, leaving just plain text."
 735   (goto-char (point-min))
 736   (while (search-forward "<!--" nil t)
 737     (delete-region (match-beginning 0)
 738                    (or (search-forward "-->" nil t)
 739                        (point-max))))
 740   (goto-char (point-min))
 741   (while (re-search-forward "<[^>]+>" nil t)
 742     (replace-match "" t t)))
 743
 744 (defun nnweb-insert (url)
 745   "Insert the contents from an URL in the current buffer."
 746   (let ((name buffer-file-name))
 747     (url-insert-file-contents url)
 748     (setq buffer-file-name name)))
 749
 750 (defun nnweb-parse-find (type parse &optional maxdepth)
 751   "Find the element of TYPE in PARSE."
 752   (catch 'found
 753     (nnweb-parse-find-1 type parse maxdepth)))
 754
 755 (defun nnweb-parse-find-1 (type contents maxdepth)
 756   (when (or (null maxdepth)
 757             (not (zerop maxdepth)))
 758     (when (consp contents)
 759       (when (eq (car contents) type)
 760         (throw 'found contents))
 761       (when (listp (cdr contents))
 762         (dolist (element contents)
 763           (when (consp element)
 764             (nnweb-parse-find-1 type element
 765                                 (and maxdepth (1- maxdepth)))))))))
 766
 767 (defun nnweb-parse-find-all (type parse)
 768   "Find all elements of TYPE in PARSE."
 769   (catch 'found
 770     (nnweb-parse-find-all-1 type parse)))
 771
 772 (defun nnweb-parse-find-all-1 (type contents)
 773   (let (result)
 774     (when (consp contents)
 775       (if (eq (car contents) type)
 776           (push contents result)
 777         (when (listp (cdr contents))
 778           (dolist (element contents)
 779             (when (consp element)
 780               (setq result
 781                     (nconc result (nnweb-parse-find-all-1 type element))))))))
 782     result))
 783
 784 (defvar nnweb-text)
 785 (defun nnweb-text (parse)
 786   "Return a list of text contents in PARSE."
 787   (let ((nnweb-text nil))
 788     (nnweb-text-1 parse)
 789     (nreverse nnweb-text)))
 790
 791 (defun nnweb-text-1 (contents)
 792   (dolist (element contents)
 793     (if (stringp element)
 794         (push element nnweb-text)
 795       (when (and (consp element)
 796                  (listp (cdr element)))
 797         (nnweb-text-1 element)))))
 798
 799 (provide 'nnweb)
 800
 801 ;;; nnweb.el ends here