git.chise.org Git - elisp/gnus.git-/blob - lisp/pop3.el

   1 ;;; pop3.el --- Post Office Protocol (RFC 1460) interface
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Richard L. Pieri <ratinox@peorth.gweep.net>
   7 ;;      Daiki Ueno  <ueno@ueda.info.waseda.ac.jp>
   8 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
   9 ;; Maintainer: Volunteers
  10 ;; Keywords: mail
  11
  12 ;; This file is part of T-gnus.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28
  29 ;;; Commentary:
  30
  31 ;; Most of the standard Post Office Protocol version 3 (RFC 1460) commands
  32 ;; are implemented.  The LIST command has not been implemented due to lack
  33 ;; of actual usefulness.
  34 ;; The optional POP3 command TOP has not been implemented.
  35
  36 ;; This program was inspired by Kyle E. Jones's vm-pop program.
  37
  38 ;; You have to set the variable `pop3-connection-type' to `ssl' or
  39 ;; `tls' expressly, if you would like to use this module with Gnus
  40 ;; (not T-gnus) for those connection types.  For examples:
  41 ;;
  42 ;;(setq mail-sources '((pop :server "POPSERVER" :port 995 :connection ssl
  43 ;;                          :authentication apop)))
  44 ;;(setq pop3-connection-type 'ssl)
  45
  46 ;;; Code:
  47
  48 (eval-when-compile
  49   (require 'cl)
  50   ;; For compiling this module in Gnus with XEmacs -no-autoloads.
  51   (require 'advice))
  52
  53 ;; as-binary-process, open-network-stream-as-binary, write-region-as-binary
  54 (require 'pces)
  55 ;; exec-installed-p
  56 (require 'path-util)
  57
  58 (require 'mail-utils)
  59
  60 (defvar pop3-maildrop (or (user-login-name) (getenv "LOGNAME") (getenv "USER") nil)
  61   "*POP3 maildrop.")
  62 (defvar pop3-mailhost (or (getenv "MAILHOST") nil)
  63   "*POP3 mailhost.")
  64 (defvar pop3-port 110
  65   "*POP3 port.")
  66 (defvar pop3-connection-type nil
  67   "*POP3 connection type.")
  68
  69 (defvar pop3-password-required t
  70   "*Non-nil if a password is required when connecting to POP server.")
  71 (defvar pop3-password nil
  72   "*Password to use when connecting to POP server.")
  73
  74 (defvar pop3-authentication-scheme 'pass
  75   "*POP3 authentication scheme.
  76 Defaults to 'pass, for the standard USER/PASS authentication.  Other valid
  77 values are 'apop.")
  78
  79 (defvar pop3-timestamp nil
  80   "Timestamp returned when initially connected to the POP server.
  81 Used for APOP authentication.")
  82
  83 (defvar pop3-leave-mail-on-server nil
  84   "Non-nil if mail is to be left on the server and UIDL used for message retrieval.")
  85
  86 (defvar pop3-maximum-message-size nil
  87   "If non-nil only download messages smaller than this.")
  88
  89 (defvar pop3-except-header-regexp nil
  90   "If non-nil we do not retrieve messages whose headers are matching this regexp.")
  91
  92 (defvar pop3-uidl-file-name "~/.uidls"
  93   "File in which to store the UIDL of processed messages.")
  94
  95 (defvar pop3-uidl-support nil
  96   "Alist of servers and flags of whether they support UIDLs.
  97 Users don't have to set this value.")
  98
  99 (defvar pop3-uidl-obarray (make-vector 31 0)
 100   "Uidl hash table.")
 101
 102 (defvar pop3-read-point nil)
 103 (defvar pop3-debug nil)
 104
 105 (eval-and-compile
 106   (autoload 'starttls-open-stream "starttls")
 107   (autoload 'starttls-negotiate "starttls"))
 108
 109 (defvar pop3-ssl-program-name
 110   (if (exec-installed-p "openssl")
 111       "openssl"
 112     "ssleay")
 113   "The program to run in a subprocess to open an SSL connection.")
 114
 115 (defvar pop3-ssl-program-arguments
 116   '("s_client" "-quiet")
 117   "Arguments to be passed to the program `pop3-ssl-program-name'.")
 118
 119 (defun pop3-progress-message (format percent &rest args)
 120   (apply (function message) format args))
 121
 122 (defun pop3-movemail (&optional crashbox)
 123   "Transfer contents of a maildrop to the specified CRASHBOX."
 124   (or crashbox (setq crashbox (expand-file-name "~/.crashbox")))
 125   (let* ((process (pop3-open-server pop3-mailhost pop3-port))
 126          (crashbuf (get-buffer-create " *pop3-retr*"))
 127          (n 1)
 128          message-count
 129          (pop3-password pop3-password)
 130          (pop3-uidl-file-name (convert-standard-filename
 131                                (concat pop3-uidl-file-name "-"
 132                                        pop3-mailhost)))
 133          retrieved-messages messages)
 134     ;; for debugging only
 135     (if pop3-debug (switch-to-buffer (process-buffer process)))
 136     ;; query for password
 137     (if (and pop3-password-required (not pop3-password))
 138         (setq pop3-password
 139               (read-passwd (format "Password for %s: " pop3-maildrop))))
 140     (cond ((equal 'apop pop3-authentication-scheme)
 141            (pop3-apop process pop3-maildrop))
 142           ((equal 'pass pop3-authentication-scheme)
 143            (pop3-user process pop3-maildrop)
 144            (pop3-pass process))
 145           (t (error "Invalid POP3 authentication scheme")))
 146     ;; get messages that are suitable for download
 147     (message "Retrieving message list...")
 148     (setq messages (pop3-get-message-numbers process)
 149           message-count (length (cdr messages)))
 150     (message "Retrieving message list...%d of %d unread"
 151              message-count (pop messages))
 152     (unwind-protect
 153         (unless (not (stringp crashbox))
 154           (while messages
 155             (pop3-progress-message
 156              "Retrieving message %d of %d (%d octets) from %s..."
 157              (floor (* (/ (float n) message-count) 100))
 158              n message-count (cdar messages) pop3-mailhost)
 159             (pop3-retr process (caar messages) crashbuf)
 160             (push (caar messages) retrieved-messages)
 161             (setq messages (cdr messages)
 162                   n (1+ n)))
 163           (with-current-buffer crashbuf
 164             (write-region-as-binary (point-min) (point-max)
 165                                     crashbox 'append 'nomesg))
 166           ;; mark messages as read
 167           (when pop3-leave-mail-on-server
 168             (pop3-save-uidls))
 169           ;; now delete the messages we have retrieved
 170           (unless pop3-leave-mail-on-server
 171             (dolist (n retrieved-messages)
 172               (message "Deleting message %d of %d from %s..."
 173                        n message-count pop3-mailhost)
 174               (pop3-dele process n)))
 175           )
 176       (pop3-quit process))
 177     (kill-buffer crashbuf)
 178     message-count))
 179
 180 (defun pop3-get-message-count ()
 181   "Return the number of messages in the maildrop."
 182   (let* ((process (pop3-open-server pop3-mailhost pop3-port))
 183          message-count
 184          (pop3-password pop3-password)
 185          )
 186     ;; for debugging only
 187     (if pop3-debug (switch-to-buffer (process-buffer process)))
 188     ;; query for password
 189     (if (and pop3-password-required (not pop3-password))
 190         (setq pop3-password
 191               (read-passwd (format "Password for %s: " pop3-maildrop))))
 192     (cond ((equal 'apop pop3-authentication-scheme)
 193            (pop3-apop process pop3-maildrop))
 194           ((equal 'pass pop3-authentication-scheme)
 195            (pop3-user process pop3-maildrop)
 196            (pop3-pass process))
 197           (t (error "Invalid POP3 authentication scheme")))
 198     (setq message-count (car (pop3-stat process)))
 199     (pop3-quit process)
 200     message-count))
 201
 202 (defun pop3-open-server (mailhost port)
 203   "Open TCP connection to MAILHOST on PORT.
 204 Returns the process associated with the connection.
 205 Argument PORT specifies connecting port."
 206   (let (process)
 207     (save-excursion
 208       (set-buffer (get-buffer-create (concat " trace of POP session to "
 209                                              mailhost)))
 210       (erase-buffer)
 211       (setq pop3-read-point (point-min))
 212       (setq
 213        process
 214        (cond
 215         ((eq pop3-connection-type 'ssl)
 216          (pop3-open-ssl-stream "POP" (current-buffer) mailhost port))
 217         ((eq pop3-connection-type 'tls)
 218          (pop3-open-tls-stream "POP" (current-buffer) mailhost port))
 219         (t
 220          (open-network-stream-as-binary "POP" (current-buffer)
 221                                         mailhost port))))
 222       (let ((response (pop3-read-response process t)))
 223         (setq pop3-timestamp
 224               (substring response (or (string-match "<" response) 0)
 225                          (+ 1 (or (string-match ">" response) -1)))))
 226       process)))
 227
 228 (eval-when-compile
 229   (autoload 'open-ssl-stream "ssl"))
 230
 231 (defun pop3-open-ssl-stream-1 (name buffer host service extra-arg)
 232   (require 'ssl)
 233   (let* ((ssl-program-name
 234           pop3-ssl-program-name)
 235          (ssl-program-arguments
 236           `(,@pop3-ssl-program-arguments
 237             ,extra-arg
 238             "-connect" ,(format "%s:%d" host service)))
 239          (process (open-ssl-stream name buffer host service)))
 240     (when process
 241       (with-current-buffer buffer
 242         (goto-char (point-min))
 243         (while (and (memq (process-status process) '(open run))
 244                     (goto-char (point-max))
 245                     (forward-line -1)
 246                     (not (looking-at "+OK")))
 247           (nnheader-accept-process-output process)
 248           (sit-for 1))
 249         (delete-region (point-min) (point)))
 250       (and process (memq (process-status process) '(open run))
 251            process))))
 252
 253 (defun pop3-open-ssl-stream (name buffer host service)
 254   "Open a SSL connection for a service to a host.
 255 Returns a subprocess-object to represent the connection.
 256 Args are NAME BUFFER HOST SERVICE."
 257   (as-binary-process
 258    (or (pop3-open-ssl-stream-1 name buffer host service "-ssl3")
 259        (pop3-open-ssl-stream-1 name buffer host service "-ssl2"))))
 260
 261 (defun pop3-open-tls-stream (name buffer host service)
 262   "Open a TLSv1 connection for a service to a host.
 263 Returns a subprocess-object to represent the connection.
 264 Args are NAME BUFFER HOST SERVICE."
 265   (let ((process
 266          (as-binary-process (starttls-open-stream
 267                              name buffer host service))))
 268     (pop3-stls process)
 269     (starttls-negotiate process)
 270     process))
 271
 272 ;; Support functions
 273
 274 (defun pop3-process-filter (process output)
 275   (save-excursion
 276     (set-buffer (process-buffer process))
 277     (goto-char (point-max))
 278     (insert output)))
 279
 280 (defun pop3-send-command (process command)
 281   (set-buffer (process-buffer process))
 282   (goto-char (point-max))
 283 ;;  (if (= (aref command 0) ?P)
 284 ;;      (insert "PASS <omitted>\r\n")
 285 ;;    (insert command "\r\n"))
 286   (setq pop3-read-point (point))
 287   (goto-char (point-max))
 288   (process-send-string process (concat command "\r\n"))
 289   )
 290
 291 (defun pop3-read-response (process &optional return)
 292   "Read the response from the server PROCESS.
 293 Return the response string if optional second argument RETURN is non-nil."
 294   (let ((case-fold-search nil)
 295         match-end)
 296     (save-excursion
 297       (set-buffer (process-buffer process))
 298       (goto-char pop3-read-point)
 299       (while (and (memq (process-status process) '(open run))
 300                   (not (search-forward "\r\n" nil t)))
 301         (nnheader-accept-process-output process)
 302         (goto-char pop3-read-point))
 303       (setq match-end (point))
 304       (goto-char pop3-read-point)
 305       (if (looking-at "-ERR")
 306           (error (buffer-substring (point) (- match-end 2)))
 307         (if (not (looking-at "+OK"))
 308             (progn (setq pop3-read-point match-end) nil)
 309           (setq pop3-read-point match-end)
 310           (if return
 311               (buffer-substring (point) match-end)
 312             t)
 313           )))))
 314
 315 (defun pop3-clean-region (start end)
 316   (setq end (set-marker (make-marker) end))
 317   (save-excursion
 318     (goto-char start)
 319     (while (and (< (point) end) (search-forward "\r\n" end t))
 320       (replace-match "\n" t t))
 321     (goto-char start)
 322     (while (re-search-forward "\n\n\\(From \\)" end t)
 323       (replace-match "\n\n>\\1" t nil))
 324     (goto-char start)
 325     (while (and (< (point) end) (re-search-forward "^\\." end t))
 326       (replace-match "" t t)
 327       (forward-char)))
 328   (set-marker end nil))
 329
 330 (eval-when-compile (defvar parse-time-months))
 331
 332 ;; Copied from message-make-date.
 333 (defun pop3-make-date (&optional now)
 334   "Make a valid date header.
 335 If NOW, use that time instead."
 336   (require 'parse-time)
 337   (let* ((now (or now (current-time)))
 338          (zone (nth 8 (decode-time now)))
 339          (sign "+"))
 340     (when (< zone 0)
 341       (setq sign "-")
 342       (setq zone (- zone)))
 343     (concat
 344      (format-time-string "%d" now)
 345      ;; The month name of the %b spec is locale-specific.  Pfff.
 346      (format " %s "
 347              (capitalize (car (rassoc (nth 4 (decode-time now))
 348                                       parse-time-months))))
 349      (format-time-string "%Y %H:%M:%S " now)
 350      ;; We do all of this because XEmacs doesn't have the %z spec.
 351      (format "%s%02d%02d" sign (/ zone 3600) (/ (% zone 3600) 60)))))
 352
 353 (defun pop3-munge-message-separator (start end)
 354   "Check to see if a message separator exists.  If not, generate one."
 355   (save-excursion
 356     (save-restriction
 357       (narrow-to-region start end)
 358       (goto-char (point-min))
 359       (if (not (or (looking-at "From .?") ; Unix mail
 360                    (looking-at "\001\001\001\001\n") ; MMDF
 361                    (looking-at "BABYL OPTIONS:") ; Babyl
 362                    ))
 363           (let* ((from (mail-strip-quoted-names (mail-fetch-field "From")))
 364                  (tdate (mail-fetch-field "Date"))
 365                  (date (split-string (or (and tdate
 366                                               (not (string= "" tdate))
 367                                               tdate)
 368                                          (pop3-make-date))
 369                                      " "))
 370                  (From_))
 371             ;; sample date formats I have seen
 372             ;; Date: Tue, 9 Jul 1996 09:04:21 -0400 (EDT)
 373             ;; Date: 08 Jul 1996 23:22:24 -0400
 374             ;; should be
 375             ;; Tue Jul 9 09:04:21 1996
 376             (setq date
 377                   (cond ((not date)
 378                          "Tue Jan 1 00:00:0 1900")
 379                         ((string-match "[A-Z]" (nth 0 date))
 380                          (format "%s %s %s %s %s"
 381                                  (nth 0 date) (nth 2 date) (nth 1 date)
 382                                  (nth 4 date) (nth 3 date)))
 383                         (t
 384                          ;; this really needs to be better but I don't feel
 385                          ;; like writing a date to day converter.
 386                          (format "Sun %s %s %s %s"
 387                                  (nth 1 date) (nth 0 date)
 388                                  (nth 3 date) (nth 2 date)))
 389                         ))
 390             (setq From_ (format "\nFrom %s  %s\n" from date))
 391             (while (string-match "," From_)
 392               (setq From_ (concat (substring From_ 0 (match-beginning 0))
 393                                   (substring From_ (match-end 0)))))
 394             (goto-char (point-min))
 395             (insert From_)
 396             (if (search-forward "\n\n" nil t)
 397                 nil
 398               (goto-char (point-max))
 399               (insert "\n"))
 400             (narrow-to-region (point) (point-max))
 401             (let ((size (- (point-max) (point-min))))
 402               (goto-char (point-min))
 403               (widen)
 404               (forward-line -1)
 405               (insert (format "Content-Length: %s\n" size)))
 406             )))))
 407
 408 ;; UIDL support
 409
 410 (defun pop3-get-message-numbers (process)
 411   "Get the list of message numbers and lengths to retrieve via PROCESS."
 412   ;; we use the LIST comand first anyway to get the message lengths.
 413   ;; then if we're leaving mail on the server, see if the UIDL command
 414   ;; is implemented. if so, we use it to get the message number list.
 415   (let* ((messages (pop3-list process))
 416          (total (or (pop messages) 0))
 417          (uidl (if pop3-leave-mail-on-server
 418                    (pop3-get-uidl process)))
 419          out)
 420     (while messages
 421       ;; only retrieve messages matching our regexp or in the uidl list
 422       (when (and
 423              ;; remove elements not in the uidl, this assumes the uidl is short
 424              (or (not (and pop3-leave-mail-on-server
 425                            (cdr (assoc pop3-mailhost pop3-uidl-support))))
 426                  (memq (caar messages) uidl))
 427              (caar messages)
 428              ;; don't download messages that are too large
 429              (not (and pop3-maximum-message-size
 430                        (> (cdar messages) pop3-maximum-message-size)))
 431              (not (and pop3-except-header-regexp
 432                        (string-match pop3-except-header-regexp
 433                                      (pop3-top process (caar messages) 0)))))
 434         (push (car messages) out))
 435       (setq messages (cdr messages)))
 436     (cons total (nreverse out))))
 437
 438 (defun pop3-get-uidl (process)
 439   "Use PROCESS to get a list of unread message numbers."
 440   (let ((messages (pop3-uidl process))
 441         (support (assoc pop3-mailhost pop3-uidl-support))
 442         uidl)
 443     (if support
 444         (setcdr support (and messages t))
 445       (push (cons pop3-mailhost (and messages t))
 446             pop3-uidl-support))
 447     (when messages
 448       (save-excursion
 449         (with-temp-buffer
 450           (when (file-readable-p pop3-uidl-file-name)
 451             (insert-file-contents pop3-uidl-file-name))
 452           (goto-char (point-min))
 453           (while (looking-at "\\([^ \n\t]+\\)")
 454             (set (intern (match-string 1) pop3-uidl-obarray)
 455                  (cons nil t))
 456             (forward-line 1))))
 457       (dolist (message (cdr messages))
 458         (if (setq uidl (intern-soft (cdr message) pop3-uidl-obarray))
 459             (setcar (symbol-value uidl) (car message))
 460           (set (intern (cdr message) pop3-uidl-obarray)
 461                (cons (car message) nil))))
 462       (pop3-get-unread-message-numbers))))
 463
 464 (defun pop3-get-unread-message-numbers ()
 465   "Return a sorted list of unread msg numbers to retrieve."
 466   (let (nums)
 467     (mapatoms (lambda (atom)
 468                 (if (not (cdr (symbol-value atom)))
 469                     (push (car (symbol-value atom)) nums)))
 470               pop3-uidl-obarray)
 471     (sort nums '<)))
 472
 473 (defun pop3-save-uidls ()
 474   "Save the updated UIDLs to disk for use next time."
 475   (when (and pop3-leave-mail-on-server
 476              ;; UIDL hash table is non-empty
 477              (let ((len (length pop3-uidl-obarray)))
 478                (while (< 0 len)
 479                  (setq len (if (symbolp (aref pop3-uidl-obarray (1- len)))
 480                                -1 (1- len))))
 481                (minusp len)))
 482     (when (file-readable-p pop3-uidl-file-name)
 483       (copy-file pop3-uidl-file-name
 484                  (concat pop3-uidl-file-name ".old")
 485                  'overwrite 'keeptime))
 486     (save-excursion
 487       (with-temp-file pop3-uidl-file-name
 488         (mapatoms
 489          (lambda (atom)
 490            (when (car (symbol-value atom))
 491              (insert (format "%s\n" atom))))
 492          pop3-uidl-obarray)))
 493     (fillarray pop3-uidl-obarray 0)))
 494
 495
 496 ;; The Command Set
 497
 498 ;; AUTHORIZATION STATE
 499
 500 (defun pop3-user (process user)
 501   "Send USER information to POP3 server."
 502   (pop3-send-command process (format "USER %s" user))
 503   (let ((response (pop3-read-response process t)))
 504     (if (not (and response (string-match "+OK" response)))
 505         (error (format "USER %s not valid" user)))))
 506
 507 (defun pop3-pass (process)
 508   "Send authentication information to the server."
 509   (pop3-send-command process (format "PASS %s" pop3-password))
 510   (let ((response (pop3-read-response process t)))
 511     (if (not (and response (string-match "+OK" response)))
 512         (pop3-quit process))))
 513
 514 (defun pop3-apop (process user)
 515   "Send alternate authentication information to the server."
 516   (let ((pass pop3-password))
 517     (if (and pop3-password-required (not pass))
 518         (setq pass
 519               (read-passwd (format "Password for %s: " pop3-maildrop))))
 520     (if pass
 521         ;; Note that `md5' should never encode a given string to use for
 522         ;; the apop authentication, so we should specify `binary'.
 523         (let ((hash (md5 (concat pop3-timestamp pass) nil nil 'binary)))
 524           (pop3-send-command process (format "APOP %s %s" user hash))
 525           (let ((response (pop3-read-response process t)))
 526             (if (not (and response (string-match "+OK" response)))
 527                 (pop3-quit process)))))
 528     ))
 529
 530 (defun pop3-stls (process)
 531   "Query whether TLS extension is supported"
 532   (pop3-send-command process "STLS")
 533   (let ((response (pop3-read-response process t)))
 534     (if (not (and response (string-match "+OK" response)))
 535         (pop3-quit process))))
 536
 537 ;; TRANSACTION STATE
 538
 539 (defun pop3-stat (process)
 540   "Return the number of messages in the maildrop and the maildrop's size."
 541   (pop3-send-command process "STAT")
 542   (let ((response (pop3-read-response process t)))
 543     (list (string-to-int (nth 1 (split-string response " ")))
 544           (string-to-int (nth 2 (split-string response " "))))
 545     ))
 546
 547 (defun pop3-retr (process msg crashbuf)
 548   "Retrieve message-id MSG to buffer CRASHBUF."
 549   (pop3-send-command process (format "RETR %s" msg))
 550   (pop3-read-response process)
 551   (save-excursion
 552     (let ((region (pop3-get-extended-response process)))
 553       (pop3-munge-message-separator (car region) (cadr region))
 554       (append-to-buffer crashbuf (car region) (cadr region))
 555       (delete-region (car region) (cadr region))
 556       )))
 557
 558 (defun pop3-dele (process msg)
 559   "Mark message-id MSG as deleted."
 560   (pop3-send-command process (format "DELE %s" msg))
 561   (pop3-read-response process))
 562
 563 (defun pop3-noop (process msg)
 564   "No-operation."
 565   (pop3-send-command process "NOOP")
 566   (pop3-read-response process))
 567
 568 (defun pop3-last (process)
 569   "Return highest accessed message-id number for the session."
 570   (pop3-send-command process "LAST")
 571   (let ((response (pop3-read-response process t)))
 572     (string-to-int (nth 1 (split-string response " ")))
 573     ))
 574
 575 (defun pop3-rset (process)
 576   "Remove all delete marks from current maildrop."
 577   (pop3-send-command process "RSET")
 578   (pop3-read-response process))
 579
 580 ;; UPDATE
 581
 582 (defun pop3-quit (process)
 583   "Close connection to POP3 server.
 584 Tell server to remove all messages marked as deleted, unlock the maildrop,
 585 and close the connection."
 586   (pop3-send-command process "QUIT")
 587   (pop3-read-response process t)
 588   (when process
 589     (save-excursion
 590       (set-buffer (process-buffer process))
 591       (goto-char (point-max))
 592       (delete-process process))))
 593
 594 (defun pop3-uidl (process &optional msgno)
 595   "Return the results of a UIDL command in PROCESS for optional MSGNO.
 596 If UIDL is unsupported on this mail server or if msgno is invalid, return nil.
 597 Otherwise, return a list in the form
 598
 599    (N (1 UIDL-1) (2 UIDL-2) ... (N UIDL-N))
 600
 601 where
 602
 603    N is an integer for the number of UIDLs returned (could be 0)
 604    UIDL-n is a string."
 605
 606   (if msgno
 607       (pop3-send-command process (format "UIDL %d" msgno))
 608     (pop3-send-command process "UIDL"))
 609
 610   (if (null (pop3-read-response process t))
 611       nil ;; UIDL is not supported on this server
 612     (let (pairs uidl)
 613       (save-excursion
 614         (save-restriction
 615           (apply 'narrow-to-region (pop3-get-extended-response process))
 616           (goto-char (point-min))
 617           (while (looking-at "\\([^ \n\t]*\\) \\([^ \n\t]*\\)")
 618             (setq msgno (string-to-int (match-string 1))
 619                   uidl (match-string 2))
 620             (push (cons msgno uidl) pairs)
 621             (beginning-of-line 2))
 622           (cons (length pairs) (nreverse pairs))
 623           )))))
 624
 625 (defun pop3-list (process &optional msgno)
 626   "Return the results of a LIST command for PROCESS and optional MSGNO.
 627 If (optional) msgno is invalid, return nil.  Otherwise, return a list
 628 in the form
 629
 630    (N (1 LEN-1) (2 LEN-2) ... (N LEN-N))
 631
 632 where
 633
 634    N is an integer for the number of msg/len pairs (could be 0)
 635    LEN-n is an integer."
 636   (if msgno
 637       (pop3-send-command process (format "LIST %d" msgno))
 638     (pop3-send-command process "LIST"))
 639
 640   (if (null (pop3-read-response process t))
 641       nil ;; MSGNO is not valid number
 642     (let (pairs len)
 643       (save-excursion
 644         (save-restriction
 645           (apply 'narrow-to-region (pop3-get-extended-response process))
 646           (goto-char (point-min))
 647           (while (looking-at "\\([^ \n\t]*\\) \\([^ \n\t]*\\)")
 648             (setq msgno (string-to-int (match-string 1))
 649                   len (string-to-int (match-string 2)))
 650             (push (cons msgno len) pairs)
 651             (beginning-of-line 2))
 652           (cons (length pairs) (nreverse pairs))
 653           )))))
 654
 655 (defun pop3-top (process msgno &optional lines)
 656   "Return the top LINES of messages for PROCESS and MSGNO.
 657 If msgno is invalid, return nil.  Otherwise, return a string."
 658   (pop3-send-command process (format "TOP %d %d" msgno (or lines 1)))
 659   (if (pop3-read-response process t)
 660       nil ;; MSGNO is not valid number
 661     (save-excursion
 662       (apply 'buffer-substring (pop3-get-extended-response process)))
 663     ))
 664
 665 ;;; Utility code
 666
 667 (defun pop3-get-extended-response (process)
 668   "Get the extended pop3 response in the PROCESS buffer."
 669   (let ((start pop3-read-point) end)
 670     (set-buffer (process-buffer process))
 671     (goto-char start)
 672     (while (not (re-search-forward "^\\.\r\n" nil t))
 673       ;; Fixme: Shouldn't depend on nnheader.
 674       (nnheader-accept-process-output process)
 675       (goto-char start))
 676     (setq pop3-read-point (point-marker))
 677     (goto-char (match-beginning 0))
 678     (setq end (point-marker))
 679     (pop3-clean-region start end)
 680     (list start end)))
 681
 682 \f
 683 ;; Summary of POP3 (Post Office Protocol version 3) commands and responses
 684
 685 ;;; AUTHORIZATION STATE
 686
 687 ;; Initial TCP connection
 688 ;; Arguments: none
 689 ;; Restrictions: none
 690 ;; Possible responses:
 691 ;;  +OK [POP3 server ready]
 692
 693 ;; USER name
 694 ;; Arguments: a server specific user-id (required)
 695 ;; Restrictions: authorization state [after unsuccessful USER or PASS
 696 ;; Possible responses:
 697 ;;  +OK [valid user-id]
 698 ;;  -ERR [invalid user-id]
 699
 700 ;; PASS string
 701 ;; Arguments: a server/user-id specific password (required)
 702 ;; Restrictions: authorization state, after successful USER
 703 ;; Possible responses:
 704 ;;  +OK [maildrop locked and ready]
 705 ;;  -ERR [invalid password]
 706 ;;  -ERR [unable to lock maildrop]
 707
 708 ;; STLS
 709 ;; Arguments: none
 710 ;; Restrictions: authorization state
 711 ;; Possible responses:
 712 ;;  +OK [negotiation is ready]
 713 ;;  -ERR [security layer is already active]
 714
 715 ;;; TRANSACTION STATE
 716
 717 ;; STAT
 718 ;; Arguments: none
 719 ;; Restrictions: transaction state
 720 ;; Possible responses:
 721 ;;  +OK nn mm [# of messages, size of maildrop]
 722
 723 ;; LIST [msg]
 724 ;; Arguments: a message-id (optional)
 725 ;; Restrictions: transaction state; msg must not be deleted
 726 ;; Possible responses:
 727 ;;  +OK [scan listing follows]
 728 ;;  -ERR [no such message]
 729
 730 ;; TOP msg [lines]
 731 ;; Arguments: a message-id (required), number of lines (optional)
 732 ;; Restrictions: transaction state; msg must not be deleted
 733 ;; Possible responses:
 734 ;;  +OK [partial message listing follows]
 735 ;;  -ERR [no such message]
 736
 737 ;; UIDL [msg]
 738 ;; Arguments: a message-id (optional)
 739 ;; Restrictions: transaction state; msg must not be deleted
 740 ;; Possible responses:
 741 ;;  +OK [uidl listing follows]
 742 ;;  -ERR [no such message]
 743
 744 ;; RETR msg
 745 ;; Arguments: a message-id (required)
 746 ;; Restrictions: transaction state; msg must not be deleted
 747 ;; Possible responses:
 748 ;;  +OK [message contents follow]
 749 ;;  -ERR [no such message]
 750
 751 ;; DELE msg
 752 ;; Arguments: a message-id (required)
 753 ;; Restrictions: transaction state; msg must not be deleted
 754 ;; Possible responses:
 755 ;;  +OK [message deleted]
 756 ;;  -ERR [no such message]
 757
 758 ;; NOOP
 759 ;; Arguments: none
 760 ;; Restrictions: transaction state
 761 ;; Possible responses:
 762 ;;  +OK
 763
 764 ;; LAST
 765 ;; Arguments: none
 766 ;; Restrictions: transaction state
 767 ;; Possible responses:
 768 ;;  +OK nn [highest numbered message accessed]
 769
 770 ;; RSET
 771 ;; Arguments: none
 772 ;; Restrictions: transaction state
 773 ;; Possible responses:
 774 ;;  +OK [all delete marks removed]
 775
 776 ;;; UPDATE STATE
 777
 778 ;; QUIT
 779 ;; Arguments: none
 780 ;; Restrictions: none
 781 ;; Possible responses:
 782 ;;  +OK [TCP connection closed]
 783
 784 (provide 'pop3)
 785
 786 ;;; pop3.el ends here