git.chise.org Git - elisp/gnus.git-/blob - lisp/pop3.el

   1 ;;; pop3.el --- Post Office Protocol (RFC 1460) interface
   2
   3 ;; Copyright (C) 1996,1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Richard L. Pieri <ratinox@peorth.gweep.net>
   6 ;; Keywords: mail, pop3
   7 ;; Version: 1.3h
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Most of the standard Post Office Protocol version 3 (RFC 1460) commands
  29 ;; are implemented.  The LIST command has not been implemented due to lack
  30 ;; of actual usefulness.
  31 ;; The optional POP3 command TOP has not been implemented.
  32
  33 ;; This program was inspired by Kyle E. Jones's vm-pop program.
  34
  35 ;;; Code:
  36
  37 (require 'mail-utils)
  38 (provide 'pop3)
  39
  40 (defconst pop3-version "1.3h")
  41
  42 (defvar pop3-maildrop (or user-login-name (getenv "LOGNAME") (getenv "USER") nil)
  43   "*POP3 maildrop.")
  44 (defvar pop3-mailhost (or (getenv "MAILHOST") nil)
  45   "*POP3 mailhost.")
  46 (defvar pop3-port 110
  47   "*POP3 port.")
  48
  49 (defvar pop3-password-required t
  50   "*Non-nil if a password is required when connecting to POP server.")
  51 (defvar pop3-password nil
  52   "*Password to use when connecting to POP server.")
  53
  54 (defvar pop3-authentication-scheme 'pass
  55   "*POP3 authentication scheme.
  56 Defaults to 'pass, for the standard USER/PASS authentication.  Other valid
  57 values are 'apop.")
  58
  59 (defvar pop3-timestamp nil
  60   "Timestamp returned when initially connected to the POP server.
  61 Used for APOP authentication.")
  62
  63 (defvar pop3-read-point nil)
  64 (defvar pop3-debug nil)
  65
  66 (defun pop3-movemail (&optional crashbox)
  67   "Transfer contents of a maildrop to the specified CRASHBOX."
  68   (or crashbox (setq crashbox (expand-file-name "~/.crashbox")))
  69   (let* ((process (pop3-open-server pop3-mailhost pop3-port))
  70          (crashbuf (get-buffer-create " *pop3-retr*"))
  71          (n 1)
  72          message-count
  73          (pop3-password pop3-password)
  74          )
  75     ;; for debugging only
  76     (if pop3-debug (switch-to-buffer (process-buffer process)))
  77     ;; query for password
  78     (if (and pop3-password-required (not pop3-password))
  79         (setq pop3-password
  80               (pop3-read-passwd (format "Password for %s: " pop3-maildrop))))
  81     (cond ((equal 'apop pop3-authentication-scheme)
  82            (pop3-apop process pop3-maildrop))
  83           ((equal 'pass pop3-authentication-scheme)
  84            (pop3-user process pop3-maildrop)
  85            (pop3-pass process))
  86           (t (error "Invalid POP3 authentication scheme.")))
  87     (setq message-count (car (pop3-stat process)))
  88     (while (<= n message-count)
  89       (message (format "Retrieving message %d of %d from %s..."
  90                        n message-count pop3-mailhost))
  91       (pop3-retr process n crashbuf)
  92       (save-excursion
  93         (set-buffer crashbuf)
  94         (append-to-file (point-min) (point-max) crashbox)
  95         (set-buffer (process-buffer process))
  96         (while (> (buffer-size) 5000)
  97           (goto-char (point-min))
  98           (forward-line 50)
  99           (delete-region (point-min) (point))))
 100       (pop3-dele process n)
 101       (setq n (+ 1 n))
 102       (if pop3-debug (sit-for 1) (sit-for 0.1))
 103       )
 104     (pop3-quit process)
 105     (kill-buffer crashbuf)
 106     )
 107   )
 108
 109 (defun pop3-open-server (mailhost port)
 110   "Open TCP connection to MAILHOST.
 111 Returns the process associated with the connection."
 112   (let ((process-buffer
 113          (get-buffer-create (format "trace of POP session to %s" mailhost)))
 114         (process))
 115     (save-excursion
 116       (set-buffer process-buffer)
 117       (erase-buffer))
 118     (setq process
 119           (open-network-stream "POP" process-buffer mailhost port))
 120     (setq pop3-read-point (point-min))
 121     (let ((response (pop3-read-response process t)))
 122       (setq pop3-timestamp
 123             (substring response (or (string-match "<" response) 0)
 124                        (+ 1 (or (string-match ">" response) -1)))))
 125     process
 126     ))
 127
 128 ;; Support functions
 129
 130 (defun pop3-process-filter (process output)
 131   (save-excursion
 132     (set-buffer (process-buffer process))
 133     (goto-char (point-max))
 134     (insert output)))
 135
 136 (defun pop3-send-command (process command)
 137     (set-buffer (process-buffer process))
 138     (goto-char (point-max))
 139 ;;    (if (= (aref command 0) ?P)
 140 ;;      (insert "PASS <omitted>\r\n")
 141 ;;      (insert command "\r\n"))
 142     (setq pop3-read-point (point))
 143     (goto-char (point-max))
 144     (process-send-string process command)
 145     (process-send-string process "\r\n")
 146     )
 147
 148 (defun pop3-read-response (process &optional return)
 149   "Read the response from the server.
 150 Return the response string if optional second argument is non-nil."
 151   (let ((case-fold-search nil)
 152         match-end)
 153     (save-excursion
 154       (set-buffer (process-buffer process))
 155       (goto-char pop3-read-point)
 156       (while (not (search-forward "\r\n" nil t))
 157         (accept-process-output process 3)
 158         (goto-char pop3-read-point))
 159       (setq match-end (point))
 160       (goto-char pop3-read-point)
 161       (if (looking-at "-ERR")
 162           (error (buffer-substring (point) (- match-end 2)))
 163         (if (not (looking-at "+OK"))
 164             (progn (setq pop3-read-point match-end) nil)
 165           (setq pop3-read-point match-end)
 166           (if return
 167               (buffer-substring (point) match-end)
 168             t)
 169           )))))
 170
 171 (defun pop3-string-to-list (string &optional regexp)
 172   "Chop up a string into a list."
 173   (let ((list)
 174         (regexp (or regexp " "))
 175         (string (if (string-match "\r" string)
 176                     (substring string 0 (match-beginning 0))
 177                   string)))
 178     (store-match-data nil)
 179     (while string
 180       (if (string-match regexp string)
 181           (setq list (cons (substring string 0 (- (match-end 0) 1)) list)
 182                 string (substring string (match-end 0)))
 183         (setq list (cons string list)
 184               string nil)))
 185     (nreverse list)))
 186
 187 (defvar pop3-read-passwd nil)
 188 (defun pop3-read-passwd (prompt)
 189   (if (not pop3-read-passwd)
 190       (if (load "passwd" t)
 191           (setq pop3-read-passwd 'read-passwd)
 192         (autoload 'ange-ftp-read-passwd "ange-ftp")
 193         (setq pop3-read-passwd 'ange-ftp-read-passwd)))
 194   (funcall pop3-read-passwd prompt))
 195
 196 (defun pop3-clean-region (start end)
 197   (setq end (set-marker (make-marker) end))
 198   (save-excursion
 199     (goto-char start)
 200     (while (and (< (point) end) (search-forward "\r\n" end t))
 201       (replace-match "\n" t t))
 202     (goto-char start)
 203     (while (and (< (point) end) (re-search-forward "^\\." end t))
 204       (replace-match "" t t)
 205       (forward-char)))
 206   (set-marker end nil))
 207
 208 (defun pop3-munge-message-separator (start end)
 209   "Check to see if a message separator exists.  If not, generate one."
 210   (if (not (fboundp 'message-make-date)) (autoload 'message-make-date "message"))
 211   (save-excursion
 212     (save-restriction
 213       (narrow-to-region start end)
 214       (goto-char (point-min))
 215       (if (not (or (looking-at "From .?") ; Unix mail
 216                    (looking-at "\001\001\001\001\n") ; MMDF
 217                    (looking-at "BABYL OPTIONS:") ; Babyl
 218                    ))
 219           (let ((from (mail-strip-quoted-names (mail-fetch-field "From")))
 220                 (date (pop3-string-to-list (or (mail-fetch-field "Date")
 221                                                (message-make-date))))
 222                 (From_))
 223             ;; sample date formats I have seen
 224             ;; Date: Tue, 9 Jul 1996 09:04:21 -0400 (EDT)
 225             ;; Date: 08 Jul 1996 23:22:24 -0400
 226             ;; should be
 227             ;; Tue Jul 9 09:04:21 1996
 228             (setq date
 229                   (cond ((string-match "[A-Z]" (nth 0 date))
 230                          (format "%s %s %s %s %s"
 231                                  (nth 0 date) (nth 2 date) (nth 1 date)
 232                                  (nth 4 date) (nth 3 date)))
 233                         (t
 234                          ;; this really needs to be better but I don't feel
 235                          ;; like writing a date to day converter.
 236                          (format "Sun %s %s %s %s"
 237                                  (nth 1 date) (nth 0 date)
 238                                  (nth 3 date) (nth 2 date)))
 239                         ))
 240             (setq From_ (format "\nFrom %s  %s\n" from date))
 241             (while (string-match "," From_)
 242               (setq From_ (concat (substring From_ 0 (match-beginning 0))
 243                                   (substring From_ (match-end 0)))))
 244             (goto-char (point-min))
 245             (insert From_))))))
 246
 247 ;; The Command Set
 248
 249 ;; AUTHORIZATION STATE
 250
 251 (defun pop3-user (process user)
 252   "Send USER information to POP3 server."
 253   (pop3-send-command process (format "USER %s" user))
 254   (let ((response (pop3-read-response process t)))
 255     (if (not (and response (string-match "+OK" response)))
 256         (error (format "USER %s not valid." user)))))
 257
 258 (defun pop3-pass (process)
 259   "Send authentication information to the server."
 260   (pop3-send-command process (format "PASS %s" pop3-password))
 261   (let ((response (pop3-read-response process t)))
 262     (if (not (and response (string-match "+OK" response)))
 263         (pop3-quit process))))
 264
 265 (defun pop3-apop (process user)
 266   "Send alternate authentication information to the server."
 267   (if (not (fboundp 'md5)) (autoload 'md5 "md5"))
 268   (let ((hash (md5 (concat pop3-timestamp pop3-password))))
 269     (pop3-send-command process (format "APOP %s %s" user hash))
 270     (let ((response (pop3-read-response process t)))
 271       (if (not (and response (string-match "+OK" response)))
 272           (pop3-quit process)))))
 273
 274 ;; TRANSACTION STATE
 275
 276 (defun pop3-stat (process)
 277   "Return the number of messages in the maildrop and the maildrop's size."
 278   (pop3-send-command process "STAT")
 279   (let ((response (pop3-read-response process t)))
 280     (list (string-to-int (nth 1 (pop3-string-to-list response)))
 281           (string-to-int (nth 2 (pop3-string-to-list response))))
 282     ))
 283
 284 (defun pop3-list (process &optional msg)
 285   "Scan listing of available messages.
 286 This function currently does nothing.")
 287
 288 (defun pop3-retr (process msg crashbuf)
 289   "Retrieve message-id MSG to buffer CRASHBUF."
 290   (pop3-send-command process (format "RETR %s" msg))
 291   (pop3-read-response process)
 292   (let ((start pop3-read-point) end)
 293     (save-excursion
 294       (set-buffer (process-buffer process))
 295       (while (not (re-search-forward "^\\.\r\n" nil t))
 296         (accept-process-output process 3)
 297         ;; bill@att.com ... to save wear and tear on the heap
 298         (if (> (buffer-size)  20000) (sleep-for 1))
 299         (if (> (buffer-size)  50000) (sleep-for 1))
 300         (if (> (buffer-size) 100000) (sleep-for 1))
 301         (if (> (buffer-size) 200000) (sleep-for 1))
 302         (if (> (buffer-size) 500000) (sleep-for 1))
 303         ;; bill@att.com
 304         (goto-char start))
 305       (setq pop3-read-point (point-marker))
 306 ;; this code does not seem to work for some POP servers...
 307 ;; and I cannot figure out why not.
 308 ;      (goto-char (match-beginning 0))
 309 ;      (backward-char 2)
 310 ;      (if (not (looking-at "\r\n"))
 311 ;         (insert "\r\n"))
 312 ;      (re-search-forward "\\.\r\n")
 313       (goto-char (match-beginning 0))
 314       (setq end (point-marker))
 315       (pop3-clean-region start end)
 316       (pop3-munge-message-separator start end)
 317       (save-excursion
 318         (set-buffer crashbuf)
 319         (erase-buffer))
 320       (copy-to-buffer crashbuf start end)
 321       (delete-region start end)
 322       )))
 323
 324 (defun pop3-dele (process msg)
 325   "Mark message-id MSG as deleted."
 326   (pop3-send-command process (format "DELE %s" msg))
 327   (pop3-read-response process))
 328
 329 (defun pop3-noop (process msg)
 330   "No-operation."
 331   (pop3-send-command process "NOOP")
 332   (pop3-read-response process))
 333
 334 (defun pop3-last (process)
 335   "Return highest accessed message-id number for the session."
 336   (pop3-send-command process "LAST")
 337   (let ((response (pop3-read-response process t)))
 338     (string-to-int (nth 1 (pop3-string-to-list response)))
 339     ))
 340
 341 (defun pop3-rset (process)
 342   "Remove all delete marks from current maildrop."
 343   (pop3-send-command process "RSET")
 344   (pop3-read-response process))
 345
 346 ;; UPDATE
 347
 348 (defun pop3-quit (process)
 349   "Close connection to POP3 server.
 350 Tell server to remove all messages marked as deleted, unlock the maildrop,
 351 and close the connection."
 352   (pop3-send-command process "QUIT")
 353   (pop3-read-response process t)
 354   (if process
 355       (save-excursion
 356         (set-buffer (process-buffer process))
 357         (goto-char (point-max))
 358         (delete-process process))))
 359 \f
 360 ;; Summary of POP3 (Post Office Protocol version 3) commands and responses
 361
 362 ;;; AUTHORIZATION STATE
 363
 364 ;; Initial TCP connection
 365 ;; Arguments: none
 366 ;; Restrictions: none
 367 ;; Possible responses:
 368 ;;  +OK [POP3 server ready]
 369
 370 ;; USER name
 371 ;; Arguments: a server specific user-id (required)
 372 ;; Restrictions: authorization state [after unsuccessful USER or PASS
 373 ;; Possible responses:
 374 ;;  +OK [valid user-id]
 375 ;;  -ERR [invalid user-id]
 376
 377 ;; PASS string
 378 ;; Arguments: a server/user-id specific password (required)
 379 ;; Restrictions: authorization state, after successful USER
 380 ;; Possible responses:
 381 ;;  +OK [maildrop locked and ready]
 382 ;;  -ERR [invalid password]
 383 ;;  -ERR [unable to lock maildrop]
 384
 385 ;;; TRANSACTION STATE
 386
 387 ;; STAT
 388 ;; Arguments: none
 389 ;; Restrictions: transaction state
 390 ;; Possible responses:
 391 ;;  +OK nn mm [# of messages, size of maildrop]
 392
 393 ;; LIST [msg]
 394 ;; Arguments: a message-id (optional)
 395 ;; Restrictions: transaction state; msg must not be deleted
 396 ;; Possible responses:
 397 ;;  +OK [scan listing follows]
 398 ;;  -ERR [no such message]
 399
 400 ;; RETR msg
 401 ;; Arguments: a message-id (required)
 402 ;; Restrictions: transaction state; msg must not be deleted
 403 ;; Possible responses:
 404 ;;  +OK [message contents follow]
 405 ;;  -ERR [no such message]
 406
 407 ;; DELE msg
 408 ;; Arguments: a message-id (required)
 409 ;; Restrictions: transaction state; msg must not be deleted
 410 ;; Possible responses:
 411 ;;  +OK [message deleted]
 412 ;;  -ERR [no such message]
 413
 414 ;; NOOP
 415 ;; Arguments: none
 416 ;; Restrictions: transaction state
 417 ;; Possible responses:
 418 ;;  +OK
 419
 420 ;; LAST
 421 ;; Arguments: none
 422 ;; Restrictions: transaction state
 423 ;; Possible responses:
 424 ;;  +OK nn [highest numbered message accessed]
 425
 426 ;; RSET
 427 ;; Arguments: none
 428 ;; Restrictions: transaction state
 429 ;; Possible responses:
 430 ;;  +OK [all delete marks removed]
 431
 432 ;;; UPDATE STATE
 433
 434 ;; QUIT
 435 ;; Arguments: none
 436 ;; Restrictions: none
 437 ;; Possible responses:
 438 ;;  +OK [TCP connection closed]