git.chise.org Git - elisp/gnus.git-/blob - lisp/sieve-mode.el

   1 ;;; sieve-mode.el --- Sieve code editing commands for Emacs
   2 ;; Copyright (C) 2001, 2003, 2004, 2005 Free Software Foundation, Inc.
   3
   4 ;; Author: Simon Josefsson <simon@josefsson.org>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; This file contain editing mode functions and font-lock support for
  26 ;; editing Sieve scripts.  It sets up C-mode with support for
  27 ;; sieve-style #-comments and a lightly hacked syntax table.  It was
  28 ;; strongly influenced by awk-mode.el.
  29 ;;
  30 ;; Put something similar to the following in your .emacs to use this file:
  31 ;;
  32 ;; (load "~/lisp/sieve")
  33 ;; (setq auto-mode-alist (cons '("\\.siv\\'" . sieve-mode) auto-mode-alist))
  34 ;;
  35 ;; References:
  36 ;;
  37 ;; RFC 3028,
  38 ;; "Sieve: A Mail Filtering Language",
  39 ;; by Tim Showalter.
  40 ;;
  41 ;; Release history:
  42 ;;
  43 ;; 2001-03-02 version 1.0 posted to gnu.emacs.sources
  44 ;;            version 1.1 change file extension into ".siv" (official one)
  45 ;;                        added keymap and menubar to hook into sieve-manage
  46 ;; 2001-10-31 version 1.2 committed to Oort Gnus
  47
  48 ;;; Code:
  49
  50 (autoload 'sieve-manage "sieve")
  51 (autoload 'sieve-upload "sieve")
  52 (require 'easymenu)
  53 (eval-when-compile
  54   (require 'font-lock))
  55
  56 (defgroup sieve nil
  57   "Sieve."
  58   :group 'languages)
  59
  60 (defcustom sieve-mode-hook nil
  61   "Hook run in sieve mode buffers."
  62   :group 'sieve
  63   :type 'hook)
  64
  65 ;; Font-lock
  66
  67 (defvar sieve-control-commands-face 'sieve-control-commands-face
  68   "Face name used for Sieve Control Commands.")
  69
  70 (defface sieve-control-commands-face
  71   '((((type tty) (class color)) (:foreground "blue" :weight light))
  72     (((class grayscale) (background light)) (:foreground "LightGray" :bold t))
  73     (((class grayscale) (background dark)) (:foreground "DimGray" :bold t))
  74     (((class color) (background light)) (:foreground "Orchid"))
  75     (((class color) (background dark)) (:foreground "LightSteelBlue"))
  76     (t (:bold t)))
  77   "Face used for Sieve Control Commands."
  78   :group 'sieve)
  79
  80 (defvar sieve-action-commands-face 'sieve-action-commands-face
  81   "Face name used for Sieve Action Commands.")
  82
  83 (defface sieve-action-commands-face
  84   '((((type tty) (class color)) (:foreground "blue" :weight bold))
  85     (((class color) (background light)) (:foreground "Blue"))
  86     (((class color) (background dark)) (:foreground "LightSkyBlue"))
  87     (t (:inverse-video t :bold t)))
  88   "Face used for Sieve Action Commands."
  89   :group 'sieve)
  90
  91 (defvar sieve-test-commands-face 'sieve-test-commands-face
  92   "Face name used for Sieve Test Commands.")
  93
  94 (defface sieve-test-commands-face
  95   '((((type tty) (class color)) (:foreground "magenta"))
  96     (((class grayscale) (background light))
  97      (:foreground "LightGray" :bold t :underline t))
  98     (((class grayscale) (background dark))
  99      (:foreground "Gray50" :bold t :underline t))
 100     (((class color) (background light)) (:foreground "CadetBlue"))
 101     (((class color) (background dark)) (:foreground "Aquamarine"))
 102     (t (:bold t :underline t)))
 103   "Face used for Sieve Test Commands."
 104   :group 'sieve)
 105
 106 (defvar sieve-tagged-arguments-face 'sieve-tagged-arguments-face
 107   "Face name used for Sieve Tagged Arguments.")
 108
 109 (defface sieve-tagged-arguments-face
 110   '((((type tty) (class color)) (:foreground "cyan" :weight bold))
 111     (((class grayscale) (background light)) (:foreground "LightGray" :bold t))
 112     (((class grayscale) (background dark)) (:foreground "DimGray" :bold t))
 113     (((class color) (background light)) (:foreground "Purple"))
 114     (((class color) (background dark)) (:foreground "Cyan"))
 115     (t (:bold t)))
 116   "Face used for Sieve Tagged Arguments."
 117   :group 'sieve)
 118
 119
 120 (defconst sieve-font-lock-keywords
 121   (eval-when-compile
 122     (list
 123      ;; control commands
 124      (cons (regexp-opt '("require" "if" "else" "elsif" "stop"))
 125            'sieve-control-commands-face)
 126      ;; action commands
 127      (cons (regexp-opt '("fileinto" "redirect" "reject" "keep" "discard"))
 128            'sieve-action-commands-face)
 129      ;; test commands
 130      (cons (regexp-opt '("address" "allof" "anyof" "exists" "false"
 131                          "true" "header" "not" "size" "envelope"))
 132            'sieve-test-commands-face)
 133      (cons "\\Sw+:\\sw+"
 134            'sieve-tagged-arguments-face))))
 135
 136 ;; Syntax table
 137
 138 (defvar sieve-mode-syntax-table nil
 139   "Syntax table in use in sieve-mode buffers.")
 140
 141 (if sieve-mode-syntax-table
 142     ()
 143   (setq sieve-mode-syntax-table (make-syntax-table))
 144   (modify-syntax-entry ?\\ "\\" sieve-mode-syntax-table)
 145   (modify-syntax-entry ?\n ">   " sieve-mode-syntax-table)
 146   (modify-syntax-entry ?\f ">   " sieve-mode-syntax-table)
 147   (modify-syntax-entry ?\# "<   " sieve-mode-syntax-table)
 148   (modify-syntax-entry ?/ "." sieve-mode-syntax-table)
 149   (modify-syntax-entry ?* "." sieve-mode-syntax-table)
 150   (modify-syntax-entry ?+ "." sieve-mode-syntax-table)
 151   (modify-syntax-entry ?- "." sieve-mode-syntax-table)
 152   (modify-syntax-entry ?= "." sieve-mode-syntax-table)
 153   (modify-syntax-entry ?% "." sieve-mode-syntax-table)
 154   (modify-syntax-entry ?< "." sieve-mode-syntax-table)
 155   (modify-syntax-entry ?> "." sieve-mode-syntax-table)
 156   (modify-syntax-entry ?& "." sieve-mode-syntax-table)
 157   (modify-syntax-entry ?| "." sieve-mode-syntax-table)
 158   (modify-syntax-entry ?_ "_" sieve-mode-syntax-table)
 159   (modify-syntax-entry ?\' "\"" sieve-mode-syntax-table))
 160
 161 ;; Key map definition
 162
 163 (defvar sieve-mode-map
 164   (let ((map (make-sparse-keymap)))
 165     (define-key map "\C-c\C-l" 'sieve-upload)
 166     (define-key map "\C-c\C-c" 'sieve-upload-and-bury)
 167     (define-key map "\C-c\C-m" 'sieve-manage)
 168     map)
 169   "Key map used in sieve mode.")
 170
 171 ;; Menu definition
 172
 173 (defvar sieve-mode-menu nil
 174   "Menubar used in sieve mode.")
 175
 176 ;; Code for Sieve editing mode.
 177
 178 ;;;###autoload
 179 (define-derived-mode sieve-mode c-mode "Sieve"
 180   "Major mode for editing Sieve code.
 181 This is much like C mode except for the syntax of comments.  Its keymap
 182 inherits from C mode's and it has the same variables for customizing
 183 indentation.  It has its own abbrev table and its own syntax table.
 184
 185 Turning on Sieve mode runs `sieve-mode-hook'."
 186   (set (make-local-variable 'paragraph-start) (concat "$\\|" page-delimiter))
 187   (set (make-local-variable 'paragraph-separate) paragraph-start)
 188   (set (make-local-variable 'comment-start) "#")
 189   (set (make-local-variable 'comment-end) "")
 190   ;;(set (make-local-variable 'comment-start-skip) "\\(^\\|\\s-\\);?#+ *")
 191   (set (make-local-variable 'comment-start-skip) "#+ *")
 192   (unless (featurep 'xemacs)
 193     (set (make-local-variable 'font-lock-defaults)
 194          '(sieve-font-lock-keywords nil nil ((?_ . "w")))))
 195   (easy-menu-add-item nil nil sieve-mode-menu))
 196
 197 ;; Menu
 198
 199 (easy-menu-define sieve-mode-menu sieve-mode-map
 200   "Sieve Menu."
 201   '("Sieve"
 202     ["Upload script" sieve-upload t]
 203     ["Manage scripts on server" sieve-manage t]))
 204
 205 (provide 'sieve-mode)
 206
 207 ;; sieve-mode.el ends here