mel-q-ccl.el

   1 ;;; mel-ccl.el: CCL based encoder/decoder of Quoted-Printable
   2 ;;;             and Q-encoding
   3
   4 ;; Copyright (C) 1998 Tanaka Akira
   5
   6 ;; Author: Tanaka Akira <akr@jaist.ac.jp>
   7 ;; Created: 1998/9/17
   8 ;; Keywords: MIME, Quoted-Printable, Q-encoding
   9
  10 ;; This file is part of FLIM (Faithful Library about Internet Message).
  11
  12 ;; This program is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 2, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Code:
  28
  29 (require 'ccl)
  30 (require 'pccl)
  31 (require 'mime-def)
  32
  33
  34 ;;; @ constants
  35 ;;;
  36
  37 (eval-when-compile
  38
  39 (defconst mel-ccl-16-table
  40   '(  0   1   2   3   4   5   6   7   8   9  10  11  12  13  14  15))
  41
  42 (defconst mel-ccl-28-table
  43   '(  0   1   2   3   4   5   6   7   8   9  10  11  12  13  14  15
  44      16  17  18  19  20  21  22  23  24  25  26  27))
  45
  46 (defconst mel-ccl-256-table
  47   '(  0   1   2   3   4   5   6   7   8   9  10  11  12  13  14  15
  48      16  17  18  19  20  21  22  23  24  25  26  27  28  29  30  31
  49      32  33  34  35  36  37  38  39  40  41  42  43  44  45  46  47
  50      48  49  50  51  52  53  54  55  56  57  58  59  60  61  62  63
  51      64  65  66  67  68  69  70  71  72  73  74  75  76  77  78  79
  52      80  81  82  83  84  85  86  87  88  89  90  91  92  93  94  95
  53      96  97  98  99 100 101 102 103 104 105 106 107 108 109 110 111
  54     112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127
  55     128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143
  56     144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159
  57     160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175
  58     176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191
  59     192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207
  60     208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223
  61     224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239
  62     240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255))
  63
  64 (defconst mel-ccl-256-to-16-table
  65   '(nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  66     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  67     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  68       0   1   2   3   4   5   6   7   8   9 nil nil nil nil nil nil
  69     nil  10  11  12  13  14  15 nil nil nil nil nil nil nil nil nil
  70     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  71     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  72     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  73     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  74     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  75     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  76     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  77     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  78     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  79     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil
  80     nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil))
  81
  82 (defconst mel-ccl-16-to-256-table
  83   (mapcar 'char-int "0123456789ABCDEF"))
  84
  85 (defconst mel-ccl-high-table
  86   (vconcat
  87    (mapcar
  88     (lambda (v) (nth (lsh v -4) mel-ccl-16-to-256-table))
  89     mel-ccl-256-table)))
  90
  91 (defconst mel-ccl-low-table
  92   (vconcat
  93    (mapcar
  94     (lambda (v) (nth (logand v 15) mel-ccl-16-to-256-table))
  95     mel-ccl-256-table)))
  96
  97 (defconst mel-ccl-u-raw
  98   (mapcar
  99    'char-int
 100    "0123456789\
 101 ABCDEFGHIJKLMNOPQRSTUVWXYZ\
 102 abcdefghijklmnopqrstuvwxyz\
 103 !@#$%&'()*+,-./:;<>@[\\]^`{|}~"))
 104
 105 (defconst mel-ccl-c-raw
 106   (mapcar
 107    'char-int
 108    "0123456789\
 109 ABCDEFGHIJKLMNOPQRSTUVWXYZ\
 110 abcdefghijklmnopqrstuvwxyz\
 111 !@#$%&'*+,-./:;<>@[]^`{|}~"))
 112
 113 (defconst mel-ccl-p-raw
 114   (mapcar
 115    'char-int
 116    "0123456789\
 117 ABCDEFGHIJKLMNOPQRSTUVWXYZ\
 118 abcdefghijklmnopqrstuvwxyz\
 119 !*+-/"))
 120
 121 (defconst mel-ccl-qp-table
 122   [enc enc enc enc enc enc enc enc enc wsp lf  enc enc cr  enc enc
 123    enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc
 124    wsp raw raw raw raw raw raw raw raw raw raw raw raw raw raw raw
 125    raw raw raw raw raw raw raw raw raw raw raw raw raw enc raw raw
 126    raw raw raw raw raw raw raw raw raw raw raw raw raw raw raw raw
 127    raw raw raw raw raw raw raw raw raw raw raw raw raw raw raw raw
 128    raw raw raw raw raw raw raw raw raw raw raw raw raw raw raw raw
 129    raw raw raw raw raw raw raw raw raw raw raw raw raw raw raw enc
 130    enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc
 131    enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc
 132    enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc
 133    enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc
 134    enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc
 135    enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc
 136    enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc
 137    enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc enc])
 138
 139 )
 140
 141
 142 ;;; @ CCL programs
 143 ;;;
 144
 145 ;;; Q
 146
 147 (define-ccl-program mel-ccl-decode-q
 148   `(1
 149     ((loop
 150       (read-branch
 151        r0
 152        ,@(mapcar
 153           (lambda (r0)
 154             (cond
 155              ((= r0 (char-int ?_))
 156               `(write-repeat ? ))
 157              ((= r0 (char-int ?=))
 158               `((loop
 159                  (read-branch
 160                   r1
 161                   ,@(mapcar
 162                      (lambda (v)
 163                        (if (integerp v)
 164                            `((r0 = ,v) (break))
 165                          '(repeat)))
 166                      mel-ccl-256-to-16-table)))
 167                 (loop
 168                  (read-branch
 169                   r1
 170                   ,@(mapcar
 171                      (lambda (v)
 172                        (if (integerp v)
 173                            `((write r0 ,(vconcat
 174                                          (mapcar
 175                                           (lambda (r0)
 176                                             (logior (lsh r0 4) v))
 177                                           mel-ccl-16-table)))
 178                              (break))
 179                          '(repeat)))
 180                      mel-ccl-256-to-16-table)))
 181                 (repeat)))
 182              (t
 183               `(write-repeat ,r0))))
 184           mel-ccl-256-table))))))
 185
 186 (eval-when-compile
 187
 188 (defun mel-ccl-encode-q-generic (raw)
 189   `(3
 190     (loop
 191      (loop
 192       (read-branch
 193        r0
 194        ,@(mapcar
 195           (lambda (r0)
 196             (cond
 197              ((= r0 32) `(write-repeat ?_))
 198              ((member r0 raw) `(write-repeat ,r0))
 199              (t '(break))))
 200           mel-ccl-256-table)))
 201      (write ?=)
 202      (write r0 ,mel-ccl-high-table)
 203      (write r0 ,mel-ccl-low-table)
 204      (repeat))))
 205
 206 ;; On xemacs, generated program counts iso-8859-1 8bit character as 6bytes.
 207 (defun mel-ccl-count-q-length (raw)
 208   `(0
 209     ((r0 = 0)
 210      (loop
 211       (read-branch
 212        r1
 213        ,@(mapcar
 214           (lambda (r1)
 215             (if (or (= r1 32) (member r1 raw))
 216                 '((r0 += 1) (repeat))
 217               '((r0 += 3) (repeat))))
 218           mel-ccl-256-table))))))
 219
 220 )
 221
 222 (define-ccl-program mel-ccl-encode-uq
 223   (mel-ccl-encode-q-generic mel-ccl-u-raw))
 224 (define-ccl-program mel-ccl-encode-cq
 225   (mel-ccl-encode-q-generic mel-ccl-c-raw))
 226 (define-ccl-program mel-ccl-encode-pq
 227   (mel-ccl-encode-q-generic mel-ccl-p-raw))
 228
 229 (define-ccl-program mel-ccl-count-uq
 230   (mel-ccl-count-q-length mel-ccl-u-raw))
 231 (define-ccl-program mel-ccl-count-cq
 232   (mel-ccl-count-q-length mel-ccl-c-raw))
 233 (define-ccl-program mel-ccl-count-pq
 234   (mel-ccl-count-q-length mel-ccl-p-raw))
 235
 236 ;; Quoted-Printable
 237
 238 (eval-when-compile
 239
 240 (defun mel-ccl-try-to-read-crlf (input-crlf reg eof-reg cr-eof lf-eof crlf-eof succ fail-cr fail-lf fail-crlf)
 241   (if input-crlf
 242       `((,eof-reg = ,cr-eof) (read-if (,reg == ?\r)
 243         ((,eof-reg = ,lf-eof) (read-if (,reg == ?\n)
 244          ,succ
 245          ,fail-lf))
 246         ,fail-cr))
 247     `((,eof-reg = ,crlf-eof) (read-if (,reg == ?\n)
 248       ,succ
 249       ,fail-crlf))))
 250
 251 ;; Generated CCL program works not properly on 20.2 because CCL_EOF_BLOCK
 252 ;; is not executed.
 253 (defun mel-ccl-encode-quoted-printable-generic (input-crlf output-crlf)
 254   `(4
 255     ((r6 = 0)                           ; column
 256      (r5 = 0)                           ; previous character is white space
 257      (r4 = 0)                           ; label for eof block
 258      (read r0)
 259      (loop                              ; r6 <= 75
 260       (loop
 261        (loop
 262         (branch
 263          r0
 264          ,@(mapcar
 265             (lambda (r0)
 266               (let ((tmp (aref mel-ccl-qp-table r0)))
 267                 (cond
 268                  ((eq r0 (char-int ?F))
 269                   `(if (r6 == 0)
 270                        ((r4 = 15) (read-if (r0 == ?r)
 271                         ((r4 = 16) (read-if (r0 == ?o)
 272                          ((r4 = 17) (read-if (r0 == ?m)
 273                           ((r4 = 18) (read-if (r0 == ? )
 274                            ((r6 = 7)
 275                             (r5 = 1)
 276                             (write "=46rom ")
 277                             (r4 = 19)
 278                             (read r0)
 279                             (repeat))
 280                            ((r6 = 4)
 281                             (write-repeat "From"))))
 282                           ((r6 = 3)
 283                            (write-repeat "Fro"))))
 284                          ((r6 = 2)
 285                           (write-repeat "Fr"))))
 286                         ((r6 = 1)
 287                          (write-repeat "F"))))
 288                      ((r3 = 0) (break)) ; RAW
 289                      ))
 290                  ((eq r0 (char-int ?.))
 291                   `(if (r6 == 0)
 292                        ,(mel-ccl-try-to-read-crlf
 293                          input-crlf
 294                          'r0 'r4 20 21 22
 295                          `((write ,(if output-crlf "=2E\r\n" "=2E\n"))
 296                            (r4 = 23)
 297                            (read r0)
 298                            (repeat))
 299                          '((r6 = 1)
 300                            (write-repeat "."))
 301                          '((r6 = 4)
 302                            (write-repeat ".=0D"))
 303                          '((r6 = 1)
 304                            (write-repeat ".")))
 305                      ((r3 = 0) (break)) ; RAW
 306                      ))
 307                  ((eq tmp 'raw) '((r3 = 0) (break))) ; RAW
 308                  ((eq tmp 'enc) '((r3 = 1) (break))) ; ENC
 309                  ((eq tmp 'wsp) '((r3 = 2) (break))) ; WSP
 310                  ((eq tmp 'cr) (if input-crlf
 311                                    '((r3 = 3) (break)) ; CR
 312                                  '((r3 = 1) (break)))) ; ENC
 313                  ((eq tmp 'lf) (if input-crlf
 314                                    '((r3 = 1) (break)) ; ENC
 315                                  '((r3 = 3) (break)))) ; CRLF
 316                  )))
 317             mel-ccl-256-table)))
 318        (branch
 319         r3
 320         ;; r0:r3=RAW
 321         (if (r6 < 75)
 322             ((r6 += 1)
 323              (r5 = 0)
 324              (r4 = 1)
 325              (write-read-repeat r0))
 326           (break))
 327         ;; r0:r3=ENC
 328         ((r5 = 0)
 329          (if (r6 < 73)
 330              ((r6 += 3)
 331               (write "=")
 332               (write r0 ,mel-ccl-high-table)
 333               (r4 = 2)
 334               (write-read-repeat r0 ,mel-ccl-low-table))
 335            (if (r6 > 73)
 336                ((r6 = 3)
 337                 (write ,(if output-crlf "=\r\n=" "=\n="))
 338                 (write r0 ,mel-ccl-high-table)
 339                 (r4 = 3)
 340                 (write-read-repeat r0 ,mel-ccl-low-table))
 341              (break))))
 342         ;; r0:r3=WSP
 343         (if (r6 < 74)
 344             (break)
 345           (if (r6 < 75)
 346               ((r6 += 1)
 347                (r5 = 1)
 348                (r4 = 4)
 349                (write-read-repeat r0))
 350             ((write ,(if output-crlf "=\r\n" "=\n"))
 351              (r6 = 0)
 352              (r5 = 0)
 353              ;; (r4 = 5)
 354              (repeat))))
 355         ;; r0:r3=CR/CRLF
 356         ,(if input-crlf
 357              ;; r0:r3=CR
 358              `((if ((r6 > 73) & r5)
 359                    ((r6 = 0)
 360                     (r5 = 0)
 361                     (write ,(if output-crlf "=\r\n" "=\n"))))
 362                (break))
 363            ;; r0:r3=CRLF
 364            `(if r5
 365                 ;; WSP ; r0:r3=CRLF
 366                 ((r5 = 0)
 367                  (r6 = 0)
 368                  (write ,(if output-crlf "=\r\n" "=\n"))
 369                  ,@(if output-crlf '((write ?\r)) '())
 370                  (r4 = 0)
 371                  (write-read-repeat r0))
 372               ;; noWSP ; r0:r3=CRLF
 373               ((r5 = 0)
 374                (r6 = 0)
 375                ,@(if output-crlf '((write ?\r)) '())
 376                (r4 = 0)
 377                (write-read-repeat r0)))
 378            )))
 379       ;; r0:r3={RAW,ENC,WSP,CR}
 380       (loop
 381        ,(funcall
 382          (lambda (after-cr after-raw-enc-wsp)
 383            (if input-crlf
 384                `(if (r0 == ?\r)
 385                     ,after-cr
 386                   ,after-raw-enc-wsp)
 387              after-raw-enc-wsp))
 388          ;; r0=\r:r3=CR
 389          `((r4 = 6)
 390            (read r0)
 391            ;; CR:r3=CR r0
 392            (if (r0 == ?\n)
 393                ;; CR:r3=CR r0=LF
 394                (if r5
 395                    ;; r5=WSP ; CR:r3=CR r0=LF
 396                    ((r6 = 0)
 397                     (r5 = 0)
 398                     (write ,(if output-crlf "=\r\n\r\n" "=\n\n"))
 399                     (r4 = 7)
 400                     (read r0)
 401                     (break))
 402                  ;; r5=noWSP ; CR:r3=CR r0=LF
 403                  ((r6 = 0)
 404                   (r5 = 0)
 405                   (write ,(if output-crlf "\r\n" "\n"))
 406                   (r4 = 8)
 407                   (read r0)
 408                   (break)))
 409              ;; CR:r3=CR r0=noLF
 410              (if (r6 < 73)
 411                  ((r6 += 3)
 412                   (r5 = 0)
 413                   (write "=0D")
 414                   (break))
 415                (if (r6 == 73)
 416                    (if (r0 == ?\r)
 417                        ;; CR:r3=CR r0=CR
 418                        ((r4 = 9)
 419                         (read r0)
 420                         ;; CR:r3=CR CR r0
 421                         (if (r0 == ?\n)
 422                             ;; CR:r3=CR CR LF
 423                             ((r6 = 0)
 424                              (r5 = 0)
 425                              (write ,(if output-crlf "=0D\r\n" "=0D\n"))
 426                              (r4 = 10)
 427                              (read r0)
 428                              (break))
 429                           ;; CR:r3=CR CR noLF
 430                           ((r6 = 6)
 431                            (r5 = 0)
 432                            (write ,(if output-crlf "=\r\n=0D=0D" "=\n=0D=0D"))
 433                            (break))))
 434                      ;; CR:r3=CR r0=noLFnorCR
 435                      ((r6 = 3)
 436                       (r5 = 0)
 437                       (write ,(if output-crlf "=\r\n=0D" "=\n=0D"))
 438                       (break)))
 439                  ((r6 = 3)
 440                   (r5 = 0)
 441                   (write ,(if output-crlf "=\r\n=0D" "=\n=0D"))
 442                   (break))))))
 443          (funcall
 444           (lambda (after-newline after-cr-nolf after-nonewline)
 445             (if input-crlf
 446                 ;; r0:r3={RAW,ENC,WSP}
 447                 `((r4 = 11)
 448                   (read r1)
 449                   ;; r0:r3={RAW,ENC,WSP} r1
 450                   (if (r1 == ?\r)
 451                       ;; r0:r3={RAW,ENC,WSP} r1=CR
 452                       ((r4 = 12)
 453                        (read r1)
 454                        ;; r0:r3={RAW,ENC,WSP} CR r1
 455                        (if (r1 == ?\n)
 456                            ;; r0:r3={RAW,ENC,WSP} CR r1=LF
 457                            ,after-newline
 458                          ;; r0:r3={RAW,ENC,WSP} CR r1=noLF
 459                          ,after-cr-nolf))
 460                     ;; r0:r3={RAW,ENC,WSP} r1:noCR
 461                     ,after-nonewline))
 462               ;; r0:r3={RAW,ENC,WSP}
 463               `((r4 = 11)
 464                 (read r1)
 465                 ;; r0:r3={RAW,ENC,WSP} r1
 466                 (if (r1 == ?\n)
 467                     ;; r0:r3={RAW,ENC,WSP} r1=CRLF
 468                     ,after-newline
 469                   ;; r0:r3={RAW,ENC,WSP} r1:noCRLF
 470                   ,after-nonewline))))
 471           ;; after-newline
 472           ;; r0:r3={RAW,ENC,WSP} CR r1=LF
 473           ;; r0:r3={RAW,ENC,WSP} r1=CRLF
 474           `((r6 = 0)
 475             (r5 = 0)
 476             (branch
 477              r3
 478              ;; r0:r3=RAW CR r1=LF
 479              ;; r0:r3=RAW r1=CRLF
 480              ((write r0)
 481               (write ,(if output-crlf "\r\n" "\n"))
 482               (r4 = 13)
 483               (read r0)
 484               (break))
 485              ;; r0:r3=ENC CR r1=LF
 486              ;; r0:r3=ENC r1=CRLF
 487              ((write ?=)
 488               (write r0 ,mel-ccl-high-table)
 489               (write r0 ,mel-ccl-low-table)
 490               (write ,(if output-crlf "\r\n" "\n"))
 491               (r4 = 14)
 492               (read r0)
 493               (break))
 494              ;; r0:r3=WSP CR r1=LF
 495              ;; r0:r3=WSP r1=CRLF
 496              ((write ?=)
 497               (write r0 ,mel-ccl-high-table)
 498               (write r0 ,mel-ccl-low-table)
 499               (write ,(if output-crlf "\r\n" "\n"))
 500               (r4 = 14)
 501               (read r0)
 502               (break))))
 503           ;; after-cr-nolf
 504           ;; r0:r3={RAW,ENC,WSP} CR r1=noLF
 505           `((branch
 506              r3
 507              ;; r0:r3=RAW CR r1:noLF
 508              ((r6 = 4)
 509               (r5 = 0)
 510               (write ,(if output-crlf "=\r\n" "=\n"))
 511               (write r0)
 512               (write "=0D")
 513               (r0 = (r1 + 0)) ; "+ 0" is workaround for mule 2.3@19.34.
 514               (break))
 515              ;; r0:r3=ENC CR r1:noLF
 516              ((r6 = 6)
 517               (r5 = 0)
 518               (write ,(if output-crlf "=\r\n=" "=\n="))
 519               (write r0 ,mel-ccl-high-table)
 520               (write r0 ,mel-ccl-low-table)
 521               (write "=0D")
 522               (r0 = (r1 + 0))
 523               (break))
 524              ;; r0:r3=WSP CR r1:noLF
 525              ((r5 = 0)
 526               (write r0)
 527               (r0 = (r1 + 0))
 528               (if (r6 < 72)
 529                   ((write "=0D")
 530                    (r6 += 4)
 531                    (break))
 532                 ;; If r6 is 72, and r1 is CR and the next byte is LF,
 533                 ;; we can write r0, "=0D" and hard linebreak.
 534                 ;; But the next byte is unknown and reading it causes buffering problem.
 535                 ;; So, we give up and write soft linebreak.
 536                 ((write ,(if output-crlf "=\r\n=0D" "=\n=0D"))
 537                  (r6 = 3)
 538                  (break))))))
 539           ;; after-nonewline
 540           ;; r0:r3={RAW,ENC,WSP} r1:noCR
 541           ;; r0:r3={RAW,ENC,WSP} r1:noCRLF
 542           `((branch
 543              r3
 544              ;; r0:r3=RAW r1:noCR
 545              ;; r0:r3=RAW r1:noCRLF
 546              ((r6 = 1)
 547               (r5 = 0)
 548               (write ,(if output-crlf "=\r\n" "=\n"))
 549               (write r0)
 550               (r0 = (r1 + 0))
 551               (break))
 552              ;; r0:r3=ENC r1:noCR
 553              ;; r0:r3=ENC r1:noCRLF
 554              ((r6 = 3)
 555               (r5 = 0)
 556               (write ,(if output-crlf "=\r\n=" "=\n="))
 557               (write r0 ,mel-ccl-high-table)
 558               (write r0 ,mel-ccl-low-table)
 559               (r0 = (r1 + 0))
 560               (break))
 561              ;; r0:r3=WSP r1:noCR
 562              ;; r0:r3=WSP r1:noCRLF
 563              ((r6 += 1)
 564               (r5 = 1)
 565               (write r0)
 566               (r0 = (r1 + 0))
 567               (break))
 568              )))))
 569       (repeat)))
 570     ;; EOF
 571     (                                   ;(write "[EOF:") (write r4 ,mel-ccl-high-table) (write r4 ,mel-ccl-low-table) (write "]")
 572      (branch
 573       r4
 574       ;; 0: (start) ;
 575       (end)
 576       ;; 1: RAW ;
 577       (end)
 578       ;; 2: r0:r3=ENC ;
 579       (end)
 580       ;; 3: SOFTBREAK r0:r3=ENC ;
 581       (end)
 582       ;; 4: r0:r3=WSP ;
 583       ((write ,(if output-crlf "=\r\n" "=\n")) (end))
 584       ;; 5: SOFTBREAK ; r0:r3=WSP
 585       ;; Now this is ignored.
 586       ((write r0)
 587        (write ,(if output-crlf "=\r\n" "=\n")) (end))
 588       ;; 6: ; r0=\r:r3=CR
 589       (if (r6 <= 73)
 590           ((write "=0D") (end))
 591         ((write ,(if output-crlf "=\r\n=0D" "=\n=0D")) (end)))
 592       ;; 7: r5=WSP SOFTBREAK CR:r3=CR r0=LF ;
 593       (end)
 594       ;; 8: r5=noWSP CR:r3=CR r0=LF ;
 595       (end)
 596       ;; 9: (r6=73) ; CR:r3=CR r0=CR
 597       ((write ,(if output-crlf "=\r\n=0D=0D" "=\n=0D=0D")) (end))
 598       ;; 10: (r6=73) CR:r3=CR CR LF ;
 599       (end)
 600       ;; 11: ; r0:r3={RAW,ENC,WSP}
 601       (branch
 602        r3
 603        ((write r0) (end))
 604        ((write "=")
 605         (write r0 ,mel-ccl-high-table)
 606         (write r0 ,mel-ccl-low-table)
 607         (end))
 608        ((write "=")
 609         (write r0 ,mel-ccl-high-table)
 610         (write r0 ,mel-ccl-low-table)
 611         (end)))
 612       ;; 12: ; r0:r3={RAW,ENC,WSP} r1=CR
 613       (branch
 614        r3
 615        ;; ; r0:r3=RAW r1=CR
 616        ((write ,(if output-crlf "=\r\n" "=\n"))
 617         (write r0)
 618         (write "=0D")
 619         (end))
 620        ;; ; r0:r3=ENC r1=CR
 621        ((write ,(if output-crlf "=\r\n=" "=\n="))
 622         (write r0 ,mel-ccl-high-table)
 623         (write r0 ,mel-ccl-low-table)
 624         (write "=0D")
 625         (end))
 626        ;; ; r0:r3=WSP r1=CR
 627        (if (r6 <= 72)
 628            ((write r0)
 629             (write "=0D")
 630             (end))
 631          (if (r6 <= 74)
 632              ((write r0)
 633               (write ,(if output-crlf "=\r\n=0D" "=\n=0D"))
 634               (end))
 635            ((write ,(if output-crlf "=\r\n" "=\n"))
 636             (write r0)
 637             (write "=0D")
 638             (end)))))
 639       ;; 13: r0:r3=RAW CR LF ;
 640       ;; 13: r0:r3=RAW CRLF ;
 641       (end)
 642       ;; 14: r0:r3=ENC CR LF ;
 643       ;; 14: r0:r3=ENC CRLF ;
 644       ;; 14: r0:r3=WSP CR LF ;
 645       ;; 14: r0:r3=WSP CRLF ;
 646       (end)
 647       ;; 15: r6=0 ; "F"
 648       ((write "F") (end))
 649       ;; 16: r6=0 ; "Fr"
 650       ((write "Fr") (end))
 651       ;; 17: r6=0 ; "Fro"
 652       ((write "Fro") (end))
 653       ;; 18: r6=0 ; "From"
 654       ((write "From") (end))
 655       ;; 19: r6=0 "From " ;
 656       (end)
 657       ;; 20: r6=0 ; "."
 658       ((write ".") (end))
 659       ;; 21: r6=0 ; ".\r"
 660       ((write ".=0D") (end))
 661       ;; 22: r6=0 ; "."
 662       ((write ".") (end))
 663       ;; 23: r6=0 ".\r\n" ;
 664       (end)
 665       ))
 666     ))
 667
 668 (defun mel-ccl-decode-quoted-printable-generic (input-crlf output-crlf)
 669   `(1
 670     ((read r0)
 671      (loop
 672       (branch
 673        r0
 674        ,@(mapcar
 675           (lambda (r0)
 676             (let ((tmp (aref mel-ccl-qp-table r0)))
 677               (cond
 678                ((eq tmp 'raw) `(write-read-repeat r0))
 679                ((eq tmp 'wsp) (if (eq r0 (char-int ? ))
 680                                   `(r1 = 1)
 681                                 `(r1 = 0)))
 682                ((eq tmp 'cr)
 683                 (if input-crlf
 684                     ;; r0='\r'
 685                     `((read r0)
 686                       ;; '\r' r0
 687                       (if (r0 == ?\n)
 688                           ;; '\r' r0='\n'
 689                           ;; hard line break found.
 690                           ,(if output-crlf
 691                                '((write ?\r)
 692                                  (write-read-repeat r0))
 693                              '(write-read-repeat r0))
 694                         ;; '\r' r0:[^\n]
 695                         ;; invalid control character (bare CR) found.
 696                         ;; -> ignore it and rescan from r0.
 697                         (repeat)))
 698                   ;; r0='\r'
 699                   ;; invalid character (bare CR) found.
 700                   ;; -> ignore.
 701                   `((read r0)
 702                     (repeat))))
 703                ((eq tmp 'lf)
 704                 (if input-crlf
 705                     ;; r0='\n'
 706                     ;; invalid character (bare LF) found.
 707                     ;; -> ignore.
 708                     `((read r0)
 709                       (repeat))
 710                   ;; r0='\r\n'
 711                   ;; hard line break found.
 712                   (if output-crlf
 713                       '((write ?\r)
 714                         (write-read-repeat r0))
 715                     '(write-read-repeat r0))))
 716                ((eq r0 (char-int ?=))
 717                 ;; r0='='
 718                 `((read r0)
 719                   ;; '=' r0
 720                   (r1 = (r0 == ?\t))
 721                   (if ((r0 == ? ) | r1)
 722                       ;; '=' r0:[\t ]
 723                       ;; Skip transport-padding.
 724                       ;; It should check CR LF after
 725                       ;; transport-padding.
 726                       (loop
 727                        (read-if (r0 == ?\t)
 728                                 (repeat)
 729                                 (if (r0 == ? )
 730                                     (repeat)
 731                                   (break)))))
 732                   ;; '=' [\t ]* r0:[^\t ]
 733                   (branch
 734                    r0
 735                    ,@(mapcar
 736                       (lambda (r0)
 737                         (cond
 738                          ((eq r0 (char-int ?\r))
 739                           (if input-crlf
 740                               ;; '=' [\t ]* r0='\r'
 741                               `((read r0)
 742                                 ;; '=' [\t ]* '\r' r0
 743                                 (if (r0 == ?\n)
 744                                     ;; '=' [\t ]* '\r' r0='\n'
 745                                     ;; soft line break found.
 746                                     ((read r0)
 747                                      (repeat))
 748                                   ;; '=' [\t ]* '\r' r0:[^\n]
 749                                   ;; invalid input ->
 750                                   ;; output "=" and rescan from r0.
 751                                   ((write "=")
 752                                    (repeat))))
 753                             ;; '=' [\t ]* r0='\r'
 754                             ;; invalid input (bare CR found) ->
 755                             ;; output "=" and rescan from next.
 756                             `((write ?=)
 757                               (read r0)
 758                               (repeat))))
 759                          ((eq r0 (char-int ?\n))
 760                           (if input-crlf
 761                               ;; '=' [\t ]* r0='\n'
 762                               ;; invalid input (bare LF found) ->
 763                               ;; output "=" and rescan from next.
 764                               `((write ?=)
 765                                 (read r0)
 766                                 (repeat))
 767                             ;; '=' [\t ]* r0='\r\n'
 768                             ;; soft line break found.
 769                             `((read r0)
 770                               (repeat))))
 771                          ((setq tmp (nth r0 mel-ccl-256-to-16-table))
 772                           ;; '=' [\t ]* r0:[0-9A-F]
 773                           ;; upper nibble of hexadecimal digit found.
 774                           `((r1 = (r0 + 0))
 775                             (r0 = ,tmp)))
 776                          (t
 777                           ;; '=' [\t ]* r0:[^\r0-9A-F]
 778                           ;; invalid input ->
 779                           ;; output "=" and rescan from r0.
 780                           `((write ?=)
 781                             (repeat)))))
 782                       mel-ccl-256-table))
 783                   ;; '=' [\t ]* r1:r0:[0-9A-F]
 784                   (read-branch
 785                    r2
 786                    ,@(mapcar
 787                       (lambda (r2)
 788                         (if (setq tmp (nth r2 mel-ccl-256-to-16-table))
 789                             ;; '=' [\t ]* r1:r0:[0-9A-F] r2:[0-9A-F]
 790                             `(write-read-repeat
 791                               r0
 792                               ,(vconcat
 793                                 (mapcar
 794                                  (lambda (r0)
 795                                    (logior (lsh r0 4) tmp))
 796                                  mel-ccl-16-table)))
 797                           ;; '=' [\t ]* r1:r0:[0-9A-F] r2:[^0-9A-F]
 798                           ;; invalid input
 799                           `(r3 = 0)     ; nop
 800                           ))
 801                       mel-ccl-256-table))
 802                   ;; '=' [\t ]* r1:r0:[0-9A-F] r2:[^0-9A-F]
 803                   ;; invalid input ->
 804                   ;; output "=" with hex digit and rescan from r2.
 805                   (write ?=)
 806                   (r0 = (r2 + 0))
 807                   (write-repeat r1)))
 808                (t
 809                 ;; r0:[^\t\r -~]
 810                 ;; invalid character found.
 811                 ;; -> ignore.
 812                 `((read r0)
 813                   (repeat))))))
 814           mel-ccl-256-table))
 815       ;; r1[0]:[\t ]
 816       (loop
 817        ,@(apply
 818           'append
 819           (mapcar
 820            (lambda (regnum)
 821              (let ((reg (aref [r1 r2 r3 r4 r5] regnum)))
 822                (apply
 823                 'append
 824                 (mapcar
 825                  (lambda (bit)
 826                    (if (= bit 0)
 827                        (if (= regnum 0)
 828                            nil
 829                          `((read r0)
 830                            (if (r0 == ?\t)
 831                                (,reg = 0)
 832                              (if (r0 == ?\ )
 833                                  (,reg = 1)
 834                                ((r6 = ,(+ (* regnum 28) bit))
 835                                 (break))))))
 836                      `((read r0)
 837                        (if (r0 == ?\ )
 838                            (,reg |= ,(lsh 1 bit))
 839                          (if (r0 != ?\t)
 840                              ((r6 = ,(+ (* regnum 28) bit))
 841                               (break)))))))
 842                  mel-ccl-28-table))))
 843            '(0 1 2 3 4)))
 844        ;; white space buffer exhaust.
 845        ;; error: line length limit (76bytes) violation.
 846        ;; -> ignore these white spaces.
 847        (repeat))
 848       ,(if input-crlf
 849            `(if (r0 == ?\r)
 850                 ((read r0)
 851                  (if (r0 == ?\n)
 852                      ;; trailing white spaces found.
 853                      ;; -> ignore these white spacs.
 854                      ((write ,(if output-crlf "\r\n" "\n"))
 855                       (read r0)
 856                       (repeat))
 857                    ;; [\t ]* \r r0:[^\n]
 858                    ;; error: bare CR found.
 859                    ;; -> output white spaces and ignore bare CR.
 860                    ))
 861               ;; [\t ]* r0:[^\r]
 862               ;; middle white spaces found.
 863               )
 864          `(if (r0 == ?\n)
 865               ;; trailing white spaces found.
 866               ;; -> ignore these white spacs.
 867               ((write ,(if output-crlf "\r\n" "\n"))
 868                (read r0)
 869                (repeat))
 870             ;; [\t ]* r0:[^\n]
 871             ;; middle white spaces found.
 872             ))
 873       ,@(apply
 874          'append
 875          (mapcar
 876           (lambda (regnum)
 877             (let ((reg (aref [r1 r2 r3 r4 r5] regnum)))
 878               (apply
 879                'append
 880                (mapcar
 881                 (lambda (bit)
 882                   `((if (,reg & ,(lsh 1 bit))
 883                         (write ?\ )
 884                       (write ?\t))
 885                     (if (r6 == ,(+ (* regnum 28) bit 1))
 886                         (repeat))))
 887                 mel-ccl-28-table))))
 888           '(0 1 2 3 4)))
 889       (repeat)
 890       ))))
 891
 892 )
 893
 894 (define-ccl-program mel-ccl-encode-quoted-printable-crlf-crlf
 895   (mel-ccl-encode-quoted-printable-generic t t))
 896
 897 (define-ccl-program mel-ccl-encode-quoted-printable-crlf-lf
 898   (mel-ccl-encode-quoted-printable-generic t nil))
 899
 900 (define-ccl-program mel-ccl-encode-quoted-printable-lf-crlf
 901   (mel-ccl-encode-quoted-printable-generic nil t))
 902
 903 (define-ccl-program mel-ccl-encode-quoted-printable-lf-lf
 904   (mel-ccl-encode-quoted-printable-generic nil nil))
 905
 906 (define-ccl-program mel-ccl-decode-quoted-printable-crlf-crlf
 907   (mel-ccl-decode-quoted-printable-generic t t))
 908
 909 (define-ccl-program mel-ccl-decode-quoted-printable-crlf-lf
 910   (mel-ccl-decode-quoted-printable-generic t nil))
 911
 912 (define-ccl-program mel-ccl-decode-quoted-printable-lf-crlf
 913   (mel-ccl-decode-quoted-printable-generic nil t))
 914
 915 (define-ccl-program mel-ccl-decode-quoted-printable-lf-lf
 916   (mel-ccl-decode-quoted-printable-generic nil nil))
 917
 918
 919 ;;; @ coding system
 920 ;;;
 921
 922 (make-ccl-coding-system
 923  'mel-ccl-uq-rev ?Q "MIME Q-encoding in unstructured field (reversed)"
 924  'mel-ccl-encode-uq 'mel-ccl-decode-q)
 925
 926 (make-ccl-coding-system
 927  'mel-ccl-cq-rev ?Q "MIME Q-encoding in comment (reversed)"
 928  'mel-ccl-encode-cq 'mel-ccl-decode-q)
 929
 930 (make-ccl-coding-system
 931  'mel-ccl-pq-rev ?Q "MIME Q-encoding in phrase (reversed)"
 932  'mel-ccl-encode-pq 'mel-ccl-decode-q)
 933
 934 (make-ccl-coding-system
 935  'mel-ccl-quoted-printable-crlf-crlf-rev
 936  ?Q "MIME Quoted-Printable-encoding (reversed)"
 937  'mel-ccl-encode-quoted-printable-crlf-crlf
 938  'mel-ccl-decode-quoted-printable-crlf-crlf)
 939
 940 (make-ccl-coding-system
 941  'mel-ccl-quoted-printable-lf-crlf-rev
 942  ?Q "MIME Quoted-Printable-encoding (LF encoding) (reversed)"
 943  'mel-ccl-encode-quoted-printable-crlf-lf
 944  'mel-ccl-decode-quoted-printable-lf-crlf)
 945
 946 (make-ccl-coding-system
 947  'mel-ccl-quoted-printable-crlf-lf-rev
 948  ?Q "MIME Quoted-Printable-encoding (LF internal) (reversed)"
 949  'mel-ccl-encode-quoted-printable-lf-crlf
 950  'mel-ccl-decode-quoted-printable-crlf-lf)
 951
 952 (make-ccl-coding-system
 953  'mel-ccl-quoted-printable-lf-lf-rev
 954  ?Q "MIME Quoted-Printable-encoding (LF encoding) (LF internal) (reversed)"
 955  'mel-ccl-encode-quoted-printable-lf-lf
 956  'mel-ccl-decode-quoted-printable-lf-lf)
 957
 958
 959 ;;; @ quoted-printable
 960 ;;;
 961
 962 (check-broken-facility ccl-execute-eof-block-on-decoding-some)
 963
 964 (unless-broken ccl-execute-eof-block-on-decoding-some
 965
 966   (defun quoted-printable-ccl-encode-string (string)
 967     "Encode STRING with quoted-printable encoding."
 968     (decode-coding-string
 969      string
 970      'mel-ccl-quoted-printable-lf-lf-rev))
 971
 972   (defun quoted-printable-ccl-encode-region (start end)
 973     "Encode the region from START to END with quoted-printable encoding."
 974     (interactive "r")
 975     (decode-coding-region start end 'mel-ccl-quoted-printable-lf-lf-rev))
 976
 977   (defun quoted-printable-ccl-insert-encoded-file (filename)
 978     "Encode contents of the file named as FILENAME, and insert it."
 979     (interactive (list (read-file-name "Insert encoded file: ")))
 980     (insert-file-contents-as-coding-system
 981      'mel-ccl-quoted-printable-lf-lf-rev filename))
 982
 983   (mel-define-method-function
 984    (mime-encode-string string (nil "quoted-printable"))
 985    'quoted-printable-ccl-encode-string)
 986   (mel-define-method-function
 987    (mime-encode-region start end (nil "quoted-printable"))
 988    'quoted-printable-ccl-encode-region)
 989   (mel-define-method-function
 990    (mime-insert-encoded-file filename (nil "quoted-printable"))
 991    'quoted-printable-ccl-insert-encoded-file)
 992   )
 993
 994 (defun quoted-printable-ccl-decode-string (string)
 995   "Decode quoted-printable encoded STRING."
 996   (encode-coding-string
 997    string
 998    'mel-ccl-quoted-printable-lf-lf-rev))
 999
1000 (defun quoted-printable-ccl-decode-region (start end)
1001   "Decode the region from START to END with quoted-printable
1002 encoding."
1003   (interactive "r")
1004   (encode-coding-region start end 'mel-ccl-quoted-printable-lf-lf-rev))
1005
1006 (defun quoted-printable-ccl-write-decoded-region
1007   (start end filename)
1008   "Decode quoted-printable encoded current region and write out to FILENAME."
1009   (interactive
1010    (list (region-beginning) (region-end)
1011          (read-file-name "Write decoded region to file: ")))
1012   (write-region-as-coding-system 'mel-ccl-quoted-printable-lf-lf-rev
1013                                  start end filename))
1014
1015 (mel-define-method-function
1016  (mime-decode-string string (nil "quoted-printable"))
1017  'quoted-printable-ccl-decode-string)
1018 (mel-define-method-function
1019  (mime-decode-region start end (nil "quoted-printable"))
1020  'quoted-printable-ccl-decode-region)
1021 (mel-define-method-function
1022  (mime-write-decoded-region start end filename (nil "quoted-printable"))
1023  'quoted-printable-ccl-write-decoded-region)
1024
1025
1026 ;;; @ Q
1027 ;;;
1028
1029 (defun q-encoding-ccl-encode-string (string &optional mode)
1030   "Encode STRING to Q-encoding of encoded-word, and return the result.
1031 MODE allows `text', `comment', `phrase' or nil.  Default value is
1032 `phrase'."
1033   (decode-coding-string
1034    string
1035    (cond
1036     ((eq mode 'text) 'mel-ccl-uq-rev)
1037     ((eq mode 'comment) 'mel-ccl-cq-rev)
1038     (t 'mel-ccl-pq-rev))))
1039
1040 (defun q-encoding-ccl-decode-string (string)
1041   "Decode Q encoded STRING and return the result."
1042   (encode-coding-string
1043    string
1044    'mel-ccl-uq-rev))
1045
1046 (unless (featurep 'xemacs)
1047   (defun q-encoding-ccl-encoded-length (string &optional mode)
1048     (let ((status [nil nil nil nil nil nil nil nil nil]))
1049       (fillarray status nil)
1050       (ccl-execute-on-string
1051        (cond
1052         ((eq mode 'text) 'mel-ccl-count-uq)
1053         ((eq mode 'comment) 'mel-ccl-count-cq)
1054         (t 'mel-ccl-count-pq))
1055        status
1056        string)
1057       (aref status 0)))
1058   )
1059
1060 (mel-define-method-function (encoded-text-encode-string string (nil "Q"))
1061                             'q-encoding-ccl-encode-string)
1062
1063 (mel-define-method encoded-text-decode-string (string (nil "Q"))
1064   (if (and (string-match Q-encoded-text-regexp string)
1065            (string= string (match-string 0 string)))
1066       (q-encoding-ccl-decode-string string)
1067     (error "Invalid encoded-text %s" string)))
1068
1069
1070 ;;; @ end
1071 ;;;
1072
1073 (provide 'mel-q-ccl)
1074
1075 ;;; mel-q-ccl.el ends here