mime-def.el

   1 ;;; mime-def.el --- definition module about MIME
   2
   3 ;; Copyright (C) 1995,1996,1997,1998,1999 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1999 Electrotechnical Laboratory, JAPAN.
   5 ;; Licensed to the Free Software Foundation.
   6
   7 ;; Author: MORIOKA Tomohiko <tomo@m17n.org>
   8 ;; Keywords: definition, MIME, multimedia, mail, news
   9
  10 ;; This file is part of FLIM (Faithful Library about Internet Message).
  11
  12 ;; This program is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 2, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Code:
  28
  29 (require 'poe)
  30 (require 'poem)
  31 (require 'pcustom)
  32 (require 'mcharset)
  33 (require 'alist)
  34
  35 (eval-when-compile (require 'cl))       ; list*
  36
  37 (eval-and-compile
  38   (defconst mime-library-product ["FLIM" (1 13 1) "Tawaramoto"]
  39     "Product name, version number and code name of MIME-library package.")
  40   )
  41
  42 (defmacro mime-product-name (product)
  43   `(aref ,product 0))
  44
  45 (defmacro mime-product-version (product)
  46   `(aref ,product 1))
  47
  48 (defmacro mime-product-code-name (product)
  49   `(aref ,product 2))
  50
  51 (defconst mime-library-version
  52   (eval-when-compile
  53     (concat (mime-product-name mime-library-product) " "
  54             (mapconcat #'number-to-string
  55                        (mime-product-version mime-library-product) ".")
  56             " - \"" (mime-product-code-name mime-library-product) "\"")))
  57
  58
  59 ;;; @ variables
  60 ;;;
  61
  62 (require 'custom)
  63
  64 (defgroup mime '((default-mime-charset custom-variable))
  65   "Emacs MIME Interfaces"
  66   :group 'news
  67   :group 'mail)
  68
  69 (defcustom mime-uuencode-encoding-name-list '("x-uue" "x-uuencode")
  70   "*List of encoding names for uuencode format."
  71   :group 'mime
  72   :type '(repeat string))
  73
  74
  75 ;;; @ required functions
  76 ;;;
  77
  78 (defsubst regexp-* (regexp)
  79   (concat regexp "*"))
  80
  81 (defsubst regexp-or (&rest args)
  82   (concat "\\(" (mapconcat (function identity) args "\\|") "\\)"))
  83
  84
  85 ;;; @ about STD 11
  86 ;;;
  87
  88 (eval-and-compile
  89   (defconst std11-quoted-pair-regexp "\\\\.")
  90   (defconst std11-non-qtext-char-list '(?\" ?\\ ?\r ?\n))
  91   (defconst std11-qtext-regexp
  92     (eval-when-compile
  93       (concat "[^" std11-non-qtext-char-list "]"))))
  94 (defconst std11-quoted-string-regexp
  95   (eval-when-compile
  96     (concat "\""
  97             (regexp-*
  98              (regexp-or std11-qtext-regexp std11-quoted-pair-regexp))
  99             "\"")))
 100
 101
 102 ;;; @ about MIME
 103 ;;;
 104
 105 (eval-and-compile
 106   (defconst mime-tspecial-char-list
 107     '(?\] ?\[ ?\( ?\) ?< ?> ?@ ?, ?\; ?: ?\\ ?\" ?/ ?? ?=)))
 108 (defconst mime-token-regexp
 109   (eval-when-compile
 110     (concat "[^" mime-tspecial-char-list "\000-\040]+")))
 111 (defconst mime-charset-regexp mime-token-regexp)
 112
 113 (defconst mime-media-type/subtype-regexp
 114   (concat mime-token-regexp "/" mime-token-regexp))
 115
 116
 117 ;;; @@ base64 / B
 118 ;;;
 119
 120 (defconst base64-token-regexp "[A-Za-z0-9+/]")
 121 (defconst base64-token-padding-regexp "[A-Za-z0-9+/=]")
 122
 123 (defconst B-encoded-text-regexp
 124   (concat "\\(\\("
 125           base64-token-regexp
 126           base64-token-regexp
 127           base64-token-regexp
 128           base64-token-regexp
 129           "\\)*"
 130           base64-token-regexp
 131           base64-token-regexp
 132           base64-token-padding-regexp
 133           base64-token-padding-regexp
 134           "\\)"))
 135
 136 ;; (defconst eword-B-encoding-and-encoded-text-regexp
 137 ;;   (concat "\\(B\\)\\?" eword-B-encoded-text-regexp))
 138
 139
 140 ;;; @@ Quoted-Printable / Q
 141 ;;;
 142
 143 (defconst quoted-printable-hex-chars "0123456789ABCDEF")
 144
 145 (defconst quoted-printable-octet-regexp
 146   (concat "=[" quoted-printable-hex-chars
 147           "][" quoted-printable-hex-chars "]"))
 148
 149 (defconst Q-encoded-text-regexp
 150   (concat "\\([^=?]\\|" quoted-printable-octet-regexp "\\)+"))
 151
 152 ;; (defconst eword-Q-encoding-and-encoded-text-regexp
 153 ;;   (concat "\\(Q\\)\\?" eword-Q-encoded-text-regexp))
 154
 155
 156 ;;; @ Content-Type
 157 ;;;
 158
 159 (defsubst make-mime-content-type (type subtype &optional parameters)
 160   (list* (cons 'type type)
 161          (cons 'subtype subtype)
 162          (nreverse parameters))
 163   )
 164
 165 (defsubst mime-content-type-primary-type (content-type)
 166   "Return primary-type of CONTENT-TYPE."
 167   (cdr (car content-type)))
 168
 169 (defsubst mime-content-type-subtype (content-type)
 170   "Return primary-type of CONTENT-TYPE."
 171   (cdr (cadr content-type)))
 172
 173 (defsubst mime-content-type-parameters (content-type)
 174   "Return primary-type of CONTENT-TYPE."
 175   (cddr content-type))
 176
 177 (defsubst mime-content-type-parameter (content-type parameter)
 178   "Return PARAMETER value of CONTENT-TYPE."
 179   (cdr (assoc parameter (mime-content-type-parameters content-type))))
 180
 181
 182 (defsubst mime-type/subtype-string (type &optional subtype)
 183   "Return type/subtype string from TYPE and SUBTYPE."
 184   (if type
 185       (if subtype
 186           (format "%s/%s" type subtype)
 187         (format "%s" type))))
 188
 189
 190 ;;; @ Content-Disposition
 191 ;;;
 192
 193 (defsubst mime-content-disposition-type (content-disposition)
 194   "Return disposition-type of CONTENT-DISPOSITION."
 195   (cdr (car content-disposition)))
 196
 197 (defsubst mime-content-disposition-parameters (content-disposition)
 198   "Return disposition-parameters of CONTENT-DISPOSITION."
 199   (cdr content-disposition))
 200
 201 (defsubst mime-content-disposition-parameter (content-disposition parameter)
 202   "Return PARAMETER value of CONTENT-DISPOSITION."
 203   (cdr (assoc parameter (cdr content-disposition))))
 204
 205 (defsubst mime-content-disposition-filename (content-disposition)
 206   "Return filename of CONTENT-DISPOSITION."
 207   (mime-content-disposition-parameter content-disposition "filename"))
 208
 209
 210 ;;; @ MIME entity
 211 ;;;
 212
 213 (require 'luna)
 214
 215 (autoload 'mime-entity-content-type "mime")
 216 (autoload 'mime-parse-multipart "mime-parse")
 217 (autoload 'mime-parse-encapsulated "mime-parse")
 218
 219 (luna-define-class mime-entity ()
 220                    (location
 221                     content-type children parent
 222                     node-id
 223                     content-disposition encoding
 224                     ;; for other fields
 225                     original-header parsed-header))
 226
 227 (defalias 'mime-entity-representation-type-internal 'luna-class-name)
 228 (defalias 'mime-entity-set-representation-type-internal 'luna-set-class-name)
 229
 230 (luna-define-internal-accessors 'mime-entity)
 231
 232 (luna-define-method mime-entity-fetch-field ((entity mime-entity)
 233                                              field-name)
 234   (or (symbolp field-name)
 235       (setq field-name (intern (capitalize (capitalize field-name)))))
 236   (cdr (assq field-name
 237              (mime-entity-original-header-internal entity))))
 238
 239 (luna-define-method mime-entity-children ((entity mime-entity))
 240   (let* ((content-type (mime-entity-content-type entity))
 241          (primary-type (mime-content-type-primary-type content-type)))
 242     (cond ((eq primary-type 'multipart)
 243            (mime-parse-multipart entity)
 244            )
 245           ((and (eq primary-type 'message)
 246                 (memq (mime-content-type-subtype content-type)
 247                       '(rfc822 news external-body)
 248                       ))
 249            (mime-parse-encapsulated entity)
 250            ))
 251     ))
 252
 253
 254 ;;; @ for mm-backend
 255 ;;;
 256
 257 (defmacro mm-expand-class-name (type)
 258   `(intern (format "mime-%s-entity" ,type)))
 259
 260 (defmacro mm-define-backend (type &optional parents)
 261   `(luna-define-class ,(mm-expand-class-name type)
 262                       ,(nconc (mapcar (lambda (parent)
 263                                         (mm-expand-class-name parent)
 264                                         )
 265                                       parents)
 266                               '(mime-entity))))
 267
 268 (defmacro mm-define-method (name args &rest body)
 269   (or (eq name 'initialize-instance)
 270       (setq name (intern (format "mime-%s" name))))
 271   (let ((spec (car args)))
 272     (setq args
 273           (cons (list (car spec)
 274                       (mm-expand-class-name (nth 1 spec)))
 275                 (cdr args)))
 276     `(luna-define-method ,name ,args ,@body)
 277     ))
 278
 279 (put 'mm-define-method 'lisp-indent-function 'defun)
 280
 281 (def-edebug-spec mm-define-method
 282   (&define name ((arg symbolp)
 283                  [&rest arg]
 284                  [&optional ["&optional" arg &rest arg]]
 285                  &optional ["&rest" arg]
 286                  )
 287            def-body))
 288
 289
 290 ;;; @ message structure
 291 ;;;
 292
 293 (defvar mime-message-structure nil
 294   "Information about structure of message.
 295 Please use reference function `mime-entity-SLOT' to get value of SLOT.
 296
 297 Following is a list of slots of the structure:
 298
 299 node-id                 node-id (list of integers)
 300 content-type            content-type (content-type)
 301 content-disposition     content-disposition (content-disposition)
 302 encoding                Content-Transfer-Encoding (string or nil)
 303 children                entities included in this entity (list of entity)
 304
 305 If an entity includes other entities in its body, such as multipart or
 306 message/rfc822, `mime-entity' structures of them are included in
 307 `children', so the `mime-entity' structure become a tree.")
 308
 309 (make-variable-buffer-local 'mime-message-structure)
 310
 311 (make-obsolete-variable 'mime-message-structure "should not use it.")
 312
 313
 314 ;;; @ for mel-backend
 315 ;;;
 316
 317 (defvar mel-service-list nil)
 318
 319 (defmacro mel-define-service (name &optional args &rest rest)
 320   "Define NAME as a service for Content-Transfer-Encodings.
 321 If ARGS is specified, NAME is defined as a generic function for the
 322 service."
 323   `(progn
 324      (add-to-list 'mel-service-list ',name)
 325      (defvar ,(intern (format "%s-obarray" name)) (make-vector 7 0))
 326      ,@(if args
 327            `((defun ,name ,args
 328                ,@rest
 329                (funcall (mel-find-function ',name ,(car (last args)))
 330                         ,@(luna-arglist-to-arguments (butlast args)))
 331                )))
 332      ))
 333
 334 (put 'mel-define-service 'lisp-indent-function 'defun)
 335
 336
 337 (defvar mel-encoding-module-alist nil)
 338
 339 (defsubst mel-find-function-from-obarray (ob-array encoding)
 340   (let* ((f (intern-soft encoding ob-array)))
 341     (or f
 342         (let ((rest (cdr (assoc encoding mel-encoding-module-alist))))
 343           (while (and rest
 344                       (progn
 345                         (require (car rest))
 346                         (null (setq f (intern-soft encoding ob-array)))
 347                         ))
 348             (setq rest (cdr rest))
 349             )
 350           f))))
 351
 352 (defsubst mel-copy-method (service src-backend dst-backend)
 353   (let* ((oa (symbol-value (intern (format "%s-obarray" service))))
 354          (f (mel-find-function-from-obarray oa src-backend))
 355          sym)
 356     (when f
 357       (setq sym (intern dst-backend oa))
 358       (or (fboundp sym)
 359           (fset sym (symbol-function f))
 360           ))))
 361
 362 (defsubst mel-copy-backend (src-backend dst-backend)
 363   (let ((services mel-service-list))
 364     (while services
 365       (mel-copy-method (car services) src-backend dst-backend)
 366       (setq services (cdr services)))))
 367
 368 (defmacro mel-define-backend (type &optional parents)
 369   "Define TYPE as a mel-backend.
 370 If PARENTS is specified, TYPE inherits PARENTS.
 371 Each parent must be backend name (string)."
 372   (cons 'progn
 373         (mapcar (lambda (parent)
 374                   `(mel-copy-backend ,parent ,type)
 375                   )
 376                 parents)))
 377
 378 (defmacro mel-define-method (name args &rest body)
 379   "Define NAME as a method function of (nth 1 (car (last ARGS))) backend.
 380 ARGS is like an argument list of lambda, but (car (last ARGS)) must be
 381 specialized parameter.  (car (car (last ARGS))) is name of variable
 382 and (nth 1 (car (last ARGS))) is name of backend (encoding)."
 383   (let* ((specializer (car (last args)))
 384          (class (nth 1 specializer)))
 385     `(progn
 386        (mel-define-service ,name)
 387        (fset (intern ,class ,(intern (format "%s-obarray" name)))
 388              (lambda ,(butlast args)
 389                ,@body)))))
 390
 391 (put 'mel-define-method 'lisp-indent-function 'defun)
 392
 393 (defmacro mel-define-method-function (spec function)
 394   "Set SPEC's function definition to FUNCTION.
 395 First element of SPEC is service.
 396 Rest of ARGS is like an argument list of lambda, but (car (last ARGS))
 397 must be specialized parameter.  (car (car (last ARGS))) is name of
 398 variable and (nth 1 (car (last ARGS))) is name of backend (encoding)."
 399   (let* ((name (car spec))
 400          (args (cdr spec))
 401          (specializer (car (last args)))
 402          (class (nth 1 specializer)))
 403     `(let (sym)
 404        (mel-define-service ,name)
 405        (setq sym (intern ,class ,(intern (format "%s-obarray" name))))
 406        (or (fboundp sym)
 407            (fset sym (symbol-function ,function))))))
 408
 409 (defmacro mel-define-function (function spec)
 410   (let* ((name (car spec))
 411          (args (cdr spec))
 412          (specializer (car (last args)))
 413          (class (nth 1 specializer)))
 414     `(progn
 415        (define-function ,function
 416          (intern ,class ,(intern (format "%s-obarray" name))))
 417        )))
 418
 419 (defvar base64-dl-module
 420   (if (and (fboundp 'base64-encode-string)
 421            (subrp (symbol-function 'base64-encode-string)))
 422       nil
 423     (if (fboundp 'dynamic-link)
 424         (let ((path (expand-file-name "base64.so" exec-directory)))
 425           (and (file-exists-p path)
 426                path)
 427           ))))
 428
 429
 430 ;;; @ end
 431 ;;;
 432
 433 (provide 'mime-def)
 434
 435 ;;; mime-def.el ends here