mime-parse.el

   1 ;;; mime-parse.el --- MIME message parser
   2
   3 ;; Copyright (C) 1994,1995,1996,1997 Free Software Foundation, Inc.
   4
   5 ;; Author: MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; Version: $Id: mime-parse.el,v 0.12 1997-07-07 17:06:36 morioka Exp $
   7 ;; Keywords: parse, MIME, multimedia, mail, news
   8
   9 ;; This file is part of SEMI (SEMI is Emacs MIME Interfaces).
  10
  11 ;; This program is free software; you can redistribute it and/or
  12 ;; modify it under the terms of the GNU General Public License as
  13 ;; published by the Free Software Foundation; either version 2, or (at
  14 ;; your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful, but
  17 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;; General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (require 'emu)
  29 (require 'std11)
  30 (require 'mime-def)
  31
  32 (defsubst symbol-concat (&rest args)
  33   "Return a symbol whose name is concatenation of arguments ARGS
  34 which are string or symbol."
  35   (intern (apply (function concat)
  36                  (mapcar (function
  37                           (lambda (s)
  38                             (cond ((symbolp s) (symbol-name s))
  39                                   ((stringp s) s)
  40                                   )))
  41                          args))))
  42
  43 (defmacro define-structure (name &rest slots)
  44   (let ((pred (symbol-concat name '-p)))
  45     (cons 'progn
  46           (nconc
  47            (list
  48             (` (defun (, pred) (obj)
  49                  (and (vectorp obj)
  50                       (eq (elt obj 0) '(, name))
  51                       ))
  52                )
  53             (` (defun (, (symbol-concat name '/create)) (, slots)
  54                  (, (cons 'vector (cons (list 'quote name) slots)))
  55                  )
  56                ))
  57            (let ((i 1))
  58              (mapcar (function
  59                       (lambda (slot)
  60                         (prog1
  61                             (` (defun (, (symbol-concat name '/ slot)) (obj)
  62                                  (if ((, pred) obj)
  63                                      (elt obj (, i))
  64                                    ))
  65                                )
  66                           (setq i (+ i 1))
  67                           )
  68                         )) slots)
  69              )
  70            (list (list 'quote name))
  71            ))))
  72
  73
  74 ;;; @ field parser
  75 ;;;
  76
  77 (defsubst regexp-* (regexp)
  78   (concat regexp "*"))
  79
  80 (defconst rfc822/quoted-pair-regexp "\\\\.")
  81 (defconst rfc822/qtext-regexp
  82   (concat "[^" (char-list-to-string std11-non-qtext-char-list) "]"))
  83 (defconst rfc822/quoted-string-regexp
  84   (concat "\""
  85           (regexp-*
  86            (regexp-or rfc822/qtext-regexp rfc822/quoted-pair-regexp)
  87            )
  88           "\""))
  89
  90 (defconst mime/content-parameter-value-regexp
  91   (concat "\\("
  92           rfc822/quoted-string-regexp
  93           "\\|[^; \t\n]*\\)"))
  94
  95 (defconst mime::parameter-regexp
  96   (concat "^[ \t]*\;[ \t]*\\(" mime-token-regexp "\\)"
  97           "[ \t]*=[ \t]*\\(" mime/content-parameter-value-regexp "\\)"))
  98
  99 (defun mime-parse-parameter (str)
 100   (if (string-match mime::parameter-regexp str)
 101       (let ((e (match-end 2)))
 102         (cons
 103          (cons (downcase (substring str (match-beginning 1) (match-end 1)))
 104                (std11-strip-quoted-string
 105                 (substring str (match-beginning 2) e))
 106                )
 107          (substring str e)
 108          ))))
 109
 110 (defconst mime::ctype-regexp (concat "^" mime-media-type/subtype-regexp))
 111
 112 (defun mime-parse-Content-Type (string)
 113   "Parse STRING as field-body of Content-Type field."
 114   (setq string (std11-unfold-string string))
 115   (if (string-match mime::ctype-regexp string)
 116       (let* ((e (match-end 0))
 117              (ctype (downcase (substring string 0 e)))
 118              ret dest)
 119         (setq string (substring string e))
 120         (while (setq ret (mime-parse-parameter string))
 121           (setq dest (cons (car ret) dest)
 122                 string (cdr ret))
 123           )
 124         (cons ctype (nreverse dest))
 125         )))
 126
 127 (defun mime-parse-Content-Disposition (string)
 128   "Parse STRING as field-body of Content-Disposition field."
 129   (setq string (std11-unfold-string string))
 130   (if (string-match `,(concat "^" mime-disposition-type-regexp) string)
 131       (let* ((e (match-end 0))
 132              (ctype (downcase (substring string 0 e)))
 133              ret dest)
 134         (setq string (substring string e))
 135         (while (setq ret (mime-parse-parameter string))
 136           (setq dest (cons (car ret) dest)
 137                 string (cdr ret))
 138           )
 139         (cons ctype (nreverse dest))
 140         )))
 141
 142
 143 ;;; @ field reader
 144 ;;;
 145
 146 (defun mime/Content-Type ()
 147   "Read field-body of Content-Type field from current-buffer,
 148 and return parsed it. [mime-parse.el]"
 149   (let ((str (std11-field-body "Content-Type")))
 150     (if str
 151         (mime-parse-Content-Type str)
 152       )))
 153
 154 (defun mime/Content-Transfer-Encoding (&optional default-encoding)
 155   "Read field-body of Content-Transfer-Encoding field from
 156 current-buffer, and return it.
 157 If is is not found, return DEFAULT-ENCODING. [mime-parse.el]"
 158   (let ((str (std11-field-body "Content-Transfer-Encoding")))
 159     (if str
 160         (progn
 161           (if (string-match "[ \t\n\r]+$" str)
 162               (setq str (substring str 0 (match-beginning 0)))
 163             )
 164           (downcase str)
 165           )
 166       default-encoding)
 167     ))
 168
 169 (defun mime/Content-Disposition ()
 170   "Read field-body of Content-Disposition field from current-buffer,
 171 and return parsed it. [mime-parse.el]"
 172   (let ((str (std11-field-body "Content-Disposition")))
 173     (if str
 174         (mime-parse-Content-Disposition str)
 175       )))
 176
 177
 178 ;;; @ message parser
 179 ;;;
 180
 181 (define-structure mime::content-info
 182   rcnum point-min point-max type parameters encoding children)
 183
 184
 185 (defun mime-parse-multipart (boundary ctype params encoding rcnum)
 186   (goto-char (point-min))
 187   (let* ((dash-boundary   (concat "--" boundary))
 188          (delimiter       (concat "\n" (regexp-quote dash-boundary)))
 189          (close-delimiter (concat delimiter "--[ \t]*$"))
 190          (beg (point-min))
 191          (end (progn
 192                 (goto-char (point-max))
 193                 (if (re-search-backward close-delimiter nil t)
 194                     (match-beginning 0)
 195                   (point-max)
 196                   )))
 197          (rsep (concat delimiter "[ \t]*\n"))
 198          (dc-ctl
 199           (if (string-equal ctype "multipart/digest")
 200               '("message/rfc822")
 201             '("text/plain")
 202             ))
 203          cb ce ret ncb children (i 0))
 204     (save-restriction
 205       (narrow-to-region beg end)
 206       (goto-char beg)
 207       (re-search-forward rsep nil t)
 208       (setq cb (match-end 0))
 209       (while (re-search-forward rsep nil t)
 210         (setq ce (match-beginning 0))
 211         (setq ncb (match-end 0))
 212         (save-restriction
 213           (narrow-to-region cb ce)
 214           (setq ret (mime-parse-message dc-ctl "7bit" (cons i rcnum)))
 215           )
 216         (setq children (cons ret children))
 217         (goto-char (mime::content-info/point-max ret))
 218         (goto-char (setq cb ncb))
 219         (setq i (1+ i))
 220         )
 221       (setq ce (point-max))
 222       (save-restriction
 223         (narrow-to-region cb ce)
 224         (setq ret (mime-parse-message dc-ctl "7bit" (cons i rcnum)))
 225         )
 226       (setq children (cons ret children))
 227       )
 228     (mime::content-info/create rcnum beg (point-max)
 229                                ctype params encoding
 230                                (nreverse children))
 231     ))
 232
 233 (defun mime-parse-message (&optional ctl encoding rcnum)
 234   "Parse current-buffer as a MIME message. [mime-parse.el]"
 235   (setq ctl (or (mime/Content-Type) ctl))
 236   (setq encoding (or (mime/Content-Transfer-Encoding) encoding))
 237   (let ((ctype (car ctl))
 238         (params (cdr ctl))
 239         )
 240     (let ((boundary (assoc "boundary" params)))
 241       (cond (boundary
 242              (setq boundary (std11-strip-quoted-string (cdr boundary)))
 243              (mime-parse-multipart boundary ctype params encoding rcnum)
 244              )
 245             ((or (string-equal ctype "message/rfc822")
 246                  (string-equal ctype "message/news")
 247                  )
 248              (goto-char (point-min))
 249              (mime::content-info/create rcnum
 250                                         (point-min) (point-max)
 251                                         ctype params encoding
 252                                         (save-restriction
 253                                           (narrow-to-region
 254                                            (if (re-search-forward "^$" nil t)
 255                                                (1+ (match-end 0))
 256                                              (point-min)
 257                                              )
 258                                            (point-max))
 259                                           (list (mime-parse-message
 260                                                  nil nil (cons 0 rcnum)))
 261                                           )
 262                                         )
 263              )
 264             (t
 265              (mime::content-info/create rcnum (point-min) (point-max)
 266                                         ctype params encoding nil)
 267              ))
 268       )))
 269
 270
 271 ;;; @ end
 272 ;;;
 273
 274 (provide 'mime-parse)
 275
 276 ;;; mime-parse.el ends here