netinstall/inilex.l

   1 %{
   2 /*
   3  * Copyright (c) 2000, Red Hat, Inc.
   4  *
   5  *     This program is free software; you can redistribute it and/or modify
   6  *     it under the terms of the GNU General Public License as published by
   7  *     the Free Software Foundation; either version 2 of the License, or
   8  *     (at your option) any later version.
   9  *
  10  *     A copy of the GNU General Public License can be found at
  11  *     http://www.gnu.org/
  12  *
  13  * Written by DJ Delorie <dj@cygnus.com>
  14  *
  15  */
  16
  17 /* tokenize the setup.ini files.  We parse a string which we've
  18    previously downloaded.  The program must call ini_init() to specify
  19    that string. */
  20
  21 #include "win32.h"
  22 #include <string.h>
  23 #include <stdlib.h>
  24
  25 #include "ini.h"
  26 #include "iniparse.h"
  27
  28 #define YY_INPUT(buf,result,max_size) { result = ini_getchar(buf, max_size); }
  29
  30 static int ini_getchar(char *buf, int max_size);
  31 static void ignore_line ();
  32
  33 %}
  34
  35 /*%option debug */
  36 %option noyywrap
  37 %option yylineno
  38 %option never-interactive
  39
  40 STR     [a-zA-Z0-9_./-]+
  41
  42 %%
  43
  44 \"[^"]*\"               { yylval = strdup (yytext+1);
  45                           yylval[strlen (yylval)-1] = 0;
  46                           return STRING; }
  47
  48 "setup-timestamp:"      return SETUP_TIMESTAMP;
  49 "setup-version:"        return SETUP_VERSION;
  50 "version:"              return VERSION;
  51 "install:"              return INSTALL;
  52 "type:"                 return TYPE;
  53 "source:"               return SOURCE;
  54 "sdesc:"                return SDESC;
  55 "ldesc:"                return LDESC;
  56
  57 ^{STR}":"               ignore_line ();
  58
  59 "[curr]"                return T_CURR;
  60 "[test]"                return T_TEST;
  61 "[exp]"                 return T_TEST;
  62 "[prev]"                return T_PREV;
  63 "["{STR}"]"             return T_UNKNOWN;
  64
  65 {STR}                   { yylval = strdup (yytext);
  66                           return STRING; }
  67
  68 [ \t\r]+                /* do nothing */
  69
  70 "#".*\n                 /* ignore comments */
  71
  72 \n                      { return yytext[0]; }
  73 .                       { return yytext[0]; }
  74
  75 %%
  76
  77 static char *input_string = 0;
  78 static char *end_input_string;
  79
  80 void
  81 ini_init(char *string)
  82 {
  83   input_string = string;
  84   end_input_string = input_string + strlen(input_string);
  85 }
  86
  87 static int
  88 ini_getchar(char *buf, int max_size)
  89 {
  90   if (input_string)
  91     {
  92       int avail = end_input_string - input_string;
  93       if (avail == 0)
  94         {
  95           input_string = end_input_string = 0;
  96           return 0;
  97         }
  98       if (avail > max_size)
  99         avail = max_size;
 100       memcpy(buf, input_string, avail);
 101       input_string += avail;
 102       return avail;
 103     }
 104   else
 105     return 0;
 106 }
 107
 108 static void
 109 ignore_line ()
 110 {
 111   char c;
 112   while (c = input ())
 113     {
 114       if (c == EOF)
 115         return;
 116       if (c == '\n')
 117         return;
 118     }
 119 }