pgg.el

   1 ;;; pgg.el --- glue for the various PGP implementations.
   2
   3 ;; Copyright (C) 1999 Daiki Ueno
   4
   5 ;; Author: Daiki Ueno <ueno@ueda.info.waseda.ac.jp>
   6 ;; Created: 1999/10/28
   7 ;; Keywords: PGP
   8
   9 ;; This file is part of SEMI (Secure Emacs MIME Interface).
  10
  11 ;; This program is free software; you can redistribute it and/or
  12 ;; modify it under the terms of the GNU General Public License as
  13 ;; published by the Free Software Foundation; either version 2, or (at
  14 ;; your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful, but
  17 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;; General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (require 'calist)
  29
  30 (eval-and-compile (require 'luna))
  31
  32 (require 'pgg-def)
  33 (require 'pgg-parse)
  34
  35 (eval-when-compile
  36   (ignore-errors
  37     (require 'w3)
  38     (require 'url)))
  39
  40 (in-calist-package 'pgg)
  41
  42 (defun pgg-field-match-method-with-containment
  43   (calist field-type field-value)
  44   (let ((s-field (assq field-type calist)))
  45     (cond ((null s-field)
  46            (cons (cons field-type field-value) calist)
  47            )
  48           ((memq (cdr s-field) field-value)
  49            calist))))
  50
  51 (define-calist-field-match-method 'signature-version
  52   #'pgg-field-match-method-with-containment)
  53
  54 (define-calist-field-match-method 'symmetric-key-algorithm
  55   #'pgg-field-match-method-with-containment)
  56
  57 (define-calist-field-match-method 'public-key-algorithm
  58   #'pgg-field-match-method-with-containment)
  59
  60 (define-calist-field-match-method 'hash-algorithm
  61   #'pgg-field-match-method-with-containment)
  62
  63 (defvar pgg-verify-condition nil
  64   "Condition-tree about which PGP implementation is used for verifying.")
  65
  66 (defvar pgg-decrypt-condition nil
  67   "Condition-tree about which PGP implementation is used for decrypting.")
  68
  69 (ctree-set-calist-strictly
  70  'pgg-verify-condition
  71  '((signature-version 3)(public-key-algorithm RSA)(hash-algorithm MD5)
  72    (scheme . pgp)))
  73
  74 (ctree-set-calist-strictly
  75  'pgg-decrypt-condition
  76  '((public-key-algorithm RSA)(symmetric-key-algorithm IDEA)
  77    (scheme . pgp)))
  78
  79 (ctree-set-calist-strictly
  80  'pgg-verify-condition
  81  '((signature-version 3 4)
  82    (public-key-algorithm RSA ELG DSA)
  83    (hash-algorithm MD5 SHA1 RIPEMD160)
  84    (scheme . pgp5)))
  85
  86 (ctree-set-calist-strictly
  87  'pgg-decrypt-condition
  88  '((public-key-algorithm RSA ELG DSA)
  89    (symmetric-key-algorithm 3DES CAST5 IDEA)
  90    (scheme . pgp5)))
  91
  92 (ctree-set-calist-strictly
  93  'pgg-verify-condition
  94  '((signature-version 3 4)
  95    (public-key-algorithm ELG-E DSA ELG)
  96    (hash-algorithm MD5 SHA1 RIPEMD160)
  97    (scheme . gpg)))
  98
  99 (ctree-set-calist-strictly
 100  'pgg-decrypt-condition
 101  '((public-key-algorithm ELG-E DSA ELG)
 102    (symmetric-key-algorithm 3DES CAST5 BLOWFISH TWOFISH)
 103    (scheme . gpg)))
 104
 105 ;;; @ definition of the implementation scheme
 106 ;;;
 107
 108 (eval-and-compile
 109   (luna-define-class pgg-scheme ())
 110
 111   (luna-define-internal-accessors 'pgg-scheme)
 112   )
 113
 114 (luna-define-generic lookup-key-string (scheme string &optional type)
 115   "Search keys associated with STRING")
 116
 117 (luna-define-generic encrypt-region (scheme start end recipients)
 118   "Encrypt the current region between START and END.")
 119
 120 (luna-define-generic decrypt-region (scheme start end)
 121   "Decrypt the current region between START and END.")
 122
 123 (luna-define-generic sign-region (scheme start end &optional cleartext)
 124   "Make detached signature from text between START and END.")
 125
 126 (luna-define-generic verify-region (scheme start end &optional signature)
 127   "Verify region between START and END
 128 as the detached signature SIGNATURE.")
 129
 130 (luna-define-generic insert-key (scheme)
 131   "Insert public key at point.")
 132
 133 (luna-define-generic snarf-keys-region (scheme start end)
 134   "Add all public keys in region between START
 135 and END to the keyring.")
 136
 137 ;;; @ interface functions
 138 ;;;
 139
 140 (defvar pgg-fetch-key-function (function pgg-fetch-key-with-w3))
 141
 142 (defmacro pgg-make-scheme (scheme)
 143   `(progn
 144      (require (intern (format "pgg-%s" ,scheme)))
 145      (funcall (intern (format "pgg-make-scheme-%s"
 146                               ,scheme)))))
 147
 148 (defun pgg-encrypt-region (start end rcpts)
 149   (interactive
 150    (list (region-beginning)(region-end)
 151          (split-string (read-string "Recipients: ") "[ \t,]+")))
 152   (let* ((entity (pgg-make-scheme pgg-default-scheme))
 153          (status (luna-send entity 'encrypt-region
 154                             entity start end rcpts)))
 155     (when (interactive-p)
 156       (if status
 157           (progn
 158             (delete-region start end)
 159             (insert-buffer-substring pgg-output-buffer))
 160         (with-output-to-temp-buffer pgg-echo-buffer
 161           (set-buffer standard-output)
 162           (insert-buffer-substring pgg-errors-buffer))))
 163     status))
 164
 165 (defun pgg-decrypt-region (start end)
 166   (interactive "r")
 167   (let* ((packet (cdr (assq 1 (pgg-parse-armor-region start end))))
 168          (scheme
 169           (or pgg-scheme
 170               (cdr (assq 'scheme
 171                          (progn
 172                            (in-calist-package 'pgg)
 173                            (ctree-match-calist pgg-decrypt-condition
 174                                                packet))))
 175               pgg-default-scheme))
 176          (entity (pgg-make-scheme scheme))
 177          (status (luna-send entity 'decrypt-region entity start end)))
 178     (when (interactive-p)
 179       (if status
 180           (progn
 181             (delete-region start end)
 182             (insert-buffer-substring pgg-output-buffer))
 183         (with-output-to-temp-buffer pgg-echo-buffer
 184           (set-buffer standard-output)
 185           (insert-buffer-substring pgg-errors-buffer))))
 186     status))
 187
 188 (defun pgg-sign-region (start end)
 189   (interactive "r")
 190   (let* ((entity (pgg-make-scheme pgg-default-scheme))
 191          (status (luna-send entity 'sign-region
 192                             entity start end (interactive-p))))
 193     (when (interactive-p)
 194       (if status
 195           (progn
 196             (delete-region start end)
 197             (insert-buffer-substring pgg-output-buffer))
 198         (with-output-to-temp-buffer pgg-echo-buffer
 199           (set-buffer standard-output)
 200           (insert-buffer-substring pgg-errors-buffer))))
 201     status))
 202
 203 (defun pgg-verify-region (start end &optional signature fetch)
 204   (interactive "r")
 205   (let* ((packet
 206           (if (null signature) nil
 207             (with-temp-buffer
 208               (buffer-disable-undo)
 209               (set-buffer-multibyte nil)
 210               (insert-file-contents signature)
 211               (cdr (assq 2 (pgg-decode-armor-region (point-min)(point-max))))
 212               )))
 213          (scheme
 214           (or pgg-scheme
 215               (cdr (assq 'scheme
 216                          (progn
 217                            (in-calist-package 'pgg)
 218                            (ctree-match-calist pgg-verify-condition
 219                                                packet))))
 220               pgg-default-scheme))
 221          (entity (pgg-make-scheme scheme))
 222          (key (cdr (assq 'key-identifier packet)))
 223          keyserver
 224          status)
 225     (and (stringp key)
 226          (setq key (concat "0x" (pgg-truncate-key-identifier key)))
 227          (null (pgg-lookup-key-string key))
 228          (or fetch (interactive-p))
 229          (y-or-n-p (format "Key %s not found; attempt to fetch? " key))
 230          (setq keyserver
 231                (or (cdr (assq 'preferred-key-server packet))
 232                    pgg-default-keyserver-address))
 233          (pgg-fetch-key keyserver key))
 234     (setq status (luna-send entity 'verify-region
 235                             entity start end signature))
 236     (when (interactive-p)
 237       (if status
 238           (progn
 239             (delete-region start end)
 240             (insert-buffer-substring pgg-output-buffer))
 241         (with-output-to-temp-buffer pgg-echo-buffer
 242           (set-buffer standard-output)
 243           (insert-buffer-substring pgg-errors-buffer))))
 244     status))
 245
 246 (defun pgg-insert-key ()
 247   (let ((entity (pgg-make-scheme (or pgg-scheme pgg-default-scheme))))
 248     (luna-send entity 'insert-key entity)))
 249
 250 (defun pgg-snarf-keys-region (start end)
 251   (let ((entity (pgg-make-scheme (or pgg-scheme pgg-default-scheme))))
 252     (luna-send entity 'snarf-keys-region entity start end)))
 253
 254 (defun pgg-lookup-key-string (string &optional type)
 255   (let ((entity (pgg-make-scheme (or pgg-scheme pgg-default-scheme))))
 256     (luna-send entity 'lookup-key-string entity string type)))
 257
 258 (defvar pgg-insert-url-function  (function pgg-insert-url-with-w3))
 259
 260 (defun pgg-insert-url-with-w3 (url)
 261   (require 'w3)
 262   (require 'url)
 263   (let (buffer-file-name)
 264     (url-insert-file-contents url)))
 265
 266 (defvar pgg-insert-url-extra-arguments nil)
 267 (defvar pgg-insert-url-program nil)
 268
 269 (defun pgg-insert-url-with-program (url)
 270   (let ((args (copy-sequence pgg-insert-url-extra-arguments))
 271         process)
 272     (setq process
 273           (apply #'call-process pgg-insert-url-program nil t
 274                  (nconc args (list url))))))
 275
 276 (defun pgg-fetch-key (keyserver key)
 277   "Attempt to fetch a key for addition to PGP or GnuPG keyring."
 278   (with-current-buffer (get-buffer-create pgg-output-buffer)
 279     (buffer-disable-undo)
 280     (erase-buffer)
 281     (let ((proto (if (string-match "^[a-zA-Z\\+\\.\\\\-]+:" keyserver)
 282                      (substring keyserver 0 (1- (match-end 0))))))
 283       (save-excursion
 284         (funcall pgg-insert-url-function
 285                  (if proto keyserver
 286                    (format "http://%s:11371/pks/lookup?op=get&search=%s"
 287                            keyserver key))))
 288       (when (re-search-forward "^-+BEGIN" nil 'last)
 289         (delete-region (point-min) (match-beginning 0))
 290         (when (re-search-forward "^-+END" nil t)
 291           (delete-region (progn (end-of-line) (point))
 292                          (point-max)))
 293         (insert "\n")
 294         (with-temp-buffer
 295           (insert-buffer-substring pgg-output-buffer)
 296           (pgg-snarf-keys-region (point-min)(point-max))))
 297       )))
 298
 299
 300 ;;; @ utility functions
 301 ;;;
 302
 303 (defvar pgg-passphrase-cache-expiry 16)
 304 (defvar pgg-passphrase-cache (make-vector 7 0))
 305
 306 (defvar pgg-read-passphrase nil)
 307 (defun pgg-read-passphrase (prompt &optional key)
 308   (if (not pgg-read-passphrase)
 309       (if (functionp 'read-passwd)
 310           (setq pgg-read-passphrase 'read-passwd)
 311         (if (load "passwd" t)
 312             (setq pgg-read-passphrase 'read-passwd)
 313           (autoload 'ange-ftp-read-passwd "ange-ftp")
 314           (setq pgg-read-passphrase 'ange-ftp-read-passwd))))
 315   (or (and key (setq key (pgg-truncate-key-identifier key))
 316            (symbol-value (intern-soft key pgg-passphrase-cache)))
 317       (funcall pgg-read-passphrase prompt)))
 318
 319 (defun pgg-add-passphrase-cache (key passphrase)
 320   (setq key (pgg-truncate-key-identifier key))
 321   (set (intern key pgg-passphrase-cache)
 322        passphrase)
 323   (run-at-time pgg-passphrase-cache-expiry nil
 324                #'pgg-remove-passphrase-cache
 325                key))
 326
 327 (defun pgg-remove-passphrase-cache (key)
 328   (unintern key pgg-passphrase-cache))
 329
 330
 331 ;;; @ postprocess macros
 332 ;;;
 333
 334 (put 'pgg-process-when-success 'lisp-indent-function 0)
 335
 336 (defmacro pgg-process-when-success (&rest body)
 337   `(with-current-buffer pgg-output-buffer
 338      (if (zerop (buffer-size)) nil ,@body t)))
 339
 340 (provide 'pgg)
 341
 342 ;;; pgg.el ends here