wl/wl-action.el

   1 ;;; wl-action.el --- Mark and actions in the Summary mode for Wanderlust.
   2
   3 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-summary)
  33
  34 (eval-when-compile
  35   (defalias-maybe 'wl-summary-target-mark 'ignore)
  36   (defalias-maybe 'wl-summary-target-mark-region 'ignore))
  37
  38 (defsubst wl-summary-action-mark (action)
  39   (nth 0 action))
  40 (defsubst wl-summary-action-symbol (action)
  41   (nth 1 action))
  42 (defsubst wl-summary-action-argument-function (action)
  43   (nth 2 action))
  44 (defsubst wl-summary-action-set-function (action)
  45   (nth 3 action))
  46 (defsubst wl-summary-action-exec-function (action)
  47   (nth 4 action))
  48 (defsubst wl-summary-action-face (action)
  49   (nth 5 action))
  50 (defsubst wl-summary-action-docstring (action)
  51   (concat (nth 6 action)
  52           "\nThis function is defined by `wl-summary-define-mark-action'."))
  53
  54 ;; Set mark
  55 (defun wl-summary-set-mark (&optional set-mark number interactive data)
  56   (interactive)
  57   "Set temporary mark SET-MARK on the message with NUMBER.
  58 NUMBER is the message number to set the mark on.
  59 INTERACTIVE is set as t if it have to run interactively.
  60 DATA is passed to the set-action function of the action as an argument.
  61 Return number if put mark succeed"
  62   (let* ((set-mark (or set-mark
  63                        (completing-read "Mark: " wl-summary-mark-action-list)))
  64          (current (wl-summary-message-number))
  65          (action (assoc set-mark wl-summary-mark-action-list))
  66          visible mark cur-mark)
  67     (when (zerop (elmo-folder-length wl-summary-buffer-elmo-folder))
  68       (error "Set mark failed"))
  69     (prog1
  70         (save-excursion
  71           ;; Put mark
  72           (if number
  73               ;; Jump to message if cursor is not on the message.
  74               (when (and (setq visible (wl-summary-message-visible-p number))
  75                          (not (eq number current)))
  76                 (wl-summary-jump-to-msg number))
  77             (setq visible t
  78                   number current))
  79           (setq cur-mark (nth 1 (wl-summary-registered-temp-mark number)))
  80           (unless number
  81             (error "No message"))
  82           (if (wl-summary-reserve-temp-mark-p cur-mark)
  83               (when interactive
  84                 (error "Already marked as `%s'" cur-mark))
  85             (when (and interactive
  86                        (null data)
  87                        (wl-summary-action-argument-function action))
  88               (setq data (funcall (wl-summary-action-argument-function action)
  89                                   (wl-summary-action-symbol action)
  90                                   number)))
  91             ;; Unset the current mark.
  92             (wl-summary-unset-mark number)
  93             ;; Set action.
  94             (funcall (wl-summary-action-set-function action)
  95                      number
  96                      (wl-summary-action-mark action)
  97                      data)
  98             (when visible
  99               (wl-summary-put-temp-mark set-mark)
 100               (when wl-summary-highlight
 101                 (wl-highlight-summary-current-line))
 102               (when data
 103                 (wl-summary-print-argument number data)))
 104             (set-buffer-modified-p nil)
 105             ;; Return value.
 106             number))
 107       ;; Move the cursor.
 108       (if (or interactive (interactive-p))
 109           (if (eq wl-summary-move-direction-downward nil)
 110               (wl-summary-prev)
 111             (wl-summary-next))))))
 112
 113 (defun wl-summary-register-target-mark (number mark data)
 114   (or (memq number wl-summary-buffer-target-mark-list)
 115       (setq wl-summary-buffer-target-mark-list
 116             (cons number wl-summary-buffer-target-mark-list))))
 117
 118 (defun wl-summary-unregister-target-mark (number)
 119   (setq wl-summary-buffer-target-mark-list
 120         (delq number wl-summary-buffer-target-mark-list)))
 121
 122 (defun wl-summary-have-target-mark-p (number)
 123   (memq number wl-summary-buffer-target-mark-list))
 124
 125 (defun wl-summary-target-mark-set-action (action)
 126   (unless (eq (wl-summary-action-symbol action) 'target-mark)
 127     (save-excursion
 128       (goto-char (point-min))
 129       (let ((numlist wl-summary-buffer-number-list)
 130             number mlist data)
 131         ;; use firstly marked message.
 132         (when (wl-summary-action-argument-function action)
 133           (while numlist
 134             (if (memq (car numlist) wl-summary-buffer-target-mark-list)
 135                 (setq number (car numlist)
 136                       numlist nil))
 137             (setq numlist (cdr numlist)))
 138           (wl-summary-jump-to-msg number)
 139           (setq data (funcall (wl-summary-action-argument-function action)
 140                               (wl-summary-action-symbol action) number)))
 141         (while (not (eobp))
 142           (when (string= (wl-summary-temp-mark) "*")
 143             (let (wl-summary-buffer-disp-msg)
 144               (when (setq number (wl-summary-message-number))
 145                 (wl-summary-set-mark (wl-summary-action-mark action)
 146                                      nil nil data)
 147                 (setq wl-summary-buffer-target-mark-list
 148                       (delq number wl-summary-buffer-target-mark-list)))))
 149           (forward-line 1))
 150         (setq mlist wl-summary-buffer-target-mark-list)
 151         (while mlist
 152           (wl-summary-register-temp-mark (car mlist)
 153                                          (wl-summary-action-mark action) data)
 154           (setq wl-summary-buffer-target-mark-list
 155                 (delq (car mlist) wl-summary-buffer-target-mark-list))
 156           (setq mlist (cdr mlist)))))))
 157
 158 ;; wl-summary-buffer-temp-mark-list specification
 159 ;; ((1 "D" nil)(2 "o" "+fuga")(3 "O" "+hoge"))
 160 (defun wl-summary-register-temp-mark (number mark mark-info)
 161   (let ((elem (assq number wl-summary-buffer-temp-mark-list)))
 162     (setq wl-summary-buffer-temp-mark-list
 163           (delq elem wl-summary-buffer-temp-mark-list)))
 164   (setq wl-summary-buffer-temp-mark-list
 165         (cons (list number mark mark-info) wl-summary-buffer-temp-mark-list)))
 166
 167 (defun wl-summary-unregister-temp-mark (number)
 168   (let ((elem (assq number wl-summary-buffer-temp-mark-list)))
 169     (setq wl-summary-buffer-temp-mark-list
 170           (delq elem wl-summary-buffer-temp-mark-list))))
 171
 172 (defun wl-summary-registered-temp-mark (number)
 173   (and wl-summary-buffer-temp-mark-list
 174        (assq number wl-summary-buffer-temp-mark-list)))
 175
 176 (defun wl-summary-collect-temp-mark (mark &optional begin end)
 177   (if (or begin end)
 178       (save-excursion
 179         (save-restriction
 180           (let (mark-list)
 181             (narrow-to-region (or begin (point-min))(or end (point-max)))
 182             (goto-char (point-min))
 183             ;; for thread...
 184             (if (eq wl-summary-buffer-view 'thread)
 185                 (let (number entity mark-info)
 186                   (while (not (eobp))
 187                     (setq number (wl-summary-message-number)
 188                           entity (wl-thread-get-entity number)
 189                           mark-info (wl-summary-registered-temp-mark number))
 190                     ;; toplevel message mark.
 191                     (when (string= (nth 1 mark-info) mark)
 192                       (setq mark-list (cons mark-info mark-list)))
 193                     ;; When thread is closed...children should also be checked.
 194                     (unless (wl-thread-entity-get-opened entity)
 195                       (dolist (msg (wl-thread-get-children-msgs number))
 196                         (setq mark-info (wl-summary-registered-temp-mark
 197                                          msg))
 198                         (when (string= (nth 1 mark-info) mark)
 199                           (setq mark-list (cons mark-info mark-list)))))
 200                     (forward-line 1)))
 201               (let (number mark-info)
 202                 (while (not (eobp))
 203                   (setq number (wl-summary-message-number)
 204                         mark-info (wl-summary-registered-temp-mark number))
 205                   (when (string= (nth 1 mark-info) mark)
 206                     (setq mark-list (cons mark-info mark-list)))
 207                   (forward-line 1))))
 208             mark-list)))
 209     (let (mark-list)
 210       (dolist (mark-info wl-summary-buffer-temp-mark-list)
 211         (when (string= (nth 1 mark-info) mark)
 212           (setq mark-list (cons mark-info mark-list))))
 213       mark-list)))
 214
 215 ;; Unset mark
 216 (defun wl-summary-unset-mark (&optional number interactive force)
 217   "Unset temporary mark of the message with NUMBER.
 218 NUMBER is the message number to unset the mark.
 219 If not specified, the message on the cursor position is treated.
 220 Optional INTERACTIVE is non-nil when it should be called interactively.
 221 If optional FORCE is non-nil, remove scored mark too.
 222 Return number if put mark succeed"
 223   (interactive)
 224   (save-excursion
 225     (beginning-of-line)
 226     (let ((buffer-read-only nil)
 227           visible mark action)
 228       (if number
 229           ;; Jump to message
 230           (when (and (setq visible (wl-summary-message-visible-p number))
 231                      (not (eq number (wl-summary-message-number))))
 232             (wl-summary-jump-to-msg number))
 233         (setq visible t
 234               number (wl-summary-message-number)))
 235       (setq mark (wl-summary-temp-mark))
 236       ;; Remove from temporal mark structure.
 237       (wl-summary-unregister-target-mark number)
 238       (wl-summary-unregister-temp-mark number)
 239       ;; Delete mark on buffer.
 240       (when visible
 241         (unless (string= mark " ")
 242           (wl-summary-put-temp-mark
 243            (or (unless force (wl-summary-get-score-mark number))
 244                " "))
 245           (setq action (assoc mark wl-summary-mark-action-list))
 246           (when wl-summary-highlight
 247             (wl-highlight-summary-current-line))
 248           (when (wl-summary-action-argument-function action)
 249             (wl-summary-remove-argument)))
 250         (set-buffer-modified-p nil))))
 251   ;; Move the cursor.
 252   ;;  (if (or interactive (interactive-p))
 253   ;;      (if (eq wl-summary-move-direction-downward nil)
 254   ;;      (wl-summary-prev)
 255   ;;    (wl-summary-next))))
 256   )
 257
 258 (defun wl-summary-make-destination-numbers-list (mark-list)
 259   (let (dest-numbers dest-number)
 260     (dolist (elem mark-list)
 261       (setq dest-number (assoc (nth 2 elem) dest-numbers))
 262       (if dest-number
 263           (unless (memq (car elem) (cdr dest-number))
 264             (nconc dest-number (list (car elem))))
 265         (setq dest-numbers (nconc dest-numbers
 266                                   (list
 267                                    (list (nth 2 elem)
 268                                          (car elem)))))))
 269     dest-numbers))
 270
 271 (defun wl-summary-move-mark-list-messages (mark-list folder-name message)
 272   (if (null mark-list)
 273       (message "No marks")
 274     (save-excursion
 275       (let ((start (point))
 276             (refiles (mapcar 'car mark-list))
 277             (refile-failures 0)
 278             refile-len
 279             dst-msgs                    ; loop counter
 280             result)
 281         ;; begin refile...
 282         (setq refile-len (length refiles))
 283         (goto-char start)               ; avoid moving cursor to
 284                                         ; the bottom line.
 285         (message message)
 286         (when (> refile-len elmo-display-progress-threshold)
 287           (elmo-progress-set 'elmo-folder-move-messages
 288                              refile-len message))
 289         (setq result nil)
 290         (condition-case nil
 291             (setq result (elmo-folder-move-messages
 292                           wl-summary-buffer-elmo-folder
 293                           refiles
 294                           (if (eq folder-name 'null)
 295                               'null
 296                             (wl-folder-get-elmo-folder folder-name))))
 297           (error nil))
 298         (when result            ; succeeded.
 299           ;; update buffer.
 300           (wl-summary-delete-messages-on-buffer refiles)
 301           ;; update wl-summary-buffer-temp-mark-list.
 302           (dolist (mark-info mark-list)
 303             (setq wl-summary-buffer-temp-mark-list
 304                   (delq mark-info wl-summary-buffer-temp-mark-list))))
 305         (elmo-progress-clear 'elmo-folder-move-messages)
 306         (message (concat message "done"))
 307         (wl-summary-set-message-modified)
 308         ;; Return the operation failed message numbers.
 309         (if result
 310             0
 311           (length refiles))))))
 312
 313 (defun wl-summary-get-refile-destination-subr (action number learn)
 314   (let* ((number (or number (wl-summary-message-number)))
 315          (msgid (and number
 316                      (elmo-message-field wl-summary-buffer-elmo-folder
 317                                          number 'message-id)))
 318          (entity (and number
 319                       (elmo-message-entity wl-summary-buffer-elmo-folder
 320                                            number)))
 321          folder cur-mark tmp-folder)
 322     (catch 'done
 323       (when (null entity)
 324         (message "Cannot decide destination.")
 325         (throw 'done nil))
 326       (when (null number)
 327         (message "No message.")
 328         (throw 'done nil))
 329       (setq folder (wl-summary-read-folder
 330                     (or (wl-refile-guess entity) wl-trash-folder)
 331                     (format "for %s " action)))
 332       ;; Cache folder hack by okada@opaopa.org
 333       (when (and (eq (elmo-folder-type-internal
 334                       (wl-folder-get-elmo-folder
 335                        (wl-folder-get-realname folder))) 'cache)
 336                  (not (string= folder
 337                                (setq tmp-folder
 338                                      (concat "'cache/"
 339                                              (elmo-cache-get-path-subr
 340                                               (elmo-msgid-to-cache msgid)))))))
 341         (setq folder tmp-folder)
 342         (message "Force refile to %s." folder))
 343       (if (string= folder (wl-summary-buffer-folder-name))
 344           (error "Same folder"))
 345       (if (or (not (elmo-folder-writable-p (wl-folder-get-elmo-folder folder)))
 346               (string= folder wl-queue-folder)
 347               (string= folder wl-draft-folder))
 348           (error "Don't set as target: %s" folder))
 349       ;; learn for refile.
 350       (when learn
 351         (wl-refile-learn entity folder))
 352       folder)))
 353
 354 ;;; Actions
 355 (defun wl-summary-define-mark-action ()
 356   (interactive)
 357   (dolist (action wl-summary-mark-action-list)
 358     (fset (intern (format "wl-summary-%s" (wl-summary-action-symbol action)))
 359           `(lambda (&optional number data)
 360              ,(wl-summary-action-docstring action)
 361              (interactive)
 362              (wl-summary-set-mark ,(wl-summary-action-mark action)
 363                                   number (interactive-p) data)))
 364     (fset (intern (format "wl-summary-%s-region"
 365                           (wl-summary-action-symbol action)))
 366           `(lambda (beg end)
 367              ,(wl-summary-action-docstring action)
 368              (interactive "r")
 369              (save-excursion
 370                (goto-char beg)
 371                (wl-summary-mark-region-subr
 372                 (quote ,(intern (format "wl-summary-%s"
 373                                         (wl-summary-action-symbol action))))
 374                 beg end
 375                 (if (quote ,(wl-summary-action-argument-function action))
 376                     (funcall (function
 377                               ,(wl-summary-action-argument-function action))
 378                              (quote ,(wl-summary-action-symbol action))
 379                              (wl-summary-message-number)))))))
 380     (fset (intern (format "wl-summary-target-mark-%s"
 381                           (wl-summary-action-symbol action)))
 382           `(lambda ()
 383              ,(wl-summary-action-docstring action)
 384              (interactive)
 385              (wl-summary-target-mark-set-action (quote ,action))))
 386     (fset (intern (format "wl-thread-%s"
 387                           (wl-summary-action-symbol action)))
 388           `(lambda (arg)
 389              ,(wl-summary-action-docstring action)
 390              (interactive "P")
 391              (wl-thread-call-region-func
 392               (quote ,(intern (format "wl-summary-%s-region"
 393                                       (wl-summary-action-symbol action))))
 394               arg)
 395              (if arg
 396                  (wl-summary-goto-top-of-current-thread))
 397              (if (not wl-summary-move-direction-downward)
 398                  (wl-summary-prev)
 399                (wl-thread-goto-bottom-of-sub-thread)
 400                (if wl-summary-buffer-disp-msg
 401                    (wl-summary-redisplay)))))))
 402
 403 (defun wl-summary-get-dispose-folder (folder)
 404   (if (string= folder wl-trash-folder)
 405       'null
 406     (let* ((type (or (wl-get-assoc-list-value wl-dispose-folder-alist folder)
 407                      'trash)))
 408       (cond ((stringp type)
 409              type)
 410             ((or (equal type 'remove) (equal type 'null))
 411              'null)
 412             (t;; (equal type 'trash)
 413              (let ((trash-folder (wl-folder-get-elmo-folder wl-trash-folder)))
 414                (unless (elmo-folder-exists-p trash-folder)
 415                  (if (y-or-n-p
 416                       (format "Trash Folder %s does not exist, create it? "
 417                               wl-trash-folder))
 418                      (elmo-folder-create trash-folder)
 419                    (error "Trash Folder is not created"))))
 420              wl-trash-folder)))))
 421
 422 ;; Dispose action.
 423 (defun wl-summary-exec-action-dispose (mark-list)
 424   (wl-summary-move-mark-list-messages mark-list
 425                                       (wl-summary-get-dispose-folder
 426                                        (wl-summary-buffer-folder-name))
 427                                       "Disposing messages..."))
 428
 429 ;; Delete action.
 430 (defun wl-summary-exec-action-delete (mark-list)
 431   (wl-summary-move-mark-list-messages mark-list
 432                                       'null
 433                                       "Deleting messages..."))
 434
 435 ;; Refile action
 436 (defun wl-summary-set-action-refile (number mark data)
 437   (let ((policy (wl-get-assoc-list-value wl-refile-policy-alist
 438                                          (wl-summary-buffer-folder-name)))
 439         (elem wl-summary-mark-action-list))
 440     (if (eq policy 'copy)
 441         (while elem
 442           (when (eq (wl-summary-action-symbol (car elem)) 'copy)
 443             (wl-summary-register-temp-mark number
 444                                            (wl-summary-action-mark (car elem))
 445                                            data)
 446             (setq elem nil))
 447           (setq elem (cdr elem)))
 448       (wl-summary-register-temp-mark number mark data)
 449       (setq wl-summary-buffer-prev-refile-destination data))))
 450
 451 (defun wl-summary-get-refile-destination (action number)
 452   "Decide refile destination."
 453   (wl-summary-get-refile-destination-subr action number t))
 454
 455 (defun wl-summary-exec-action-refile (mark-list)
 456   (save-excursion
 457     (let ((start (point))
 458           (failures 0)
 459           (refile-len (length mark-list))
 460           dst-msgs ; loop counter
 461           result)
 462       ;; begin refile...
 463       (setq dst-msgs
 464             (wl-summary-make-destination-numbers-list mark-list))
 465       (goto-char start) ; avoid moving cursor to the bottom line.
 466       (when (> refile-len elmo-display-progress-threshold)
 467         (elmo-progress-set 'elmo-folder-move-messages
 468                            refile-len "Refiling messages..."))
 469       (while dst-msgs
 470         (setq result nil)
 471         (condition-case nil
 472             (setq result (elmo-folder-move-messages
 473                           wl-summary-buffer-elmo-folder
 474                           (cdr (car dst-msgs))
 475                           (wl-folder-get-elmo-folder (car (car dst-msgs)))))
 476           (error nil))
 477         (if result              ; succeeded.
 478             (progn
 479               ;; update buffer.
 480               (wl-summary-delete-messages-on-buffer (cdr (car dst-msgs)))
 481               (setq wl-summary-buffer-temp-mark-list
 482                     (wl-delete-associations
 483                      (cdr (car dst-msgs))
 484                      wl-summary-buffer-temp-mark-list)))
 485           (setq failures
 486                 (+ failures (length (cdr (car dst-msgs))))))
 487         (setq dst-msgs (cdr dst-msgs)))
 488       (elmo-progress-clear 'elmo-folder-move-messages)
 489       failures)))
 490
 491 ;; Copy action
 492 (defun wl-summary-get-copy-destination (action number)
 493   (wl-summary-get-refile-destination-subr action number nil))
 494
 495 (defun wl-summary-exec-action-copy (mark-list)
 496   (save-excursion
 497     (let ((start (point))
 498           (failures 0)
 499           (refile-len (length mark-list))
 500           dst-msgs ; loop counter
 501           result)
 502       ;; begin refile...
 503       (setq dst-msgs
 504             (wl-summary-make-destination-numbers-list mark-list))
 505       (goto-char start) ; avoid moving cursor to the bottom line.
 506       (when (> refile-len elmo-display-progress-threshold)
 507         (elmo-progress-set 'elmo-folder-move-messages
 508                            refile-len "Copying messages..."))
 509       (while dst-msgs
 510         (setq result nil)
 511         (condition-case nil
 512             (setq result (elmo-folder-move-messages
 513                           wl-summary-buffer-elmo-folder
 514                           (cdr (car dst-msgs))
 515                           (wl-folder-get-elmo-folder (car (car dst-msgs)))
 516                           'no-delete))
 517           (error nil))
 518         (if result              ; succeeded.
 519             (progn
 520               ;; update buffer.
 521               (wl-summary-delete-copy-marks-on-buffer (cdr (car dst-msgs)))
 522               (setq wl-summary-buffer-temp-mark-list
 523                     (wl-delete-associations
 524                      (cdr (car dst-msgs))
 525                      wl-summary-buffer-temp-mark-list)))
 526           (setq failures
 527                 (+ failures (length (cdr (car dst-msgs))))))
 528         (setq dst-msgs (cdr dst-msgs)))
 529       (elmo-progress-clear 'elmo-folder-move-messages)
 530       failures)))
 531
 532 ;; Prefetch.
 533 (defun wl-summary-exec-action-prefetch (mark-list)
 534   (save-excursion
 535     (let* ((count 0)
 536            (length (length mark-list))
 537            (mark-list-copy (copy-sequence mark-list))
 538            (pos (point))
 539            (failures 0))
 540       (dolist (mark-info mark-list-copy)
 541         (message "Prefetching...(%d/%d)"
 542                  (setq count (+ 1 count)) length)
 543         (if (wl-summary-prefetch-msg (car mark-info))
 544             (progn
 545               (wl-summary-unset-mark (car mark-info))
 546               (sit-for 0))
 547           (incf failures)))
 548       (message "Prefetching...done")
 549       0)))
 550
 551 ;; Resend.
 552 (defun wl-summary-get-resend-address (action number)
 553   "Decide resend address."
 554   (completing-read "Resend message to: " 'wl-complete-address))
 555
 556 (defun wl-summary-exec-action-resend (mark-list)
 557   (let ((failure 0))
 558     (dolist (mark-info mark-list)
 559       (if (condition-case nil
 560               (progn
 561                 (wl-summary-exec-action-resend-subr (car mark-info)
 562                                                     (nth 2 mark-info))
 563                 t)
 564             (error))
 565           (wl-summary-unmark (car mark-info))
 566         (incf failure)))
 567     failure))
 568
 569 (defun wl-summary-exec-action-resend-subr (number address)
 570   "Resend the message with NUMBER to ADDRESS."
 571   (message "Resending message to %s..." address)
 572   (let ((folder wl-summary-buffer-elmo-folder))
 573     (save-excursion
 574       ;; We first set up a normal mail buffer.
 575       (set-buffer (get-buffer-create " *wl-draft-resend*"))
 576       (buffer-disable-undo (current-buffer))
 577       (erase-buffer)
 578       (setq wl-sent-message-via nil)
 579       ;; Insert our usual headers.
 580       (wl-draft-insert-from-field)
 581       (wl-draft-insert-date-field)
 582       (insert "To: " address "\n")
 583       (goto-char (point-min))
 584       ;; Rename them all to "Resent-*".
 585       (while (re-search-forward "^[A-Za-z]" nil t)
 586         (forward-char -1)
 587         (insert "Resent-"))
 588       (widen)
 589       (forward-line)
 590       (delete-region (point) (point-max))
 591       (let ((beg (point)))
 592         ;; Insert the message to be resent.
 593         (insert
 594          (with-temp-buffer
 595            (elmo-message-fetch folder number
 596                                (elmo-make-fetch-strategy 'entire)
 597                                nil (current-buffer) 'unread)
 598            (buffer-string)))
 599         (goto-char (point-min))
 600         (search-forward "\n\n")
 601         (forward-char -1)
 602         (save-restriction
 603           (narrow-to-region beg (point))
 604           (wl-draft-delete-fields wl-ignored-resent-headers)
 605           (goto-char (point-max)))
 606         (insert mail-header-separator)
 607         ;; Rename all old ("Previous-")Resent headers.
 608         (while (re-search-backward "^\\(Previous-\\)*Resent-" beg t)
 609           (beginning-of-line)
 610           (insert "Previous-"))
 611         ;; Quote any "From " lines at the beginning.
 612         (goto-char beg)
 613         (when (looking-at "From ")
 614           (replace-match "X-From-Line: ")))
 615       ;; Send it.
 616       (wl-draft-dispatch-message)
 617       (kill-buffer (current-buffer)))
 618     (message "Resending message to %s...done" address)))
 619
 620 ;;;
 621 (defun wl-summary-remove-argument ()
 622   (save-excursion
 623     (let ((inhibit-read-only t)
 624           (buffer-read-only nil)
 625           (buf (current-buffer))
 626           sol eol rs re)
 627       (beginning-of-line)
 628       (setq sol (point))
 629       (search-forward "\r")
 630       (forward-char -1)
 631       (setq eol (point))
 632       (setq rs (next-single-property-change sol 'wl-summary-action-argument
 633                                             buf eol))
 634       (setq re (next-single-property-change rs 'wl-summary-action-argument
 635                                             buf eol))
 636       (put-text-property rs re 'wl-summary-action-argument nil)
 637       (put-text-property rs re 'invisible nil)
 638       (goto-char re)
 639       (delete-char (- eol re)))))
 640
 641 (defun wl-summary-collect-numbers-region (begin end)
 642   "Return a list of message number in the region specified by BEGIN and END."
 643   (save-excursion
 644     (save-restriction
 645       (let (numbers)
 646         (wl-summary-narrow-to-region (or begin (point-min))(or end (point-max)))
 647         (goto-char (point-min))
 648         ;; for thread...
 649         (if (eq wl-summary-buffer-view 'thread)
 650             (let (number entity)
 651               (while (not (eobp))
 652                 (setq numbers (cons (wl-summary-message-number) numbers)
 653                       entity (wl-thread-get-entity number))
 654                 ;; When thread is closed...children should also be checked.
 655                 (unless (wl-thread-entity-get-opened entity)
 656                   (dolist (msg (wl-thread-get-children-msgs number))
 657                     (setq numbers (cons msg numbers))))
 658                 (forward-line 1)))
 659           (let (number)
 660             (while (not (eobp))
 661               (setq numbers (cons (wl-summary-message-number) numbers))
 662               (forward-line 1))))
 663         (nreverse (delq nil numbers))))))
 664
 665 (defun wl-summary-exec (&optional numbers)
 666   (interactive)
 667   (let ((failures 0)
 668         collected pair action modified)
 669     (dolist (action wl-summary-mark-action-list)
 670       (setq collected (cons (cons
 671                              (wl-summary-action-mark action)
 672                              nil) collected)))
 673     (dolist (mark-info wl-summary-buffer-temp-mark-list)
 674       (if numbers
 675           (when (memq (nth 0 mark-info) numbers)
 676             (setq pair (assoc (nth 1 mark-info) collected)))
 677         (setq pair (assoc (nth 1 mark-info) collected)))
 678       (setq pair (assoc (nth 1 mark-info) collected))
 679       (setcdr pair (cons mark-info (cdr pair))))
 680     ;; collected is a pair of
 681     ;; mark-string and a list of mark-info
 682     (dolist (pair collected)
 683       (setq action (assoc (car pair) wl-summary-mark-action-list))
 684       (when (and (cdr pair) (wl-summary-action-exec-function action))
 685         (setq modified t)
 686         (setq failures (+ failures (funcall
 687                                     (wl-summary-action-exec-function action)
 688                                     (cdr pair))))))
 689     (when modified
 690       (wl-summary-set-message-modified))
 691     (run-hooks 'wl-summary-exec-hook)
 692     ;; message buffer is not up-to-date
 693     (unless (and wl-message-buffer
 694                  (eq (wl-summary-message-number)
 695                      (with-current-buffer wl-message-buffer
 696                        wl-message-buffer-cur-number)))
 697       (wl-summary-toggle-disp-msg 'off)
 698       (setq wl-message-buffer nil))
 699     (set-buffer-modified-p nil)
 700     (when (> failures 0)
 701       (format "%d execution(s) were failed" failures))))
 702
 703 (defun wl-summary-exec-region (beg end)
 704   (interactive "r")
 705   (wl-summary-exec
 706    (wl-summary-collect-numbers-region beg end)))
 707
 708 (defun wl-summary-read-folder (default &optional purpose ignore-error
 709                                 no-create init)
 710   (let ((fld (completing-read
 711               (format "Folder name %s(%s): " (or purpose "")
 712                       default)
 713               'wl-folder-complete-folder
 714               nil nil (or init wl-default-spec)
 715               'wl-read-folder-history)))
 716     (if (or (string= fld wl-default-spec)
 717             (string= fld ""))
 718         (setq fld default))
 719     (setq fld (elmo-string (wl-folder-get-realname fld)))
 720     (if (string-match "\n" fld)
 721         (error "Not supported folder name: %s" fld))
 722     (unless no-create
 723       (if ignore-error
 724           (condition-case nil
 725               (wl-folder-confirm-existence
 726                (wl-folder-get-elmo-folder
 727                 fld))
 728             (error))
 729         (wl-folder-confirm-existence (wl-folder-get-elmo-folder
 730                                       fld))))
 731     fld))
 732
 733 (defun wl-summary-print-argument (msg-num folder)
 734   "Print action argument on line."
 735   (when folder
 736     (wl-summary-remove-argument)
 737     (save-excursion
 738       (let ((inhibit-read-only t)
 739             (folder (copy-sequence folder))
 740             (buffer-read-only nil)
 741             len rs re c)
 742         (setq len (string-width folder))
 743         (if (< len 1) ()
 744           ;;(end-of-line)
 745           (beginning-of-line)
 746           (search-forward "\r")
 747           (forward-char -1)
 748           (setq re (point))
 749           (let ((width (cond (wl-summary-width
 750                               (1- wl-summary-width))
 751                              (wl-summary-print-argument-within-window
 752                               (1- (window-width)))))
 753                 (c (current-column))
 754                 (padding 0))
 755             (if (and width (> (+ c len) width))
 756                 (progn
 757                   (move-to-column width)
 758                   (setq c (current-column))
 759                   (while (> (+ c len) width)
 760                     (forward-char -1)
 761                     (setq c (current-column)))
 762                   (when (< (+ c len) width)
 763                     (setq folder (concat " " folder)))
 764                   (setq rs (point))
 765                   (put-text-property rs re 'invisible t))
 766               (when (and width
 767                          (> (setq padding (- width len c)) 0))
 768                 (setq folder (concat (make-string padding ?\ )
 769                                      folder)))
 770               (setq rs (1- re))))
 771           (put-text-property rs re 'wl-summary-action-argument t)
 772           (goto-char re)
 773           (wl-highlight-action-argument-string folder)
 774           (insert folder)
 775           (set-buffer-modified-p nil))))))
 776
 777 (defsubst wl-summary-reserve-temp-mark-p (mark)
 778   "Return t if temporal MARK should be reserved."
 779   (member mark wl-summary-reserve-mark-list))
 780
 781 (defun wl-summary-refile-prev-destination ()
 782   "Refile message to previously refiled destination."
 783   (interactive)
 784   (funcall (symbol-function 'wl-summary-refile)
 785            wl-summary-buffer-prev-refile-destination)
 786   (if (eq wl-summary-move-direction-downward nil)
 787       (wl-summary-prev)
 788     (wl-summary-next)))
 789
 790 (defsubst wl-summary-no-auto-refile-message-p (number)
 791   (member (wl-summary-message-mark wl-summary-buffer-elmo-folder number)
 792           wl-summary-auto-refile-skip-marks))
 793
 794 (defvar wl-auto-refile-guess-functions
 795   '(wl-refile-guess-by-rule)
 796   "*List of functions which is used for guessing refile destination folder.")
 797
 798 (defun wl-summary-auto-refile (&optional open-all)
 799   "Set refile mark automatically according to 'wl-refile-guess-by-rule'."
 800   (interactive "P")
 801   (message "Marking...")
 802   (save-excursion
 803     (if (and (eq wl-summary-buffer-view 'thread)
 804              open-all)
 805         (wl-thread-open-all))
 806     (let* ((spec (wl-summary-buffer-folder-name))
 807            checked-dsts
 808            (count 0)
 809            number dst thr-entity)
 810       (goto-line 1)
 811       (while (not (eobp))
 812         (setq number (wl-summary-message-number))
 813         (dolist (number (cons number
 814                               (and (eq wl-summary-buffer-view 'thread)
 815                                    ;; process invisible children.
 816                                    (not (wl-thread-entity-get-opened
 817                                          (setq thr-entity
 818                                                (wl-thread-get-entity number))))
 819                                    (wl-thread-entity-get-descendant
 820                                     thr-entity))))
 821           (when (and (not (wl-summary-no-auto-refile-message-p
 822                            number))
 823                      (setq dst
 824                            (wl-folder-get-realname
 825                             (wl-refile-guess
 826                              (elmo-message-entity wl-summary-buffer-elmo-folder
 827                                                   number)
 828                              wl-auto-refile-guess-functions)))
 829                      (not (equal dst spec))
 830                      (let ((pair (assoc dst checked-dsts))
 831                            ret)
 832                        (if pair
 833                            (cdr pair)
 834                          (setq ret
 835                                (condition-case nil
 836                                    (progn
 837                                      (wl-folder-confirm-existence
 838                                       (wl-folder-get-elmo-folder dst))
 839                                      t)
 840                                  (error)))
 841                          (setq checked-dsts (cons (cons dst ret) checked-dsts))
 842                          ret)))
 843             (if (funcall (symbol-function 'wl-summary-refile) number dst)
 844                 (incf count))
 845             (message "Marking...%d message(s)." count)))
 846         (forward-line))
 847       (if (eq count 0)
 848           (message "No message was marked.")
 849         (message "Marked %d message(s)." count)))))
 850
 851 (defun wl-summary-unmark (&optional number)
 852   "Unmark marks (temporary, refile, copy, delete)of current line.
 853 If optional argument NUMBER is specified, unmark message specified by NUMBER."
 854   (interactive)
 855   (wl-summary-unset-mark number (interactive-p)))
 856
 857 (defun wl-summary-unmark-region (beg end)
 858   (interactive "r")
 859   (save-excursion
 860     (save-restriction
 861       (wl-summary-narrow-to-region beg end)
 862       (goto-char (point-min))
 863       (if (eq wl-summary-buffer-view 'thread)
 864           (progn
 865             (while (not (eobp))
 866               (let* ((number (wl-summary-message-number))
 867                      (entity (wl-thread-get-entity number)))
 868                 (if (wl-thread-entity-get-opened entity)
 869                     ;; opened...unmark line.
 870                     (wl-summary-unmark)
 871                   ;; closed
 872                   (wl-summary-delete-marks-on-buffer
 873                    (wl-thread-get-children-msgs number))))
 874               (forward-line 1)))
 875         (while (not (eobp))
 876           (wl-summary-unmark)
 877           (forward-line 1))))))
 878
 879 (defun wl-summary-mark-region-subr (function beg end data)
 880   (save-excursion
 881     (save-restriction
 882       (wl-summary-narrow-to-region beg end)
 883       (goto-char (point-min))
 884       (if (eq wl-summary-buffer-view 'thread)
 885           (progn
 886             (while (not (eobp))
 887               (let* ((number (wl-summary-message-number))
 888                      (entity (wl-thread-get-entity number))
 889                      (wl-summary-move-direction-downward t)
 890                      children)
 891                 (if (wl-thread-entity-get-opened entity)
 892                     ;; opened...delete line.
 893                     (funcall function nil data)
 894                   ;; closed
 895                   (setq children (wl-thread-get-children-msgs number))
 896                   (while children
 897                     (funcall function (pop children) data)))
 898                 (forward-line 1))))
 899         (while (not (eobp))
 900           (funcall function nil data)
 901           (forward-line 1))))))
 902
 903 (defun wl-summary-target-mark-all ()
 904   (interactive)
 905   (wl-summary-target-mark-region (point-min) (point-max))
 906   (setq wl-summary-buffer-target-mark-list
 907         (elmo-folder-list-messages wl-summary-buffer-elmo-folder
 908                                    nil 'in-msgdb)))
 909
 910 (defun wl-summary-delete-all-mark (mark)
 911   (goto-char (point-min))
 912   (while (not (eobp))
 913     (when (string= (wl-summary-temp-mark) mark)
 914       (wl-summary-unmark))
 915     (forward-line 1))
 916   (let (deleted)
 917     (dolist (mark-info wl-summary-buffer-temp-mark-list)
 918       (when (string= (nth 1 mark-info) mark)
 919         (setq deleted (cons mark-info deleted))))
 920     (dolist (delete deleted)
 921       (setq wl-summary-buffer-temp-mark-list
 922             (delq delete wl-summary-buffer-temp-mark-list)))))
 923
 924 (defun wl-summary-unmark-all ()
 925   "Unmark all according to what you input."
 926   (interactive)
 927   (let ((unmarks (string-to-char-list (read-from-minibuffer "Unmark: ")))
 928         cur-mark)
 929     (save-excursion
 930       (while unmarks
 931         (setq cur-mark (char-to-string (car unmarks)))
 932         (wl-summary-delete-all-mark cur-mark)
 933         (setq unmarks (cdr unmarks))))))
 934
 935 (defun wl-summary-target-mark-thread ()
 936   (interactive)
 937   (wl-thread-call-region-func 'wl-summary-target-mark-region t))
 938
 939 (require 'product)
 940 (product-provide (provide 'wl-action) (require 'wl-version))
 941
 942 ;;; wl-action.el ends here