wl/wl-action.el

   1 ;;; wl-action.el --- Mark and actions in the Summary mode for Wanderlust.
   2
   3 ;; Copyright (C) 2003 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-summary)
  33
  34 (eval-when-compile
  35   (defalias-maybe 'wl-summary-target-mark 'ignore)
  36   (defalias-maybe 'wl-summary-target-mark-region 'ignore))
  37
  38 (defsubst wl-summary-action-mark (action)
  39   (nth 0 action))
  40 (defsubst wl-summary-action-symbol (action)
  41   (nth 1 action))
  42 (defsubst wl-summary-action-argument-function (action)
  43   (nth 2 action))
  44 (defsubst wl-summary-action-set-function (action)
  45   (nth 3 action))
  46 (defsubst wl-summary-action-exec-function (action)
  47   (nth 4 action))
  48 (defsubst wl-summary-action-face (action)
  49   (nth 5 action))
  50 (defsubst wl-summary-action-docstring (action)
  51   (concat (nth 6 action)
  52           "\nThis function is defined by `wl-summary-define-mark-action'."))
  53
  54 ;; Set mark
  55 (defun wl-summary-set-mark (&optional set-mark number interactive data)
  56   (interactive)
  57   "Set temporary mark SET-MARK on the message with NUMBER.
  58 NUMBER is the message number to set the mark on.
  59 INTERACTIVE is set as t if it have to run interactively.
  60 DATA is passed to the set-action function of the action as an argument.
  61 Return number if put mark succeed"
  62   (let* ((set-mark (or set-mark
  63                        (completing-read "Mark: " wl-summary-mark-action-list)))
  64          (current (wl-summary-message-number))
  65          (action (assoc set-mark wl-summary-mark-action-list))
  66          visible mark cur-mark)
  67     (when (zerop (elmo-folder-length wl-summary-buffer-elmo-folder))
  68       (error "Set mark failed"))
  69     (prog1
  70         (save-excursion
  71           ;; Put mark
  72           (if number
  73               ;; Jump to message if cursor is not on the message.
  74               (when (and (setq visible (wl-summary-message-visible-p number))
  75                          (not (eq number current)))
  76                 (wl-summary-jump-to-msg number))
  77             (setq visible t
  78                   number current))
  79           (setq cur-mark (nth 1 (wl-summary-registered-temp-mark number)))
  80           (unless number
  81             (error "No message"))
  82           (if (wl-summary-reserve-temp-mark-p cur-mark)
  83               (when interactive
  84                 (error "Already marked as `%s'" cur-mark))
  85             (when (and interactive
  86                        (null data)
  87                        (wl-summary-action-argument-function action))
  88               (setq data (funcall (wl-summary-action-argument-function action)
  89                                   (wl-summary-action-symbol action)
  90                                   number)))
  91             ;; Unset the current mark.
  92             (wl-summary-unset-mark number)
  93             ;; Set action.
  94             (funcall (wl-summary-action-set-function action)
  95                      number
  96                      (wl-summary-action-mark action)
  97                      data)
  98             (when visible
  99               (wl-summary-put-temp-mark set-mark)
 100               (when wl-summary-highlight
 101                 (wl-highlight-summary-current-line))
 102               (when data
 103                 (wl-summary-print-argument number data)))
 104             (set-buffer-modified-p nil)
 105             ;; Return value.
 106             number))
 107       ;; Move the cursor.
 108       (if (or interactive (interactive-p))
 109           (if (eq wl-summary-move-direction-downward nil)
 110               (wl-summary-prev)
 111             (wl-summary-next))))))
 112
 113 (defun wl-summary-register-target-mark (number mark data)
 114   (or (memq number wl-summary-buffer-target-mark-list)
 115       (setq wl-summary-buffer-target-mark-list
 116             (cons number wl-summary-buffer-target-mark-list))))
 117
 118 (defun wl-summary-unregister-target-mark (number)
 119   (setq wl-summary-buffer-target-mark-list
 120         (delq number wl-summary-buffer-target-mark-list)))
 121
 122 (defun wl-summary-have-target-mark-p (number)
 123   (memq number wl-summary-buffer-target-mark-list))
 124
 125 (defun wl-summary-target-mark-set-action (action)
 126   (unless (eq (wl-summary-action-symbol action) 'target-mark)
 127     (save-excursion
 128       (goto-char (point-min))
 129       (let ((numlist wl-summary-buffer-number-list)
 130             number mlist data)
 131         ;; use firstly marked message.
 132         (when (wl-summary-action-argument-function action)
 133           (while numlist
 134             (if (memq (car numlist) wl-summary-buffer-target-mark-list)
 135                 (setq number (car numlist)
 136                       numlist nil))
 137             (setq numlist (cdr numlist)))
 138           (wl-summary-jump-to-msg number)
 139           (setq data (funcall (wl-summary-action-argument-function action)
 140                               (wl-summary-action-symbol action) number)))
 141         (while (not (eobp))
 142           (when (string= (wl-summary-temp-mark) "*")
 143             (let (wl-summary-buffer-disp-msg)
 144               (when (setq number (wl-summary-message-number))
 145                 (wl-summary-set-mark (wl-summary-action-mark action)
 146                                      nil nil data)
 147                 (setq wl-summary-buffer-target-mark-list
 148                       (delq number wl-summary-buffer-target-mark-list)))))
 149           (forward-line 1))
 150         (setq mlist wl-summary-buffer-target-mark-list)
 151         (while mlist
 152           (wl-summary-register-temp-mark (car mlist)
 153                                          (wl-summary-action-mark action) data)
 154           (setq wl-summary-buffer-target-mark-list
 155                 (delq (car mlist) wl-summary-buffer-target-mark-list))
 156           (setq mlist (cdr mlist)))))))
 157
 158 ;; wl-summary-buffer-temp-mark-list specification
 159 ;; ((1 "D" nil)(2 "o" "+fuga")(3 "O" "+hoge"))
 160 (defun wl-summary-register-temp-mark (number mark mark-info)
 161   (let ((elem (assq number wl-summary-buffer-temp-mark-list)))
 162     (setq wl-summary-buffer-temp-mark-list
 163           (delq elem wl-summary-buffer-temp-mark-list)))
 164   (setq wl-summary-buffer-temp-mark-list
 165         (cons (list number mark mark-info) wl-summary-buffer-temp-mark-list)))
 166
 167 (defun wl-summary-unregister-temp-mark (number)
 168   (let ((elem (assq number wl-summary-buffer-temp-mark-list)))
 169     (setq wl-summary-buffer-temp-mark-list
 170           (delq elem wl-summary-buffer-temp-mark-list))))
 171
 172 (defun wl-summary-registered-temp-mark (number)
 173   (and wl-summary-buffer-temp-mark-list
 174        (assq number wl-summary-buffer-temp-mark-list)))
 175
 176 (defun wl-summary-collect-temp-mark (mark &optional begin end)
 177   (if (or begin end)
 178       (save-excursion
 179         (save-restriction
 180           (let (mark-list)
 181             (narrow-to-region (or begin (point-min))(or end (point-max)))
 182             (goto-char (point-min))
 183             ;; for thread...
 184             (if (eq wl-summary-buffer-view 'thread)
 185                 (let (number entity mark-info)
 186                   (while (not (eobp))
 187                     (setq number (wl-summary-message-number)
 188                           entity (wl-thread-get-entity number)
 189                           mark-info (wl-summary-registered-temp-mark number))
 190                     ;; toplevel message mark.
 191                     (when (string= (nth 1 mark-info) mark)
 192                       (setq mark-list (cons mark-info mark-list)))
 193                     ;; When thread is closed...children should also be checked.
 194                     (unless (wl-thread-entity-get-opened entity)
 195                       (dolist (msg (wl-thread-get-children-msgs number))
 196                         (setq mark-info (wl-summary-registered-temp-mark
 197                                          msg))
 198                         (when (string= (nth 1 mark-info) mark)
 199                           (setq mark-list (cons mark-info mark-list)))))
 200                     (forward-line 1)))
 201               (let (number mark-info)
 202                 (while (not (eobp))
 203                   (setq number (wl-summary-message-number)
 204                         mark-info (wl-summary-registered-temp-mark number))
 205                   (when (string= (nth 1 mark-info) mark)
 206                     (setq mark-list (cons mark-info mark-list)))
 207                   (forward-line 1))))
 208             mark-list)))
 209     (let (mark-list)
 210       (dolist (mark-info wl-summary-buffer-temp-mark-list)
 211         (when (string= (nth 1 mark-info) mark)
 212           (setq mark-list (cons mark-info mark-list))))
 213       mark-list)))
 214
 215 ;; Unset mark
 216 (defun wl-summary-unset-mark (&optional number interactive force)
 217   "Unset temporary mark of the message with NUMBER.
 218 NUMBER is the message number to unset the mark.
 219 If not specified, the message on the cursor position is treated.
 220 Optional INTERACTIVE is non-nil when it should be called interactively.
 221 If optional FORCE is non-nil, remove scored mark too.
 222 Return number if put mark succeed"
 223   (interactive)
 224   (save-excursion
 225     (beginning-of-line)
 226     (let ((buffer-read-only nil)
 227           visible mark action)
 228       (if number
 229           ;; Jump to message
 230           (when (and (setq visible (wl-summary-message-visible-p number))
 231                      (not (eq number (wl-summary-message-number))))
 232             (wl-summary-jump-to-msg number))
 233         (setq visible t
 234               number (wl-summary-message-number)))
 235       (setq mark (wl-summary-temp-mark))
 236       ;; Remove from temporal mark structure.
 237       (wl-summary-unregister-target-mark number)
 238       (wl-summary-unregister-temp-mark number)
 239       ;; Delete mark on buffer.
 240       (when visible
 241         (unless (string= mark " ")
 242           (wl-summary-put-temp-mark
 243            (or (unless force (wl-summary-get-score-mark number))
 244                " "))
 245           (setq action (assoc mark wl-summary-mark-action-list))
 246           (when wl-summary-highlight
 247             (wl-highlight-summary-current-line))
 248           (when (wl-summary-action-argument-function action)
 249             (wl-summary-remove-argument)))
 250         (set-buffer-modified-p nil))))
 251   ;; Move the cursor.
 252   ;;  (if (or interactive (interactive-p))
 253   ;;      (if (eq wl-summary-move-direction-downward nil)
 254   ;;      (wl-summary-prev)
 255   ;;    (wl-summary-next))))
 256   )
 257
 258 (defun wl-summary-make-destination-numbers-list (mark-list)
 259   (let (dest-numbers dest-number)
 260     (dolist (elem mark-list)
 261       (setq dest-number (assoc (nth 2 elem) dest-numbers))
 262       (if dest-number
 263           (unless (memq (car elem) (cdr dest-number))
 264             (nconc dest-number (list (car elem))))
 265         (setq dest-numbers (nconc dest-numbers
 266                                   (list
 267                                    (list (nth 2 elem)
 268                                          (car elem)))))))
 269     dest-numbers))
 270
 271 (defun wl-summary-move-mark-list-messages (mark-list folder-name message)
 272   (if (null mark-list)
 273       (message "No marks")
 274     (save-excursion
 275       (let ((start (point))
 276             (refiles (mapcar 'car mark-list))
 277             (refile-failures 0)
 278             refile-len
 279             dst-msgs                    ; loop counter
 280             result)
 281         ;; begin refile...
 282         (setq refile-len (length refiles))
 283         (goto-char start)               ; avoid moving cursor to
 284                                         ; the bottom line.
 285         (message message)
 286         (when (> refile-len elmo-display-progress-threshold)
 287           (elmo-progress-set 'elmo-folder-move-messages
 288                              refile-len message))
 289         (setq result nil)
 290         (condition-case nil
 291             (setq result (elmo-folder-move-messages
 292                           wl-summary-buffer-elmo-folder
 293                           refiles
 294                           (if (eq folder-name 'null)
 295                               'null
 296                             (wl-folder-get-elmo-folder folder-name))))
 297           (error nil))
 298         (when result            ; succeeded.
 299           ;; update buffer.
 300           (wl-summary-delete-messages-on-buffer refiles)
 301           ;; update wl-summary-buffer-temp-mark-list.
 302           (dolist (mark-info mark-list)
 303             (setq wl-summary-buffer-temp-mark-list
 304                   (delq mark-info wl-summary-buffer-temp-mark-list))))
 305         (elmo-progress-clear 'elmo-folder-move-messages)
 306         (message (concat message "done"))
 307         (wl-summary-set-message-modified)
 308         ;; Return the operation failed message numbers.
 309         (if result
 310             0
 311           (length refiles))))))
 312
 313 (defun wl-summary-get-refile-destination-subr (action number learn)
 314   (let* ((number (or number (wl-summary-message-number)))
 315          (msgid (and number
 316                      (elmo-message-field wl-summary-buffer-elmo-folder
 317                                          number 'message-id)))
 318          (entity (and number
 319                       (elmo-message-entity wl-summary-buffer-elmo-folder
 320                                            number)))
 321          folder cur-mark tmp-folder)
 322     (catch 'done
 323       (when (null entity)
 324         (message "Cannot decide destination.")
 325         (throw 'done nil))
 326       (when (null number)
 327         (message "No message.")
 328         (throw 'done nil))
 329       (setq folder (wl-summary-read-folder
 330                     (or (wl-refile-guess entity) wl-trash-folder)
 331                     (format "for %s " action)))
 332       ;; Cache folder hack by okada@opaopa.org
 333       (when (and (eq (elmo-folder-type-internal
 334                       (wl-folder-get-elmo-folder
 335                        (wl-folder-get-realname folder))) 'cache)
 336                  (not (string= folder
 337                                (setq tmp-folder
 338                                      (concat "'cache/"
 339                                              (elmo-cache-get-path-subr
 340                                               (elmo-msgid-to-cache msgid)))))))
 341         (setq folder tmp-folder)
 342         (message "Force refile to %s." folder))
 343       (if (string= folder (wl-summary-buffer-folder-name))
 344           (error "Same folder"))
 345       (if (or (not (elmo-folder-writable-p (wl-folder-get-elmo-folder folder)))
 346               (string= folder wl-queue-folder)
 347               (string= folder wl-draft-folder))
 348           (error "Don't set as target: %s" folder))
 349       ;; learn for refile.
 350       (when learn
 351         (wl-refile-learn entity folder))
 352       folder)))
 353
 354 ;;; Actions
 355 (defun wl-summary-define-mark-action ()
 356   (interactive)
 357   (dolist (action wl-summary-mark-action-list)
 358     (fset (intern (format "wl-summary-%s" (wl-summary-action-symbol action)))
 359           `(lambda (&optional number data)
 360              ,(wl-summary-action-docstring action)
 361              (interactive)
 362              (wl-summary-set-mark ,(wl-summary-action-mark action)
 363                                   number (interactive-p) data)))
 364     (fset (intern (format "wl-summary-%s-region"
 365                           (wl-summary-action-symbol action)))
 366           `(lambda (beg end)
 367              ,(wl-summary-action-docstring action)
 368              (interactive "r")
 369              (save-excursion
 370                (goto-char beg)
 371                (wl-summary-mark-region-subr
 372                 (quote ,(intern (format "wl-summary-%s"
 373                                         (wl-summary-action-symbol action))))
 374                 beg end
 375                 (if (quote ,(wl-summary-action-argument-function action))
 376                     (funcall (function
 377                               ,(wl-summary-action-argument-function action))
 378                              (quote ,(wl-summary-action-symbol action))
 379                              (wl-summary-message-number)))))))
 380     (fset (intern (format "wl-summary-target-mark-%s"
 381                           (wl-summary-action-symbol action)))
 382           `(lambda ()
 383              ,(wl-summary-action-docstring action)
 384              (interactive)
 385              (wl-summary-target-mark-set-action (quote ,action))))
 386     (fset (intern (format "wl-thread-%s"
 387                           (wl-summary-action-symbol action)))
 388           `(lambda (arg)
 389              ,(wl-summary-action-docstring action)
 390              (interactive "P")
 391              (wl-thread-call-region-func
 392               (quote ,(intern (format "wl-summary-%s-region"
 393                                       (wl-summary-action-symbol action))))
 394               arg)
 395              (if arg
 396                  (wl-summary-goto-top-of-current-thread))
 397              (if (not wl-summary-move-direction-downward)
 398                  (wl-summary-prev)
 399                (wl-thread-goto-bottom-of-sub-thread)
 400                (if wl-summary-buffer-disp-msg
 401                    (wl-summary-redisplay)))))))
 402
 403 (defun wl-summary-get-dispose-folder (folder)
 404   (if (string= folder wl-trash-folder)
 405       'null
 406     (let* ((type (or (wl-get-assoc-list-value wl-dispose-folder-alist folder)
 407                      'trash)))
 408       (cond ((stringp type)
 409              type)
 410             ((or (equal type 'remove) (equal type 'null))
 411              'null)
 412             (t;; (equal type 'trash)
 413              (let ((trash-folder (wl-folder-get-elmo-folder wl-trash-folder)))
 414                (unless (elmo-folder-exists-p trash-folder)
 415                  (if (y-or-n-p
 416                       (format "Trash Folder %s does not exist, create it? "
 417                               wl-trash-folder))
 418                      (elmo-folder-create trash-folder)
 419                    (error "Trash Folder is not created"))))
 420              wl-trash-folder)))))
 421
 422 ;; Dispose action.
 423 (defun wl-summary-exec-action-dispose (mark-list)
 424   (wl-summary-move-mark-list-messages mark-list
 425                                       (wl-summary-get-dispose-folder
 426                                        (wl-summary-buffer-folder-name))
 427                                       "Disposing messages..."))
 428
 429 ;; Delete action.
 430 (defun wl-summary-exec-action-delete (mark-list)
 431   (wl-summary-move-mark-list-messages mark-list
 432                                       'null
 433                                       "Deleting messages..."))
 434
 435 ;; Refile action
 436 (defun wl-summary-set-action-refile (number mark data)
 437   (when (null data)
 438     (error "Destination folder is empty"))
 439   (wl-summary-register-temp-mark number mark data)
 440   (setq wl-summary-buffer-prev-refile-destination data))
 441
 442 (defun wl-summary-get-refile-destination (action number)
 443   "Decide refile destination."
 444   (wl-summary-get-refile-destination-subr action number t))
 445
 446 (defun wl-summary-exec-action-refile (mark-list)
 447   (save-excursion
 448     (let ((start (point))
 449           (failures 0)
 450           (refile-len (length mark-list))
 451           dst-msgs ; loop counter
 452           result)
 453       ;; begin refile...
 454       (setq dst-msgs
 455             (wl-summary-make-destination-numbers-list mark-list))
 456       (goto-char start) ; avoid moving cursor to the bottom line.
 457       (when (> refile-len elmo-display-progress-threshold)
 458         (elmo-progress-set 'elmo-folder-move-messages
 459                            refile-len "Refiling messages..."))
 460       (while dst-msgs
 461         (setq result nil)
 462         (condition-case nil
 463             (setq result (elmo-folder-move-messages
 464                           wl-summary-buffer-elmo-folder
 465                           (cdr (car dst-msgs))
 466                           (wl-folder-get-elmo-folder (car (car dst-msgs)))))
 467           (error nil))
 468         (if result              ; succeeded.
 469             (progn
 470               ;; update buffer.
 471               (wl-summary-delete-messages-on-buffer (cdr (car dst-msgs)))
 472               (setq wl-summary-buffer-temp-mark-list
 473                     (wl-delete-associations
 474                      (cdr (car dst-msgs))
 475                      wl-summary-buffer-temp-mark-list)))
 476           (setq failures
 477                 (+ failures (length (cdr (car dst-msgs))))))
 478         (setq dst-msgs (cdr dst-msgs)))
 479       (elmo-progress-clear 'elmo-folder-move-messages)
 480       failures)))
 481
 482 ;; Copy action
 483 (defun wl-summary-get-copy-destination (action number)
 484   (wl-summary-get-refile-destination-subr action number nil))
 485
 486 (defun wl-summary-exec-action-copy (mark-list)
 487   (save-excursion
 488     (let ((start (point))
 489           (failures 0)
 490           (refile-len (length mark-list))
 491           dst-msgs ; loop counter
 492           result)
 493       ;; begin refile...
 494       (setq dst-msgs
 495             (wl-summary-make-destination-numbers-list mark-list))
 496       (goto-char start) ; avoid moving cursor to the bottom line.
 497       (when (> refile-len elmo-display-progress-threshold)
 498         (elmo-progress-set 'elmo-folder-move-messages
 499                            refile-len "Copying messages..."))
 500       (while dst-msgs
 501         (setq result nil)
 502         (condition-case nil
 503             (setq result (elmo-folder-move-messages
 504                           wl-summary-buffer-elmo-folder
 505                           (cdr (car dst-msgs))
 506                           (wl-folder-get-elmo-folder (car (car dst-msgs)))
 507                           'no-delete))
 508           (error nil))
 509         (if result              ; succeeded.
 510             (progn
 511               ;; update buffer.
 512               (wl-summary-delete-copy-marks-on-buffer (cdr (car dst-msgs)))
 513               (setq wl-summary-buffer-temp-mark-list
 514                     (wl-delete-associations
 515                      (cdr (car dst-msgs))
 516                      wl-summary-buffer-temp-mark-list)))
 517           (setq failures
 518                 (+ failures (length (cdr (car dst-msgs))))))
 519         (setq dst-msgs (cdr dst-msgs)))
 520       (elmo-progress-clear 'elmo-folder-move-messages)
 521       failures)))
 522
 523 ;; Prefetch.
 524 (defun wl-summary-exec-action-prefetch (mark-list)
 525   (save-excursion
 526     (let* ((count 0)
 527            (length (length mark-list))
 528            (mark-list-copy (copy-sequence mark-list))
 529            (pos (point))
 530            (failures 0))
 531       (dolist (mark-info mark-list-copy)
 532         (message "Prefetching...(%d/%d)"
 533                  (setq count (+ 1 count)) length)
 534         (if (wl-summary-prefetch-msg (car mark-info))
 535             (progn
 536               (wl-summary-unset-mark (car mark-info))
 537               (sit-for 0))
 538           (incf failures)))
 539       (message "Prefetching...done")
 540       0)))
 541
 542 ;; Resend.
 543 (defun wl-summary-get-resend-address (action number)
 544   "Decide resend address."
 545   (completing-read "Resend message to: " 'wl-complete-address))
 546
 547 (defun wl-summary-exec-action-resend (mark-list)
 548   (let ((failure 0))
 549     (dolist (mark-info mark-list)
 550       (if (condition-case nil
 551               (progn
 552                 (wl-summary-exec-action-resend-subr (car mark-info)
 553                                                     (nth 2 mark-info))
 554                 t)
 555             (error))
 556           (wl-summary-unmark (car mark-info))
 557         (incf failure)))
 558     failure))
 559
 560 (defun wl-summary-exec-action-resend-subr (number address)
 561   "Resend the message with NUMBER to ADDRESS."
 562   (message "Resending message to %s..." address)
 563   (let ((folder wl-summary-buffer-elmo-folder))
 564     (save-excursion
 565       ;; We first set up a normal mail buffer.
 566       (set-buffer (get-buffer-create " *wl-draft-resend*"))
 567       (buffer-disable-undo (current-buffer))
 568       (erase-buffer)
 569       (setq wl-sent-message-via nil)
 570       ;; Insert our usual headers.
 571       (wl-draft-insert-from-field)
 572       (wl-draft-insert-date-field)
 573       (insert "To: " address "\n")
 574       (goto-char (point-min))
 575       ;; Rename them all to "Resent-*".
 576       (while (re-search-forward "^[A-Za-z]" nil t)
 577         (forward-char -1)
 578         (insert "Resent-"))
 579       (widen)
 580       (forward-line)
 581       (delete-region (point) (point-max))
 582       (let ((beg (point)))
 583         ;; Insert the message to be resent.
 584         (insert
 585          (with-temp-buffer
 586            (elmo-message-fetch folder number
 587                                (elmo-make-fetch-strategy 'entire)
 588                                nil (current-buffer) 'unread)
 589            (buffer-string)))
 590         (goto-char (point-min))
 591         (search-forward "\n\n")
 592         (forward-char -1)
 593         (save-restriction
 594           (narrow-to-region beg (point))
 595           (wl-draft-delete-fields wl-ignored-resent-headers)
 596           (goto-char (point-max)))
 597         (insert mail-header-separator)
 598         ;; Rename all old ("Previous-")Resent headers.
 599         (while (re-search-backward "^\\(Previous-\\)*Resent-" beg t)
 600           (beginning-of-line)
 601           (insert "Previous-"))
 602         ;; Quote any "From " lines at the beginning.
 603         (goto-char beg)
 604         (when (looking-at "From ")
 605           (replace-match "X-From-Line: ")))
 606       ;; Send it.
 607       (wl-draft-dispatch-message)
 608       (kill-buffer (current-buffer)))
 609     (message "Resending message to %s...done" address)))
 610
 611 ;;;
 612 (defun wl-summary-remove-argument ()
 613   (save-excursion
 614     (let ((inhibit-read-only t)
 615           (buffer-read-only nil)
 616           (buf (current-buffer))
 617           sol eol rs re)
 618       (beginning-of-line)
 619       (setq sol (point))
 620       (search-forward "\r")
 621       (forward-char -1)
 622       (setq eol (point))
 623       (setq rs (next-single-property-change sol 'wl-summary-action-argument
 624                                             buf eol))
 625       (setq re (next-single-property-change rs 'wl-summary-action-argument
 626                                             buf eol))
 627       (put-text-property rs re 'wl-summary-action-argument nil)
 628       (put-text-property rs re 'invisible nil)
 629       (goto-char re)
 630       (delete-char (- eol re)))))
 631
 632 (defun wl-summary-collect-numbers-region (begin end)
 633   "Return a list of message number in the region specified by BEGIN and END."
 634   (save-excursion
 635     (save-restriction
 636       (let (numbers)
 637         (wl-summary-narrow-to-region (or begin (point-min))(or end (point-max)))
 638         (goto-char (point-min))
 639         ;; for thread...
 640         (if (eq wl-summary-buffer-view 'thread)
 641             (let (number entity)
 642               (while (not (eobp))
 643                 (setq numbers (cons (wl-summary-message-number) numbers)
 644                       entity (wl-thread-get-entity number))
 645                 ;; When thread is closed...children should also be checked.
 646                 (unless (wl-thread-entity-get-opened entity)
 647                   (dolist (msg (wl-thread-get-children-msgs number))
 648                     (setq numbers (cons msg numbers))))
 649                 (forward-line 1)))
 650           (let (number)
 651             (while (not (eobp))
 652               (setq numbers (cons (wl-summary-message-number) numbers))
 653               (forward-line 1))))
 654         (nreverse (delq nil numbers))))))
 655
 656 (defun wl-summary-exec (&optional numbers)
 657   (interactive)
 658   (let ((failures 0)
 659         collected pair action modified)
 660     (dolist (action wl-summary-mark-action-list)
 661       (setq collected (cons (cons
 662                              (wl-summary-action-mark action)
 663                              nil) collected)))
 664     (dolist (mark-info wl-summary-buffer-temp-mark-list)
 665       (if numbers
 666           (when (memq (nth 0 mark-info) numbers)
 667             (setq pair (assoc (nth 1 mark-info) collected)))
 668         (setq pair (assoc (nth 1 mark-info) collected)))
 669       (setq pair (assoc (nth 1 mark-info) collected))
 670       (setcdr pair (cons mark-info (cdr pair))))
 671     ;; collected is a pair of
 672     ;; mark-string and a list of mark-info
 673     (dolist (pair collected)
 674       (setq action (assoc (car pair) wl-summary-mark-action-list))
 675       (when (and (cdr pair) (wl-summary-action-exec-function action))
 676         (setq modified t)
 677         (setq failures (+ failures (funcall
 678                                     (wl-summary-action-exec-function action)
 679                                     (cdr pair))))))
 680     (when modified
 681       (wl-summary-set-message-modified))
 682     (run-hooks 'wl-summary-exec-hook)
 683     ;; message buffer is not up-to-date
 684     (unless (and wl-message-buffer
 685                  (eq (wl-summary-message-number)
 686                      (with-current-buffer wl-message-buffer
 687                        wl-message-buffer-cur-number)))
 688       (wl-summary-toggle-disp-msg 'off)
 689       (setq wl-message-buffer nil))
 690     (set-buffer-modified-p nil)
 691     (when (> failures 0)
 692       (format "%d execution(s) were failed" failures))))
 693
 694 (defun wl-summary-exec-region (beg end)
 695   (interactive "r")
 696   (wl-summary-exec
 697    (wl-summary-collect-numbers-region beg end)))
 698
 699 (defun wl-summary-read-folder (default &optional purpose ignore-error
 700                                 no-create init)
 701   (let ((fld (completing-read
 702               (format "Folder name %s(%s): " (or purpose "")
 703                       default)
 704               'wl-folder-complete-folder
 705               nil nil (or init wl-default-spec)
 706               'wl-read-folder-history)))
 707     (if (or (string= fld wl-default-spec)
 708             (string= fld ""))
 709         (setq fld default))
 710     (setq fld (elmo-string (wl-folder-get-realname fld)))
 711     (if (string-match "\n" fld)
 712         (error "Not supported folder name: %s" fld))
 713     (unless no-create
 714       (if ignore-error
 715           (condition-case nil
 716               (wl-folder-confirm-existence
 717                (wl-folder-get-elmo-folder
 718                 fld))
 719             (error))
 720         (wl-folder-confirm-existence (wl-folder-get-elmo-folder
 721                                       fld))))
 722     fld))
 723
 724 (defun wl-summary-print-argument (msg-num folder)
 725   "Print action argument on line."
 726   (when folder
 727     (wl-summary-remove-argument)
 728     (save-excursion
 729       (let ((inhibit-read-only t)
 730             (folder (copy-sequence folder))
 731             (buffer-read-only nil)
 732             len rs re c)
 733         (setq len (string-width folder))
 734         (if (< len 1) ()
 735           ;;(end-of-line)
 736           (beginning-of-line)
 737           (search-forward "\r")
 738           (forward-char -1)
 739           (setq re (point))
 740           (let ((width (cond (wl-summary-width
 741                               (1- wl-summary-width))
 742                              (wl-summary-print-argument-within-window
 743                               (1- (window-width)))))
 744                 (c (current-column))
 745                 (padding 0))
 746             (if (and width (> (+ c len) width))
 747                 (progn
 748                   (move-to-column width)
 749                   (setq c (current-column))
 750                   (while (> (+ c len) width)
 751                     (forward-char -1)
 752                     (setq c (current-column)))
 753                   (when (< (+ c len) width)
 754                     (setq folder (concat " " folder)))
 755                   (setq rs (point))
 756                   (put-text-property rs re 'invisible t))
 757               (when (and width
 758                          (> (setq padding (- width len c)) 0))
 759                 (setq folder (concat (make-string padding ?\ )
 760                                      folder)))
 761               (setq rs (1- re))))
 762           (put-text-property rs re 'wl-summary-action-argument t)
 763           (goto-char re)
 764           (wl-highlight-action-argument-string folder)
 765           (insert folder)
 766           (set-buffer-modified-p nil))))))
 767
 768 (defsubst wl-summary-reserve-temp-mark-p (mark)
 769   "Return t if temporal MARK should be reserved."
 770   (member mark wl-summary-reserve-mark-list))
 771
 772 ;; Refile prev destination
 773 (defun wl-summary-refile-prev-destination ()
 774   "Refile message to previously refiled destination."
 775   (interactive)
 776   (funcall (symbol-function 'wl-summary-refile)
 777            (wl-summary-message-number)
 778            wl-summary-buffer-prev-refile-destination)
 779   (if (and (interactive-p)
 780            (eq wl-summary-move-direction-downward nil))
 781       (wl-summary-prev)
 782     (wl-summary-next)))
 783
 784 (defun wl-summary-refile-prev-destination-region (beg end)
 785   "Refile messages in the region to previously refiled destination."
 786   (interactive "r")
 787   (wl-summary-mark-region-subr 'wl-summary-refile
 788                                beg end
 789                                wl-summary-buffer-prev-refile-destination))
 790
 791 (defun wl-thread-refile-prev-destination (arg)
 792   "Refile messages in the thread to previously refiled destination."
 793   (interactive "P")
 794   (wl-thread-call-region-func
 795    'wl-summary-refile-prev-destination-region
 796    arg))
 797
 798 (defun wl-summary-target-mark-refile-prev-destination ()
 799   "Refile messages with target mark to previously refiled destination."
 800   (interactive)
 801   (let ((elem wl-summary-mark-action-list)
 802         action)
 803     (while elem
 804       (when (eq (wl-summary-action-symbol (car elem)) 'refile)
 805         (setq action (car elem))
 806         (setq elem nil))
 807       (setq elem (cdr elem)))
 808     (wl-summary-target-mark-set-action
 809      (list
 810       (car action)
 811       'refile-prev-destination
 812       (lambda (&rest args) wl-summary-buffer-prev-refile-destination)
 813       (nth 2 action)
 814       (nth 3 action)
 815       (nth 4 action)
 816       (nth 6 action)))))
 817
 818 (defsubst wl-summary-no-auto-refile-message-p (number)
 819   (member (wl-summary-message-mark wl-summary-buffer-elmo-folder number)
 820           wl-summary-auto-refile-skip-marks))
 821
 822 (defvar wl-auto-refile-guess-functions
 823   '(wl-refile-guess-by-rule)
 824   "*List of functions which is used for guessing refile destination folder.")
 825
 826 (defun wl-summary-auto-refile (&optional open-all)
 827   "Set refile mark automatically according to 'wl-refile-guess-by-rule'."
 828   (interactive "P")
 829   (message "Marking...")
 830   (save-excursion
 831     (if (and (eq wl-summary-buffer-view 'thread)
 832              open-all)
 833         (wl-thread-open-all))
 834     (let* ((spec (wl-summary-buffer-folder-name))
 835            checked-dsts
 836            (count 0)
 837            number dst thr-entity)
 838       (goto-line 1)
 839       (while (not (eobp))
 840         (setq number (wl-summary-message-number))
 841         (dolist (number (cons number
 842                               (and (eq wl-summary-buffer-view 'thread)
 843                                    ;; process invisible children.
 844                                    (not (wl-thread-entity-get-opened
 845                                          (setq thr-entity
 846                                                (wl-thread-get-entity number))))
 847                                    (wl-thread-entity-get-descendant
 848                                     thr-entity))))
 849           (when (and (not (wl-summary-no-auto-refile-message-p
 850                            number))
 851                      (setq dst
 852                            (wl-folder-get-realname
 853                             (wl-refile-guess
 854                              (elmo-message-entity wl-summary-buffer-elmo-folder
 855                                                   number)
 856                              wl-auto-refile-guess-functions)))
 857                      (not (equal dst spec))
 858                      (let ((pair (assoc dst checked-dsts))
 859                            ret)
 860                        (if pair
 861                            (cdr pair)
 862                          (setq ret
 863                                (condition-case nil
 864                                    (progn
 865                                      (wl-folder-confirm-existence
 866                                       (wl-folder-get-elmo-folder dst))
 867                                      t)
 868                                  (error)))
 869                          (setq checked-dsts (cons (cons dst ret) checked-dsts))
 870                          ret)))
 871             (if (funcall (symbol-function 'wl-summary-refile) number dst)
 872                 (incf count))
 873             (message "Marking...%d message(s)." count)))
 874         (forward-line))
 875       (if (eq count 0)
 876           (message "No message was marked.")
 877         (message "Marked %d message(s)." count)))))
 878
 879 (defun wl-summary-unmark (&optional number)
 880   "Unmark marks (temporary, refile, copy, delete)of current line.
 881 If optional argument NUMBER is specified, unmark message specified by NUMBER."
 882   (interactive)
 883   (wl-summary-unset-mark number (interactive-p)))
 884
 885 (defun wl-summary-unmark-region (beg end)
 886   (interactive "r")
 887   (save-excursion
 888     (save-restriction
 889       (wl-summary-narrow-to-region beg end)
 890       (goto-char (point-min))
 891       (if (eq wl-summary-buffer-view 'thread)
 892           (progn
 893             (while (not (eobp))
 894               (let* ((number (wl-summary-message-number))
 895                      (entity (wl-thread-get-entity number)))
 896                 (if (wl-thread-entity-get-opened entity)
 897                     ;; opened...unmark line.
 898                     (wl-summary-unmark)
 899                   ;; closed
 900                   (wl-summary-delete-marks-on-buffer
 901                    (wl-thread-get-children-msgs number))))
 902               (forward-line 1)))
 903         (while (not (eobp))
 904           (wl-summary-unmark)
 905           (forward-line 1))))))
 906
 907 (defun wl-summary-mark-region-subr (function beg end data)
 908   (save-excursion
 909     (save-restriction
 910       (wl-summary-narrow-to-region beg end)
 911       (goto-char (point-min))
 912       (if (eq wl-summary-buffer-view 'thread)
 913           (progn
 914             (while (not (eobp))
 915               (let* ((number (wl-summary-message-number))
 916                      (entity (wl-thread-get-entity number))
 917                      (wl-summary-move-direction-downward t)
 918                      children)
 919                 (if (wl-thread-entity-get-opened entity)
 920                     ;; opened...delete line.
 921                     (funcall function nil data)
 922                   ;; closed
 923                   (setq children (wl-thread-get-children-msgs number))
 924                   (while children
 925                     (funcall function (pop children) data)))
 926                 (forward-line 1))))
 927         (while (not (eobp))
 928           (funcall function nil data)
 929           (forward-line 1))))))
 930
 931 (defun wl-summary-target-mark-all ()
 932   (interactive)
 933   (wl-summary-target-mark-region (point-min) (point-max))
 934   (setq wl-summary-buffer-target-mark-list
 935         (elmo-folder-list-messages wl-summary-buffer-elmo-folder
 936                                    t 'in-msgdb)))
 937
 938 (defun wl-summary-delete-all-mark (mark)
 939   (goto-char (point-min))
 940   (while (not (eobp))
 941     (when (string= (wl-summary-temp-mark) mark)
 942       (wl-summary-unmark))
 943     (forward-line 1))
 944   (if (string= mark "*")
 945       (setq wl-summary-buffer-target-mark-list nil)
 946     (let (deleted)
 947       (dolist (mark-info wl-summary-buffer-temp-mark-list)
 948         (when (string= (nth 1 mark-info) mark)
 949           (setq deleted (cons mark-info deleted))))
 950       (dolist (delete deleted)
 951         (setq wl-summary-buffer-temp-mark-list
 952               (delq delete wl-summary-buffer-temp-mark-list))))))
 953
 954 (defun wl-summary-unmark-all ()
 955   "Unmark all according to what you input."
 956   (interactive)
 957   (let ((unmarks (string-to-char-list (read-from-minibuffer "Unmark: ")))
 958         cur-mark)
 959     (save-excursion
 960       (while unmarks
 961         (setq cur-mark (char-to-string (car unmarks)))
 962         (wl-summary-delete-all-mark cur-mark)
 963         (setq unmarks (cdr unmarks))))))
 964
 965 (defun wl-summary-target-mark-thread ()
 966   (interactive)
 967   (wl-thread-call-region-func 'wl-summary-target-mark-region t))
 968
 969 (require 'product)
 970 (product-provide (provide 'wl-action) (require 'wl-version))
 971
 972 ;;; wl-action.el ends here