wl/wl-draft.el

   1 ;;; wl-draft.el -- Message draft mode for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1998,1999,2000 Masahiro MURATA <muse@ba2.so-net.ne.jp>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;;      Masahiro MURATA <muse@ba2.so-net.ne.jp>
   8 ;; Keywords: mail, net news
   9
  10 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  11
  12 ;; This program is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16 ;;
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21 ;;
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 ;;
  27
  28 ;;; Commentary:
  29 ;;
  30
  31 ;;; Code:
  32 ;;
  33
  34 (require 'sendmail)
  35 (require 'wl-template)
  36 (require 'emu)
  37 (condition-case nil (require 'timezone) (error nil))
  38 (require 'std11)
  39 (require 'wl-vars)
  40
  41 (defvar x-face-add-x-face-version-header)
  42 (defvar mail-reply-buffer)
  43 (defvar mail-from-style)
  44
  45 (eval-when-compile
  46   (require 'elmo-pop3)
  47   (defalias-maybe 'x-face-insert 'ignore)
  48   (defalias-maybe 'x-face-insert-version-header 'ignore)
  49   (defalias-maybe 'wl-init 'ignore)
  50   (defalias-maybe 'wl-draft-mode 'ignore))
  51
  52 (eval-and-compile
  53   (autoload 'wl-addrmgr "wl-addrmgr"))
  54
  55 (defvar wl-draft-buf-name "Draft")
  56 (defvar wl-draft-cite-function 'wl-default-draft-cite)
  57 (defvar wl-draft-buffer-file-name nil)
  58 (defvar wl-draft-field-completion-list nil)
  59 (defvar wl-draft-verbose-send t)
  60 (defvar wl-draft-verbose-msg nil)
  61 (defvar wl-draft-queue-flushing nil)
  62 (defvar wl-draft-config-variables nil)
  63 (defvar wl-draft-config-exec-flag t)
  64 (defvar wl-draft-buffer-cur-summary-buffer nil)
  65 (defvar wl-draft-clone-local-variable-regexp "^\\(wl\\|mime\\)")
  66 (defvar wl-draft-sendlog-filename "sendlog")
  67 (defvar wl-draft-queue-save-filename "qinfo")
  68 (defvar wl-draft-config-save-filename "config")
  69 (defvar wl-draft-queue-flush-send-function 'wl-draft-dispatch-message)
  70 (defvar wl-sent-message-via nil)
  71 (defvar wl-sent-message-modified nil)
  72 (defvar wl-draft-fcc-list nil)
  73 (defvar wl-draft-reedit nil)
  74 (defvar wl-draft-reply-buffer nil)
  75 (defvar wl-draft-forward nil)
  76
  77 (defvar wl-draft-config-sub-func-alist
  78   '((body        . wl-draft-config-sub-body)
  79     (top         . wl-draft-config-sub-top)
  80     (bottom      . wl-draft-config-sub-bottom)
  81     (header      . wl-draft-config-sub-header)
  82     (body-file   . wl-draft-config-sub-body-file)
  83     (top-file    . wl-draft-config-sub-top-file)
  84     (bottom-file . wl-draft-config-sub-bottom-file)
  85     (header-file . wl-draft-config-sub-header-file)
  86     (template    . wl-draft-config-sub-template)
  87     (x-face      . wl-draft-config-sub-x-face)))
  88
  89 (make-variable-buffer-local 'wl-draft-buffer-file-name)
  90 (make-variable-buffer-local 'wl-draft-buffer-cur-summary-buffer)
  91 (make-variable-buffer-local 'wl-draft-config-variables)
  92 (make-variable-buffer-local 'wl-draft-config-exec-flag)
  93 (make-variable-buffer-local 'wl-sent-message-via)
  94 (make-variable-buffer-local 'wl-draft-fcc-list)
  95 (make-variable-buffer-local 'wl-draft-reply-buffer)
  96
  97 (defmacro wl-smtp-extension-bind (&rest body)
  98   (` (let* ((smtp-sasl-mechanisms
  99              (if wl-smtp-authenticate-type
 100                  (mapcar 'upcase
 101                          (if (listp wl-smtp-authenticate-type)
 102                              wl-smtp-authenticate-type
 103                            (list wl-smtp-authenticate-type)))))
 104             (smtp-use-sasl (and smtp-sasl-mechanisms t))
 105             (smtp-use-starttls wl-smtp-connection-type)
 106             smtp-sasl-user-name smtp-sasl-properties sasl-read-passphrase)
 107        (if (and (string= (car smtp-sasl-mechanisms) "DIGEST-MD5")
 108                 ;; sendmail bug?
 109                 (string-match "^\\([^@]*\\)@\\([^@]*\\)"
 110                               wl-smtp-posting-user))
 111            (setq smtp-sasl-user-name (match-string 1 wl-smtp-posting-user)
 112                  smtp-sasl-properties (list 'realm
 113                                             (match-string 2 wl-smtp-posting-user)))
 114          (setq smtp-sasl-user-name wl-smtp-posting-user
 115                smtp-sasl-properties nil))
 116        (setq sasl-read-passphrase
 117              (function
 118               (lambda (prompt)
 119                 (elmo-get-passwd
 120                  (format "%s@%s"
 121                          smtp-sasl-user-name
 122                          smtp-server)))))
 123        (,@ body))))
 124
 125 (defun wl-draft-insert-date-field ()
 126   "Insert Date field."
 127   (insert "Date: " (wl-make-date-string) "\n"))
 128
 129 (defun wl-draft-insert-from-field ()
 130   "Insert From field."
 131   ;; Put the "From:" field in unless for some odd reason
 132   ;; they put one in themselves.
 133   (let* ((login (or user-mail-address (user-login-name)))
 134          (fullname (user-full-name)))
 135     (cond ((eq mail-from-style 'angles)
 136            (insert "From: " fullname)
 137            (let ((fullname-start (+ (point-min) (length "From: ")))
 138                  (fullname-end (point-marker)))
 139              (goto-char fullname-start)
 140              ;; Look for a character that cannot appear unquoted
 141              ;; according to RFC 822.
 142              (if (re-search-forward "[^- !#-'*+/-9=?A-Z^-~]"
 143                                     fullname-end 1)
 144                  (progn
 145                    ;; Quote fullname, escaping specials.
 146                    (goto-char fullname-start)
 147                    (insert "\"")
 148                    (while (re-search-forward "[\"\\]"
 149                                              fullname-end 1)
 150                      (replace-match "\\\\\\&" t))
 151                    (insert "\""))))
 152            (insert " <" login ">\n"))
 153           ((eq mail-from-style 'parens)
 154            (insert "From: " login " (")
 155            (let ((fullname-start (point)))
 156              (insert fullname)
 157              (let ((fullname-end (point-marker)))
 158                (goto-char fullname-start)
 159                ;; RFC 822 says \ and nonmatching parentheses
 160                ;; must be escaped in comments.
 161                ;; Escape every instance of ()\ ...
 162                (while (re-search-forward "[()\\]" fullname-end 1)
 163                  (replace-match "\\\\\\&" t))
 164                ;; ... then undo escaping of matching parentheses,
 165                ;; including matching nested parentheses.
 166                (goto-char fullname-start)
 167                (while (re-search-forward
 168                        "\\(\\=\\|[^\\]\\(\\\\\\\\\\)*\\)\\\\(\\(\\([^\\]\\|\\\\\\\\\\)*\\)\\\\)"
 169                        fullname-end 1)
 170                  (replace-match "\\1(\\3)" t)
 171                  (goto-char fullname-start))))
 172            (insert ")\n"))
 173           ((not mail-from-style)
 174            (insert "From: " login "\n")))))
 175
 176 (defun wl-draft-insert-x-face-field ()
 177   "Insert X-Face header."
 178   (interactive)
 179   (if (not (file-exists-p wl-x-face-file))
 180       (error "File %s does not exist" wl-x-face-file)
 181     (beginning-of-buffer)
 182     (search-forward mail-header-separator nil t)
 183     (beginning-of-line)
 184     (wl-draft-insert-x-face-field-here)
 185     (run-hooks 'wl-draft-insert-x-face-field-hook))) ; highlight it if you want.
 186
 187 (defun wl-draft-insert-x-face-field-here ()
 188   "Insert X-Face field at point."
 189   (let ((x-face-string (elmo-get-file-string wl-x-face-file)))
 190     (when (string-match "^[ \t]*" x-face-string)
 191       (setq x-face-string (substring x-face-string (match-end 0))))
 192     (insert "X-Face: " x-face-string))
 193   (when (not (= (preceding-char) ?\n))  ; for chomped (choped) x-face-string
 194     (insert ?\n))
 195   ;; Insert X-Face-Version: field
 196   (when (and (fboundp 'x-face-insert-version-header)
 197              (boundp 'x-face-add-x-face-version-header)
 198              x-face-add-x-face-version-header)
 199     (x-face-insert-version-header)))
 200
 201 (defun wl-draft-setup ()
 202   (let ((field wl-draft-fields)
 203         ret-val)
 204     (while field
 205       (setq ret-val (append ret-val
 206                             (list (cons (concat (car field) " ")
 207                                         (concat (car field) " ")))))
 208       (setq field (cdr field)))
 209     (setq wl-draft-field-completion-list ret-val)))
 210
 211 (defun wl-draft-make-mail-followup-to (recipients)
 212   (if (elmo-list-member
 213        (or wl-user-mail-address-list
 214            (list (wl-address-header-extract-address wl-from)))
 215        recipients)
 216       (let ((rlist (elmo-list-delete
 217                     (or wl-user-mail-address-list
 218                         (list (wl-address-header-extract-address wl-from)))
 219                     (copy-sequence recipients))))
 220         (if (elmo-list-member rlist (mapcar 'downcase
 221                                             wl-subscribed-mailing-list))
 222             rlist
 223           (append rlist (list (wl-address-header-extract-address
 224                                wl-from)))))
 225     recipients))
 226
 227 (defun wl-draft-delete-myself-from-cc (to cc)
 228   (let ((myself (or wl-user-mail-address-list
 229                     (list (wl-address-header-extract-address wl-from)))))
 230     (cond (wl-draft-always-delete-myself ; always-delete option
 231            (elmo-list-delete myself cc))
 232           ((elmo-list-member (append to cc) ; subscribed mailing-list
 233                              (mapcar 'downcase wl-subscribed-mailing-list))
 234            (elmo-list-delete myself cc))
 235           (t cc))))
 236
 237 (defun wl-draft-forward (original-subject summary-buf)
 238   (let (references)
 239     (with-current-buffer (wl-message-get-original-buffer)
 240       (setq references (nconc
 241                         (std11-field-bodies '("References" "In-Reply-To"))
 242                         (list (std11-field-body "Message-Id"))))
 243       (setq references (delq nil references)
 244             references (mapconcat 'identity references " ")
 245             references (wl-draft-parse-msg-id-list-string references)
 246             references (wl-delete-duplicates references)
 247             references (when references
 248                          (mapconcat 'identity references "\n\t"))))
 249     (wl-draft "" (concat "Forward: " original-subject)
 250               nil nil references nil nil nil nil nil nil summary-buf))
 251   (goto-char (point-max))
 252   (wl-draft-insert-message)
 253   (mail-position-on-field "To"))
 254
 255 (defun wl-draft-strip-subject-re (subject)
 256   "Remove \"Re:\" from subject lines. Shamelessly copied from Gnus"
 257   (if (string-match wl-subject-prefix-regexp subject)
 258       (substring subject (match-end 0))
 259     subject))
 260
 261 (defun wl-draft-reply-list-symbol (with-arg)
 262   "Return symbol `wl-draft-reply-*-argument-list' match condition.
 263 Check WITH-ARG and From: field."
 264   (if (wl-address-user-mail-address-p (or (elmo-field-body "From") ""))
 265       (if with-arg
 266           'wl-draft-reply-myself-with-argument-list
 267         'wl-draft-reply-myself-without-argument-list)
 268     (if with-arg
 269         'wl-draft-reply-with-argument-list
 270       'wl-draft-reply-without-argument-list)))
 271
 272 (defun wl-draft-reply (buf with-arg summary-buf)
 273   "Reply to BUF buffer message.
 274 Reply to author if WITH-ARG is non-nil."
 275 ;;;(save-excursion
 276   (let (r-list
 277         to mail-followup-to cc subject in-reply-to references newsgroups
 278         from to-alist cc-alist decoder)
 279     (set-buffer buf)
 280     (setq r-list (symbol-value (wl-draft-reply-list-symbol with-arg)))
 281     (catch 'done
 282       (while r-list
 283         (when (let ((condition (car (car r-list))))
 284                 (cond ((stringp condition)
 285                        (std11-field-body condition))
 286                       ((listp condition)
 287                        (catch 'done
 288                          (while condition
 289                            (if (not (std11-field-body (car condition)))
 290                                (throw 'done nil))
 291                            (setq condition (cdr condition)))
 292                          t))
 293                       ((symbolp condition)
 294                        (funcall condition))))
 295           (let ((r-to-list (nth 0 (cdr (car r-list))))
 296                 (r-cc-list (nth 1 (cdr (car r-list))))
 297                 (r-ng-list (nth 2 (cdr (car r-list)))))
 298             (when (and (member "Followup-To" r-ng-list)
 299                        (string= (std11-field-body "Followup-To") "poster"))
 300               (setq r-to-list (cons "From" r-to-list))
 301               (setq r-ng-list (delete "Followup-To" (copy-sequence r-ng-list))))
 302             (setq to (wl-concat-list (cons to
 303                                            (elmo-multiple-fields-body-list
 304                                             r-to-list))
 305                                      ","))
 306             (setq cc (wl-concat-list (cons cc
 307                                            (elmo-multiple-fields-body-list
 308                                             r-cc-list))
 309                                      ","))
 310             (setq newsgroups (wl-concat-list (cons newsgroups
 311                                                    (std11-field-bodies
 312                                                     r-ng-list))
 313                                              ",")))
 314           (throw 'done nil))
 315         (setq r-list (cdr r-list)))
 316       (error "No match field: check your `%s'"
 317              (symbol-name (wl-draft-reply-list-symbol with-arg))))
 318     (setq subject (std11-field-body "Subject"))
 319     (setq to (wl-parse-addresses to)
 320           cc (wl-parse-addresses cc))
 321     (with-temp-buffer                   ; to keep raw buffer unibyte.
 322       (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 323       (setq decoder (mime-find-field-decoder 'Subject 'plain))
 324       (setq subject (if (and subject decoder)
 325                         (funcall decoder subject) subject))
 326       (setq to-alist
 327             (mapcar
 328              (lambda (addr)
 329                (setq decoder (mime-find-field-decoder 'To 'plain))
 330                (cons (nth 1 (std11-extract-address-components addr))
 331                      (if decoder (funcall decoder addr) addr)))
 332              to))
 333       (setq cc-alist
 334             (mapcar
 335              (lambda (addr)
 336                (setq decoder (mime-find-field-decoder 'Cc 'plain))
 337                (cons (nth 1 (std11-extract-address-components addr))
 338                      (if decoder (funcall decoder addr) addr)))
 339              cc)))
 340     (and wl-reply-subject-prefix
 341          (setq subject (concat wl-reply-subject-prefix
 342                                (wl-draft-strip-subject-re
 343                                 (or subject "")))))
 344     (setq in-reply-to (std11-field-body "Message-Id"))
 345     (setq references (nconc
 346                       (std11-field-bodies '("References" "In-Reply-To"))
 347                       (list in-reply-to)))
 348     (setq to (delq nil (mapcar 'car to-alist)))
 349     (setq cc (delq nil (mapcar 'car cc-alist)))
 350     ;; if subscribed mailing list is contained in cc or to
 351     ;; and myself is contained in cc,
 352     ;; delete myself from cc.
 353     (setq cc (wl-draft-delete-myself-from-cc to cc))
 354     (when wl-insert-mail-followup-to
 355       (setq mail-followup-to
 356             (wl-draft-make-mail-followup-to (append to cc)))
 357       (setq mail-followup-to (wl-delete-duplicates mail-followup-to nil t)))
 358     (setq newsgroups (wl-parse newsgroups
 359                                "[ \t\f\r\n,]*\\([^ \t\f\r\n,]+\\)")
 360           newsgroups (wl-delete-duplicates newsgroups)
 361           newsgroups (if newsgroups (mapconcat 'identity newsgroups ",")))
 362     (setq to (wl-delete-duplicates to nil t))
 363     (setq cc (wl-delete-duplicates
 364               (append (wl-delete-duplicates cc nil t)
 365                       to (copy-sequence to))
 366               t t))
 367     (and to (setq to (mapconcat
 368                       '(lambda (addr)
 369                          (if wl-draft-reply-use-address-with-full-name
 370                              (or (cdr (assoc addr to-alist)) addr)
 371                            addr))
 372                       to ",\n\t")))
 373     (and cc (setq cc (mapconcat
 374                       '(lambda (addr)
 375                          (if wl-draft-reply-use-address-with-full-name
 376                              (or (cdr (assoc addr cc-alist)) addr)
 377                            addr))
 378                       cc ",\n\t")))
 379     (and mail-followup-to
 380          (setq mail-followup-to
 381                (mapconcat
 382                 '(lambda (addr)
 383                    (if wl-draft-reply-use-address-with-full-name
 384                        (or (cdr (assoc addr (append to-alist cc-alist))) addr)
 385                      addr))
 386                 mail-followup-to ",\n\t")))
 387     (and (null to) (setq to cc cc nil))
 388     (setq references (delq nil references)
 389           references (mapconcat 'identity references " ")
 390           references (wl-draft-parse-msg-id-list-string references)
 391           references (wl-delete-duplicates references)
 392           references (if references
 393                          (mapconcat 'identity references "\n\t")))
 394     (wl-draft
 395      to subject in-reply-to cc references newsgroups mail-followup-to
 396      nil nil nil nil summary-buf)
 397     (setq wl-draft-reply-buffer buf))
 398   (run-hooks 'wl-reply-hook))
 399
 400 (defun wl-draft-add-references ()
 401   (let* ((mes-id (save-excursion
 402                    (set-buffer mail-reply-buffer)
 403                    (std11-field-body "message-id")))
 404          (ref (std11-field-body "References"))
 405          (ref-list nil) (st nil))
 406     (when (and mes-id ref)
 407       (while (string-match "<[^>]+>" ref st)
 408         (setq ref-list
 409               (cons (substring ref (match-beginning 0) (setq st (match-end 0)))
 410                     ref-list)))
 411       (when (and ref-list
 412                  (member mes-id ref-list))
 413         (setq mes-id nil)))
 414     (when mes-id
 415       (save-excursion
 416         (when (mail-position-on-field "References")
 417           (forward-line)
 418           (while (looking-at "^[ \t]")
 419             (forward-line))
 420           (setq mes-id (concat "\t" mes-id "\n")))
 421         (insert mes-id))
 422       t)))
 423
 424 (defun wl-draft-yank-from-mail-reply-buffer (decode-it
 425                                              &optional ignored-fields)
 426   (interactive)
 427   (save-restriction
 428     (narrow-to-region (point)(point))
 429     (insert
 430      (with-current-buffer mail-reply-buffer
 431        (when decode-it
 432          (decode-mime-charset-region (point-min) (point-max)
 433                                      wl-mime-charset))
 434        (buffer-substring-no-properties
 435         (point-min) (point-max))))
 436     (when ignored-fields
 437       (goto-char (point-min))
 438       (wl-draft-delete-fields ignored-fields))
 439     (goto-char (point-max))
 440     (push-mark)
 441     (goto-char (point-min)))
 442   (let ((beg (point)))
 443     (cond (mail-citation-hook (run-hooks 'mail-citation-hook))
 444           (mail-yank-hooks (run-hooks 'mail-yank-hooks))
 445           (wl-draft-cite-function (funcall wl-draft-cite-function))) ; default cite
 446     (run-hooks 'wl-draft-cited-hook)
 447     (when (and wl-draft-add-references
 448                (wl-draft-add-references))
 449       (wl-highlight-headers 'for-draft)) ; highlight when added References:
 450     (when wl-highlight-body-too
 451       (wl-highlight-body-region beg (point-max)))))
 452
 453 (defun wl-draft-confirm ()
 454   "Confirm send message."
 455   (interactive)
 456   (y-or-n-p (format "Send current draft as %s? "
 457                     (cond ((and (wl-message-mail-p) (wl-message-news-p))
 458                            "Mail and News")
 459                           ((wl-message-mail-p) "Mail")
 460                           ((wl-message-news-p) "News")))))
 461
 462 (defun wl-message-news-p ()
 463   "If exist valid Newsgroups field, return non-nil."
 464   (std11-field-body "Newsgroups"))
 465
 466 (defun wl-message-field-exists-p (field)
 467   "If FIELD exist and FIELD value is not empty, return non-nil."
 468   (let ((value (std11-field-body field)))
 469     (and value
 470          (not (string= value "")))))
 471
 472 (defun wl-message-mail-p ()
 473   "If exist To, Cc or Bcc field, return non-nil."
 474   (or (wl-message-field-exists-p "To")
 475       (wl-message-field-exists-p "Resent-to")
 476       (wl-message-field-exists-p "Cc")
 477       (wl-message-field-exists-p "Bcc")
 478 ;;; This may be needed..
 479 ;;;   (wl-message-field-exists-p "Fcc")
 480       ))
 481
 482 (defun wl-draft-open-file (&optional file)
 483   "Open FILE for edit."
 484   (interactive)
 485 ;;;(interactive "*fFile to edit: ")
 486   (wl-draft-edit-string (elmo-get-file-string
 487                          (or file
 488                              (read-file-name "File to edit: "
 489                                              (or wl-tmp-dir "~/"))))))
 490
 491 (defun wl-draft-edit-string (string)
 492   (let ((cur-buf (current-buffer))
 493         (tmp-buf (get-buffer-create " *wl-draft-edit-string*"))
 494         to subject in-reply-to cc references newsgroups mail-followup-to
 495         content-type content-transfer-encoding from
 496         body-beg buffer-read-only)
 497     (set-buffer tmp-buf)
 498     (erase-buffer)
 499     (insert string)
 500     (setq to (std11-field-body "To"))
 501     (setq to (and to
 502                   (eword-decode-string
 503                    (decode-mime-charset-string
 504                     to
 505                     wl-mime-charset))))
 506     (setq subject (std11-field-body "Subject"))
 507     (setq subject (and subject
 508                        (eword-decode-string
 509                         (decode-mime-charset-string
 510                          subject
 511                          wl-mime-charset))))
 512     (setq from (std11-field-body "From")
 513           from (and from
 514                     (eword-decode-string
 515                      (decode-mime-charset-string
 516                       from
 517                       wl-mime-charset))))
 518     (setq in-reply-to (std11-field-body "In-Reply-To"))
 519     (setq cc (std11-field-body "Cc"))
 520     (setq cc (and cc
 521                   (eword-decode-string
 522                    (decode-mime-charset-string
 523                     cc
 524                     wl-mime-charset))))
 525     (setq references (std11-field-body "References"))
 526     (setq newsgroups (std11-field-body "Newsgroups"))
 527     (setq mail-followup-to (std11-field-body "Mail-Followup-To"))
 528     (setq content-type (std11-field-body "Content-Type"))
 529     (setq content-transfer-encoding (std11-field-body "Content-Transfer-Encoding"))
 530     (goto-char (point-min))
 531     (or (re-search-forward "\n\n" nil t)
 532         (search-forward (concat mail-header-separator "\n") nil t))
 533     (unwind-protect
 534         (set-buffer
 535          (wl-draft to subject in-reply-to cc references newsgroups
 536                    mail-followup-to
 537                    content-type content-transfer-encoding
 538                    (buffer-substring (point) (point-max))
 539                    'edit-again nil
 540                    (if (member (nth 1 (std11-extract-address-components from))
 541                                wl-user-mail-address-list)
 542                        from)))
 543       (and to (mail-position-on-field "To"))
 544       (delete-other-windows)
 545       (kill-buffer tmp-buf)))
 546   (setq buffer-read-only nil) ;;??
 547   (run-hooks 'wl-draft-reedit-hook))
 548
 549 (defun wl-draft-insert-current-message (dummy)
 550   (interactive)
 551   (let (original-buffer
 552         mail-reply-buffer
 553         mail-citation-hook mail-yank-hooks
 554         wl-draft-add-references wl-draft-cite-function)
 555     (with-current-buffer wl-draft-buffer-cur-summary-buffer
 556       (with-current-buffer wl-message-buffer
 557         (setq original-buffer (wl-message-get-original-buffer))
 558         (if (zerop
 559              (with-current-buffer original-buffer
 560                (buffer-size)))
 561             (error "No current message"))))
 562     (setq mail-reply-buffer original-buffer)
 563     (wl-draft-yank-from-mail-reply-buffer
 564      nil
 565      wl-ignored-forwarded-headers)))
 566
 567 (defun wl-draft-insert-get-message (dummy)
 568   (let ((fld (completing-read
 569               "Folder name: "
 570               (if (memq 'read-folder wl-use-folder-petname)
 571                   (wl-folder-get-entity-with-petname)
 572                 wl-folder-entity-hashtb)
 573               nil nil wl-default-spec
 574               'wl-read-folder-hist))
 575         (number (call-interactively
 576                  (function (lambda (num)
 577                              (interactive "nNumber: ")
 578                              num))))
 579         (mail-reply-buffer (get-buffer-create "*wl-draft-insert-get-message*"))
 580         mail-citation-hook mail-yank-hooks
 581         wl-draft-cite-function)
 582     (unwind-protect
 583         (progn
 584           (elmo-message-fetch (wl-folder-get-elmo-folder fld)
 585                               number
 586                               ;; No cache.
 587                               (elmo-make-fetch-strategy 'entire)
 588                               nil mail-reply-buffer)
 589           (wl-draft-yank-from-mail-reply-buffer nil))
 590       (kill-buffer mail-reply-buffer))))
 591
 592 ;;
 593 ;; default body citation func
 594 ;;
 595 (defun wl-default-draft-cite ()
 596   (let ((mail-yank-ignored-headers "[^:]+:")
 597         (mail-yank-prefix "> ")
 598         (summary-buf wl-current-summary-buffer)
 599         (message-buf (get-buffer (wl-current-message-buffer)))
 600         from date cite-title num entity)
 601     (if (and summary-buf
 602              (buffer-live-p summary-buf)
 603              message-buf
 604              (buffer-live-p message-buf))
 605         (progn
 606           (with-current-buffer summary-buf
 607             (setq num (save-excursion
 608                         (set-buffer message-buf)
 609                         wl-message-buffer-cur-number))
 610             (setq entity (elmo-msgdb-overview-get-entity
 611                           num (wl-summary-buffer-msgdb)))
 612             (setq date (elmo-msgdb-overview-entity-get-date entity))
 613             (setq from (elmo-msgdb-overview-entity-get-from entity)))
 614           (setq cite-title (format "At %s,\n%s wrote:"
 615                                    (or date "some time ago")
 616                                    (wl-summary-from-func-internal
 617                                     (or from "you"))))))
 618     (and cite-title
 619          (insert cite-title "\n"))
 620     (mail-indent-citation)))
 621
 622 (defvar wl-draft-buffer nil "Draft buffer to yank content")
 623 (defun wl-draft-yank-to-draft-buffer (buffer)
 624   "Yank BUFFER content to `wl-draft-buffer'."
 625   (set-buffer wl-draft-buffer)
 626   (let ((mail-reply-buffer buffer))
 627     (wl-draft-yank-from-mail-reply-buffer nil)
 628     (kill-buffer buffer)))
 629
 630 (defun wl-draft-yank-original (&optional arg)
 631   "Yank original message."
 632   (interactive "P")
 633   (if arg
 634       (let (buf mail-reply-buffer)
 635         (elmo-set-work-buf
 636          (yank)
 637          (setq buf (current-buffer)))
 638         (setq mail-reply-buffer buf)
 639         (wl-draft-yank-from-mail-reply-buffer nil))
 640     (wl-draft-yank-current-message-entity)))
 641
 642 (defun wl-draft-hide (editing-buffer)
 643   "Hide the editing draft buffer if possible."
 644   (interactive)
 645   (when (and editing-buffer
 646              (buffer-live-p editing-buffer))
 647     (set-buffer editing-buffer)
 648     (let ((sum-buf wl-draft-buffer-cur-summary-buffer)
 649           fld-buf sum-win fld-win)
 650       (if (and wl-draft-use-frame
 651                (> (length (visible-frame-list)) 1))
 652           ;; hide draft frame
 653           (delete-frame)
 654         ;; hide draft window
 655         (or (one-window-p)
 656             (delete-window)))
 657       ;; stay folder window if required
 658       (when wl-stay-folder-window
 659         (if (setq fld-buf (get-buffer wl-folder-buffer-name))
 660             (if (setq fld-win (get-buffer-window fld-buf))
 661                 (select-window fld-win)
 662               (if wl-draft-resume-folder-window ;; resume folder window
 663                   (switch-to-buffer fld-buf)))))
 664       (if (buffer-live-p sum-buf)
 665           (if (setq sum-win (get-buffer-window sum-buf t))
 666               ;; if Summary is on the frame, select it.
 667               (select-window sum-win)
 668             ;; if summary is not on the frame, switch to it.
 669             (if (and wl-stay-folder-window
 670                      (or wl-draft-resume-folder-window fld-win))
 671                 (wl-folder-select-buffer sum-buf)
 672               (switch-to-buffer sum-buf)))))))
 673
 674 (defun wl-draft-delete (editing-buffer)
 675   "kill the editing draft buffer and delete the file corresponds to it."
 676   (save-excursion
 677     (when editing-buffer
 678       (set-buffer editing-buffer)
 679       (if wl-draft-buffer-file-name
 680           (progn
 681             (if (file-exists-p wl-draft-buffer-file-name)
 682                 (delete-file wl-draft-buffer-file-name))
 683             (let ((msg (and wl-draft-buffer-file-name
 684                             (string-match "[0-9]+$" wl-draft-buffer-file-name)
 685                             (string-to-int
 686                              (match-string 0 wl-draft-buffer-file-name)))))
 687               (wl-draft-config-info-operation msg 'delete))))
 688       (set-buffer-modified-p nil)               ; force kill
 689       (kill-buffer editing-buffer))))
 690
 691 (defun wl-draft-kill (&optional force-kill)
 692   "Kill current draft buffer and quit editing."
 693   (interactive "P")
 694   (save-excursion
 695     (when (and (or (eq major-mode 'wl-draft-mode)
 696                    (eq major-mode 'mail-mode))
 697                (or force-kill
 698                    (y-or-n-p "Kill Current Draft?")))
 699       (let ((cur-buf (current-buffer)))
 700         (wl-draft-hide cur-buf)
 701         (wl-draft-delete cur-buf)))
 702     (message "")))
 703
 704 (defun wl-draft-fcc ()
 705   "Add a new Fcc field, with file name completion."
 706   (interactive)
 707   (or (mail-position-on-field "fcc" t)  ;Put new field after exiting Fcc.
 708       (mail-position-on-field "to"))
 709   (insert "\nFcc: "))
 710
 711 ;; function for wl-sent-message-via
 712
 713 (defmacro wl-draft-sent-message-p (type)
 714   (` (eq (nth 1 (assq (, type) wl-sent-message-via)) 'sent)))
 715
 716 (defmacro wl-draft-set-sent-message (type result &optional server-port)
 717   (` (let ((element (assq (, type) wl-sent-message-via)))
 718        (if element
 719            (unless (eq (nth 1 element) (, result))
 720              (setcdr element (list (, result) (, server-port)))
 721              (setq wl-sent-message-modified t))
 722          (push (list (, type) (, result) (, server-port)) wl-sent-message-via)
 723          (setq wl-sent-message-modified t)))))
 724
 725 (defun wl-draft-sent-message-results ()
 726   (let ((results wl-sent-message-via)
 727         unplugged-via sent-via)
 728     (while results
 729       (cond ((eq (nth 1 (car results)) 'unplugged)
 730              (push (caar results) unplugged-via))
 731             ((eq (nth 1 (car results)) 'sent)
 732              (push (caar results) sent-via)))
 733       (setq results (cdr results)))
 734     (list unplugged-via sent-via)))
 735
 736 (defun wl-draft-write-sendlog (status proto server to id)
 737   "Write send log file, if `wl-draft-sendlog' is non-nil."
 738   (when wl-draft-sendlog
 739     (save-excursion
 740       (let* ((tmp-buf (get-buffer-create " *wl-draft-sendlog*"))
 741              (filename (expand-file-name wl-draft-sendlog-filename
 742                                          elmo-msgdb-dir))
 743              (filesize (nth 7 (file-attributes filename)))
 744              (server (if server (concat " server=" server) ""))
 745              (to (if to (cond
 746                          ((memq proto '(fcc queue))
 747                           (format " folder=\"%s\"" to))
 748                          ((eq proto 'nntp)
 749                           (format " ng=<%s>" to))
 750                          (t
 751                           (concat " to="
 752                                   (mapconcat
 753                                    'identity
 754                                    (mapcar '(lambda(x) (format "<%s>" x)) to)
 755                                    ","))))
 756                    ""))
 757              (id (if id (concat " id=" id) ""))
 758              (time (wl-sendlog-time)))
 759         (set-buffer tmp-buf)
 760         (erase-buffer)
 761         (insert (format "%s proto=%s stat=%s%s%s%s\n"
 762                         time proto status server to id))
 763         (if (and wl-draft-sendlog-max-size filesize
 764                  (> filesize wl-draft-sendlog-max-size))
 765             (rename-file filename (concat filename ".old") t))
 766         (if (file-writable-p filename)
 767             (write-region (point-min) (point-max)
 768                           filename t 'no-msg)
 769           (message (format "%s is not writable." filename)))
 770         (kill-buffer tmp-buf)))))
 771
 772 (defun wl-draft-get-header-delimiter (&optional delete)
 773   ;; If DELETE is non-nil, replace the header delimiter with a blank line
 774   (let (delimline)
 775     (goto-char (point-min))
 776     (when (re-search-forward
 777            (concat "^" (regexp-quote mail-header-separator) "$\\|^$") nil t)
 778       (replace-match "")
 779       (if delete
 780           (forward-char -1))
 781       (setq delimline (point-marker)))
 782     delimline))
 783
 784 (defun wl-draft-send-mail-with-qmail ()
 785   "Pass the prepared message buffer to qmail-inject.
 786 Refer to the documentation for the variable `send-mail-function'
 787 to find out how to use this."
 788   (if (and wl-draft-qmail-send-plugged
 789            (not (elmo-plugged-p)))
 790       (wl-draft-set-sent-message 'mail 'unplugged)
 791     ;; send the message
 792     (let ((id (std11-field-body "Message-ID"))
 793           (to (std11-field-body "To")))
 794       (case
 795           (as-binary-process
 796            (apply
 797             'call-process-region 1 (point-max) wl-qmail-inject-program
 798             nil nil nil
 799             wl-qmail-inject-args))
 800         ;; qmail-inject doesn't say anything on it's stdout/stderr,
 801         ;; we have to look at the retval instead
 802         (0   (progn
 803                (wl-draft-set-sent-message 'mail 'sent)
 804                (wl-draft-write-sendlog 'ok 'qmail nil (list to) id)))
 805         (1   (error "qmail-inject reported permanent failure"))
 806         (111 (error "qmail-inject reported transient failure"))
 807         ;; should never happen
 808         (t   (error "qmail-inject reported unknown failure"))))))
 809
 810 (defun wl-draft-parse-msg-id-list-string (string)
 811   "Get msg-id list from STRING."
 812   (let (msg-id-list)
 813     (dolist (parsed-id (std11-parse-msg-ids-string string))
 814       (when (eq (car parsed-id) 'msg-id)
 815         (setq msg-id-list (cons (std11-msg-id-string parsed-id)
 816                                 msg-id-list))))
 817     (nreverse msg-id-list)))
 818
 819 (defun wl-draft-std11-parse-addresses (lal)
 820   (let ((ret (std11-parse-address lal)))
 821     (if ret
 822         (let ((dest (list (car ret))))
 823           (setq lal (cdr ret))
 824           (while (and (setq ret (std11-parse-ascii-token lal))
 825                       (string-equal (cdr (assq 'specials (car ret))) ",")
 826                       (setq ret (std11-parse-address (cdr ret)))
 827                       )
 828             (setq dest (cons (car ret) dest))
 829             (setq lal (cdr ret)))
 830           (if lal (error "Error while parsing address"))
 831           (nreverse dest)))))
 832
 833 (defun wl-draft-parse-mailbox-list (field &optional remove-group-list)
 834   "Get mailbox list of FIELD from current buffer.
 835 The buffer is expected to be narrowed to just the headers of the message.
 836 If optional argument REMOVE-GROUP-LIST is non-nil, remove group list content
 837 from current buffer."
 838   (save-excursion
 839     (let ((case-fold-search t)
 840           (inhibit-read-only t)
 841           addresses address
 842           mailbox-list beg seq has-group-list)
 843       (goto-char (point-min))
 844       (while (re-search-forward (concat "^" (regexp-quote field) "[\t ]*:")
 845                                 nil t)
 846         (setq beg (point))
 847         (re-search-forward "^[^ \t]" nil 'move)
 848         (beginning-of-line)
 849         (skip-chars-backward "\n")
 850         (setq seq (std11-lexical-analyze
 851                    (buffer-substring-no-properties beg (point))))
 852         (setq addresses (wl-draft-std11-parse-addresses seq))
 853         (while addresses
 854           (cond ((eq (car (car addresses)) 'group)
 855                  (setq has-group-list t)
 856                  (setq mailbox-list
 857                        (nconc mailbox-list
 858                               (mapcar
 859                                'std11-address-string
 860                                (nth 2 (car addresses))))))
 861                 ((eq (car (car addresses)) 'mailbox)
 862                  (setq address (nth 1 (car addresses)))
 863                  (setq mailbox-list
 864                        (nconc mailbox-list
 865                               (list
 866                                (std11-addr-to-string
 867                                 (if (eq (car address) 'phrase-route-addr)
 868                                     (nth 2 address)
 869                                   (cdr address))))))))
 870           (setq addresses (cdr addresses)))
 871         (when (and remove-group-list has-group-list)
 872           (delete-region beg (point))
 873           (insert (wl-address-string-without-group-list-contents seq))))
 874       mailbox-list)))
 875
 876 (defun wl-draft-deduce-address-list (buffer header-start header-end)
 877   "Get address list suitable for smtp RCPT TO:<address>.
 878 Group list content is removed if `wl-draft-remove-group-list-contents' is
 879 non-nil."
 880   (let ((fields        '("to" "cc" "bcc"))
 881         (resent-fields '("resent-to" "resent-cc" "resent-bcc"))
 882         (case-fold-search t)
 883         addrs recipients)
 884     (save-excursion
 885       (save-restriction
 886         (narrow-to-region header-start header-end)
 887         (goto-char (point-min))
 888         (save-excursion
 889           (if (re-search-forward "^resent-to[\t ]*:" nil t)
 890               (setq fields resent-fields)))
 891         (while fields
 892           (setq recipients
 893                 (nconc recipients
 894                        (wl-draft-parse-mailbox-list
 895                         (car fields)
 896                         wl-draft-remove-group-list-contents)))
 897           (setq fields (cdr fields)))
 898         recipients))))
 899
 900 ;;
 901 ;; from Semi-gnus
 902 ;;
 903 (defun wl-draft-send-mail-with-smtp ()
 904   "Send the prepared message buffer with SMTP."
 905   (require 'smtp)
 906   (let* ((errbuf (if mail-interactive
 907                      (generate-new-buffer " smtp errors")
 908                    0))
 909          (case-fold-search t)
 910          (default-case-fold-search t)
 911          (sender (or wl-envelope-from
 912                      (wl-address-header-extract-address wl-from)))
 913          (delimline (save-excursion
 914                       (goto-char (point-min))
 915                       (re-search-forward
 916                        (concat "^" (regexp-quote mail-header-separator)
 917                                "$\\|^$") nil t)
 918                       (point-marker)))
 919          (smtp-server
 920           (or wl-smtp-posting-server
 921               ;; Compatibility stuff for FLIM 1.12.5 or earlier.
 922               ;; They don't accept a function as the value of `smtp-server'.
 923               (if (functionp smtp-server)
 924                   (funcall
 925                    smtp-server
 926                    sender
 927                    ;; no harm..
 928                    (let (wl-draft-remove-group-list-contents)
 929                      (wl-draft-deduce-address-list
 930                       (current-buffer) (point-min) delimline)))
 931                 (or smtp-server "localhost"))))
 932          (smtp-service (or wl-smtp-posting-port smtp-service))
 933          (smtp-local-domain (or smtp-local-domain wl-local-domain))
 934          (id (std11-field-body "message-id"))
 935          recipients)
 936     (if (not (elmo-plugged-p smtp-server smtp-service))
 937         (wl-draft-set-sent-message 'mail 'unplugged
 938                                    (cons smtp-server smtp-service))
 939       (unwind-protect
 940           (save-excursion
 941             ;; Instead of `smtp-deduce-address-list'.
 942             (setq recipients (wl-draft-deduce-address-list
 943                               (current-buffer) (point-min) delimline))
 944             (unless recipients (error "No recipients"))
 945             ;; Insert an extra newline if we need it to work around
 946             ;; Sun's bug that swallows newlines.
 947             (goto-char (1+ delimline))
 948             (if (eval mail-mailer-swallows-blank-line)
 949                 (newline))
 950 ;;;         (run-hooks 'wl-mail-send-pre-hook)
 951             (if mail-interactive
 952                 (save-excursion
 953                   (set-buffer errbuf)
 954                   (erase-buffer)))
 955             (wl-draft-delete-field "bcc" delimline)
 956             (wl-draft-delete-field "resent-bcc" delimline)
 957             (let (process-connection-type)
 958               (as-binary-process
 959                (when recipients
 960                  (wl-smtp-extension-bind
 961                   (condition-case err
 962                       (smtp-send-buffer sender recipients (current-buffer))
 963                     (error
 964                      (wl-draft-write-sendlog 'failed 'smtp smtp-server
 965                                              recipients id)
 966                      (signal (car err) (cdr err)))))
 967                  (wl-draft-set-sent-message 'mail 'sent)
 968                  (wl-draft-write-sendlog
 969                   'ok 'smtp smtp-server recipients id)))))
 970         (if (bufferp errbuf)
 971             (kill-buffer errbuf))))))
 972
 973 (defun wl-draft-send-mail-with-pop-before-smtp ()
 974   "Send the prepared message buffer with POP-before-SMTP."
 975   (require 'elmo-pop3)
 976   (condition-case ()
 977       (let ((session (elmo-pop3-get-session
 978                       (list 'pop3
 979                             (or wl-pop-before-smtp-user
 980                                 elmo-pop3-default-user)
 981                             (or wl-pop-before-smtp-authenticate-type
 982                                 elmo-pop3-default-authenticate-type)
 983                             (or wl-pop-before-smtp-server
 984                                 elmo-pop3-default-server)
 985                             (or wl-pop-before-smtp-port
 986                                 elmo-pop3-default-port)
 987                             (or wl-pop-before-smtp-stream-type
 988                                 elmo-pop3-default-stream-type)))))
 989         (when session (elmo-network-close-session session)))
 990     (error))
 991   (wl-draft-send-mail-with-smtp))
 992
 993 (defun wl-draft-insert-required-fields (&optional force-msgid)
 994   "Insert Message-ID, Date, and From field.
 995 If FORCE-MSGID, ignore 'wl-insert-message-id'."
 996   ;; Insert Message-Id field...
 997   (goto-char (point-min))
 998   (when (and (or force-msgid
 999                  wl-insert-message-id)
1000              (not (re-search-forward "^Message-ID[ \t]*:" nil t)))
1001     (insert (concat "Message-ID: "
1002                     (wl-draft-make-message-id-string)
1003                     "\n")))
1004   ;; Insert date field.
1005   (goto-char (point-min))
1006   (or (re-search-forward "^Date[ \t]*:" nil t)
1007       (wl-draft-insert-date-field))
1008   ;; Insert from field.
1009   (goto-char (point-min))
1010   (or (re-search-forward "^From[ \t]*:" nil t)
1011       (wl-draft-insert-from-field)))
1012
1013 (defun wl-draft-normal-send-func (editing-buffer kill-when-done)
1014   "Send the message in the current buffer."
1015   (save-restriction
1016     (std11-narrow-to-header mail-header-separator)
1017     (wl-draft-insert-required-fields)
1018     ;; Delete null fields.
1019     (goto-char (point-min))
1020     (while (re-search-forward "^[^ \t\n:]+:[ \t]*\n" nil t)
1021       (replace-match ""))
1022     ;; ignore any blank lines in the header
1023     (while (re-search-forward "\n\n\n*" nil t)
1024       (replace-match "\n")))
1025   (run-hooks 'wl-mail-send-pre-hook) ;; X-PGP-Sig, Cancel-Lock
1026   (wl-draft-dispatch-message)
1027   (when kill-when-done
1028     ;; hide editing-buffer.
1029     (wl-draft-hide editing-buffer)
1030     ;; delete editing-buffer and its file.
1031     (wl-draft-delete editing-buffer)))
1032
1033 (defun wl-draft-dispatch-message (&optional mes-string)
1034   "Send the message in the current buffer.  Not modified the header fields."
1035   (let (delimline)
1036     (if (and wl-draft-verbose-send mes-string)
1037         (message mes-string))
1038     ;; get fcc folders.
1039     (setq delimline (wl-draft-get-header-delimiter t))
1040     (unless wl-draft-fcc-list
1041       (setq wl-draft-fcc-list (wl-draft-get-fcc-list delimline)))
1042     ;;
1043     (setq wl-sent-message-modified nil)
1044     (unwind-protect
1045         (progn
1046           (if (and (wl-message-mail-p)
1047                    (not (wl-draft-sent-message-p 'mail)))
1048               (funcall wl-draft-send-mail-function))
1049           (if (and (wl-message-news-p)
1050                    (not (wl-draft-sent-message-p 'news))
1051                    (not (wl-message-field-exists-p "Resent-to")))
1052               (funcall wl-draft-send-news-function)))
1053       ;;
1054       (let* ((status (wl-draft-sent-message-results))
1055              (unplugged-via (car status))
1056              (sent-via (nth 1 status)))
1057         ;; If one sent, process fcc folder.
1058         (if (and sent-via wl-draft-fcc-list)
1059             (progn
1060               (wl-draft-do-fcc (wl-draft-get-header-delimiter) wl-draft-fcc-list)
1061               (setq wl-draft-fcc-list nil)))
1062         (if wl-draft-use-cache
1063             (let ((id (std11-field-body "Message-ID"))
1064                   (elmo-enable-disconnected-operation t))
1065               (elmo-file-cache-save (elmo-file-cache-get-path id)
1066                                     nil)))
1067         ;; If one unplugged, append queue.
1068         (when (and unplugged-via
1069                    wl-sent-message-modified)
1070           (if wl-draft-enable-queuing
1071               (wl-draft-queue-append wl-sent-message-via)
1072             (error "Unplugged")))
1073         (when wl-draft-verbose-send
1074           (if (and unplugged-via sent-via);; combined message
1075               (progn
1076                 (setq wl-draft-verbose-msg
1077                       (format "Sending%s and Queuing%s..."
1078                               sent-via unplugged-via))
1079                 (message (concat wl-draft-verbose-msg "done")))
1080             (if mes-string
1081                 (message (concat mes-string
1082                                  (if sent-via "done" "failed")))))))))
1083   (not wl-sent-message-modified)) ;; return value
1084
1085 (defun wl-draft-raw-send (&optional kill-when-done force-pre-hook mes-string)
1086   "Force send current buffer as raw message."
1087   (interactive)
1088   (save-excursion
1089     (let (wl-interactive-send
1090 ;;;       wl-draft-verbose-send
1091           (wl-mail-send-pre-hook (and force-pre-hook wl-mail-send-pre-hook))
1092 ;;;       wl-news-send-pre-hook
1093           mail-send-hook
1094           mail-send-actions)
1095       (wl-draft-send kill-when-done mes-string))))
1096
1097 (defun wl-draft-clone-local-variables ()
1098   (let ((locals (buffer-local-variables))
1099         result)
1100     (while locals
1101       (when (and (consp (car locals))
1102                  (car (car locals))
1103                  (string-match wl-draft-clone-local-variable-regexp
1104                                (symbol-name (car (car locals)))))
1105         (wl-append result (list (car (car locals)))))
1106       (setq locals (cdr locals)))
1107     result))
1108
1109 (defun wl-draft-send (&optional kill-when-done mes-string)
1110   "Send current draft message.
1111 If optional argument is non-nil, current draft buffer is killed"
1112   (interactive)
1113   ;; Don't call this explicitly.
1114   ;; Added to 'wl-draft-send-hook (by teranisi)
1115   ;; (wl-draft-config-exec)
1116   (run-hooks 'wl-draft-send-hook)
1117   (when (or (not wl-interactive-send)
1118             (y-or-n-p "Send current draft. OK?"))
1119     (let ((send-mail-function 'wl-draft-raw-send)
1120           (editing-buffer (current-buffer))
1121           (sending-buffer (wl-draft-generate-clone-buffer
1122                            " *wl-draft-sending-buffer*"
1123                            (append wl-draft-config-variables
1124                                    (wl-draft-clone-local-variables))))
1125           (wl-draft-verbose-msg nil)
1126           err)
1127       (unwind-protect
1128           (save-excursion (set-buffer sending-buffer)
1129             (if (and (not (wl-message-mail-p))
1130                      (not (wl-message-news-p)))
1131                 (error "No recipient is specified"))
1132             (expand-abbrev) ; for mail-abbrevs
1133             (run-hooks 'mail-send-hook) ; translate buffer
1134             (if wl-draft-verbose-send
1135                 (message (or mes-string "Sending...")))
1136             (funcall wl-draft-send-function editing-buffer kill-when-done)
1137             ;; Now perform actions on successful sending.
1138             (while mail-send-actions
1139               (condition-case ()
1140                   (apply (car (car mail-send-actions))
1141                          (cdr (car mail-send-actions)))
1142                 (error))
1143               (setq mail-send-actions (cdr mail-send-actions)))
1144 ;;          (if (or (eq major-mode 'wl-draft-mode)
1145 ;;                  (eq major-mode 'mail-mode))
1146 ;;              (local-set-key "\C-c\C-s" 'wl-draft-send)) ; override
1147             (if wl-draft-verbose-send
1148                 (message (concat (or wl-draft-verbose-msg
1149                                      mes-string "Sending...")
1150                                  "done"))))
1151         ;; kill sending buffer, anyway.
1152         (and (buffer-live-p sending-buffer)
1153              (kill-buffer sending-buffer))))))
1154
1155 (defun wl-draft-save ()
1156   "Save current draft."
1157   (interactive)
1158   (save-buffer)
1159   (wl-draft-config-info-operation
1160    (and (string-match "[0-9]+$" wl-draft-buffer-file-name)
1161         (string-to-int
1162          (match-string 0 wl-draft-buffer-file-name)))
1163    'save))
1164
1165 (defun wl-draft-mimic-kill-buffer ()
1166   "Kill the current (draft) buffer with query."
1167   (interactive)
1168   (let ((bufname (read-buffer (format "Kill buffer: (default %s) "
1169                                       (buffer-name))))
1170         wl-draft-use-frame)
1171     (if (or (not bufname)
1172             (string-equal bufname "")
1173             (string-equal bufname (buffer-name)))
1174         (wl-draft-save-and-exit)
1175       (kill-buffer bufname))))
1176
1177 (defun wl-draft-save-and-exit ()
1178   "Save current draft and exit current draft mode."
1179   (interactive)
1180   (wl-draft-save)
1181   (let ((editing-buffer (current-buffer)))
1182     (wl-draft-hide editing-buffer)
1183     (kill-buffer editing-buffer)))
1184
1185 (defun wl-draft-send-and-exit ()
1186   "Send current draft message and kill it."
1187   (interactive)
1188   (wl-draft-send t))
1189
1190 (defun wl-draft-send-from-toolbar ()
1191   (interactive)
1192   (let ((wl-interactive-send t))
1193     (wl-draft-send-and-exit)))
1194
1195 (defun wl-draft-delete-field (field &optional delimline)
1196   (wl-draft-delete-fields (regexp-quote field) delimline))
1197
1198 (defun wl-draft-delete-fields (regexp &optional delimline)
1199   (save-restriction
1200     (unless delimline
1201       (if (search-forward "\n\n" nil t)
1202           (setq delimline (point))
1203         (setq delimline (point-max))))
1204     (narrow-to-region (point-min) delimline)
1205     (goto-char (point-min))
1206     (let ((regexp (concat "^" regexp ":"))
1207           (case-fold-search t)
1208           last)
1209       (while (not (eobp))
1210         (if (looking-at regexp)
1211             (progn
1212               (delete-region
1213                (point)
1214                (progn
1215                  (forward-line 1)
1216                  (if (re-search-forward "^[^ \t]" nil t)
1217                      (goto-char (match-beginning 0))
1218                    (point-max)))))
1219           (forward-line 1)
1220           (if (re-search-forward "^[^ \t]" nil t)
1221               (goto-char (match-beginning 0))
1222             (point-max)))))))
1223
1224 (defun wl-draft-get-fcc-list (header-end)
1225   (let (fcc-list
1226         (case-fold-search t))
1227     (or (markerp header-end) (error "header-end must be a marker"))
1228     (save-excursion
1229       (goto-char (point-min))
1230       (while (re-search-forward "^Fcc:[ \t]*" header-end t)
1231         (setq fcc-list
1232               (cons (buffer-substring-no-properties
1233                      (point)
1234                      (progn
1235                        (end-of-line)
1236                        (skip-chars-backward " \t")
1237                        (point)))
1238                     fcc-list))
1239         (save-match-data
1240           (wl-folder-confirm-existence
1241            (wl-folder-get-elmo-folder (eword-decode-string (car fcc-list)))))
1242         (delete-region (match-beginning 0)
1243                        (progn (forward-line 1) (point)))))
1244     fcc-list))
1245
1246 (defun wl-draft-do-fcc (header-end &optional fcc-list)
1247   (let ((send-mail-buffer (current-buffer))
1248         (tembuf (generate-new-buffer " fcc output"))
1249         (case-fold-search t)
1250         beg end)
1251     (or (markerp header-end) (error "header-end must be a marker"))
1252     (save-excursion
1253       (unless fcc-list
1254         (setq fcc-list (wl-draft-get-fcc-list header-end)))
1255       (set-buffer tembuf)
1256       (erase-buffer)
1257       ;; insert just the headers to avoid moving the gap more than
1258       ;; necessary (the message body could be arbitrarily huge.)
1259       (insert-buffer-substring send-mail-buffer 1 header-end)
1260       (wl-draft-insert-required-fields t)
1261       (goto-char (point-max))
1262       (insert-buffer-substring send-mail-buffer header-end)
1263       (let ((id (std11-field-body "Message-ID"))
1264             (elmo-enable-disconnected-operation t)
1265             cache-saved)
1266         (while fcc-list
1267           (unless (or cache-saved
1268                       (elmo-folder-plugged-p
1269                        (wl-folder-get-elmo-folder (car fcc-list))))
1270             (elmo-file-cache-save id nil) ;; for disconnected operation
1271             (setq cache-saved t))
1272           (if (elmo-folder-append-buffer
1273                (wl-folder-get-elmo-folder
1274                 (eword-decode-string (car fcc-list)))
1275                id)
1276               (wl-draft-write-sendlog 'ok 'fcc nil (car fcc-list) id)
1277             (wl-draft-write-sendlog 'failed 'fcc nil (car fcc-list) id))
1278           (setq fcc-list (cdr fcc-list)))))
1279     (kill-buffer tembuf)))
1280
1281 (defun wl-draft-on-field-p ()
1282   (if (< (point)
1283          (save-excursion
1284            (goto-char (point-min))
1285            (search-forward (concat "\n" mail-header-separator "\n") nil 0)
1286            (point)))
1287       (if (bolp)
1288           (if (bobp)
1289               t
1290             (save-excursion
1291               (forward-line -1)
1292               (if (or (looking-at ".*,[ \t]?$")
1293                       (looking-at "^[^ \t]+:[ \t]+.*:$")); group list name
1294                   nil t)))
1295         (let ((pos (point)))
1296           (save-excursion
1297             (beginning-of-line)
1298             (if (looking-at "^[ \t]")
1299                 nil
1300               (if (re-search-forward ":" pos t) nil t)))))))
1301
1302 (defun wl-draft-random-alphabet ()
1303   (let ((alphabet '(?A ?B ?C ?D ?E ?F ?G ?H ?I ?J ?K ?L ?M ?N ?O ?P ?Q ?R ?S ?T ?U ?V ?W ?X ?Y ?Z)))
1304     (nth (abs (% (random) 26)) alphabet)))
1305
1306 ;;;###autoload
1307 (defun wl-draft (&optional to subject in-reply-to cc references newsgroups
1308                            mail-followup-to
1309                            content-type content-transfer-encoding
1310                            body edit-again summary-buf from)
1311   "Write and send mail/news message with Wanderlust."
1312   (interactive)
1313   (unless (featurep 'wl)
1314     (require 'wl))
1315   (unless wl-init
1316     (wl-load-profile)
1317     (elmo-init)
1318     (wl-folder-init))
1319   (wl-init) ;; returns immediately if already initialized.
1320   (if (interactive-p)
1321       (setq summary-buf (wl-summary-get-buffer (wl-summary-buffer-folder-name))))
1322   (let ((draft-folder (wl-folder-get-elmo-folder wl-draft-folder))
1323         buf-name file-name num wl-demo change-major-mode-hook)
1324     (if (not (elmo-folder-message-file-p draft-folder))
1325         (error "%s folder cannot be used for draft folder" wl-draft-folder))
1326     (setq num (elmo-max-of-list
1327                (or (elmo-folder-list-messages draft-folder) '(0))))
1328     (setq num (+ 1 num))
1329     ;; To get unused buffer name.
1330     (while (get-buffer (concat wl-draft-folder "/" (int-to-string num)))
1331       (setq num (+ 1 num)))
1332     (setq buf-name (find-file-noselect
1333                     (setq file-name
1334                           (elmo-message-file-name
1335                            (wl-folder-get-elmo-folder wl-draft-folder)
1336                            num))))
1337     (if wl-draft-use-frame
1338         (switch-to-buffer-other-frame buf-name)
1339       (switch-to-buffer buf-name))
1340     (set-buffer buf-name)
1341     (if (not (string-match (regexp-quote wl-draft-folder)
1342                            (buffer-name)))
1343         (rename-buffer (concat wl-draft-folder "/" (int-to-string num))))
1344     (if (or (eq wl-draft-reply-buffer-style 'full)
1345             (eq this-command 'wl-draft)
1346             (eq this-command 'wl-summary-write)
1347             (eq this-command 'wl-summary-write-current-folder))
1348         (delete-other-windows))
1349     (auto-save-mode -1)
1350     (wl-draft-mode)
1351     (setq wl-sent-message-via nil)
1352     (if (stringp (or from wl-from))
1353         (insert "From: " (or from wl-from) "\n"))
1354     (and (or (interactive-p)
1355              (eq this-command 'wl-summary-write)
1356              to)
1357          (insert "To: " (or to "") "\n"))
1358     (and cc (insert "Cc: " (or cc "") "\n"))
1359     (insert "Subject: " (or subject "") "\n")
1360     (and newsgroups (insert "Newsgroups: " newsgroups "\n"))
1361     (and mail-followup-to (insert "Mail-Followup-To: " mail-followup-to "\n"))
1362     (and wl-insert-mail-reply-to
1363          (insert "Mail-Reply-To: "
1364                  (wl-address-header-extract-address
1365                   wl-from) "\n"))
1366     (and in-reply-to (insert "In-Reply-To: " in-reply-to "\n"))
1367     (and references (insert "References: " references "\n"))
1368     (insert (funcall wl-generate-mailer-string-function) "\n")
1369     (setq wl-draft-buffer-file-name file-name)
1370     (if mail-default-reply-to
1371         (insert "Reply-To: " mail-default-reply-to "\n"))
1372     (wl-draft-insert-ccs "Bcc: " (or wl-bcc
1373                                (and mail-self-blind (user-login-name))))
1374     (wl-draft-insert-ccs "Fcc: " wl-fcc)
1375     (if wl-organization
1376         (insert "Organization: " wl-organization "\n"))
1377     (and wl-auto-insert-x-face
1378          (file-exists-p wl-x-face-file)
1379          (wl-draft-insert-x-face-field-here))
1380     (if mail-default-headers
1381         (insert mail-default-headers))
1382     (if (not (= (preceding-char) ?\n))
1383         (insert ?\n))
1384     (if edit-again
1385         (let (start)
1386           (setq start (point))
1387           (when content-type
1388             (insert "Content-type: " content-type "\n"))
1389           (when content-transfer-encoding
1390             (insert "Content-Transfer-Encoding: " content-transfer-encoding "\n"))
1391           (if (or content-type content-transfer-encoding)
1392               (insert "\n"))
1393           (and body (insert body))
1394           (save-restriction
1395             (narrow-to-region start (point))
1396             (and edit-again
1397                  (wl-draft-decode-message-in-buffer))
1398             (widen)
1399             (goto-char start)
1400             (put-text-property (point)
1401                                (progn
1402                                  (insert mail-header-separator "\n")
1403                                  (1- (point)))
1404                                'category 'mail-header-separator)))
1405       (put-text-property (point)
1406                          (progn
1407                            (insert mail-header-separator "\n")
1408                            (1- (point)))
1409                          'category 'mail-header-separator)
1410       (and body (insert body)))
1411     (push-mark (point) t t)
1412     (as-binary-output-file
1413      (write-region (point-min)(point-max) wl-draft-buffer-file-name
1414                    nil t))
1415     (wl-draft-editor-mode)
1416     (wl-draft-overload-functions)
1417     (wl-highlight-headers 'for-draft)
1418     (goto-char (point-min))
1419     (setq wl-draft-config-exec-flag t)
1420     (if (interactive-p)
1421         (run-hooks 'wl-mail-setup-hook))
1422     (wl-user-agent-compose-internal) ;; user-agent
1423     (cond ((eq this-command 'wl-summary-write-current-newsgroup)
1424            (mail-position-on-field "Subject"))
1425           ((and (interactive-p) (null to))
1426            (mail-position-on-field "To"))
1427           (t
1428            (goto-char (point-max))))
1429     (setq wl-draft-buffer-cur-summary-buffer (or summary-buf
1430                                                  (get-buffer
1431                                                   wl-summary-buffer-name)))
1432     buf-name))
1433
1434 (defsubst wl-draft-insert-ccs (str cc)
1435   (let ((field
1436          (if (functionp cc)
1437              (funcall cc)
1438            cc)))
1439     (if (and field
1440              (null (and wl-draft-delete-myself-from-bcc-fcc
1441                         (elmo-list-member
1442                          (mapcar 'wl-address-header-extract-address
1443                                  (append
1444                                   (wl-parse-addresses (std11-field-body "To"))
1445                                   (wl-parse-addresses (std11-field-body "Cc"))))
1446                          (mapcar 'downcase wl-subscribed-mailing-list)))))
1447         (insert str field "\n"))))
1448
1449 (defun wl-draft-elmo-nntp-send ()
1450   (let ((elmo-nntp-post-pre-hook wl-news-send-pre-hook)
1451         (elmo-nntp-default-user
1452          (or wl-nntp-posting-user elmo-nntp-default-user))
1453         (elmo-nntp-default-server
1454          (or wl-nntp-posting-server elmo-nntp-default-server))
1455         (elmo-nntp-default-port
1456          (or wl-nntp-posting-port elmo-nntp-default-port))
1457         (elmo-nntp-default-stream-type
1458          (or wl-nntp-posting-stream-type elmo-nntp-default-stream-type)))
1459     (if (not (elmo-plugged-p elmo-nntp-default-server elmo-nntp-default-port))
1460         (wl-draft-set-sent-message 'news 'unplugged
1461                                    (cons elmo-nntp-default-server
1462                                          elmo-nntp-default-port))
1463       (elmo-nntp-post elmo-nntp-default-server (current-buffer))
1464       (wl-draft-set-sent-message 'news 'sent)
1465       (wl-draft-write-sendlog 'ok 'nntp elmo-nntp-default-server
1466                               (std11-field-body "Newsgroups")
1467                               (std11-field-body "Message-ID")))))
1468
1469 (defun wl-draft-generate-clone-buffer (name &optional local-variables)
1470   "generate clone of current buffer named NAME."
1471   (let ((editing-buffer (current-buffer)))
1472     (save-excursion
1473       (set-buffer (generate-new-buffer name))
1474       (erase-buffer)
1475       (wl-draft-mode)
1476       (wl-draft-editor-mode)
1477       (insert-buffer editing-buffer)
1478       (message "")
1479       (while local-variables
1480         (make-local-variable (car local-variables))
1481         (set (car local-variables)
1482              (save-excursion
1483                (set-buffer editing-buffer)
1484                (symbol-value (car local-variables))))
1485         (setq local-variables (cdr local-variables)))
1486       (current-buffer))))
1487
1488 (defun wl-draft-reedit (number)
1489   (let ((draft-folder (wl-folder-get-elmo-folder wl-draft-folder))
1490         (wl-draft-reedit t)
1491         buf-name file-name change-major-mode-hook)
1492     (setq file-name (elmo-message-file-name draft-folder number))
1493     (unless (file-exists-p file-name)
1494       (error "File %s does not exist" file-name))
1495     (setq buf-name (find-file-noselect file-name))
1496     (if wl-draft-use-frame
1497         (switch-to-buffer-other-frame buf-name)
1498       (switch-to-buffer buf-name))
1499     (set-buffer buf-name)
1500     (if (not (string-match (regexp-quote wl-draft-folder)
1501                            (buffer-name)))
1502         (rename-buffer (concat wl-draft-folder "/" (buffer-name))))
1503     (auto-save-mode -1)
1504     (wl-draft-mode)
1505     (setq wl-sent-message-via nil)
1506     (setq wl-draft-buffer-file-name file-name)
1507     (wl-draft-config-info-operation number 'load)
1508     (goto-char (point-min))
1509     (or (re-search-forward "\n\n" nil t)
1510         (search-forward (concat mail-header-separator "\n") nil t))
1511     (push-mark (point) t t)
1512     (write-region (point-min)(point-max) wl-draft-buffer-file-name
1513                   nil t)
1514     (wl-draft-overload-functions)
1515     (wl-draft-editor-mode)
1516     (wl-highlight-headers 'for-draft)
1517     (run-hooks 'wl-draft-reedit-hook)
1518     (goto-char (point-max))
1519     buf-name
1520     ))
1521
1522 (defmacro wl-draft-body-goto-top ()
1523   (` (progn
1524        (goto-char (point-min))
1525        (if (re-search-forward mail-header-separator nil t)
1526            (forward-char 1)
1527          (goto-char (point-max))))))
1528
1529 (defmacro wl-draft-body-goto-bottom ()
1530   (` (goto-char (point-max))))
1531
1532 (defmacro wl-draft-config-body-goto-header ()
1533   (` (progn
1534        (goto-char (point-min))
1535        (if (re-search-forward mail-header-separator nil t)
1536            (beginning-of-line)
1537          (goto-char (point-max))))))
1538
1539 (defun wl-draft-config-sub-body (content)
1540   (wl-draft-body-goto-top)
1541   (delete-region (point) (point-max))
1542   (if content (insert (eval content))))
1543
1544 (defun wl-draft-config-sub-top (content)
1545   (wl-draft-body-goto-top)
1546   (if content (insert (eval content))))
1547
1548 (defun wl-draft-config-sub-bottom (content)
1549   (wl-draft-body-goto-bottom)
1550   (if content (insert (eval content))))
1551
1552 (defun wl-draft-config-sub-header (content)
1553   (wl-draft-config-body-goto-header)
1554   (if content (insert (concat (eval content) "\n"))))
1555
1556 (defsubst wl-draft-config-sub-file (content)
1557   (let ((coding-system-for-read wl-cs-autoconv)
1558         (file (expand-file-name (eval content))))
1559     (if (file-exists-p file)
1560         (insert-file-contents file)
1561       (error "%s: no exists file" file))))
1562
1563 (defun wl-draft-config-sub-body-file (content)
1564   (wl-draft-body-goto-top)
1565   (delete-region (point) (point-max))
1566   (wl-draft-config-sub-file content))
1567
1568 (defun wl-draft-config-sub-top-file (content)
1569   (wl-draft-body-goto-top)
1570   (wl-draft-config-sub-file content))
1571
1572 (defun wl-draft-config-sub-bottom-file (content)
1573   (wl-draft-body-goto-bottom)
1574   (wl-draft-config-sub-file content))
1575
1576 (defun wl-draft-config-sub-header-file (content)
1577   (wl-draft-config-body-goto-header)
1578   (wl-draft-config-sub-file content))
1579
1580 (defun wl-draft-config-sub-template (content)
1581   (setq wl-draft-config-variables
1582         (wl-template-insert (eval content))))
1583
1584 (defun wl-draft-config-sub-x-face (content)
1585   (if (and (string-match "\\.xbm\\(\\.gz\\)?$" content)
1586            (fboundp 'x-face-insert)) ; x-face.el is installed.
1587       (x-face-insert content)
1588     (wl-draft-replace-field "X-Face" (elmo-get-file-string content t) t)))
1589
1590 (defsubst wl-draft-config-sub-func (field content)
1591   (let (func)
1592     (if (setq func (assq field wl-draft-config-sub-func-alist))
1593         (let (wl-draft-config-variables)
1594           (funcall (cdr func) content)
1595           ;; for wl-draft-config-sub-template
1596           (cons t wl-draft-config-variables)))))
1597
1598 (defsubst wl-draft-config-exec-sub (clist)
1599   (let (config local-variables)
1600     (while clist
1601       (setq config (car clist))
1602       (cond
1603        ((consp config)
1604         (let ((field (car config))
1605               (content (cdr config))
1606               ret-val)
1607           (cond
1608            ((stringp field)
1609             (wl-draft-replace-field field (eval content) t))
1610            ((setq ret-val (wl-draft-config-sub-func field content))
1611             (if (cdr ret-val) ;; for wl-draft-config-sub-template
1612                 (wl-append local-variables (cdr ret-val))))
1613            ((boundp field) ;; variable
1614             (make-local-variable field)
1615             (set field (eval content))
1616             (wl-append local-variables (list field)))
1617            (t
1618             (error "%s: not variable" field)))))
1619        ((or (functionp config)
1620             (and (symbolp config)
1621                  (fboundp config)))
1622         (funcall config))
1623        (t
1624         (error "%s: not supported type" config)))
1625       (setq clist (cdr clist)))
1626     local-variables))
1627
1628 (defun wl-draft-prepared-config-exec (&optional config-alist reply-buf)
1629   "Change headers in draft preparation time."
1630   (interactive)
1631   (unless wl-draft-reedit
1632     (let ((config-alist
1633            (or config-alist
1634                (and (boundp 'wl-draft-prepared-config-alist)
1635                     wl-draft-prepared-config-alist)     ;; For compatible.
1636                wl-draft-config-alist)))
1637       (if config-alist
1638           (wl-draft-config-exec config-alist reply-buf)))))
1639
1640 (defun wl-draft-config-exec (&optional config-alist reply-buf)
1641   "Change headers in draft sending time."
1642   (interactive)
1643   (let ((case-fold-search t)
1644         (alist (or config-alist wl-draft-config-alist))
1645         (reply-buf (or reply-buf (and (buffer-live-p wl-draft-reply-buffer)
1646                                       wl-draft-reply-buffer)))
1647         (local-variables wl-draft-config-variables)
1648         key clist found)
1649     (when (and (or (interactive-p)
1650                    wl-draft-config-exec-flag)
1651                alist)
1652       (save-excursion
1653         (catch 'done
1654           (while alist
1655             (setq key (caar alist)
1656                   clist (cdar alist))
1657             (cond
1658              ((eq key 'reply)
1659               (when (and
1660                      reply-buf
1661                      (save-excursion
1662                        (set-buffer reply-buf)
1663                        (save-restriction
1664                          (std11-narrow-to-header)
1665                          (goto-char (point-min))
1666                          (re-search-forward (car clist) nil t))))
1667                 (wl-draft-config-exec-sub (cdr clist))
1668                 (setq found t)))
1669              ((stringp key)
1670               (when (save-restriction
1671                       (std11-narrow-to-header mail-header-separator)
1672                       (goto-char (point-min))
1673                       (re-search-forward key nil t))
1674                 (wl-append local-variables
1675                            (wl-draft-config-exec-sub clist))
1676                 (setq found t)))
1677              ((eval key)
1678               (wl-append local-variables
1679                          (wl-draft-config-exec-sub clist))
1680               (setq found t)))
1681             (if (and found wl-draft-config-matchone)
1682                 (throw 'done t))
1683             (setq alist (cdr alist))))
1684         (if found
1685             (setq wl-draft-config-exec-flag nil))
1686         (run-hooks 'wl-draft-config-exec-hook)
1687         (put-text-property (point-min)(point-max) 'face nil)
1688         (wl-highlight-message (point-min)(point-max) t)
1689         (setq wl-draft-config-variables
1690               (elmo-uniq-list local-variables))))))
1691
1692 (defun wl-draft-replace-field (field content &optional add)
1693   (save-excursion
1694     (save-restriction
1695       (let ((case-fold-search t)
1696             (inhibit-read-only t) ;; added by teranisi.
1697             beg)
1698         (std11-narrow-to-header mail-header-separator)
1699         (goto-char (point-min))
1700         (if (re-search-forward (concat "^" (regexp-quote field) ":") nil t)
1701             (if content
1702                 ;; replace field
1703                 (progn
1704                   (setq beg (point))
1705                   (re-search-forward "^[^ \t]" nil 'move)
1706                   (beginning-of-line)
1707                   (skip-chars-backward "\n")
1708                   (delete-region beg (point))
1709                   (insert " " content))
1710               ;; delete field
1711               (save-excursion
1712                 (beginning-of-line)
1713                 (setq beg (point)))
1714               (re-search-forward "^[^ \t]" nil 'move)
1715               (beginning-of-line)
1716               (delete-region beg (point)))
1717           (when (and add content)
1718             ;; add field
1719             (goto-char (point-max))
1720             (insert (concat field ": " content "\n"))))))))
1721
1722 (defun wl-draft-config-info-operation (msg operation)
1723   (let* ((msgdb-dir (elmo-folder-msgdb-path (wl-folder-get-elmo-folder
1724                                              wl-draft-folder)))
1725          (filename
1726           (expand-file-name
1727            (format "%s-%d" wl-draft-config-save-filename msg)
1728            msgdb-dir))
1729          element alist variable)
1730     (cond
1731      ((eq operation 'save)
1732       (let ((variables (elmo-uniq-list wl-draft-config-variables)))
1733         (while (setq variable (pop variables))
1734           (when (boundp variable)
1735             (wl-append alist
1736                        (list (cons variable (eval variable))))))
1737         (elmo-object-save filename alist)))
1738      ((eq operation 'load)
1739       (setq alist (elmo-object-load filename))
1740       (while (setq element (pop alist))
1741         (set (make-local-variable (car element)) (cdr element))
1742         (wl-append wl-draft-config-variables (list (car element)))))
1743      ((eq operation 'delete)
1744       (if (file-exists-p filename)
1745           (delete-file filename))))))
1746
1747 (defun wl-draft-queue-info-operation (msg operation
1748                                           &optional add-sent-message-via)
1749   (let* ((msgdb-dir (elmo-folder-msgdb-path
1750                      (wl-folder-get-elmo-folder wl-queue-folder)))
1751          (filename
1752           (expand-file-name
1753            (format "%s-%d" wl-draft-queue-save-filename msg)
1754            msgdb-dir))
1755          element alist variable)
1756     (cond
1757      ((eq operation 'save)
1758       (let ((variables (elmo-uniq-list
1759                         (append wl-draft-queue-save-variables
1760                                 wl-draft-config-variables
1761                                 (list 'wl-draft-fcc-list)))))
1762         (if add-sent-message-via
1763             (push 'wl-sent-message-via variables))
1764         (while (setq variable (pop variables))
1765           (when (boundp variable)
1766             (wl-append alist
1767                        (list (cons variable (eval variable))))))
1768         (elmo-object-save filename alist)))
1769      ((eq operation 'load)
1770       (setq alist (elmo-object-load filename))
1771       (while (setq element (pop alist))
1772         (set (make-local-variable (car element)) (cdr element))))
1773      ((eq operation 'get-sent-via)
1774       (setq alist (elmo-object-load filename))
1775       (cdr (assq 'wl-sent-message-via alist)))
1776      ((eq operation 'delete)
1777       (if (file-exists-p filename)
1778           (delete-file filename))))))
1779
1780 (defun wl-draft-queue-append (wl-sent-message-via)
1781   (if wl-draft-verbose-send
1782       (message "Queuing..."))
1783   (let ((send-buffer (current-buffer))
1784         (folder (wl-folder-get-elmo-folder wl-queue-folder))
1785         (message-id (std11-field-body "Message-ID")))
1786     (if (elmo-folder-append-buffer folder t)
1787         (progn
1788           (wl-draft-queue-info-operation
1789            (car (elmo-folder-status folder))
1790            'save wl-sent-message-via)
1791           (wl-draft-write-sendlog 'ok 'queue nil wl-queue-folder message-id)
1792           (when wl-draft-verbose-send
1793             (setq wl-draft-verbose-msg "Queuing...")
1794             (message "Queuing...done")))
1795       (wl-draft-write-sendlog 'failed 'queue nil wl-queue-folder message-id)
1796       (error "Queuing failed"))))
1797
1798 (defun wl-draft-queue-flush ()
1799   "Flush draft queue."
1800   (interactive)
1801   (let* ((queue-folder (wl-folder-get-elmo-folder wl-queue-folder))
1802          (msgs2 (elmo-folder-list-messages queue-folder))
1803          (i 0)
1804          (performed 0)
1805          (wl-draft-queue-flushing t)
1806          msgs failure len buffer msgid sent-via)
1807     ;; get plugged send message
1808     (while msgs2
1809       (setq sent-via (wl-draft-queue-info-operation (car msgs2) 'get-sent-via))
1810       (catch 'found
1811         (while sent-via
1812           (when (and (eq (nth 1 (car sent-via)) 'unplugged)
1813                      (elmo-plugged-p
1814                       (car (nth 2 (car sent-via)))
1815                       (cdr (nth 2 (car sent-via)))))
1816             (wl-append msgs (list (car msgs2)))
1817             (throw 'found t))
1818           (setq sent-via (cdr sent-via))))
1819       (setq msgs2 (cdr msgs2)))
1820     (when (> (setq len (length msgs)) 0)
1821       (if (elmo-y-or-n-p (format
1822                           "%d message(s) are in the sending queue. Send now?"
1823                           len)
1824                          (not elmo-dop-flush-confirm) t)
1825           (progn
1826             (save-excursion
1827               (setq buffer (get-buffer-create " *wl-draft-queue-flush*"))
1828               (set-buffer buffer)
1829               (while msgs
1830                 ;; reset buffer local variables
1831                 (kill-all-local-variables)
1832                 (erase-buffer)
1833                 (setq i (+ 1 i)
1834                       failure nil)
1835                 (setq wl-sent-message-via nil)
1836                 (wl-draft-queue-info-operation (car msgs) 'load)
1837                 (elmo-message-fetch queue-folder
1838                                     (car msgs)
1839                                     (elmo-make-fetch-strategy 'entire)
1840                                     nil (current-buffer))
1841                 (condition-case err
1842                     (setq failure (funcall
1843                                    wl-draft-queue-flush-send-function
1844                                    (format "Sending (%d/%d)..." i len)))
1845 ;;;               (wl-draft-raw-send nil nil
1846 ;;;                                  (format "Sending (%d/%d)..." i len))
1847                   (error
1848                    (elmo-display-error err t)
1849                    (setq failure t))
1850                   (quit
1851                    (setq failure t)))
1852                 (unless failure
1853                   (elmo-folder-delete-messages
1854                    queue-folder (cons (car msgs) nil))
1855                   (wl-draft-queue-info-operation (car msgs) 'delete)
1856                   (setq performed (+ 1 performed)))
1857                 (setq msgs (cdr msgs)))
1858               (kill-buffer buffer)
1859               (message "%d message(s) are sent." performed)))
1860         (message "%d message(s) are remained to be sent." len))
1861       len)))
1862
1863 (defun wl-jump-to-draft-buffer (&optional arg)
1864   "Jump to the draft if exists."
1865   (interactive "P")
1866   (if arg
1867       (wl-jump-to-draft-folder)
1868     (let ((bufs (buffer-list))
1869           (draft-regexp (concat
1870                          "^" (regexp-quote
1871                               (elmo-localdir-folder-directory-internal
1872                                (wl-folder-get-elmo-folder wl-draft-folder)))))
1873           buf draft-bufs)
1874       (while bufs
1875         (if (and
1876              (setq buf (buffer-file-name (car bufs)))
1877              (string-match draft-regexp buf))
1878             (setq draft-bufs (cons (buffer-name (car bufs)) draft-bufs)))
1879         (setq bufs (cdr bufs)))
1880       (cond
1881        ((null draft-bufs)
1882         (message "No draft buffer exist."))
1883        (t
1884         (setq draft-bufs
1885               (sort draft-bufs (function (lambda (a b) (not (string< a b))))))
1886         (if (setq buf (cdr (member (buffer-name) draft-bufs)))
1887             (setq buf (car buf))
1888           (setq buf (car draft-bufs)))
1889         (switch-to-buffer buf))))))
1890
1891 (defun wl-jump-to-draft-folder ()
1892   (let ((msgs (reverse (elmo-folder-list-messages (wl-folder-get-elmo-folder
1893                                                    wl-draft-folder))))
1894         (mybuf (buffer-name))
1895         msg buf)
1896     (if (not msgs)
1897         (message "No draft message exist.")
1898       (if (string-match (concat "^" wl-draft-folder "/") mybuf)
1899           (setq msg (cadr (memq
1900                            (string-to-int (substring mybuf (match-end 0)))
1901                            msgs))))
1902       (or msg (setq msg (car msgs)))
1903       (if (setq buf (get-buffer (format "%s/%d" wl-draft-folder msg)))
1904           (switch-to-buffer buf)
1905         (wl-draft-reedit msg)))))
1906
1907 (defun wl-draft-highlight-and-recenter (&optional n)
1908   (interactive "P")
1909   (if wl-highlight-body-too
1910       (let ((beg (point-min))
1911             (end (point-max)))
1912         (put-text-property beg end 'face nil)
1913         (wl-highlight-message beg end t)))
1914   (recenter n))
1915
1916 ;;;; user-agent support by Sen Nagata
1917
1918 ;; this appears to be necessarily global...
1919 (defvar wl-user-agent-compose-p nil)
1920 (defvar wl-user-agent-headers-and-body-alist nil)
1921
1922 ;; this should be a generic function for mail-mode -- i wish there was
1923 ;; something like it in sendmail.el
1924 (defun wl-user-agent-insert-header (header-name header-value)
1925   "Insert HEADER-NAME w/ value HEADER-VALUE into a message."
1926   ;; it seems like overriding existing headers is acceptable -- should
1927   ;; we provide an option?
1928
1929   ;; plan was: unfold header (might be folded), remove existing value, insert
1930   ;;           new value
1931   ;; wl doesn't seem to fold header lines yet anyway :-)
1932
1933   (let ((kill-whole-line t)
1934         end-of-line)
1935     (mail-position-on-field (capitalize header-name))
1936     (setq end-of-line (point))
1937     (beginning-of-line)
1938     (re-search-forward ":" end-of-line)
1939     (insert (concat " " header-value "\n"))
1940     (kill-line)))
1941
1942 ;; this should be a generic function for mail-mode -- i wish there was
1943 ;; something like it in sendmail.el
1944 ;;
1945 ;; ** haven't dealt w/ case where the body is already set **
1946 (defun wl-user-agent-insert-body (body-text)
1947   "Insert a body of text, BODY-TEXT, into a message."
1948   ;; code defensively... :-P
1949   (goto-char (point-min))
1950   (search-forward mail-header-separator)
1951   (forward-line 1)
1952   (insert body-text))
1953
1954 ;;;###autoload
1955 (defun wl-user-agent-compose (&optional to subject other-headers continue
1956                                         switch-function yank-action
1957                                         send-actions)
1958   "Support the `compose-mail' interface for wl.
1959 Only support for TO, SUBJECT, and OTHER-HEADERS has been implemented.
1960 Support for CONTINUE, YANK-ACTION, and SEND-ACTIONS has not
1961 been implemented yet.  Partial support for SWITCH-FUNCTION now supported."
1962
1963   (unless (featurep 'wl)
1964     (require 'wl))
1965   ;; protect these -- to and subject get bound at some point, so it looks
1966   ;; to be necessary to protect the values used w/in
1967   (let ((wl-user-agent-headers-and-body-alist other-headers)
1968         (wl-draft-use-frame (eq switch-function 'switch-to-buffer-other-frame))
1969         (wl-draft-reply-buffer-style 'split))
1970     (when (eq switch-function 'switch-to-buffer-other-window)
1971       (when (one-window-p t)
1972         (if (window-minibuffer-p) (other-window 1))
1973         (split-window))
1974       (other-window 1))
1975     (if to
1976         (if (wl-string-match-assoc "to" wl-user-agent-headers-and-body-alist
1977                                    'ignore-case)
1978             (setcdr
1979              (wl-string-match-assoc "to" wl-user-agent-headers-and-body-alist
1980                                     'ignore-case)
1981              to)
1982           (setq wl-user-agent-headers-and-body-alist
1983                 (cons (cons "to" to)
1984                       wl-user-agent-headers-and-body-alist))))
1985     (if subject
1986         (if (wl-string-match-assoc "subject"
1987                                    wl-user-agent-headers-and-body-alist
1988                                    'ignore-case)
1989             (setcdr
1990              (wl-string-match-assoc "subject"
1991                                     wl-user-agent-headers-and-body-alist
1992                                     'ignore-case)
1993              subject)
1994           (setq wl-user-agent-headers-and-body-alist
1995                 (cons (cons "subject" subject)
1996                       wl-user-agent-headers-and-body-alist))))
1997     ;; i think this is what we want to use...
1998     (unwind-protect
1999         (progn
2000           ;; tell the hook-function to do its stuff
2001           (setq wl-user-agent-compose-p t)
2002           ;; because to get the hooks working, wl-draft has to think it has
2003           ;; been called interactively
2004           (call-interactively 'wl-draft))
2005       (setq wl-user-agent-compose-p nil))))
2006
2007 (defun wl-user-agent-compose-internal ()
2008   "Manipulate headers and/or a body of a draft message."
2009   ;; being called from wl-user-agent-compose?
2010   (if wl-user-agent-compose-p
2011       (progn
2012         ;; insert headers
2013         (let ((headers wl-user-agent-headers-and-body-alist)
2014               (case-fold-search t))
2015           (while headers
2016             ;; skip body
2017             (if (not (string-match "^body$" (car (car headers))))
2018                 (wl-user-agent-insert-header
2019                  (car (car headers)) (cdr (car headers)))
2020               t)
2021             (setq headers (cdr headers))))
2022         ;; highlight headers (from wl-draft in wl-draft.el)
2023         (wl-highlight-headers 'for-draft)
2024         ;; insert body
2025         (if (wl-string-match-assoc "body" wl-user-agent-headers-and-body-alist
2026                                    'ignore-case)
2027             (wl-user-agent-insert-body
2028              (cdr (wl-string-match-assoc
2029                    "body"
2030                    wl-user-agent-headers-and-body-alist 'ignore-case)))))
2031     t))
2032
2033 (require 'product)
2034 (product-provide (provide 'wl-draft) (require 'wl-version))
2035
2036 ;;; wl-draft.el ends here