wl/wl-draft.el

   1 ;;; wl-draft.el --- Message draft mode for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1998,1999,2000 Masahiro MURATA <muse@ba2.so-net.ne.jp>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;;      Masahiro MURATA <muse@ba2.so-net.ne.jp>
   8 ;; Keywords: mail, net news
   9
  10 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  11
  12 ;; This program is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16 ;;
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21 ;;
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 ;;
  27
  28 ;;; Commentary:
  29 ;;
  30
  31 ;;; Code:
  32 ;;
  33
  34 (require 'sendmail)
  35 (require 'wl-template)
  36 (require 'emu)
  37 (condition-case nil (require 'timezone) (error nil))
  38 (require 'std11)
  39 (require 'wl-vars)
  40
  41 (defvar x-face-add-x-face-version-header)
  42 (defvar mail-reply-buffer)
  43 (defvar mail-from-style)
  44
  45 (eval-when-compile
  46   (require 'static)
  47   (require 'elmo-pop3)
  48   (defalias-maybe 'x-face-insert 'ignore)
  49   (defalias-maybe 'x-face-insert-version-header 'ignore)
  50   (defalias-maybe 'wl-init 'ignore)
  51   (defalias-maybe 'wl-draft-mode 'ignore))
  52
  53 (eval-and-compile
  54   (autoload 'wl-addrmgr "wl-addrmgr"))
  55
  56 (autoload 'open-ssl-stream "ssl")
  57
  58 (defvar wl-draft-buffer-message-number nil)
  59 (defvar wl-draft-field-completion-list nil)
  60 (defvar wl-draft-verbose-send t)
  61 (defvar wl-draft-verbose-msg nil)
  62 (defvar wl-draft-queue-flushing nil)
  63 (defvar wl-draft-config-variables nil)
  64 (defvar wl-draft-config-exec-flag t)
  65 (defvar wl-draft-buffer-cur-summary-buffer nil)
  66 (defvar wl-draft-clone-local-variable-regexp "^\\(wl\\|mime\\)")
  67 (defvar wl-draft-sendlog-filename "sendlog")
  68 (defvar wl-draft-queue-save-filename "qinfo")
  69 (defvar wl-draft-config-save-filename "config")
  70 (defvar wl-draft-queue-flush-send-function 'wl-draft-dispatch-message)
  71 (defvar wl-sent-message-via nil)
  72 (defvar wl-sent-message-modified nil)
  73 (defvar wl-sent-message-queued nil)
  74 (defvar wl-draft-fcc-list nil)
  75 (defvar wl-draft-reedit nil)
  76 (defvar wl-draft-reply-buffer nil)
  77 (defvar wl-draft-forward nil)
  78 (defvar wl-draft-doing-mime-bcc nil)
  79
  80 (defvar wl-draft-parent-folder nil
  81   "Folder name of the summary in which current draft is invoked.
  82 This variable is local in each draft buffer.
  83 You can refer its value in `wl-draft-config-alist'.
  84
  85 e.g.
  86 \(setq wl-draft-config-alist
  87       '(((string-match \".*@domain1$\" wl-draft-parent-folder)
  88          (\"From\" . \"user@domain1\"))
  89         ((string-match \".*@domain2$\" wl-draft-parent-folder)
  90          (\"From\" . \"user@domain2\"))))")
  91
  92 (defvar wl-draft-parent-number nil)
  93
  94 (defconst wl-draft-reply-saved-variables
  95   '(wl-draft-parent-folder
  96     wl-draft-parent-number))
  97
  98 (defvar wl-draft-config-sub-func-alist
  99   '((body               . wl-draft-config-sub-body)
 100     (top                . wl-draft-config-sub-top)
 101     (bottom             . wl-draft-config-sub-bottom)
 102     (header             . wl-draft-config-sub-header)
 103     (header-top         . wl-draft-config-sub-header-top)
 104     (header-bottom      . wl-draft-config-sub-header)
 105     (part-top           . wl-draft-config-sub-part-top)
 106     (part-bottom        . wl-draft-config-sub-part-bottom)
 107     (body-file          . wl-draft-config-sub-body-file)
 108     (top-file           . wl-draft-config-sub-top-file)
 109     (bottom-file        . wl-draft-config-sub-bottom-file)
 110     (header-file        . wl-draft-config-sub-header-file)
 111     (template           . wl-draft-config-sub-template)
 112     (x-face             . wl-draft-config-sub-x-face)))
 113
 114 (make-variable-buffer-local 'wl-draft-buffer-message-number)
 115 (make-variable-buffer-local 'wl-draft-buffer-cur-summary-buffer)
 116 (make-variable-buffer-local 'wl-draft-config-variables)
 117 (make-variable-buffer-local 'wl-draft-config-exec-flag)
 118 (make-variable-buffer-local 'wl-sent-message-via)
 119 (make-variable-buffer-local 'wl-sent-message-queued)
 120 (make-variable-buffer-local 'wl-draft-fcc-list)
 121 (make-variable-buffer-local 'wl-draft-reply-buffer)
 122 (make-variable-buffer-local 'wl-draft-parent-folder)
 123 (make-variable-buffer-local 'wl-draft-parent-number)
 124
 125 (defvar wl-draft-folder-internal nil
 126   "Internal variable for caching `opened' draft folder.")
 127
 128 (defsubst wl-smtp-password-key (user mechanism server)
 129   (format "SMTP:%s/%s@%s"
 130           user mechanism server))
 131
 132 (defmacro wl-smtp-extension-bind (&rest body)
 133   (` (let* ((smtp-sasl-mechanisms
 134              (if wl-smtp-authenticate-type
 135                  (mapcar 'upcase
 136                          (if (listp wl-smtp-authenticate-type)
 137                              wl-smtp-authenticate-type
 138                            (list wl-smtp-authenticate-type)))))
 139             (smtp-use-sasl (and smtp-sasl-mechanisms t))
 140             (smtp-use-starttls (eq wl-smtp-connection-type 'starttls))
 141             (smtp-open-connection-function
 142              (if (eq wl-smtp-connection-type 'ssl)
 143                  #'open-ssl-stream
 144                smtp-open-connection-function))
 145             (smtp-end-of-line
 146              (if (eq wl-smtp-connection-type 'ssl)
 147                  "\n"
 148                smtp-end-of-line))
 149             smtp-sasl-user-name smtp-sasl-properties sasl-read-passphrase)
 150        (if (and (string= (car smtp-sasl-mechanisms) "DIGEST-MD5")
 151                 ;; sendmail bug?
 152                 (string-match "^\\([^@]*\\)@\\([^@]*\\)"
 153                               wl-smtp-posting-user))
 154            (setq smtp-sasl-user-name (match-string 1 wl-smtp-posting-user)
 155                  smtp-sasl-properties (list 'realm
 156                                             (match-string 2 wl-smtp-posting-user)))
 157          (setq smtp-sasl-user-name wl-smtp-posting-user
 158                smtp-sasl-properties nil))
 159        (setq sasl-read-passphrase
 160              (function
 161               (lambda (prompt)
 162                 (elmo-get-passwd
 163                  (wl-smtp-password-key
 164                   smtp-sasl-user-name
 165                   (car smtp-sasl-mechanisms)
 166                   smtp-server)))))
 167        (,@ body))))
 168
 169 (defun wl-draft-insert-date-field ()
 170   "Insert Date field."
 171   (insert "Date: " (wl-make-date-string) "\n"))
 172
 173 (defun wl-draft-insert-from-field ()
 174   "Insert From field."
 175   ;; Put the "From:" field in unless for some odd reason
 176   ;; they put one in themselves.
 177   (let (from)
 178     (condition-case err
 179         (setq from (wl-draft-eword-encode-address-list wl-from))
 180       (error (error "Please look at `wl-from' again")))
 181     (insert "From: " from "\n")))
 182
 183 (defun wl-draft-insert-x-face-field ()
 184   "Insert X-Face header."
 185   (interactive)
 186   (if (not (file-exists-p wl-x-face-file))
 187       (error "File %s does not exist" wl-x-face-file)
 188     (goto-char (point-min))
 189     (search-forward mail-header-separator nil t)
 190     (beginning-of-line)
 191     (wl-draft-insert-x-face-field-here)
 192     (run-hooks 'wl-draft-insert-x-face-field-hook))) ; highlight it if you want.
 193
 194 (defun wl-draft-insert-x-face-field-here ()
 195   "Insert X-Face field at point."
 196   (let ((x-face-string (elmo-get-file-string wl-x-face-file)))
 197     (when (string-match "^\\(X-Face:\\)?[ \t\n]*" x-face-string)
 198       (setq x-face-string (substring x-face-string (match-end 0))))
 199     (insert "X-Face: " x-face-string))
 200   (when (not (= (preceding-char) ?\n))  ; for chomped (choped) x-face-string
 201     (insert ?\n))
 202   ;; Insert X-Face-Version: field
 203   (when (and (fboundp 'x-face-insert-version-header)
 204              (boundp 'x-face-add-x-face-version-header)
 205              x-face-add-x-face-version-header)
 206     (x-face-insert-version-header)))
 207
 208 (defun wl-draft-setup ()
 209   (let ((field wl-draft-fields)
 210         cl)
 211     (while field
 212       (setq cl (append cl
 213                        (list (cons (concat (car field) " ")
 214                                    (concat (car field) " ")))))
 215       (setq field (cdr field)))
 216     (setq cl
 217           (cons (cons (concat wl-draft-mime-bcc-field-name  ": ")
 218                       (concat wl-draft-mime-bcc-field-name  ": "))
 219                 cl))
 220     (setq wl-draft-field-completion-list cl)
 221     (setq wl-address-complete-header-regexp
 222           (wl-regexp-opt
 223            (append wl-address-complete-header-list
 224                    (list (concat wl-draft-mime-bcc-field-name  ":")))))))
 225
 226 (defun wl-draft-make-mail-followup-to (recipients)
 227   (if (elmo-list-member
 228        (or wl-user-mail-address-list
 229            (list (wl-address-header-extract-address wl-from)))
 230        recipients)
 231       (let ((rlist (elmo-list-delete
 232                     (or wl-user-mail-address-list
 233                         (list (wl-address-header-extract-address wl-from)))
 234                     recipients
 235                     (lambda (elem list)
 236                       (elmo-delete-if
 237                        (lambda (item) (string= (downcase elem)
 238                                                (downcase item)))
 239                        list)))))
 240         (if (elmo-list-member rlist (mapcar 'downcase
 241                                             wl-subscribed-mailing-list))
 242             rlist
 243           (append rlist (list (wl-address-header-extract-address
 244                                wl-from)))))
 245     recipients))
 246
 247 (defun wl-draft-delete-myself-from-cc (to cc)
 248   (let ((myself (or wl-user-mail-address-list
 249                     (list (wl-address-header-extract-address wl-from)))))
 250     (cond (wl-draft-always-delete-myself ; always-delete option
 251            (elmo-list-delete myself cc
 252                              (lambda (elem list)
 253                                (elmo-delete-if
 254                                 (lambda (item) (string= (downcase elem)
 255                                                         (downcase item)))
 256                                 list))))
 257           ((elmo-list-member (append to cc) ; subscribed mailing-list
 258                              (mapcar 'downcase wl-subscribed-mailing-list))
 259            (elmo-list-delete myself cc
 260                              (lambda (elem list)
 261                                (elmo-delete-if
 262                                 (lambda (item) (string= (downcase elem)
 263                                                         (downcase item)))
 264                                 list))))
 265           (t cc))))
 266
 267 (defun wl-draft-forward (original-subject summary-buf)
 268   (let (references parent-folder)
 269     (with-current-buffer summary-buf
 270       (setq parent-folder (wl-summary-buffer-folder-name)))
 271     (with-current-buffer (wl-message-get-original-buffer)
 272       (setq references (nconc
 273                         (std11-field-bodies '("References" "In-Reply-To"))
 274                         (list (std11-field-body "Message-Id"))))
 275       (setq references (delq nil references)
 276             references (mapconcat 'identity references " ")
 277             references (wl-draft-parse-msg-id-list-string references)
 278             references (wl-delete-duplicates references)
 279             references (when references
 280                          (mapconcat 'identity references "\n\t"))))
 281     (and wl-draft-use-frame
 282          (get-buffer-window summary-buf)
 283          (select-window (get-buffer-window summary-buf)))
 284     (wl-draft (list (cons 'To "")
 285                     (cons 'Subject
 286                           (concat wl-forward-subject-prefix original-subject))
 287                     (cons 'References references))
 288               nil nil nil nil parent-folder))
 289   (goto-char (point-max))
 290   (wl-draft-insert-message)
 291   (mail-position-on-field "To"))
 292
 293 (defun wl-draft-strip-subject-re (subject)
 294   "Remove \"Re:\" from SUBJECT string. Shamelessly copied from Gnus."
 295   (if (string-match wl-subject-prefix-regexp subject)
 296       (substring subject (match-end 0))
 297     subject))
 298
 299 (defun wl-draft-self-reply-p ()
 300   "Return t when From address in the current message is user's self one or not."
 301   (wl-address-user-mail-address-p (or (elmo-field-body "From") "")))
 302
 303 (defun wl-draft-reply (buf with-arg summary-buf &optional number)
 304   "Reply to BUF buffer message.
 305 Reply to author if WITH-ARG is non-nil."
 306 ;;;(save-excursion
 307   (let (r-list
 308         to mail-followup-to cc subject in-reply-to references newsgroups
 309         to-alist cc-alist decoder parent-folder)
 310     (when (buffer-live-p summary-buf)
 311       (with-current-buffer summary-buf
 312         (setq parent-folder (wl-summary-buffer-folder-name))))
 313     (set-buffer (or buf mime-mother-buffer))
 314     (setq r-list (if with-arg wl-draft-reply-with-argument-list
 315                    wl-draft-reply-without-argument-list))
 316     (catch 'done
 317       (while r-list
 318         (when (let ((condition (car (car r-list))))
 319                 (cond ((stringp condition)
 320                        (std11-field-body condition))
 321                       ((listp condition)
 322                        (catch 'done
 323                          (while condition
 324                            (cond
 325                             ((stringp (car condition))
 326                              (or (std11-field-body (car condition))
 327                                  (throw 'done nil)))
 328                             ((symbolp (car condition))
 329                              (or (funcall (car condition))
 330                                  (throw 'done nil)))
 331                             (t
 332                              (debug)))
 333                            (setq condition (cdr condition)))
 334                          t))
 335                       ((symbolp condition)
 336                        (funcall condition))))
 337           (let ((r-to-list (nth 0 (cdr (car r-list))))
 338                 (r-cc-list (nth 1 (cdr (car r-list))))
 339                 (r-ng-list (nth 2 (cdr (car r-list)))))
 340             (when (and (member "Followup-To" r-ng-list)
 341                        (string= (std11-field-body "Followup-To") "poster"))
 342               (setq r-to-list (cons "From" r-to-list))
 343               (setq r-ng-list (delete "Followup-To"
 344                                       (copy-sequence r-ng-list))))
 345             (if (and r-to-list (symbolp r-to-list))
 346                 (setq to (wl-concat-list (funcall r-to-list) ","))
 347               (setq to (wl-concat-list (cons to
 348                                              (elmo-multiple-fields-body-list
 349                                               r-to-list))
 350                                        ",")))
 351             (if (and r-cc-list (symbolp r-cc-list))
 352                 (setq cc (wl-concat-list (funcall r-cc-list) ","))
 353               (setq cc (wl-concat-list (cons cc
 354                                              (elmo-multiple-fields-body-list
 355                                               r-cc-list))
 356                                        ",")))
 357             (if (and r-ng-list (symbolp r-ng-list))
 358                 (setq newsgroups (wl-concat-list (funcall r-ng-list) ","))
 359               (setq newsgroups (wl-concat-list (cons newsgroups
 360                                                      (std11-field-bodies
 361                                                       r-ng-list))
 362                                                ","))))
 363           (throw 'done nil))
 364         (setq r-list (cdr r-list)))
 365       (error "No match field: check your `wl-draft-reply-%s-argument-list'"
 366              (if with-arg "with" "without")))
 367     (setq subject (std11-field-body "Subject"))
 368     (setq to (wl-parse-addresses to)
 369           cc (wl-parse-addresses cc))
 370     (with-temp-buffer                   ; to keep raw buffer unibyte.
 371       (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 372       (setq decoder (mime-find-field-decoder 'Subject 'plain))
 373       (setq subject (if (and subject decoder)
 374                         (funcall decoder subject) subject))
 375       (setq to-alist
 376             (mapcar
 377              (lambda (addr)
 378                (setq decoder (mime-find-field-decoder 'To 'plain))
 379                (cons (nth 1 (std11-extract-address-components addr))
 380                      (if decoder (funcall decoder addr) addr)))
 381              to))
 382       (setq cc-alist
 383             (mapcar
 384              (lambda (addr)
 385                (setq decoder (mime-find-field-decoder 'Cc 'plain))
 386                (cons (nth 1 (std11-extract-address-components addr))
 387                      (if decoder (funcall decoder addr) addr)))
 388              cc)))
 389     (and wl-reply-subject-prefix
 390          (setq subject (concat wl-reply-subject-prefix
 391                                (wl-draft-strip-subject-re
 392                                 (or subject "")))))
 393     (setq in-reply-to (std11-field-body "Message-Id"))
 394     (setq references (nconc
 395                       (std11-field-bodies '("References" "In-Reply-To"))
 396                       (list in-reply-to)))
 397     (setq to (delq nil (mapcar 'car to-alist)))
 398     (setq cc (delq nil (mapcar 'car cc-alist)))
 399     ;; if subscribed mailing list is contained in cc or to
 400     ;; and myself is contained in cc,
 401     ;; delete myself from cc.
 402     (setq cc (wl-draft-delete-myself-from-cc to cc))
 403     (when wl-insert-mail-followup-to
 404       (setq mail-followup-to
 405             (wl-draft-make-mail-followup-to (append to cc)))
 406       (setq mail-followup-to (wl-delete-duplicates mail-followup-to nil t)))
 407     (with-temp-buffer                   ; to keep raw buffer unibyte.
 408       (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 409       (setq newsgroups (wl-parse newsgroups
 410                                  "[ \t\f\r\n,]*\\([^ \t\f\r\n,]+\\)")
 411             newsgroups (wl-delete-duplicates newsgroups)
 412             newsgroups
 413             (if newsgroups
 414                 (mapconcat
 415                  (lambda (grp)
 416                    (setq decoder (mime-find-field-decoder 'Newsgroups 'plain))
 417                    (if decoder (funcall decoder grp) grp))
 418                  newsgroups ","))))
 419     (setq to (wl-delete-duplicates to nil t))
 420     (setq cc (wl-delete-duplicates
 421               (append (wl-delete-duplicates cc nil t)
 422                       to (copy-sequence to))
 423               t t))
 424     (and to (setq to (mapconcat
 425                       '(lambda (addr)
 426                          (if wl-draft-reply-use-address-with-full-name
 427                              (or (cdr (assoc addr to-alist)) addr)
 428                            addr))
 429                       to ",\n\t")))
 430     (and cc (setq cc (mapconcat
 431                       '(lambda (addr)
 432                          (if wl-draft-reply-use-address-with-full-name
 433                              (or (cdr (assoc addr cc-alist)) addr)
 434                            addr))
 435                       cc ",\n\t")))
 436     (and mail-followup-to
 437          (setq mail-followup-to
 438                (mapconcat
 439                 '(lambda (addr)
 440                    (if wl-draft-reply-use-address-with-full-name
 441                        (or (cdr (assoc addr (append to-alist cc-alist))) addr)
 442                      addr))
 443                 mail-followup-to ",\n\t")))
 444     (and (null to) (setq to cc cc nil))
 445     (setq references (delq nil references)
 446           references (mapconcat 'identity references " ")
 447           references (wl-draft-parse-msg-id-list-string references)
 448           references (wl-delete-duplicates references)
 449           references (if references
 450                          (mapconcat 'identity references "\n\t")))
 451     (and wl-draft-use-frame
 452          (get-buffer-window summary-buf)
 453          (select-window (get-buffer-window summary-buf)))
 454     (wl-draft (list (cons 'To to)
 455                     (cons 'Cc cc)
 456                     (cons 'Newsgroups newsgroups)
 457                     (cons 'Subject subject)
 458                     (cons 'In-Reply-To in-reply-to)
 459                     (cons 'References references)
 460                     (cons 'Mail-Followup-To mail-followup-to))
 461               nil nil nil nil parent-folder)
 462     (setq wl-draft-parent-number number)
 463     (setq wl-draft-reply-buffer buf)
 464     (setq wl-draft-config-variables
 465           (append wl-draft-reply-saved-variables
 466                   wl-draft-config-variables)))
 467   (run-hooks 'wl-reply-hook))
 468
 469 (defun wl-draft-reply-position (position)
 470   (cond ((eq position 'body)
 471          (wl-draft-body-goto-top))
 472         ((eq position 'bottom)
 473          (wl-draft-body-goto-bottom))
 474         ((eq position 'top)
 475          (goto-char (point-min)))
 476         ((and (stringp position)
 477               (std11-field-body position))
 478          (progn (mail-position-on-field position)
 479                 (wl-draft-beginning-of-line)))
 480         ((listp position)
 481          (while (car position)
 482            (wl-draft-reply-position (car position))
 483            (setq position (cdr position))))))
 484
 485 (defun wl-draft-add-references ()
 486   (wl-draft-add-in-reply-to "References"))
 487
 488 (defun wl-draft-add-in-reply-to (&optional alt-field)
 489   (let* ((mes-id (save-excursion
 490                    (set-buffer mail-reply-buffer)
 491                    (std11-field-body "message-id")))
 492          (field (or alt-field "In-Reply-To"))
 493          (ref (std11-field-body field))
 494          (ref-list nil) (st nil))
 495     (when (and mes-id ref)
 496       (while (string-match "<[^>]+>" ref st)
 497         (setq ref-list
 498               (cons (substring ref (match-beginning 0) (setq st (match-end 0)))
 499                     ref-list)))
 500       (when (and ref-list
 501                  (member mes-id ref-list))
 502         (setq mes-id nil)))
 503     (when mes-id
 504       (save-excursion
 505         (when (mail-position-on-field field)
 506           (forward-line)
 507           (while (looking-at "^[ \t]")
 508             (forward-line))
 509           (setq mes-id (concat "\t" mes-id "\n")))
 510         (insert mes-id))
 511       t)))
 512
 513 (defun wl-draft-yank-from-mail-reply-buffer (decode-it
 514                                              &optional ignored-fields)
 515   (interactive)
 516   (save-restriction
 517     (narrow-to-region (point)(point))
 518     (insert
 519      (with-current-buffer mail-reply-buffer
 520        (when decode-it
 521          (decode-mime-charset-region (point-min) (point-max)
 522                                      wl-mime-charset))
 523        (buffer-substring-no-properties
 524         (point-min) (point-max))))
 525     (when ignored-fields
 526       (goto-char (point-min))
 527       (wl-draft-delete-fields ignored-fields))
 528     (goto-char (point-max))
 529     (push-mark (point) nil t)
 530     (goto-char (point-min)))
 531   (let ((beg (point)))
 532     (cond (mail-citation-hook (run-hooks 'mail-citation-hook))
 533           (mail-yank-hooks (run-hooks 'mail-yank-hooks))
 534           (wl-draft-cite-function (funcall wl-draft-cite-function))) ; default cite
 535     (run-hooks 'wl-draft-cited-hook)
 536     (when (if wl-draft-add-references
 537               (wl-draft-add-references)
 538             (if wl-draft-add-in-reply-to
 539                 (wl-draft-add-in-reply-to)))
 540       (wl-highlight-headers 'for-draft)) ; highlight when added References:
 541     (when wl-highlight-body-too
 542       (wl-highlight-body-region beg (point-max)))))
 543
 544 (defun wl-message-news-p ()
 545   "If exist valid Newsgroups field, return non-nil."
 546   (std11-field-body "Newsgroups"))
 547
 548 (defun wl-message-field-exists-p (field)
 549   "If FIELD exist and FIELD value is not empty, return non-nil."
 550   (let ((value (std11-field-body field)))
 551     (and value
 552          (not (string= value "")))))
 553
 554 (defun wl-message-mail-p ()
 555   "If exist To, Cc or Bcc field, return non-nil."
 556   (or (wl-message-field-exists-p "To")
 557       (wl-message-field-exists-p "Resent-to")
 558       (wl-message-field-exists-p "Cc")
 559       (wl-message-field-exists-p "Bcc")
 560       (wl-message-field-exists-p wl-draft-mime-bcc-field-name)
 561 ;;; This may be needed..
 562 ;;;   (wl-message-field-exists-p "Fcc")
 563       ))
 564
 565 (defun wl-draft-edit-string (string)
 566   (let ((cur-buf (current-buffer))
 567         (tmp-buf (get-buffer-create " *wl-draft-edit-string*"))
 568         to subject in-reply-to cc references newsgroups mail-followup-to
 569         content-type content-transfer-encoding from
 570         body-beg)
 571     (set-buffer tmp-buf)
 572     (erase-buffer)
 573     (insert string)
 574     (setq to (std11-field-body "To"))
 575     (setq to (and to
 576                   (eword-decode-string
 577                    (decode-mime-charset-string
 578                     to
 579                     wl-mime-charset))))
 580     (setq subject (std11-field-body "Subject"))
 581     (setq subject (and subject
 582                        (eword-decode-string
 583                         (decode-mime-charset-string
 584                          subject
 585                          wl-mime-charset))))
 586     (setq from (std11-field-body "From")
 587           from (and from
 588                     (eword-decode-string
 589                      (decode-mime-charset-string
 590                       from
 591                       wl-mime-charset))))
 592     (setq in-reply-to (std11-field-body "In-Reply-To"))
 593     (setq cc (std11-field-body "Cc"))
 594     (setq cc (and cc
 595                   (eword-decode-string
 596                    (decode-mime-charset-string
 597                     cc
 598                     wl-mime-charset))))
 599     (setq references (std11-field-body "References"))
 600     (setq newsgroups (std11-field-body "Newsgroups"))
 601     (setq mail-followup-to (std11-field-body "Mail-Followup-To"))
 602     (setq content-type (std11-field-body "Content-Type"))
 603     (setq content-transfer-encoding (std11-field-body "Content-Transfer-Encoding"))
 604     (goto-char (point-min))
 605     (or (re-search-forward "\n\n" nil t)
 606         (search-forward (concat mail-header-separator "\n") nil t))
 607     (unwind-protect
 608         (set-buffer
 609          (wl-draft (list
 610                     (cons 'From
 611                           (if (member
 612                                (nth 1 (std11-extract-address-components from))
 613                                wl-user-mail-address-list)
 614                               from))
 615                     (cons 'To to)
 616                     (cons 'Cc cc)
 617                     (cons 'Subject subject)
 618                     (cons 'Newsgroups newsgroups)
 619                     (cons 'Mail-Followup-To mail-followup-to)
 620                     (cons 'In-Reply-To in-reply-to)
 621                     (cons 'References references))
 622                    content-type content-transfer-encoding
 623                    (buffer-substring (point) (point-max))
 624                    'edit-again))
 625       (kill-buffer tmp-buf))
 626     ;; Set cursor point to the top.
 627     (goto-char (point-min))
 628     (search-forward (concat mail-header-separator "\n") nil t)
 629     (run-hooks 'wl-draft-reedit-hook)
 630     (and to (mail-position-on-field "To"))))
 631
 632 (defun wl-draft-insert-current-message (dummy)
 633   (interactive)
 634   (let (original-buffer
 635         mail-reply-buffer
 636         mail-citation-hook mail-yank-hooks
 637         wl-draft-add-references wl-draft-add-in-reply-to
 638         wl-draft-cite-function)
 639     (with-current-buffer wl-draft-buffer-cur-summary-buffer
 640       (with-current-buffer wl-message-buffer
 641         (setq original-buffer (wl-message-get-original-buffer))
 642         (if (zerop
 643              (with-current-buffer original-buffer
 644                (buffer-size)))
 645             (error "No current message"))))
 646     (setq mail-reply-buffer original-buffer)
 647     (wl-draft-yank-from-mail-reply-buffer
 648      nil
 649      wl-ignored-forwarded-headers)))
 650
 651 (defun wl-draft-insert-get-message (dummy)
 652   (let ((fld (completing-read
 653               "Folder name: "
 654               (if (memq 'read-folder wl-use-folder-petname)
 655                   (wl-folder-get-entity-with-petname)
 656                 wl-folder-entity-hashtb)
 657               nil nil wl-default-spec
 658               'wl-read-folder-history))
 659         (number (call-interactively
 660                  (function (lambda (num)
 661                              (interactive "nNumber: ")
 662                              num))))
 663         (mail-reply-buffer (get-buffer-create "*wl-draft-insert-get-message*"))
 664         mail-citation-hook mail-yank-hooks
 665         wl-draft-cite-function)
 666     (unwind-protect
 667         (progn
 668           (elmo-message-fetch (wl-folder-get-elmo-folder fld)
 669                               number
 670                               ;; No cache.
 671                               (elmo-make-fetch-strategy 'entire)
 672                               nil mail-reply-buffer)
 673           (wl-draft-yank-from-mail-reply-buffer nil))
 674       (kill-buffer mail-reply-buffer))))
 675
 676 ;;
 677 ;; default body citation func
 678 ;;
 679 (defun wl-default-draft-cite ()
 680   (let ((mail-yank-ignored-headers "[^:]+:")
 681         (mail-yank-prefix "> ")
 682         date from cite-title)
 683     (save-restriction
 684       (if (< (mark t) (point))
 685           (exchange-point-and-mark))
 686       (narrow-to-region (point)(point-max))
 687       (setq date (std11-field-body "date")
 688             from (std11-field-body "from")))
 689     (when (or date from)
 690       (insert (format "At %s,\n%s wrote:\n"
 691                       (or date "some time ago")
 692                       (if wl-default-draft-cite-decorate-author
 693                           (funcall wl-summary-from-function
 694                                    (or from "you"))
 695                         (or from "you")))))
 696     (mail-indent-citation)))
 697
 698 (defvar wl-draft-buffer nil "Draft buffer to yank content.")
 699 (defun wl-draft-yank-to-draft-buffer (buffer)
 700   "Yank BUFFER content to `wl-draft-buffer'."
 701   (set-buffer wl-draft-buffer)
 702   (let ((mail-reply-buffer buffer))
 703     (wl-draft-yank-from-mail-reply-buffer nil)
 704     (kill-buffer buffer)))
 705
 706 (defun wl-draft-yank-original (&optional arg)
 707   "Yank original message."
 708   (interactive "P")
 709   (if arg
 710       (let (buf mail-reply-buffer)
 711         (elmo-set-work-buf
 712          (insert "\n")
 713          (yank)
 714          (setq buf (current-buffer)))
 715         (setq mail-reply-buffer buf)
 716         (wl-draft-yank-from-mail-reply-buffer nil))
 717     (wl-draft-yank-current-message-entity)))
 718
 719 (defun wl-draft-hide (editing-buffer)
 720   "Hide the editing draft buffer if possible."
 721   (when (and editing-buffer
 722              (buffer-live-p editing-buffer)
 723              (get-buffer-window editing-buffer))
 724     (select-window (get-buffer-window editing-buffer))
 725     (let ((sum-buf wl-draft-buffer-cur-summary-buffer)
 726           fld-buf sum-win fld-win)
 727       (if (and wl-draft-use-frame
 728                (> (length (visible-frame-list)) 1))
 729           ;; hide draft frame
 730           (delete-frame)
 731         ;; hide draft window
 732         (or (one-window-p)
 733             (delete-window))
 734         ;; stay folder window if required
 735         (when wl-stay-folder-window
 736           (if (setq fld-buf (get-buffer wl-folder-buffer-name))
 737               (if (setq fld-win (get-buffer-window fld-buf))
 738                   (select-window fld-win)
 739                 (if wl-draft-resume-folder-window ;; resume folder window
 740                     (switch-to-buffer fld-buf)))))
 741         (if (buffer-live-p sum-buf)
 742             (if (setq sum-win (get-buffer-window sum-buf t))
 743                 ;; if Summary is on the frame, select it.
 744                 (select-window sum-win)
 745               ;; if summary is not on the frame, switch to it.
 746               (if (and wl-stay-folder-window
 747                        (or wl-draft-resume-folder-window fld-win))
 748                   (wl-folder-select-buffer sum-buf)
 749                 (switch-to-buffer sum-buf))))))))
 750
 751 (defun wl-draft-delete (editing-buffer)
 752   "Kill the editing draft buffer and delete the file corresponds to it."
 753   (save-excursion
 754     (when editing-buffer
 755       (set-buffer editing-buffer)
 756       (when wl-draft-buffer-message-number
 757         (elmo-folder-delete-messages (wl-draft-get-folder)
 758                                      (list
 759                                       wl-draft-buffer-message-number))
 760         (wl-draft-config-info-operation wl-draft-buffer-message-number
 761                                         'delete))
 762       (set-buffer-modified-p nil)               ; force kill
 763       (kill-buffer editing-buffer))))
 764
 765 (defun wl-draft-kill (&optional force-kill)
 766   "Kill current draft buffer and quit editing."
 767   (interactive "P")
 768   (save-excursion
 769     (when (and (or (eq major-mode 'wl-draft-mode)
 770                    (eq major-mode 'mail-mode))
 771                (or force-kill
 772                    (yes-or-no-p "Kill Current Draft? ")))
 773       (let ((cur-buf (current-buffer)))
 774         (when (and wl-draft-parent-number
 775                    (not (string= wl-draft-parent-folder "")))
 776           (let* ((number wl-draft-parent-number)
 777                  (folder-name wl-draft-parent-folder)
 778                  (folder (wl-folder-get-elmo-folder folder-name))
 779                  buffer)
 780             (if (and (setq buffer (wl-summary-get-buffer folder-name))
 781                      (with-current-buffer buffer
 782                        (string= (wl-summary-buffer-folder-name)
 783                                 folder-name)))
 784                 (with-current-buffer buffer
 785                   (elmo-folder-unset-flag folder (list number) 'answered)
 786                   (when (wl-summary-jump-to-msg number)
 787                     (wl-summary-update-persistent-mark)))
 788               (elmo-folder-open folder 'load-msgdb)
 789               (elmo-folder-unset-flag folder (list number) 'answered)
 790               (elmo-folder-close folder))))
 791         (wl-draft-hide cur-buf)
 792         (wl-draft-delete cur-buf)))
 793     (message "")))
 794
 795 (defun wl-draft-fcc ()
 796   "Add a new Fcc field, with file name completion."
 797   (interactive)
 798   (or (mail-position-on-field "fcc" t)  ;Put new field after exiting Fcc.
 799       (mail-position-on-field "to"))
 800   (insert "\nFcc: "))
 801
 802 ;; Imported from message.el.
 803 (defun wl-draft-elide-region (b e)
 804   "Elide the text in the region.
 805 An ellipsis (from `wl-draft-elide-ellipsis') will be inserted where the
 806 text was killed."
 807   (interactive "r")
 808   (kill-region b e)
 809   (insert wl-draft-elide-ellipsis))
 810
 811 ;; Imported from message.el.
 812 (defun wl-draft-beginning-of-line (&optional n)
 813   "Move point to beginning of header value or to beginning of line."
 814   (interactive "p")
 815   (let ((zrs 'zmacs-region-stays))
 816     (when (and (interactive-p) (boundp zrs))
 817       (set zrs t)))
 818   (if (wl-draft-point-in-header-p)
 819       (let* ((here (point))
 820              (bol (progn (beginning-of-line n) (point)))
 821              (eol (line-end-position))
 822              (eoh (and (looking-at "[^ \t]")
 823                        (re-search-forward ": *" eol t))))
 824         (if (and eoh (or (> here eoh) (= here bol)))
 825             (goto-char eoh)
 826           (goto-char bol)))
 827     (beginning-of-line n)))
 828
 829 (defun wl-draft-point-in-header-p ()
 830   "Return t if point is in the header."
 831   (save-excursion
 832     (let ((p (point)))
 833       (goto-char (point-min))
 834       (not (re-search-forward
 835             (concat "^" (regexp-quote mail-header-separator) "\n")
 836             p t)))))
 837
 838 ;; function for wl-sent-message-via
 839
 840 (defmacro wl-draft-sent-message-p (type)
 841   (` (eq (nth 1 (assq (, type) wl-sent-message-via)) 'sent)))
 842
 843 (defmacro wl-draft-set-sent-message (type result &optional server-port)
 844   (` (let ((element (assq (, type) wl-sent-message-via)))
 845        (if element
 846            (unless (eq (nth 1 element) (, result))
 847              (setcdr element (list (, result) (, server-port)))
 848              (setq wl-sent-message-modified t))
 849          (push (list (, type) (, result) (, server-port)) wl-sent-message-via)
 850          (setq wl-sent-message-modified t)))))
 851
 852 (defun wl-draft-sent-message-results ()
 853   (let ((results wl-sent-message-via)
 854         unplugged-via sent-via)
 855     (while results
 856       (cond ((eq (nth 1 (car results)) 'unplugged)
 857              (push (caar results) unplugged-via))
 858             ((eq (nth 1 (car results)) 'sent)
 859              (push (caar results) sent-via)))
 860       (setq results (cdr results)))
 861     (list unplugged-via sent-via)))
 862
 863 (defun wl-draft-write-sendlog (status proto server to id)
 864   "Write send log file, if `wl-draft-sendlog' is non-nil."
 865   (when wl-draft-sendlog
 866     (with-temp-buffer
 867       (let* ((filename (expand-file-name wl-draft-sendlog-filename
 868                                          elmo-msgdb-directory))
 869              (filesize (nth 7 (file-attributes filename)))
 870              (server (if server (concat " server=" server) ""))
 871              (to (if to (cond
 872                          ((memq proto '(fcc queue))
 873                           (format " folder=\"%s\"" to))
 874                          ((eq proto 'nntp)
 875                           (format " ng=<%s>" to))
 876                          (t
 877                           (concat " to="
 878                                   (mapconcat
 879                                    'identity
 880                                    (mapcar '(lambda(x) (format "<%s>" x)) to)
 881                                    ","))))
 882                    ""))
 883              (id (if id (concat " id=" id) ""))
 884              (time (format-time-string "%Y/%m/%d %T")))
 885         (insert (format "%s proto=%s stat=%s%s%s%s\n"
 886                         time proto status server to id))
 887         (if (and wl-draft-sendlog-max-size filesize
 888                  (> filesize wl-draft-sendlog-max-size))
 889             (rename-file filename (concat filename ".old") t))
 890         (if (file-writable-p filename)
 891             (write-region-as-binary (point-min) (point-max)
 892                                     filename t 'no-msg)
 893           (message "%s is not writable." filename))))))
 894
 895 (defun wl-draft-get-header-delimiter (&optional delete)
 896   ;; If DELETE is non-nil, replace the header delimiter with a blank line
 897   (let (delimline)
 898     (goto-char (point-min))
 899     (when (re-search-forward
 900            (concat "^" (regexp-quote mail-header-separator) "$\\|^$") nil t)
 901       (replace-match "")
 902       (if delete
 903           (forward-char -1))
 904       (setq delimline (point-marker)))
 905     delimline))
 906
 907 (defun wl-draft-send-mail-with-qmail ()
 908   "Pass the prepared message buffer to qmail-inject.
 909 Refer to the documentation for the variable `send-mail-function'
 910 to find out how to use this."
 911   (if (and wl-draft-qmail-send-plugged
 912            (not (elmo-plugged-p)))
 913       (wl-draft-set-sent-message 'mail 'unplugged)
 914     ;; send the message
 915     (run-hooks 'wl-mail-send-pre-hook) ;; X-PGP-Sig, Cancel-Lock
 916     (let ((id (std11-field-body "Message-ID"))
 917           (to (std11-field-body "To")))
 918       (case
 919           (as-binary-process
 920            (apply
 921             'call-process-region 1 (point-max) wl-qmail-inject-program
 922             nil nil nil
 923             wl-qmail-inject-args))
 924         ;; qmail-inject doesn't say anything on it's stdout/stderr,
 925         ;; we have to look at the retval instead
 926         (0   (progn
 927                (wl-draft-set-sent-message 'mail 'sent)
 928                (wl-draft-write-sendlog 'ok 'qmail nil (list to) id)))
 929         (1   (error "`qmail-inject' reported permanent failure"))
 930         (111 (error "`qmail-inject' reported transient failure"))
 931         ;; should never happen
 932         (t   (error "`qmail-inject' reported unknown failure"))))))
 933
 934 (defun wl-draft-parse-msg-id-list-string (string)
 935   "Get msg-id list from STRING."
 936   (let (msg-id-list)
 937     (dolist (parsed-id (std11-parse-msg-ids-string string))
 938       (when (eq (car parsed-id) 'msg-id)
 939         (setq msg-id-list (cons (std11-msg-id-string parsed-id)
 940                                 msg-id-list))))
 941     (nreverse msg-id-list)))
 942
 943 (defun wl-draft-eword-encode-address-list (string &optional column)
 944   "Encode header field STRING as list of address, and return the result.
 945 Cause an error when STRING contains invalid address.
 946 Optional argument COLUMN is start-position of the field."
 947   (car (eword-encode-rword-list
 948         (or column eword-encode-default-start-column)
 949         (eword-encode-addresses-to-rword-list
 950          (wl-draft-std11-parse-addresses (std11-lexical-analyze string))))))
 951
 952 (defun wl-draft-std11-parse-addresses (lal)
 953   (let ((ret (std11-parse-address lal)))
 954     (when (and (not (and (eq (length lal) 1)
 955                          (eq (car (car lal)) 'spaces)))
 956                (null ret))
 957       (error "Error while parsing address"))
 958     (if ret
 959         (let ((dest (list (car ret))))
 960           (setq lal (cdr ret))
 961           (while (and (setq ret (std11-parse-ascii-token lal))
 962                       (string-equal (cdr (assq 'specials (car ret))) ",")
 963                       (setq ret (std11-parse-address (cdr ret)))
 964                       )
 965             (setq dest (cons (car ret) dest))
 966             (setq lal (cdr ret)))
 967           (while (eq 'spaces (car (car lal)))
 968             (setq lal (cdr lal)))
 969           (if lal (error "Error while parsing address"))
 970           (nreverse dest)))))
 971
 972 (defun wl-draft-parse-mailbox-list (field &optional remove-group-list)
 973   "Get mailbox list of FIELD from current buffer.
 974 The buffer is expected to be narrowed to just the headers of the message.
 975 If optional argument REMOVE-GROUP-LIST is non-nil, remove group list content
 976 from current buffer."
 977   (save-excursion
 978     (let ((case-fold-search t)
 979           (inhibit-read-only t)
 980           addresses address
 981           mailbox-list beg seq has-group-list)
 982       (goto-char (point-min))
 983       (while (re-search-forward (concat "^" (regexp-quote field) "[\t ]*:")
 984                                 nil t)
 985         (setq beg (point))
 986         (re-search-forward "^[^ \t]" nil 'move)
 987         (beginning-of-line)
 988         (skip-chars-backward "\n")
 989         (setq seq (std11-lexical-analyze
 990                    (buffer-substring-no-properties beg (point))))
 991         (setq addresses (wl-draft-std11-parse-addresses seq))
 992         (while addresses
 993           (cond ((eq (car (car addresses)) 'group)
 994                  (setq has-group-list t)
 995                  (setq mailbox-list
 996                        (nconc mailbox-list
 997                               (mapcar
 998                                'std11-address-string
 999                                (nth 2 (car addresses))))))
1000                 ((eq (car (car addresses)) 'mailbox)
1001                  (setq address (nth 1 (car addresses)))
1002                  (setq mailbox-list
1003                        (nconc mailbox-list
1004                               (list
1005                                (std11-addr-to-string
1006                                 (if (eq (car address) 'phrase-route-addr)
1007                                     (nth 2 address)
1008                                   (cdr address))))))))
1009           (setq addresses (cdr addresses)))
1010         (when (and remove-group-list has-group-list)
1011           (delete-region beg (point))
1012           (insert (wl-address-string-without-group-list-contents seq))))
1013       mailbox-list)))
1014
1015 (defun wl-draft-deduce-address-list (buffer header-start header-end)
1016   "Get address list suitable for smtp RCPT TO:<address>.
1017 Group list content is removed if `wl-draft-remove-group-list-contents' is
1018 non-nil."
1019   (let ((fields (if (and wl-draft-doing-mime-bcc
1020                          wl-draft-disable-bcc-for-mime-bcc)
1021                     '("to" "cc")
1022                   '("to" "cc" "bcc")))
1023         (resent-fields '("resent-to" "resent-cc" "resent-bcc"))
1024         (case-fold-search t)
1025         addrs recipients)
1026     (save-excursion
1027       (save-restriction
1028         (narrow-to-region header-start header-end)
1029         (goto-char (point-min))
1030         (save-excursion
1031           (if (re-search-forward "^resent-to[\t ]*:" nil t)
1032               (setq fields resent-fields)))
1033         (while fields
1034           (setq recipients
1035                 (nconc recipients
1036                        (wl-draft-parse-mailbox-list
1037                         (car fields)
1038                         wl-draft-remove-group-list-contents)))
1039           (setq fields (cdr fields)))
1040         recipients))))
1041
1042 ;;
1043 ;; from Semi-gnus
1044 ;;
1045 (defun wl-draft-send-mail-with-smtp ()
1046   "Send the prepared message buffer with SMTP."
1047   (require 'smtp)
1048   (let* ((errbuf (if mail-interactive
1049                      (generate-new-buffer " smtp errors")
1050                    0))
1051          (case-fold-search t)
1052          (default-case-fold-search t)
1053          (sender (or wl-envelope-from
1054                      (wl-address-header-extract-address wl-from)))
1055          (delimline (save-excursion
1056                       (goto-char (point-min))
1057                       (re-search-forward
1058                        (concat "^" (regexp-quote mail-header-separator)
1059                                "$\\|^$") nil t)
1060                       (point-marker)))
1061          (smtp-server
1062           (or wl-smtp-posting-server smtp-server "localhost"))
1063          (smtp-service (or wl-smtp-posting-port smtp-service))
1064          (smtp-local-domain (or smtp-local-domain wl-local-domain))
1065          (id (std11-field-body "message-id"))
1066          recipients)
1067     (if (not (elmo-plugged-p smtp-server smtp-service))
1068         (wl-draft-set-sent-message 'mail 'unplugged
1069                                    (cons smtp-server smtp-service))
1070       (unwind-protect
1071           (save-excursion
1072             ;; Instead of `smtp-deduce-address-list'.
1073             (setq recipients (wl-draft-deduce-address-list
1074                               (current-buffer) (point-min) delimline))
1075             (unless recipients (error "No recipients"))
1076             ;; Insert an extra newline if we need it to work around
1077             ;; Sun's bug that swallows newlines.
1078             (goto-char (1+ delimline))
1079             (if (eval mail-mailer-swallows-blank-line)
1080                 (newline))
1081             (run-hooks 'wl-mail-send-pre-hook) ;; X-PGP-Sig, Cancel-Lock
1082             (if mail-interactive
1083                 (save-excursion
1084                   (set-buffer errbuf)
1085                   (erase-buffer)))
1086             (wl-draft-delete-field "bcc" delimline)
1087             (wl-draft-delete-field "resent-bcc" delimline)
1088             (let (process-connection-type)
1089               (as-binary-process
1090                (when recipients
1091                  (wl-smtp-extension-bind
1092                   (condition-case err
1093                       (smtp-send-buffer sender recipients (current-buffer))
1094                     (error
1095                      (wl-draft-write-sendlog 'failed 'smtp smtp-server
1096                                              recipients id)
1097                      (if (and (eq (car err) 'smtp-response-error)
1098                               (= (nth 1 err) 535))
1099                          (elmo-remove-passwd
1100                           (wl-smtp-password-key
1101                            smtp-sasl-user-name
1102                            (car smtp-sasl-mechanisms)
1103                            smtp-server)))
1104                      (signal (car err) (cdr err)))
1105                     (quit
1106                      (wl-draft-write-sendlog 'uncertain 'smtp smtp-server
1107                                              recipients id)
1108                      (signal (car err) (cdr err)))))
1109                  (wl-draft-set-sent-message 'mail 'sent)
1110                  (wl-draft-write-sendlog
1111                   'ok 'smtp smtp-server recipients id)))))
1112         (if (bufferp errbuf)
1113             (kill-buffer errbuf))))))
1114
1115 (defun wl-draft-send-mail-with-pop-before-smtp ()
1116   "Send the prepared message buffer with POP-before-SMTP."
1117   (require 'elmo-pop3)
1118   (let ((folder
1119          (luna-make-entity
1120           'elmo-pop3-folder
1121           :user   (or wl-pop-before-smtp-user
1122                       elmo-pop3-default-user)
1123           :server (or wl-pop-before-smtp-server
1124                       elmo-pop3-default-server)
1125           :port   (or wl-pop-before-smtp-port
1126                       elmo-pop3-default-port)
1127           :auth   (or wl-pop-before-smtp-authenticate-type
1128                       elmo-pop3-default-authenticate-type)
1129           :stream-type (elmo-get-network-stream-type
1130                         (or wl-pop-before-smtp-stream-type
1131                             elmo-pop3-default-stream-type))))
1132         session)
1133     (condition-case error
1134         (progn
1135           (setq session (elmo-pop3-get-session folder))
1136           (when session (elmo-network-close-session session)))
1137       (error
1138        (unless (string= (nth 1 error) "Unplugged")
1139          (signal (car error) (cdr error))))))
1140   (wl-draft-send-mail-with-smtp))
1141
1142 (defun wl-draft-insert-required-fields (&optional force-msgid)
1143   "Insert Message-ID, Date, and From field.
1144 If FORCE-MSGID, insert message-id regardless of `wl-insert-message-id'."
1145   ;; Insert Message-Id field...
1146   (goto-char (point-min))
1147   (when (and (or force-msgid
1148                  wl-insert-message-id)
1149              (not (re-search-forward "^Message-ID[ \t]*:" nil t)))
1150     (insert (concat "Message-ID: "
1151                     (funcall wl-message-id-function)
1152                     "\n")))
1153   ;; Insert date field.
1154   (goto-char (point-min))
1155   (or (re-search-forward "^Date[ \t]*:" nil t)
1156       (wl-draft-insert-date-field))
1157   ;; Insert from field.
1158   (goto-char (point-min))
1159   (or (re-search-forward "^From[ \t]*:" nil t)
1160       (wl-draft-insert-from-field)))
1161
1162 (defun wl-draft-normal-send-func (editing-buffer kill-when-done)
1163   "Send the message in the current buffer."
1164   (save-restriction
1165     (narrow-to-region (goto-char (point-min))
1166                       (if (re-search-forward
1167                            (concat
1168                             "^" (regexp-quote mail-header-separator) "$")
1169                            nil t)
1170                           (match-beginning 0)
1171                         (point-max)))
1172     (wl-draft-insert-required-fields)
1173     ;; ignore any blank lines in the header
1174     (while (progn (goto-char (point-min))
1175                   (re-search-forward "\n[ \t]*\n\n*" nil t))
1176       (replace-match "\n"))
1177     (goto-char (point-min))
1178     (while (re-search-forward
1179             "^[^ \t\n:]+:[ \t]*\\(.*\\(\n[ \t].*\\)*\\)\n"
1180             nil t)
1181       (when (string= "" (match-string 1))
1182         (replace-match ""))))
1183 ;;;  (run-hooks 'wl-mail-send-pre-hook) ;; X-PGP-Sig, Cancel-Lock
1184   (wl-draft-dispatch-message)
1185   (when kill-when-done
1186     ;; hide editing-buffer.
1187     (wl-draft-hide editing-buffer)
1188     ;; delete editing-buffer and its file.
1189     (wl-draft-delete editing-buffer)))
1190
1191 (defun wl-draft-dispatch-message (&optional mes-string)
1192   "Send the message in the current buffer.  Not modified the header fields."
1193   (let (delimline mime-bcc)
1194     (if (and wl-draft-verbose-send mes-string)
1195         (message "%s" mes-string))
1196     ;; get fcc folders.
1197     (setq delimline (wl-draft-get-header-delimiter t))
1198     (unless wl-draft-fcc-list
1199       (setq wl-draft-fcc-list (wl-draft-get-fcc-list delimline)))
1200     ;;
1201     (setq wl-sent-message-modified nil)
1202     (unwind-protect
1203         (progn
1204           (if (and (wl-message-mail-p)
1205                    (not (wl-draft-sent-message-p 'mail)))
1206               (if (or (not (or wl-draft-force-queuing
1207                                wl-draft-force-queuing-mail))
1208                       (memq 'mail wl-sent-message-queued))
1209                   (progn
1210                     (setq mime-bcc (wl-draft-mime-bcc-field))
1211                     (funcall wl-draft-send-mail-function)
1212                     (when (not (zerop (length mime-bcc)))
1213                       (wl-draft-do-mime-bcc mime-bcc)))
1214                 (push 'mail wl-sent-message-queued)
1215                 (wl-draft-set-sent-message 'mail 'unplugged)))
1216           (if (and (wl-message-news-p)
1217                    (not (wl-draft-sent-message-p 'news))
1218                    (not (wl-message-field-exists-p "Resent-to")))
1219               (if (or (not (or wl-draft-force-queuing
1220                                wl-draft-force-queuing-news))
1221                       (memq 'news wl-sent-message-queued))
1222                   (funcall wl-draft-send-news-function)
1223                 (push 'news wl-sent-message-queued)
1224                 (wl-draft-set-sent-message 'news 'unplugged))))
1225       (let* ((status (wl-draft-sent-message-results))
1226              (unplugged-via (car status))
1227              (sent-via (nth 1 status)))
1228         ;; If one sent, process fcc folder.
1229         (if (and sent-via wl-draft-fcc-list)
1230             (progn
1231               (wl-draft-do-fcc (wl-draft-get-header-delimiter)
1232                                wl-draft-fcc-list)
1233               (setq wl-draft-fcc-list nil)))
1234         (if wl-draft-use-cache
1235             (let ((id (std11-field-body "Message-ID"))
1236                   (elmo-enable-disconnected-operation t))
1237               (elmo-file-cache-save (elmo-file-cache-get-path id)
1238                                     nil)))
1239         ;; If one unplugged, append queue.
1240         (when (and unplugged-via
1241                    wl-sent-message-modified)
1242           (if wl-draft-enable-queuing
1243               (progn
1244                 (wl-draft-queue-append wl-sent-message-via)
1245                 (setq wl-sent-message-modified 'requeue))
1246             (error "Unplugged")))
1247         (when wl-draft-verbose-send
1248           (if (and unplugged-via sent-via);; combined message
1249               (progn
1250                 (setq wl-draft-verbose-msg
1251                       (format "Sending%s and Queuing%s..."
1252                               sent-via unplugged-via))
1253                 (message "%sdone" wl-draft-verbose-msg))
1254             (if mes-string
1255                 (message "%s%s"
1256                          mes-string
1257                          (if sent-via "done" "failed"))))))))
1258   (not wl-sent-message-modified)) ;; return value
1259
1260 (defun wl-draft-raw-send (&optional kill-when-done force-pre-hook mes-string)
1261   "Force send current buffer as raw message."
1262   (interactive)
1263   (save-excursion
1264     (let (wl-interactive-send
1265 ;;;       wl-draft-verbose-send
1266           (wl-mail-send-pre-hook (and force-pre-hook wl-mail-send-pre-hook))
1267           (wl-news-send-pre-hook (and force-pre-hook wl-news-send-pre-hook))
1268           mail-send-hook
1269           mail-send-actions)
1270       (wl-draft-send kill-when-done mes-string))))
1271
1272 (defun wl-draft-clone-local-variables ()
1273   (let ((locals (buffer-local-variables))
1274         result)
1275     (while locals
1276       (when (and (consp (car locals))
1277                  (car (car locals))
1278                  (string-match wl-draft-clone-local-variable-regexp
1279                                (symbol-name (car (car locals)))))
1280         (wl-append result (list (car (car locals)))))
1281       (setq locals (cdr locals)))
1282     result))
1283
1284 (defcustom wl-draft-send-confirm-with-preview t
1285   "Non-nil to invoke preview through confirmation of sending.
1286 This variable is valid when `wl-interactive-send' has non-nil value."
1287   :type 'boolean
1288   :group 'wl-draft)
1289
1290 (defun wl-draft-send-confirm ()
1291   (let (answer)
1292     (unwind-protect
1293         (condition-case quit
1294             (progn
1295               (when wl-draft-send-confirm-with-preview
1296                 (wl-draft-preview-message))
1297               (save-excursion
1298                 (goto-char (point-min)) ; to show recipients in header
1299                 (catch 'done
1300                   (while t
1301                     (discard-input)
1302                     (message "Send current draft? <y/n/j(down)/k(up)> ")
1303                     (setq answer (let ((cursor-in-echo-area t)) (read-char)))
1304                     (cond
1305                      ((or (eq answer ?y)
1306                           (eq answer ?Y)
1307                           (eq answer ? ))
1308                   (throw 'done t))
1309                      ((or (eq answer ?v)
1310                           (eq answer ?j)
1311                           (eq answer ?J))
1312                       (condition-case err
1313                           (scroll-up)
1314                         (error nil)))
1315                      ((or (eq answer ?^)
1316                           (eq answer ?k)
1317                           (eq answer ?K))
1318                       (condition-case err
1319                           (scroll-down)
1320                         (error nil)))
1321                      (t
1322                       (throw 'done nil)))))))
1323           (quit nil))
1324       (when wl-draft-send-confirm-with-preview
1325         (mime-preview-quit)))))
1326
1327 (defun wl-draft-send (&optional kill-when-done mes-string)
1328   "Send current draft message.
1329 If KILL-WHEN-DONE is non-nil, current draft buffer is killed"
1330   (interactive)
1331   ;; Don't call this explicitly.
1332   ;; Added to 'wl-draft-send-hook (by teranisi)
1333   ;; (wl-draft-config-exec)
1334   (run-hooks 'wl-draft-send-hook)
1335   (when (or (not wl-interactive-send)
1336             (wl-draft-send-confirm))
1337     (let ((send-mail-function 'wl-draft-raw-send)
1338           (editing-buffer (current-buffer))
1339           (sending-buffer (wl-draft-generate-clone-buffer
1340                            " *wl-draft-sending-buffer*"
1341                            (append wl-draft-config-variables
1342                                    (wl-draft-clone-local-variables))))
1343           (wl-draft-verbose-msg nil)
1344           err)
1345       (unwind-protect
1346           (save-excursion
1347             (set-buffer sending-buffer)
1348             (if (and (not (wl-message-mail-p))
1349                      (not (wl-message-news-p)))
1350                 (error "No recipient is specified"))
1351             (expand-abbrev)             ; for mail-abbrevs
1352             (let ((mime-header-encode-method-alist
1353                    (append
1354                     '((wl-draft-eword-encode-address-list
1355                        .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
1356                     (if (boundp 'mime-header-encode-method-alist)
1357                         (symbol-value 'mime-header-encode-method-alist)))))
1358               (run-hooks 'mail-send-hook) ; translate buffer
1359               )
1360             ;;
1361             (if wl-draft-verbose-send
1362                 (message "%s" (or mes-string "Sending...")))
1363             (funcall wl-draft-send-function editing-buffer kill-when-done)
1364             ;; Now perform actions on successful sending.
1365             (while mail-send-actions
1366               (condition-case ()
1367                   (apply (car (car mail-send-actions))
1368                          (cdr (car mail-send-actions)))
1369                 (error))
1370               (setq mail-send-actions (cdr mail-send-actions)))
1371             (if wl-draft-verbose-send
1372                 (message "%sdone"
1373                          (or wl-draft-verbose-msg
1374                              mes-string
1375                              "Sending..."))))
1376         ;; kill sending buffer, anyway.
1377         (and (buffer-live-p sending-buffer)
1378              (kill-buffer sending-buffer))))))
1379
1380 (defun wl-draft-mime-bcc-field ()
1381   "Return the MIME-Bcc field body.  The field is deleted."
1382   (prog1 (std11-field-body wl-draft-mime-bcc-field-name)
1383     (wl-draft-delete-field wl-draft-mime-bcc-field-name)))
1384
1385 (defun wl-draft-do-mime-bcc (field-body)
1386   "Send MIME-Bcc (Encapsulated blind carbon copy)."
1387   (let ((orig-from (mime-decode-field-body (std11-field-body "from")
1388                                            'From))
1389         (orig-subj (mime-decode-field-body (or (std11-field-body "subject")
1390                                                "")
1391                                            'Subject))
1392         (recipients (wl-parse-addresses field-body))
1393         (draft-buffer (current-buffer))
1394         wl-draft-use-frame)
1395     (save-window-excursion
1396       (when (and (not wl-draft-doing-mime-bcc) ; To avoid infinite loop.
1397                  (not (zerop (length field-body))))
1398         (let ((wl-draft-doing-mime-bcc t))
1399           (dolist (recipient recipients)
1400             (wl-draft-create-buffer)
1401             (wl-draft-create-contents
1402              (append `((From . ,orig-from)
1403                        (To . ,recipient)
1404                        (Subject . ,(concat "A blind carbon copy ("
1405                                            orig-subj
1406                                            ")")))
1407                      (wl-draft-default-headers)))
1408             (wl-draft-insert-mail-header-separator)
1409             (wl-draft-prepare-edit)
1410             (goto-char (point-max))
1411             (insert (or wl-draft-mime-bcc-body
1412                         "This is a blind carbon copy.")
1413                     "\n")
1414             (mime-edit-insert-tag "message" "rfc822")
1415             (insert-buffer draft-buffer)
1416             (let (wl-interactive-send)
1417               (wl-draft-send 'kill-when-done))))))))
1418
1419 (defun wl-draft-save ()
1420   "Save current draft."
1421   (interactive)
1422   (if (buffer-modified-p)
1423       (progn
1424         (message "Saving...")
1425         (let ((msg (buffer-substring-no-properties (point-min) (point-max)))
1426               next-number)
1427           (when wl-draft-buffer-message-number
1428             (elmo-folder-delete-messages (wl-draft-get-folder)
1429                                          (list wl-draft-buffer-message-number))
1430             (wl-draft-config-info-operation wl-draft-buffer-message-number
1431                                             'delete))
1432           (elmo-folder-check (wl-draft-get-folder))
1433           ;; If no header separator, insert it.
1434           (with-temp-buffer
1435             (insert msg)
1436             (goto-char (point-min))
1437             (unless (re-search-forward
1438                      (concat "^" (regexp-quote mail-header-separator) "$")
1439                      nil t)
1440               (goto-char (point-min))
1441               (if (re-search-forward "\n\n" nil t)
1442                   (replace-match (concat "\n" mail-header-separator "\n"))
1443                 (goto-char (point-max))
1444                 (insert (if (eq (char-before) ?\n) "" "\n")
1445                         mail-header-separator "\n")))
1446             (let ((mime-header-encode-method-alist
1447                    '((eword-encode-unstructured-field-body))))
1448               (mime-edit-translate-buffer))
1449             (wl-draft-get-header-delimiter t)
1450             (setq next-number
1451                   (elmo-folder-next-message-number (wl-draft-get-folder)))
1452             (elmo-folder-append-buffer (wl-draft-get-folder)))
1453           (elmo-folder-check (wl-draft-get-folder))
1454           (elmo-folder-commit (wl-draft-get-folder))
1455           (setq wl-draft-buffer-message-number next-number)
1456           (rename-buffer (format "%s/%d" wl-draft-folder next-number))
1457           (setq buffer-file-name (buffer-name))
1458           (set-buffer-modified-p nil)
1459           (wl-draft-config-info-operation wl-draft-buffer-message-number 'save)
1460           (message "Saving...done")))
1461     (message "(No changes need to be saved)")))
1462
1463 (defun wl-draft-mimic-kill-buffer ()
1464   "Kill the current (draft) buffer with query."
1465   (interactive)
1466   (let ((bufname (read-buffer (format "Kill buffer: (default %s) "
1467                                       (buffer-name))))
1468         wl-draft-use-frame)
1469     (if (or (not bufname)
1470             (string-equal bufname "")
1471             (string-equal bufname (buffer-name)))
1472         (let ((bufname (current-buffer)))
1473           (when (or (not (buffer-modified-p))
1474                     (yes-or-no-p
1475                      (format "Buffer %s modified; kill anyway? " bufname)))
1476             (set-buffer-modified-p nil)
1477             (wl-draft-hide bufname)
1478             (kill-buffer bufname)))
1479       (kill-buffer bufname))))
1480
1481 (defun wl-draft-save-and-exit ()
1482   "Save current draft and exit current draft mode."
1483   (interactive)
1484   (wl-draft-save)
1485   (let ((editing-buffer (current-buffer)))
1486     (wl-draft-hide editing-buffer)
1487     (kill-buffer editing-buffer)))
1488
1489 (defun wl-draft-send-and-exit ()
1490   "Send current draft message and kill it."
1491   (interactive)
1492   (wl-draft-send t))
1493
1494 (defun wl-draft-send-from-toolbar ()
1495   (interactive)
1496   (let ((wl-interactive-send t))
1497     (wl-draft-send-and-exit)))
1498
1499 (defun wl-draft-delete-field (field &optional delimline replace)
1500   (wl-draft-delete-fields (regexp-quote field) delimline replace))
1501
1502 (defun wl-draft-delete-fields (field &optional delimline replace)
1503   (save-restriction
1504     (unless delimline
1505       (goto-char (point-min))
1506       (if (search-forward "\n\n" nil t)
1507           (setq delimline (point))
1508         (setq delimline (point-max))))
1509     (narrow-to-region (point-min) delimline)
1510     (goto-char (point-min))
1511     (let ((regexp (concat "^" field ":"))
1512           (case-fold-search t))
1513       (while (not (eobp))
1514         (if (looking-at regexp)
1515             (progn
1516               (delete-region
1517                (point)
1518                (progn
1519                  (forward-line 1)
1520                  (if (re-search-forward "^[^ \t]" nil t)
1521                      (goto-char (match-beginning 0))
1522                    (point-max))))
1523               (if replace
1524                   (insert (concat field ": " replace "\n"))))
1525           (forward-line 1)
1526           (if (re-search-forward "^[^ \t]" nil t)
1527               (goto-char (match-beginning 0))
1528             (point-max)))))))
1529
1530 (defun wl-draft-get-fcc-list (header-end)
1531   (if (and wl-draft-doing-mime-bcc
1532            wl-draft-disable-fcc-for-mime-bcc)
1533       (progn
1534         (wl-draft-delete-field "fcc")
1535         nil)
1536     (let (fcc-list
1537           (case-fold-search t))
1538       (or (markerp header-end) (error "HEADER-END must be a marker"))
1539       (save-excursion
1540         (goto-char (point-min))
1541         (while (re-search-forward "^Fcc:[ \t]*" header-end t)
1542           (save-match-data
1543             (setq fcc-list
1544                   (append fcc-list
1545                           (split-string
1546                            (buffer-substring-no-properties
1547                             (point)
1548                             (progn
1549                               (end-of-line)
1550                               (skip-chars-backward " \t")
1551                               (point)))
1552                            ",[ \t]*")))
1553             (dolist (folder fcc-list)
1554               (wl-folder-confirm-existence
1555                (wl-folder-get-elmo-folder (eword-decode-string folder)))))
1556           (delete-region (match-beginning 0)
1557                          (progn (forward-line 1) (point)))))
1558       fcc-list)))
1559
1560 (defcustom wl-draft-fcc-append-read-folder-history t
1561   "Non-nil to append fcc'ed folder to `wl-read-folder-history'."
1562   :type 'boolean
1563   :group 'wl-draft)
1564
1565 (defun wl-draft-do-fcc (header-end &optional fcc-list)
1566   (let ((send-mail-buffer (current-buffer))
1567         (tembuf (generate-new-buffer " fcc output"))
1568         (case-fold-search t)
1569         beg end)
1570     (or (markerp header-end) (error "HEADER-END must be a marker"))
1571     (save-excursion
1572       (unless fcc-list
1573         (setq fcc-list (wl-draft-get-fcc-list header-end)))
1574       (set-buffer tembuf)
1575       (erase-buffer)
1576       ;; insert just the headers to avoid moving the gap more than
1577       ;; necessary (the message body could be arbitrarily huge.)
1578       (insert-buffer-substring send-mail-buffer 1 header-end)
1579       (wl-draft-insert-required-fields t)
1580       (goto-char (point-max))
1581       (insert-buffer-substring send-mail-buffer header-end)
1582       (let ((id (std11-field-body "Message-ID"))
1583             (elmo-enable-disconnected-operation t)
1584             cache-saved)
1585         (while fcc-list
1586           (unless (or cache-saved
1587                       (elmo-folder-plugged-p
1588                        (wl-folder-get-elmo-folder (car fcc-list))))
1589             (elmo-file-cache-save id nil) ;; for disconnected operation
1590             (setq cache-saved t))
1591           (if (elmo-folder-append-buffer
1592                (wl-folder-get-elmo-folder
1593                 (eword-decode-string (car fcc-list)))
1594                (and wl-fcc-force-as-read '(read)))
1595               (wl-draft-write-sendlog 'ok 'fcc nil (car fcc-list) id)
1596             (wl-draft-write-sendlog 'failed 'fcc nil (car fcc-list) id))
1597           (if (and wl-draft-fcc-append-read-folder-history
1598                    (boundp 'wl-read-folder-history))
1599               (or (equal (car fcc-list) (car wl-read-folder-history))
1600                   (setq wl-read-folder-history
1601                         (append (list (car fcc-list)) wl-read-folder-history))))
1602           (setq fcc-list (cdr fcc-list)))))
1603     (kill-buffer tembuf)))
1604
1605 (defun wl-draft-on-field-p ()
1606   (if (< (point)
1607          (save-excursion
1608            (goto-char (point-min))
1609            (search-forward (concat "\n" mail-header-separator "\n") nil 0)
1610            (point)))
1611       (if (bolp)
1612           (if (bobp)
1613               t
1614             (save-excursion
1615               (forward-line -1)
1616               (if (or (looking-at ".*,[ \t]?$")
1617                       (looking-at "^[^ \t]+:[ \t]+.*:$")); group list name
1618                   nil t)))
1619         (let ((pos (point)))
1620           (save-excursion
1621             (beginning-of-line)
1622             (if (looking-at "^[ \t]")
1623                 nil
1624               (if (re-search-forward ":" pos t) nil t)))))))
1625
1626 ;;;;;;;;;;;;;;;;
1627 ;;;###autoload
1628 (defun wl-draft (&optional header-alist
1629                            content-type content-transfer-encoding
1630                            body edit-again
1631                            parent-folder)
1632   "Write and send mail/news message with Wanderlust."
1633   (interactive)
1634   (require 'wl)
1635   (unless wl-init
1636     (wl-load-profile)
1637     (wl-folder-init)
1638     (elmo-init)
1639     (wl-plugged-init t))
1640   (let (wl-demo)
1641     (wl-init)) ; returns immediately if already initialized.
1642
1643
1644   (let (buffer header-alist-internal)
1645     (setq buffer (wl-draft-create-buffer parent-folder))
1646     (unless (cdr (assq 'From header-alist))
1647       (setq header-alist
1648             (append (list (cons 'From wl-from)) header-alist)))
1649     (unless (cdr (assq 'To header-alist))
1650       (let ((to))
1651         (when (setq to (and
1652                         (interactive-p)
1653                         ""))
1654           (if (assq 'To header-alist)
1655               (setcdr (assq 'To header-alist) to)
1656             (setq header-alist
1657                   (append header-alist
1658                           (list (cons 'To to))))))))
1659     (unless (cdr (assq 'Subject header-alist))
1660       (if (assq 'Subject header-alist)
1661           (setcdr (assq 'Subject header-alist) "")
1662         (setq header-alist
1663               (append header-alist (list (cons 'Subject ""))))))
1664     (setq header-alist (append header-alist
1665                                (wl-draft-default-headers)
1666                                wl-draft-additional-header-alist
1667                                (if body (list "" (cons 'Body body)))))
1668     (wl-draft-create-contents header-alist)
1669     (if edit-again
1670         (wl-draft-decode-body
1671          content-type content-transfer-encoding))
1672     (wl-draft-insert-mail-header-separator)
1673     (wl-draft-prepare-edit)
1674     (if (interactive-p)
1675         (run-hooks 'wl-mail-setup-hook))
1676     (goto-char (point-min))
1677     (setq buffer-undo-list nil)
1678     (wl-user-agent-compose-internal) ;; user-agent
1679     (cond ((and
1680             (interactive-p)
1681             (string= (cdr (assq 'To header-alist)) ""))
1682            (mail-position-on-field "To"))
1683           (t
1684            (goto-char (point-max))))
1685     buffer))
1686
1687 (defun wl-draft-create-buffer (&optional parent-folder)
1688   (let* ((draft-folder (wl-draft-get-folder))
1689          (parent-folder (or parent-folder (wl-summary-buffer-folder-name)))
1690          (summary-buf (wl-summary-get-buffer parent-folder))
1691          (reply-or-forward
1692           (or (eq this-command 'wl-summary-reply)
1693               (eq this-command 'wl-summary-reply-with-citation)
1694               (eq this-command 'wl-summary-forward)
1695               (eq this-command 'wl-summary-target-mark-forward)
1696               (eq this-command 'wl-summary-target-mark-reply-with-citation)))
1697          (buffer (generate-new-buffer "*draft*")) ; Just for initial name.
1698          change-major-mode-hook)
1699     (set-buffer buffer)
1700     ;; switch-buffer according to draft buffer style.
1701     (if wl-draft-use-frame
1702         (switch-to-buffer-other-frame buffer)
1703       (if reply-or-forward
1704           (case wl-draft-reply-buffer-style
1705             (split
1706              (split-window-vertically)
1707              (other-window 1)
1708              (switch-to-buffer buffer))
1709             (keep
1710              (switch-to-buffer buffer))
1711             (full
1712              (delete-other-windows)
1713              (switch-to-buffer buffer))
1714             (t
1715              (if (functionp wl-draft-reply-buffer-style)
1716                  (funcall wl-draft-reply-buffer-style buffer)
1717                (error "Invalid value for wl-draft-reply-buffer-style"))))
1718         (case wl-draft-buffer-style
1719           (split
1720            (when (eq major-mode 'wl-summary-mode)
1721              (wl-summary-toggle-disp-msg 'off))
1722            (split-window-vertically)
1723            (other-window 1)
1724            (switch-to-buffer buffer))
1725           (keep
1726            (switch-to-buffer buffer))
1727           (full
1728            (delete-other-windows)
1729            (switch-to-buffer buffer))
1730           (t (if (functionp wl-draft-buffer-style)
1731                  (funcall wl-draft-buffer-style buffer)
1732                (error "Invalid value for wl-draft-buffer-style"))))))
1733     (auto-save-mode -1)
1734     (wl-draft-mode)
1735     (make-local-variable 'truncate-partial-width-windows)
1736     (setq truncate-partial-width-windows nil)
1737     (setq truncate-lines wl-draft-truncate-lines)
1738     (setq wl-sent-message-via nil)
1739     (setq wl-sent-message-queued nil)
1740     (setq wl-draft-config-exec-flag t)
1741     (setq wl-draft-parent-folder (or parent-folder ""))
1742     (or (eq this-command 'wl-folder-write-current-folder)
1743         (setq wl-draft-buffer-cur-summary-buffer summary-buf))
1744     buffer))
1745
1746 (defun wl-draft-create-contents (header-alist)
1747   "header-alist' sample
1748 '(function  ;; funcall
1749   string    ;; insert string
1750   (symbol . string)    ;;  insert symbol-value: string
1751   (symbol . function)  ;;  (funcall) and if it returns string,
1752                        ;;  insert symbol-value: string
1753   (symbol . nil)       ;;  do nothing
1754   nil                  ;;  do nothing
1755   )"
1756   (unless (eq major-mode 'wl-draft-mode)
1757     (error "`wl-draft-create-header' must be use in wl-draft-mode"))
1758   (let ((halist header-alist)
1759         field value)
1760     (while halist
1761       (cond
1762        ;; function
1763        ((functionp (car halist)) (funcall (car halist)))
1764        ;; string
1765        ((stringp (car halist)) (insert (car halist) "\n"))
1766        ;; cons
1767        ((consp (car halist))
1768         (setq field (car (car halist)))
1769         (setq value (cdr (car halist)))
1770         (cond
1771          ((symbolp field)
1772           (cond
1773            ((eq field 'Body) ; body
1774             (insert value))
1775            ((stringp value) (insert (symbol-name field) ": " value "\n"))
1776            ((functionp value)
1777             (let ((value-return (funcall value)))
1778               (when (stringp value-return)
1779                 (insert (symbol-name field) ": " value-return "\n"))))
1780            ((not value))
1781            (t
1782             (debug))))
1783          ;;
1784          ((not field))
1785          (t
1786           (debug))
1787          )))
1788       (setq halist (cdr halist)))))
1789
1790 (defun wl-draft-prepare-edit ()
1791   (unless (eq major-mode 'wl-draft-mode)
1792     (error "`wl-draft-create-header' must be use in wl-draft-mode"))
1793   (let (change-major-mode-hook)
1794     (wl-draft-editor-mode)
1795     (static-when (boundp 'auto-save-file-name-transforms)
1796       (make-local-variable 'auto-save-file-name-transforms)
1797       (setq auto-save-file-name-transforms
1798             (cons (list (concat (regexp-quote wl-draft-folder)
1799                                 "/\\([0-9]+\\)")
1800                         (concat (expand-file-name
1801                                  "auto-save-"
1802                                  (elmo-folder-msgdb-path
1803                                   (wl-draft-get-folder)))
1804                                 "\\1"))
1805                   auto-save-file-name-transforms)))
1806     (when wl-draft-write-file-function
1807       (add-hook 'local-write-file-hooks wl-draft-write-file-function))
1808     (wl-draft-overload-functions)
1809     (wl-highlight-headers 'for-draft)
1810     (wl-draft-save)
1811     (clear-visited-file-modtime)))
1812
1813 (defun wl-draft-decode-header ()
1814   (save-excursion
1815     (std11-narrow-to-header)
1816     (wl-draft-decode-message-in-buffer)
1817     (widen)))
1818
1819 (defun wl-draft-decode-body (&optional content-type content-transfer-encoding)
1820   (let ((content-type
1821          (or content-type
1822                 (std11-field-body "content-type")))
1823         (content-transfer-encoding
1824          (or content-transfer-encoding
1825              (std11-field-body "content-transfer-encoding")))
1826         delimline)
1827     (save-excursion
1828       (std11-narrow-to-header)
1829       (wl-draft-delete-field "content-type")
1830       (wl-draft-delete-field "content-transfer-encoding")
1831       (goto-char (point-max))
1832       (setq delimline (point-marker))
1833       (widen)
1834       (narrow-to-region delimline (point-max))
1835       (goto-char (point-min))
1836       (when content-type
1837         (insert "Content-type: " content-type "\n"))
1838       (when content-transfer-encoding
1839         (insert "Content-Transfer-Encoding: " content-transfer-encoding "\n"))
1840       (wl-draft-decode-message-in-buffer)
1841       (goto-char (point-min))
1842       (unless (re-search-forward "^$" (point-at-eol) t)
1843         (insert "\n"))
1844       (widen)
1845       delimline)))
1846
1847 ;;; subroutine for wl-draft-create-contents
1848 ;;; must be used in wl-draft-mode
1849 (defun wl-draft-check-new-line ()
1850   (if (not (= (preceding-char) ?\n))
1851       (insert ?\n)))
1852
1853 (defsubst wl-draft-trim-ccs (cc)
1854   (let ((field
1855          (if (functionp cc)
1856              (funcall cc)
1857            cc)))
1858     (if (and field
1859              (null (and wl-draft-delete-myself-from-bcc-fcc
1860                         (elmo-list-member
1861                          (mapcar 'wl-address-header-extract-address
1862                                  (append
1863                                   (wl-parse-addresses (std11-field-body "To"))
1864                                   (wl-parse-addresses (std11-field-body "Cc"))))
1865                          (mapcar 'downcase wl-subscribed-mailing-list)))))
1866         field
1867       nil)))
1868
1869 (defsubst wl-draft-default-headers ()
1870   (list
1871    (cons 'Mail-Reply-To (and wl-insert-mail-reply-to
1872                              (wl-address-header-extract-address
1873                               wl-from)))
1874    (cons 'User-Agent wl-generate-mailer-string-function)
1875    (cons 'Reply-To mail-default-reply-to)
1876    (cons 'Bcc (function
1877                (lambda ()
1878                  (wl-draft-trim-ccs
1879                   (or wl-bcc (and mail-self-blind (user-login-name)))))))
1880    (cons 'Fcc (function
1881                (lambda ()
1882                  (wl-draft-trim-ccs wl-fcc))))
1883    (cons 'Organization wl-organization)
1884    (and wl-auto-insert-x-face
1885         (file-exists-p wl-x-face-file)
1886         'wl-draft-insert-x-face-field-here) ;; allow nil
1887    mail-default-headers
1888    ;; check \n at th end of line for `mail-default-headers'
1889    'wl-draft-check-new-line
1890    ))
1891
1892 (defun wl-draft-insert-mail-header-separator (&optional delimline)
1893   (save-excursion
1894     (if delimline
1895         (goto-char delimline)
1896       (goto-char (point-min))
1897       (if (search-forward "\n\n" nil t)
1898           (delete-backward-char 1)
1899         (goto-char (point-max))))
1900     (wl-draft-check-new-line)
1901     (put-text-property (point)
1902                        (progn
1903                          (insert mail-header-separator "\n")
1904                          (1- (point)))
1905                        'category 'mail-header-separator)
1906     (point)))
1907
1908 ;;;;;;;;;;;;;;;;
1909
1910 (defun wl-draft-elmo-nntp-send ()
1911   (let ((elmo-nntp-post-pre-hook wl-news-send-pre-hook)
1912         (elmo-nntp-default-user
1913          (or wl-nntp-posting-user elmo-nntp-default-user))
1914         (elmo-nntp-default-server
1915          (or wl-nntp-posting-server elmo-nntp-default-server))
1916         (elmo-nntp-default-port
1917          (or wl-nntp-posting-port elmo-nntp-default-port))
1918         (elmo-nntp-default-stream-type
1919          (or wl-nntp-posting-stream-type elmo-nntp-default-stream-type))
1920         (elmo-nntp-default-function wl-nntp-posting-function)
1921         condition)
1922     (if (setq condition (cdr (elmo-string-matched-assoc
1923                               (std11-field-body "Newsgroups")
1924                               wl-nntp-posting-config-alist)))
1925         (if (stringp condition)
1926             (setq elmo-nntp-default-server condition)
1927           (while (car condition)
1928             (set (intern (format "elmo-nntp-default-%s"
1929                                  (symbol-name (caar condition))))
1930                  (cdar condition))
1931             (setq condition (cdr condition)))))
1932     (unless elmo-nntp-default-function
1933       (error "wl-draft-nntp-send: posting-function is nil"))
1934     (if (not (elmo-plugged-p elmo-nntp-default-server elmo-nntp-default-port))
1935         (wl-draft-set-sent-message 'news 'unplugged
1936                                    (cons elmo-nntp-default-server
1937                                          elmo-nntp-default-port))
1938       (funcall elmo-nntp-default-function
1939                elmo-nntp-default-server (current-buffer))
1940       (wl-draft-set-sent-message 'news 'sent)
1941       (wl-draft-write-sendlog 'ok 'nntp elmo-nntp-default-server
1942                               (std11-field-body "Newsgroups")
1943                               (std11-field-body "Message-ID")))))
1944
1945 (defun wl-draft-generate-clone-buffer (name &optional local-variables)
1946   "Generate clone of current buffer named NAME."
1947   (let ((editing-buffer (current-buffer)))
1948     (save-excursion
1949       (set-buffer (generate-new-buffer name))
1950       (erase-buffer)
1951       (wl-draft-mode)
1952       (wl-draft-editor-mode)
1953       (insert-buffer editing-buffer)
1954       (message "")
1955       (while local-variables
1956         (make-local-variable (car local-variables))
1957         (set (car local-variables)
1958              (save-excursion
1959                (set-buffer editing-buffer)
1960                (symbol-value (car local-variables))))
1961         (setq local-variables (cdr local-variables)))
1962       (current-buffer))))
1963
1964 (defun wl-draft-remove-text-plain-tag ()
1965   "Remove text/plain tag of mime-edit."
1966   (when (string= (mime-make-text-tag "plain")
1967                  (buffer-substring-no-properties (point-at-bol)(point-at-eol)))
1968     (delete-region (point-at-bol)(1+ (point-at-eol)))))
1969
1970 (defun wl-draft-reedit (number)
1971   (let ((draft-folder (wl-draft-get-folder))
1972         (wl-draft-reedit t)
1973         (num 0)
1974         buffer change-major-mode-hook body-top)
1975     (setq buffer (get-buffer-create (format "%s/%d" wl-draft-folder
1976                                             number)))
1977     (if wl-draft-use-frame
1978         (switch-to-buffer-other-frame buffer)
1979       (switch-to-buffer buffer))
1980     (set-buffer buffer)
1981     (elmo-message-fetch draft-folder number (elmo-make-fetch-strategy 'entire)
1982                         nil (current-buffer))
1983     (elmo-delete-cr-buffer)
1984     (let ((mime-edit-again-ignored-field-regexp
1985            "^\\(Content-.*\\|Mime-Version\\):"))
1986       (wl-draft-decode-message-in-buffer))
1987     (setq body-top (wl-draft-insert-mail-header-separator))
1988     (auto-save-mode -1)
1989     (wl-draft-mode)
1990     (make-local-variable 'truncate-partial-width-windows)
1991     (setq truncate-partial-width-windows nil)
1992     (setq truncate-lines wl-draft-truncate-lines)
1993     (setq wl-sent-message-via nil)
1994     (setq wl-sent-message-queued nil)
1995     (wl-draft-config-info-operation number 'load)
1996     (goto-char (point-min))
1997     (wl-draft-overload-functions)
1998     (wl-draft-editor-mode)
1999     (static-when (boundp 'auto-save-file-name-transforms)
2000       (make-local-variable 'auto-save-file-name-transforms)
2001       (setq auto-save-file-name-transforms
2002             (cons (list (concat (regexp-quote wl-draft-folder)
2003                                 "/\\([0-9]+\\)")
2004                         (concat (expand-file-name
2005                                  "auto-save-"
2006                                  (elmo-folder-msgdb-path
2007                                   (wl-draft-get-folder)))
2008                                 "\\1"))
2009                   auto-save-file-name-transforms)))
2010     (setq buffer-file-name (buffer-name)
2011           wl-draft-parent-folder ""
2012           wl-draft-buffer-message-number number)
2013     (when wl-draft-write-file-function
2014       (add-hook 'local-write-file-hooks wl-draft-write-file-function))
2015     (wl-highlight-headers 'for-draft)
2016     (goto-char body-top)
2017     (run-hooks 'wl-draft-reedit-hook)
2018     (goto-char (point-max))
2019     buffer))
2020
2021 (defmacro wl-draft-body-goto-top ()
2022   (` (progn
2023        (goto-char (point-min))
2024        (if (re-search-forward mail-header-separator nil t)
2025            (forward-char 1)
2026          (goto-char (point-max))))))
2027
2028 (defmacro wl-draft-body-goto-bottom ()
2029   (` (goto-char (point-max))))
2030
2031 (defmacro wl-draft-config-body-goto-header ()
2032   (` (progn
2033        (goto-char (point-min))
2034        (if (re-search-forward mail-header-separator nil t)
2035            (beginning-of-line)
2036          (goto-char (point-max))))))
2037
2038 (defsubst wl-draft-config-sub-eval-insert (content &optional newline)
2039   (let (content-value)
2040     (when (and content
2041                (stringp (setq content-value (eval content))))
2042       (insert content-value)
2043       (if newline (insert "\n")))))
2044
2045 (defun wl-draft-config-sub-body (content)
2046   (wl-draft-body-goto-top)
2047   (delete-region (point) (point-max))
2048   (wl-draft-config-sub-eval-insert content))
2049
2050 (defun wl-draft-config-sub-top (content)
2051   (wl-draft-body-goto-top)
2052   (wl-draft-config-sub-eval-insert content))
2053
2054 (defun wl-draft-config-sub-bottom (content)
2055   (wl-draft-body-goto-bottom)
2056   (wl-draft-config-sub-eval-insert content))
2057
2058 (defun wl-draft-config-sub-header (content)
2059   (wl-draft-config-body-goto-header)
2060   (wl-draft-config-sub-eval-insert content 'newline))
2061
2062 (defun wl-draft-config-sub-header-top (content)
2063   (goto-char (point-min))
2064   (wl-draft-config-sub-eval-insert content 'newline))
2065
2066 (defun wl-draft-config-sub-part-top (content)
2067   (goto-char (mime-edit-content-beginning))
2068   (wl-draft-config-sub-eval-insert content 'newline))
2069
2070 (defun wl-draft-config-sub-part-bottom (content)
2071   (goto-char (mime-edit-content-end))
2072   (wl-draft-config-sub-eval-insert content 'newline))
2073
2074 (defsubst wl-draft-config-sub-file (content)
2075   (let ((coding-system-for-read wl-cs-autoconv)
2076         (file (expand-file-name (eval content))))
2077     (if (file-exists-p file)
2078         (insert-file-contents file)
2079       (error "%s: no exists file" file))))
2080
2081 (defun wl-draft-config-sub-body-file (content)
2082   (wl-draft-body-goto-top)
2083   (delete-region (point) (point-max))
2084   (wl-draft-config-sub-file content))
2085
2086 (defun wl-draft-config-sub-top-file (content)
2087   (wl-draft-body-goto-top)
2088   (wl-draft-config-sub-file content))
2089
2090 (defun wl-draft-config-sub-bottom-file (content)
2091   (wl-draft-body-goto-bottom)
2092   (wl-draft-config-sub-file content))
2093
2094 (defun wl-draft-config-sub-header-file (content)
2095   (wl-draft-config-body-goto-header)
2096   (wl-draft-config-sub-file content))
2097
2098 (defun wl-draft-config-sub-template (content)
2099   (setq wl-draft-config-variables
2100         (wl-template-insert (eval content))))
2101
2102 (defun wl-draft-config-sub-x-face (content)
2103   (if (and (string-match "\\.xbm\\(\\.gz\\)?$" content)
2104            (fboundp 'x-face-insert)) ; x-face.el is installed.
2105       (x-face-insert content)
2106     (wl-draft-replace-field "X-Face" (elmo-get-file-string content t) t)))
2107
2108 (defsubst wl-draft-config-sub-func (field content)
2109   (let (func)
2110     (if (setq func (assq field wl-draft-config-sub-func-alist))
2111         (let (wl-draft-config-variables)
2112           (funcall (cdr func) content)
2113           ;; for wl-draft-config-sub-template
2114           (cons t wl-draft-config-variables)))))
2115
2116 (defsubst wl-draft-config-exec-sub (clist)
2117   (let (config local-variables)
2118     (while clist
2119       (setq config (car clist))
2120       (cond
2121        ((functionp config)
2122         (funcall config))
2123        ((consp config)
2124         (let ((field (car config))
2125               (content (cdr config))
2126               ret-val)
2127           (cond
2128            ((stringp field)
2129             (wl-draft-replace-field field (eval content) t))
2130            ((setq ret-val (wl-draft-config-sub-func field content))
2131             (if (cdr ret-val) ;; for wl-draft-config-sub-template
2132                 (wl-append local-variables (cdr ret-val))))
2133            ((boundp field) ;; variable
2134             (make-local-variable field)
2135             (set field (eval content))
2136             (wl-append local-variables (list field)))
2137            (t
2138             (error "%s: not variable" field)))))
2139        (t
2140         (error "%s: not supported type" config)))
2141       (setq clist (cdr clist)))
2142     local-variables))
2143
2144 (defun wl-draft-prepared-config-exec (&optional config-alist reply-buf)
2145   "Change headers in draft preparation time."
2146   (interactive)
2147   (unless wl-draft-reedit
2148     (let ((config-alist
2149            (or config-alist
2150                (and (boundp 'wl-draft-prepared-config-alist)
2151                     wl-draft-prepared-config-alist)     ;; For compatible.
2152                wl-draft-config-alist)))
2153       (if config-alist
2154           (wl-draft-config-exec config-alist reply-buf)))))
2155
2156 (defun wl-draft-config-exec (&optional config-alist reply-buf)
2157   "Change headers according to the value of `wl-draft-config-alist'.
2158 Automatically applied in draft sending time."
2159   (interactive)
2160   (let ((case-fold-search t)
2161         (alist (or config-alist wl-draft-config-alist))
2162         (reply-buf (or reply-buf (and (buffer-live-p wl-draft-reply-buffer)
2163                                       wl-draft-reply-buffer)))
2164         (local-variables wl-draft-config-variables)
2165         key clist found)
2166     (when (and (or (interactive-p)
2167                    wl-draft-config-exec-flag)
2168                alist)
2169       (save-excursion
2170         (catch 'done
2171           (while alist
2172             (setq key (caar alist)
2173                   clist (cdar alist))
2174             (cond
2175              ((eq key 'reply)
2176               (when (and
2177                      reply-buf
2178                      (save-excursion
2179                        (set-buffer reply-buf)
2180                        (save-restriction
2181                          (std11-narrow-to-header)
2182                          (goto-char (point-min))
2183                          (re-search-forward (car clist) nil t))))
2184                 (wl-draft-config-exec-sub (cdr clist))
2185                 (setq found t)))
2186              ((stringp key)
2187               (when (save-restriction
2188                       (std11-narrow-to-header mail-header-separator)
2189                       (goto-char (point-min))
2190                       (re-search-forward key nil t))
2191                 (wl-append local-variables
2192                            (wl-draft-config-exec-sub clist))
2193                 (setq found t)))
2194              ((eval key)
2195               (wl-append local-variables
2196                          (wl-draft-config-exec-sub clist))
2197               (setq found t)))
2198             (if (and found wl-draft-config-matchone)
2199                 (throw 'done t))
2200             (setq alist (cdr alist))))
2201         (if found
2202             (setq wl-draft-config-exec-flag nil))
2203         (run-hooks 'wl-draft-config-exec-hook)
2204         (put-text-property (point-min)(point-max) 'face nil)
2205         (wl-highlight-message (point-min)(point-max) t)
2206         (setq wl-draft-config-variables
2207               (elmo-uniq-list local-variables))))))
2208
2209 (defun wl-draft-replace-field (field content &optional add)
2210   (save-excursion
2211     (save-restriction
2212       (let ((case-fold-search t)
2213             (inhibit-read-only t) ;; added by teranisi.
2214             beg)
2215         (std11-narrow-to-header mail-header-separator)
2216         (goto-char (point-min))
2217         (if (re-search-forward (concat "^" (regexp-quote field) ":") nil t)
2218             (if content
2219                 ;; replace field
2220                 (progn
2221                   (setq beg (point))
2222                   (re-search-forward "^[^ \t]" nil 'move)
2223                   (beginning-of-line)
2224                   (skip-chars-backward "\n")
2225                   (delete-region beg (point))
2226                   (insert " " content))
2227               ;; delete field
2228               (save-excursion
2229                 (beginning-of-line)
2230                 (setq beg (point)))
2231               (re-search-forward "^[^ \t]" nil 'move)
2232               (beginning-of-line)
2233               (delete-region beg (point)))
2234           (when (and add content)
2235             ;; add field
2236             (goto-char (point-max))
2237             (insert (concat field ": " content "\n"))))))))
2238
2239 (defun wl-draft-config-info-operation (msg operation)
2240   (let* ((msgdb-dir (elmo-folder-msgdb-path (wl-draft-get-folder)))
2241          (filename
2242           (expand-file-name
2243            (format "%s-%d" wl-draft-config-save-filename msg)
2244            msgdb-dir))
2245          element alist variable)
2246     (cond
2247      ((eq operation 'save)
2248       (let ((variables (elmo-uniq-list wl-draft-config-variables)))
2249         (while (setq variable (pop variables))
2250           (when (boundp variable)
2251             (wl-append alist
2252                        (list (cons variable (eval variable))))))
2253         (elmo-object-save filename alist)))
2254      ((eq operation 'load)
2255       (setq alist (elmo-object-load filename))
2256       (while (setq element (pop alist))
2257         (set (make-local-variable (car element)) (cdr element))
2258         (wl-append wl-draft-config-variables (list (car element)))))
2259      ((eq operation 'delete)
2260       (if (file-exists-p filename)
2261           (delete-file filename))))))
2262
2263 (defun wl-draft-queue-info-operation (msg operation
2264                                           &optional add-sent-message-via)
2265   (let* ((msgdb-dir (elmo-folder-msgdb-path
2266                      (wl-folder-get-elmo-folder wl-queue-folder)))
2267          (filename
2268           (expand-file-name
2269            (format "%s-%d" wl-draft-queue-save-filename msg)
2270            msgdb-dir))
2271          element alist variable)
2272     (cond
2273      ((eq operation 'save)
2274       (let ((variables (elmo-uniq-list
2275                         (append wl-draft-queue-save-variables
2276                                 wl-draft-config-variables
2277                                 (list 'wl-draft-fcc-list)))))
2278         (if add-sent-message-via
2279             (progn
2280               (push 'wl-sent-message-queued variables)
2281               (push 'wl-sent-message-via variables)))
2282         (while (setq variable (pop variables))
2283           (when (boundp variable)
2284             (wl-append alist
2285                        (list (cons variable (eval variable))))))
2286         (elmo-object-save filename alist)))
2287      ((eq operation 'load)
2288       (setq alist (elmo-object-load filename))
2289       (while (setq element (pop alist))
2290         (set (make-local-variable (car element)) (cdr element))))
2291      ((eq operation 'get-sent-via)
2292       (setq alist (elmo-object-load filename))
2293       (cdr (assq 'wl-sent-message-via alist)))
2294      ((eq operation 'delete)
2295       (if (file-exists-p filename)
2296           (delete-file filename))))))
2297
2298 (defun wl-draft-queue-append (wl-sent-message-via)
2299   (if wl-draft-verbose-send
2300       (message "Queuing..."))
2301   (let ((send-buffer (current-buffer))
2302         (folder (wl-folder-get-elmo-folder wl-queue-folder))
2303         (message-id (std11-field-body "Message-ID")))
2304     (if (elmo-folder-append-buffer folder)
2305         (progn
2306           (wl-draft-queue-info-operation
2307            (car (elmo-folder-status folder))
2308            'save wl-sent-message-via)
2309           (wl-draft-write-sendlog 'ok 'queue nil wl-queue-folder message-id)
2310           (when wl-draft-verbose-send
2311             (setq wl-draft-verbose-msg "Queuing...")
2312             (message "Queuing...done")))
2313       (wl-draft-write-sendlog 'failed 'queue nil wl-queue-folder message-id)
2314       (error "Queuing failed"))))
2315
2316 (defun wl-draft-queue-flush ()
2317   "Flush draft queue."
2318   (interactive)
2319   (let* ((queue-folder (wl-folder-get-elmo-folder wl-queue-folder))
2320          (msgs2 (progn
2321                   (elmo-folder-open-internal queue-folder)
2322                   (elmo-folder-list-messages queue-folder)))
2323          (i 0)
2324          (performed 0)
2325          (wl-draft-queue-flushing t)
2326          msgs failure len buffer msgid sent-via)
2327     ;; get plugged send message
2328     (while msgs2
2329       (setq sent-via (wl-draft-queue-info-operation (car msgs2) 'get-sent-via))
2330       (catch 'found
2331         (while sent-via
2332           (when (and (eq (nth 1 (car sent-via)) 'unplugged)
2333                      (or (not (nth 2 (car sent-via)))
2334                          (elmo-plugged-p
2335                           (car (nth 2 (car sent-via)))
2336                           (cdr (nth 2 (car sent-via))))))
2337             (wl-append msgs (list (car msgs2)))
2338             (throw 'found t))
2339           (setq sent-via (cdr sent-via))))
2340       (setq msgs2 (cdr msgs2)))
2341     (when (> (setq len (length msgs)) 0)
2342       (if (elmo-y-or-n-p (format
2343                           "%d message(s) are in the sending queue.  Send now? "
2344                           len)
2345                          (not elmo-dop-flush-confirm) t)
2346           (progn
2347             (save-excursion
2348               (setq buffer (get-buffer-create " *wl-draft-queue-flush*"))
2349               (set-buffer buffer)
2350               (while msgs
2351                 ;; reset buffer local variables
2352                 (kill-all-local-variables)
2353                 (erase-buffer)
2354                 (setq i (+ 1 i)
2355                       failure nil)
2356                 (setq wl-sent-message-via nil)
2357                 (wl-draft-queue-info-operation (car msgs) 'load)
2358                 (elmo-message-fetch queue-folder
2359                                     (car msgs)
2360                                     (elmo-make-fetch-strategy 'entire)
2361                                     nil (current-buffer))
2362                 (condition-case err
2363                     (setq failure (funcall
2364                                    wl-draft-queue-flush-send-function
2365                                    (format "Sending (%d/%d)..." i len)))
2366 ;;;               (wl-draft-raw-send nil nil
2367 ;;;                                  (format "Sending (%d/%d)..." i len))
2368                   (error
2369                    (elmo-display-error err t)
2370                    (setq failure t))
2371                   (quit
2372                    (setq failure t)))
2373                 (if (eq wl-sent-message-modified 'requeue)
2374                     (progn
2375                       (elmo-folder-delete-messages
2376                        queue-folder (cons (car msgs) nil))
2377                       (wl-draft-queue-info-operation (car msgs) 'delete))
2378                   (unless failure
2379                     (elmo-folder-delete-messages
2380                      queue-folder (cons (car msgs) nil))
2381                     (wl-draft-queue-info-operation (car msgs) 'delete)
2382                     (setq performed (+ 1 performed))))
2383                 (setq msgs (cdr msgs)))
2384               (kill-buffer buffer)
2385               (message "%d message(s) are sent." performed)))
2386         (message "%d message(s) are remained to be sent." len))
2387       (elmo-folder-close queue-folder)
2388       len)))
2389
2390 (defun wl-jump-to-draft-buffer (&optional arg)
2391   "Jump to the draft if exists."
2392   (interactive "P")
2393   (if arg
2394       (wl-jump-to-draft-folder)
2395     (let ((draft-bufs (wl-collect-draft))
2396           buf)
2397       (cond
2398        ((null draft-bufs)
2399         (message "No draft buffer exist."))
2400        (t
2401         (setq draft-bufs
2402               (sort (mapcar 'buffer-name draft-bufs)
2403                     (function (lambda (a b)
2404                                 (not (string< a b))))))
2405         (if (setq buf (cdr (member (buffer-name)
2406                                    draft-bufs)))
2407             (setq buf (car buf))
2408           (setq buf (car draft-bufs)))
2409         (switch-to-buffer buf))))))
2410
2411 (defun wl-jump-to-draft-folder ()
2412   (let ((msgs (reverse (elmo-folder-list-messages (wl-draft-get-folder))))
2413         (mybuf (buffer-name))
2414         msg buf)
2415     (if (not msgs)
2416         (message "No draft message exist.")
2417       (if (string-match (concat "^" wl-draft-folder "/") mybuf)
2418           (setq msg (cadr (memq
2419                            (string-to-int (substring mybuf (match-end 0)))
2420                            msgs))))
2421       (or msg (setq msg (car msgs)))
2422       (if (setq buf (get-buffer (format "%s/%d" wl-draft-folder msg)))
2423           (switch-to-buffer buf)
2424         (wl-draft-reedit msg)))))
2425
2426 (defun wl-draft-highlight-and-recenter (&optional n)
2427   (interactive "P")
2428   (when wl-highlight-body-too
2429     (let ((modified (buffer-modified-p)))
2430       (unwind-protect
2431           (progn
2432             (put-text-property (point-min) (point-max) 'face nil)
2433             (wl-highlight-message (point-min) (point-max) t))
2434         (set-buffer-modified-p modified))))
2435   (static-when (featurep 'xemacs)
2436     ;; Cope with one of many XEmacs bugs that `recenter' takes
2437     ;; a long time if there are a lot of invisible text lines.
2438     (redraw-frame))
2439   (recenter n))
2440
2441 ;; insert element from history
2442 (defvar wl-draft-current-history-position nil)
2443 (defvar wl-draft-history-backup-word "")
2444
2445 (defun wl-draft-previous-history-element (n)
2446   (interactive "p")
2447   (let (bol history beg end prev new)
2448     (when (and (not (wl-draft-on-field-p))
2449                (< (point)
2450                   (save-excursion
2451                     (goto-char (point-min))
2452                     (search-forward (concat "\n" mail-header-separator "\n") nil 0)
2453                     (point)))
2454                (save-excursion
2455                  (beginning-of-line)
2456                  (while (and (looking-at "^[ \t]")
2457                              (not (= (point) (point-min))))
2458                    (forward-line -1))
2459                  (cond
2460                   ((looking-at wl-folder-complete-header-regexp)
2461                    (and (boundp 'wl-read-folder-history)
2462                         (setq history wl-read-folder-history)))
2463                   ;; ((looking-at wl-address-complete-header-regexp)
2464                   ;;  (setq history .....))
2465                   (t
2466                    nil)))
2467                (eolp))
2468       (setq bol (save-excursion (beginning-of-line) (point)))
2469       (cond ((and (or (eq last-command 'wl-draft-previous-history-element)
2470                       (eq last-command 'wl-draft-next-history-element))
2471                   wl-draft-current-history-position)
2472              (setq end (point))
2473              (or (search-backward-regexp ",[ \t]*\\(.*\\)" bol t)
2474                  (search-backward-regexp "^[ \t]\\(.*\\)" bol t)
2475                  (search-backward-regexp "^[^ \t]*: \\(.*\\)" bol t))
2476              (setq prev (match-string 1))
2477              (goto-char (match-beginning 1))
2478              (setq beg (point))
2479              (if (cond ((< n 0)
2480                         (>= (+ n wl-draft-current-history-position) 0))
2481                        ((> n 0)
2482                         (<= (+ n wl-draft-current-history-position)
2483                             (length history))))
2484                  (progn
2485                    (setq wl-draft-current-history-position
2486                          (+ n wl-draft-current-history-position))
2487                    (setq new
2488                          (nth wl-draft-current-history-position
2489                               (append (list wl-draft-history-backup-word)
2490                                       history)))
2491                    (delete-region beg end)
2492                    (insert new))
2493                (goto-char end)
2494                (cond ((< n 0)
2495                       (message "End of history; no next item"))
2496                      ((> n 0)
2497                       (message "Beginning of history; no preceding item")))))
2498             ((and (> n 0)
2499                   (save-excursion
2500                     (or (search-backward-regexp ",[ \t]*\\(.*\\)" bol t)
2501                         (search-backward-regexp "^[ \t]\\(.*\\)" bol t)
2502                         (search-backward-regexp "^[^ \t]*: \\(.*\\)" bol t)))
2503                   (car history))
2504              (setq wl-draft-current-history-position 1)
2505              (setq wl-draft-history-backup-word (match-string 1))
2506              (delete-region (match-beginning 1) (match-end 1))
2507              (insert (car history)))
2508             (t
2509              (setq wl-draft-current-history-position nil))))))
2510
2511 (defun wl-draft-next-history-element (n)
2512   (interactive "p")
2513   (wl-draft-previous-history-element (- n)))
2514
2515 ;;;; user-agent support by Sen Nagata
2516
2517 ;; this appears to be necessarily global...
2518 (defvar wl-user-agent-compose-p nil)
2519 (defvar wl-user-agent-headers-and-body-alist nil)
2520
2521 ;; this should be a generic function for mail-mode -- i wish there was
2522 ;; something like it in sendmail.el
2523 (defun wl-user-agent-insert-header (header-name header-value)
2524   "Insert HEADER-NAME w/ value HEADER-VALUE into a message."
2525   ;; it seems like overriding existing headers is acceptable -- should
2526   ;; we provide an option?
2527
2528   ;; plan was: unfold header (might be folded), remove existing value, insert
2529   ;;           new value
2530   ;; wl doesn't seem to fold header lines yet anyway :-)
2531
2532   (let ((kill-whole-line t)
2533         end-of-line)
2534     (mail-position-on-field (capitalize header-name))
2535     (setq end-of-line (point))
2536     (beginning-of-line)
2537     (re-search-forward ":" end-of-line)
2538     (insert (concat " " header-value "\n"))
2539     (kill-line)))
2540
2541 ;; this should be a generic function for mail-mode -- i wish there was
2542 ;; something like it in sendmail.el
2543 ;;
2544 ;; ** haven't dealt w/ case where the body is already set **
2545 (defun wl-user-agent-insert-body (body-text)
2546   "Insert a body of text, BODY-TEXT, into a message."
2547   ;; code defensively... :-P
2548   (goto-char (point-min))
2549   (search-forward mail-header-separator)
2550   (forward-line 1)
2551   (insert body-text))
2552
2553 ;;;###autoload
2554 (defun wl-user-agent-compose (&optional to subject other-headers continue
2555                                         switch-function yank-action
2556                                         send-actions)
2557   "Support the `compose-mail' interface for wl.
2558 Only support for TO, SUBJECT, and OTHER-HEADERS has been implemented.
2559 Support for CONTINUE, YANK-ACTION, and SEND-ACTIONS has not
2560 been implemented yet.  Partial support for SWITCH-FUNCTION now supported."
2561
2562   (unless (featurep 'wl)
2563     (require 'wl))
2564   (or switch-function
2565       (setq switch-function 'keep))
2566   ;; protect these -- to and subject get bound at some point, so it looks
2567   ;; to be necessary to protect the values used w/in
2568   (let ((wl-user-agent-headers-and-body-alist other-headers)
2569         (wl-draft-use-frame (eq switch-function 'switch-to-buffer-other-frame))
2570         (wl-draft-buffer-style switch-function))
2571     (if to
2572         (if (wl-string-match-assoc "to" wl-user-agent-headers-and-body-alist
2573                                    'ignore-case)
2574             (setcdr
2575              (wl-string-match-assoc "to" wl-user-agent-headers-and-body-alist
2576                                     'ignore-case)
2577              to)
2578           (setq wl-user-agent-headers-and-body-alist
2579                 (cons (cons "to" to)
2580                       wl-user-agent-headers-and-body-alist))))
2581     (if subject
2582         (if (wl-string-match-assoc "subject"
2583                                    wl-user-agent-headers-and-body-alist
2584                                    'ignore-case)
2585             (setcdr
2586              (wl-string-match-assoc "subject"
2587                                     wl-user-agent-headers-and-body-alist
2588                                     'ignore-case)
2589              subject)
2590           (setq wl-user-agent-headers-and-body-alist
2591                 (cons (cons "subject" subject)
2592                       wl-user-agent-headers-and-body-alist))))
2593     ;; i think this is what we want to use...
2594     (unwind-protect
2595         (progn
2596           ;; tell the hook-function to do its stuff
2597           (setq wl-user-agent-compose-p t)
2598           ;; because to get the hooks working, wl-draft has to think it has
2599           ;; been called interactively
2600           (call-interactively 'wl-draft))
2601       (setq wl-user-agent-compose-p nil))))
2602
2603 (defun wl-user-agent-compose-internal ()
2604   "Manipulate headers and/or a body of a draft message."
2605   ;; being called from wl-user-agent-compose?
2606   (if wl-user-agent-compose-p
2607       (progn
2608         ;; insert headers
2609         (let ((headers wl-user-agent-headers-and-body-alist)
2610               (case-fold-search t))
2611           (while headers
2612             ;; skip body
2613             (if (not (string-match "^body$" (car (car headers))))
2614                 (wl-user-agent-insert-header
2615                  (car (car headers)) (cdr (car headers)))
2616               t)
2617             (setq headers (cdr headers))))
2618         ;; highlight headers (from wl-draft in wl-draft.el)
2619         (wl-highlight-headers 'for-draft)
2620         ;; insert body
2621         (if (wl-string-match-assoc "body" wl-user-agent-headers-and-body-alist
2622                                    'ignore-case)
2623             (wl-user-agent-insert-body
2624              (cdr (wl-string-match-assoc
2625                    "body"
2626                    wl-user-agent-headers-and-body-alist 'ignore-case)))))
2627     t))
2628
2629 (require 'product)
2630 (product-provide (provide 'wl-draft) (require 'wl-version))
2631
2632 ;;; wl-draft.el ends here