wl/wl-expire.el

   1 ;;; wl-expire.el -- Message expire modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Masahiro MURATA <muse@ba2.so-net.ne.jp>
   4 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   5
   6 ;; Author: Masahiro MURATA <muse@ba2.so-net.ne.jp>
   7 ;; Keywords: mail, net news
   8
   9 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29
  30 (require 'wl-summary)
  31 (require 'wl-thread)
  32 (require 'wl-folder)
  33 (require 'elmo)
  34
  35 ;;; Code:
  36
  37 (eval-when-compile
  38   (require 'wl-util)
  39   (require 'elmo-archive))
  40
  41 ;; Variables
  42
  43 (defvar wl-expired-alist nil)
  44 (defvar wl-expired-alist-file-name "expired-alist")
  45 (defvar wl-expired-log-alist nil)
  46 (defvar wl-expired-log-alist-file-name "expired-log")
  47
  48 (defun wl-expired-alist-load ()
  49   (elmo-object-load (expand-file-name
  50                      wl-expired-alist-file-name
  51                      elmo-msgdb-dir)))
  52
  53 (defun wl-expired-alist-save (&optional alist)
  54   (elmo-object-save (expand-file-name
  55                      wl-expired-alist-file-name
  56                      elmo-msgdb-dir)
  57                     (or alist wl-expired-alist)))
  58
  59 (defsubst wl-expire-msg-p (msg-num mark-alist)
  60   (cond ((consp wl-summary-expire-reserve-marks)
  61          (let ((mark (nth 1 (assq msg-num mark-alist))))
  62            (not (or (member mark wl-summary-expire-reserve-marks)
  63                     (and wl-summary-buffer-disp-msg
  64                          (eq msg-num wl-summary-buffer-current-msg))))))
  65         ((eq wl-summary-expire-reserve-marks 'all)
  66          (not (or (assq msg-num mark-alist)
  67                   (and wl-summary-buffer-disp-msg
  68                        (eq msg-num wl-summary-buffer-current-msg)))))
  69         ((eq wl-summary-expire-reserve-marks 'none)
  70          t)
  71         (t
  72          (error "Invalid marks: %s" wl-summary-expire-reserve-marks))))
  73
  74 (defmacro wl-expire-make-sortable-date (date)
  75   (` (timezone-make-sortable-date
  76       (aref (, date) 0) (aref (, date) 1) (aref (, date) 2)
  77       (timezone-make-time-string
  78        (aref (, date) 3) (aref (, date) 4) (aref (, date) 5)))))
  79
  80 (defsubst wl-expire-date-p (key-datevec date)
  81   (let ((datevec (condition-case nil
  82                      (timezone-fix-time date nil nil)
  83                    (error nil))))
  84     (and
  85      datevec (> (aref datevec 1) 0)
  86      (string<
  87       (wl-expire-make-sortable-date datevec)
  88       (wl-expire-make-sortable-date key-datevec)))))
  89
  90 (defun wl-expire-delete-reserve-marked-msgs-from-list (msgs mark-alist)
  91   (let ((dlist msgs))
  92     (while dlist
  93       (unless (wl-expire-msg-p (car dlist) mark-alist)
  94         (setq msgs (delq (car dlist) msgs)))
  95       (setq dlist (cdr dlist)))
  96     msgs))
  97
  98 (defun wl-expire-delete (folder delete-list msgdb &optional no-reserve-marks)
  99   "Delete message for expire."
 100   (unless no-reserve-marks
 101     (setq delete-list
 102           (wl-expire-delete-reserve-marked-msgs-from-list
 103            delete-list (elmo-msgdb-get-mark-alist msgdb))))
 104   (when delete-list
 105    (let ((mess
 106          (format "Expiring (delete) %s msgs..."
 107                  (length delete-list))))
 108     (message "%s" mess)
 109     (if (elmo-folder-delete-messages folder
 110                                      delete-list)
 111         (progn
 112           (elmo-msgdb-delete-msgs folder
 113                                   delete-list)
 114           (wl-expire-append-log folder delete-list nil 'delete)
 115           (message "%s" (concat mess "done")))
 116       (error (concat mess "failed!")))))
 117   (cons delete-list (length delete-list)))
 118
 119 (defun wl-expire-refile (folder refile-list msgdb dst-folder
 120                                 &optional no-reserve-marks preserve-number copy)
 121   "Refile message for expire. If COPY is non-nil, copy message."
 122   (when (not (string= folder dst-folder))
 123     (unless no-reserve-marks
 124       (setq refile-list
 125             (wl-expire-delete-reserve-marked-msgs-from-list
 126              refile-list (elmo-msgdb-get-mark-alist msgdb))))
 127     (when refile-list
 128      (let* ((doingmes (if copy
 129                           "Copying %s"
 130                         "Expiring (move %s)"))
 131             (mess (format (concat doingmes " %s msgs...")
 132                           (elmo-folder-name-internal dst-folder)
 133                           (length refile-list))))
 134        (message "%s" mess)
 135        (unless (or (elmo-folder-exists-p dst-folder)
 136                    (elmo-folder-create dst-folder))
 137          (error "%s: create folder failed" dst-folder))
 138        (if (elmo-folder-move-messages folder
 139                                       refile-list
 140                                       dst-folder
 141                                       msgdb
 142                                       nil nil t
 143                                       copy
 144                                       preserve-number
 145                                       nil
 146                                       wl-expire-add-seen-list)
 147            (progn
 148              (wl-expire-append-log
 149               folder refile-list dst-folder (if copy 'copy 'move))
 150              (message "%s" (concat mess "done")))
 151          (error (concat mess "failed!")))))
 152     (cons refile-list (length refile-list))))
 153
 154 (defun wl-expire-refile-with-copy-reserve-msg
 155   (folder refile-list msgdb dst-folder
 156           &optional no-reserve-marks preserve-number copy)
 157   "Refile message for expire.
 158 If REFILE-LIST includes reserve mark message, so copy."
 159   (when (not (string= (elmo-folder-name-internal folder) dst-folder))
 160     (let ((msglist refile-list)
 161           (mark-alist (elmo-msgdb-get-mark-alist (elmo-folder-msgdb-internal folder)))
 162           (number-alist (elmo-msgdb-get-number-alist (elmo-folder-msgdb-internal folder)))
 163           (dst-folder (wl-folder-get-elmo-folder dst-folder))
 164           (ret-val t)
 165           (copy-reserve-message)
 166           (copy-len 0)
 167           msg msg-id)
 168       (message "Expiring (move %s) %s msgs..."
 169                (elmo-folder-name-internal dst-folder) (length refile-list))
 170       (unless (or (elmo-folder-exists-p dst-folder)
 171                   (elmo-folder-create dst-folder))
 172         (error "%s: create folder failed" (elmo-folder-name-internal
 173                                            dst-folder)))
 174       (while (setq msg (wl-pop msglist))
 175         (unless (wl-expire-msg-p msg mark-alist)
 176           (setq msg-id (cdr (assq msg number-alist)))
 177           (if (assoc msg-id wl-expired-alist)
 178               ;; reserve mark message already refiled or expired
 179               (setq refile-list (delq msg refile-list))
 180             ;; reserve mark message not refiled
 181             (wl-append wl-expired-alist (list (cons msg-id
 182                                                     (elmo-folder-name-internal
 183                                                      dst-folder))))
 184             (setq copy-reserve-message t))))
 185       (when refile-list
 186         (unless
 187             (setq ret-val
 188                   (elmo-folder-move-messages folder
 189                                              refile-list
 190                                              dst-folder
 191                                              msgdb
 192                                              nil nil t
 193                                              copy-reserve-message
 194                                              preserve-number
 195                                              nil
 196                                              wl-expire-add-seen-list
 197                                              ))
 198           (error "Expire: move msgs to %s failed"
 199                  (elmo-folder-name-internal dst-folder)))
 200         (wl-expire-append-log (elmo-folder-name-internal folder)
 201                               refile-list
 202                               (elmo-folder-name-internal dst-folder)
 203                               (if copy-reserve-message 'copy 'move))
 204         (setq copy-len (length refile-list))
 205         (when copy-reserve-message
 206           (setq refile-list
 207                 (wl-expire-delete-reserve-marked-msgs-from-list
 208                  refile-list
 209                  mark-alist))
 210           (when refile-list
 211            (if (setq ret-val
 212                      (elmo-folder-delete-messages folder
 213                                                   refile-list))
 214                (progn
 215                  (elmo-msgdb-delete-msgs folder
 216                                          refile-list)
 217                  (wl-expire-append-log folder refile-list nil 'delete))))))
 218       (let ((mes (format "Expiring (move %s) %s msgs..."
 219                          (elmo-folder-name-internal dst-folder)
 220                          (length refile-list))))
 221         (if ret-val
 222             (message (concat mes "done"))
 223           (error (concat mes "failed!"))))
 224       (cons refile-list copy-len))))
 225
 226 (defun wl-expire-archive-get-folder (src-folder &optional fmt)
 227   "Get archive folder name from SRC-FOLDER."
 228   (let* ((fmt (or fmt wl-expire-archive-folder-name-fmt))
 229          (archive-spec (char-to-string
 230                         (car (rassq 'archive elmo-folder-type-alist))))
 231          dst-folder-base dst-folder-fmt prefix)
 232     (cond ((eq (elmo-folder-type-internal src-folder) 'localdir)
 233            (setq dst-folder-base
 234                  (concat archive-spec
 235                          (elmo-folder-name-internal src-folder))))
 236           (t
 237            (setq dst-folder-base
 238                  (elmo-concat-path
 239                   (format "%s%s" archive-spec (elmo-folder-type-internal
 240                                                src-folder))
 241                   (substring (elmo-folder-name-internal src-folder)
 242                              (length (elmo-folder-prefix-internal src-folder)))))))
 243     (setq dst-folder-fmt (format fmt
 244                                  dst-folder-base
 245                                  wl-expire-archive-folder-type))
 246     (setq dst-folder-base (format "%s;%s"
 247                                   dst-folder-base
 248                                   wl-expire-archive-folder-type))
 249     (when wl-expire-archive-folder-prefix
 250       (cond ((eq wl-expire-archive-folder-prefix 'short)
 251              (setq prefix (file-name-nondirectory
 252                            (elmo-folder-name-internal src-folder))))
 253             (t
 254              (setq prefix (elmo-folder-name-internal src-folder))))
 255       (setq dst-folder-fmt (concat dst-folder-fmt ";" prefix))
 256       (setq dst-folder-base (concat dst-folder-base ";" prefix)))
 257     (cons dst-folder-base dst-folder-fmt)))
 258
 259 (defsubst wl-expire-archive-get-max-number (dst-folder-base &optional regexp)
 260   (let ((files (reverse (sort (elmo-folder-list-subfolders
 261                                (elmo-make-folder dst-folder-base))
 262                               'string<)))
 263         (regexp (or regexp wl-expire-archive-folder-num-regexp))
 264         filenum in-folder)
 265     (catch 'done
 266       (while files
 267         (when (string-match regexp (car files))
 268           (setq filenum (elmo-match-string 1 (car files)))
 269           (setq in-folder (elmo-folder-status
 270                            (wl-folder-get-elmo-folder (car files))))
 271           (throw 'done (cons in-folder filenum)))
 272         (setq files (cdr files))))))
 273
 274 (defun wl-expire-archive-number-delete-old (dst-folder-base
 275                                             preserve-number msgs mark-alist
 276                                             &optional no-confirm regexp file)
 277   (let ((len 0) (max-num 0)
 278         folder-info dels)
 279     (if (or (and file (setq folder-info
 280                             (cons (elmo-folder-status
 281                                    (wl-folder-get-elmo-folder file))
 282                                   nil)))
 283             (setq folder-info (wl-expire-archive-get-max-number
 284                                dst-folder-base
 285                                regexp)))
 286         (progn
 287           (setq len (cdar folder-info))
 288           (when preserve-number
 289             ;; delete small number than max number of dst-folder
 290             (setq max-num (caar folder-info))
 291             (while (and msgs (>= max-num (car msgs)))
 292               (wl-append dels (list (car msgs)))
 293               (setq msgs (cdr msgs)))
 294             (setq dels (wl-expire-delete-reserve-marked-msgs-from-list
 295                         dels mark-alist))
 296             (unless (and dels
 297                          (or (or no-confirm (not wl-expire-delete-oldmsg-confirm))
 298                              (progn
 299                                (if (eq major-mode 'wl-summary-mode)
 300                                    (wl-thread-jump-to-msg (car dels)))
 301                                (y-or-n-p (format "Delete old messages %s? "
 302                                                  dels)))))
 303               (setq dels nil)))
 304           (list msgs dels max-num (cdr folder-info) len))
 305       (list msgs dels 0 "0" 0))))
 306
 307 (defun wl-expire-archive-number1 (folder delete-list msgdb
 308                                          &optional preserve-number no-delete)
 309   "Standard function for `wl-summary-expire'.
 310 Refile to archive folder followed message number."
 311   (let* ((elmo-archive-treat-file t)    ;; treat archive folder as a file.
 312          (dst-folder-fmt (funcall
 313                           wl-expire-archive-get-folder-func folder))
 314          (dst-folder-base (car dst-folder-fmt))
 315          (dst-folder-fmt (cdr dst-folder-fmt))
 316          (refile-func (if no-delete
 317                           'wl-expire-refile
 318                         'wl-expire-refile-with-copy-reserve-msg))
 319          tmp dels dst-folder
 320          prev-arcnum arcnum msg arcmsg-list
 321          deleted-list ret-val)
 322     (setq tmp (wl-expire-archive-number-delete-old
 323                dst-folder-base preserve-number delete-list
 324                (elmo-msgdb-get-mark-alist msgdb)
 325                no-delete))
 326     (when (and (not no-delete)
 327                (setq dels (nth 1 tmp)))
 328       (wl-append deleted-list (car (wl-expire-delete folder dels msgdb))))
 329     (setq delete-list (car tmp))
 330     (catch 'done
 331       (while t
 332         (if (setq msg (wl-pop delete-list))
 333             (setq arcnum (/ msg wl-expire-archive-files))
 334           (setq arcnum nil))
 335         (when (and prev-arcnum
 336                    (not (eq arcnum prev-arcnum)))
 337           (setq dst-folder (format dst-folder-fmt
 338                                    (* prev-arcnum wl-expire-archive-files)))
 339           (and (setq ret-val
 340                      (funcall
 341                       refile-func
 342                       folder arcmsg-list msgdb dst-folder t preserve-number
 343                       no-delete))
 344                (wl-append deleted-list (car ret-val)))
 345           (setq arcmsg-list nil))
 346         (if (null msg)
 347             (throw 'done t))
 348         (wl-append arcmsg-list (list msg))
 349         (setq prev-arcnum arcnum)))
 350     deleted-list
 351     ))
 352
 353 (defun wl-expire-archive-number2 (folder delete-list msgdb
 354                                          &optional preserve-number no-delete)
 355   "Standard function for `wl-summary-expire'.
 356 Refile to archive folder followed the number of message in one archive folder."
 357   (let* ((elmo-archive-treat-file t)    ;; treat archive folder as a file.
 358          (dst-folder-fmt (funcall
 359                           wl-expire-archive-get-folder-func folder))
 360          (dst-folder-base (car dst-folder-fmt))
 361          (dst-folder-fmt (cdr dst-folder-fmt))
 362          (refile-func (if no-delete
 363                           'wl-expire-refile
 364                         'wl-expire-refile-with-copy-reserve-msg))
 365          (len 0) (filenum 0)
 366          tmp dels dst-folder
 367          arc-len msg arcmsg-list
 368          deleted-list ret-val)
 369     (setq tmp (wl-expire-archive-number-delete-old
 370                dst-folder-base preserve-number delete-list
 371                (elmo-msgdb-get-mark-alist msgdb)
 372                no-delete))
 373     (when (and (not no-delete)
 374                (setq dels (nth 1 tmp)))
 375       (wl-append deleted-list (car (wl-expire-delete folder dels msgdb))))
 376     (setq delete-list (car tmp)
 377           filenum (string-to-int (nth 3 tmp))
 378           len (nth 4 tmp)
 379           arc-len len)
 380     (catch 'done
 381       (while t
 382         (if (setq msg (wl-pop delete-list))
 383             (setq len (1+ len))
 384           (setq len (1+ wl-expire-archive-files)))
 385         (when (> len wl-expire-archive-files)
 386           (when arcmsg-list
 387             (setq dst-folder (format dst-folder-fmt filenum))
 388             (and (setq ret-val
 389                        (funcall
 390                         refile-func
 391                         folder arcmsg-list msgdb dst-folder t preserve-number
 392                         no-delete))
 393                  (wl-append deleted-list (car ret-val)))
 394             (setq arc-len (+ arc-len (cdr ret-val))))
 395           (setq arcmsg-list nil)
 396           (if (< arc-len wl-expire-archive-files)
 397               (setq len (1+ arc-len))
 398             (setq filenum (+ filenum wl-expire-archive-files)
 399                   len (- len arc-len)   ;; maybe 1
 400                   arc-len (1- len)      ;; maybe 0
 401                   )))
 402         (if (null msg)
 403             (throw 'done t))
 404         (wl-append arcmsg-list (list msg))))
 405     deleted-list
 406     ))
 407
 408 (defun wl-expire-archive-date (folder delete-list msgdb
 409                                       &optional preserve-number no-delete)
 410   "Standard function for `wl-summary-expire'.
 411 Refile to archive folder followed message date."
 412   (let* ((elmo-archive-treat-file t)    ;; treat archive folder as a file.
 413          (number-alist (elmo-msgdb-get-number-alist msgdb))
 414          (overview (elmo-msgdb-get-overview msgdb))
 415          (dst-folder-fmt (funcall
 416                           wl-expire-archive-get-folder-func
 417                           folder
 418                           wl-expire-archive-date-folder-name-fmt
 419                           ))
 420          (dst-folder-base (car dst-folder-fmt))
 421          (dst-folder-fmt (cdr dst-folder-fmt))
 422          (refile-func (if no-delete
 423                           'wl-expire-refile
 424                         'wl-expire-refile-with-copy-reserve-msg))
 425          tmp dels dst-folder date time
 426          msg arcmsg-alist arcmsg-list
 427          deleted-list ret-val)
 428     (setq tmp (wl-expire-archive-number-delete-old
 429                dst-folder-base preserve-number delete-list
 430                (elmo-msgdb-get-mark-alist msgdb)
 431                no-delete
 432                wl-expire-archive-date-folder-num-regexp))
 433     (when (and (not no-delete)
 434                (setq dels (nth 1 tmp)))
 435       (wl-append deleted-list (car (wl-expire-delete folder dels msgdb))))
 436     (setq delete-list (car tmp))
 437     (while (setq msg (wl-pop delete-list))
 438       (setq date (elmo-msgdb-overview-entity-get-date
 439                   (assoc (cdr (assq msg number-alist)) overview)))
 440       (setq time
 441             (condition-case nil
 442                 (timezone-fix-time date nil nil)
 443               (error [0 0 0 0 0 0 0])))
 444       (if (= (aref time 1) 0)   ;; if (month == 0)
 445           (aset time 0 0))      ;;    year = 0
 446       (setq dst-folder (format dst-folder-fmt
 447                                (aref time 0)  ;; year
 448                                (aref time 1)  ;; month
 449                                ))
 450       (setq arcmsg-alist
 451             (wl-append-assoc-list
 452              dst-folder
 453              msg
 454              arcmsg-alist)))
 455     (while arcmsg-alist
 456       (setq dst-folder (caar arcmsg-alist))
 457       (setq arcmsg-list (cdar arcmsg-alist))
 458       (and (setq ret-val
 459                  (funcall
 460                   refile-func
 461                   folder arcmsg-list msgdb dst-folder t preserve-number
 462                   no-delete))
 463            (wl-append deleted-list (car ret-val)))
 464       (setq arcmsg-alist (cdr arcmsg-alist)))
 465     deleted-list
 466     ))
 467
 468 (defun wl-expire-hide (folder hide-list msgdb &optional no-reserve-marks)
 469   "Hide message for expire."
 470   (unless no-reserve-marks
 471     (setq hide-list
 472           (wl-expire-delete-reserve-marked-msgs-from-list
 473            hide-list (elmo-msgdb-get-mark-alist msgdb))))
 474   (let ((mess (format "Hiding %s msgs..." (length hide-list))))
 475     (message mess)
 476     (elmo-msgdb-delete-msgs folder hide-list)
 477     (elmo-msgdb-append-to-killed-list folder hide-list)
 478     (elmo-folder-commit folder)
 479     (message (concat mess "done"))
 480     (cons hide-list (length hide-list))))
 481
 482 (defsubst wl-expire-folder-p (entity)
 483   "Return non-nil, when ENTITY matched `wl-expire-alist'."
 484   (wl-get-assoc-list-value wl-expire-alist entity))
 485
 486 (defun wl-summary-expire (&optional folder notsummary nolist)
 487   ""
 488   (interactive)
 489   (let ((folder (or folder wl-summary-buffer-elmo-folder))
 490         (deleting-info "Expiring...")
 491         expires)
 492     (when (and (or (setq expires (wl-expire-folder-p
 493                                   (elmo-folder-name-internal folder)))
 494                    (progn (and (interactive-p)
 495                                (message "no match %s in wl-expire-alist"
 496                                         folder))
 497                           nil))
 498                (or (not (interactive-p))
 499                    (y-or-n-p (format "Expire %s? " (elmo-folder-name-internal
 500                                                     folder)))))
 501       (let* ((msgdb (wl-summary-buffer-msgdb))
 502              (number-alist (elmo-msgdb-get-number-alist msgdb))
 503              (mark-alist (elmo-msgdb-get-mark-alist msgdb))
 504              expval rm-type val-type value more args
 505              delete-list)
 506         (save-excursion
 507           (setq expval (car expires)
 508                 rm-type (nth 1 expires)
 509                 args (cddr expires))
 510           (setq val-type (car expval)
 511                 value (nth 1 expval)
 512                 more (nth 2 expval))
 513           (run-hooks 'wl-summary-expire-pre-hook)
 514           (cond
 515            ((eq val-type nil))
 516            ((eq val-type 'number)
 517             (let* ((msgs (if (not nolist)
 518                              (elmo-folder-list-messages folder)
 519                            (mapcar 'car number-alist)))
 520                    (msglen (length msgs))
 521                    (more (or more (1+ value)))
 522                    count)
 523               (when (>= msglen more)
 524                 (setq count (- msglen value))
 525                 (while (and msgs (> count 0))
 526                   (when (assq (car msgs) number-alist) ;; don't expire new message
 527                     (wl-append delete-list (list (car msgs)))
 528                     (when (or (not wl-expire-number-with-reserve-marks)
 529                               (wl-expire-msg-p (car msgs) mark-alist))
 530                       (setq count (1- count))))
 531                   (setq msgs (cdr msgs))))))
 532            ((eq val-type 'date)
 533             (let* ((overview (elmo-msgdb-get-overview msgdb))
 534                    (key-date (elmo-date-get-offset-datevec
 535                               (timezone-fix-time (current-time-string)
 536                                                  (current-time-zone) nil)
 537                               value t)))
 538               (while overview
 539                 (when (wl-expire-date-p
 540                        key-date
 541                        (elmo-msgdb-overview-entity-get-date
 542                         (car overview)))
 543                   (wl-append delete-list
 544                              (list (elmo-msgdb-overview-entity-get-number
 545                                     (car overview)))))
 546                 (setq overview (cdr overview)))))
 547            (t
 548             (error "%s: not supported" val-type)))
 549           (when delete-list
 550             (or wl-expired-alist
 551                 (setq wl-expired-alist (wl-expired-alist-load)))
 552             (setq delete-list
 553                   (cond ((eq rm-type nil) nil)
 554                         ((eq rm-type 'remove)
 555                          (setq deleting-info "Deleting...")
 556                          (car (wl-expire-delete folder delete-list msgdb)))
 557                         ((eq rm-type 'trash)
 558                          (setq deleting-info "Deleting...")
 559                          (car (wl-expire-refile folder delete-list msgdb wl-trash-folder)))
 560                         ((eq rm-type 'hide)
 561                          (setq deleting-info "Hiding...")
 562                          (car (wl-expire-hide folder delete-list msgdb)))
 563                         ((stringp rm-type)
 564                          (setq deleting-info "Refiling...")
 565                          (car (wl-expire-refile folder delete-list msgdb rm-type)))
 566                         ((fboundp rm-type)
 567                          (apply rm-type (append (list folder delete-list msgdb)
 568                                                 args)))
 569                         (t
 570                          (error "%s: invalid type" rm-type))))
 571             (when (and (not notsummary) delete-list)
 572               (wl-summary-delete-messages-on-buffer delete-list deleting-info)
 573               (wl-summary-folder-info-update)
 574               (wl-summary-set-message-modified)
 575               (wl-summary-set-mark-modified)
 576               (sit-for 0)
 577               (set-buffer-modified-p nil))
 578             (wl-expired-alist-save))
 579           (run-hooks 'wl-summary-expire-hook)
 580           (if delete-list
 581               (message "Expiring %s is done" (elmo-folder-name-internal
 582                                               folder))
 583             (and (interactive-p)
 584                  (message "No expire"))))
 585
 586
 587
 588         delete-list
 589         ))))
 590
 591 (defun wl-folder-expire-entity (entity)
 592   (cond
 593    ((consp entity)
 594     (let ((flist (nth 2 entity)))
 595       (while flist
 596         (wl-folder-expire-entity (car flist))
 597         (setq flist (cdr flist)))))
 598    ((stringp entity)
 599     (when (wl-expire-folder-p entity)
 600       (let* ((folder (wl-folder-get-elmo-folder entity))
 601              (update-msgdb (cond
 602                            ((consp wl-expire-folder-update-msgdb)
 603                             (wl-string-match-member
 604                              entity
 605                              wl-expire-folder-update-msgdb))
 606                            (t
 607                             wl-expire-folder-update-msgdb)))
 608             (wl-summary-highlight (if (or (wl-summary-sticky-p folder)
 609                                           (wl-summary-always-sticky-folder-p
 610                                            folder))
 611                                       wl-summary-highlight))
 612             wl-auto-select-first ret-val)
 613         (save-window-excursion
 614           (save-excursion
 615             (and update-msgdb
 616                  (wl-summary-goto-folder-subr entity 'force-update nil))
 617             (setq ret-val (wl-summary-expire folder (not update-msgdb)))
 618             (if update-msgdb
 619                 (progn
 620                   (wl-summary-save-view 'keep)
 621                   (elmo-folder-commit wl-summary-buffer-elmo-folder))
 622               (if ret-val
 623                   (wl-folder-check-entity entity))))))))))
 624
 625 ;; Command
 626
 627 (defun wl-folder-expire-current-entity ()
 628   (interactive)
 629   (let ((entity-name
 630          (or (wl-folder-get-folder-name-by-id
 631               (get-text-property (point) 'wl-folder-entity-id))
 632              (wl-folder-get-realname (wl-folder-folder-name)))))
 633     (when (and entity-name
 634                (or (not (interactive-p))
 635                    (y-or-n-p (format "Expire %s? " entity-name))))
 636       (wl-folder-expire-entity
 637        (wl-folder-search-entity-by-name entity-name
 638                                         wl-folder-entity))
 639       (if (get-buffer wl-summary-buffer-name)
 640           (kill-buffer wl-summary-buffer-name))
 641       (message "Expiring %s is done" entity-name))))
 642
 643 ;;; Archive
 644
 645 (defun wl-folder-archive-current-entity ()
 646   (interactive)
 647   (let ((entity-name
 648          (or (wl-folder-get-folder-name-by-id
 649               (get-text-property (point) 'wl-folder-entity-id))
 650              (wl-folder-get-realname (wl-folder-folder-name)))))
 651     (when (and entity-name
 652                (or (not (interactive-p))
 653                    (y-or-n-p (format "Archive %s? " entity-name))))
 654       (wl-folder-archive-entity
 655        (wl-folder-search-entity-by-name entity-name
 656                                         wl-folder-entity))
 657       (message "Archiving %s is done" entity-name))))
 658
 659 (defun wl-archive-number1 (folder archive-list msgdb)
 660   (wl-expire-archive-number1 folder archive-list msgdb t t))
 661
 662 (defun wl-archive-number2 (folder archive-list msgdb)
 663   (wl-expire-archive-number2 folder archive-list msgdb t t))
 664
 665 (defun wl-archive-date (folder archive-list msgdb)
 666   (wl-expire-archive-date folder archive-list msgdb t t))
 667
 668 (defun wl-archive-folder (folder archive-list msgdb dst-folder)
 669   (let* ((elmo-archive-treat-file t)    ;; treat archive folder as a file.
 670          copied-list ret-val)
 671     (setq archive-list
 672           (car (wl-expire-archive-number-delete-old
 673                 nil t archive-list
 674                 (elmo-msgdb-get-mark-alist msgdb)
 675                 t ;; no-confirm
 676                 nil dst-folder)))
 677     (when archive-list
 678       (and (setq ret-val
 679                  (wl-expire-refile
 680                   folder archive-list msgdb dst-folder t t t)) ;; copy!!
 681            (wl-append copied-list ret-val)))
 682     copied-list
 683     ))
 684
 685 (defun wl-summary-archive (&optional arg folder notsummary nolist)
 686   (interactive "P")
 687   (let* ((folder (or folder wl-summary-buffer-elmo-folder))
 688          (msgdb (or (wl-summary-buffer-msgdb)
 689                     (elmo-msgdb-load folder)))
 690          (msgs (if (not nolist)
 691                    (elmo-folder-list-messages folder)
 692                  (mapcar 'car (elmo-msgdb-get-number-alist msgdb))))
 693          (alist wl-archive-alist)
 694          func dst-folder archive-list)
 695     (if arg
 696         (let ((wl-default-spec (char-to-string
 697                                 (car (rassq 'archive elmo-folder-type-alist)))))
 698           (setq dst-folder (wl-summary-read-folder
 699                             (concat wl-default-spec (substring folder 1))
 700                             "for archive"))))
 701     (run-hooks 'wl-summary-archive-pre-hook)
 702     (if dst-folder
 703         (wl-archive-folder folder msgs msgdb dst-folder)
 704       (when (and (catch 'match
 705                    (while alist
 706                      (when (string-match (caar alist) folder)
 707                        (setq func (cadar alist))
 708                        (throw 'match t))
 709                      (setq alist (cdr alist)))
 710                    (and (interactive-p)
 711                         (message "No match %s in wl-archive-alist" folder))
 712                    (throw 'match nil))
 713                  (or (not (interactive-p))
 714                      (y-or-n-p (format "Archive %s? " folder))))
 715         (setq archive-list
 716               (funcall func folder msgs msgdb))
 717         (run-hooks 'wl-summary-archive-hook)
 718         (if archive-list
 719             (message "Archiving %s is done" folder)
 720           (and (interactive-p)
 721                (message "No archive")))))))
 722
 723 (defun wl-folder-archive-entity (entity)
 724   (cond
 725    ((consp entity)
 726     (let ((flist (nth 2 entity)))
 727       (while flist
 728         (wl-folder-archive-entity (car flist))
 729         (setq flist (cdr flist)))))
 730    ((stringp entity)
 731     (wl-summary-archive nil (wl-folder-get-elmo-folder entity) t))))
 732
 733 ;; append log
 734
 735 (defun wl-expire-append-log (src-folder msgs dst-folder action)
 736   (when wl-expire-use-log
 737     (save-excursion
 738       (let ((tmp-buf (get-buffer-create " *wl-expire work*"))
 739             (filename (expand-file-name wl-expired-log-alist-file-name
 740                                         elmo-msgdb-dir)))
 741         (set-buffer tmp-buf)
 742         (erase-buffer)
 743         (if dst-folder
 744             (insert (format "%s\t%s -> %s\t%s\n"
 745                             action
 746                             src-folder dst-folder msgs))
 747           (insert (format "%s\t%s\t%s\n"
 748                           action
 749                           src-folder msgs)))
 750         (if (file-writable-p filename)
 751             (write-region (point-min) (point-max)
 752                           filename t 'no-msg)
 753           (message (format "%s is not writable." filename)))
 754         (kill-buffer tmp-buf)))))
 755
 756 (require 'product)
 757 (product-provide (provide 'wl-expire) (require 'wl-version))
 758
 759 ;;; wl-expire.el ends here