wl/wl-expire.el

   1 ;;; wl-expire.el -- Message expire modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Masahiro MURATA <muse@ba2.so-net.ne.jp>
   4 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   5
   6 ;; Author: Masahiro MURATA <muse@ba2.so-net.ne.jp>
   7 ;; Keywords: mail, net news
   8
   9 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29
  30 (require 'wl-summary)
  31 (require 'wl-thread)
  32 (require 'wl-folder)
  33 (require 'elmo)
  34
  35 ;;; Code:
  36
  37 (eval-when-compile
  38   (require 'wl-util)
  39   (require 'elmo-archive))
  40
  41 ;; Variables
  42
  43 (defvar wl-expired-alist nil)
  44 (defvar wl-expired-alist-file-name "expired-alist")
  45 (defvar wl-expired-log-alist nil)
  46 (defvar wl-expired-log-alist-file-name "expired-log")
  47 (defvar wl-expire-test nil)     ;; for debug (no execute)
  48
  49 (defun wl-expired-alist-load ()
  50   (elmo-object-load (expand-file-name
  51                      wl-expired-alist-file-name
  52                      elmo-msgdb-dir)))
  53
  54 (defun wl-expired-alist-save (&optional alist)
  55   (elmo-object-save (expand-file-name
  56                      wl-expired-alist-file-name
  57                      elmo-msgdb-dir)
  58                     (or alist wl-expired-alist)))
  59
  60 (defsubst wl-expire-msg-p (msg-num mark-alist)
  61   (cond ((consp wl-summary-expire-reserve-marks)
  62          (let ((mark (nth 1 (assq msg-num mark-alist))))
  63            (not (or (member mark wl-summary-expire-reserve-marks)
  64                     (and wl-summary-buffer-disp-msg
  65                          (eq msg-num wl-summary-buffer-current-msg))))))
  66         ((eq wl-summary-expire-reserve-marks 'all)
  67          (not (or (assq msg-num mark-alist)
  68                   (and wl-summary-buffer-disp-msg
  69                        (eq msg-num wl-summary-buffer-current-msg)))))
  70         ((eq wl-summary-expire-reserve-marks 'none)
  71          t)
  72         (t
  73          (error "Invalid marks: %s" wl-summary-expire-reserve-marks))))
  74
  75 (defmacro wl-expire-make-sortable-date (date)
  76   (` (timezone-make-sortable-date
  77       (aref (, date) 0) (aref (, date) 1) (aref (, date) 2)
  78       (timezone-make-time-string
  79        (aref (, date) 3) (aref (, date) 4) (aref (, date) 5)))))
  80
  81 (defsubst wl-expire-date-p (key-datevec date)
  82   (let ((datevec (condition-case nil
  83                      (timezone-fix-time date nil nil)
  84                    (error nil))))
  85     (and
  86      datevec (> (aref datevec 1) 0)
  87      (string<
  88       (wl-expire-make-sortable-date datevec)
  89       (wl-expire-make-sortable-date key-datevec)))))
  90
  91 (defun wl-expire-delete-reserve-marked-msgs-from-list (msgs mark-alist)
  92   (let ((dlist msgs))
  93     (while dlist
  94       (unless (wl-expire-msg-p (car dlist) mark-alist)
  95         (setq msgs (delq (car dlist) msgs)))
  96       (setq dlist (cdr dlist)))
  97     msgs))
  98
  99 (defun wl-expire-delete (folder delete-list msgdb &optional no-reserve-marks)
 100   "Delete message for expire."
 101   (unless no-reserve-marks
 102     (setq delete-list
 103           (wl-expire-delete-reserve-marked-msgs-from-list
 104            delete-list (elmo-msgdb-get-mark-alist msgdb))))
 105   (when delete-list
 106    (let ((mess
 107          (format "Expiring (delete) %s msgs..."
 108                  (length delete-list))))
 109     (message "%s" mess)
 110     (if (elmo-folder-delete-messages folder
 111                                      delete-list)
 112         (progn
 113           (elmo-msgdb-delete-msgs (elmo-folder-msgdb folder)
 114                                   delete-list)
 115           (wl-expire-append-log
 116            (elmo-folder-name-internal folder)
 117            delete-list nil 'delete)
 118           (message "%s" (concat mess "done")))
 119       (error (concat mess "failed!")))))
 120   (cons delete-list (length delete-list)))
 121
 122 (defun wl-expire-refile (folder refile-list msgdb dst-folder
 123                                 &optional no-reserve-marks preserve-number copy)
 124   "Refile message for expire. If COPY is non-nil, copy message."
 125   (when (not (string= (elmo-folder-name-internal folder) dst-folder))
 126     (unless no-reserve-marks
 127       (setq refile-list
 128             (wl-expire-delete-reserve-marked-msgs-from-list
 129              refile-list (elmo-msgdb-get-mark-alist msgdb))))
 130     (when refile-list
 131       (let* ((doingmes (if copy
 132                            "Copying %s"
 133                          "Expiring (move %s)"))
 134              (dst-folder (wl-folder-get-elmo-folder dst-folder))
 135              (mess (format (concat doingmes " %s msgs...")
 136                            (elmo-folder-name-internal dst-folder)
 137                            (length refile-list))))
 138         (message "%s" mess)
 139         (if wl-expire-test
 140             nil
 141           (unless (or (elmo-folder-exists-p dst-folder)
 142                       (elmo-folder-create dst-folder))
 143             (error "%s: create folder failed"
 144                    (elmo-folder-name-internal dst-folder)))
 145           (if (elmo-folder-move-messages folder
 146                                          refile-list
 147                                          dst-folder
 148                                          msgdb
 149                                          nil nil t
 150                                          copy
 151                                          preserve-number
 152                                          nil
 153                                          wl-expire-add-seen-list)
 154               (progn
 155                 (wl-expire-append-log
 156                  (elmo-folder-name-internal folder)
 157                  refile-list
 158                  (elmo-folder-name-internal dst-folder)
 159                  (if copy 'copy 'move))
 160                 (message "%s" (concat mess "done")))
 161             (error (concat mess "failed!"))))))
 162     (cons refile-list (length refile-list))))
 163
 164 (defun wl-expire-refile-with-copy-reserve-msg
 165   (folder refile-list msgdb dst-folder
 166           &optional no-reserve-marks preserve-number copy)
 167   "Refile message for expire.
 168 If REFILE-LIST includes reserve mark message, so copy."
 169   (when (not (string= (elmo-folder-name-internal folder) dst-folder))
 170     (let ((msglist refile-list)
 171           (mark-alist (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
 172           (number-alist (elmo-msgdb-get-number-alist (elmo-folder-msgdb
 173                                                       folder)))
 174           (dst-folder (wl-folder-get-elmo-folder dst-folder))
 175           (ret-val t)
 176           (copy-reserve-message)
 177           (copy-len 0)
 178           msg msg-id)
 179       (message "Expiring (move %s) %s msgs..."
 180                (elmo-folder-name-internal dst-folder) (length refile-list))
 181       (if wl-expire-test
 182           (setq copy-len (length refile-list))
 183         (unless (or (elmo-folder-exists-p dst-folder)
 184                   (elmo-folder-create dst-folder))
 185         (error "%s: create folder failed" (elmo-folder-name-internal
 186                                            dst-folder)))
 187         (while (setq msg (wl-pop msglist))
 188           (unless (wl-expire-msg-p msg mark-alist)
 189             (setq msg-id (cdr (assq msg number-alist)))
 190             (if (assoc msg-id wl-expired-alist)
 191                 ;; reserve mark message already refiled or expired
 192                 (setq refile-list (delq msg refile-list))
 193               ;; reserve mark message not refiled
 194               (wl-append wl-expired-alist (list (cons msg-id
 195                                                       (elmo-folder-name-internal
 196                                                        dst-folder))))
 197               (setq copy-reserve-message t))))
 198         (when refile-list
 199           (unless
 200               (setq ret-val
 201                     (elmo-folder-move-messages folder
 202                                                refile-list
 203                                                dst-folder
 204                                                msgdb
 205                                                nil nil t
 206                                                copy-reserve-message
 207                                                preserve-number
 208                                                nil
 209                                                wl-expire-add-seen-list
 210                                                ))
 211             (error "Expire: move msgs to %s failed"
 212                    (elmo-folder-name-internal dst-folder)))
 213           (wl-expire-append-log (elmo-folder-name-internal folder)
 214                                 refile-list
 215                                 (elmo-folder-name-internal dst-folder)
 216                                 (if copy-reserve-message 'copy 'move))
 217           (setq copy-len (length refile-list))
 218           (when copy-reserve-message
 219             (setq refile-list
 220                   (wl-expire-delete-reserve-marked-msgs-from-list
 221                    refile-list
 222                    mark-alist))
 223             (when refile-list
 224               (if (setq ret-val
 225                         (elmo-folder-delete-messages folder
 226                                                      refile-list))
 227                   (progn
 228                     (elmo-msgdb-delete-msgs (elmo-folder-msgdb folder)
 229                                             refile-list)
 230                     (wl-expire-append-log
 231                      (elmo-folder-name-internal folder)
 232                      refile-list nil 'delete))))))
 233         (let ((mes (format "Expiring (move %s) %s msgs..."
 234                            (elmo-folder-name-internal dst-folder)
 235                            (length refile-list))))
 236           (if ret-val
 237               (message (concat mes "done"))
 238             (error (concat mes "failed!")))))
 239       (cons refile-list copy-len))))
 240
 241 (defun wl-expire-archive-get-folder (src-folder &optional fmt dst-folder-arg)
 242   "Get archive folder name from SRC-FOLDER."
 243   (let* ((fmt (or fmt wl-expire-archive-folder-name-fmt))
 244          (archive-spec (char-to-string
 245                         (car (rassq 'archive elmo-folder-type-alist))))
 246          dst-folder-base dst-folder-fmt prefix)
 247     (cond (dst-folder-arg
 248            (setq dst-folder-base (concat archive-spec dst-folder-arg)))
 249           ((eq (elmo-folder-type-internal src-folder) 'localdir)
 250            (setq dst-folder-base
 251                  (concat archive-spec
 252                          (substring
 253                           (elmo-folder-name-internal src-folder) 1))))
 254           (t
 255            (setq dst-folder-base
 256                  (elmo-concat-path
 257                   (format "%s%s" archive-spec (elmo-folder-type-internal
 258                                                src-folder))
 259                   (substring (substring (elmo-folder-name-internal src-folder) 1)
 260                              (length (elmo-folder-prefix-internal src-folder)))))))
 261     (setq dst-folder-fmt (format fmt
 262                                  dst-folder-base
 263                                  wl-expire-archive-folder-type))
 264     (setq dst-folder-base (format "%s;%s"
 265                                   dst-folder-base
 266                                   wl-expire-archive-folder-type))
 267     (when wl-expire-archive-folder-prefix
 268       (cond ((eq wl-expire-archive-folder-prefix 'short)
 269              (setq prefix (file-name-nondirectory
 270                            (substring
 271                             (elmo-folder-name-internal src-folder) 1))))
 272             (t
 273              (setq prefix (substring
 274                            (elmo-folder-name-internal src-folder) 1))))
 275       (setq dst-folder-fmt (concat dst-folder-fmt ";" prefix))
 276       (setq dst-folder-base (concat dst-folder-base ";" prefix)))
 277     (cons dst-folder-base dst-folder-fmt)))
 278
 279 (defsubst wl-expire-archive-get-max-number (dst-folder-base &optional regexp)
 280   (let ((files (reverse (sort (elmo-folder-list-subfolders
 281                                (elmo-make-folder dst-folder-base))
 282                               'string<)))
 283         (regexp (or regexp wl-expire-archive-folder-num-regexp))
 284         filenum in-folder)
 285     (catch 'done
 286       (while files
 287         (when (string-match regexp (car files))
 288           (setq filenum (elmo-match-string 1 (car files)))
 289           (setq in-folder (elmo-folder-status
 290                            (wl-folder-get-elmo-folder (car files))))
 291           (throw 'done (cons in-folder filenum)))
 292         (setq files (cdr files))))))
 293
 294 (defun wl-expire-archive-number-delete-old (dst-folder-base
 295                                             preserve-number msgs mark-alist
 296                                             &optional no-confirm regexp file)
 297   (let ((len 0) (max-num 0)
 298         folder-info dels)
 299     (if (or (and file (setq folder-info
 300                             (cons (elmo-folder-status
 301                                    (wl-folder-get-elmo-folder file))
 302                                   nil)))
 303             (setq folder-info (wl-expire-archive-get-max-number
 304                                dst-folder-base
 305                                regexp)))
 306         (progn
 307           (setq len (cdar folder-info))
 308           (when preserve-number
 309             ;; delete small number than max number of dst-folder
 310             (setq max-num (caar folder-info))
 311             (while (and msgs (>= max-num (car msgs)))
 312               (wl-append dels (list (car msgs)))
 313               (setq msgs (cdr msgs)))
 314             (setq dels (wl-expire-delete-reserve-marked-msgs-from-list
 315                         dels mark-alist))
 316             (unless (and dels
 317                          (or (or no-confirm (not wl-expire-delete-oldmsg-confirm))
 318                              (progn
 319                                (if (eq major-mode 'wl-summary-mode)
 320                                    (wl-thread-jump-to-msg (car dels)))
 321                                (y-or-n-p (format "Delete old messages %s? "
 322                                                  dels)))))
 323               (setq dels nil)))
 324           (list msgs dels max-num (cdr folder-info) len))
 325       (list msgs dels 0 "0" 0))))
 326
 327 (defun wl-expire-archive-number1 (folder delete-list msgdb
 328                                   &optional preserve-number dst-folder-arg
 329                                             no-delete)
 330   "Standard function for `wl-summary-expire'.
 331 Refile to archive folder followed message number."
 332   (let* ((elmo-archive-treat-file t)    ;; treat archive folder as a file.
 333          (dst-folder-expand (and dst-folder-arg
 334                                  (wl-expand-newtext
 335                                   dst-folder-arg
 336                                   (elmo-folder-name-internal folder))))
 337          (dst-folder-fmt (funcall
 338                           wl-expire-archive-get-folder-function
 339                           folder nil dst-folder-expand))
 340          (dst-folder-base (car dst-folder-fmt))
 341          (dst-folder-fmt (cdr dst-folder-fmt))
 342          (refile-func (if no-delete
 343                           'wl-expire-refile
 344                         'wl-expire-refile-with-copy-reserve-msg))
 345          tmp dels dst-folder
 346          prev-arcnum arcnum msg arcmsg-list
 347          deleted-list ret-val)
 348     (setq tmp (wl-expire-archive-number-delete-old
 349                dst-folder-base preserve-number delete-list
 350                (elmo-msgdb-get-mark-alist msgdb)
 351                no-delete))
 352     (when (and (not no-delete)
 353                (setq dels (nth 1 tmp)))
 354       (wl-append deleted-list (car (wl-expire-delete folder dels msgdb))))
 355     (setq delete-list (car tmp))
 356     (catch 'done
 357       (while t
 358         (if (setq msg (wl-pop delete-list))
 359             (setq arcnum (/ msg wl-expire-archive-files))
 360           (setq arcnum nil))
 361         (when (and prev-arcnum
 362                    (not (eq arcnum prev-arcnum)))
 363           (setq dst-folder (format dst-folder-fmt
 364                                    (* prev-arcnum wl-expire-archive-files)))
 365           (and (setq ret-val
 366                      (funcall
 367                       refile-func
 368                       folder arcmsg-list msgdb dst-folder t preserve-number
 369                       no-delete))
 370                (wl-append deleted-list (car ret-val)))
 371           (setq arcmsg-list nil))
 372         (if (null msg)
 373             (throw 'done t))
 374         (wl-append arcmsg-list (list msg))
 375         (setq prev-arcnum arcnum)))
 376     deleted-list))
 377
 378 (defun wl-expire-archive-number2 (folder delete-list msgdb
 379                                   &optional preserve-number dst-folder-arg
 380                                             no-delete)
 381   "Standard function for `wl-summary-expire'.
 382 Refile to archive folder followed the number of message in one archive folder."
 383   (let* ((elmo-archive-treat-file t)    ;; treat archive folder as a file.
 384          (dst-folder-expand (and dst-folder-arg
 385                                  (wl-expand-newtext
 386                                   dst-folder-arg
 387                                   (elmo-folder-name-internal folder))))
 388          (dst-folder-fmt (funcall
 389                           wl-expire-archive-get-folder-function
 390                           folder nil dst-folder-expand))
 391          (dst-folder-base (car dst-folder-fmt))
 392          (dst-folder-fmt (cdr dst-folder-fmt))
 393          (refile-func (if no-delete
 394                           'wl-expire-refile
 395                         'wl-expire-refile-with-copy-reserve-msg))
 396          (len 0) (filenum 0)
 397          tmp dels dst-folder
 398          arc-len msg arcmsg-list
 399          deleted-list ret-val)
 400     (setq tmp (wl-expire-archive-number-delete-old
 401                dst-folder-base preserve-number delete-list
 402                (elmo-msgdb-get-mark-alist msgdb)
 403                no-delete))
 404     (when (and (not no-delete)
 405                (setq dels (nth 1 tmp)))
 406       (wl-append deleted-list (car (wl-expire-delete folder dels msgdb))))
 407     (setq delete-list (car tmp)
 408           filenum (string-to-int (nth 3 tmp))
 409           len (nth 4 tmp)
 410           arc-len len)
 411     (catch 'done
 412       (while t
 413         (if (setq msg (wl-pop delete-list))
 414             (setq len (1+ len))
 415           (setq len (1+ wl-expire-archive-files)))
 416         (when (> len wl-expire-archive-files)
 417           (when arcmsg-list
 418             (setq dst-folder (format dst-folder-fmt filenum))
 419             (and (setq ret-val
 420                        (funcall
 421                         refile-func
 422                         folder arcmsg-list msgdb dst-folder t preserve-number
 423                         no-delete))
 424                  (wl-append deleted-list (car ret-val)))
 425             (setq arc-len (+ arc-len (cdr ret-val))))
 426           (setq arcmsg-list nil)
 427           (if (< arc-len wl-expire-archive-files)
 428               (setq len (1+ arc-len))
 429             (setq filenum (+ filenum wl-expire-archive-files)
 430                   len (- len arc-len)   ;; maybe 1
 431                   arc-len (1- len)      ;; maybe 0
 432                   )))
 433         (if (null msg)
 434             (throw 'done t))
 435         (wl-append arcmsg-list (list msg))))
 436     deleted-list))
 437
 438 (defun wl-expire-archive-date (folder delete-list msgdb
 439                                &optional preserve-number dst-folder-arg
 440                                          no-delete)
 441   "Standard function for `wl-summary-expire'.
 442 Refile to archive folder followed message date."
 443   (let* ((elmo-archive-treat-file t)    ;; treat archive folder as a file.
 444          (number-alist (elmo-msgdb-get-number-alist msgdb))
 445          (overview (elmo-msgdb-get-overview msgdb))
 446          (dst-folder-expand (and dst-folder-arg
 447                                  (wl-expand-newtext
 448                                   dst-folder-arg
 449                                   (elmo-folder-name-internal folder))))
 450          (dst-folder-fmt (funcall
 451                           wl-expire-archive-get-folder-function
 452                           folder
 453                           wl-expire-archive-date-folder-name-fmt
 454                           dst-folder-expand
 455                           ))
 456          (dst-folder-base (car dst-folder-fmt))
 457          (dst-folder-fmt (cdr dst-folder-fmt))
 458          (refile-func (if no-delete
 459                           'wl-expire-refile
 460                         'wl-expire-refile-with-copy-reserve-msg))
 461          tmp dels dst-folder date time
 462          msg arcmsg-alist arcmsg-list
 463          deleted-list ret-val)
 464     (setq tmp (wl-expire-archive-number-delete-old
 465                dst-folder-base preserve-number delete-list
 466                (elmo-msgdb-get-mark-alist msgdb)
 467                no-delete
 468                wl-expire-archive-date-folder-num-regexp))
 469     (when (and (not no-delete)
 470                (setq dels (nth 1 tmp)))
 471       (wl-append deleted-list (car (wl-expire-delete folder dels msgdb))))
 472     (setq delete-list (car tmp))
 473     (while (setq msg (wl-pop delete-list))
 474       (setq date (elmo-msgdb-overview-entity-get-date
 475                   (assoc (cdr (assq msg number-alist)) overview)))
 476       (setq time
 477             (condition-case nil
 478                 (timezone-fix-time date nil nil)
 479               (error [0 0 0 0 0 0 0])))
 480       (if (= (aref time 1) 0)   ;; if (month == 0)
 481           (aset time 0 0))      ;;    year = 0
 482       (setq dst-folder (format dst-folder-fmt
 483                                (aref time 0)  ;; year
 484                                (aref time 1)  ;; month
 485                                ))
 486       (setq arcmsg-alist
 487             (wl-append-assoc-list
 488              dst-folder
 489              msg
 490              arcmsg-alist)))
 491     (while arcmsg-alist
 492       (setq dst-folder (caar arcmsg-alist))
 493       (setq arcmsg-list (cdar arcmsg-alist))
 494       (and (setq ret-val
 495                  (funcall
 496                   refile-func
 497                   folder arcmsg-list msgdb dst-folder t preserve-number
 498                   no-delete))
 499            (wl-append deleted-list (car ret-val)))
 500       (setq arcmsg-alist (cdr arcmsg-alist)))
 501     deleted-list))
 502
 503 (defun wl-expire-hide (folder hide-list msgdb &optional no-reserve-marks)
 504   "Hide message for expire."
 505   (unless no-reserve-marks
 506     (setq hide-list
 507           (wl-expire-delete-reserve-marked-msgs-from-list
 508            hide-list (elmo-msgdb-get-mark-alist msgdb))))
 509   (let ((mess (format "Hiding %s msgs..." (length hide-list))))
 510     (message mess)
 511     (elmo-msgdb-delete-msgs (elmo-folder-msgdb folder) hide-list)
 512     (elmo-msgdb-append-to-killed-list folder hide-list)
 513     (elmo-folder-commit folder)
 514     (message (concat mess "done"))
 515     (cons hide-list (length hide-list))))
 516
 517 (defsubst wl-expire-folder-p (entity)
 518   "Return non-nil, when ENTITY matched `wl-expire-alist'."
 519   (wl-get-assoc-list-value wl-expire-alist entity))
 520
 521 (defsubst wl-archive-folder-p (entity)
 522   "Return non-nil, when ENTITY matched `wl-archive-alist'."
 523   (wl-get-assoc-list-value wl-archive-alist entity))
 524
 525 (defun wl-summary-expire (&optional folder notsummary nolist)
 526   ""
 527   (interactive)
 528   (let ((folder (or folder wl-summary-buffer-elmo-folder))
 529         (deleting-info "Expiring...")
 530         expires)
 531     (when (and (or (setq expires (wl-expire-folder-p
 532                                   (elmo-folder-name-internal folder)))
 533                    (progn (and (interactive-p)
 534                                (message "no match %s in wl-expire-alist"
 535                                         (elmo-folder-name-internal folder)))
 536                           nil))
 537                (or (not (interactive-p))
 538                    (y-or-n-p (format "Expire %s? " (elmo-folder-name-internal
 539                                                     folder)))))
 540       (let* ((msgdb (wl-summary-buffer-msgdb))
 541              (number-alist (elmo-msgdb-get-number-alist msgdb))
 542              (mark-alist (elmo-msgdb-get-mark-alist msgdb))
 543              expval rm-type val-type value more args
 544              delete-list)
 545         (save-excursion
 546           (setq expval (car expires)
 547                 rm-type (nth 1 expires)
 548                 args (cddr expires))
 549           (setq val-type (car expval)
 550                 value (nth 1 expval)
 551                 more (nth 2 expval))
 552           (run-hooks 'wl-summary-expire-pre-hook)
 553           (cond
 554            ((eq val-type nil))
 555            ((eq val-type 'number)
 556             (let* ((msgs (if (not nolist)
 557                              (elmo-folder-list-messages folder)
 558                            (mapcar 'car number-alist)))
 559                    (msglen (length msgs))
 560                    (more (or more (1+ value)))
 561                    count)
 562               (when (>= msglen more)
 563                 (setq count (- msglen value))
 564                 (while (and msgs (> count 0))
 565                   (when (assq (car msgs) number-alist) ;; don't expire new message
 566                     (wl-append delete-list (list (car msgs)))
 567                     (when (or (not wl-expire-number-with-reserve-marks)
 568                               (wl-expire-msg-p (car msgs) mark-alist))
 569                       (setq count (1- count))))
 570                   (setq msgs (cdr msgs))))))
 571            ((eq val-type 'date)
 572             (let* ((overview (elmo-msgdb-get-overview msgdb))
 573                    (key-date (elmo-date-get-offset-datevec
 574                               (timezone-fix-time (current-time-string)
 575                                                  (current-time-zone) nil)
 576                               value t)))
 577               (while overview
 578                 (when (wl-expire-date-p
 579                        key-date
 580                        (elmo-msgdb-overview-entity-get-date
 581                         (car overview)))
 582                   (wl-append delete-list
 583                              (list (elmo-msgdb-overview-entity-get-number
 584                                     (car overview)))))
 585                 (setq overview (cdr overview)))))
 586            (t
 587             (error "%s: not supported" val-type)))
 588           (when delete-list
 589             (or wl-expired-alist
 590                 (setq wl-expired-alist (wl-expired-alist-load)))
 591             ;; evaluate string-match for wl-expand-newtext
 592             (wl-expire-folder-p
 593              (elmo-folder-name-internal folder))
 594             (setq delete-list
 595                   (cond ((eq rm-type nil) nil)
 596                         ((eq rm-type 'remove)
 597                          (setq deleting-info "Deleting...")
 598                          (car (wl-expire-delete folder delete-list msgdb)))
 599                         ((eq rm-type 'trash)
 600                          (setq deleting-info "Deleting...")
 601                          (car (wl-expire-refile folder delete-list msgdb wl-trash-folder)))
 602                         ((eq rm-type 'hide)
 603                          (setq deleting-info "Hiding...")
 604                          (car (wl-expire-hide folder delete-list msgdb)))
 605                         ((stringp rm-type)
 606                          (setq deleting-info "Refiling...")
 607                          (car (wl-expire-refile folder delete-list msgdb
 608                                                 (wl-expand-newtext
 609                                                  rm-type
 610                                                  (elmo-folder-name-internal folder)))))
 611                         ((fboundp rm-type)
 612                          (apply rm-type (append (list folder delete-list msgdb)
 613                                                 args)))
 614                         (t
 615                          (error "%s: invalid type" rm-type))))
 616             (when (and (not wl-expire-test) (not notsummary) delete-list)
 617               (wl-summary-delete-messages-on-buffer delete-list deleting-info)
 618               (wl-summary-folder-info-update)
 619               (wl-summary-set-message-modified)
 620               (wl-summary-set-mark-modified)
 621               (sit-for 0)
 622               (set-buffer-modified-p nil))
 623             (wl-expired-alist-save))
 624           (run-hooks 'wl-summary-expire-hook)
 625           (if delete-list
 626               (message "Expiring %s is done" (elmo-folder-name-internal
 627                                               folder))
 628             (and (interactive-p)
 629                  (message "No expire"))))
 630         delete-list))))
 631
 632 (defun wl-folder-expire-entity (entity)
 633   (cond
 634    ((consp entity)
 635     (let ((flist (nth 2 entity)))
 636       (while flist
 637         (wl-folder-expire-entity (car flist))
 638         (setq flist (cdr flist)))))
 639    ((stringp entity)
 640     (when (wl-expire-folder-p entity)
 641       (let* ((folder (wl-folder-get-elmo-folder entity))
 642              (update-msgdb (cond
 643                            ((consp wl-expire-folder-update-msgdb)
 644                             (wl-string-match-member
 645                              entity
 646                              wl-expire-folder-update-msgdb))
 647                            (t
 648                             wl-expire-folder-update-msgdb)))
 649             (wl-summary-highlight (if (or (wl-summary-sticky-p folder)
 650                                           (wl-summary-always-sticky-folder-p
 651                                            folder))
 652                                       wl-summary-highlight))
 653             wl-auto-select-first ret-val)
 654         (save-window-excursion
 655           (save-excursion
 656             (and update-msgdb
 657                  (wl-summary-goto-folder-subr entity 'force-update nil))
 658             (setq ret-val (wl-summary-expire folder (not update-msgdb)))
 659             (if update-msgdb
 660                 (progn
 661                   (wl-summary-save-view 'keep)
 662                   (elmo-folder-commit wl-summary-buffer-elmo-folder))
 663               (if ret-val
 664                   (wl-folder-check-entity entity))))))))))
 665
 666 ;; Command
 667
 668 (defun wl-folder-expire-current-entity ()
 669   (interactive)
 670   (let ((entity-name
 671          (or (wl-folder-get-folder-name-by-id
 672               (get-text-property (point) 'wl-folder-entity-id))
 673              (wl-folder-get-realname (wl-folder-folder-name)))))
 674     (when (and entity-name
 675                (or (not (interactive-p))
 676                    (y-or-n-p (format "Expire %s? " entity-name))))
 677       (wl-folder-expire-entity
 678        (wl-folder-search-entity-by-name entity-name
 679                                         wl-folder-entity))
 680       (if (get-buffer wl-summary-buffer-name)
 681           (kill-buffer wl-summary-buffer-name))
 682       (message "Expiring %s is done" entity-name))))
 683
 684 ;;; Archive
 685
 686 (defun wl-folder-archive-current-entity ()
 687   (interactive)
 688   (let ((entity-name
 689          (or (wl-folder-get-folder-name-by-id
 690               (get-text-property (point) 'wl-folder-entity-id))
 691              (wl-folder-get-realname (wl-folder-folder-name)))))
 692     (when (and entity-name
 693                (or (not (interactive-p))
 694                    (y-or-n-p (format "Archive %s? " entity-name))))
 695       (wl-folder-archive-entity
 696        (wl-folder-search-entity-by-name entity-name
 697                                         wl-folder-entity))
 698       (message "Archiving %s is done" entity-name))))
 699
 700 (defun wl-archive-number1 (folder archive-list msgdb &optional dst-folder-arg)
 701   (wl-expire-archive-number1 folder archive-list msgdb t dst-folder-arg t))
 702
 703 (defun wl-archive-number2 (folder archive-list msgdb &optional dst-folder-arg)
 704   (wl-expire-archive-number2 folder archive-list msgdb t dst-folder-arg t))
 705
 706 (defun wl-archive-date (folder archive-list msgdb &optional dst-folder-arg)
 707   (wl-expire-archive-date folder archive-list msgdb t dst-folder-arg t))
 708
 709 (defun wl-archive-folder (folder archive-list msgdb dst-folder)
 710   (let* ((elmo-archive-treat-file t)    ;; treat archive folder as a file.
 711          copied-list ret-val)
 712     (setq archive-list
 713           (car (wl-expire-archive-number-delete-old
 714                 nil t archive-list
 715                 (elmo-msgdb-get-mark-alist msgdb)
 716                 t ;; no-confirm
 717                 nil dst-folder)))
 718     (when archive-list
 719       (and (setq ret-val
 720                  (wl-expire-refile
 721                   folder archive-list msgdb dst-folder t t t)) ;; copy!!
 722            (wl-append copied-list ret-val)))
 723     copied-list))
 724
 725 (defun wl-summary-archive (&optional arg folder notsummary nolist)
 726   ""
 727   (interactive "P")
 728   (let* ((folder (or folder wl-summary-buffer-elmo-folder))
 729          (msgdb (or (wl-summary-buffer-msgdb)
 730                     (elmo-msgdb-load folder)))
 731          (msgs (if (not nolist)
 732                    (elmo-folder-list-messages folder)
 733                  (mapcar 'car (elmo-msgdb-get-number-alist msgdb))))
 734          (alist wl-archive-alist)
 735          archives func args dst-folder archive-list)
 736     (if arg
 737         (let ((wl-default-spec (char-to-string
 738                                 (car (rassq 'archive elmo-folder-type-alist)))))
 739           (setq dst-folder (wl-summary-read-folder
 740                             (concat wl-default-spec (substring folder 1))
 741                             "for archive"))))
 742     (run-hooks 'wl-summary-archive-pre-hook)
 743     (if dst-folder
 744         (wl-archive-folder folder msgs msgdb dst-folder)
 745       (when (and (or (setq archives (wl-archive-folder-p
 746                                      (elmo-folder-name-internal folder)))
 747                      (progn (and (interactive-p)
 748                                  (message "No match %s in wl-archive-alist"
 749                                           (elmo-folder-name-internal folder)))
 750                             nil))
 751                  (or (not (interactive-p))
 752                      (y-or-n-p (format "Archive %s? "
 753                                        (elmo-folder-name-internal folder)))))
 754         (setq func (car archives)
 755               args (cdr archives))
 756         (setq archive-list
 757               (apply func (append (list folder msgs msgdb) args)))
 758         (run-hooks 'wl-summary-archive-hook)
 759         (if archive-list
 760             (message "Archiving %s is done" (elmo-folder-name-internal folder))
 761           (and (interactive-p)
 762                (message "No archive")))))))
 763
 764 (defun wl-folder-archive-entity (entity)
 765   (cond
 766    ((consp entity)
 767     (let ((flist (nth 2 entity)))
 768       (while flist
 769         (wl-folder-archive-entity (car flist))
 770         (setq flist (cdr flist)))))
 771    ((stringp entity)
 772     (wl-summary-archive nil (wl-folder-get-elmo-folder entity) t))))
 773
 774 ;; append log
 775
 776 (defun wl-expire-append-log (src-folder msgs dst-folder action)
 777   (when wl-expire-use-log
 778     (save-excursion
 779       (let ((tmp-buf (get-buffer-create " *wl-expire work*"))
 780             (filename (expand-file-name wl-expired-log-alist-file-name
 781                                         elmo-msgdb-dir)))
 782         (set-buffer tmp-buf)
 783         (erase-buffer)
 784         (if dst-folder
 785             (insert (format "%s\t%s -> %s\t%s\n"
 786                             action
 787                             src-folder dst-folder msgs))
 788           (insert (format "%s\t%s\t%s\n"
 789                           action
 790                           src-folder msgs)))
 791         (if (file-writable-p filename)
 792             (write-region (point-min) (point-max)
 793                           filename t 'no-msg)
 794           (message (format "%s is not writable." filename)))
 795         (kill-buffer tmp-buf)))))
 796
 797 (require 'product)
 798 (product-provide (provide 'wl-expire) (require 'wl-version))
 799
 800 ;;; wl-expire.el ends here