wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'wl-vars)
  34 (require 'wl-highlight)
  35 (require 'elmo)
  36 (require 'elmo-mime)
  37 (require 'timer)
  38
  39 (eval-when-compile
  40   (require 'wl-mime)
  41   (require 'mime-view)
  42   (defalias-maybe 'event-window 'ignore)
  43   (defalias-maybe 'posn-window 'ignore)
  44   (defalias-maybe 'event-start 'ignore)
  45   (defalias-maybe 'mime-open-entity 'ignore)
  46   (defalias-maybe 'itimer-function 'ignore)
  47   (defalias-maybe 'delete-itimer 'ignore)
  48   (defvar-maybe itimer-list))
  49
  50 (defvar wl-message-buffer-prefetch-get-next-function
  51   'wl-summary-default-get-next-msg)
  52
  53 (defvar wl-message-buffer-prefetch-debug nil)
  54 (defvar wl-message-buffer-prefetch-timer nil)
  55
  56 (defvar wl-message-buffer nil) ; message buffer.
  57
  58 (defvar wl-message-buffer-cur-folder nil)
  59 (defvar wl-message-buffer-cur-number nil)
  60 (defvar wl-message-buffer-cur-display-type nil)
  61 (defvar wl-message-buffer-cur-summary-buffer nil)
  62 (defvar wl-message-buffer-require-all-header nil)
  63 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  64 (defvar wl-message-buffer-mode-line-formatter nil)
  65 (defvar wl-message-buffer-flag-indicator nil)
  66 (defvar wl-message-buffer-mime-entity nil)
  67
  68 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  70 (make-variable-buffer-local 'wl-message-buffer-cur-display-type)
  71 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  72 (make-variable-buffer-local 'wl-message-buffer-require-all-header)
  73 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  74 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  75 (make-variable-buffer-local 'wl-message-buffer-flag-indicator)
  76 (make-variable-buffer-local 'wl-message-buffer-mime-entity)
  77
  78 (defvar wl-fixed-window-configuration nil)
  79
  80 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  81
  82 ;;; Message buffer cache.
  83
  84 (defvar wl-message-buffer-cache nil
  85   "Message cache.  (old ... new) order alist.
  86 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  87
  88 (defmacro wl-message-buffer-cache-buffer-get (entry)
  89   (` (cdr (, entry))))
  90
  91 (defmacro wl-message-buffer-cache-folder-get (entry)
  92   (` (car (car (, entry)))))
  93
  94 (defmacro wl-message-buffer-cache-message-get (entry)
  95   (` (cdr (car (, entry)))))
  96
  97 (defmacro wl-message-buffer-cache-entry-make (key buf)
  98   (` (cons (, key) (, buf))))
  99
 100 (defmacro wl-message-buffer-cache-hit (key)
 101   "Return value assosiated with key."
 102   (` (wl-message-buffer-cache-buffer-get
 103       (assoc (, key) wl-message-buffer-cache))))
 104
 105 (defun wl-message-buffer-cache-sort (entry)
 106   "Move ENTRY to the top of `wl-message-buffer-cache'."
 107   (setq wl-message-buffer-cache
 108         (cons entry (delete entry wl-message-buffer-cache))))
 109 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 110 ;        (top pointer))
 111 ;    (while (cdr pointer)
 112 ;      (if (equal (car (cdr pointer)) entry)
 113 ;         (setcdr pointer (cdr (cdr pointer)))
 114 ;       (setq pointer (cdr pointer))))
 115 ;    (setcdr pointer (list entry))
 116 ;    (setq wl-message-buffer-cache (cdr top))))
 117
 118 (defconst wl-original-message-buffer-name " *Original*")
 119
 120 (defun wl-original-message-mode ()
 121   "A major mode for original message buffer."
 122   (setq major-mode 'wl-original-message-mode)
 123   (setq buffer-read-only t)
 124   (set-buffer-multibyte nil)
 125   (setq mode-name "Wanderlust original message"))
 126
 127 (defun wl-original-message-buffer-get (name)
 128   "Get original message buffer for NAME.
 129 If original message buffer already exists, it is re-used."
 130   (let* ((name (concat wl-original-message-buffer-name name))
 131          (buffer (get-buffer name)))
 132     (unless (and buffer (buffer-live-p buffer))
 133       (with-current-buffer (setq buffer (get-buffer-create name))
 134         (wl-original-message-mode)))
 135     buffer))
 136
 137 (defun wl-message-buffer-create ()
 138   "Create a new message buffer."
 139   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 140          (name (buffer-name buffer)))
 141     (with-current-buffer buffer
 142       (setq wl-message-buffer-original-buffer
 143             (wl-original-message-buffer-get name))
 144       (when wl-message-use-header-narrowing
 145         (wl-message-header-narrowing-setup))
 146       (run-hooks 'wl-message-buffer-created-hook))
 147     buffer))
 148
 149 (defun wl-message-buffer-cache-add (key)
 150   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 151 Return its cache buffer."
 152   (let ((len (length wl-message-buffer-cache))
 153         (buf nil))
 154     (if (< len wl-message-buffer-cache-size)
 155         (setq buf (wl-message-buffer-create))
 156       (let ((entry (nth (1- len) wl-message-buffer-cache)))
 157         (if (buffer-live-p
 158              (setq buf (wl-message-buffer-cache-buffer-get entry)))
 159             (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil)
 160           (setq wl-message-buffer-cache (delq entry wl-message-buffer-cache))
 161           (setq buf (wl-message-buffer-create)))))
 162     (setq wl-message-buffer-cache
 163           (cons (wl-message-buffer-cache-entry-make key buf)
 164                 wl-message-buffer-cache))
 165     buf))
 166
 167 (defun wl-message-buffer-cache-delete (&optional key)
 168   "Delete the most recent cache entry"
 169   (if key
 170       (setq wl-message-buffer-cache
 171             (delq (assoc key wl-message-buffer-cache)
 172                   wl-message-buffer-cache))
 173     (let ((buf (wl-message-buffer-cache-buffer-get
 174                 (car wl-message-buffer-cache))))
 175       (setq wl-message-buffer-cache
 176             (nconc (cdr wl-message-buffer-cache)
 177                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 178
 179 (defun wl-message-buffer-cache-clean-up ()
 180   "A function to flush all decoded messages in cache list."
 181   (interactive)
 182   (if (and (eq major-mode 'wl-summary-mode)
 183            wl-message-buffer
 184            (get-buffer-window wl-message-buffer))
 185       (delete-window (get-buffer-window wl-message-buffer)))
 186   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 187   (setq wl-message-buffer-cache nil))
 188
 189 ;;; Message buffer handling from summary buffer.
 190
 191 (defun wl-message-buffer-window ()
 192   "Get message buffer window if any."
 193   (let* ((start-win (selected-window))
 194          (cur-win start-win))
 195     (catch 'found
 196       (while (progn
 197                (setq cur-win (next-window cur-win))
 198                (with-current-buffer (window-buffer cur-win)
 199                  (if (or (eq major-mode 'wl-message-mode)
 200                          (eq major-mode 'mime-view-mode))
 201                      (throw 'found cur-win)))
 202                (not (eq cur-win start-win)))))))
 203
 204 (defun wl-message-select-buffer (buffer)
 205   "Select BUFFER as a message buffer."
 206   (let ((window (get-buffer-window buffer))
 207         (sum (car wl-message-window-size))
 208         (mes (cdr wl-message-window-size))
 209         whi)
 210     (when (and window
 211                (not (eq (save-excursion (set-buffer (window-buffer window))
 212                                         wl-message-buffer-cur-summary-buffer)
 213                         (current-buffer))))
 214       (delete-window window)
 215       (run-hooks 'wl-message-window-deleted-hook)
 216       (setq window nil))
 217     (if window
 218         (select-window window)
 219       (when wl-fixed-window-configuration
 220         (delete-other-windows)
 221         (and wl-stay-folder-window
 222              (wl-summary-toggle-disp-folder)))
 223       ;; There's no buffer window. Search for message window and snatch it.
 224       (if (setq window (wl-message-buffer-window))
 225           (select-window window)
 226         (setq whi (1- (window-height)))
 227         (if mes
 228             (progn
 229               (let ((total (+ sum mes)))
 230                 (setq sum (max window-min-height (/ (* whi sum) total)))
 231                 (setq mes (max window-min-height (/ (* whi mes) total))))
 232               (if (< whi (+ sum mes))
 233                   (enlarge-window (- (+ sum mes) whi)))))
 234         (split-window (get-buffer-window (current-buffer)) sum)
 235         (other-window 1)))
 236     (switch-to-buffer buffer)))
 237
 238 (defun wl-message-narrow-to-page (&optional arg)
 239   "Narrow to page.
 240 If ARG is specified, narrow to ARGth page."
 241   (interactive "P")
 242   (setq arg (if arg (prefix-numeric-value arg) 0))
 243   (save-excursion
 244     (condition-case ()
 245         (forward-page -1)               ; Beginning of current page.
 246       (beginning-of-buffer
 247        (goto-char (point-min))))
 248     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 249     (widen)
 250     (cond
 251      ((> arg 0) (forward-page arg))
 252      ((< arg 0) (forward-page (1- arg))))
 253     (forward-page)
 254     (if wl-break-pages
 255         (narrow-to-region (point)
 256                           (progn
 257                             (forward-page -1)
 258                             (if (and (eolp) (not (bobp)))
 259                                 (forward-line))
 260                             (point))))))
 261
 262 (defun wl-message-prev-page (&optional lines)
 263   "Scroll down current message by LINES.
 264 Returns non-nil if top of message."
 265   (interactive)
 266   (let (top real-top)
 267     (save-selected-window
 268       (unless (eq major-mode 'mime-view-mode)
 269         (when (buffer-live-p wl-message-buffer)
 270           (wl-message-select-buffer wl-message-buffer)))
 271       (move-to-window-line 0)
 272       (if (and wl-break-pages
 273                (bobp)
 274                (not (setq real-top (save-restriction (widen) (bobp)))))
 275           (progn
 276             (wl-message-narrow-to-page -1)
 277             (goto-char (point-max))
 278             (recenter))
 279         (if (not (bobp))
 280             (condition-case nil
 281                 (scroll-down (or lines wl-message-scroll-amount))
 282               (error))
 283           (setq top t)))
 284       (if real-top
 285           (let ((f (assq (mime-preview-original-major-mode)
 286                          mime-preview-over-to-previous-method-alist)))
 287             (if f (funcall (cdr f))))))
 288     top))
 289
 290 (defun wl-message-next-page (&optional lines)
 291   "Scroll up current message by LINES.
 292 Returns non-nil if bottom of message."
 293   (interactive)
 294   (let (bottom)
 295     (save-selected-window
 296       (unless (eq major-mode 'mime-view-mode)
 297         (when (buffer-live-p wl-message-buffer)
 298           (wl-message-select-buffer wl-message-buffer)))
 299       (move-to-window-line -1)
 300       (if (save-excursion
 301             (end-of-line)
 302             (and (pos-visible-in-window-p)
 303                  (eobp)))
 304           (if (or (null wl-break-pages)
 305                   (save-excursion
 306                     (save-restriction
 307                       (widen) (forward-line) (eobp))))
 308               (setq bottom t)
 309             (wl-message-narrow-to-page 1)
 310             (setq bottom nil))
 311         (condition-case ()
 312             (static-if (boundp 'window-pixel-scroll-increment)
 313                 ;; XEmacs 21.2.20 and later.
 314                 (let (window-pixel-scroll-increment)
 315                   (scroll-up (or lines wl-message-scroll-amount)))
 316               (scroll-up (or lines wl-message-scroll-amount)))
 317           (end-of-buffer
 318            (goto-char (point-max))))
 319         (setq bottom nil))
 320       (if (eobp)
 321           (let ((f (assq (mime-preview-original-major-mode)
 322                          mime-preview-over-to-next-method-alist)))
 323             (if f (funcall (cdr f))))))
 324     bottom))
 325
 326
 327 (defun wl-message-follow-current-entity (buffer)
 328   "Follow to current message."
 329   (wl-draft-reply (wl-message-get-original-buffer)
 330                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 331   (let ((mail-reply-buffer buffer))
 332     (wl-draft-yank-from-mail-reply-buffer nil)))
 333
 334 ;;
 335
 336 (defun wl-message-mode ()
 337   "A major mode for message displaying."
 338   (interactive)
 339   (setq major-mode 'wl-message-mode)
 340   (setq buffer-read-only t)
 341   (setq mode-name "Message"))
 342
 343 (defun wl-message-exit ()
 344   "Move to summary buffer or mother buffer."
 345   (interactive)
 346   (let (summary-buf summary-win mother-buffer)
 347     (cond ((setq summary-buf wl-message-buffer-cur-summary-buffer)
 348            (if (setq summary-win (get-buffer-window summary-buf))
 349                (select-window summary-win)
 350              (switch-to-buffer summary-buf)
 351              (wl-message-select-buffer wl-message-buffer)
 352              (select-window (get-buffer-window summary-buf))))
 353           ((setq mother-buffer mime-mother-buffer)
 354            (kill-buffer (current-buffer))
 355            (switch-to-buffer mother-buffer)))
 356     (run-hooks 'wl-message-exit-hook)))
 357
 358 (defun wl-message-toggle-disp-summary ()
 359   (interactive)
 360   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 361         summary-win)
 362     (if (and summary-buf
 363              (buffer-live-p summary-buf))
 364         (if (setq summary-win (get-buffer-window summary-buf))
 365             (delete-window summary-win)
 366           (switch-to-buffer summary-buf)
 367           (wl-message-select-buffer wl-message-buffer))
 368       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 369                                    nil nil t)
 370                                         ; no summary-buf
 371       (let ((sum-buf (current-buffer)))
 372         (wl-message-select-buffer wl-message-buffer)
 373         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 374
 375 (defun wl-message-get-original-buffer ()
 376   "Get original buffer for current message buffer."
 377   (if (buffer-live-p wl-message-buffer-original-buffer)
 378       wl-message-buffer-original-buffer
 379     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 380
 381 (defun wl-message-add-buttons-to-body (start end)
 382   (save-excursion
 383     (save-restriction
 384       (narrow-to-region start end)
 385       (let ((case-fold-search t)
 386             (alist wl-message-body-button-alist)
 387             entry)
 388         (while alist
 389           (setq entry (car alist)
 390                 alist (cdr alist))
 391           (goto-char (point-min))
 392           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 393             (unless (get-text-property (point) 'keymap)
 394               (wl-message-add-button
 395                (match-beginning (nth 1 entry))
 396                (match-end (nth 1 entry))
 397                (nth 2 entry)
 398                (match-string (nth 3 entry))))))))))
 399
 400 (defun wl-message-add-buttons-to-header (start end)
 401   (save-excursion
 402     (save-restriction
 403       (narrow-to-region start end)
 404       (let ((case-fold-search t)
 405             (alist wl-message-header-button-alist)
 406             entry)
 407         (while alist
 408           (setq entry (car alist)
 409                 alist (cdr alist))
 410           (goto-char (point-min))
 411           (while (re-search-forward (car entry) nil t)
 412             (setq start (match-beginning 0)
 413                   end (if (re-search-forward "^[^ \t]" nil t)
 414                           (match-beginning 0)
 415                         (point-max)))
 416             (goto-char start)
 417             (while (re-search-forward (nth 1 entry) end t)
 418               (wl-message-add-button
 419                (match-beginning (nth 2 entry))
 420                (match-end (nth 2 entry))
 421                (nth 3 entry) (match-string (nth 4 entry))))
 422             (goto-char end)))))))
 423
 424 ;; display-type object definition.
 425 (defun wl-message-make-display-type (mime header)
 426   (let (symbol)
 427     (prog1
 428         (setq symbol (intern (format "%s-%s-header" mime header)))
 429       (put symbol
 430            'wl-message-display-type
 431            (list :mime mime :header header)))))
 432
 433 (defun wl-message-display-type-property (display-type prop)
 434   (plist-get (get display-type 'wl-message-display-type) prop))
 435
 436 (defun wl-message-mime-analysis-p (display-type &optional header-or-body)
 437   (let ((mode (wl-message-display-type-property display-type :mime)))
 438     (case header-or-body
 439       (header
 440        (memq mode '(mime header-only)))
 441       (t
 442        (eq mode 'mime)))))
 443
 444 (defun wl-message-display-all-header-p (display-type)
 445   (eq (wl-message-display-type-property display-type :header) 'all))
 446
 447 (defun wl-message-buffer-display-type (&optional message-buffer)
 448   (if message-buffer
 449       (with-current-buffer message-buffer
 450         wl-message-buffer-cur-display-type)
 451     wl-message-buffer-cur-display-type))
 452
 453 (defun wl-message-redisplay (folder number display-type &optional force-reload)
 454   (let* ((default-mime-charset wl-mime-charset)
 455          (buffer-read-only nil)
 456          (summary-buf (current-buffer))
 457          message-buf entity summary-win flags)
 458     (setq buffer-read-only nil)
 459     (setq wl-message-buffer (wl-message-buffer-display
 460                              folder number display-type force-reload))
 461     (setq message-buf wl-message-buffer)
 462     (wl-message-select-buffer wl-message-buffer)
 463
 464     (set-buffer message-buf)
 465     (wl-deactivate-region)
 466     (make-local-variable 'truncate-partial-width-windows)
 467     (setq truncate-partial-width-windows nil)
 468     (setq truncate-lines wl-message-truncate-lines)
 469     (setq buffer-read-only nil)
 470     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 471     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 472     (setq wl-message-buffer-cur-number number)
 473     (setq wl-message-buffer-flag-indicator
 474           (if (setq flags (elmo-get-global-flags (elmo-message-flags
 475                                                   folder number)))
 476               (let ((fl wl-summary-flag-alist)
 477                     flag-strings flag-string face)
 478                 (while fl
 479                   (when (memq (car (car fl)) flags)
 480                     (setq flag-string (capitalize
 481                                        (symbol-name (car (car fl))))
 482                           flags (delq (car (car fl)) flags))
 483                     (when (facep (setq face
 484                                        (intern
 485                                         (format
 486                                          "wl-highlight-summary-%s-flag-face"
 487                                          (car (car fl))))))
 488                       (put-text-property 0 (length flag-string)
 489                                          'face face flag-string))
 490                     (setq flag-strings (nconc flag-strings
 491                                               (list flag-string))))
 492                   (setq fl (cdr fl)))
 493                 (setq flag-strings
 494                       (nconc flag-strings
 495                              (mapcar (lambda (flag)
 496                                        (capitalize (symbol-name flag)))
 497                                      flags)))
 498                 (concat " (" (mapconcat 'identity flag-strings ", ") ")"))
 499             ""))
 500     (wl-line-formatter-setup
 501      wl-message-buffer-mode-line-formatter
 502      wl-message-mode-line-format
 503      wl-message-mode-line-format-spec-alist)
 504     (setq mode-line-buffer-identification
 505           (funcall wl-message-buffer-mode-line-formatter))
 506     ;; highlight body
 507 ;    (when wl-highlight-body-too
 508 ;      (wl-highlight-body))
 509     (ignore-errors (wl-message-narrow-to-page))
 510     (goto-char (point-min))
 511     (when (re-search-forward "^$" nil t)
 512       (wl-message-add-buttons-to-header (point-min) (point))
 513       (wl-message-add-buttons-to-body (point) (point-max)))
 514     (when (and wl-message-use-header-narrowing
 515                (not (wl-message-display-all-header-p display-type)))
 516       (wl-message-header-narrowing))
 517     (goto-char (point-min))
 518     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 519     ;; go back to summary mode
 520     (set-buffer-modified-p nil)
 521     (setq buffer-read-only t)
 522     (set-buffer summary-buf)
 523     (setq summary-win (get-buffer-window summary-buf))
 524     (if (window-live-p summary-win)
 525         (select-window summary-win))))
 526
 527 ;; Use message buffer cache.
 528 (defun wl-message-buffer-display (folder number display-type
 529                                          &optional force-reload unread)
 530   (let* ((msg-id (ignore-errors
 531                    (elmo-message-field folder number 'message-id)))
 532          (fname (elmo-folder-name-internal folder))
 533          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 534          (redisplay nil)
 535          entity)
 536     (when (and hit (not (buffer-live-p hit)))
 537       (wl-message-buffer-cache-delete (list fname number msg-id))
 538       (setq hit nil))
 539     (if hit
 540         (progn
 541           ;; move hit to the top.
 542           (wl-message-buffer-cache-sort
 543            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 544           (with-current-buffer hit
 545             ;; Rewind to the top page
 546             (widen)
 547             (goto-char (point-min))
 548             (ignore-errors (wl-message-narrow-to-page))
 549             (setq entity wl-message-buffer-mime-entity)
 550             (unless (eq wl-message-buffer-cur-display-type display-type)
 551               (setq redisplay t))))
 552       ;; delete tail and add new to the top.
 553       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 554       (setq redisplay t))
 555     (when (or force-reload redisplay)
 556       (condition-case err
 557           (save-excursion
 558             (set-buffer hit)
 559             (when (or force-reload
 560                       (null entity)
 561                       (not (elmo-mime-entity-display-p
 562                             entity
 563                             (if (wl-message-mime-analysis-p display-type)
 564                                 'mime
 565                               'as-is))))
 566               (setq entity (elmo-message-mime-entity
 567                             folder
 568                             number
 569                             (wl-message-get-original-buffer)
 570                             force-reload
 571                             unread
 572                             (not (wl-message-mime-analysis-p display-type)))))
 573             (unless entity
 574               (error "Cannot display message %s/%s" fname number))
 575             (wl-message-display-internal entity display-type))
 576         (quit
 577          (wl-message-buffer-cache-delete)
 578          (error "Display message %s/%s is quitted" fname number))
 579         (error
 580          (wl-message-buffer-cache-delete)
 581          (signal (car err) (cdr err))
 582          nil))) ;; will not be used
 583     hit))
 584
 585 (defun wl-message-display-internal (entity display-type)
 586   (let ((default-mime-charset wl-mime-charset)
 587         (elmo-mime-charset wl-mime-charset)
 588         (wl-message-buffer-require-all-header
 589          (wl-message-display-all-header-p display-type)))
 590     (if (wl-message-mime-analysis-p display-type)
 591         (elmo-mime-entity-display entity
 592                                   (current-buffer)
 593                                   'wl-original-message-mode
 594                                   (wl-message-define-keymap))
 595       (let* ((elmo-mime-display-header-analysis
 596               (wl-message-mime-analysis-p display-type 'header))
 597              (wl-highlight-x-face-function
 598               (and elmo-mime-display-header-analysis
 599                    wl-highlight-x-face-function)))
 600         (elmo-mime-entity-display-as-is entity
 601                                         (current-buffer)
 602                                         'wl-original-message-mode
 603                                         (wl-message-define-keymap))
 604         (let (buffer-read-only)
 605           (wl-highlight-message (point-min) (point-max) t))))
 606     (setq wl-message-buffer-cur-display-type display-type
 607           wl-message-buffer-mime-entity entity)
 608     (run-hooks 'wl-message-display-internal-hook)
 609     (setq buffer-read-only t)))
 610
 611 (defun wl-message-buffer-prefetch-p (folder &optional number)
 612   (and (or (not number)
 613            (elmo-message-file-p folder number)
 614            (let ((size (elmo-message-field folder number 'size)))
 615              (not (and (integerp size)
 616                        wl-message-buffer-prefetch-threshold
 617                        (>= size wl-message-buffer-prefetch-threshold)))))
 618        (or (not number)
 619            (elmo-folder-plugged-p folder)
 620            (elmo-file-cache-exists-p
 621                  (elmo-message-field folder number 'message-id)))
 622        (or (cond
 623             ((eq wl-message-buffer-prefetch-folder-type-list t)
 624              t)
 625             ((and number wl-message-buffer-prefetch-folder-type-list)
 626              (memq (elmo-folder-type-internal
 627                     (elmo-message-folder folder number))
 628                    wl-message-buffer-prefetch-folder-type-list))
 629             (wl-message-buffer-prefetch-folder-type-list
 630              (let ((list wl-message-buffer-prefetch-folder-type-list)
 631                    type)
 632                (catch 'done
 633                  (while (setq type (pop list))
 634                    (if (elmo-folder-contains-type folder type)
 635                        (throw 'done t)))))))
 636            (cond
 637             ((consp wl-message-buffer-prefetch-folder-list)
 638              (wl-string-match-member (elmo-folder-name-internal folder)
 639                                      wl-message-buffer-prefetch-folder-list))
 640             (t wl-message-buffer-prefetch-folder-list)))))
 641
 642 (defsubst wl-message-buffer-prefetch-clear-timer ()
 643 ;;;     cannot use for the bug of fsf-compat package (1.09).
 644 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 645   (if (fboundp 'run-with-idle-timer)
 646       (if (featurep 'xemacs)
 647           (let ((p itimer-list))
 648             (while (car p)
 649               (if (eq 'wl-message-buffer-prefetch-subr
 650                       (itimer-function (car p)))
 651                   (delete-itimer (car p)))
 652               (setq p (cdr p))))
 653         ;; FSF Emacs is correct
 654         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 655
 656 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 657                                                        summary charset)
 658   (if (not (fboundp 'run-with-idle-timer))
 659       (when (sit-for wl-message-buffer-prefetch-idle-time)
 660         (wl-message-buffer-prefetch-subr
 661          folder number count summary charset))
 662     (run-with-idle-timer
 663      wl-message-buffer-prefetch-idle-time
 664      nil
 665      'wl-message-buffer-prefetch-subr
 666      folder number count summary charset)))
 667
 668 (defvar wl-message-buffer-prefetch-move-spec-alist nil)
 669
 670 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 671   (if (buffer-live-p summary)
 672       (with-current-buffer summary
 673         (let ((wl-summary-move-spec-alist
 674                (or wl-message-buffer-prefetch-move-spec-alist
 675                    wl-summary-move-spec-alist))
 676               (next number))
 677           (while (and (setq next (funcall
 678                                   wl-message-buffer-prefetch-get-next-function
 679                                   next))
 680                       (not (wl-message-buffer-prefetch-p folder next))))
 681           next))))
 682
 683 (defun wl-message-buffer-prefetch (folder number count
 684                                           &optional summary charset)
 685   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 686          (num number))
 687     (when (and (> count 0)
 688                (wl-message-buffer-prefetch-p folder))
 689       (unless (wl-message-buffer-prefetch-p folder number)
 690         (setq num
 691               (wl-message-buffer-prefetch-get-next folder number summary)))
 692       (when num
 693         (wl-message-buffer-prefetch-clear-timer)
 694         (wl-message-buffer-prefetch-set-timer
 695          folder num count summary charset)))))
 696
 697 (defun wl-message-buffer-prefetch-next (folder number count
 698                                                &optional summary charset)
 699   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 700          next)
 701     (when (and (> count 0)
 702                (wl-message-buffer-prefetch-p folder))
 703       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 704       (when next
 705         (wl-message-buffer-prefetch-clear-timer)
 706         (wl-message-buffer-prefetch-set-timer
 707          folder next count summary charset)))))
 708
 709 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 710   (if (buffer-live-p summary)
 711       (with-current-buffer summary
 712         (if (and number
 713                  (numberp count)
 714                  (>= (setq count (- count 1)) 0)
 715                  (string= (elmo-folder-name-internal folder)
 716                           (wl-summary-buffer-folder-name)))
 717             (let* ((wl-mime-charset      charset)
 718                    (default-mime-charset charset)
 719                    (message-id (elmo-message-field folder number 'message-id))
 720                    (key (list (elmo-folder-name-internal folder)
 721                               number message-id))
 722                    (hit (wl-message-buffer-cache-hit key))
 723                    (display-type (wl-message-make-display-type
 724                                   wl-summary-buffer-display-mime-mode
 725                                   wl-summary-buffer-display-header-mode))
 726                    time1 time2 sec micro)
 727               (when wl-message-buffer-prefetch-debug
 728                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 729               (if (and hit (buffer-live-p hit))
 730                   (progn
 731                     (wl-message-buffer-cache-sort
 732                      (wl-message-buffer-cache-entry-make key hit))
 733                     (wl-message-buffer-prefetch-subr
 734                      folder
 735                      (wl-message-buffer-prefetch-get-next
 736                       folder number summary)
 737                      count summary charset))
 738                 ;; prefetching
 739                 (when wl-message-buffer-prefetch-debug
 740                   (setq time1 (current-time))
 741                   (message "Prefetching %d..." number))
 742                 (wl-message-buffer-display folder number
 743                                            display-type nil 'unread)
 744                 (when (elmo-message-use-cache-p folder number)
 745                   (elmo-message-set-cached folder number t))
 746                 (when wl-message-buffer-prefetch-debug
 747                   (setq time2 (current-time))
 748                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 749                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 750                   (setq micro (+ micro (* 1000000 sec)))
 751                   (message "Prefetching %d...done(%f msec)."
 752                            number
 753                            (/ micro 1000.0))
 754                   (sit-for 0))
 755                 ;; set next prefetch
 756                 (wl-message-buffer-prefetch-set-timer
 757                  folder
 758                  (wl-message-buffer-prefetch-get-next
 759                   folder number summary)
 760                  count summary charset)
 761                 (sit-for 0)
 762                 ;; success prefetch
 763                 )))
 764         ;; finish prefetch
 765         (when wl-message-buffer-prefetch-debug
 766           (message "Buffer Cached Messages: %s"
 767                    (mapconcat
 768                     '(lambda (cache)
 769                        (if (numberp (nth 1 (car cache)))
 770                            (if (string=
 771                                 (nth 0 (car cache))
 772                                 (elmo-folder-name-internal folder))
 773                                (format "%d"
 774                                        (nth 1 (car cache)))
 775                              (format "*%d" (nth 1 (car cache))))
 776                          "-"))
 777                     wl-message-buffer-cache " "))) )))
 778
 779 (defvar wl-message-button-map (make-sparse-keymap))
 780
 781 (defun wl-message-add-button (from to function &optional data)
 782   "Create a button between FROM and TO with callback FUNCTION and DATA."
 783   (add-text-properties
 784    from to
 785    (nconc (list 'wl-message-button-callback function)
 786           (if data
 787               (list 'wl-message-button-data data))))
 788   (let ((ov (make-overlay from to)))
 789     (overlay-put ov 'mouse-face 'highlight)
 790     (overlay-put ov 'local-map wl-message-button-map)
 791     (overlay-put ov 'evaporate t)))
 792
 793 (defun wl-message-button-dispatcher (event)
 794   "Select the button under point."
 795   (interactive "@e")
 796   (mouse-set-point event)
 797   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 798         (data (get-text-property (point) 'wl-message-button-data)))
 799     (if callback
 800         (funcall callback data)
 801       (wl-message-button-dispatcher-internal event))))
 802
 803 (defun wl-message-button-refer-article (data)
 804   "Read article specified by Message-ID DATA at point."
 805   (switch-to-buffer-other-window
 806    wl-message-buffer-cur-summary-buffer)
 807   (if (wl-summary-jump-to-msg-by-message-id data)
 808       (wl-summary-redisplay)))
 809
 810 (defun wl-message-uu-substring (buf outbuf &optional first last)
 811   (save-excursion
 812     (set-buffer buf)
 813     (search-forward "\n\n")
 814     (let ((sp (point))
 815           ep filename case-fold-search)
 816       (catch 'done
 817         (if first
 818             (progn
 819               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 820                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 821                 (throw 'done nil)))
 822           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 823         (beginning-of-line)
 824         (setq sp (point))
 825         (goto-char (point-max))
 826         (if last
 827             (re-search-backward "^end" sp t)
 828           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 829         (forward-line 1)
 830         (setq ep (point))
 831         (set-buffer outbuf)
 832         (goto-char (point-max))
 833         (insert-buffer-substring buf sp ep)
 834         (set-buffer buf)
 835         filename))))
 836
 837 ;;; Header narrowing courtesy of Hideyuki Shirai.
 838 (defun wl-message-header-narrowing ()
 839   "Narrowing headers."
 840   (unless (eq this-command 'wl-summary-redisplay-all-header)
 841     (save-excursion
 842       (save-restriction
 843         (goto-char (point-min))
 844         (if (re-search-forward "^$" nil t)
 845             (beginning-of-line)
 846           (goto-char (point-max)))
 847         (narrow-to-region (point-min) (point))
 848         (let ((fields wl-message-header-narrowing-fields))
 849           (while fields
 850             (wl-message-header-narrowing-1 (concat "^" (car fields) ":"))
 851             (setq fields (cdr fields))))))))
 852
 853 (defvar wl-message-header-narrowing-map (make-sparse-keymap))
 854 (define-key wl-message-header-narrowing-map [mouse-2]
 855   'wl-message-header-narrowing-again-at-mouse)
 856
 857 (defvar wl-message-header-narrowing-widen-map (make-sparse-keymap))
 858 (define-key wl-message-header-narrowing-widen-map [mouse-2]
 859   'wl-message-header-narrowing-widen-at-mouse)
 860
 861 (defun wl-message-header-narrowing-again-at-mouse (event)
 862   (interactive "e")
 863   (save-window-excursion
 864     (save-excursion
 865       (mouse-set-point event)
 866       (wl-message-header-narrowing))))
 867
 868 (defun wl-message-header-narrowing-1 (hregexp)
 869   (let ((case-fold-search t)
 870         ov start end)
 871     (goto-char (point-min))
 872     (while (re-search-forward hregexp nil t)
 873       (setq start (match-beginning 0))
 874       (forward-line 1)
 875       (setq end (progn (while (looking-at "^[ \t]") (forward-line))
 876                        (forward-line -1)
 877                        (line-end-position)))
 878       (if (<= (count-lines start end) wl-message-header-narrowing-lines)
 879           (forward-line 1)
 880         (goto-char start)
 881         (forward-line (1- wl-message-header-narrowing-lines))
 882         (end-of-line)
 883         (setq start (point))
 884         (unless (eq (get-char-property start 'invisible)
 885                     'wl-message-header-narrowing)
 886           (setq ov (or
 887                     (let ((ovs (overlays-at start))
 888                           ov)
 889                       (while (and ovs (not (overlayp ov)))
 890                         (if (overlay-get (car ovs)
 891                                          'wl-message-header-narrowing)
 892                             (setq ov (car ovs)))
 893                         (setq ovs (cdr ovs)))
 894                       ov)
 895                     (make-overlay start end)))
 896           (overlay-put ov 'wl-message-header-narrowing t)
 897           (overlay-put ov 'evaporate t)
 898           (overlay-put ov 'invisible 'wl-message-header-narrowing)
 899           (overlay-put ov 'after-string
 900                        wl-message-header-narrowing-string))))))
 901
 902 (defun wl-message-header-narrowing-widen-at-mouse (event)
 903   (interactive "e")
 904   (save-selected-window
 905     (select-window (posn-window (event-start event)))
 906     (let* ((win (selected-window))
 907            (wpos (window-start win))
 908            (pos (mouse-set-point event))
 909            (ovs (overlays-in (1- pos) (1+ pos)))        ;; Uum...
 910            ov)
 911       (while (and ovs (not (overlayp ov)))
 912         (when (overlay-get (car ovs) 'wl-message-header-narrowing)
 913           (setq ov (car ovs)))
 914         (setq ovs (cdr ovs)))
 915       (when (overlayp ov)
 916         (overlay-put ov 'face 'wl-message-header-narrowing-face)
 917         (overlay-put ov 'local-map wl-message-header-narrowing-map)
 918         (overlay-put ov 'invisible nil)
 919         (overlay-put ov 'after-string nil))
 920       (set-window-start win wpos))))
 921
 922 (defun wl-message-header-narrowing-setup ()
 923   (when (boundp 'line-move-ignore-invisible)
 924     (set (make-local-variable 'line-move-ignore-invisible) t))
 925   (set-text-properties 0 (length wl-message-header-narrowing-string)
 926                        `(face
 927                          wl-message-header-narrowing-face
 928                          keymap
 929                          ,wl-message-header-narrowing-widen-map)
 930                        wl-message-header-narrowing-string))
 931
 932 (defun wl-message-header-narrowing-toggle ()
 933   "Toggle header narrowing."
 934   (interactive)
 935   (when wl-message-use-header-narrowing
 936     (save-excursion
 937       (goto-char (point-min))
 938       (if (re-search-forward "^$" nil t)
 939           (beginning-of-line)
 940         (goto-char (point-max)))
 941       (let ((ovs (overlays-in (point-min) (point)))
 942             ov hn-ovs)
 943         (while (setq ov (car ovs))
 944           (when (overlay-get ov 'wl-message-header-narrowing)
 945             (setq hn-ovs (cons ov hn-ovs)))
 946           (setq ovs (cdr ovs)))
 947         (if hn-ovs
 948             (while hn-ovs
 949               (delete-overlay (car hn-ovs))
 950               (setq hn-ovs (cdr hn-ovs)))
 951           (wl-message-header-narrowing))))))
 952
 953 (require 'product)
 954 (product-provide (provide 'wl-message) (require 'wl-version))
 955
 956 ;;; wl-message.el ends here