wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36 (require 'timer)
  37
  38 (eval-when-compile
  39   (require 'wl-mime)
  40   (require 'mime-view)
  41   (defalias-maybe 'event-window 'ignore)
  42   (defalias-maybe 'posn-window 'ignore)
  43   (defalias-maybe 'event-start 'ignore)
  44   (defalias-maybe 'mime-open-entity 'ignore)
  45   (defalias-maybe 'itimer-function 'ignore)
  46   (defalias-maybe 'delete-itimer 'ignore)
  47   (defvar-maybe itimer-list))
  48
  49 (defvar wl-message-buffer-prefetch-get-next-function
  50   'wl-summary-default-get-next-msg)
  51
  52 (defvar wl-message-buffer-prefetch-debug nil)
  53 (defvar wl-message-buffer-prefetch-timer nil)
  54
  55 (defvar wl-message-buffer nil) ; message buffer.
  56
  57 (defvar wl-message-buffer-cur-summary-buffer nil)
  58 (defvar wl-message-buffer-cur-folder nil)
  59 (defvar wl-message-buffer-cur-number nil)
  60 (defvar wl-message-buffer-cur-flag nil)
  61 (defvar wl-message-buffer-cur-summary-buffer nil)
  62 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  63 (defvar wl-message-buffer-all-header-flag nil)
  64 (defvar wl-message-buffer-mode-line-formatter nil)
  65
  66 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  67 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-flag)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  70 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  71 (make-variable-buffer-local 'wl-message-buffer-all-header-flag)
  72 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  73
  74 (defvar wl-fixed-window-configuration nil)
  75
  76 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  77
  78 ;;; Message buffer cache.
  79
  80 (defvar wl-message-buffer-cache nil
  81   "Message cache.  (old ... new) order alist.
  82 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  83
  84 (defmacro wl-message-buffer-cache-buffer-get (entry)
  85   (` (cdr (, entry))))
  86
  87 (defmacro wl-message-buffer-cache-folder-get (entry)
  88   (` (car (car (, entry)))))
  89
  90 (defmacro wl-message-buffer-cache-message-get (entry)
  91   (` (cdr (car (, entry)))))
  92
  93 (defmacro wl-message-buffer-cache-entry-make (key buf)
  94   (` (cons (, key) (, buf))))
  95
  96 (defmacro wl-message-buffer-cache-hit (key)
  97   "Return value assosiated with key."
  98   (` (wl-message-buffer-cache-buffer-get
  99       (assoc (, key) wl-message-buffer-cache))))
 100
 101 (defun wl-message-buffer-cache-sort (entry)
 102   "Move ENTRY to the top of `wl-message-buffer-cache'."
 103   (setq wl-message-buffer-cache
 104         (cons entry (delete entry wl-message-buffer-cache))))
 105 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 106 ;        (top pointer))
 107 ;    (while (cdr pointer)
 108 ;      (if (equal (car (cdr pointer)) entry)
 109 ;         (setcdr pointer (cdr (cdr pointer)))
 110 ;       (setq pointer (cdr pointer))))
 111 ;    (setcdr pointer (list entry))
 112 ;    (setq wl-message-buffer-cache (cdr top))))
 113
 114 (defconst wl-original-message-buffer-name " *Original*")
 115
 116 (defun wl-original-message-mode ()
 117   "A major mode for original message buffer."
 118   (setq major-mode 'wl-original-message-mode)
 119   (setq buffer-read-only t)
 120   (elmo-set-buffer-multibyte nil)
 121   (setq mode-name "Wanderlust original message"))
 122
 123 (defun wl-original-message-buffer-get (name)
 124   "Get original message buffer for NAME.
 125 If original message buffer already exists, it is re-used."
 126   (let* ((name (concat wl-original-message-buffer-name name))
 127          (buffer (get-buffer name)))
 128     (unless (and buffer (buffer-live-p buffer))
 129       (with-current-buffer (setq buffer (get-buffer-create name))
 130         (wl-original-message-mode)))
 131     buffer))
 132
 133 (defun wl-message-buffer-create ()
 134   "Create a new message buffer."
 135   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 136          (name (buffer-name buffer)))
 137     (with-current-buffer buffer
 138       (setq wl-message-buffer-original-buffer
 139             (wl-original-message-buffer-get name))
 140       (run-hooks 'wl-message-buffer-created-hook))
 141     buffer))
 142
 143 (defun wl-message-buffer-cache-add (key)
 144   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 145 Return its cache buffer."
 146   (let ((len (length wl-message-buffer-cache))
 147         (buf nil))
 148     (if (< len wl-message-buffer-cache-size)
 149         (setq buf (wl-message-buffer-create))
 150       (let ((entry (nth (1- len) wl-message-buffer-cache)))
 151         (if (buffer-live-p
 152              (setq buf (wl-message-buffer-cache-buffer-get entry)))
 153             (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil)
 154           (setq wl-message-buffer-cache (delq entry wl-message-buffer-cache))
 155           (setq buf (wl-message-buffer-create)))))
 156     (setq wl-message-buffer-cache
 157           (cons (wl-message-buffer-cache-entry-make key buf)
 158                 wl-message-buffer-cache))
 159     buf))
 160
 161 (defun wl-message-buffer-cache-delete (&optional key)
 162   "Delete the most recent cache entry"
 163   (if key
 164       (setq wl-message-buffer-cache
 165             (delq (assoc key wl-message-buffer-cache)
 166                   wl-message-buffer-cache))
 167     (let ((buf (wl-message-buffer-cache-buffer-get
 168                 (car wl-message-buffer-cache))))
 169       (setq wl-message-buffer-cache
 170             (nconc (cdr wl-message-buffer-cache)
 171                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 172
 173 (defun wl-message-buffer-cache-clean-up ()
 174   "A function to flush all decoded messages in cache list."
 175   (interactive)
 176   (if (and (eq major-mode 'wl-summary-mode)
 177            wl-message-buffer
 178            (get-buffer-window wl-message-buffer))
 179       (delete-window (get-buffer-window wl-message-buffer)))
 180   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 181   (setq wl-message-buffer-cache nil))
 182
 183 ;;; Message buffer handling from summary buffer.
 184
 185 (defun wl-message-buffer-window ()
 186   "Get message buffer window if any."
 187   (let* ((start-win (selected-window))
 188          (cur-win start-win))
 189     (catch 'found
 190       (while (progn
 191                (setq cur-win (next-window cur-win))
 192                (with-current-buffer (window-buffer cur-win)
 193                  (if (or (eq major-mode 'wl-message-mode)
 194                          (eq major-mode 'mime-view-mode))
 195                      (throw 'found cur-win)))
 196                (not (eq cur-win start-win)))))))
 197
 198 (defun wl-message-select-buffer (buffer)
 199   "Select BUFFER as a message buffer."
 200   (let ((window (get-buffer-window buffer))
 201         (sum (car wl-message-window-size))
 202         (mes (cdr wl-message-window-size))
 203         whi)
 204     (when (and window
 205                (not (eq (save-excursion (set-buffer (window-buffer window))
 206                                         wl-message-buffer-cur-summary-buffer)
 207                         (current-buffer))))
 208       (delete-window window)
 209       (run-hooks 'wl-message-window-deleted-hook)
 210       (setq window nil))
 211     (if window
 212         (select-window window)
 213       (when wl-fixed-window-configuration
 214         (delete-other-windows)
 215         (and wl-stay-folder-window
 216              (wl-summary-toggle-disp-folder)))
 217       ;; There's no buffer window. Search for message window and snatch it.
 218       (if (setq window (wl-message-buffer-window))
 219           (select-window window)
 220         (setq whi (1- (window-height)))
 221         (if mes
 222             (progn
 223               (let ((total (+ sum mes)))
 224                 (setq sum (max window-min-height (/ (* whi sum) total)))
 225                 (setq mes (max window-min-height (/ (* whi mes) total))))
 226               (if (< whi (+ sum mes))
 227                   (enlarge-window (- (+ sum mes) whi)))))
 228         (split-window (get-buffer-window (current-buffer)) sum)
 229         (other-window 1)))
 230     (switch-to-buffer buffer)))
 231
 232 (defun wl-message-narrow-to-page (&optional arg)
 233   "Narrow to page.
 234 If ARG is specified, narrow to ARGth page."
 235   (interactive "P")
 236   (setq arg (if arg (prefix-numeric-value arg) 0))
 237   (save-excursion
 238     (condition-case ()
 239         (forward-page -1)               ; Beginning of current page.
 240       (beginning-of-buffer
 241        (goto-char (point-min))))
 242     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 243     (widen)
 244     (cond
 245      ((> arg 0) (forward-page arg))
 246      ((< arg 0) (forward-page (1- arg))))
 247     (forward-page)
 248     (if wl-break-pages
 249         (narrow-to-region (point)
 250                           (progn
 251                             (forward-page -1)
 252                             (if (and (eolp) (not (bobp)))
 253                                 (forward-line))
 254                             (point))))))
 255
 256 (defun wl-message-prev-page (&optional lines)
 257   "Scroll down current message by LINES.
 258 Returns non-nil if top of message."
 259   (interactive)
 260   (let (cur-buf top real-top)
 261     (unless (eq major-mode 'mime-view-mode)
 262       (when (buffer-live-p wl-message-buffer)
 263         (setq cur-buf (current-buffer))
 264         (wl-message-select-buffer wl-message-buffer)))
 265     (move-to-window-line 0)
 266     (if (and wl-break-pages
 267              (bobp)
 268              (not (setq real-top (save-restriction (widen) (bobp)))))
 269         (progn
 270           (wl-message-narrow-to-page -1)
 271           (goto-char (point-max))
 272           (recenter))
 273       (if (not (bobp))
 274           (condition-case nil
 275               (scroll-down (or lines wl-message-scroll-amount))
 276             (error))
 277         (setq top t)))
 278     (if real-top
 279         (let ((f (assq (mime-preview-original-major-mode)
 280                        mime-preview-over-to-previous-method-alist)))
 281           (if f (funcall (cdr f))))
 282       (when cur-buf
 283         (select-window (get-buffer-window cur-buf))))
 284     top))
 285
 286 (defun wl-message-next-page (&optional lines)
 287   "Scroll up current message by LINES.
 288 Returns non-nil if bottom of message."
 289   (interactive)
 290   (let (cur-buf bottom)
 291     (unless (eq major-mode 'mime-view-mode)
 292       (when (buffer-live-p wl-message-buffer)
 293         (setq cur-buf (current-buffer))
 294         (wl-message-select-buffer wl-message-buffer)))
 295     (move-to-window-line -1)
 296     (if (save-excursion
 297           (end-of-line)
 298           (and (pos-visible-in-window-p)
 299                (eobp)))
 300         (if (or (null wl-break-pages)
 301                 (save-excursion
 302                   (save-restriction
 303                     (widen) (forward-line) (eobp))))
 304             (setq bottom t)
 305           (wl-message-narrow-to-page 1)
 306           (setq bottom nil))
 307       (condition-case ()
 308           (static-if (boundp 'window-pixel-scroll-increment)
 309               ;; XEmacs 21.2.20 and later.
 310               (let (window-pixel-scroll-increment)
 311                 (scroll-up (or lines wl-message-scroll-amount)))
 312             (scroll-up (or lines wl-message-scroll-amount)))
 313         (end-of-buffer
 314          (goto-char (point-max))))
 315       (setq bottom nil))
 316     (if (eobp)
 317         (let ((f (assq (mime-preview-original-major-mode)
 318                        mime-preview-over-to-next-method-alist)))
 319           (if f (funcall (cdr f))))
 320       (when cur-buf
 321         (select-window (get-buffer-window cur-buf))))
 322     bottom))
 323
 324
 325 (defun wl-message-follow-current-entity (buffer)
 326   "Follow to current message."
 327   (wl-draft-reply (wl-message-get-original-buffer)
 328                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 329   (let ((mail-reply-buffer buffer))
 330     (wl-draft-yank-from-mail-reply-buffer nil)))
 331
 332 ;;
 333
 334 (defun wl-message-mode ()
 335   "A major mode for message displaying."
 336   (interactive)
 337   (setq major-mode 'wl-message-mode)
 338   (setq buffer-read-only t)
 339   (setq mode-name "Message"))
 340
 341 (defun wl-message-exit ()
 342   "Move to summary buffer."
 343   (interactive)
 344   (let (summary-buf summary-win)
 345     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 346         (if (setq summary-win (get-buffer-window summary-buf))
 347             (select-window summary-win)
 348           (switch-to-buffer summary-buf)
 349           (wl-message-select-buffer wl-message-buffer)
 350           (select-window (get-buffer-window summary-buf))))
 351     (run-hooks 'wl-message-exit-hook)))
 352
 353 (defun wl-message-toggle-disp-summary ()
 354   (interactive)
 355   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 356         summary-win)
 357     (if (and summary-buf
 358              (buffer-live-p summary-buf))
 359         (if (setq summary-win (get-buffer-window summary-buf))
 360             (delete-window summary-win)
 361           (switch-to-buffer summary-buf)
 362           (wl-message-select-buffer wl-message-buffer))
 363       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 364                                    nil nil t)
 365                                         ; no summary-buf
 366       (let ((sum-buf (current-buffer)))
 367         (wl-message-select-buffer wl-message-buffer)
 368         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 369
 370 (defun wl-message-get-original-buffer ()
 371   "Get original buffer for current message buffer."
 372   (if (buffer-live-p wl-message-buffer-original-buffer)
 373       wl-message-buffer-original-buffer
 374     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 375
 376 (defun wl-message-add-buttons-to-body (start end)
 377   (save-excursion
 378     (save-restriction
 379       (narrow-to-region start end)
 380       (let ((case-fold-search t)
 381             (alist wl-message-body-button-alist)
 382             entry)
 383         (while alist
 384           (setq entry (car alist)
 385                 alist (cdr alist))
 386           (goto-char (point-min))
 387           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 388             (unless (get-text-property (point) 'keymap)
 389               (wl-message-add-button
 390                (match-beginning (nth 1 entry))
 391                (match-end (nth 1 entry))
 392                (nth 2 entry)
 393                (match-string (nth 3 entry))))))))))
 394
 395 (defun wl-message-add-buttons-to-header (start end)
 396   (save-excursion
 397     (save-restriction
 398       (narrow-to-region start end)
 399       (let ((case-fold-search t)
 400             (alist wl-message-header-button-alist)
 401             entry)
 402         (while alist
 403           (setq entry (car alist)
 404                 alist (cdr alist))
 405           (goto-char (point-min))
 406           (while (re-search-forward (car entry) nil t)
 407             (setq start (match-beginning 0)
 408                   end (if (re-search-forward "^[^ \t]" nil t)
 409                           (match-beginning 0)
 410                         (point-max)))
 411             (goto-char start)
 412             (while (re-search-forward (nth 1 entry) end t)
 413               (wl-message-add-button
 414                (match-beginning (nth 2 entry))
 415                (match-end (nth 2 entry))
 416                (nth 3 entry) (match-string (nth 4 entry))))
 417             (goto-char end)))))))
 418
 419 (defun wl-message-redisplay (folder number flag &optional force-reload)
 420   (let* ((default-mime-charset wl-mime-charset)
 421          (buffer-read-only nil)
 422          (summary-buf (current-buffer))
 423          message-buf
 424          strategy entity
 425          cache-used
 426          summary-win delim)
 427     (setq buffer-read-only nil)
 428     (setq cache-used (wl-message-buffer-display
 429                       folder number flag force-reload))
 430     (setq wl-message-buffer (car cache-used))
 431     (setq message-buf wl-message-buffer)
 432     (wl-message-select-buffer wl-message-buffer)
 433
 434     (set-buffer message-buf)
 435     (make-local-variable 'truncate-partial-width-windows)
 436     (setq truncate-partial-width-windows nil)
 437     (setq truncate-lines wl-message-truncate-lines)
 438     (setq buffer-read-only nil)
 439     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 440     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 441     (setq wl-message-buffer-cur-number number)
 442     (wl-line-formatter-setup
 443      wl-message-buffer-mode-line-formatter
 444      wl-message-mode-line-format
 445      wl-message-mode-line-format-spec-alist)
 446     (setq mode-line-buffer-identification
 447           (funcall wl-message-buffer-mode-line-formatter))
 448     ;; highlight body
 449 ;    (when wl-highlight-body-too
 450 ;      (wl-highlight-body))
 451     (ignore-errors (wl-message-narrow-to-page))
 452     (setq cache-used (cdr cache-used))
 453     (goto-char (point-min))
 454     (when (re-search-forward "^$" nil t)
 455       (wl-message-add-buttons-to-header (point-min) (point))
 456       (wl-message-add-buttons-to-body (point) (point-max)))
 457     (goto-char (point-min))
 458     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 459     ;; go back to summary mode
 460     (set-buffer-modified-p nil)
 461     (setq buffer-read-only t)
 462     (set-buffer summary-buf)
 463     (setq summary-win (get-buffer-window summary-buf))
 464     (if (window-live-p summary-win)
 465         (select-window summary-win))
 466     cache-used))
 467
 468 ;; Use message buffer cache.
 469 (defun wl-message-buffer-display (folder number flag
 470                                          &optional force-reload unread)
 471   (let* ((msg-id (elmo-message-field folder number 'message-id))
 472          (fname (elmo-folder-name-internal folder))
 473          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 474          (read nil)
 475          cache-used)
 476     (when (and hit (not (buffer-live-p hit)))
 477       (wl-message-buffer-cache-delete (list fname number msg-id))
 478       (setq hit nil))
 479     (if hit
 480         (progn
 481           ;; move hit to the top.
 482           (wl-message-buffer-cache-sort
 483            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 484           ;; buffer cache is used.
 485           (setq cache-used t)
 486           (with-current-buffer hit
 487             ;; Rewind to the top page
 488             (widen)
 489             (goto-char (point-min))
 490             (ignore-errors (wl-message-narrow-to-page))
 491             (unless (eq wl-message-buffer-cur-flag flag)
 492               (setq read t))))
 493       ;; delete tail and add new to the top.
 494       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 495       (setq read t))
 496     (if (or force-reload read)
 497         (condition-case err
 498             (save-excursion
 499               (set-buffer hit)
 500               (setq
 501                cache-used
 502                (wl-message-display-internal folder number flag
 503                                             force-reload unread))
 504               (setq wl-message-buffer-cur-flag flag))
 505           (quit
 506            (wl-message-buffer-cache-delete)
 507            (error "Display message %s/%s is quitted" fname number))
 508           (error
 509            (wl-message-buffer-cache-delete)
 510            (signal (car err) (cdr err))
 511            nil))) ;; will not be used
 512     (cons hit cache-used)))
 513
 514 (defun wl-message-display-internal (folder number flag
 515                                            &optional force-reload unread)
 516   (let ((default-mime-charset wl-mime-charset)
 517         (elmo-mime-charset wl-mime-charset))
 518     (setq wl-message-buffer-all-header-flag (eq flag 'all-header))
 519     (prog1
 520         (if (eq flag 'as-is)
 521             (let (wl-highlight-x-face-function)
 522               (prog1 (elmo-mime-display-as-is folder number
 523                                               (current-buffer)
 524                                               (wl-message-get-original-buffer)
 525                                               'wl-original-message-mode
 526                                               force-reload
 527                                               unread
 528                                               (wl-message-define-keymap))
 529                 (let (buffer-read-only)
 530                   (wl-highlight-message (point-min) (point-max) t))))
 531           (elmo-mime-message-display folder number
 532                                      (current-buffer)
 533                                      (wl-message-get-original-buffer)
 534                                      'wl-original-message-mode
 535                                      force-reload
 536                                      unread
 537                                      (wl-message-define-keymap)))
 538       (run-hooks 'wl-message-display-internal-hook)
 539       (setq buffer-read-only t))))
 540
 541 (defsubst wl-message-buffer-prefetch-p (folder &optional number)
 542   (and (or (not number)
 543            (elmo-message-file-p folder number)
 544            (let ((size (elmo-message-field folder number 'size)))
 545              (not (and (integerp size)
 546                        wl-message-buffer-prefetch-threshold
 547                        (>= size wl-message-buffer-prefetch-threshold)))))
 548        (or (not number)
 549            (elmo-folder-plugged-p folder)
 550            (elmo-file-cache-exists-p
 551                  (elmo-message-field folder number 'message-id)))
 552        (or (cond
 553             ((eq wl-message-buffer-prefetch-folder-type-list t)
 554              t)
 555             ((and number wl-message-buffer-prefetch-folder-type-list)
 556              (memq (elmo-folder-type-internal
 557                     (elmo-message-folder folder number))
 558                    wl-message-buffer-prefetch-folder-type-list))
 559             (wl-message-buffer-prefetch-folder-type-list
 560              (let ((list wl-message-buffer-prefetch-folder-type-list)
 561                    type)
 562                (catch 'done
 563                  (while (setq type (pop list))
 564                    (if (elmo-folder-contains-type folder type)
 565                        (throw 'done t)))))))
 566            (cond
 567             ((consp wl-message-buffer-prefetch-folder-list)
 568              (wl-string-match-member (elmo-folder-name-internal folder)
 569                                      wl-message-buffer-prefetch-folder-list))
 570             (t wl-message-buffer-prefetch-folder-list)))))
 571
 572 (defsubst wl-message-buffer-prefetch-clear-timer ()
 573 ;;;     cannot use for the bug of fsf-compat package (1.09).
 574 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 575   (if (fboundp 'run-with-idle-timer)
 576       (if (featurep 'xemacs)
 577           (let ((p itimer-list))
 578             (while (car p)
 579               (if (eq 'wl-message-buffer-prefetch-subr
 580                       (itimer-function (car p)))
 581                   (delete-itimer (car p)))
 582               (setq p (cdr p))))
 583         ;; FSF Emacs is correct
 584         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 585
 586 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 587                                                        summary charset)
 588   (if (not (fboundp 'run-with-idle-timer))
 589       (when (sit-for wl-message-buffer-prefetch-idle-time)
 590         (wl-message-buffer-prefetch-subr
 591          folder number count summary charset))
 592     (run-with-idle-timer
 593      wl-message-buffer-prefetch-idle-time
 594      nil
 595      'wl-message-buffer-prefetch-subr
 596      folder number count summary charset)))
 597
 598 (defvar wl-message-buffer-prefetch-move-spec-alist nil)
 599
 600 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 601   (if (buffer-live-p summary)
 602       (with-current-buffer summary
 603         (let ((wl-summary-move-spec-alist
 604                (or wl-message-buffer-prefetch-move-spec-alist
 605                    wl-summary-move-spec-alist))
 606               (next number))
 607           (while (and (setq next (funcall
 608                                   wl-message-buffer-prefetch-get-next-function
 609                                   next))
 610                       (not (wl-message-buffer-prefetch-p folder next))))
 611           next))))
 612
 613 (defun wl-message-buffer-prefetch (folder number count
 614                                           &optional summary charset)
 615   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 616          (num number))
 617     (when (and count
 618                (wl-message-buffer-prefetch-p folder))
 619       (unless (wl-message-buffer-prefetch-p folder number)
 620         (setq num
 621               (wl-message-buffer-prefetch-get-next folder number summary)))
 622       (when num
 623         (wl-message-buffer-prefetch-clear-timer)
 624         (wl-message-buffer-prefetch-set-timer
 625          folder num count summary charset)))))
 626
 627 (defun wl-message-buffer-prefetch-next (folder number count
 628                                                &optional summary charset)
 629   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 630          next)
 631     (when (and count
 632                (wl-message-buffer-prefetch-p folder))
 633       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 634       (when next
 635         (wl-message-buffer-prefetch-clear-timer)
 636         (wl-message-buffer-prefetch-set-timer
 637          folder next count summary charset)))))
 638
 639 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 640   (if (buffer-live-p summary)
 641       (with-current-buffer summary
 642         (if (and number
 643                  (numberp count)
 644                  (>= (setq count (- count 1)) 0)
 645                  (string= (elmo-folder-name-internal folder)
 646                           (wl-summary-buffer-folder-name)))
 647             (let* ((wl-mime-charset      charset)
 648                    (default-mime-charset charset)
 649                    (message-id (elmo-message-field folder number 'message-id))
 650                    (key (list (elmo-folder-name-internal folder)
 651                               number message-id))
 652                    (hit (wl-message-buffer-cache-hit key))
 653                    result time1 time2 sec micro)
 654               (when wl-message-buffer-prefetch-debug
 655                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 656               (if (and hit (buffer-live-p hit))
 657                   (progn
 658                     (wl-message-buffer-cache-sort
 659                      (wl-message-buffer-cache-entry-make key hit))
 660                     (wl-message-buffer-prefetch-subr
 661                      folder
 662                      (wl-message-buffer-prefetch-get-next
 663                       folder number summary)
 664                      count summary charset))
 665                 ;; prefetching
 666                 (when wl-message-buffer-prefetch-debug
 667                   (setq time1 (current-time))
 668                   (message "Prefetching %d..." number))
 669                 (setq result (wl-message-buffer-display
 670                               folder number 'mime nil 'unread))
 671                 (when wl-message-buffer-prefetch-debug
 672                   (setq time2 (current-time))
 673                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 674                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 675                   (setq micro (+ micro (* 1000000 sec)))
 676                   (message "Prefetching %d...done(%f msec)."
 677                            number
 678                            (/ micro 1000.0))
 679                   (sit-for 0))
 680                 ;; set next prefetch
 681                 (wl-message-buffer-prefetch-set-timer
 682                  folder
 683                  (wl-message-buffer-prefetch-get-next
 684                   folder number summary)
 685                  count summary charset)
 686                 (sit-for 0)
 687                 ;; success prefetch
 688                 )))
 689         ;; finish prefetch
 690         (when wl-message-buffer-prefetch-debug
 691           (message "Buffer Cached Messages: %s"
 692                    (mapconcat
 693                     '(lambda (cache)
 694                        (if (numberp (nth 1 (car cache)))
 695                            (if (string=
 696                                 (nth 0 (car cache))
 697                                 (elmo-folder-name-internal folder))
 698                                (format "%d"
 699                                        (nth 1 (car cache)))
 700                              (format "*%d" (nth 1 (car cache))))
 701                          "-"))
 702                     wl-message-buffer-cache " "))) )))
 703
 704 (defvar wl-message-button-map (make-sparse-keymap))
 705
 706 (defun wl-message-add-button (from to function &optional data)
 707   "Create a button between FROM and TO with callback FUNCTION and DATA."
 708   (add-text-properties
 709    from to
 710    (nconc (list 'wl-message-button-callback function)
 711           (if data
 712               (list 'wl-message-button-data data))))
 713   (let ((ov (make-overlay from to)))
 714     (overlay-put ov 'mouse-face 'highlight)
 715     (overlay-put ov 'local-map wl-message-button-map)
 716     (overlay-put ov 'evaporate t)))
 717
 718 (defun wl-message-button-dispatcher (event)
 719   "Select the button under point."
 720   (interactive "@e")
 721   (mouse-set-point event)
 722   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 723         (data (get-text-property (point) 'wl-message-button-data)))
 724     (if callback
 725         (funcall callback data)
 726       (wl-message-button-dispatcher-internal event))))
 727
 728 (defun wl-message-button-refer-article (data)
 729   "Read article specified by Message-ID DATA at point."
 730   (switch-to-buffer-other-window
 731    wl-message-buffer-cur-summary-buffer)
 732   (if (wl-summary-jump-to-msg-by-message-id data)
 733       (wl-summary-redisplay)))
 734
 735 (defun wl-message-uu-substring (buf outbuf &optional first last)
 736   (save-excursion
 737     (set-buffer buf)
 738     (search-forward "\n\n")
 739     (let ((sp (point))
 740           ep filename case-fold-search)
 741       (catch 'done
 742         (if first
 743             (progn
 744               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 745                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 746                 (throw 'done nil)))
 747           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 748         (beginning-of-line)
 749         (setq sp (point))
 750         (goto-char (point-max))
 751         (if last
 752             (re-search-backward "^end" sp t)
 753           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 754         (forward-line 1)
 755         (setq ep (point))
 756         (set-buffer outbuf)
 757         (goto-char (point-max))
 758         (insert-buffer-substring buf sp ep)
 759         (set-buffer buf)
 760         filename))))
 761
 762 (require 'product)
 763 (product-provide (provide 'wl-message) (require 'wl-version))
 764
 765 ;;; wl-message.el ends here