wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'wl-vars)
  34 (require 'wl-highlight)
  35 (require 'elmo)
  36 (require 'elmo-mime)
  37 (require 'timer)
  38
  39 (eval-when-compile
  40   (require 'wl-mime)
  41   (require 'mime-view)
  42   (defalias-maybe 'event-window 'ignore)
  43   (defalias-maybe 'posn-window 'ignore)
  44   (defalias-maybe 'event-start 'ignore)
  45   (defalias-maybe 'mime-open-entity 'ignore)
  46   (defalias-maybe 'itimer-function 'ignore)
  47   (defalias-maybe 'delete-itimer 'ignore)
  48   (defvar-maybe itimer-list))
  49
  50 (defvar wl-message-buffer-prefetch-get-next-function
  51   'wl-summary-default-get-next-msg)
  52
  53 (defvar wl-message-buffer-prefetch-debug nil)
  54
  55 (defvar wl-message-buffer nil) ; message buffer.
  56
  57 (defvar wl-message-buffer-cur-folder nil)
  58 (defvar wl-message-buffer-cur-number nil)
  59 (defvar wl-message-buffer-cur-display-type nil)
  60 (defvar wl-message-buffer-cur-summary-buffer nil)
  61 (defvar wl-message-buffer-require-all-header nil)
  62 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  63 (defvar wl-message-buffer-mode-line-formatter nil)
  64 (defvar wl-message-buffer-flag-indicator nil)
  65 (defvar wl-message-buffer-mime-entity nil)
  66
  67 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-display-type)
  70 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  71 (make-variable-buffer-local 'wl-message-buffer-require-all-header)
  72 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  73 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  74 (make-variable-buffer-local 'wl-message-buffer-flag-indicator)
  75 (make-variable-buffer-local 'wl-message-buffer-mime-entity)
  76
  77 (defvar wl-fixed-window-configuration nil)
  78
  79 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  80
  81 ;;; Message buffer cache.
  82
  83 (defvar wl-message-buffer-cache nil
  84   "Message cache.  (old ... new) order alist.
  85 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  86
  87 (defmacro wl-message-buffer-cache-buffer-get (entry)
  88   (` (cdr (, entry))))
  89
  90 (defmacro wl-message-buffer-cache-folder-get (entry)
  91   (` (car (car (, entry)))))
  92
  93 (defmacro wl-message-buffer-cache-message-get (entry)
  94   (` (cdr (car (, entry)))))
  95
  96 (defmacro wl-message-buffer-cache-entry-make (key buf)
  97   (` (cons (, key) (, buf))))
  98
  99 (defmacro wl-message-buffer-cache-hit (key)
 100   "Return value assosiated with key."
 101   (` (wl-message-buffer-cache-buffer-get
 102       (assoc (, key) wl-message-buffer-cache))))
 103
 104 (defun wl-message-buffer-cache-sort (entry)
 105   "Move ENTRY to the top of `wl-message-buffer-cache'."
 106   (setq wl-message-buffer-cache
 107         (cons entry (delete entry wl-message-buffer-cache))))
 108 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 109 ;        (top pointer))
 110 ;    (while (cdr pointer)
 111 ;      (if (equal (car (cdr pointer)) entry)
 112 ;         (setcdr pointer (cdr (cdr pointer)))
 113 ;       (setq pointer (cdr pointer))))
 114 ;    (setcdr pointer (list entry))
 115 ;    (setq wl-message-buffer-cache (cdr top))))
 116
 117 (defconst wl-original-message-buffer-name " *Original*")
 118
 119 (defun wl-original-message-mode ()
 120   "A major mode for original message buffer."
 121   (setq major-mode 'wl-original-message-mode)
 122   (setq buffer-read-only t)
 123   (set-buffer-multibyte nil)
 124   (setq mode-name "Wanderlust original message"))
 125
 126 (defun wl-original-message-buffer-get (name)
 127   "Get original message buffer for NAME.
 128 If original message buffer already exists, it is re-used."
 129   (let* ((name (concat wl-original-message-buffer-name name))
 130          (buffer (get-buffer name)))
 131     (unless (and buffer (buffer-live-p buffer))
 132       (with-current-buffer (setq buffer (get-buffer-create name))
 133         (wl-original-message-mode)))
 134     buffer))
 135
 136 (defun wl-message-buffer-create ()
 137   "Create a new message buffer."
 138   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 139          (name (buffer-name buffer)))
 140     (with-current-buffer buffer
 141       (setq wl-message-buffer-original-buffer
 142             (wl-original-message-buffer-get name))
 143       (when wl-message-use-header-narrowing
 144         (wl-message-header-narrowing-setup))
 145       (run-hooks 'wl-message-buffer-created-hook))
 146     buffer))
 147
 148 (defun wl-message-buffer-cache-add (key)
 149   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 150 Return its cache buffer."
 151   (let ((len (length wl-message-buffer-cache))
 152         (buf nil))
 153     (if (< len wl-message-buffer-cache-size)
 154         (setq buf (wl-message-buffer-create))
 155       (let ((entry (nth (1- len) wl-message-buffer-cache)))
 156         (if (buffer-live-p
 157              (setq buf (wl-message-buffer-cache-buffer-get entry)))
 158             (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil)
 159           (setq wl-message-buffer-cache (delq entry wl-message-buffer-cache))
 160           (setq buf (wl-message-buffer-create)))))
 161     (setq wl-message-buffer-cache
 162           (cons (wl-message-buffer-cache-entry-make key buf)
 163                 wl-message-buffer-cache))
 164     buf))
 165
 166 (defun wl-message-buffer-cache-delete (&optional key)
 167   "Delete the most recent cache entry"
 168   (if key
 169       (setq wl-message-buffer-cache
 170             (delq (assoc key wl-message-buffer-cache)
 171                   wl-message-buffer-cache))
 172     (let ((buf (wl-message-buffer-cache-buffer-get
 173                 (car wl-message-buffer-cache))))
 174       (setq wl-message-buffer-cache
 175             (nconc (cdr wl-message-buffer-cache)
 176                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 177
 178 (defun wl-message-buffer-cache-clean-up ()
 179   "A function to flush all decoded messages in cache list."
 180   (interactive)
 181   (if (and (eq major-mode 'wl-summary-mode)
 182            wl-message-buffer
 183            (get-buffer-window wl-message-buffer))
 184       (delete-window (get-buffer-window wl-message-buffer)))
 185   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 186   (setq wl-message-buffer-cache nil))
 187
 188 ;;; Message buffer handling from summary buffer.
 189
 190 (defun wl-message-buffer-window ()
 191   "Get message buffer window if any."
 192   (let* ((start-win (selected-window))
 193          (cur-win start-win))
 194     (catch 'found
 195       (while (progn
 196                (setq cur-win (next-window cur-win))
 197                (with-current-buffer (window-buffer cur-win)
 198                  (if (or (eq major-mode 'wl-message-mode)
 199                          (eq major-mode 'mime-view-mode))
 200                      (throw 'found cur-win)))
 201                (not (eq cur-win start-win)))))))
 202
 203 (defun wl-message-select-buffer (buffer)
 204   "Select BUFFER as a message buffer."
 205   (let ((window (get-buffer-window buffer))
 206         (sum (car wl-message-window-size))
 207         (mes (cdr wl-message-window-size))
 208         whi)
 209     (when (and window
 210                (not (eq (save-excursion (set-buffer (window-buffer window))
 211                                         wl-message-buffer-cur-summary-buffer)
 212                         (current-buffer))))
 213       (delete-window window)
 214       (run-hooks 'wl-message-window-deleted-hook)
 215       (setq window nil))
 216     (if window
 217         (select-window window)
 218       (when wl-fixed-window-configuration
 219         (delete-other-windows)
 220         (and wl-stay-folder-window
 221              (wl-summary-toggle-disp-folder)))
 222       ;; There's no buffer window. Search for message window and snatch it.
 223       (if (setq window (wl-message-buffer-window))
 224           (select-window window)
 225         (setq whi (1- (window-height)))
 226         (if mes
 227             (progn
 228               (let ((total (+ sum mes)))
 229                 (setq sum (max window-min-height (/ (* whi sum) total)))
 230                 (setq mes (max window-min-height (/ (* whi mes) total))))
 231               (if (< whi (+ sum mes))
 232                   (enlarge-window (- (+ sum mes) whi)))))
 233         (split-window (get-buffer-window (current-buffer)) sum)
 234         (other-window 1)))
 235     (switch-to-buffer buffer)))
 236
 237 (defun wl-message-narrow-to-page (&optional arg)
 238   "Narrow to page.
 239 If ARG is specified, narrow to ARGth page."
 240   (interactive "P")
 241   (setq arg (if arg (prefix-numeric-value arg) 0))
 242   (save-excursion
 243     (condition-case ()
 244         (forward-page -1)               ; Beginning of current page.
 245       (beginning-of-buffer
 246        (goto-char (point-min))))
 247     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 248     (widen)
 249     (cond
 250      ((> arg 0) (forward-page arg))
 251      ((< arg 0) (forward-page (1- arg))))
 252     (forward-page)
 253     (if wl-break-pages
 254         (narrow-to-region (point)
 255                           (progn
 256                             (forward-page -1)
 257                             (if (and (eolp) (not (bobp)))
 258                                 (forward-line))
 259                             (point))))))
 260
 261 (defun wl-message-prev-page (&optional lines)
 262   "Scroll down current message by LINES.
 263 Returns non-nil if top of message."
 264   (interactive)
 265   (let (top real-top)
 266     (save-selected-window
 267       (unless (eq major-mode 'mime-view-mode)
 268         (when (buffer-live-p wl-message-buffer)
 269           (wl-message-select-buffer wl-message-buffer)))
 270       (move-to-window-line 0)
 271       (if (and wl-break-pages
 272                (bobp)
 273                (not (setq real-top (save-restriction (widen) (bobp)))))
 274           (progn
 275             (wl-message-narrow-to-page -1)
 276             (goto-char (point-max))
 277             (recenter))
 278         (if (not (bobp))
 279             (condition-case nil
 280                 (scroll-down (or lines wl-message-scroll-amount))
 281               (error))
 282           (setq top t)))
 283       (if real-top
 284           (let ((f (assq (mime-preview-original-major-mode)
 285                          mime-preview-over-to-previous-method-alist)))
 286             (if f (funcall (cdr f))))))
 287     top))
 288
 289 (defun wl-message-next-page (&optional lines)
 290   "Scroll up current message by LINES.
 291 Returns non-nil if bottom of message."
 292   (interactive)
 293   (let (bottom)
 294     (save-selected-window
 295       (unless (eq major-mode 'mime-view-mode)
 296         (when (buffer-live-p wl-message-buffer)
 297           (wl-message-select-buffer wl-message-buffer)))
 298       (move-to-window-line -1)
 299       (if (save-excursion
 300             (end-of-line)
 301             (and (pos-visible-in-window-p)
 302                  (eobp)))
 303           (if (or (null wl-break-pages)
 304                   (save-excursion
 305                     (save-restriction
 306                       (widen) (forward-line) (eobp))))
 307               (setq bottom t)
 308             (wl-message-narrow-to-page 1)
 309             (setq bottom nil))
 310         (condition-case ()
 311             (static-if (boundp 'window-pixel-scroll-increment)
 312                 ;; XEmacs 21.2.20 and later.
 313                 (let (window-pixel-scroll-increment)
 314                   (scroll-up (or lines wl-message-scroll-amount)))
 315               (scroll-up (or lines wl-message-scroll-amount)))
 316           (end-of-buffer
 317            (goto-char (point-max))))
 318         (setq bottom nil))
 319       (if (eobp)
 320           (let ((f (assq (mime-preview-original-major-mode)
 321                          mime-preview-over-to-next-method-alist)))
 322             (if f (funcall (cdr f))))))
 323     bottom))
 324
 325
 326 (defun wl-message-follow-current-entity (buffer)
 327   "Follow to current message."
 328   (wl-draft-reply (wl-message-get-original-buffer)
 329                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 330   (let ((mail-reply-buffer buffer))
 331     (wl-draft-yank-from-mail-reply-buffer nil)))
 332
 333 ;;
 334
 335 (defun wl-message-mode ()
 336   "A major mode for message displaying."
 337   (interactive)
 338   (setq major-mode 'wl-message-mode)
 339   (setq buffer-read-only t)
 340   (setq mode-name "Message"))
 341
 342 (defun wl-message-exit ()
 343   "Move to summary buffer or mother buffer."
 344   (interactive)
 345   (let (summary-buf summary-win mother-buffer)
 346     (cond ((setq summary-buf wl-message-buffer-cur-summary-buffer)
 347            (unless (buffer-live-p summary-buf)
 348              (error "Summary buffer not found: %s"
 349                     wl-message-buffer-cur-folder))
 350            (if (setq summary-win (get-buffer-window summary-buf))
 351                (select-window summary-win)
 352              (switch-to-buffer summary-buf)
 353              (wl-message-select-buffer wl-message-buffer)
 354              (select-window (get-buffer-window summary-buf))))
 355           ((setq mother-buffer mime-mother-buffer)
 356            (kill-buffer (current-buffer))
 357            (when (buffer-live-p mother-buffer)
 358              (switch-to-buffer mother-buffer))))
 359     (run-hooks 'wl-message-exit-hook)))
 360
 361 (defun wl-message-toggle-disp-summary ()
 362   (interactive)
 363   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 364         summary-win)
 365     (if (and summary-buf
 366              (buffer-live-p summary-buf))
 367         (if (setq summary-win (get-buffer-window summary-buf))
 368             (delete-window summary-win)
 369           (switch-to-buffer summary-buf)
 370           (wl-message-select-buffer wl-message-buffer))
 371       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 372                                    nil nil t)
 373                                         ; no summary-buf
 374       (let ((sum-buf (current-buffer)))
 375         (wl-message-select-buffer wl-message-buffer)
 376         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 377
 378 (defun wl-message-get-original-buffer ()
 379   "Get original buffer for current message buffer."
 380   (if (buffer-live-p wl-message-buffer-original-buffer)
 381       wl-message-buffer-original-buffer
 382     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 383
 384 (defun wl-message-add-buttons-to-body (start end)
 385   (save-excursion
 386     (save-restriction
 387       (narrow-to-region start end)
 388       (let ((case-fold-search t)
 389             (alist wl-message-body-button-alist)
 390             entry)
 391         (while alist
 392           (setq entry (car alist)
 393                 alist (cdr alist))
 394           (goto-char (point-min))
 395           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 396             (unless (get-text-property (point) 'keymap)
 397               (wl-message-add-button
 398                (match-beginning (nth 1 entry))
 399                (match-end (nth 1 entry))
 400                (nth 2 entry)
 401                (match-string (nth 3 entry))))))))))
 402
 403 (defun wl-message-add-buttons-to-header (start end)
 404   (save-excursion
 405     (save-restriction
 406       (narrow-to-region start end)
 407       (let ((case-fold-search t)
 408             (alist wl-message-header-button-alist)
 409             entry)
 410         (while alist
 411           (setq entry (car alist)
 412                 alist (cdr alist))
 413           (goto-char (point-min))
 414           (while (re-search-forward (car entry) nil t)
 415             (setq start (match-beginning 0)
 416                   end (if (re-search-forward "^[^ \t]" nil t)
 417                           (match-beginning 0)
 418                         (point-max)))
 419             (goto-char start)
 420             (while (re-search-forward (nth 1 entry) end t)
 421               (wl-message-add-button
 422                (match-beginning (nth 2 entry))
 423                (match-end (nth 2 entry))
 424                (nth 3 entry) (match-string (nth 4 entry))))
 425             (goto-char end)))))))
 426
 427 ;; display-type object definition.
 428 (defun wl-message-make-display-type (mime header)
 429   (let (symbol)
 430     (prog1
 431         (setq symbol (intern (format "%s-%s-header" mime header)))
 432       (put symbol
 433            'wl-message-display-type
 434            (list :mime mime :header header)))))
 435
 436 (defun wl-message-display-type-property (display-type prop)
 437   (plist-get (get display-type 'wl-message-display-type) prop))
 438
 439 (defun wl-message-mime-analysis-p (display-type &optional header-or-body)
 440   (let ((mode (wl-message-display-type-property display-type :mime)))
 441     (case header-or-body
 442       (header
 443        (memq mode '(mime header-only)))
 444       (t
 445        (eq mode 'mime)))))
 446
 447 (defun wl-message-display-all-header-p (display-type)
 448   (eq (wl-message-display-type-property display-type :header) 'all))
 449
 450 (defun wl-message-display-no-merge-p (display-type)
 451   (eq (wl-message-display-type-property display-type :mime) 'no-merge))
 452
 453 (defun wl-message-buffer-display-type (&optional message-buffer)
 454   (if message-buffer
 455       (with-current-buffer message-buffer
 456         wl-message-buffer-cur-display-type)
 457     wl-message-buffer-cur-display-type))
 458
 459 (defun wl-message-flag-indicator (flags)
 460   (let ((flags (elmo-get-global-flags flags)))
 461     (if (null flags)
 462         ""
 463       (concat
 464        " ("
 465        (mapconcat
 466         (lambda (flag)
 467           (let ((indicator (capitalize (symbol-name flag)))
 468                 face)
 469             (when (and (assq flag wl-summary-flag-alist)
 470                        (facep
 471                         (setq face (intern
 472                                     (format "wl-highlight-summary-%s-flag-face"
 473                                             flag)))))
 474               (put-text-property 0 (length indicator) 'face face indicator))
 475             indicator))
 476         (sort flags
 477               (lambda (l r)
 478                 (> (length (memq (assq l wl-summary-flag-alist)
 479                                  wl-summary-flag-alist))
 480                    (length (memq (assq r wl-summary-flag-alist)
 481                                  wl-summary-flag-alist)))))
 482         ", ")
 483        ")"))))
 484
 485 (defun wl-message-redisplay (folder number display-type &optional force-reload)
 486   (let* ((default-mime-charset wl-mime-charset)
 487          (buffer-read-only nil)
 488          (summary-buf (current-buffer))
 489          message-buf entity summary-win flags)
 490     (setq buffer-read-only nil)
 491     (setq wl-message-buffer (wl-message-buffer-display
 492                              folder number display-type force-reload))
 493     (setq message-buf wl-message-buffer)
 494     (wl-message-select-buffer wl-message-buffer)
 495
 496     (set-buffer message-buf)
 497     (wl-deactivate-region)
 498     (make-local-variable 'truncate-partial-width-windows)
 499     (setq truncate-partial-width-windows nil)
 500     (setq truncate-lines wl-message-truncate-lines)
 501     (setq buffer-read-only nil)
 502     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 503     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 504     (setq wl-message-buffer-cur-number number)
 505     (setq wl-message-buffer-flag-indicator
 506           (wl-message-flag-indicator (elmo-message-flags folder number)))
 507     (wl-line-formatter-setup
 508      wl-message-buffer-mode-line-formatter
 509      wl-message-mode-line-format
 510      wl-message-mode-line-format-spec-alist)
 511     (setq mode-line-buffer-identification
 512           (funcall wl-message-buffer-mode-line-formatter))
 513     ;; highlight body
 514 ;    (when wl-highlight-body-too
 515 ;      (wl-highlight-body))
 516     (ignore-errors (wl-message-narrow-to-page))
 517     (goto-char (point-min))
 518     (when (re-search-forward "^$" nil t)
 519       (wl-message-add-buttons-to-header (point-min) (point))
 520       (wl-message-add-buttons-to-body (point) (point-max)))
 521     (when (and wl-message-use-header-narrowing
 522                (not (wl-message-display-all-header-p display-type)))
 523       (wl-message-header-narrowing))
 524     (goto-char (point-min))
 525     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 526     ;; go back to summary mode
 527     (set-buffer-modified-p nil)
 528     (setq buffer-read-only t)
 529     (set-buffer summary-buf)
 530     (setq summary-win (get-buffer-window summary-buf))
 531     (if (window-live-p summary-win)
 532         (select-window summary-win))))
 533
 534 ;; Use message buffer cache.
 535 (defun wl-message-buffer-display (folder number display-type
 536                                          &optional force-reload unread)
 537   (let* ((msg-id (ignore-errors
 538                    (elmo-message-field folder number 'message-id)))
 539          (fname (elmo-folder-name-internal folder))
 540          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 541          (redisplay nil)
 542          entity)
 543     (when (and hit (not (buffer-live-p hit)))
 544       (wl-message-buffer-cache-delete (list fname number msg-id))
 545       (setq hit nil))
 546     (if hit
 547         (progn
 548           ;; move hit to the top.
 549           (wl-message-buffer-cache-sort
 550            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 551           (with-current-buffer hit
 552             ;; Rewind to the top page
 553             (widen)
 554             (goto-char (point-min))
 555             (ignore-errors (wl-message-narrow-to-page))
 556             (setq entity wl-message-buffer-mime-entity)
 557             (unless (eq wl-message-buffer-cur-display-type display-type)
 558               (setq redisplay t))))
 559       ;; delete tail and add new to the top.
 560       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 561       (setq redisplay t))
 562     (when (or force-reload redisplay)
 563       (condition-case err
 564           (with-current-buffer hit
 565             (when (or force-reload
 566                       (null entity)
 567                       (not (elmo-mime-entity-display-p
 568                             entity
 569                             (if (wl-message-mime-analysis-p display-type)
 570                                 'mime
 571                               'as-is)))
 572                       (if (wl-message-display-no-merge-p display-type)
 573                           (elmo-mime-entity-reassembled-p entity)
 574                         (elmo-mime-entity-fragment-p entity)))
 575               (setq entity (elmo-message-mime-entity
 576                             folder
 577                             number
 578                             (wl-message-get-original-buffer)
 579                             (and wl-message-auto-reassemble-message/partial
 580                                  (not (wl-message-display-no-merge-p
 581                                        display-type)))
 582                             force-reload
 583                             unread
 584                             (not (wl-message-mime-analysis-p display-type)))))
 585             (unless entity
 586               (error "Cannot display message %s/%s" fname number))
 587             (wl-message-display-internal entity display-type))
 588         (quit
 589          (wl-message-buffer-cache-delete)
 590          (error "Display message %s/%s is quitted" fname number))
 591         (error
 592          (wl-message-buffer-cache-delete)
 593          (signal (car err) (cdr err))
 594          nil))) ;; will not be used
 595     hit))
 596
 597 (defun wl-message-display-internal (entity display-type)
 598   (let ((default-mime-charset wl-mime-charset)
 599         (elmo-mime-charset wl-mime-charset)
 600         (wl-message-buffer-require-all-header
 601          (wl-message-display-all-header-p display-type)))
 602     (if (wl-message-mime-analysis-p display-type)
 603         (elmo-mime-entity-display entity
 604                                   (current-buffer)
 605                                   'wl-original-message-mode
 606                                   (wl-message-define-keymap))
 607       (let* ((elmo-mime-display-header-analysis
 608               (wl-message-mime-analysis-p display-type 'header))
 609              (wl-highlight-x-face-function
 610               (and elmo-mime-display-header-analysis
 611                    wl-highlight-x-face-function)))
 612         (elmo-mime-entity-display-as-is entity
 613                                         (current-buffer)
 614                                         'wl-original-message-mode
 615                                         (wl-message-define-keymap))
 616         (let (buffer-read-only)
 617           (wl-highlight-message (point-min) (point-max) t))))
 618     (setq wl-message-buffer-cur-display-type display-type
 619           wl-message-buffer-mime-entity entity)
 620     (run-hooks 'wl-message-display-internal-hook)
 621     (setq buffer-read-only t)))
 622
 623 (defun wl-message-buffer-prefetch-p (folder &optional number)
 624   (and (or (not number)
 625            (elmo-message-file-p folder number)
 626            (let ((size (elmo-message-field folder number 'size)))
 627              (not (and (integerp size)
 628                        wl-message-buffer-prefetch-threshold
 629                        (>= size wl-message-buffer-prefetch-threshold)))))
 630        (or (not number)
 631            (elmo-folder-plugged-p folder)
 632            (elmo-file-cache-exists-p
 633                  (elmo-message-field folder number 'message-id)))
 634        (or (cond
 635             ((eq wl-message-buffer-prefetch-folder-type-list t)
 636              t)
 637             ((and number wl-message-buffer-prefetch-folder-type-list)
 638              (memq (elmo-folder-type-internal
 639                     (elmo-message-folder folder number))
 640                    wl-message-buffer-prefetch-folder-type-list))
 641             (wl-message-buffer-prefetch-folder-type-list
 642              (let ((list wl-message-buffer-prefetch-folder-type-list)
 643                    type)
 644                (catch 'done
 645                  (while (setq type (pop list))
 646                    (if (elmo-folder-contains-type folder type)
 647                        (throw 'done t)))))))
 648            (cond
 649             ((consp wl-message-buffer-prefetch-folder-list)
 650              (wl-string-match-member (elmo-folder-name-internal folder)
 651                                      wl-message-buffer-prefetch-folder-list))
 652             (t wl-message-buffer-prefetch-folder-list)))))
 653
 654 (defsubst wl-message-buffer-prefetch-clear-timer ()
 655 ;;;     cannot use for the bug of fsf-compat package (1.09).
 656 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 657   (if (fboundp 'run-with-idle-timer)
 658       (if (featurep 'xemacs)
 659           (let ((p itimer-list))
 660             (while (car p)
 661               (if (eq 'wl-message-buffer-prefetch-subr
 662                       (itimer-function (car p)))
 663                   (delete-itimer (car p)))
 664               (setq p (cdr p))))
 665         ;; FSF Emacs is correct
 666         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 667
 668 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 669                                                        summary charset)
 670   (if (not (fboundp 'run-with-idle-timer))
 671       (when (sit-for wl-message-buffer-prefetch-idle-time)
 672         (wl-message-buffer-prefetch-subr
 673          folder number count summary charset))
 674     (run-with-idle-timer
 675      wl-message-buffer-prefetch-idle-time
 676      nil
 677      'wl-message-buffer-prefetch-subr
 678      folder number count summary charset)))
 679
 680 (defvar wl-message-buffer-prefetch-move-spec-alist nil)
 681
 682 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 683   (if (buffer-live-p summary)
 684       (with-current-buffer summary
 685         (let ((wl-summary-move-spec-alist
 686                (or wl-message-buffer-prefetch-move-spec-alist
 687                    wl-summary-move-spec-alist))
 688               (next number))
 689           (while (and (setq next (funcall
 690                                   wl-message-buffer-prefetch-get-next-function
 691                                   next))
 692                       (not (wl-message-buffer-prefetch-p folder next))))
 693           next))))
 694
 695 (defun wl-message-buffer-prefetch (folder number count
 696                                           &optional summary charset)
 697   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 698          (num number))
 699     (when (and (> count 0)
 700                (wl-message-buffer-prefetch-p folder))
 701       (unless (wl-message-buffer-prefetch-p folder number)
 702         (setq num
 703               (wl-message-buffer-prefetch-get-next folder number summary)))
 704       (when num
 705         (wl-message-buffer-prefetch-clear-timer)
 706         (wl-message-buffer-prefetch-set-timer
 707          folder num count summary charset)))))
 708
 709 (defun wl-message-buffer-prefetch-next (folder number count
 710                                                &optional summary charset)
 711   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 712          next)
 713     (when (and (> count 0)
 714                (wl-message-buffer-prefetch-p folder))
 715       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 716       (when next
 717         (wl-message-buffer-prefetch-clear-timer)
 718         (wl-message-buffer-prefetch-set-timer
 719          folder next count summary charset)))))
 720
 721 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 722   (if (buffer-live-p summary)
 723       (with-current-buffer summary
 724         (if (and number
 725                  (numberp count)
 726                  (>= (setq count (- count 1)) 0)
 727                  (string= (elmo-folder-name-internal folder)
 728                           (wl-summary-buffer-folder-name)))
 729             (let* ((wl-mime-charset      charset)
 730                    (default-mime-charset charset)
 731                    (message-id (elmo-message-field folder number 'message-id))
 732                    (key (list (elmo-folder-name-internal folder)
 733                               number message-id))
 734                    (hit (wl-message-buffer-cache-hit key))
 735                    (display-type (wl-message-make-display-type
 736                                   wl-summary-buffer-display-mime-mode
 737                                   wl-summary-buffer-display-header-mode))
 738                    time1 time2 sec micro)
 739               (when wl-message-buffer-prefetch-debug
 740                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 741               (if (and hit (buffer-live-p hit))
 742                   (progn
 743                     (wl-message-buffer-cache-sort
 744                      (wl-message-buffer-cache-entry-make key hit))
 745                     (wl-message-buffer-prefetch-subr
 746                      folder
 747                      (wl-message-buffer-prefetch-get-next
 748                       folder number summary)
 749                      count summary charset))
 750                 ;; prefetching
 751                 (when wl-message-buffer-prefetch-debug
 752                   (setq time1 (current-time))
 753                   (message "Prefetching %d..." number))
 754                 (wl-message-buffer-display folder number
 755                                            display-type nil 'unread)
 756                 (when (elmo-message-use-cache-p folder number)
 757                   (elmo-message-set-cached folder number t))
 758                 (when wl-message-buffer-prefetch-debug
 759                   (setq time2 (current-time))
 760                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 761                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 762                   (setq micro (+ micro (* 1000000 sec)))
 763                   (message "Prefetching %d...done(%f msec)."
 764                            number
 765                            (/ micro 1000.0))
 766                   (sit-for 0))
 767                 ;; set next prefetch
 768                 (wl-message-buffer-prefetch-set-timer
 769                  folder
 770                  (wl-message-buffer-prefetch-get-next
 771                   folder number summary)
 772                  count summary charset)
 773                 (sit-for 0)
 774                 ;; success prefetch
 775                 )))
 776         ;; finish prefetch
 777         (when wl-message-buffer-prefetch-debug
 778           (message "Buffer Cached Messages: %s"
 779                    (mapconcat
 780                     '(lambda (cache)
 781                        (if (numberp (nth 1 (car cache)))
 782                            (if (string=
 783                                 (nth 0 (car cache))
 784                                 (elmo-folder-name-internal folder))
 785                                (format "%d"
 786                                        (nth 1 (car cache)))
 787                              (format "*%d" (nth 1 (car cache))))
 788                          "-"))
 789                     wl-message-buffer-cache " "))) )))
 790
 791 (defvar wl-message-button-map (make-sparse-keymap))
 792
 793 (defun wl-message-add-button (from to function &optional data)
 794   "Create a button between FROM and TO with callback FUNCTION and DATA."
 795   (add-text-properties
 796    from to
 797    (nconc (list 'wl-message-button-callback function)
 798           (if data
 799               (list 'wl-message-button-data data))))
 800   (let ((ov (make-overlay from to)))
 801     (overlay-put ov 'mouse-face 'highlight)
 802     (overlay-put ov 'local-map wl-message-button-map)
 803     (overlay-put ov 'evaporate t)))
 804
 805 (defun wl-message-button-dispatcher (event)
 806   "Select the button under point."
 807   (interactive "@e")
 808   (mouse-set-point event)
 809   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 810         (data (get-text-property (point) 'wl-message-button-data)))
 811     (if callback
 812         (funcall callback data)
 813       (wl-message-button-dispatcher-internal event))))
 814
 815 (defun wl-message-button-refer-article (data)
 816   "Read article specified by Message-ID DATA at point."
 817   (switch-to-buffer-other-window
 818    wl-message-buffer-cur-summary-buffer)
 819   (if (wl-summary-jump-to-msg-by-message-id data)
 820       (wl-summary-redisplay)))
 821
 822 (defun wl-message-uu-substring (buf outbuf &optional first last)
 823   (save-excursion
 824     (set-buffer buf)
 825     (search-forward "\n\n")
 826     (let ((sp (point))
 827           ep filename case-fold-search)
 828       (catch 'done
 829         (if first
 830             (progn
 831               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 832                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 833                 (throw 'done nil)))
 834           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 835         (beginning-of-line)
 836         (setq sp (point))
 837         (goto-char (point-max))
 838         (if last
 839             (re-search-backward "^end" sp t)
 840           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 841         (forward-line 1)
 842         (setq ep (point))
 843         (set-buffer outbuf)
 844         (goto-char (point-max))
 845         (insert-buffer-substring buf sp ep)
 846         (set-buffer buf)
 847         filename))))
 848
 849 ;;; Header narrowing courtesy of Hideyuki Shirai.
 850 (defun wl-message-header-narrowing ()
 851   "Narrowing headers."
 852   (unless (eq this-command 'wl-summary-redisplay-all-header)
 853     (save-excursion
 854       (save-restriction
 855         (goto-char (point-min))
 856         (if (re-search-forward "^$" nil t)
 857             (beginning-of-line)
 858           (goto-char (point-max)))
 859         (narrow-to-region (point-min) (point))
 860         (let ((fields wl-message-header-narrowing-fields))
 861           (while fields
 862             (wl-message-header-narrowing-1 (concat "^" (car fields) ":"))
 863             (setq fields (cdr fields))))))))
 864
 865 (defvar wl-message-header-narrowing-map (make-sparse-keymap))
 866 (define-key wl-message-header-narrowing-map [mouse-2]
 867   'wl-message-header-narrowing-again-at-mouse)
 868
 869 (defvar wl-message-header-narrowing-widen-map (make-sparse-keymap))
 870 (define-key wl-message-header-narrowing-widen-map [mouse-2]
 871   'wl-message-header-narrowing-widen-at-mouse)
 872
 873 (defun wl-message-header-narrowing-again-at-mouse (event)
 874   (interactive "e")
 875   (save-window-excursion
 876     (save-excursion
 877       (mouse-set-point event)
 878       (wl-message-header-narrowing))))
 879
 880 (defun wl-message-header-narrowing-1 (hregexp)
 881   (let ((case-fold-search t)
 882         ov start end)
 883     (goto-char (point-min))
 884     (while (re-search-forward hregexp nil t)
 885       (setq start (match-beginning 0))
 886       (forward-line 1)
 887       (setq end (progn (while (looking-at "^[ \t]") (forward-line))
 888                        (forward-line -1)
 889                        (line-end-position)))
 890       (if (<= (count-lines start end) wl-message-header-narrowing-lines)
 891           (forward-line 1)
 892         (goto-char start)
 893         (forward-line (1- wl-message-header-narrowing-lines))
 894         (end-of-line)
 895         (setq start (point))
 896         (unless (eq (get-char-property start 'invisible)
 897                     'wl-message-header-narrowing)
 898           (setq ov (or
 899                     (let ((ovs (overlays-at start))
 900                           ov)
 901                       (while (and ovs (not (overlayp ov)))
 902                         (if (overlay-get (car ovs)
 903                                          'wl-message-header-narrowing)
 904                             (setq ov (car ovs)))
 905                         (setq ovs (cdr ovs)))
 906                       ov)
 907                     (make-overlay start end)))
 908           (overlay-put ov 'wl-message-header-narrowing t)
 909           (overlay-put ov 'evaporate t)
 910           (overlay-put ov 'invisible 'wl-message-header-narrowing)
 911           (overlay-put ov 'after-string
 912                        wl-message-header-narrowing-string))))))
 913
 914 (defun wl-message-header-narrowing-widen-at-mouse (event)
 915   (interactive "e")
 916   (save-selected-window
 917     (select-window (posn-window (event-start event)))
 918     (let* ((win (selected-window))
 919            (wpos (window-start win))
 920            (pos (mouse-set-point event))
 921            (ovs (overlays-in (1- pos) (1+ pos)))        ;; Uum...
 922            ov)
 923       (while (and ovs (not (overlayp ov)))
 924         (when (overlay-get (car ovs) 'wl-message-header-narrowing)
 925           (setq ov (car ovs)))
 926         (setq ovs (cdr ovs)))
 927       (when (overlayp ov)
 928         (overlay-put ov 'face 'wl-message-header-narrowing-face)
 929         (overlay-put ov 'local-map wl-message-header-narrowing-map)
 930         (overlay-put ov 'invisible nil)
 931         (overlay-put ov 'after-string nil))
 932       (set-window-start win wpos))))
 933
 934 (defun wl-message-header-narrowing-setup ()
 935   (when (boundp 'line-move-ignore-invisible)
 936     (set (make-local-variable 'line-move-ignore-invisible) t))
 937   (set-text-properties 0 (length wl-message-header-narrowing-string)
 938                        `(face
 939                          wl-message-header-narrowing-face
 940                          keymap
 941                          ,wl-message-header-narrowing-widen-map)
 942                        wl-message-header-narrowing-string))
 943
 944 (defun wl-message-header-narrowing-toggle ()
 945   "Toggle header narrowing."
 946   (interactive)
 947   (when wl-message-use-header-narrowing
 948     (save-excursion
 949       (goto-char (point-min))
 950       (if (re-search-forward "^$" nil t)
 951           (beginning-of-line)
 952         (goto-char (point-max)))
 953       (let ((ovs (overlays-in (point-min) (point)))
 954             ov hn-ovs)
 955         (while (setq ov (car ovs))
 956           (when (overlay-get ov 'wl-message-header-narrowing)
 957             (setq hn-ovs (cons ov hn-ovs)))
 958           (setq ovs (cdr ovs)))
 959         (if hn-ovs
 960             (while hn-ovs
 961               (delete-overlay (car hn-ovs))
 962               (setq hn-ovs (cdr hn-ovs)))
 963           (wl-message-header-narrowing))))))
 964
 965 (require 'product)
 966 (product-provide (provide 'wl-message) (require 'wl-version))
 967
 968 ;;; wl-message.el ends here