wl/wl-message.el

   1 ;;; wl-message.el -- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime) ; XXX should modify for tm.
  36
  37 (eval-when-compile
  38   (if wl-use-semi
  39       (progn
  40         (require 'wl-mime)
  41         (require 'mime-view))
  42     (require 'tm-wl))
  43   (defalias-maybe 'event-window 'ignore)
  44   (defalias-maybe 'posn-window 'ignore)
  45   (defalias-maybe 'event-start 'ignore)
  46   (defalias-maybe 'mime-open-entity 'ignore))
  47
  48 (defconst wl-message-buffer-prefetch-idle-time
  49   (if (featurep 'lisp-float-type) (/ (float 1) (float 5)) 1))
  50 (defvar wl-message-buffer-prefetch-get-next-func
  51   'wl-summary-default-get-next-msg)
  52
  53 (defvar wl-message-buffer-prefetch-folder-type-list t)
  54
  55 (defvar wl-message-buffer-prefetch-debug
  56   t)
  57 (defvar wl-message-buffer-prefetch-threshold
  58   30000)
  59
  60 (defvar wl-message-buffer nil) ; message buffer.
  61
  62 (defvar wl-message-buffer-cur-summary-buffer nil)
  63 (defvar wl-message-buffer-cur-folder nil)
  64 (defvar wl-message-buffer-cur-number nil)
  65 (defvar wl-message-buffer-cur-flag nil)
  66 (defvar wl-message-buffer-cur-summary-buffer nil)
  67 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  68
  69 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  70 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  71 (make-variable-buffer-local 'wl-message-buffer-cur-flag)
  72 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  73 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  74
  75 (defvar wl-fixed-window-configuration nil)
  76
  77 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  78
  79 ;;; Message buffer cache.
  80
  81 (defvar wl-message-buffer-cache nil
  82   "Message cache.  (old ... new) order alist.
  83 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  84
  85 (defmacro wl-message-buffer-cache-buffer-get (entry)
  86   (` (cdr (, entry))))
  87
  88 (defmacro wl-message-buffer-cache-folder-get (entry)
  89   (` (car (car (, entry)))))
  90
  91 (defmacro wl-message-buffer-cache-message-get (entry)
  92   (` (cdr (car (, entry)))))
  93
  94 (defmacro wl-message-buffer-cache-entry-make (key buf)
  95   (` (cons (, key) (, buf))))
  96
  97 (defmacro wl-message-buffer-cache-hit (key)
  98   "Return value assosiated with key."
  99   (` (wl-message-buffer-cache-buffer-get
 100       (assoc (, key) wl-message-buffer-cache))))
 101
 102 (defun wl-message-buffer-cache-sort (entry)
 103   "Move ENTRY to the top of `wl-message-buffer-cache'."
 104   (setq wl-message-buffer-cache
 105         (cons entry (delete entry wl-message-buffer-cache))))
 106 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 107 ;        (top pointer))
 108 ;    (while (cdr pointer)
 109 ;      (if (equal (car (cdr pointer)) entry)
 110 ;         (setcdr pointer (cdr (cdr pointer)))
 111 ;       (setq pointer (cdr pointer))))
 112 ;    (setcdr pointer (list entry))
 113 ;    (setq wl-message-buffer-cache (cdr top))))
 114
 115 (defconst wl-message-buffer-cache-name    " *WL:Message*")
 116 (defconst wl-original-message-buffer-name " *Original*")
 117
 118 (defun wl-original-message-mode ()
 119   "A major mode for original message buffer."
 120   (setq major-mode 'wl-original-message-mode)
 121   (setq buffer-read-only t)
 122   (elmo-set-buffer-multibyte nil)
 123   (setq mode-name "Wanderlust original message"))
 124
 125 (defun wl-original-message-buffer-get (name)
 126   "Get original message buffer for NAME.
 127 If original message buffer already exists, it is re-used."
 128   (let* ((name (concat wl-original-message-buffer-name name))
 129          (buffer (get-buffer name)))
 130     (unless (and buffer (buffer-live-p buffer))
 131       (with-current-buffer (setq buffer (get-buffer-create name))
 132         (wl-original-message-mode)))
 133     buffer))
 134
 135 (defun wl-message-buffer-create ()
 136   "Create a new message buffer."
 137   (let* ((buffer (generate-new-buffer wl-message-buffer-cache-name))
 138          (name (buffer-name buffer)))
 139     (with-current-buffer buffer
 140       (setq wl-message-buffer-original-buffer
 141             (wl-original-message-buffer-get name)))
 142     buffer))
 143
 144 (defun wl-message-buffer-cache-add (key)
 145   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 146 Return its cache buffer."
 147   (let ((len (length wl-message-buffer-cache))
 148         (buf nil))
 149     (if (< len wl-message-buffer-cache-size)
 150         (setq buf (wl-message-buffer-create))
 151       (setq buf (wl-message-buffer-cache-buffer-get
 152                  (nth (1- len) wl-message-buffer-cache)))
 153       (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil))
 154     (setq wl-message-buffer-cache
 155           (cons (wl-message-buffer-cache-entry-make key buf)
 156                 wl-message-buffer-cache))
 157     buf))
 158
 159 (defun wl-message-buffer-cache-delete (&optional key)
 160   "Delete the most recent cache entry"
 161   (if key
 162       (setq wl-message-buffer-cache
 163             (delq (assoc key wl-message-buffer-cache)
 164                   wl-message-buffer-cache))
 165     (let ((buf (wl-message-buffer-cache-buffer-get
 166                 (car wl-message-buffer-cache))))
 167       (setq wl-message-buffer-cache
 168             (nconc (cdr wl-message-buffer-cache)
 169                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 170
 171 (defun wl-message-buffer-cache-clean-up ()
 172   "A function to flush all decoded messages in cache list."
 173   (interactive)
 174   (if (and (eq major-mode 'wl-summary-mode)
 175            wl-message-buffer
 176            (get-buffer-window wl-message-buffer))
 177       (delete-window (get-buffer-window wl-message-buffer)))
 178   (wl-kill-buffers (regexp-quote wl-message-buffer-cache-name))
 179   (setq wl-message-buffer-cache nil))
 180
 181 ;;; Message buffer handling from summary buffer.
 182
 183 (defun wl-message-buffer-window ()
 184   "Get message buffer window if any."
 185   (let* ((start-win (selected-window))
 186          (cur-win start-win))
 187     (catch 'found
 188       (while (progn
 189                (setq cur-win (next-window cur-win))
 190                (with-current-buffer (window-buffer cur-win)
 191                  (if (or (eq major-mode 'wl-message-mode)
 192                          (eq major-mode 'mime-view-mode))
 193                      (throw 'found cur-win)))
 194                (not (eq cur-win start-win)))))))
 195
 196 (defun wl-message-select-buffer (buffer)
 197   "Select BUFFER as a message buffer."
 198   (let ((window (get-buffer-window buffer))
 199         (sum (car wl-message-window-size))
 200         (mes (cdr wl-message-window-size))
 201         whi)
 202     (when (and window
 203                (not (eq (save-excursion (set-buffer (window-buffer window))
 204                                         wl-message-buffer-cur-summary-buffer)
 205                         (current-buffer))))
 206       (delete-window window)
 207       (run-hooks 'wl-message-window-deleted-hook)
 208       (setq window nil))
 209     (if window
 210         (select-window window)
 211       (when wl-fixed-window-configuration
 212         (delete-other-windows)
 213         (and wl-stay-folder-window
 214              (wl-summary-toggle-disp-folder)))
 215       ;; There's no buffer window. Search for message window and snatch it.
 216       (if (setq window (wl-message-buffer-window))
 217           (select-window window)
 218         (setq whi (1- (window-height)))
 219         (if mes
 220             (progn
 221               (let ((total (+ sum mes)))
 222                 (setq sum (max window-min-height (/ (* whi sum) total)))
 223                 (setq mes (max window-min-height (/ (* whi mes) total))))
 224               (if (< whi (+ sum mes))
 225                   (enlarge-window (- (+ sum mes) whi)))))
 226         (split-window (get-buffer-window (current-buffer)) sum)
 227         (other-window 1)))
 228     (switch-to-buffer buffer)))
 229
 230 (defun wl-message-narrow-to-page (&optional arg)
 231   "Narrow to page.
 232 If ARG is specified, narrow to ARGth page."
 233   (interactive "P")
 234   (setq arg (if arg (prefix-numeric-value arg) 0))
 235   (save-excursion
 236     (condition-case ()
 237         (forward-page -1)               ; Beginning of current page.
 238       (beginning-of-buffer
 239        (goto-char (point-min))))
 240     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 241     (widen)
 242     (cond
 243      ((> arg 0) (forward-page arg))
 244      ((< arg 0) (forward-page (1- arg))))
 245     (forward-page)
 246     (if wl-break-pages
 247         (narrow-to-region (point)
 248                           (progn
 249                             (forward-page -1)
 250                             (if (and (eolp) (not (bobp)))
 251                                 (forward-line))
 252                             (point))))))
 253
 254 (defun wl-message-prev-page (&optional lines)
 255   "Scroll down current message by LINES.
 256 Returns non-nil if top of message."
 257   (interactive)
 258   (if (buffer-live-p wl-message-buffer)
 259       (let ((cur-buf (current-buffer))
 260             top)
 261         (wl-message-select-buffer wl-message-buffer)
 262         (move-to-window-line 0)
 263         (if (and wl-break-pages
 264                  (bobp)
 265                  (not (save-restriction (widen) (bobp))))
 266             (progn
 267               (wl-message-narrow-to-page -1)
 268               (goto-char (point-max))
 269               (recenter))
 270           (if (not (bobp))
 271               (condition-case nil
 272                   (scroll-down lines)
 273                 (error))
 274             (setq top t)))
 275         (select-window (get-buffer-window cur-buf))
 276         top)))
 277
 278 (defun wl-message-next-page (&optional lines)
 279   "Scroll up current message by LINES.
 280 Returns non-nil if bottom of message."
 281   (interactive)
 282   (if (buffer-live-p wl-message-buffer)
 283       (let ((cur-buf (current-buffer))
 284             bottom)
 285         (wl-message-select-buffer wl-message-buffer)
 286         (move-to-window-line -1)
 287         (if (save-excursion
 288               (end-of-line)
 289               (and (pos-visible-in-window-p)
 290                    (eobp)))
 291             (if (or (null wl-break-pages)
 292                     (save-excursion
 293                       (save-restriction
 294                         (widen) (forward-line) (eobp))))
 295                 (setq bottom t)
 296               (wl-message-narrow-to-page 1)
 297               (setq bottom nil))
 298           (condition-case ()
 299               (static-if (boundp 'window-pixel-scroll-increment)
 300                   ;; XEmacs 21.2.20 and later.
 301                   (let (window-pixel-scroll-increment)
 302                     (scroll-up lines))
 303                 (scroll-up lines))
 304             (end-of-buffer
 305              (goto-char (point-max))))
 306           (setq bottom nil))
 307         (select-window (get-buffer-window cur-buf))
 308         bottom)))
 309
 310
 311 (defun wl-message-follow-current-entity (buffer)
 312   "Follow to current message."
 313   (wl-draft-reply (wl-message-get-original-buffer)
 314                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 315   (let ((mail-reply-buffer buffer))
 316     (wl-draft-yank-from-mail-reply-buffer nil)))
 317
 318 ;;
 319
 320 (defun wl-message-mode ()
 321   "A major mode for message displaying."
 322   (interactive)
 323   (setq major-mode 'wl-message-mode)
 324   (setq buffer-read-only t)
 325   (setq mode-name "Message"))
 326
 327 (defun wl-message-exit ()
 328   "Move to summary buffer."
 329   (interactive)
 330   (let (summary-buf summary-win)
 331     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 332         (if (setq summary-win (get-buffer-window summary-buf))
 333             (select-window summary-win)
 334           (switch-to-buffer summary-buf)
 335           (wl-message-select-buffer wl-message-buffer)
 336           (select-window (get-buffer-window summary-buf))))
 337     (run-hooks 'wl-message-exit-hook)))
 338
 339 (defun wl-message-toggle-disp-summary ()
 340   (interactive)
 341   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 342         summary-win)
 343     (if (and summary-buf
 344              (buffer-live-p summary-buf))
 345         (if (setq summary-win (get-buffer-window summary-buf))
 346             (delete-window summary-win)
 347           (switch-to-buffer summary-buf)
 348           (wl-message-select-buffer wl-message-buffer))
 349       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 350                                    nil nil t)
 351                                         ; no summary-buf
 352       (let ((sum-buf (current-buffer)))
 353         (wl-message-select-buffer wl-message-buffer)
 354         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 355
 356 (defun wl-message-get-original-buffer ()
 357   "Get original buffer for current message buffer."
 358   wl-message-buffer-original-buffer)
 359
 360 (defun wl-message-redisplay (folder number flag &optional force-reload)
 361   (let* ((default-mime-charset wl-mime-charset)
 362          (buffer-read-only nil)
 363          (summary-buf (current-buffer))
 364          message-buf
 365          strategy entity
 366          cache-used
 367          header-end real-fld-num summary-win)
 368     (setq buffer-read-only nil)
 369     (setq cache-used (wl-message-buffer-display
 370                       folder number flag force-reload))
 371     (setq wl-message-buffer (car cache-used))
 372     (setq message-buf wl-message-buffer)
 373     (wl-message-select-buffer wl-message-buffer)
 374
 375     (set-buffer message-buf)
 376     (setq buffer-read-only nil)
 377     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 378     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 379     (setq wl-message-buffer-cur-number number)
 380     (wl-message-overload-functions)
 381     (setq mode-line-buffer-identification
 382           (format "Wanderlust: << %s / %s >>"
 383                   (if (memq 'modeline wl-use-folder-petname)
 384                       (wl-folder-get-petname (elmo-folder-name-internal
 385                                               folder))
 386                     (elmo-folder-name-internal folder)) number))
 387     ;; highlight body
 388 ;    (when wl-highlight-body-too
 389 ;      (wl-highlight-body))
 390     (condition-case ()
 391         (wl-message-narrow-to-page)
 392       (error nil)); ignore errors.
 393     (setq cache-used (cdr cache-used))
 394     (goto-char (point-min))
 395     (unwind-protect
 396         (save-excursion
 397           (run-hooks 'wl-message-redisplay-hook))
 398       ;; go back to summary mode
 399       (set-buffer-modified-p nil)
 400       (setq buffer-read-only t)
 401       (set-buffer summary-buf)
 402       (setq summary-win (get-buffer-window summary-buf))
 403       (if (window-live-p summary-win)
 404           (select-window summary-win)))
 405     cache-used))
 406
 407 ;; Use message buffer cache.
 408 (defun wl-message-buffer-display (folder number flag
 409                                          &optional force-reload unread)
 410   (let* ((msg-id (elmo-message-field folder number 'message-id))
 411          (fname (elmo-folder-name-internal folder))
 412          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 413          (read nil)
 414          cache-used)
 415     (when (and hit (not (buffer-live-p hit)))
 416       (wl-message-buffer-cache-delete (list fname number msg-id))
 417       (setq hit nil))
 418     (if hit
 419         (progn
 420           ;; move hit to the top.
 421           (wl-message-buffer-cache-sort
 422            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 423           ;; buffer cache is used.
 424           (setq cache-used t)
 425           (with-current-buffer hit
 426             (unless (eq wl-message-buffer-cur-flag flag)
 427               (setq read t))))
 428       ;; delete tail and add new to the top.
 429       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 430       (setq read t))
 431     (if (or force-reload read)
 432         (condition-case err
 433             (save-excursion
 434               (set-buffer hit)
 435               (setq
 436                cache-used
 437                (wl-message-display-internal folder number flag
 438                                             force-reload unread))
 439               (setq wl-message-buffer-cur-flag flag))
 440           (quit
 441            (wl-message-buffer-cache-delete)
 442            (error "Display message %s/%s is quitted" fname number))
 443           (error
 444            (wl-message-buffer-cache-delete)
 445            (signal (car err) (cdr err))
 446            nil))) ;; will not be used
 447     (cons hit cache-used)))
 448
 449 (defun wl-message-display-internal (folder number flag
 450                                            &optional force-reload unread)
 451   (let ((elmo-message-ignored-field-list
 452          (if (eq flag 'all-header)
 453              nil
 454            wl-message-ignored-field-list))
 455         (elmo-message-visible-field-list wl-message-visible-field-list)
 456         (elmo-message-sorted-field-list wl-message-sort-field-list)
 457         (elmo-fetch-threshold wl-fetch-confirm-threshold))
 458     (prog1
 459         (if (eq flag 'as-is)
 460             (let (wl-highlight-x-face-func)
 461               (elmo-mime-display-as-is folder number
 462                                        (current-buffer)
 463                                        (wl-message-get-original-buffer)
 464                                        'wl-original-message-mode
 465                                        force-reload
 466                                        unread))
 467           (elmo-mime-message-display folder number
 468                                      (current-buffer)
 469                                      (wl-message-get-original-buffer)
 470                                      'wl-original-message-mode
 471                                      force-reload
 472                                      unread))
 473       (setq buffer-read-only t))))
 474
 475 (defsubst wl-message-buffer-prefetch-p (folder &optional number)
 476   (cond
 477    ((eq wl-message-buffer-prefetch-folder-type-list t)
 478     t)
 479    ((and number wl-message-buffer-prefetch-folder-type-list)
 480     (memq (elmo-folder-type-internal
 481            (elmo-message-folder folder number))
 482           wl-message-buffer-prefetch-folder-type-list))
 483    (wl-message-buffer-prefetch-folder-type-list
 484     (let ((list wl-message-buffer-prefetch-folder-type-list)
 485           type)
 486       (catch 'done
 487         (while (setq type (pop list))
 488           (if (elmo-folder-contains-type folder type)
 489               (throw 'done t))))))
 490    ((consp wl-message-buffer-prefetch-folder-type-list)
 491     (wl-string-match-member (elmo-folder-name-internal folder)
 492                             wl-message-buffer-prefetch-folder-type-list))
 493    (t wl-message-buffer-prefetch-folder-type-list)))
 494
 495 (defun wl-message-buffer-prefetch-next (folder number &optional
 496                                                summary charset)
 497   (if (wl-message-buffer-prefetch-p folder)
 498       (with-current-buffer (or summary (get-buffer wl-summary-buffer-name))
 499         (let* ((next (funcall wl-message-buffer-prefetch-get-next-func
 500                               number)))
 501           (when (and next (wl-message-buffer-prefetch-p folder next))
 502             (if (not (fboundp 'run-with-idle-timer))
 503                 (when (sit-for wl-message-buffer-prefetch-idle-time)
 504                   (wl-message-buffer-prefetch folder next summary charset))
 505               (run-with-idle-timer
 506                wl-message-buffer-prefetch-idle-time
 507                nil
 508                'wl-message-buffer-prefetch folder next summary charset)
 509               (sit-for 0)))))))
 510
 511 (defun wl-message-buffer-prefetch (folder number summary charset)
 512   (when (buffer-live-p summary)
 513     (save-excursion
 514       (set-buffer summary)
 515       (when (string= (elmo-folder-name-internal folder)
 516                      (wl-summary-buffer-folder-name))
 517         (let ((message-id (elmo-message-field folder number 'message-id))
 518               (wl-mime-charset      charset)
 519               (default-mime-charset charset)
 520               result time1 time2 sec micro)
 521           (if (not (wl-message-buffer-cache-hit (list folder
 522                                                       number message-id)))
 523               (let* ((size (elmo-message-field folder number 'size)))
 524                 (when (or (elmo-message-file-p folder number)
 525                           (not
 526                            (and (integerp size)
 527                                 wl-message-buffer-prefetch-threshold
 528                                 (>= size
 529                                     wl-message-buffer-prefetch-threshold))))
 530                   ;;(not (elmo-file-cache-exists-p message-id)))))
 531                   (when wl-message-buffer-prefetch-debug
 532                     (setq time1 (current-time))
 533                     (message "Prefetching %d..." number))
 534                   (setq result (wl-message-buffer-display folder number
 535                                                           'mime nil 'unread))
 536                   (when wl-message-buffer-prefetch-debug
 537                     (setq time2 (current-time))
 538                     (setq sec  (- (nth 1 time2)(nth 1 time1)))
 539                     (setq micro (- (nth 2 time2)(nth 2 time1)))
 540                     (setq micro (+ micro (* 1000000 sec)))
 541                     (message "Prefetching %d...done(%f msec)."
 542                              number
 543                              (/ micro 1000.0)))))))))))
 544
 545 (defvar wl-message-button-map (make-sparse-keymap))
 546
 547 (defun wl-message-add-button (from to function &optional data)
 548   "Create a button between FROM and TO with callback FUNCTION and DATA."
 549   (add-text-properties
 550    from to
 551    (nconc (list 'wl-message-button-callback function)
 552           (if data
 553               (list 'wl-message-button-data data))))
 554   (let ((ov (make-overlay from to)))
 555     (overlay-put ov 'mouse-face 'highlight)
 556     (overlay-put ov 'local-map wl-message-button-map)
 557     (overlay-put ov 'evaporate t)))
 558
 559 (defun wl-message-button-dispatcher (event)
 560   "Select the button under point."
 561   (interactive "@e")
 562   (mouse-set-point event)
 563   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 564         (data (get-text-property (point) 'wl-message-button-data)))
 565     (if callback
 566         (funcall callback data)
 567       (wl-message-button-dispatcher-internal event))))
 568
 569 (defun wl-message-button-refer-article (data)
 570   "Read article specified by Message-ID DATA at point."
 571   (switch-to-buffer-other-window
 572    wl-message-buffer-cur-summary-buffer)
 573   (if (wl-summary-jump-to-msg-by-message-id data)
 574       (wl-summary-redisplay)))
 575
 576 (defun wl-message-refer-article-or-url (e)
 577   "Read article specified by message-id around point.
 578 If failed, attempt to execute button-dispatcher."
 579   (interactive "e")
 580   (let ((window (get-buffer-window (current-buffer)))
 581         mouse-window point beg end msg-id)
 582     (unwind-protect
 583         (progn
 584           (mouse-set-point e)
 585           (setq mouse-window (get-buffer-window (current-buffer)))
 586           (setq point (point))
 587           (setq beg (save-excursion (beginning-of-line) (point)))
 588           (setq end (save-excursion (end-of-line) (point)))
 589           (search-forward ">" end t)      ;Move point to end of "<....>".
 590           (if (and (re-search-backward "\\(<[^<> \t\n]+@[^<> \t\n]+>\\)"
 591                                        beg t)
 592                    (not (string-match "mailto:"
 593                                       (setq msg-id (wl-match-buffer 1)))))
 594               (progn
 595                 (goto-char point)
 596                 (switch-to-buffer-other-window
 597                  wl-message-buffer-cur-summary-buffer)
 598                 (if (wl-summary-jump-to-msg-by-message-id msg-id)
 599                     (wl-summary-redisplay)))
 600             (wl-message-button-dispatcher-internal e)))
 601       (if (eq mouse-window (get-buffer-window (current-buffer)))
 602           (select-window window)))))
 603
 604 (defun wl-message-uu-substring (buf outbuf &optional first last)
 605   (save-excursion
 606     (set-buffer buf)
 607     (search-forward "\n\n")
 608     (let ((sp (point))
 609           ep filename case-fold-search)
 610       (catch 'done
 611         (if first
 612             (progn
 613               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 614                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 615                 (throw 'done nil)))
 616           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 617         (beginning-of-line)
 618         (setq sp (point))
 619         (goto-char (point-max))
 620         (if last
 621             (re-search-backward "^end" sp t)
 622           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 623         (forward-line 1)
 624         (setq ep (point))
 625         (set-buffer outbuf)
 626         (goto-char (point-max))
 627         (insert-buffer-substring buf sp ep)
 628         (set-buffer buf)
 629         filename))))
 630
 631 (require 'product)
 632 (product-provide (provide 'wl-message) (require 'wl-version))
 633
 634 ;;; wl-message.el ends here