wl/wl-message.el

   1 ;;; wl-message.el -- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime) ; XXX should modify for tm.
  36
  37 (eval-when-compile
  38   (if wl-use-semi
  39       (progn
  40         (require 'wl-mime)
  41         (require 'mime-view))
  42     (require 'tm-wl))
  43   (defalias-maybe 'event-window 'ignore)
  44   (defalias-maybe 'posn-window 'ignore)
  45   (defalias-maybe 'event-start 'ignore)
  46   (defalias-maybe 'mime-open-entity 'ignore))
  47
  48 (defconst wl-message-buffer-prefetch-idle-time
  49   (if (featurep 'lisp-float-type) (/ (float 1) (float 5)) 1))
  50 (defvar wl-message-buffer-prefetch-get-next-function
  51   'wl-summary-default-get-next-msg)
  52
  53 (defvar wl-message-buffer-prefetch-folder-type-list t)
  54
  55 (defvar wl-message-buffer-prefetch-debug
  56   t)
  57
  58 (defvar wl-message-buffer nil) ; message buffer.
  59
  60 (defvar wl-message-buffer-cur-summary-buffer nil)
  61 (defvar wl-message-buffer-cur-folder nil)
  62 (defvar wl-message-buffer-cur-number nil)
  63 (defvar wl-message-buffer-cur-flag nil)
  64 (defvar wl-message-buffer-cur-summary-buffer nil)
  65 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  66
  67 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-flag)
  70 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  71 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  72
  73 (defvar wl-fixed-window-configuration nil)
  74
  75 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  76
  77 ;;; Message buffer cache.
  78
  79 (defvar wl-message-buffer-cache nil
  80   "Message cache.  (old ... new) order alist.
  81 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  82
  83 (defmacro wl-message-buffer-cache-buffer-get (entry)
  84   (` (cdr (, entry))))
  85
  86 (defmacro wl-message-buffer-cache-folder-get (entry)
  87   (` (car (car (, entry)))))
  88
  89 (defmacro wl-message-buffer-cache-message-get (entry)
  90   (` (cdr (car (, entry)))))
  91
  92 (defmacro wl-message-buffer-cache-entry-make (key buf)
  93   (` (cons (, key) (, buf))))
  94
  95 (defmacro wl-message-buffer-cache-hit (key)
  96   "Return value assosiated with key."
  97   (` (wl-message-buffer-cache-buffer-get
  98       (assoc (, key) wl-message-buffer-cache))))
  99
 100 (defun wl-message-buffer-cache-sort (entry)
 101   "Move ENTRY to the top of `wl-message-buffer-cache'."
 102   (setq wl-message-buffer-cache
 103         (cons entry (delete entry wl-message-buffer-cache))))
 104 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 105 ;        (top pointer))
 106 ;    (while (cdr pointer)
 107 ;      (if (equal (car (cdr pointer)) entry)
 108 ;         (setcdr pointer (cdr (cdr pointer)))
 109 ;       (setq pointer (cdr pointer))))
 110 ;    (setcdr pointer (list entry))
 111 ;    (setq wl-message-buffer-cache (cdr top))))
 112
 113 (defconst wl-message-buffer-cache-name    " *WL:Message*")
 114 (defconst wl-original-message-buffer-name " *Original*")
 115
 116 (defun wl-original-message-mode ()
 117   "A major mode for original message buffer."
 118   (setq major-mode 'wl-original-message-mode)
 119   (setq buffer-read-only t)
 120   (elmo-set-buffer-multibyte nil)
 121   (setq mode-name "Wanderlust original message"))
 122
 123 (defun wl-original-message-buffer-get (name)
 124   "Get original message buffer for NAME.
 125 If original message buffer already exists, it is re-used."
 126   (let* ((name (concat wl-original-message-buffer-name name))
 127          (buffer (get-buffer name)))
 128     (unless (and buffer (buffer-live-p buffer))
 129       (with-current-buffer (setq buffer (get-buffer-create name))
 130         (wl-original-message-mode)))
 131     buffer))
 132
 133 (defun wl-message-buffer-create ()
 134   "Create a new message buffer."
 135   (let* ((buffer (generate-new-buffer wl-message-buffer-cache-name))
 136          (name (buffer-name buffer)))
 137     (with-current-buffer buffer
 138       (setq wl-message-buffer-original-buffer
 139             (wl-original-message-buffer-get name)))
 140     buffer))
 141
 142 (defun wl-message-buffer-cache-add (key)
 143   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 144 Return its cache buffer."
 145   (let ((len (length wl-message-buffer-cache))
 146         (buf nil))
 147     (if (< len wl-message-buffer-cache-size)
 148         (setq buf (wl-message-buffer-create))
 149       (setq buf (wl-message-buffer-cache-buffer-get
 150                  (nth (1- len) wl-message-buffer-cache)))
 151       (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil))
 152     (setq wl-message-buffer-cache
 153           (cons (wl-message-buffer-cache-entry-make key buf)
 154                 wl-message-buffer-cache))
 155     buf))
 156
 157 (defun wl-message-buffer-cache-delete (&optional key)
 158   "Delete the most recent cache entry"
 159   (if key
 160       (setq wl-message-buffer-cache
 161             (delq (assoc key wl-message-buffer-cache)
 162                   wl-message-buffer-cache))
 163     (let ((buf (wl-message-buffer-cache-buffer-get
 164                 (car wl-message-buffer-cache))))
 165       (setq wl-message-buffer-cache
 166             (nconc (cdr wl-message-buffer-cache)
 167                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 168
 169 (defun wl-message-buffer-cache-clean-up ()
 170   "A function to flush all decoded messages in cache list."
 171   (interactive)
 172   (if (and (eq major-mode 'wl-summary-mode)
 173            wl-message-buffer
 174            (get-buffer-window wl-message-buffer))
 175       (delete-window (get-buffer-window wl-message-buffer)))
 176   (wl-kill-buffers (regexp-quote wl-message-buffer-cache-name))
 177   (setq wl-message-buffer-cache nil))
 178
 179 ;;; Message buffer handling from summary buffer.
 180
 181 (defun wl-message-buffer-window ()
 182   "Get message buffer window if any."
 183   (let* ((start-win (selected-window))
 184          (cur-win start-win))
 185     (catch 'found
 186       (while (progn
 187                (setq cur-win (next-window cur-win))
 188                (with-current-buffer (window-buffer cur-win)
 189                  (if (or (eq major-mode 'wl-message-mode)
 190                          (eq major-mode 'mime-view-mode))
 191                      (throw 'found cur-win)))
 192                (not (eq cur-win start-win)))))))
 193
 194 (defun wl-message-select-buffer (buffer)
 195   "Select BUFFER as a message buffer."
 196   (let ((window (get-buffer-window buffer))
 197         (sum (car wl-message-window-size))
 198         (mes (cdr wl-message-window-size))
 199         whi)
 200     (when (and window
 201                (not (eq (save-excursion (set-buffer (window-buffer window))
 202                                         wl-message-buffer-cur-summary-buffer)
 203                         (current-buffer))))
 204       (delete-window window)
 205       (run-hooks 'wl-message-window-deleted-hook)
 206       (setq window nil))
 207     (if window
 208         (select-window window)
 209       (when wl-fixed-window-configuration
 210         (delete-other-windows)
 211         (and wl-stay-folder-window
 212              (wl-summary-toggle-disp-folder)))
 213       ;; There's no buffer window. Search for message window and snatch it.
 214       (if (setq window (wl-message-buffer-window))
 215           (select-window window)
 216         (setq whi (1- (window-height)))
 217         (if mes
 218             (progn
 219               (let ((total (+ sum mes)))
 220                 (setq sum (max window-min-height (/ (* whi sum) total)))
 221                 (setq mes (max window-min-height (/ (* whi mes) total))))
 222               (if (< whi (+ sum mes))
 223                   (enlarge-window (- (+ sum mes) whi)))))
 224         (split-window (get-buffer-window (current-buffer)) sum)
 225         (other-window 1)))
 226     (switch-to-buffer buffer)))
 227
 228 (defun wl-message-narrow-to-page (&optional arg)
 229   "Narrow to page.
 230 If ARG is specified, narrow to ARGth page."
 231   (interactive "P")
 232   (setq arg (if arg (prefix-numeric-value arg) 0))
 233   (save-excursion
 234     (condition-case ()
 235         (forward-page -1)               ; Beginning of current page.
 236       (beginning-of-buffer
 237        (goto-char (point-min))))
 238     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 239     (widen)
 240     (cond
 241      ((> arg 0) (forward-page arg))
 242      ((< arg 0) (forward-page (1- arg))))
 243     (forward-page)
 244     (if wl-break-pages
 245         (narrow-to-region (point)
 246                           (progn
 247                             (forward-page -1)
 248                             (if (and (eolp) (not (bobp)))
 249                                 (forward-line))
 250                             (point))))))
 251
 252 (defun wl-message-prev-page (&optional lines)
 253   "Scroll down current message by LINES.
 254 Returns non-nil if top of message."
 255   (interactive)
 256   (if (buffer-live-p wl-message-buffer)
 257       (let ((cur-buf (current-buffer))
 258             top)
 259         (wl-message-select-buffer wl-message-buffer)
 260         (move-to-window-line 0)
 261         (if (and wl-break-pages
 262                  (bobp)
 263                  (not (save-restriction (widen) (bobp))))
 264             (progn
 265               (wl-message-narrow-to-page -1)
 266               (goto-char (point-max))
 267               (recenter))
 268           (if (not (bobp))
 269               (condition-case nil
 270                   (scroll-down lines)
 271                 (error))
 272             (setq top t)))
 273         (select-window (get-buffer-window cur-buf))
 274         top)))
 275
 276 (defun wl-message-next-page (&optional lines)
 277   "Scroll up current message by LINES.
 278 Returns non-nil if bottom of message."
 279   (interactive)
 280   (if (buffer-live-p wl-message-buffer)
 281       (let ((cur-buf (current-buffer))
 282             bottom)
 283         (wl-message-select-buffer wl-message-buffer)
 284         (move-to-window-line -1)
 285         (if (save-excursion
 286               (end-of-line)
 287               (and (pos-visible-in-window-p)
 288                    (eobp)))
 289             (if (or (null wl-break-pages)
 290                     (save-excursion
 291                       (save-restriction
 292                         (widen) (forward-line) (eobp))))
 293                 (setq bottom t)
 294               (wl-message-narrow-to-page 1)
 295               (setq bottom nil))
 296           (condition-case ()
 297               (static-if (boundp 'window-pixel-scroll-increment)
 298                   ;; XEmacs 21.2.20 and later.
 299                   (let (window-pixel-scroll-increment)
 300                     (scroll-up lines))
 301                 (scroll-up lines))
 302             (end-of-buffer
 303              (goto-char (point-max))))
 304           (setq bottom nil))
 305         (select-window (get-buffer-window cur-buf))
 306         bottom)))
 307
 308
 309 (defun wl-message-follow-current-entity (buffer)
 310   "Follow to current message."
 311   (wl-draft-reply (wl-message-get-original-buffer)
 312                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 313   (let ((mail-reply-buffer buffer))
 314     (wl-draft-yank-from-mail-reply-buffer nil)))
 315
 316 ;;
 317
 318 (defun wl-message-mode ()
 319   "A major mode for message displaying."
 320   (interactive)
 321   (setq major-mode 'wl-message-mode)
 322   (setq buffer-read-only t)
 323   (setq mode-name "Message"))
 324
 325 (defun wl-message-exit ()
 326   "Move to summary buffer."
 327   (interactive)
 328   (let (summary-buf summary-win)
 329     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 330         (if (setq summary-win (get-buffer-window summary-buf))
 331             (select-window summary-win)
 332           (switch-to-buffer summary-buf)
 333           (wl-message-select-buffer wl-message-buffer)
 334           (select-window (get-buffer-window summary-buf))))
 335     (run-hooks 'wl-message-exit-hook)))
 336
 337 (defun wl-message-toggle-disp-summary ()
 338   (interactive)
 339   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 340         summary-win)
 341     (if (and summary-buf
 342              (buffer-live-p summary-buf))
 343         (if (setq summary-win (get-buffer-window summary-buf))
 344             (delete-window summary-win)
 345           (switch-to-buffer summary-buf)
 346           (wl-message-select-buffer wl-message-buffer))
 347       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 348                                    nil nil t)
 349                                         ; no summary-buf
 350       (let ((sum-buf (current-buffer)))
 351         (wl-message-select-buffer wl-message-buffer)
 352         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 353
 354 (defun wl-message-get-original-buffer ()
 355   "Get original buffer for current message buffer."
 356   wl-message-buffer-original-buffer)
 357
 358 (defun wl-message-redisplay (folder number flag &optional force-reload)
 359   (let* ((default-mime-charset wl-mime-charset)
 360          (buffer-read-only nil)
 361          (summary-buf (current-buffer))
 362          message-buf
 363          strategy entity
 364          cache-used
 365          header-end real-fld-num summary-win)
 366     (setq buffer-read-only nil)
 367     (setq cache-used (wl-message-buffer-display
 368                       folder number flag force-reload))
 369     (setq wl-message-buffer (car cache-used))
 370     (setq message-buf wl-message-buffer)
 371     (wl-message-select-buffer wl-message-buffer)
 372
 373     (set-buffer message-buf)
 374     (setq buffer-read-only nil)
 375     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 376     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 377     (setq wl-message-buffer-cur-number number)
 378     (wl-message-overload-functions)
 379     (setq mode-line-buffer-identification
 380           (format "Wanderlust: << %s / %s >>"
 381                   (if (memq 'modeline wl-use-folder-petname)
 382                       (wl-folder-get-petname (elmo-folder-name-internal
 383                                               folder))
 384                     (elmo-folder-name-internal folder)) number))
 385     ;; highlight body
 386 ;    (when wl-highlight-body-too
 387 ;      (wl-highlight-body))
 388     (condition-case ()
 389         (wl-message-narrow-to-page)
 390       (error nil)); ignore errors.
 391     (setq cache-used (cdr cache-used))
 392     (goto-char (point-min))
 393     (unwind-protect
 394         (save-excursion
 395           (run-hooks 'wl-message-redisplay-hook))
 396       ;; go back to summary mode
 397       (set-buffer-modified-p nil)
 398       (setq buffer-read-only t)
 399       (set-buffer summary-buf)
 400       (setq summary-win (get-buffer-window summary-buf))
 401       (if (window-live-p summary-win)
 402           (select-window summary-win)))
 403     cache-used))
 404
 405 ;; Use message buffer cache.
 406 (defun wl-message-buffer-display (folder number flag
 407                                          &optional force-reload unread)
 408   (let* ((msg-id (elmo-message-field folder number 'message-id))
 409          (fname (elmo-folder-name-internal folder))
 410          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 411          (read nil)
 412          cache-used)
 413     (when (and hit (not (buffer-live-p hit)))
 414       (wl-message-buffer-cache-delete (list fname number msg-id))
 415       (setq hit nil))
 416     (if hit
 417         (progn
 418           ;; move hit to the top.
 419           (wl-message-buffer-cache-sort
 420            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 421           ;; buffer cache is used.
 422           (setq cache-used t)
 423           (with-current-buffer hit
 424             (unless (eq wl-message-buffer-cur-flag flag)
 425               (setq read t))))
 426       ;; delete tail and add new to the top.
 427       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 428       (setq read t))
 429     (if (or force-reload read)
 430         (condition-case err
 431             (save-excursion
 432               (set-buffer hit)
 433               (setq
 434                cache-used
 435                (wl-message-display-internal folder number flag
 436                                             force-reload unread))
 437               (setq wl-message-buffer-cur-flag flag))
 438           (quit
 439            (wl-message-buffer-cache-delete)
 440            (error "Display message %s/%s is quitted" fname number))
 441           (error
 442            (wl-message-buffer-cache-delete)
 443            (signal (car err) (cdr err))
 444            nil))) ;; will not be used
 445     (cons hit cache-used)))
 446
 447 (defun wl-message-display-internal (folder number flag
 448                                            &optional force-reload unread)
 449   (let ((elmo-message-ignored-field-list
 450          (if (eq flag 'all-header)
 451              nil
 452            wl-message-ignored-field-list))
 453         (elmo-message-visible-field-list wl-message-visible-field-list)
 454         (elmo-message-sorted-field-list wl-message-sort-field-list)
 455         (elmo-message-fetch-threshold wl-fetch-confirm-threshold))
 456     (prog1
 457         (if (eq flag 'as-is)
 458             (let (wl-highlight-x-face-function)
 459               (elmo-mime-display-as-is folder number
 460                                        (current-buffer)
 461                                        (wl-message-get-original-buffer)
 462                                        'wl-original-message-mode
 463                                        force-reload
 464                                        unread))
 465           (elmo-mime-message-display folder number
 466                                      (current-buffer)
 467                                      (wl-message-get-original-buffer)
 468                                      'wl-original-message-mode
 469                                      force-reload
 470                                      unread))
 471       (setq buffer-read-only t))))
 472
 473 (defsubst wl-message-buffer-prefetch-p (folder &optional number)
 474   (cond
 475    ((eq wl-message-buffer-prefetch-folder-type-list t)
 476     t)
 477    ((and number wl-message-buffer-prefetch-folder-type-list)
 478     (memq (elmo-folder-type-internal
 479            (elmo-message-folder folder number))
 480           wl-message-buffer-prefetch-folder-type-list))
 481    (wl-message-buffer-prefetch-folder-type-list
 482     (let ((list wl-message-buffer-prefetch-folder-type-list)
 483           type)
 484       (catch 'done
 485         (while (setq type (pop list))
 486           (if (elmo-folder-contains-type folder type)
 487               (throw 'done t))))))
 488    ((consp wl-message-buffer-prefetch-folder-type-list)
 489     (wl-string-match-member (elmo-folder-name-internal folder)
 490                             wl-message-buffer-prefetch-folder-type-list))
 491    (t wl-message-buffer-prefetch-folder-type-list)))
 492
 493
 494 (defvar wl-message-buffer-prefetch-timer nil)
 495
 496 (defun wl-message-buffer-prefetch-next (folder number &optional
 497                                                summary charset)
 498   (if (wl-message-buffer-prefetch-p folder)
 499       (with-current-buffer (or summary (get-buffer wl-summary-buffer-name))
 500         (let* ((next (funcall wl-message-buffer-prefetch-get-next-function
 501                               number)))
 502           (when (and next (wl-message-buffer-prefetch-p folder next))
 503             (if (not (fboundp 'run-with-idle-timer))
 504                 (when (sit-for wl-message-buffer-prefetch-idle-time)
 505                   (wl-message-buffer-prefetch folder next summary charset))
 506               (unless wl-message-buffer-prefetch-timer
 507                 (setq wl-message-buffer-prefetch-timer
 508                       (run-with-idle-timer
 509                        wl-message-buffer-prefetch-idle-time
 510                        nil
 511                        'wl-message-buffer-prefetch
 512                        folder next summary charset)))))))))
 513
 514 (defun wl-message-buffer-prefetch (folder number summary charset)
 515   (when (buffer-live-p summary)
 516     (save-excursion
 517       (set-buffer summary)
 518       (when (string= (elmo-folder-name-internal folder)
 519                      (wl-summary-buffer-folder-name))
 520         (let ((message-id (elmo-message-field folder number 'message-id))
 521               (wl-mime-charset      charset)
 522               (default-mime-charset charset)
 523               result time1 time2 sec micro)
 524           (if (not (wl-message-buffer-cache-hit (list folder
 525                                                       number message-id)))
 526               (let* ((size (elmo-message-field folder number 'size)))
 527                 (when (or (elmo-message-file-p folder number)
 528                           (not
 529                            (and (integerp size)
 530                                 elmo-message-fetch-threshold
 531                                 (>= size
 532                                     elmo-message-fetch-threshold))))
 533                   ;;(not (elmo-file-cache-exists-p message-id)))))
 534                   (when wl-message-buffer-prefetch-debug
 535                     (setq time1 (current-time))
 536                     (message "Prefetching %d..." number))
 537                   (setq result (wl-message-buffer-display folder number
 538                                                           'mime nil 'unread))
 539                   (when wl-message-buffer-prefetch-debug
 540                     (setq time2 (current-time))
 541                     (setq sec  (- (nth 1 time2)(nth 1 time1)))
 542                     (setq micro (- (nth 2 time2)(nth 2 time1)))
 543                     (setq micro (+ micro (* 1000000 sec)))
 544                     (message "Prefetching %d...done(%f msec)."
 545                              number
 546                              (/ micro 1000.0))))))))))
 547   (setq wl-message-buffer-prefetch-timer nil))
 548
 549 (defvar wl-message-button-map (make-sparse-keymap))
 550
 551 (defun wl-message-add-button (from to function &optional data)
 552   "Create a button between FROM and TO with callback FUNCTION and DATA."
 553   (add-text-properties
 554    from to
 555    (nconc (list 'wl-message-button-callback function)
 556           (if data
 557               (list 'wl-message-button-data data))))
 558   (let ((ov (make-overlay from to)))
 559     (overlay-put ov 'mouse-face 'highlight)
 560     (overlay-put ov 'local-map wl-message-button-map)
 561     (overlay-put ov 'evaporate t)))
 562
 563 (defun wl-message-button-dispatcher (event)
 564   "Select the button under point."
 565   (interactive "@e")
 566   (mouse-set-point event)
 567   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 568         (data (get-text-property (point) 'wl-message-button-data)))
 569     (if callback
 570         (funcall callback data)
 571       (wl-message-button-dispatcher-internal event))))
 572
 573 (defun wl-message-button-refer-article (data)
 574   "Read article specified by Message-ID DATA at point."
 575   (switch-to-buffer-other-window
 576    wl-message-buffer-cur-summary-buffer)
 577   (if (wl-summary-jump-to-msg-by-message-id data)
 578       (wl-summary-redisplay)))
 579
 580 (defun wl-message-refer-article-or-url (e)
 581   "Read article specified by message-id around point.
 582 If failed, attempt to execute button-dispatcher."
 583   (interactive "e")
 584   (let ((window (get-buffer-window (current-buffer)))
 585         mouse-window point beg end msg-id)
 586     (unwind-protect
 587         (progn
 588           (mouse-set-point e)
 589           (setq mouse-window (get-buffer-window (current-buffer)))
 590           (setq point (point))
 591           (setq beg (save-excursion (beginning-of-line) (point)))
 592           (setq end (save-excursion (end-of-line) (point)))
 593           (search-forward ">" end t)      ;Move point to end of "<....>".
 594           (if (and (re-search-backward "\\(<[^<> \t\n]+@[^<> \t\n]+>\\)"
 595                                        beg t)
 596                    (not (string-match "mailto:"
 597                                       (setq msg-id (wl-match-buffer 1)))))
 598               (progn
 599                 (goto-char point)
 600                 (switch-to-buffer-other-window
 601                  wl-message-buffer-cur-summary-buffer)
 602                 (if (wl-summary-jump-to-msg-by-message-id msg-id)
 603                     (wl-summary-redisplay)))
 604             (wl-message-button-dispatcher-internal e)))
 605       (if (eq mouse-window (get-buffer-window (current-buffer)))
 606           (select-window window)))))
 607
 608 (defun wl-message-uu-substring (buf outbuf &optional first last)
 609   (save-excursion
 610     (set-buffer buf)
 611     (search-forward "\n\n")
 612     (let ((sp (point))
 613           ep filename case-fold-search)
 614       (catch 'done
 615         (if first
 616             (progn
 617               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 618                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 619                 (throw 'done nil)))
 620           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 621         (beginning-of-line)
 622         (setq sp (point))
 623         (goto-char (point-max))
 624         (if last
 625             (re-search-backward "^end" sp t)
 626           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 627         (forward-line 1)
 628         (setq ep (point))
 629         (set-buffer outbuf)
 630         (goto-char (point-max))
 631         (insert-buffer-substring buf sp ep)
 632         (set-buffer buf)
 633         filename))))
 634
 635 (require 'product)
 636 (product-provide (provide 'wl-message) (require 'wl-version))
 637
 638 ;;; wl-message.el ends here