wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36 (require 'timer)
  37
  38 (eval-when-compile
  39   (require 'wl-mime)
  40   (require 'mime-view)
  41   (defalias-maybe 'event-window 'ignore)
  42   (defalias-maybe 'posn-window 'ignore)
  43   (defalias-maybe 'event-start 'ignore)
  44   (defalias-maybe 'mime-open-entity 'ignore)
  45   (defalias-maybe 'itimer-function 'ignore)
  46   (defalias-maybe 'delete-itimer 'ignore)
  47   (defvar-maybe itimer-list))
  48
  49 (defvar wl-message-buffer-prefetch-get-next-function
  50   'wl-summary-default-get-next-msg)
  51
  52 (defvar wl-message-buffer-prefetch-debug nil)
  53 (defvar wl-message-buffer-prefetch-timer nil)
  54
  55 (defvar wl-message-buffer nil) ; message buffer.
  56
  57 (defvar wl-message-buffer-cur-folder nil)
  58 (defvar wl-message-buffer-cur-number nil)
  59 (defvar wl-message-buffer-cur-display-type nil)
  60 (defvar wl-message-buffer-cur-summary-buffer nil)
  61 (defvar wl-message-buffer-require-all-header nil)
  62 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  63 (defvar wl-message-buffer-mode-line-formatter nil)
  64 (defvar wl-message-buffer-flag-indicator nil)
  65 (defvar wl-message-buffer-mime-entity nil)
  66
  67 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-display-type)
  70 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  71 (make-variable-buffer-local 'wl-message-buffer-require-all-header)
  72 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  73 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  74 (make-variable-buffer-local 'wl-message-buffer-flag-indicator)
  75 (make-variable-buffer-local 'wl-message-buffer-mime-entity)
  76
  77 (defvar wl-fixed-window-configuration nil)
  78
  79 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  80
  81 ;;; Message buffer cache.
  82
  83 (defvar wl-message-buffer-cache nil
  84   "Message cache.  (old ... new) order alist.
  85 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  86
  87 (defmacro wl-message-buffer-cache-buffer-get (entry)
  88   (` (cdr (, entry))))
  89
  90 (defmacro wl-message-buffer-cache-folder-get (entry)
  91   (` (car (car (, entry)))))
  92
  93 (defmacro wl-message-buffer-cache-message-get (entry)
  94   (` (cdr (car (, entry)))))
  95
  96 (defmacro wl-message-buffer-cache-entry-make (key buf)
  97   (` (cons (, key) (, buf))))
  98
  99 (defmacro wl-message-buffer-cache-hit (key)
 100   "Return value assosiated with key."
 101   (` (wl-message-buffer-cache-buffer-get
 102       (assoc (, key) wl-message-buffer-cache))))
 103
 104 (defun wl-message-buffer-cache-sort (entry)
 105   "Move ENTRY to the top of `wl-message-buffer-cache'."
 106   (setq wl-message-buffer-cache
 107         (cons entry (delete entry wl-message-buffer-cache))))
 108 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 109 ;        (top pointer))
 110 ;    (while (cdr pointer)
 111 ;      (if (equal (car (cdr pointer)) entry)
 112 ;         (setcdr pointer (cdr (cdr pointer)))
 113 ;       (setq pointer (cdr pointer))))
 114 ;    (setcdr pointer (list entry))
 115 ;    (setq wl-message-buffer-cache (cdr top))))
 116
 117 (defconst wl-original-message-buffer-name " *Original*")
 118
 119 (defun wl-original-message-mode ()
 120   "A major mode for original message buffer."
 121   (setq major-mode 'wl-original-message-mode)
 122   (setq buffer-read-only t)
 123   (set-buffer-multibyte nil)
 124   (setq mode-name "Wanderlust original message"))
 125
 126 (defun wl-original-message-buffer-get (name)
 127   "Get original message buffer for NAME.
 128 If original message buffer already exists, it is re-used."
 129   (let* ((name (concat wl-original-message-buffer-name name))
 130          (buffer (get-buffer name)))
 131     (unless (and buffer (buffer-live-p buffer))
 132       (with-current-buffer (setq buffer (get-buffer-create name))
 133         (wl-original-message-mode)))
 134     buffer))
 135
 136 (defun wl-message-buffer-create ()
 137   "Create a new message buffer."
 138   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 139          (name (buffer-name buffer)))
 140     (with-current-buffer buffer
 141       (setq wl-message-buffer-original-buffer
 142             (wl-original-message-buffer-get name))
 143       (when wl-message-use-header-narrowing
 144         (wl-message-header-narrowing-setup))
 145       (run-hooks 'wl-message-buffer-created-hook))
 146     buffer))
 147
 148 (defun wl-message-buffer-cache-add (key)
 149   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 150 Return its cache buffer."
 151   (let ((len (length wl-message-buffer-cache))
 152         (buf nil))
 153     (if (< len wl-message-buffer-cache-size)
 154         (setq buf (wl-message-buffer-create))
 155       (let ((entry (nth (1- len) wl-message-buffer-cache)))
 156         (if (buffer-live-p
 157              (setq buf (wl-message-buffer-cache-buffer-get entry)))
 158             (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil)
 159           (setq wl-message-buffer-cache (delq entry wl-message-buffer-cache))
 160           (setq buf (wl-message-buffer-create)))))
 161     (setq wl-message-buffer-cache
 162           (cons (wl-message-buffer-cache-entry-make key buf)
 163                 wl-message-buffer-cache))
 164     buf))
 165
 166 (defun wl-message-buffer-cache-delete (&optional key)
 167   "Delete the most recent cache entry"
 168   (if key
 169       (setq wl-message-buffer-cache
 170             (delq (assoc key wl-message-buffer-cache)
 171                   wl-message-buffer-cache))
 172     (let ((buf (wl-message-buffer-cache-buffer-get
 173                 (car wl-message-buffer-cache))))
 174       (setq wl-message-buffer-cache
 175             (nconc (cdr wl-message-buffer-cache)
 176                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 177
 178 (defun wl-message-buffer-cache-clean-up ()
 179   "A function to flush all decoded messages in cache list."
 180   (interactive)
 181   (if (and (eq major-mode 'wl-summary-mode)
 182            wl-message-buffer
 183            (get-buffer-window wl-message-buffer))
 184       (delete-window (get-buffer-window wl-message-buffer)))
 185   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 186   (setq wl-message-buffer-cache nil))
 187
 188 ;;; Message buffer handling from summary buffer.
 189
 190 (defun wl-message-buffer-window ()
 191   "Get message buffer window if any."
 192   (let* ((start-win (selected-window))
 193          (cur-win start-win))
 194     (catch 'found
 195       (while (progn
 196                (setq cur-win (next-window cur-win))
 197                (with-current-buffer (window-buffer cur-win)
 198                  (if (or (eq major-mode 'wl-message-mode)
 199                          (eq major-mode 'mime-view-mode))
 200                      (throw 'found cur-win)))
 201                (not (eq cur-win start-win)))))))
 202
 203 (defun wl-message-select-buffer (buffer)
 204   "Select BUFFER as a message buffer."
 205   (let ((window (get-buffer-window buffer))
 206         (sum (car wl-message-window-size))
 207         (mes (cdr wl-message-window-size))
 208         whi)
 209     (when (and window
 210                (not (eq (save-excursion (set-buffer (window-buffer window))
 211                                         wl-message-buffer-cur-summary-buffer)
 212                         (current-buffer))))
 213       (delete-window window)
 214       (run-hooks 'wl-message-window-deleted-hook)
 215       (setq window nil))
 216     (if window
 217         (select-window window)
 218       (when wl-fixed-window-configuration
 219         (delete-other-windows)
 220         (and wl-stay-folder-window
 221              (wl-summary-toggle-disp-folder)))
 222       ;; There's no buffer window. Search for message window and snatch it.
 223       (if (setq window (wl-message-buffer-window))
 224           (select-window window)
 225         (setq whi (1- (window-height)))
 226         (if mes
 227             (progn
 228               (let ((total (+ sum mes)))
 229                 (setq sum (max window-min-height (/ (* whi sum) total)))
 230                 (setq mes (max window-min-height (/ (* whi mes) total))))
 231               (if (< whi (+ sum mes))
 232                   (enlarge-window (- (+ sum mes) whi)))))
 233         (split-window (get-buffer-window (current-buffer)) sum)
 234         (other-window 1)))
 235     (switch-to-buffer buffer)))
 236
 237 (defun wl-message-narrow-to-page (&optional arg)
 238   "Narrow to page.
 239 If ARG is specified, narrow to ARGth page."
 240   (interactive "P")
 241   (setq arg (if arg (prefix-numeric-value arg) 0))
 242   (save-excursion
 243     (condition-case ()
 244         (forward-page -1)               ; Beginning of current page.
 245       (beginning-of-buffer
 246        (goto-char (point-min))))
 247     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 248     (widen)
 249     (cond
 250      ((> arg 0) (forward-page arg))
 251      ((< arg 0) (forward-page (1- arg))))
 252     (forward-page)
 253     (if wl-break-pages
 254         (narrow-to-region (point)
 255                           (progn
 256                             (forward-page -1)
 257                             (if (and (eolp) (not (bobp)))
 258                                 (forward-line))
 259                             (point))))))
 260
 261 (defun wl-message-prev-page (&optional lines)
 262   "Scroll down current message by LINES.
 263 Returns non-nil if top of message."
 264   (interactive)
 265   (let (top real-top)
 266     (save-selected-window
 267       (unless (eq major-mode 'mime-view-mode)
 268         (when (buffer-live-p wl-message-buffer)
 269           (wl-message-select-buffer wl-message-buffer)))
 270       (move-to-window-line 0)
 271       (if (and wl-break-pages
 272                (bobp)
 273                (not (setq real-top (save-restriction (widen) (bobp)))))
 274           (progn
 275             (wl-message-narrow-to-page -1)
 276             (goto-char (point-max))
 277             (recenter))
 278         (if (not (bobp))
 279             (condition-case nil
 280                 (scroll-down (or lines wl-message-scroll-amount))
 281               (error))
 282           (setq top t)))
 283       (if real-top
 284           (let ((f (assq (mime-preview-original-major-mode)
 285                          mime-preview-over-to-previous-method-alist)))
 286             (if f (funcall (cdr f))))))
 287     top))
 288
 289 (defun wl-message-next-page (&optional lines)
 290   "Scroll up current message by LINES.
 291 Returns non-nil if bottom of message."
 292   (interactive)
 293   (let (bottom)
 294     (save-selected-window
 295       (unless (eq major-mode 'mime-view-mode)
 296         (when (buffer-live-p wl-message-buffer)
 297           (wl-message-select-buffer wl-message-buffer)))
 298       (move-to-window-line -1)
 299       (if (save-excursion
 300             (end-of-line)
 301             (and (pos-visible-in-window-p)
 302                  (eobp)))
 303           (if (or (null wl-break-pages)
 304                   (save-excursion
 305                     (save-restriction
 306                       (widen) (forward-line) (eobp))))
 307               (setq bottom t)
 308             (wl-message-narrow-to-page 1)
 309             (setq bottom nil))
 310         (condition-case ()
 311             (static-if (boundp 'window-pixel-scroll-increment)
 312                 ;; XEmacs 21.2.20 and later.
 313                 (let (window-pixel-scroll-increment)
 314                   (scroll-up (or lines wl-message-scroll-amount)))
 315               (scroll-up (or lines wl-message-scroll-amount)))
 316           (end-of-buffer
 317            (goto-char (point-max))))
 318         (setq bottom nil))
 319       (if (eobp)
 320           (let ((f (assq (mime-preview-original-major-mode)
 321                          mime-preview-over-to-next-method-alist)))
 322             (if f (funcall (cdr f))))))
 323     bottom))
 324
 325
 326 (defun wl-message-follow-current-entity (buffer)
 327   "Follow to current message."
 328   (wl-draft-reply (wl-message-get-original-buffer)
 329                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 330   (let ((mail-reply-buffer buffer))
 331     (wl-draft-yank-from-mail-reply-buffer nil)))
 332
 333 ;;
 334
 335 (defun wl-message-mode ()
 336   "A major mode for message displaying."
 337   (interactive)
 338   (setq major-mode 'wl-message-mode)
 339   (setq buffer-read-only t)
 340   (setq mode-name "Message"))
 341
 342 (defun wl-message-exit ()
 343   "Move to summary buffer or mother buffer."
 344   (interactive)
 345   (let (summary-buf summary-win mother-buffer)
 346     (cond ((setq summary-buf wl-message-buffer-cur-summary-buffer)
 347            (if (setq summary-win (get-buffer-window summary-buf))
 348                (select-window summary-win)
 349              (switch-to-buffer summary-buf)
 350              (wl-message-select-buffer wl-message-buffer)
 351              (select-window (get-buffer-window summary-buf))))
 352           ((setq mother-buffer mime-mother-buffer)
 353            (kill-buffer (current-buffer))
 354            (switch-to-buffer mother-buffer)))
 355     (run-hooks 'wl-message-exit-hook)))
 356
 357 (defun wl-message-toggle-disp-summary ()
 358   (interactive)
 359   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 360         summary-win)
 361     (if (and summary-buf
 362              (buffer-live-p summary-buf))
 363         (if (setq summary-win (get-buffer-window summary-buf))
 364             (delete-window summary-win)
 365           (switch-to-buffer summary-buf)
 366           (wl-message-select-buffer wl-message-buffer))
 367       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 368                                    nil nil t)
 369                                         ; no summary-buf
 370       (let ((sum-buf (current-buffer)))
 371         (wl-message-select-buffer wl-message-buffer)
 372         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 373
 374 (defun wl-message-get-original-buffer ()
 375   "Get original buffer for current message buffer."
 376   (if (buffer-live-p wl-message-buffer-original-buffer)
 377       wl-message-buffer-original-buffer
 378     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 379
 380 (defun wl-message-add-buttons-to-body (start end)
 381   (save-excursion
 382     (save-restriction
 383       (narrow-to-region start end)
 384       (let ((case-fold-search t)
 385             (alist wl-message-body-button-alist)
 386             entry)
 387         (while alist
 388           (setq entry (car alist)
 389                 alist (cdr alist))
 390           (goto-char (point-min))
 391           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 392             (unless (get-text-property (point) 'keymap)
 393               (wl-message-add-button
 394                (match-beginning (nth 1 entry))
 395                (match-end (nth 1 entry))
 396                (nth 2 entry)
 397                (match-string (nth 3 entry))))))))))
 398
 399 (defun wl-message-add-buttons-to-header (start end)
 400   (save-excursion
 401     (save-restriction
 402       (narrow-to-region start end)
 403       (let ((case-fold-search t)
 404             (alist wl-message-header-button-alist)
 405             entry)
 406         (while alist
 407           (setq entry (car alist)
 408                 alist (cdr alist))
 409           (goto-char (point-min))
 410           (while (re-search-forward (car entry) nil t)
 411             (setq start (match-beginning 0)
 412                   end (if (re-search-forward "^[^ \t]" nil t)
 413                           (match-beginning 0)
 414                         (point-max)))
 415             (goto-char start)
 416             (while (re-search-forward (nth 1 entry) end t)
 417               (wl-message-add-button
 418                (match-beginning (nth 2 entry))
 419                (match-end (nth 2 entry))
 420                (nth 3 entry) (match-string (nth 4 entry))))
 421             (goto-char end)))))))
 422
 423 ;; display-type object definition.
 424 (defun wl-message-make-display-type (mime header)
 425   (let (symbol)
 426     (prog1
 427         (setq symbol (intern (format "%s-%s-header" mime header)))
 428       (put symbol
 429            'wl-message-display-type
 430            (list :mime mime :header header)))))
 431
 432 (defun wl-message-display-type-property (display-type prop)
 433   (plist-get (get display-type 'wl-message-display-type) prop))
 434
 435 (defun wl-message-mime-analysis-p (display-type &optional header-or-body)
 436   (let ((mode (wl-message-display-type-property display-type :mime)))
 437     (case header-or-body
 438       (header
 439        (memq mode '(mime header-only)))
 440       (t
 441        (eq mode 'mime)))))
 442
 443 (defun wl-message-display-all-header-p (display-type)
 444   (eq (wl-message-display-type-property display-type :header) 'all))
 445
 446 (defun wl-message-buffer-display-type (&optional message-buffer)
 447   (if message-buffer
 448       (with-current-buffer message-buffer
 449         wl-message-buffer-cur-display-type)
 450     wl-message-buffer-cur-display-type))
 451
 452 (defun wl-message-redisplay (folder number display-type &optional force-reload)
 453   (let* ((default-mime-charset wl-mime-charset)
 454          (buffer-read-only nil)
 455          (summary-buf (current-buffer))
 456          message-buf entity summary-win flags)
 457     (setq buffer-read-only nil)
 458     (setq wl-message-buffer (wl-message-buffer-display
 459                              folder number display-type force-reload))
 460     (setq message-buf wl-message-buffer)
 461     (wl-message-select-buffer wl-message-buffer)
 462
 463     (set-buffer message-buf)
 464     (wl-deactivate-region)
 465     (make-local-variable 'truncate-partial-width-windows)
 466     (setq truncate-partial-width-windows nil)
 467     (setq truncate-lines wl-message-truncate-lines)
 468     (setq buffer-read-only nil)
 469     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 470     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 471     (setq wl-message-buffer-cur-number number)
 472     (setq wl-message-buffer-flag-indicator
 473           (if (setq flags (elmo-get-global-flags (elmo-message-flags
 474                                                   folder number)))
 475               (let ((fl wl-summary-flag-alist)
 476                     flag-strings flag-string face)
 477                 (while fl
 478                   (when (memq (car (car fl)) flags)
 479                     (setq flag-string (capitalize
 480                                        (symbol-name (car (car fl))))
 481                           flags (delq (car (car fl)) flags))
 482                     (when (facep (setq face
 483                                        (intern
 484                                         (format
 485                                          "wl-highlight-summary-%s-flag-face"
 486                                          (car (car fl))))))
 487                       (put-text-property 0 (length flag-string)
 488                                          'face face flag-string))
 489                     (setq flag-strings (nconc flag-strings
 490                                               (list flag-string))))
 491                   (setq fl (cdr fl)))
 492                 (setq flag-strings
 493                       (nconc flag-strings
 494                              (mapcar (lambda (flag)
 495                                        (capitalize (symbol-name flag)))
 496                                      flags)))
 497                 (concat " (" (mapconcat 'identity flag-strings ", ") ")"))
 498             ""))
 499     (wl-line-formatter-setup
 500      wl-message-buffer-mode-line-formatter
 501      wl-message-mode-line-format
 502      wl-message-mode-line-format-spec-alist)
 503     (setq mode-line-buffer-identification
 504           (funcall wl-message-buffer-mode-line-formatter))
 505     ;; highlight body
 506 ;    (when wl-highlight-body-too
 507 ;      (wl-highlight-body))
 508     (ignore-errors (wl-message-narrow-to-page))
 509     (goto-char (point-min))
 510     (when (re-search-forward "^$" nil t)
 511       (wl-message-add-buttons-to-header (point-min) (point))
 512       (wl-message-add-buttons-to-body (point) (point-max)))
 513     (when (and wl-message-use-header-narrowing
 514                (not (wl-message-display-all-header-p display-type)))
 515       (wl-message-header-narrowing))
 516     (goto-char (point-min))
 517     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 518     ;; go back to summary mode
 519     (set-buffer-modified-p nil)
 520     (setq buffer-read-only t)
 521     (set-buffer summary-buf)
 522     (setq summary-win (get-buffer-window summary-buf))
 523     (if (window-live-p summary-win)
 524         (select-window summary-win))))
 525
 526 ;; Use message buffer cache.
 527 (defun wl-message-buffer-display (folder number display-type
 528                                          &optional force-reload unread)
 529   (let* ((msg-id (ignore-errors
 530                    (elmo-message-field folder number 'message-id)))
 531          (fname (elmo-folder-name-internal folder))
 532          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 533          (redisplay nil)
 534          entity)
 535     (when (and hit (not (buffer-live-p hit)))
 536       (wl-message-buffer-cache-delete (list fname number msg-id))
 537       (setq hit nil))
 538     (if hit
 539         (progn
 540           ;; move hit to the top.
 541           (wl-message-buffer-cache-sort
 542            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 543           (with-current-buffer hit
 544             ;; Rewind to the top page
 545             (widen)
 546             (goto-char (point-min))
 547             (ignore-errors (wl-message-narrow-to-page))
 548             (setq entity wl-message-buffer-mime-entity)
 549             (unless (eq wl-message-buffer-cur-display-type display-type)
 550               (setq redisplay t))))
 551       ;; delete tail and add new to the top.
 552       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 553       (setq redisplay t))
 554     (when (or force-reload redisplay)
 555       (condition-case err
 556           (save-excursion
 557             (set-buffer hit)
 558             (when (or force-reload
 559                       (null entity)
 560                       (not (elmo-mime-entity-display-p
 561                             entity
 562                             (if (wl-message-mime-analysis-p display-type)
 563                                 'mime
 564                               'as-is))))
 565               (setq entity (elmo-message-mime-entity
 566                             folder
 567                             number
 568                             (wl-message-get-original-buffer)
 569                             force-reload
 570                             unread
 571                             (not (wl-message-mime-analysis-p display-type)))))
 572             (unless entity
 573               (error "Cannot display message %s/%s" fname number))
 574             (wl-message-display-internal entity display-type))
 575         (quit
 576          (wl-message-buffer-cache-delete)
 577          (error "Display message %s/%s is quitted" fname number))
 578         (error
 579          (wl-message-buffer-cache-delete)
 580          (signal (car err) (cdr err))
 581          nil))) ;; will not be used
 582     hit))
 583
 584 (defun wl-message-display-internal (entity display-type)
 585   (let ((default-mime-charset wl-mime-charset)
 586         (elmo-mime-charset wl-mime-charset)
 587         (wl-message-buffer-require-all-header
 588          (wl-message-display-all-header-p display-type)))
 589     (if (wl-message-mime-analysis-p display-type)
 590         (elmo-mime-entity-display entity
 591                                   (current-buffer)
 592                                   'wl-original-message-mode
 593                                   (wl-message-define-keymap))
 594       (let* ((elmo-mime-display-header-analysis
 595               (wl-message-mime-analysis-p display-type 'header))
 596              (wl-highlight-x-face-function
 597               (and elmo-mime-display-header-analysis
 598                    wl-highlight-x-face-function)))
 599         (elmo-mime-entity-display-as-is entity
 600                                         (current-buffer)
 601                                         'wl-original-message-mode
 602                                         (wl-message-define-keymap))
 603         (let (buffer-read-only)
 604           (wl-highlight-message (point-min) (point-max) t))))
 605     (setq wl-message-buffer-cur-display-type display-type
 606           wl-message-buffer-mime-entity entity)
 607     (run-hooks 'wl-message-display-internal-hook)
 608     (setq buffer-read-only t)))
 609
 610 (defun wl-message-buffer-prefetch-p (folder &optional number)
 611   (and (or (not number)
 612            (elmo-message-file-p folder number)
 613            (let ((size (elmo-message-field folder number 'size)))
 614              (not (and (integerp size)
 615                        wl-message-buffer-prefetch-threshold
 616                        (>= size wl-message-buffer-prefetch-threshold)))))
 617        (or (not number)
 618            (elmo-folder-plugged-p folder)
 619            (elmo-file-cache-exists-p
 620                  (elmo-message-field folder number 'message-id)))
 621        (or (cond
 622             ((eq wl-message-buffer-prefetch-folder-type-list t)
 623              t)
 624             ((and number wl-message-buffer-prefetch-folder-type-list)
 625              (memq (elmo-folder-type-internal
 626                     (elmo-message-folder folder number))
 627                    wl-message-buffer-prefetch-folder-type-list))
 628             (wl-message-buffer-prefetch-folder-type-list
 629              (let ((list wl-message-buffer-prefetch-folder-type-list)
 630                    type)
 631                (catch 'done
 632                  (while (setq type (pop list))
 633                    (if (elmo-folder-contains-type folder type)
 634                        (throw 'done t)))))))
 635            (cond
 636             ((consp wl-message-buffer-prefetch-folder-list)
 637              (wl-string-match-member (elmo-folder-name-internal folder)
 638                                      wl-message-buffer-prefetch-folder-list))
 639             (t wl-message-buffer-prefetch-folder-list)))))
 640
 641 (defsubst wl-message-buffer-prefetch-clear-timer ()
 642 ;;;     cannot use for the bug of fsf-compat package (1.09).
 643 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 644   (if (fboundp 'run-with-idle-timer)
 645       (if (featurep 'xemacs)
 646           (let ((p itimer-list))
 647             (while (car p)
 648               (if (eq 'wl-message-buffer-prefetch-subr
 649                       (itimer-function (car p)))
 650                   (delete-itimer (car p)))
 651               (setq p (cdr p))))
 652         ;; FSF Emacs is correct
 653         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 654
 655 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 656                                                        summary charset)
 657   (if (not (fboundp 'run-with-idle-timer))
 658       (when (sit-for wl-message-buffer-prefetch-idle-time)
 659         (wl-message-buffer-prefetch-subr
 660          folder number count summary charset))
 661     (run-with-idle-timer
 662      wl-message-buffer-prefetch-idle-time
 663      nil
 664      'wl-message-buffer-prefetch-subr
 665      folder number count summary charset)))
 666
 667 (defvar wl-message-buffer-prefetch-move-spec-alist nil)
 668
 669 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 670   (if (buffer-live-p summary)
 671       (with-current-buffer summary
 672         (let ((wl-summary-move-spec-alist
 673                (or wl-message-buffer-prefetch-move-spec-alist
 674                    wl-summary-move-spec-alist))
 675               (next number))
 676           (while (and (setq next (funcall
 677                                   wl-message-buffer-prefetch-get-next-function
 678                                   next))
 679                       (not (wl-message-buffer-prefetch-p folder next))))
 680           next))))
 681
 682 (defun wl-message-buffer-prefetch (folder number count
 683                                           &optional summary charset)
 684   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 685          (num number))
 686     (when (and count
 687                (wl-message-buffer-prefetch-p folder))
 688       (unless (wl-message-buffer-prefetch-p folder number)
 689         (setq num
 690               (wl-message-buffer-prefetch-get-next folder number summary)))
 691       (when num
 692         (wl-message-buffer-prefetch-clear-timer)
 693         (wl-message-buffer-prefetch-set-timer
 694          folder num count summary charset)))))
 695
 696 (defun wl-message-buffer-prefetch-next (folder number count
 697                                                &optional summary charset)
 698   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 699          next)
 700     (when (and count
 701                (wl-message-buffer-prefetch-p folder))
 702       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 703       (when next
 704         (wl-message-buffer-prefetch-clear-timer)
 705         (wl-message-buffer-prefetch-set-timer
 706          folder next count summary charset)))))
 707
 708 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 709   (if (buffer-live-p summary)
 710       (with-current-buffer summary
 711         (if (and number
 712                  (numberp count)
 713                  (>= (setq count (- count 1)) 0)
 714                  (string= (elmo-folder-name-internal folder)
 715                           (wl-summary-buffer-folder-name)))
 716             (let* ((wl-mime-charset      charset)
 717                    (default-mime-charset charset)
 718                    (message-id (elmo-message-field folder number 'message-id))
 719                    (key (list (elmo-folder-name-internal folder)
 720                               number message-id))
 721                    (hit (wl-message-buffer-cache-hit key))
 722                    (display-type (wl-message-make-display-type
 723                                   wl-summary-buffer-display-mime-mode
 724                                   wl-summary-buffer-display-header-mode))
 725                    time1 time2 sec micro)
 726               (when wl-message-buffer-prefetch-debug
 727                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 728               (if (and hit (buffer-live-p hit))
 729                   (progn
 730                     (wl-message-buffer-cache-sort
 731                      (wl-message-buffer-cache-entry-make key hit))
 732                     (wl-message-buffer-prefetch-subr
 733                      folder
 734                      (wl-message-buffer-prefetch-get-next
 735                       folder number summary)
 736                      count summary charset))
 737                 ;; prefetching
 738                 (when wl-message-buffer-prefetch-debug
 739                   (setq time1 (current-time))
 740                   (message "Prefetching %d..." number))
 741                 (wl-message-buffer-display folder number
 742                                            display-type nil 'unread)
 743                 (when (elmo-message-use-cache-p folder number)
 744                   (elmo-message-set-cached folder number t))
 745                 (when wl-message-buffer-prefetch-debug
 746                   (setq time2 (current-time))
 747                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 748                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 749                   (setq micro (+ micro (* 1000000 sec)))
 750                   (message "Prefetching %d...done(%f msec)."
 751                            number
 752                            (/ micro 1000.0))
 753                   (sit-for 0))
 754                 ;; set next prefetch
 755                 (wl-message-buffer-prefetch-set-timer
 756                  folder
 757                  (wl-message-buffer-prefetch-get-next
 758                   folder number summary)
 759                  count summary charset)
 760                 (sit-for 0)
 761                 ;; success prefetch
 762                 )))
 763         ;; finish prefetch
 764         (when wl-message-buffer-prefetch-debug
 765           (message "Buffer Cached Messages: %s"
 766                    (mapconcat
 767                     '(lambda (cache)
 768                        (if (numberp (nth 1 (car cache)))
 769                            (if (string=
 770                                 (nth 0 (car cache))
 771                                 (elmo-folder-name-internal folder))
 772                                (format "%d"
 773                                        (nth 1 (car cache)))
 774                              (format "*%d" (nth 1 (car cache))))
 775                          "-"))
 776                     wl-message-buffer-cache " "))) )))
 777
 778 (defvar wl-message-button-map (make-sparse-keymap))
 779
 780 (defun wl-message-add-button (from to function &optional data)
 781   "Create a button between FROM and TO with callback FUNCTION and DATA."
 782   (add-text-properties
 783    from to
 784    (nconc (list 'wl-message-button-callback function)
 785           (if data
 786               (list 'wl-message-button-data data))))
 787   (let ((ov (make-overlay from to)))
 788     (overlay-put ov 'mouse-face 'highlight)
 789     (overlay-put ov 'local-map wl-message-button-map)
 790     (overlay-put ov 'evaporate t)))
 791
 792 (defun wl-message-button-dispatcher (event)
 793   "Select the button under point."
 794   (interactive "@e")
 795   (mouse-set-point event)
 796   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 797         (data (get-text-property (point) 'wl-message-button-data)))
 798     (if callback
 799         (funcall callback data)
 800       (wl-message-button-dispatcher-internal event))))
 801
 802 (defun wl-message-button-refer-article (data)
 803   "Read article specified by Message-ID DATA at point."
 804   (switch-to-buffer-other-window
 805    wl-message-buffer-cur-summary-buffer)
 806   (if (wl-summary-jump-to-msg-by-message-id data)
 807       (wl-summary-redisplay)))
 808
 809 (defun wl-message-uu-substring (buf outbuf &optional first last)
 810   (save-excursion
 811     (set-buffer buf)
 812     (search-forward "\n\n")
 813     (let ((sp (point))
 814           ep filename case-fold-search)
 815       (catch 'done
 816         (if first
 817             (progn
 818               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 819                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 820                 (throw 'done nil)))
 821           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 822         (beginning-of-line)
 823         (setq sp (point))
 824         (goto-char (point-max))
 825         (if last
 826             (re-search-backward "^end" sp t)
 827           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 828         (forward-line 1)
 829         (setq ep (point))
 830         (set-buffer outbuf)
 831         (goto-char (point-max))
 832         (insert-buffer-substring buf sp ep)
 833         (set-buffer buf)
 834         filename))))
 835
 836 ;;; Header narrowing courtesy of Hideyuki Shirai.
 837 (defun wl-message-header-narrowing ()
 838   "Narrowing headers."
 839   (unless (eq this-command 'wl-summary-redisplay-all-header)
 840     (save-excursion
 841       (save-restriction
 842         (goto-char (point-min))
 843         (if (re-search-forward "^$" nil t)
 844             (beginning-of-line)
 845           (goto-char (point-max)))
 846         (narrow-to-region (point-min) (point))
 847         (let ((fields wl-message-header-narrowing-fields))
 848           (while fields
 849             (wl-message-header-narrowing-1 (concat "^" (car fields) ":"))
 850             (setq fields (cdr fields))))))))
 851
 852 (defvar wl-message-header-narrowing-map (make-sparse-keymap))
 853 (define-key wl-message-header-narrowing-map [mouse-2]
 854   'wl-message-header-narrowing-again-at-mouse)
 855
 856 (defvar wl-message-header-narrowing-widen-map (make-sparse-keymap))
 857 (define-key wl-message-header-narrowing-widen-map [mouse-2]
 858   'wl-message-header-narrowing-widen-at-mouse)
 859
 860 (defun wl-message-header-narrowing-again-at-mouse (event)
 861   (interactive "e")
 862   (save-window-excursion
 863     (save-excursion
 864       (mouse-set-point event)
 865       (wl-message-header-narrowing))))
 866
 867 (defun wl-message-header-narrowing-1 (hregexp)
 868   (let ((case-fold-search t)
 869         ov start end)
 870     (goto-char (point-min))
 871     (while (re-search-forward hregexp nil t)
 872       (setq start (match-beginning 0))
 873       (forward-line 1)
 874       (setq end (progn (while (looking-at "^[ \t]") (forward-line))
 875                        (forward-line -1)
 876                        (line-end-position)))
 877       (if (<= (count-lines start end) wl-message-header-narrowing-lines)
 878           (forward-line 1)
 879         (goto-char start)
 880         (forward-line (1- wl-message-header-narrowing-lines))
 881         (end-of-line)
 882         (setq start (point))
 883         (unless (eq (get-char-property start 'invisible)
 884                     'wl-message-header-narrowing)
 885           (setq ov (or
 886                     (let ((ovs (overlays-at start))
 887                           ov)
 888                       (while (and ovs (not (overlayp ov)))
 889                         (if (overlay-get (car ovs)
 890                                          'wl-message-header-narrowing)
 891                             (setq ov (car ovs)))
 892                         (setq ovs (cdr ovs)))
 893                       ov)
 894                     (make-overlay start end)))
 895           (overlay-put ov 'wl-message-header-narrowing t)
 896           (overlay-put ov 'evaporate t)
 897           (overlay-put ov 'invisible 'wl-message-header-narrowing)
 898           (overlay-put ov 'after-string
 899                        wl-message-header-narrowing-string))))))
 900
 901 (defun wl-message-header-narrowing-widen-at-mouse (event)
 902   (interactive "e")
 903   (save-selected-window
 904     (select-window (posn-window (event-start event)))
 905     (let* ((win (selected-window))
 906            (wpos (window-start win))
 907            (pos (mouse-set-point event))
 908            (ovs (overlays-in (1- pos) (1+ pos)))        ;; Uum...
 909            ov)
 910       (while (and ovs (not (overlayp ov)))
 911         (when (overlay-get (car ovs) 'wl-message-header-narrowing)
 912           (setq ov (car ovs)))
 913         (setq ovs (cdr ovs)))
 914       (when (overlayp ov)
 915         (overlay-put ov 'face 'wl-message-header-narrowing-face)
 916         (overlay-put ov 'local-map wl-message-header-narrowing-map)
 917         (overlay-put ov 'invisible nil)
 918         (overlay-put ov 'after-string nil))
 919       (set-window-start win wpos))))
 920
 921 (defun wl-message-header-narrowing-setup ()
 922   (when (boundp 'line-move-ignore-invisible)
 923     (set (make-local-variable 'line-move-ignore-invisible) t))
 924   (set-text-properties 0 (length wl-message-header-narrowing-string)
 925                        `(face
 926                          wl-message-header-narrowing-face
 927                          keymap
 928                          ,wl-message-header-narrowing-widen-map)
 929                        wl-message-header-narrowing-string))
 930
 931 (defun wl-message-header-narrowing-toggle ()
 932   "Toggle header narrowing."
 933   (interactive)
 934   (when wl-message-use-header-narrowing
 935     (save-excursion
 936       (goto-char (point-min))
 937       (if (re-search-forward "^$" nil t)
 938           (beginning-of-line)
 939         (goto-char (point-max)))
 940       (let ((ovs (overlays-in (point-min) (point)))
 941             ov hn-ovs)
 942         (while (setq ov (car ovs))
 943           (when (overlay-get ov 'wl-message-header-narrowing)
 944             (setq hn-ovs (cons ov hn-ovs)))
 945           (setq ovs (cdr ovs)))
 946         (if hn-ovs
 947             (while hn-ovs
 948               (delete-overlay (car hn-ovs))
 949               (setq hn-ovs (cdr hn-ovs)))
 950           (wl-message-header-narrowing))))))
 951
 952 (require 'product)
 953 (product-provide (provide 'wl-message) (require 'wl-version))
 954
 955 ;;; wl-message.el ends here