wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36 (require 'timer)
  37
  38 (eval-when-compile
  39   (require 'wl-mime)
  40   (require 'mime-view)
  41   (defalias-maybe 'event-window 'ignore)
  42   (defalias-maybe 'posn-window 'ignore)
  43   (defalias-maybe 'event-start 'ignore)
  44   (defalias-maybe 'mime-open-entity 'ignore)
  45   (defalias-maybe 'itimer-function 'ignore)
  46   (defalias-maybe 'delete-itimer 'ignore)
  47   (defvar-maybe itimer-list))
  48
  49 (defvar wl-message-buffer-prefetch-get-next-function
  50   'wl-summary-default-get-next-msg)
  51
  52 (defvar wl-message-buffer-prefetch-debug nil)
  53 (defvar wl-message-buffer-prefetch-timer nil)
  54
  55 (defvar wl-message-buffer nil) ; message buffer.
  56
  57 (defvar wl-message-buffer-cur-summary-buffer nil)
  58 (defvar wl-message-buffer-cur-folder nil)
  59 (defvar wl-message-buffer-cur-number nil)
  60 (defvar wl-message-buffer-cur-flag nil)
  61 (defvar wl-message-buffer-cur-summary-buffer nil)
  62 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  63 (defvar wl-message-buffer-all-header-flag nil)
  64 (defvar wl-message-buffer-mode-line-formatter nil)
  65
  66 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  67 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-flag)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  70 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  71 (make-variable-buffer-local 'wl-message-buffer-all-header-flag)
  72 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  73
  74 (defvar wl-fixed-window-configuration nil)
  75
  76 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  77
  78 ;;; Message buffer cache.
  79
  80 (defvar wl-message-buffer-cache nil
  81   "Message cache.  (old ... new) order alist.
  82 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  83
  84 (defmacro wl-message-buffer-cache-buffer-get (entry)
  85   (` (cdr (, entry))))
  86
  87 (defmacro wl-message-buffer-cache-folder-get (entry)
  88   (` (car (car (, entry)))))
  89
  90 (defmacro wl-message-buffer-cache-message-get (entry)
  91   (` (cdr (car (, entry)))))
  92
  93 (defmacro wl-message-buffer-cache-entry-make (key buf)
  94   (` (cons (, key) (, buf))))
  95
  96 (defmacro wl-message-buffer-cache-hit (key)
  97   "Return value assosiated with key."
  98   (` (wl-message-buffer-cache-buffer-get
  99       (assoc (, key) wl-message-buffer-cache))))
 100
 101 (defun wl-message-buffer-cache-sort (entry)
 102   "Move ENTRY to the top of `wl-message-buffer-cache'."
 103   (setq wl-message-buffer-cache
 104         (cons entry (delete entry wl-message-buffer-cache))))
 105 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 106 ;        (top pointer))
 107 ;    (while (cdr pointer)
 108 ;      (if (equal (car (cdr pointer)) entry)
 109 ;         (setcdr pointer (cdr (cdr pointer)))
 110 ;       (setq pointer (cdr pointer))))
 111 ;    (setcdr pointer (list entry))
 112 ;    (setq wl-message-buffer-cache (cdr top))))
 113
 114 (defconst wl-original-message-buffer-name " *Original*")
 115
 116 (defun wl-original-message-mode ()
 117   "A major mode for original message buffer."
 118   (setq major-mode 'wl-original-message-mode)
 119   (setq buffer-read-only t)
 120   (elmo-set-buffer-multibyte nil)
 121   (setq mode-name "Wanderlust original message"))
 122
 123 (defun wl-original-message-buffer-get (name)
 124   "Get original message buffer for NAME.
 125 If original message buffer already exists, it is re-used."
 126   (let* ((name (concat wl-original-message-buffer-name name))
 127          (buffer (get-buffer name)))
 128     (unless (and buffer (buffer-live-p buffer))
 129       (with-current-buffer (setq buffer (get-buffer-create name))
 130         (wl-original-message-mode)))
 131     buffer))
 132
 133 (defun wl-message-buffer-create ()
 134   "Create a new message buffer."
 135   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 136          (name (buffer-name buffer)))
 137     (with-current-buffer buffer
 138       (setq wl-message-buffer-original-buffer
 139             (wl-original-message-buffer-get name))
 140       (when wl-message-use-header-narrowing
 141         (wl-message-header-narrowing-setup))
 142       (run-hooks 'wl-message-buffer-created-hook))
 143     buffer))
 144
 145 (defun wl-message-buffer-cache-add (key)
 146   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 147 Return its cache buffer."
 148   (let ((len (length wl-message-buffer-cache))
 149         (buf nil))
 150     (if (< len wl-message-buffer-cache-size)
 151         (setq buf (wl-message-buffer-create))
 152       (let ((entry (nth (1- len) wl-message-buffer-cache)))
 153         (if (buffer-live-p
 154              (setq buf (wl-message-buffer-cache-buffer-get entry)))
 155             (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil)
 156           (setq wl-message-buffer-cache (delq entry wl-message-buffer-cache))
 157           (setq buf (wl-message-buffer-create)))))
 158     (setq wl-message-buffer-cache
 159           (cons (wl-message-buffer-cache-entry-make key buf)
 160                 wl-message-buffer-cache))
 161     buf))
 162
 163 (defun wl-message-buffer-cache-delete (&optional key)
 164   "Delete the most recent cache entry"
 165   (if key
 166       (setq wl-message-buffer-cache
 167             (delq (assoc key wl-message-buffer-cache)
 168                   wl-message-buffer-cache))
 169     (let ((buf (wl-message-buffer-cache-buffer-get
 170                 (car wl-message-buffer-cache))))
 171       (setq wl-message-buffer-cache
 172             (nconc (cdr wl-message-buffer-cache)
 173                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 174
 175 (defun wl-message-buffer-cache-clean-up ()
 176   "A function to flush all decoded messages in cache list."
 177   (interactive)
 178   (if (and (eq major-mode 'wl-summary-mode)
 179            wl-message-buffer
 180            (get-buffer-window wl-message-buffer))
 181       (delete-window (get-buffer-window wl-message-buffer)))
 182   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 183   (setq wl-message-buffer-cache nil))
 184
 185 ;;; Message buffer handling from summary buffer.
 186
 187 (defun wl-message-buffer-window ()
 188   "Get message buffer window if any."
 189   (let* ((start-win (selected-window))
 190          (cur-win start-win))
 191     (catch 'found
 192       (while (progn
 193                (setq cur-win (next-window cur-win))
 194                (with-current-buffer (window-buffer cur-win)
 195                  (if (or (eq major-mode 'wl-message-mode)
 196                          (eq major-mode 'mime-view-mode))
 197                      (throw 'found cur-win)))
 198                (not (eq cur-win start-win)))))))
 199
 200 (defun wl-message-select-buffer (buffer)
 201   "Select BUFFER as a message buffer."
 202   (let ((window (get-buffer-window buffer))
 203         (sum (car wl-message-window-size))
 204         (mes (cdr wl-message-window-size))
 205         whi)
 206     (when (and window
 207                (not (eq (save-excursion (set-buffer (window-buffer window))
 208                                         wl-message-buffer-cur-summary-buffer)
 209                         (current-buffer))))
 210       (delete-window window)
 211       (run-hooks 'wl-message-window-deleted-hook)
 212       (setq window nil))
 213     (if window
 214         (select-window window)
 215       (when wl-fixed-window-configuration
 216         (delete-other-windows)
 217         (and wl-stay-folder-window
 218              (wl-summary-toggle-disp-folder)))
 219       ;; There's no buffer window. Search for message window and snatch it.
 220       (if (setq window (wl-message-buffer-window))
 221           (select-window window)
 222         (setq whi (1- (window-height)))
 223         (if mes
 224             (progn
 225               (let ((total (+ sum mes)))
 226                 (setq sum (max window-min-height (/ (* whi sum) total)))
 227                 (setq mes (max window-min-height (/ (* whi mes) total))))
 228               (if (< whi (+ sum mes))
 229                   (enlarge-window (- (+ sum mes) whi)))))
 230         (split-window (get-buffer-window (current-buffer)) sum)
 231         (other-window 1)))
 232     (switch-to-buffer buffer)))
 233
 234 (defun wl-message-narrow-to-page (&optional arg)
 235   "Narrow to page.
 236 If ARG is specified, narrow to ARGth page."
 237   (interactive "P")
 238   (setq arg (if arg (prefix-numeric-value arg) 0))
 239   (save-excursion
 240     (condition-case ()
 241         (forward-page -1)               ; Beginning of current page.
 242       (beginning-of-buffer
 243        (goto-char (point-min))))
 244     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 245     (widen)
 246     (cond
 247      ((> arg 0) (forward-page arg))
 248      ((< arg 0) (forward-page (1- arg))))
 249     (forward-page)
 250     (if wl-break-pages
 251         (narrow-to-region (point)
 252                           (progn
 253                             (forward-page -1)
 254                             (if (and (eolp) (not (bobp)))
 255                                 (forward-line))
 256                             (point))))))
 257
 258 (defun wl-message-prev-page (&optional lines)
 259   "Scroll down current message by LINES.
 260 Returns non-nil if top of message."
 261   (interactive)
 262   (let (top real-top)
 263     (save-selected-window
 264       (unless (eq major-mode 'mime-view-mode)
 265         (when (buffer-live-p wl-message-buffer)
 266           (wl-message-select-buffer wl-message-buffer)))
 267       (move-to-window-line 0)
 268       (if (and wl-break-pages
 269                (bobp)
 270                (not (setq real-top (save-restriction (widen) (bobp)))))
 271           (progn
 272             (wl-message-narrow-to-page -1)
 273             (goto-char (point-max))
 274             (recenter))
 275         (if (not (bobp))
 276             (condition-case nil
 277                 (scroll-down (or lines wl-message-scroll-amount))
 278               (error))
 279           (setq top t)))
 280       (if real-top
 281           (let ((f (assq (mime-preview-original-major-mode)
 282                          mime-preview-over-to-previous-method-alist)))
 283             (if f (funcall (cdr f))))))
 284     top))
 285
 286 (defun wl-message-next-page (&optional lines)
 287   "Scroll up current message by LINES.
 288 Returns non-nil if bottom of message."
 289   (interactive)
 290   (let (bottom)
 291     (save-selected-window
 292       (unless (eq major-mode 'mime-view-mode)
 293         (when (buffer-live-p wl-message-buffer)
 294           (wl-message-select-buffer wl-message-buffer)))
 295       (move-to-window-line -1)
 296       (if (save-excursion
 297             (end-of-line)
 298             (and (pos-visible-in-window-p)
 299                  (eobp)))
 300           (if (or (null wl-break-pages)
 301                   (save-excursion
 302                     (save-restriction
 303                       (widen) (forward-line) (eobp))))
 304               (setq bottom t)
 305             (wl-message-narrow-to-page 1)
 306             (setq bottom nil))
 307         (condition-case ()
 308             (static-if (boundp 'window-pixel-scroll-increment)
 309                 ;; XEmacs 21.2.20 and later.
 310                 (let (window-pixel-scroll-increment)
 311                   (scroll-up (or lines wl-message-scroll-amount)))
 312               (scroll-up (or lines wl-message-scroll-amount)))
 313           (end-of-buffer
 314            (goto-char (point-max))))
 315         (setq bottom nil))
 316       (if (eobp)
 317           (let ((f (assq (mime-preview-original-major-mode)
 318                          mime-preview-over-to-next-method-alist)))
 319             (if f (funcall (cdr f))))))
 320     bottom))
 321
 322
 323 (defun wl-message-follow-current-entity (buffer)
 324   "Follow to current message."
 325   (wl-draft-reply (wl-message-get-original-buffer)
 326                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 327   (let ((mail-reply-buffer buffer))
 328     (wl-draft-yank-from-mail-reply-buffer nil)))
 329
 330 ;;
 331
 332 (defun wl-message-mode ()
 333   "A major mode for message displaying."
 334   (interactive)
 335   (setq major-mode 'wl-message-mode)
 336   (setq buffer-read-only t)
 337   (setq mode-name "Message"))
 338
 339 (defun wl-message-exit ()
 340   "Move to summary buffer."
 341   (interactive)
 342   (let (summary-buf summary-win)
 343     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 344         (if (setq summary-win (get-buffer-window summary-buf))
 345             (select-window summary-win)
 346           (switch-to-buffer summary-buf)
 347           (wl-message-select-buffer wl-message-buffer)
 348           (select-window (get-buffer-window summary-buf))))
 349     (run-hooks 'wl-message-exit-hook)))
 350
 351 (defun wl-message-toggle-disp-summary ()
 352   (interactive)
 353   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 354         summary-win)
 355     (if (and summary-buf
 356              (buffer-live-p summary-buf))
 357         (if (setq summary-win (get-buffer-window summary-buf))
 358             (delete-window summary-win)
 359           (switch-to-buffer summary-buf)
 360           (wl-message-select-buffer wl-message-buffer))
 361       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 362                                    nil nil t)
 363                                         ; no summary-buf
 364       (let ((sum-buf (current-buffer)))
 365         (wl-message-select-buffer wl-message-buffer)
 366         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 367
 368 (defun wl-message-get-original-buffer ()
 369   "Get original buffer for current message buffer."
 370   (if (buffer-live-p wl-message-buffer-original-buffer)
 371       wl-message-buffer-original-buffer
 372     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 373
 374 (defun wl-message-add-buttons-to-body (start end)
 375   (save-excursion
 376     (save-restriction
 377       (narrow-to-region start end)
 378       (let ((case-fold-search t)
 379             (alist wl-message-body-button-alist)
 380             entry)
 381         (while alist
 382           (setq entry (car alist)
 383                 alist (cdr alist))
 384           (goto-char (point-min))
 385           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 386             (unless (get-text-property (point) 'keymap)
 387               (wl-message-add-button
 388                (match-beginning (nth 1 entry))
 389                (match-end (nth 1 entry))
 390                (nth 2 entry)
 391                (match-string (nth 3 entry))))))))))
 392
 393 (defun wl-message-add-buttons-to-header (start end)
 394   (save-excursion
 395     (save-restriction
 396       (narrow-to-region start end)
 397       (let ((case-fold-search t)
 398             (alist wl-message-header-button-alist)
 399             entry)
 400         (while alist
 401           (setq entry (car alist)
 402                 alist (cdr alist))
 403           (goto-char (point-min))
 404           (while (re-search-forward (car entry) nil t)
 405             (setq start (match-beginning 0)
 406                   end (if (re-search-forward "^[^ \t]" nil t)
 407                           (match-beginning 0)
 408                         (point-max)))
 409             (goto-char start)
 410             (while (re-search-forward (nth 1 entry) end t)
 411               (wl-message-add-button
 412                (match-beginning (nth 2 entry))
 413                (match-end (nth 2 entry))
 414                (nth 3 entry) (match-string (nth 4 entry))))
 415             (goto-char end)))))))
 416
 417 (defun wl-message-redisplay (folder number flag &optional force-reload)
 418   (let* ((default-mime-charset wl-mime-charset)
 419          (buffer-read-only nil)
 420          (summary-buf (current-buffer))
 421          message-buf
 422          strategy entity
 423          cache-used
 424          summary-win delim)
 425     (setq buffer-read-only nil)
 426     (setq cache-used (wl-message-buffer-display
 427                       folder number flag force-reload))
 428     (setq wl-message-buffer (car cache-used))
 429     (setq message-buf wl-message-buffer)
 430     (wl-message-select-buffer wl-message-buffer)
 431
 432     (set-buffer message-buf)
 433     (make-local-variable 'truncate-partial-width-windows)
 434     (setq truncate-partial-width-windows nil)
 435     (setq truncate-lines wl-message-truncate-lines)
 436     (setq buffer-read-only nil)
 437     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 438     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 439     (setq wl-message-buffer-cur-number number)
 440     (wl-line-formatter-setup
 441      wl-message-buffer-mode-line-formatter
 442      wl-message-mode-line-format
 443      wl-message-mode-line-format-spec-alist)
 444     (setq mode-line-buffer-identification
 445           (funcall wl-message-buffer-mode-line-formatter))
 446     ;; highlight body
 447 ;    (when wl-highlight-body-too
 448 ;      (wl-highlight-body))
 449     (ignore-errors (wl-message-narrow-to-page))
 450     (setq cache-used (cdr cache-used))
 451     (goto-char (point-min))
 452     (when (re-search-forward "^$" nil t)
 453       (wl-message-add-buttons-to-header (point-min) (point))
 454       (wl-message-add-buttons-to-body (point) (point-max)))
 455     (when wl-message-use-header-narrowing
 456       (wl-message-header-narrowing))
 457     (goto-char (point-min))
 458     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 459     ;; go back to summary mode
 460     (set-buffer-modified-p nil)
 461     (setq buffer-read-only t)
 462     (set-buffer summary-buf)
 463     (setq summary-win (get-buffer-window summary-buf))
 464     (if (window-live-p summary-win)
 465         (select-window summary-win))
 466     cache-used))
 467
 468 ;; Use message buffer cache.
 469 (defun wl-message-buffer-display (folder number flag
 470                                          &optional force-reload unread)
 471   (let* ((msg-id (ignore-errors (elmo-message-field folder number
 472                                                     'message-id)))
 473          (fname (elmo-folder-name-internal folder))
 474          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 475          (read nil)
 476          cache-used)
 477     (when (and hit (not (buffer-live-p hit)))
 478       (wl-message-buffer-cache-delete (list fname number msg-id))
 479       (setq hit nil))
 480     (if hit
 481         (progn
 482           ;; move hit to the top.
 483           (wl-message-buffer-cache-sort
 484            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 485           ;; buffer cache is used.
 486           (setq cache-used t)
 487           (with-current-buffer hit
 488             ;; Rewind to the top page
 489             (widen)
 490             (goto-char (point-min))
 491             (ignore-errors (wl-message-narrow-to-page))
 492             (unless (eq wl-message-buffer-cur-flag flag)
 493               (setq read t))))
 494       ;; delete tail and add new to the top.
 495       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 496       (setq read t))
 497     (if (or force-reload read)
 498         (condition-case err
 499             (save-excursion
 500               (set-buffer hit)
 501               (setq
 502                cache-used
 503                (wl-message-display-internal folder number flag
 504                                             force-reload unread))
 505               (setq wl-message-buffer-cur-flag flag))
 506           (quit
 507            (wl-message-buffer-cache-delete)
 508            (error "Display message %s/%s is quitted" fname number))
 509           (error
 510            (wl-message-buffer-cache-delete)
 511            (signal (car err) (cdr err))
 512            nil))) ;; will not be used
 513     (cons hit cache-used)))
 514
 515 (defun wl-message-display-internal (folder number flag
 516                                            &optional force-reload unread)
 517   (let ((default-mime-charset wl-mime-charset)
 518         (elmo-mime-charset wl-mime-charset))
 519     (setq wl-message-buffer-all-header-flag (eq flag 'all-header))
 520     (prog1
 521         (if (eq flag 'as-is)
 522             (let (wl-highlight-x-face-function)
 523               (prog1 (elmo-mime-display-as-is folder number
 524                                               (current-buffer)
 525                                               (wl-message-get-original-buffer)
 526                                               'wl-original-message-mode
 527                                               force-reload
 528                                               unread
 529                                               (wl-message-define-keymap))
 530                 (let (buffer-read-only)
 531                   (wl-highlight-message (point-min) (point-max) t))))
 532           (elmo-mime-message-display folder number
 533                                      (current-buffer)
 534                                      (wl-message-get-original-buffer)
 535                                      'wl-original-message-mode
 536                                      force-reload
 537                                      unread
 538                                      (wl-message-define-keymap)))
 539       (run-hooks 'wl-message-display-internal-hook)
 540       (setq buffer-read-only t))))
 541
 542 (defsubst wl-message-buffer-prefetch-p (folder &optional number)
 543   (and (or (not number)
 544            (elmo-message-file-p folder number)
 545            (let ((size (elmo-message-field folder number 'size)))
 546              (not (and (integerp size)
 547                        wl-message-buffer-prefetch-threshold
 548                        (>= size wl-message-buffer-prefetch-threshold)))))
 549        (or (not number)
 550            (elmo-folder-plugged-p folder)
 551            (elmo-file-cache-exists-p
 552                  (elmo-message-field folder number 'message-id)))
 553        (or (cond
 554             ((eq wl-message-buffer-prefetch-folder-type-list t)
 555              t)
 556             ((and number wl-message-buffer-prefetch-folder-type-list)
 557              (memq (elmo-folder-type-internal
 558                     (elmo-message-folder folder number))
 559                    wl-message-buffer-prefetch-folder-type-list))
 560             (wl-message-buffer-prefetch-folder-type-list
 561              (let ((list wl-message-buffer-prefetch-folder-type-list)
 562                    type)
 563                (catch 'done
 564                  (while (setq type (pop list))
 565                    (if (elmo-folder-contains-type folder type)
 566                        (throw 'done t)))))))
 567            (cond
 568             ((consp wl-message-buffer-prefetch-folder-list)
 569              (wl-string-match-member (elmo-folder-name-internal folder)
 570                                      wl-message-buffer-prefetch-folder-list))
 571             (t wl-message-buffer-prefetch-folder-list)))))
 572
 573 (defsubst wl-message-buffer-prefetch-clear-timer ()
 574 ;;;     cannot use for the bug of fsf-compat package (1.09).
 575 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 576   (if (fboundp 'run-with-idle-timer)
 577       (if (featurep 'xemacs)
 578           (let ((p itimer-list))
 579             (while (car p)
 580               (if (eq 'wl-message-buffer-prefetch-subr
 581                       (itimer-function (car p)))
 582                   (delete-itimer (car p)))
 583               (setq p (cdr p))))
 584         ;; FSF Emacs is correct
 585         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 586
 587 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 588                                                        summary charset)
 589   (if (not (fboundp 'run-with-idle-timer))
 590       (when (sit-for wl-message-buffer-prefetch-idle-time)
 591         (wl-message-buffer-prefetch-subr
 592          folder number count summary charset))
 593     (run-with-idle-timer
 594      wl-message-buffer-prefetch-idle-time
 595      nil
 596      'wl-message-buffer-prefetch-subr
 597      folder number count summary charset)))
 598
 599 (defvar wl-message-buffer-prefetch-move-spec-alist nil)
 600
 601 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 602   (if (buffer-live-p summary)
 603       (with-current-buffer summary
 604         (let ((wl-summary-move-spec-alist
 605                (or wl-message-buffer-prefetch-move-spec-alist
 606                    wl-summary-move-spec-alist))
 607               (next number))
 608           (while (and (setq next (funcall
 609                                   wl-message-buffer-prefetch-get-next-function
 610                                   next))
 611                       (not (wl-message-buffer-prefetch-p folder next))))
 612           next))))
 613
 614 (defun wl-message-buffer-prefetch (folder number count
 615                                           &optional summary charset)
 616   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 617          (num number))
 618     (when (and count
 619                (wl-message-buffer-prefetch-p folder))
 620       (unless (wl-message-buffer-prefetch-p folder number)
 621         (setq num
 622               (wl-message-buffer-prefetch-get-next folder number summary)))
 623       (when num
 624         (wl-message-buffer-prefetch-clear-timer)
 625         (wl-message-buffer-prefetch-set-timer
 626          folder num count summary charset)))))
 627
 628 (defun wl-message-buffer-prefetch-next (folder number count
 629                                                &optional summary charset)
 630   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 631          next)
 632     (when (and count
 633                (wl-message-buffer-prefetch-p folder))
 634       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 635       (when next
 636         (wl-message-buffer-prefetch-clear-timer)
 637         (wl-message-buffer-prefetch-set-timer
 638          folder next count summary charset)))))
 639
 640 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 641   (if (buffer-live-p summary)
 642       (with-current-buffer summary
 643         (if (and number
 644                  (numberp count)
 645                  (>= (setq count (- count 1)) 0)
 646                  (string= (elmo-folder-name-internal folder)
 647                           (wl-summary-buffer-folder-name)))
 648             (let* ((wl-mime-charset      charset)
 649                    (default-mime-charset charset)
 650                    (message-id (elmo-message-field folder number 'message-id))
 651                    (key (list (elmo-folder-name-internal folder)
 652                               number message-id))
 653                    (hit (wl-message-buffer-cache-hit key))
 654                    result time1 time2 sec micro)
 655               (when wl-message-buffer-prefetch-debug
 656                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 657               (if (and hit (buffer-live-p hit))
 658                   (progn
 659                     (wl-message-buffer-cache-sort
 660                      (wl-message-buffer-cache-entry-make key hit))
 661                     (wl-message-buffer-prefetch-subr
 662                      folder
 663                      (wl-message-buffer-prefetch-get-next
 664                       folder number summary)
 665                      count summary charset))
 666                 ;; prefetching
 667                 (when wl-message-buffer-prefetch-debug
 668                   (setq time1 (current-time))
 669                   (message "Prefetching %d..." number))
 670                 (setq result (wl-message-buffer-display
 671                               folder number 'mime nil 'unread))
 672                 (when wl-message-buffer-prefetch-debug
 673                   (setq time2 (current-time))
 674                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 675                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 676                   (setq micro (+ micro (* 1000000 sec)))
 677                   (message "Prefetching %d...done(%f msec)."
 678                            number
 679                            (/ micro 1000.0))
 680                   (sit-for 0))
 681                 ;; set next prefetch
 682                 (wl-message-buffer-prefetch-set-timer
 683                  folder
 684                  (wl-message-buffer-prefetch-get-next
 685                   folder number summary)
 686                  count summary charset)
 687                 (sit-for 0)
 688                 ;; success prefetch
 689                 )))
 690         ;; finish prefetch
 691         (when wl-message-buffer-prefetch-debug
 692           (message "Buffer Cached Messages: %s"
 693                    (mapconcat
 694                     '(lambda (cache)
 695                        (if (numberp (nth 1 (car cache)))
 696                            (if (string=
 697                                 (nth 0 (car cache))
 698                                 (elmo-folder-name-internal folder))
 699                                (format "%d"
 700                                        (nth 1 (car cache)))
 701                              (format "*%d" (nth 1 (car cache))))
 702                          "-"))
 703                     wl-message-buffer-cache " "))) )))
 704
 705 (defvar wl-message-button-map (make-sparse-keymap))
 706
 707 (defun wl-message-add-button (from to function &optional data)
 708   "Create a button between FROM and TO with callback FUNCTION and DATA."
 709   (add-text-properties
 710    from to
 711    (nconc (list 'wl-message-button-callback function)
 712           (if data
 713               (list 'wl-message-button-data data))))
 714   (let ((ov (make-overlay from to)))
 715     (overlay-put ov 'mouse-face 'highlight)
 716     (overlay-put ov 'local-map wl-message-button-map)
 717     (overlay-put ov 'evaporate t)))
 718
 719 (defun wl-message-button-dispatcher (event)
 720   "Select the button under point."
 721   (interactive "@e")
 722   (mouse-set-point event)
 723   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 724         (data (get-text-property (point) 'wl-message-button-data)))
 725     (if callback
 726         (funcall callback data)
 727       (wl-message-button-dispatcher-internal event))))
 728
 729 (defun wl-message-button-refer-article (data)
 730   "Read article specified by Message-ID DATA at point."
 731   (switch-to-buffer-other-window
 732    wl-message-buffer-cur-summary-buffer)
 733   (if (wl-summary-jump-to-msg-by-message-id data)
 734       (wl-summary-redisplay)))
 735
 736 (defun wl-message-uu-substring (buf outbuf &optional first last)
 737   (save-excursion
 738     (set-buffer buf)
 739     (search-forward "\n\n")
 740     (let ((sp (point))
 741           ep filename case-fold-search)
 742       (catch 'done
 743         (if first
 744             (progn
 745               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 746                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 747                 (throw 'done nil)))
 748           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 749         (beginning-of-line)
 750         (setq sp (point))
 751         (goto-char (point-max))
 752         (if last
 753             (re-search-backward "^end" sp t)
 754           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 755         (forward-line 1)
 756         (setq ep (point))
 757         (set-buffer outbuf)
 758         (goto-char (point-max))
 759         (insert-buffer-substring buf sp ep)
 760         (set-buffer buf)
 761         filename))))
 762
 763 ;;; Header narrowing courtesy of Hideyuki Shirai.
 764 (defun wl-message-header-narrowing ()
 765   "Narrowing headers."
 766   (unless (eq this-command 'wl-summary-redisplay-all-header)
 767     (save-excursion
 768       (save-restriction
 769         (goto-char (point-min))
 770         (if (re-search-forward "^$" nil t)
 771             (beginning-of-line)
 772           (goto-char (point-max)))
 773         (narrow-to-region (point-min) (point))
 774         (let ((fields wl-message-header-narrowing-fields))
 775           (while fields
 776             (wl-message-header-narrowing-1 (concat "^" (car fields) ":"))
 777             (setq fields (cdr fields))))))))
 778
 779 (defvar wl-message-header-narrowing-map (make-sparse-keymap))
 780 (define-key wl-message-header-narrowing-map [mouse-2]
 781   'wl-message-header-narrowing-again-at-mouse)
 782
 783 (defvar wl-message-header-narrowing-widen-map (make-sparse-keymap))
 784 (define-key wl-message-header-narrowing-widen-map [mouse-2]
 785   'wl-message-header-narrowing-widen-at-mouse)
 786
 787 (defun wl-message-header-narrowing-again-at-mouse (event)
 788   (interactive "e")
 789   (save-window-excursion
 790     (save-excursion
 791       (mouse-set-point event)
 792       (wl-message-header-narrowing))))
 793
 794 (defun wl-message-header-narrowing-1 (hregexp)
 795   (let ((case-fold-search t)
 796         ov start end)
 797     (goto-char (point-min))
 798     (while (re-search-forward hregexp nil t)
 799       (setq start (match-beginning 0))
 800       (forward-line 1)
 801       (setq end (progn (while (looking-at "^[ \t]") (forward-line))
 802                        (forward-line -1)
 803                        (line-end-position)))
 804       (if (<= (count-lines start end) wl-message-header-narrowing-lines)
 805           (forward-line 1)
 806         (goto-char start)
 807         (forward-line (1- wl-message-header-narrowing-lines))
 808         (end-of-line)
 809         (setq start (point))
 810         (unless (eq (get-char-property start 'invisible)
 811                     'wl-message-header-narrowing)
 812           (setq ov (or
 813                     (let ((ovs (overlays-at start))
 814                           ov)
 815                       (while (and ovs (not (overlayp ov)))
 816                         (if (overlay-get (car ovs)
 817                                          'wl-message-header-narrowing)
 818                             (setq ov (car ovs)))
 819                         (setq ovs (cdr ovs)))
 820                       ov)
 821                     (make-overlay start end)))
 822           (overlay-put ov 'wl-message-header-narrowing t)
 823           (overlay-put ov 'evaporate t)
 824           (overlay-put ov 'invisible 'wl-message-header-narrowing)
 825           (overlay-put ov 'after-string
 826                        wl-message-header-narrowing-string))))))
 827
 828 (defun wl-message-header-narrowing-widen-at-mouse (event)
 829   (interactive "e")
 830   (save-selected-window
 831     (select-window (posn-window (event-start event)))
 832     (let* ((win (selected-window))
 833            (wpos (window-start win))
 834            (pos (posn-point (event-start event)))
 835            (ovs (overlays-in (1- pos) (1+ pos)))        ;; Uum...
 836            ov)
 837       (while (and ovs (not (overlayp ov)))
 838         (when (overlay-get (car ovs) 'wl-message-header-narrowing)
 839           (setq ov (car ovs)))
 840         (setq ovs (cdr ovs)))
 841       (when (overlayp ov)
 842         (overlay-put ov 'face 'wl-message-header-narrowing-face)
 843         (overlay-put ov 'local-map wl-message-header-narrowing-map)
 844         (overlay-put ov 'invisible nil)
 845         (overlay-put ov 'after-string nil))
 846       (set-window-start win wpos))))
 847
 848 (defun wl-message-header-narrowing-setup ()
 849   (when (boundp 'line-move-ignore-invisible)
 850     (set (make-local-variable 'line-move-ignore-invisible) t))
 851   (set-text-properties 0 (length wl-message-header-narrowing-string)
 852                        `(face
 853                          wl-message-header-narrowing-face
 854                          keymap
 855                          ,wl-message-header-narrowing-widen-map)
 856                        wl-message-header-narrowing-string))
 857
 858 (defun wl-message-header-narrowing-toggle ()
 859   "Toggle header narrowing."
 860   (interactive)
 861   (when wl-message-use-header-narrowing
 862     (save-excursion
 863       (goto-char (point-min))
 864       (if (re-search-forward "^$" nil t)
 865           (beginning-of-line)
 866         (goto-char (point-max)))
 867       (let ((ovs (overlays-in (point-min) (point)))
 868             ov hn-ovs)
 869         (while (setq ov (car ovs))
 870           (when (overlay-get ov 'wl-message-header-narrowing)
 871             (setq hn-ovs (cons ov hn-ovs)))
 872           (setq ovs (cdr ovs)))
 873         (if hn-ovs
 874             (while hn-ovs
 875               (delete-overlay (car hn-ovs))
 876               (setq hn-ovs (cdr hn-ovs)))
 877           (wl-message-header-narrowing))))))
 878
 879 (require 'product)
 880 (product-provide (provide 'wl-message) (require 'wl-version))
 881
 882 ;;; wl-message.el ends here