wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36 (require 'timer)
  37
  38 (eval-when-compile
  39   (require 'wl-mime)
  40   (require 'mime-view)
  41   (defalias-maybe 'event-window 'ignore)
  42   (defalias-maybe 'posn-window 'ignore)
  43   (defalias-maybe 'event-start 'ignore)
  44   (defalias-maybe 'mime-open-entity 'ignore)
  45   (defalias-maybe 'itimer-function 'ignore)
  46   (defalias-maybe 'delete-itimer 'ignore)
  47   (defvar-maybe itimer-list))
  48
  49 (defvar wl-message-buffer-prefetch-get-next-function
  50   'wl-summary-default-get-next-msg)
  51
  52 (defvar wl-message-buffer-prefetch-debug nil)
  53 (defvar wl-message-buffer-prefetch-timer nil)
  54
  55 (defvar wl-message-buffer nil) ; message buffer.
  56
  57 (defvar wl-message-buffer-cur-summary-buffer nil)
  58 (defvar wl-message-buffer-cur-folder nil)
  59 (defvar wl-message-buffer-cur-number nil)
  60 (defvar wl-message-buffer-cur-flag nil)
  61 (defvar wl-message-buffer-cur-summary-buffer nil)
  62 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  63 (defvar wl-message-buffer-all-header-flag nil)
  64 (defvar wl-message-buffer-mode-line-formatter nil)
  65
  66 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  67 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-flag)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  70 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  71 (make-variable-buffer-local 'wl-message-buffer-all-header-flag)
  72 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  73
  74 (defvar wl-fixed-window-configuration nil)
  75
  76 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  77
  78 ;;; Message buffer cache.
  79
  80 (defvar wl-message-buffer-cache nil
  81   "Message cache.  (old ... new) order alist.
  82 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  83
  84 (defmacro wl-message-buffer-cache-buffer-get (entry)
  85   (` (cdr (, entry))))
  86
  87 (defmacro wl-message-buffer-cache-folder-get (entry)
  88   (` (car (car (, entry)))))
  89
  90 (defmacro wl-message-buffer-cache-message-get (entry)
  91   (` (cdr (car (, entry)))))
  92
  93 (defmacro wl-message-buffer-cache-entry-make (key buf)
  94   (` (cons (, key) (, buf))))
  95
  96 (defmacro wl-message-buffer-cache-hit (key)
  97   "Return value assosiated with key."
  98   (` (wl-message-buffer-cache-buffer-get
  99       (assoc (, key) wl-message-buffer-cache))))
 100
 101 (defun wl-message-buffer-cache-sort (entry)
 102   "Move ENTRY to the top of `wl-message-buffer-cache'."
 103   (setq wl-message-buffer-cache
 104         (cons entry (delete entry wl-message-buffer-cache))))
 105 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 106 ;        (top pointer))
 107 ;    (while (cdr pointer)
 108 ;      (if (equal (car (cdr pointer)) entry)
 109 ;         (setcdr pointer (cdr (cdr pointer)))
 110 ;       (setq pointer (cdr pointer))))
 111 ;    (setcdr pointer (list entry))
 112 ;    (setq wl-message-buffer-cache (cdr top))))
 113
 114 (defconst wl-original-message-buffer-name " *Original*")
 115
 116 (defun wl-original-message-mode ()
 117   "A major mode for original message buffer."
 118   (setq major-mode 'wl-original-message-mode)
 119   (setq buffer-read-only t)
 120   (elmo-set-buffer-multibyte nil)
 121   (setq mode-name "Wanderlust original message"))
 122
 123 (defun wl-original-message-buffer-get (name)
 124   "Get original message buffer for NAME.
 125 If original message buffer already exists, it is re-used."
 126   (let* ((name (concat wl-original-message-buffer-name name))
 127          (buffer (get-buffer name)))
 128     (unless (and buffer (buffer-live-p buffer))
 129       (with-current-buffer (setq buffer (get-buffer-create name))
 130         (wl-original-message-mode)))
 131     buffer))
 132
 133 (defun wl-message-buffer-create ()
 134   "Create a new message buffer."
 135   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 136          (name (buffer-name buffer)))
 137     (with-current-buffer buffer
 138       (setq wl-message-buffer-original-buffer
 139             (wl-original-message-buffer-get name))
 140       (when wl-message-use-header-narrowing
 141         (wl-message-header-narrowing-setup))
 142       (run-hooks 'wl-message-buffer-created-hook))
 143     buffer))
 144
 145 (defun wl-message-buffer-cache-add (key)
 146   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 147 Return its cache buffer."
 148   (let ((len (length wl-message-buffer-cache))
 149         (buf nil))
 150     (if (< len wl-message-buffer-cache-size)
 151         (setq buf (wl-message-buffer-create))
 152       (let ((entry (nth (1- len) wl-message-buffer-cache)))
 153         (if (buffer-live-p
 154              (setq buf (wl-message-buffer-cache-buffer-get entry)))
 155             (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil)
 156           (setq wl-message-buffer-cache (delq entry wl-message-buffer-cache))
 157           (setq buf (wl-message-buffer-create)))))
 158     (setq wl-message-buffer-cache
 159           (cons (wl-message-buffer-cache-entry-make key buf)
 160                 wl-message-buffer-cache))
 161     buf))
 162
 163 (defun wl-message-buffer-cache-delete (&optional key)
 164   "Delete the most recent cache entry"
 165   (if key
 166       (setq wl-message-buffer-cache
 167             (delq (assoc key wl-message-buffer-cache)
 168                   wl-message-buffer-cache))
 169     (let ((buf (wl-message-buffer-cache-buffer-get
 170                 (car wl-message-buffer-cache))))
 171       (setq wl-message-buffer-cache
 172             (nconc (cdr wl-message-buffer-cache)
 173                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 174
 175 (defun wl-message-buffer-cache-clean-up ()
 176   "A function to flush all decoded messages in cache list."
 177   (interactive)
 178   (if (and (eq major-mode 'wl-summary-mode)
 179            wl-message-buffer
 180            (get-buffer-window wl-message-buffer))
 181       (delete-window (get-buffer-window wl-message-buffer)))
 182   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 183   (setq wl-message-buffer-cache nil))
 184
 185 ;;; Message buffer handling from summary buffer.
 186
 187 (defun wl-message-buffer-window ()
 188   "Get message buffer window if any."
 189   (let* ((start-win (selected-window))
 190          (cur-win start-win))
 191     (catch 'found
 192       (while (progn
 193                (setq cur-win (next-window cur-win))
 194                (with-current-buffer (window-buffer cur-win)
 195                  (if (or (eq major-mode 'wl-message-mode)
 196                          (eq major-mode 'mime-view-mode))
 197                      (throw 'found cur-win)))
 198                (not (eq cur-win start-win)))))))
 199
 200 (defun wl-message-select-buffer (buffer)
 201   "Select BUFFER as a message buffer."
 202   (let ((window (get-buffer-window buffer))
 203         (sum (car wl-message-window-size))
 204         (mes (cdr wl-message-window-size))
 205         whi)
 206     (when (and window
 207                (not (eq (save-excursion (set-buffer (window-buffer window))
 208                                         wl-message-buffer-cur-summary-buffer)
 209                         (current-buffer))))
 210       (delete-window window)
 211       (run-hooks 'wl-message-window-deleted-hook)
 212       (setq window nil))
 213     (if window
 214         (select-window window)
 215       (when wl-fixed-window-configuration
 216         (delete-other-windows)
 217         (and wl-stay-folder-window
 218              (wl-summary-toggle-disp-folder)))
 219       ;; There's no buffer window. Search for message window and snatch it.
 220       (if (setq window (wl-message-buffer-window))
 221           (select-window window)
 222         (setq whi (1- (window-height)))
 223         (if mes
 224             (progn
 225               (let ((total (+ sum mes)))
 226                 (setq sum (max window-min-height (/ (* whi sum) total)))
 227                 (setq mes (max window-min-height (/ (* whi mes) total))))
 228               (if (< whi (+ sum mes))
 229                   (enlarge-window (- (+ sum mes) whi)))))
 230         (split-window (get-buffer-window (current-buffer)) sum)
 231         (other-window 1)))
 232     (switch-to-buffer buffer)))
 233
 234 (defun wl-message-narrow-to-page (&optional arg)
 235   "Narrow to page.
 236 If ARG is specified, narrow to ARGth page."
 237   (interactive "P")
 238   (setq arg (if arg (prefix-numeric-value arg) 0))
 239   (save-excursion
 240     (condition-case ()
 241         (forward-page -1)               ; Beginning of current page.
 242       (beginning-of-buffer
 243        (goto-char (point-min))))
 244     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 245     (widen)
 246     (cond
 247      ((> arg 0) (forward-page arg))
 248      ((< arg 0) (forward-page (1- arg))))
 249     (forward-page)
 250     (if wl-break-pages
 251         (narrow-to-region (point)
 252                           (progn
 253                             (forward-page -1)
 254                             (if (and (eolp) (not (bobp)))
 255                                 (forward-line))
 256                             (point))))))
 257
 258 (defun wl-message-prev-page (&optional lines)
 259   "Scroll down current message by LINES.
 260 Returns non-nil if top of message."
 261   (interactive)
 262   (let (cur-buf top real-top)
 263     (unless (eq major-mode 'mime-view-mode)
 264       (when (buffer-live-p wl-message-buffer)
 265         (setq cur-buf (current-buffer))
 266         (wl-message-select-buffer wl-message-buffer)))
 267     (move-to-window-line 0)
 268     (if (and wl-break-pages
 269              (bobp)
 270              (not (setq real-top (save-restriction (widen) (bobp)))))
 271         (progn
 272           (wl-message-narrow-to-page -1)
 273           (goto-char (point-max))
 274           (recenter))
 275       (if (not (bobp))
 276           (condition-case nil
 277               (scroll-down (or lines wl-message-scroll-amount))
 278             (error))
 279         (setq top t)))
 280     (if real-top
 281         (let ((f (assq (mime-preview-original-major-mode)
 282                        mime-preview-over-to-previous-method-alist)))
 283           (if f (funcall (cdr f))))
 284       (when cur-buf
 285         (select-window (get-buffer-window cur-buf))))
 286     top))
 287
 288 (defun wl-message-next-page (&optional lines)
 289   "Scroll up current message by LINES.
 290 Returns non-nil if bottom of message."
 291   (interactive)
 292   (let (cur-buf bottom)
 293     (unless (eq major-mode 'mime-view-mode)
 294       (when (buffer-live-p wl-message-buffer)
 295         (setq cur-buf (current-buffer))
 296         (wl-message-select-buffer wl-message-buffer)))
 297     (move-to-window-line -1)
 298     (if (save-excursion
 299           (end-of-line)
 300           (and (pos-visible-in-window-p)
 301                (eobp)))
 302         (if (or (null wl-break-pages)
 303                 (save-excursion
 304                   (save-restriction
 305                     (widen) (forward-line) (eobp))))
 306             (setq bottom t)
 307           (wl-message-narrow-to-page 1)
 308           (setq bottom nil))
 309       (condition-case ()
 310           (static-if (boundp 'window-pixel-scroll-increment)
 311               ;; XEmacs 21.2.20 and later.
 312               (let (window-pixel-scroll-increment)
 313                 (scroll-up (or lines wl-message-scroll-amount)))
 314             (scroll-up (or lines wl-message-scroll-amount)))
 315         (end-of-buffer
 316          (goto-char (point-max))))
 317       (setq bottom nil))
 318     (if (eobp)
 319         (let ((f (assq (mime-preview-original-major-mode)
 320                        mime-preview-over-to-next-method-alist)))
 321           (if f (funcall (cdr f))))
 322       (when cur-buf
 323         (select-window (get-buffer-window cur-buf))))
 324     bottom))
 325
 326
 327 (defun wl-message-follow-current-entity (buffer)
 328   "Follow to current message."
 329   (wl-draft-reply (wl-message-get-original-buffer)
 330                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 331   (let ((mail-reply-buffer buffer))
 332     (wl-draft-yank-from-mail-reply-buffer nil)))
 333
 334 ;;
 335
 336 (defun wl-message-mode ()
 337   "A major mode for message displaying."
 338   (interactive)
 339   (setq major-mode 'wl-message-mode)
 340   (setq buffer-read-only t)
 341   (setq mode-name "Message"))
 342
 343 (defun wl-message-exit ()
 344   "Move to summary buffer."
 345   (interactive)
 346   (let (summary-buf summary-win)
 347     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 348         (if (setq summary-win (get-buffer-window summary-buf))
 349             (select-window summary-win)
 350           (switch-to-buffer summary-buf)
 351           (wl-message-select-buffer wl-message-buffer)
 352           (select-window (get-buffer-window summary-buf))))
 353     (run-hooks 'wl-message-exit-hook)))
 354
 355 (defun wl-message-toggle-disp-summary ()
 356   (interactive)
 357   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 358         summary-win)
 359     (if (and summary-buf
 360              (buffer-live-p summary-buf))
 361         (if (setq summary-win (get-buffer-window summary-buf))
 362             (delete-window summary-win)
 363           (switch-to-buffer summary-buf)
 364           (wl-message-select-buffer wl-message-buffer))
 365       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 366                                    nil nil t)
 367                                         ; no summary-buf
 368       (let ((sum-buf (current-buffer)))
 369         (wl-message-select-buffer wl-message-buffer)
 370         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 371
 372 (defun wl-message-get-original-buffer ()
 373   "Get original buffer for current message buffer."
 374   (if (buffer-live-p wl-message-buffer-original-buffer)
 375       wl-message-buffer-original-buffer
 376     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 377
 378 (defun wl-message-add-buttons-to-body (start end)
 379   (save-excursion
 380     (save-restriction
 381       (narrow-to-region start end)
 382       (let ((case-fold-search t)
 383             (alist wl-message-body-button-alist)
 384             entry)
 385         (while alist
 386           (setq entry (car alist)
 387                 alist (cdr alist))
 388           (goto-char (point-min))
 389           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 390             (unless (get-text-property (point) 'keymap)
 391               (wl-message-add-button
 392                (match-beginning (nth 1 entry))
 393                (match-end (nth 1 entry))
 394                (nth 2 entry)
 395                (match-string (nth 3 entry))))))))))
 396
 397 (defun wl-message-add-buttons-to-header (start end)
 398   (save-excursion
 399     (save-restriction
 400       (narrow-to-region start end)
 401       (let ((case-fold-search t)
 402             (alist wl-message-header-button-alist)
 403             entry)
 404         (while alist
 405           (setq entry (car alist)
 406                 alist (cdr alist))
 407           (goto-char (point-min))
 408           (while (re-search-forward (car entry) nil t)
 409             (setq start (match-beginning 0)
 410                   end (if (re-search-forward "^[^ \t]" nil t)
 411                           (match-beginning 0)
 412                         (point-max)))
 413             (goto-char start)
 414             (while (re-search-forward (nth 1 entry) end t)
 415               (wl-message-add-button
 416                (match-beginning (nth 2 entry))
 417                (match-end (nth 2 entry))
 418                (nth 3 entry) (match-string (nth 4 entry))))
 419             (goto-char end)))))))
 420
 421 (defun wl-message-redisplay (folder number flag &optional force-reload)
 422   (let* ((default-mime-charset wl-mime-charset)
 423          (buffer-read-only nil)
 424          (summary-buf (current-buffer))
 425          message-buf
 426          strategy entity
 427          cache-used
 428          summary-win delim)
 429     (setq buffer-read-only nil)
 430     (setq cache-used (wl-message-buffer-display
 431                       folder number flag force-reload))
 432     (setq wl-message-buffer (car cache-used))
 433     (setq message-buf wl-message-buffer)
 434     (wl-message-select-buffer wl-message-buffer)
 435
 436     (set-buffer message-buf)
 437     (make-local-variable 'truncate-partial-width-windows)
 438     (setq truncate-partial-width-windows nil)
 439     (setq truncate-lines wl-message-truncate-lines)
 440     (setq buffer-read-only nil)
 441     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 442     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 443     (setq wl-message-buffer-cur-number number)
 444     (wl-line-formatter-setup
 445      wl-message-buffer-mode-line-formatter
 446      wl-message-mode-line-format
 447      wl-message-mode-line-format-spec-alist)
 448     (setq mode-line-buffer-identification
 449           (funcall wl-message-buffer-mode-line-formatter))
 450     ;; highlight body
 451 ;    (when wl-highlight-body-too
 452 ;      (wl-highlight-body))
 453     (ignore-errors (wl-message-narrow-to-page))
 454     (setq cache-used (cdr cache-used))
 455     (goto-char (point-min))
 456     (when (re-search-forward "^$" nil t)
 457       (wl-message-add-buttons-to-header (point-min) (point))
 458       (wl-message-add-buttons-to-body (point) (point-max)))
 459     (when wl-message-use-header-narrowing
 460       (wl-message-header-narrowing))
 461     (goto-char (point-min))
 462     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 463     ;; go back to summary mode
 464     (set-buffer-modified-p nil)
 465     (setq buffer-read-only t)
 466     (set-buffer summary-buf)
 467     (setq summary-win (get-buffer-window summary-buf))
 468     (if (window-live-p summary-win)
 469         (select-window summary-win))
 470     cache-used))
 471
 472 ;; Use message buffer cache.
 473 (defun wl-message-buffer-display (folder number flag
 474                                          &optional force-reload unread)
 475   (let* ((msg-id (ignore-errors (elmo-message-field folder number
 476                                                     'message-id)))
 477          (fname (elmo-folder-name-internal folder))
 478          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 479          (read nil)
 480          cache-used)
 481     (when (and hit (not (buffer-live-p hit)))
 482       (wl-message-buffer-cache-delete (list fname number msg-id))
 483       (setq hit nil))
 484     (if hit
 485         (progn
 486           ;; move hit to the top.
 487           (wl-message-buffer-cache-sort
 488            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 489           ;; buffer cache is used.
 490           (setq cache-used t)
 491           (with-current-buffer hit
 492             ;; Rewind to the top page
 493             (widen)
 494             (goto-char (point-min))
 495             (ignore-errors (wl-message-narrow-to-page))
 496             (unless (eq wl-message-buffer-cur-flag flag)
 497               (setq read t))))
 498       ;; delete tail and add new to the top.
 499       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 500       (setq read t))
 501     (if (or force-reload read)
 502         (condition-case err
 503             (save-excursion
 504               (set-buffer hit)
 505               (setq
 506                cache-used
 507                (wl-message-display-internal folder number flag
 508                                             force-reload unread))
 509               (setq wl-message-buffer-cur-flag flag))
 510           (quit
 511            (wl-message-buffer-cache-delete)
 512            (error "Display message %s/%s is quitted" fname number))
 513           (error
 514            (wl-message-buffer-cache-delete)
 515            (signal (car err) (cdr err))
 516            nil))) ;; will not be used
 517     (cons hit cache-used)))
 518
 519 (defun wl-message-display-internal (folder number flag
 520                                            &optional force-reload unread)
 521   (let ((default-mime-charset wl-mime-charset)
 522         (elmo-mime-charset wl-mime-charset))
 523     (setq wl-message-buffer-all-header-flag (eq flag 'all-header))
 524     (prog1
 525         (if (eq flag 'as-is)
 526             (let (wl-highlight-x-face-function)
 527               (prog1 (elmo-mime-display-as-is folder number
 528                                               (current-buffer)
 529                                               (wl-message-get-original-buffer)
 530                                               'wl-original-message-mode
 531                                               force-reload
 532                                               unread
 533                                               (wl-message-define-keymap))
 534                 (let (buffer-read-only)
 535                   (wl-highlight-message (point-min) (point-max) t))))
 536           (elmo-mime-message-display folder number
 537                                      (current-buffer)
 538                                      (wl-message-get-original-buffer)
 539                                      'wl-original-message-mode
 540                                      force-reload
 541                                      unread
 542                                      (wl-message-define-keymap)))
 543       (run-hooks 'wl-message-display-internal-hook)
 544       (setq buffer-read-only t))))
 545
 546 (defsubst wl-message-buffer-prefetch-p (folder &optional number)
 547   (and (or (not number)
 548            (elmo-message-file-p folder number)
 549            (let ((size (elmo-message-field folder number 'size)))
 550              (not (and (integerp size)
 551                        wl-message-buffer-prefetch-threshold
 552                        (>= size wl-message-buffer-prefetch-threshold)))))
 553        (or (not number)
 554            (elmo-folder-plugged-p folder)
 555            (elmo-file-cache-exists-p
 556                  (elmo-message-field folder number 'message-id)))
 557        (or (cond
 558             ((eq wl-message-buffer-prefetch-folder-type-list t)
 559              t)
 560             ((and number wl-message-buffer-prefetch-folder-type-list)
 561              (memq (elmo-folder-type-internal
 562                     (elmo-message-folder folder number))
 563                    wl-message-buffer-prefetch-folder-type-list))
 564             (wl-message-buffer-prefetch-folder-type-list
 565              (let ((list wl-message-buffer-prefetch-folder-type-list)
 566                    type)
 567                (catch 'done
 568                  (while (setq type (pop list))
 569                    (if (elmo-folder-contains-type folder type)
 570                        (throw 'done t)))))))
 571            (cond
 572             ((consp wl-message-buffer-prefetch-folder-list)
 573              (wl-string-match-member (elmo-folder-name-internal folder)
 574                                      wl-message-buffer-prefetch-folder-list))
 575             (t wl-message-buffer-prefetch-folder-list)))))
 576
 577 (defsubst wl-message-buffer-prefetch-clear-timer ()
 578 ;;;     cannot use for the bug of fsf-compat package (1.09).
 579 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 580   (if (fboundp 'run-with-idle-timer)
 581       (if (featurep 'xemacs)
 582           (let ((p itimer-list))
 583             (while (car p)
 584               (if (eq 'wl-message-buffer-prefetch-subr
 585                       (itimer-function (car p)))
 586                   (delete-itimer (car p)))
 587               (setq p (cdr p))))
 588         ;; FSF Emacs is correct
 589         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 590
 591 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 592                                                        summary charset)
 593   (if (not (fboundp 'run-with-idle-timer))
 594       (when (sit-for wl-message-buffer-prefetch-idle-time)
 595         (wl-message-buffer-prefetch-subr
 596          folder number count summary charset))
 597     (run-with-idle-timer
 598      wl-message-buffer-prefetch-idle-time
 599      nil
 600      'wl-message-buffer-prefetch-subr
 601      folder number count summary charset)))
 602
 603 (defvar wl-message-buffer-prefetch-move-spec-alist nil)
 604
 605 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 606   (if (buffer-live-p summary)
 607       (with-current-buffer summary
 608         (let ((wl-summary-move-spec-alist
 609                (or wl-message-buffer-prefetch-move-spec-alist
 610                    wl-summary-move-spec-alist))
 611               (next number))
 612           (while (and (setq next (funcall
 613                                   wl-message-buffer-prefetch-get-next-function
 614                                   next))
 615                       (not (wl-message-buffer-prefetch-p folder next))))
 616           next))))
 617
 618 (defun wl-message-buffer-prefetch (folder number count
 619                                           &optional summary charset)
 620   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 621          (num number))
 622     (when (and count
 623                (wl-message-buffer-prefetch-p folder))
 624       (unless (wl-message-buffer-prefetch-p folder number)
 625         (setq num
 626               (wl-message-buffer-prefetch-get-next folder number summary)))
 627       (when num
 628         (wl-message-buffer-prefetch-clear-timer)
 629         (wl-message-buffer-prefetch-set-timer
 630          folder num count summary charset)))))
 631
 632 (defun wl-message-buffer-prefetch-next (folder number count
 633                                                &optional summary charset)
 634   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 635          next)
 636     (when (and count
 637                (wl-message-buffer-prefetch-p folder))
 638       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 639       (when next
 640         (wl-message-buffer-prefetch-clear-timer)
 641         (wl-message-buffer-prefetch-set-timer
 642          folder next count summary charset)))))
 643
 644 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 645   (if (buffer-live-p summary)
 646       (with-current-buffer summary
 647         (if (and number
 648                  (numberp count)
 649                  (>= (setq count (- count 1)) 0)
 650                  (string= (elmo-folder-name-internal folder)
 651                           (wl-summary-buffer-folder-name)))
 652             (let* ((wl-mime-charset      charset)
 653                    (default-mime-charset charset)
 654                    (message-id (elmo-message-field folder number 'message-id))
 655                    (key (list (elmo-folder-name-internal folder)
 656                               number message-id))
 657                    (hit (wl-message-buffer-cache-hit key))
 658                    result time1 time2 sec micro)
 659               (when wl-message-buffer-prefetch-debug
 660                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 661               (if (and hit (buffer-live-p hit))
 662                   (progn
 663                     (wl-message-buffer-cache-sort
 664                      (wl-message-buffer-cache-entry-make key hit))
 665                     (wl-message-buffer-prefetch-subr
 666                      folder
 667                      (wl-message-buffer-prefetch-get-next
 668                       folder number summary)
 669                      count summary charset))
 670                 ;; prefetching
 671                 (when wl-message-buffer-prefetch-debug
 672                   (setq time1 (current-time))
 673                   (message "Prefetching %d..." number))
 674                 (setq result (wl-message-buffer-display
 675                               folder number 'mime nil 'unread))
 676                 (when wl-message-buffer-prefetch-debug
 677                   (setq time2 (current-time))
 678                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 679                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 680                   (setq micro (+ micro (* 1000000 sec)))
 681                   (message "Prefetching %d...done(%f msec)."
 682                            number
 683                            (/ micro 1000.0))
 684                   (sit-for 0))
 685                 ;; set next prefetch
 686                 (wl-message-buffer-prefetch-set-timer
 687                  folder
 688                  (wl-message-buffer-prefetch-get-next
 689                   folder number summary)
 690                  count summary charset)
 691                 (sit-for 0)
 692                 ;; success prefetch
 693                 )))
 694         ;; finish prefetch
 695         (when wl-message-buffer-prefetch-debug
 696           (message "Buffer Cached Messages: %s"
 697                    (mapconcat
 698                     '(lambda (cache)
 699                        (if (numberp (nth 1 (car cache)))
 700                            (if (string=
 701                                 (nth 0 (car cache))
 702                                 (elmo-folder-name-internal folder))
 703                                (format "%d"
 704                                        (nth 1 (car cache)))
 705                              (format "*%d" (nth 1 (car cache))))
 706                          "-"))
 707                     wl-message-buffer-cache " "))) )))
 708
 709 (defvar wl-message-button-map (make-sparse-keymap))
 710
 711 (defun wl-message-add-button (from to function &optional data)
 712   "Create a button between FROM and TO with callback FUNCTION and DATA."
 713   (add-text-properties
 714    from to
 715    (nconc (list 'wl-message-button-callback function)
 716           (if data
 717               (list 'wl-message-button-data data))))
 718   (let ((ov (make-overlay from to)))
 719     (overlay-put ov 'mouse-face 'highlight)
 720     (overlay-put ov 'local-map wl-message-button-map)
 721     (overlay-put ov 'evaporate t)))
 722
 723 (defun wl-message-button-dispatcher (event)
 724   "Select the button under point."
 725   (interactive "@e")
 726   (mouse-set-point event)
 727   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 728         (data (get-text-property (point) 'wl-message-button-data)))
 729     (if callback
 730         (funcall callback data)
 731       (wl-message-button-dispatcher-internal event))))
 732
 733 (defun wl-message-button-refer-article (data)
 734   "Read article specified by Message-ID DATA at point."
 735   (switch-to-buffer-other-window
 736    wl-message-buffer-cur-summary-buffer)
 737   (if (wl-summary-jump-to-msg-by-message-id data)
 738       (wl-summary-redisplay)))
 739
 740 (defun wl-message-uu-substring (buf outbuf &optional first last)
 741   (save-excursion
 742     (set-buffer buf)
 743     (search-forward "\n\n")
 744     (let ((sp (point))
 745           ep filename case-fold-search)
 746       (catch 'done
 747         (if first
 748             (progn
 749               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 750                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 751                 (throw 'done nil)))
 752           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 753         (beginning-of-line)
 754         (setq sp (point))
 755         (goto-char (point-max))
 756         (if last
 757             (re-search-backward "^end" sp t)
 758           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 759         (forward-line 1)
 760         (setq ep (point))
 761         (set-buffer outbuf)
 762         (goto-char (point-max))
 763         (insert-buffer-substring buf sp ep)
 764         (set-buffer buf)
 765         filename))))
 766
 767 ;;; Header narrowing courtesy of Hideyuki Shirai.
 768 (defun wl-message-header-narrowing ()
 769   "Narrowing headers."
 770   (unless (eq this-command 'wl-summary-redisplay-all-header)
 771     (save-excursion
 772       (save-restriction
 773         (goto-char (point-min))
 774         (if (re-search-forward "^$" nil t)
 775             (beginning-of-line)
 776           (goto-char (point-max)))
 777         (narrow-to-region (point-min) (point))
 778         (let ((fields wl-message-header-narrowing-fields))
 779           (while fields
 780             (wl-message-header-narrowing-1 (concat "^" (car fields) ":"))
 781             (setq fields (cdr fields))))))))
 782
 783 (defvar wl-message-header-narrowing-map (make-sparse-keymap))
 784 (define-key wl-message-header-narrowing-map [mouse-2]
 785   'wl-message-header-narrowing-again-at-mouse)
 786
 787 (defvar wl-message-header-narrowing-widen-map (make-sparse-keymap))
 788 (define-key wl-message-header-narrowing-widen-map [mouse-2]
 789   'wl-message-header-narrowing-widen-at-mouse)
 790
 791 (defun wl-message-header-narrowing-again-at-mouse (event)
 792   (interactive "e")
 793   (save-window-excursion
 794     (save-excursion
 795       (mouse-set-point event)
 796       (wl-message-header-narrowing))))
 797
 798 (defun wl-message-header-narrowing-1 (hregexp)
 799   (let ((case-fold-search t)
 800         ov start end)
 801     (goto-char (point-min))
 802     (while (re-search-forward hregexp nil t)
 803       (setq start (match-beginning 0))
 804       (forward-line 1)
 805       (setq end (progn (while (looking-at "^[ \t]") (forward-line))
 806                        (forward-line -1)
 807                        (line-end-position)))
 808       (if (<= (count-lines start end) wl-message-header-narrowing-lines)
 809           (forward-line 1)
 810         (goto-char start)
 811         (forward-line (1- wl-message-header-narrowing-lines))
 812         (end-of-line)
 813         (setq start (point))
 814         (unless (eq (get-char-property start 'invisible)
 815                     'wl-message-header-narrowing)
 816           (setq ov (or
 817                     (let ((ovs (overlays-at start))
 818                           ov)
 819                       (while (and ovs (not (overlayp ov)))
 820                         (if (overlay-get (car ovs)
 821                                          'wl-message-header-narrowing)
 822                             (setq ov (car ovs)))
 823                         (setq ovs (cdr ovs)))
 824                       ov)
 825                     (make-overlay start end)))
 826           (overlay-put ov 'wl-message-header-narrowing t)
 827           (overlay-put ov 'evaporate t)
 828           (overlay-put ov 'invisible 'wl-message-header-narrowing)
 829           (overlay-put ov 'after-string
 830                        wl-message-header-narrowing-string))))))
 831
 832 (defun wl-message-header-narrowing-widen-at-mouse (event)
 833   (interactive "e")
 834   (save-selected-window
 835     (select-window (posn-window (event-start event)))
 836     (let* ((win (selected-window))
 837            (wpos (window-start win))
 838            (pos (posn-point (event-start event)))
 839            (ovs (overlays-in (1- pos) (1+ pos)))        ;; Uum...
 840            ov)
 841       (while (and ovs (not (overlayp ov)))
 842         (when (overlay-get (car ovs) 'wl-message-header-narrowing)
 843           (setq ov (car ovs)))
 844         (setq ovs (cdr ovs)))
 845       (when (overlayp ov)
 846         (overlay-put ov 'face 'wl-message-header-narrowing-face)
 847         (overlay-put ov 'local-map wl-message-header-narrowing-map)
 848         (overlay-put ov 'invisible nil)
 849         (overlay-put ov 'after-string nil))
 850       (set-window-start win wpos))))
 851
 852 (defun wl-message-header-narrowing-setup ()
 853   (when (boundp 'line-move-ignore-invisible)
 854     (set (make-local-variable 'line-move-ignore-invisible) t))
 855   (set-text-properties 0 (length wl-message-header-narrowing-string)
 856                        `(face
 857                          wl-message-header-narrowing-face
 858                          keymap
 859                          ,wl-message-header-narrowing-widen-map)
 860                        wl-message-header-narrowing-string))
 861
 862 (defun wl-message-header-narrowing-toggle ()
 863   "Toggle header narrowing."
 864   (interactive)
 865   (when wl-message-use-header-narrowing
 866     (save-excursion
 867       (goto-char (point-min))
 868       (if (re-search-forward "^$" nil t)
 869           (beginning-of-line)
 870         (goto-char (point-max)))
 871       (let ((ovs (overlays-in (point-min) (point)))
 872             ov hn-ovs)
 873         (while (setq ov (car ovs))
 874           (when (overlay-get ov 'wl-message-header-narrowing)
 875             (setq hn-ovs (cons ov hn-ovs)))
 876           (setq ovs (cdr ovs)))
 877         (if hn-ovs
 878             (while hn-ovs
 879               (delete-overlay (car hn-ovs))
 880               (setq hn-ovs (cdr hn-ovs)))
 881           (wl-message-header-narrowing))))))
 882
 883 (require 'product)
 884 (product-provide (provide 'wl-message) (require 'wl-version))
 885
 886 ;;; wl-message.el ends here