wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36 (require 'timer)
  37
  38 (eval-when-compile
  39   (require 'wl-mime)
  40   (require 'mime-view)
  41   (defalias-maybe 'event-window 'ignore)
  42   (defalias-maybe 'posn-window 'ignore)
  43   (defalias-maybe 'event-start 'ignore)
  44   (defalias-maybe 'mime-open-entity 'ignore)
  45   (defalias-maybe 'itimer-function 'ignore)
  46   (defalias-maybe 'delete-itimer 'ignore)
  47   (defvar-maybe itimer-list))
  48
  49 (defvar wl-message-buffer-prefetch-get-next-function
  50   'wl-summary-default-get-next-msg)
  51
  52 (defvar wl-message-buffer-prefetch-debug nil)
  53 (defvar wl-message-buffer-prefetch-timer nil)
  54
  55 (defvar wl-message-buffer nil) ; message buffer.
  56
  57 (defvar wl-message-buffer-cur-folder nil)
  58 (defvar wl-message-buffer-cur-number nil)
  59 (defvar wl-message-buffer-cur-display-type nil)
  60 (defvar wl-message-buffer-cur-summary-buffer nil)
  61 (defvar wl-message-buffer-require-all-header nil)
  62 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  63 (defvar wl-message-buffer-mode-line-formatter nil)
  64 (defvar wl-message-buffer-flag-indicator nil)
  65
  66 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  67 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-display-type)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  70 (make-variable-buffer-local 'wl-message-buffer-require-all-header)
  71 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  72 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  73 (make-variable-buffer-local 'wl-message-buffer-flag-indicator)
  74
  75 (defvar wl-fixed-window-configuration nil)
  76
  77 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  78
  79 ;;; Message buffer cache.
  80
  81 (defvar wl-message-buffer-cache nil
  82   "Message cache.  (old ... new) order alist.
  83 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  84
  85 (defmacro wl-message-buffer-cache-buffer-get (entry)
  86   (` (cdr (, entry))))
  87
  88 (defmacro wl-message-buffer-cache-folder-get (entry)
  89   (` (car (car (, entry)))))
  90
  91 (defmacro wl-message-buffer-cache-message-get (entry)
  92   (` (cdr (car (, entry)))))
  93
  94 (defmacro wl-message-buffer-cache-entry-make (key buf)
  95   (` (cons (, key) (, buf))))
  96
  97 (defmacro wl-message-buffer-cache-hit (key)
  98   "Return value assosiated with key."
  99   (` (wl-message-buffer-cache-buffer-get
 100       (assoc (, key) wl-message-buffer-cache))))
 101
 102 (defun wl-message-buffer-cache-sort (entry)
 103   "Move ENTRY to the top of `wl-message-buffer-cache'."
 104   (setq wl-message-buffer-cache
 105         (cons entry (delete entry wl-message-buffer-cache))))
 106 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 107 ;        (top pointer))
 108 ;    (while (cdr pointer)
 109 ;      (if (equal (car (cdr pointer)) entry)
 110 ;         (setcdr pointer (cdr (cdr pointer)))
 111 ;       (setq pointer (cdr pointer))))
 112 ;    (setcdr pointer (list entry))
 113 ;    (setq wl-message-buffer-cache (cdr top))))
 114
 115 (defconst wl-original-message-buffer-name " *Original*")
 116
 117 (defun wl-original-message-mode ()
 118   "A major mode for original message buffer."
 119   (setq major-mode 'wl-original-message-mode)
 120   (setq buffer-read-only t)
 121   (set-buffer-multibyte nil)
 122   (setq mode-name "Wanderlust original message"))
 123
 124 (defun wl-original-message-buffer-get (name)
 125   "Get original message buffer for NAME.
 126 If original message buffer already exists, it is re-used."
 127   (let* ((name (concat wl-original-message-buffer-name name))
 128          (buffer (get-buffer name)))
 129     (unless (and buffer (buffer-live-p buffer))
 130       (with-current-buffer (setq buffer (get-buffer-create name))
 131         (wl-original-message-mode)))
 132     buffer))
 133
 134 (defun wl-message-buffer-create ()
 135   "Create a new message buffer."
 136   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 137          (name (buffer-name buffer)))
 138     (with-current-buffer buffer
 139       (setq wl-message-buffer-original-buffer
 140             (wl-original-message-buffer-get name))
 141       (when wl-message-use-header-narrowing
 142         (wl-message-header-narrowing-setup))
 143       (run-hooks 'wl-message-buffer-created-hook))
 144     buffer))
 145
 146 (defun wl-message-buffer-cache-add (key)
 147   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 148 Return its cache buffer."
 149   (let ((len (length wl-message-buffer-cache))
 150         (buf nil))
 151     (if (< len wl-message-buffer-cache-size)
 152         (setq buf (wl-message-buffer-create))
 153       (let ((entry (nth (1- len) wl-message-buffer-cache)))
 154         (if (buffer-live-p
 155              (setq buf (wl-message-buffer-cache-buffer-get entry)))
 156             (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil)
 157           (setq wl-message-buffer-cache (delq entry wl-message-buffer-cache))
 158           (setq buf (wl-message-buffer-create)))))
 159     (setq wl-message-buffer-cache
 160           (cons (wl-message-buffer-cache-entry-make key buf)
 161                 wl-message-buffer-cache))
 162     buf))
 163
 164 (defun wl-message-buffer-cache-delete (&optional key)
 165   "Delete the most recent cache entry"
 166   (if key
 167       (setq wl-message-buffer-cache
 168             (delq (assoc key wl-message-buffer-cache)
 169                   wl-message-buffer-cache))
 170     (let ((buf (wl-message-buffer-cache-buffer-get
 171                 (car wl-message-buffer-cache))))
 172       (setq wl-message-buffer-cache
 173             (nconc (cdr wl-message-buffer-cache)
 174                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 175
 176 (defun wl-message-buffer-cache-clean-up ()
 177   "A function to flush all decoded messages in cache list."
 178   (interactive)
 179   (if (and (eq major-mode 'wl-summary-mode)
 180            wl-message-buffer
 181            (get-buffer-window wl-message-buffer))
 182       (delete-window (get-buffer-window wl-message-buffer)))
 183   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 184   (setq wl-message-buffer-cache nil))
 185
 186 ;;; Message buffer handling from summary buffer.
 187
 188 (defun wl-message-buffer-window ()
 189   "Get message buffer window if any."
 190   (let* ((start-win (selected-window))
 191          (cur-win start-win))
 192     (catch 'found
 193       (while (progn
 194                (setq cur-win (next-window cur-win))
 195                (with-current-buffer (window-buffer cur-win)
 196                  (if (or (eq major-mode 'wl-message-mode)
 197                          (eq major-mode 'mime-view-mode))
 198                      (throw 'found cur-win)))
 199                (not (eq cur-win start-win)))))))
 200
 201 (defun wl-message-select-buffer (buffer)
 202   "Select BUFFER as a message buffer."
 203   (let ((window (get-buffer-window buffer))
 204         (sum (car wl-message-window-size))
 205         (mes (cdr wl-message-window-size))
 206         whi)
 207     (when (and window
 208                (not (eq (save-excursion (set-buffer (window-buffer window))
 209                                         wl-message-buffer-cur-summary-buffer)
 210                         (current-buffer))))
 211       (delete-window window)
 212       (run-hooks 'wl-message-window-deleted-hook)
 213       (setq window nil))
 214     (if window
 215         (select-window window)
 216       (when wl-fixed-window-configuration
 217         (delete-other-windows)
 218         (and wl-stay-folder-window
 219              (wl-summary-toggle-disp-folder)))
 220       ;; There's no buffer window. Search for message window and snatch it.
 221       (if (setq window (wl-message-buffer-window))
 222           (select-window window)
 223         (setq whi (1- (window-height)))
 224         (if mes
 225             (progn
 226               (let ((total (+ sum mes)))
 227                 (setq sum (max window-min-height (/ (* whi sum) total)))
 228                 (setq mes (max window-min-height (/ (* whi mes) total))))
 229               (if (< whi (+ sum mes))
 230                   (enlarge-window (- (+ sum mes) whi)))))
 231         (split-window (get-buffer-window (current-buffer)) sum)
 232         (other-window 1)))
 233     (switch-to-buffer buffer)))
 234
 235 (defun wl-message-narrow-to-page (&optional arg)
 236   "Narrow to page.
 237 If ARG is specified, narrow to ARGth page."
 238   (interactive "P")
 239   (setq arg (if arg (prefix-numeric-value arg) 0))
 240   (save-excursion
 241     (condition-case ()
 242         (forward-page -1)               ; Beginning of current page.
 243       (beginning-of-buffer
 244        (goto-char (point-min))))
 245     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 246     (widen)
 247     (cond
 248      ((> arg 0) (forward-page arg))
 249      ((< arg 0) (forward-page (1- arg))))
 250     (forward-page)
 251     (if wl-break-pages
 252         (narrow-to-region (point)
 253                           (progn
 254                             (forward-page -1)
 255                             (if (and (eolp) (not (bobp)))
 256                                 (forward-line))
 257                             (point))))))
 258
 259 (defun wl-message-prev-page (&optional lines)
 260   "Scroll down current message by LINES.
 261 Returns non-nil if top of message."
 262   (interactive)
 263   (let (top real-top)
 264     (save-selected-window
 265       (unless (eq major-mode 'mime-view-mode)
 266         (when (buffer-live-p wl-message-buffer)
 267           (wl-message-select-buffer wl-message-buffer)))
 268       (move-to-window-line 0)
 269       (if (and wl-break-pages
 270                (bobp)
 271                (not (setq real-top (save-restriction (widen) (bobp)))))
 272           (progn
 273             (wl-message-narrow-to-page -1)
 274             (goto-char (point-max))
 275             (recenter))
 276         (if (not (bobp))
 277             (condition-case nil
 278                 (scroll-down (or lines wl-message-scroll-amount))
 279               (error))
 280           (setq top t)))
 281       (if real-top
 282           (let ((f (assq (mime-preview-original-major-mode)
 283                          mime-preview-over-to-previous-method-alist)))
 284             (if f (funcall (cdr f))))))
 285     top))
 286
 287 (defun wl-message-next-page (&optional lines)
 288   "Scroll up current message by LINES.
 289 Returns non-nil if bottom of message."
 290   (interactive)
 291   (let (bottom)
 292     (save-selected-window
 293       (unless (eq major-mode 'mime-view-mode)
 294         (when (buffer-live-p wl-message-buffer)
 295           (wl-message-select-buffer wl-message-buffer)))
 296       (move-to-window-line -1)
 297       (if (save-excursion
 298             (end-of-line)
 299             (and (pos-visible-in-window-p)
 300                  (eobp)))
 301           (if (or (null wl-break-pages)
 302                   (save-excursion
 303                     (save-restriction
 304                       (widen) (forward-line) (eobp))))
 305               (setq bottom t)
 306             (wl-message-narrow-to-page 1)
 307             (setq bottom nil))
 308         (condition-case ()
 309             (static-if (boundp 'window-pixel-scroll-increment)
 310                 ;; XEmacs 21.2.20 and later.
 311                 (let (window-pixel-scroll-increment)
 312                   (scroll-up (or lines wl-message-scroll-amount)))
 313               (scroll-up (or lines wl-message-scroll-amount)))
 314           (end-of-buffer
 315            (goto-char (point-max))))
 316         (setq bottom nil))
 317       (if (eobp)
 318           (let ((f (assq (mime-preview-original-major-mode)
 319                          mime-preview-over-to-next-method-alist)))
 320             (if f (funcall (cdr f))))))
 321     bottom))
 322
 323
 324 (defun wl-message-follow-current-entity (buffer)
 325   "Follow to current message."
 326   (wl-draft-reply (wl-message-get-original-buffer)
 327                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 328   (let ((mail-reply-buffer buffer))
 329     (wl-draft-yank-from-mail-reply-buffer nil)))
 330
 331 ;;
 332
 333 (defun wl-message-mode ()
 334   "A major mode for message displaying."
 335   (interactive)
 336   (setq major-mode 'wl-message-mode)
 337   (setq buffer-read-only t)
 338   (setq mode-name "Message"))
 339
 340 (defun wl-message-exit ()
 341   "Move to summary buffer or mother buffer."
 342   (interactive)
 343   (let (summary-buf summary-win mother-buffer)
 344     (cond ((setq summary-buf wl-message-buffer-cur-summary-buffer)
 345            (if (setq summary-win (get-buffer-window summary-buf))
 346                (select-window summary-win)
 347              (switch-to-buffer summary-buf)
 348              (wl-message-select-buffer wl-message-buffer)
 349              (select-window (get-buffer-window summary-buf))))
 350           ((setq mother-buffer mime-mother-buffer)
 351            (kill-buffer (current-buffer))
 352            (switch-to-buffer mother-buffer)))
 353     (run-hooks 'wl-message-exit-hook)))
 354
 355 (defun wl-message-toggle-disp-summary ()
 356   (interactive)
 357   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 358         summary-win)
 359     (if (and summary-buf
 360              (buffer-live-p summary-buf))
 361         (if (setq summary-win (get-buffer-window summary-buf))
 362             (delete-window summary-win)
 363           (switch-to-buffer summary-buf)
 364           (wl-message-select-buffer wl-message-buffer))
 365       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 366                                    nil nil t)
 367                                         ; no summary-buf
 368       (let ((sum-buf (current-buffer)))
 369         (wl-message-select-buffer wl-message-buffer)
 370         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 371
 372 (defun wl-message-get-original-buffer ()
 373   "Get original buffer for current message buffer."
 374   (if (buffer-live-p wl-message-buffer-original-buffer)
 375       wl-message-buffer-original-buffer
 376     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 377
 378 (defun wl-message-add-buttons-to-body (start end)
 379   (save-excursion
 380     (save-restriction
 381       (narrow-to-region start end)
 382       (let ((case-fold-search t)
 383             (alist wl-message-body-button-alist)
 384             entry)
 385         (while alist
 386           (setq entry (car alist)
 387                 alist (cdr alist))
 388           (goto-char (point-min))
 389           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 390             (unless (get-text-property (point) 'keymap)
 391               (wl-message-add-button
 392                (match-beginning (nth 1 entry))
 393                (match-end (nth 1 entry))
 394                (nth 2 entry)
 395                (match-string (nth 3 entry))))))))))
 396
 397 (defun wl-message-add-buttons-to-header (start end)
 398   (save-excursion
 399     (save-restriction
 400       (narrow-to-region start end)
 401       (let ((case-fold-search t)
 402             (alist wl-message-header-button-alist)
 403             entry)
 404         (while alist
 405           (setq entry (car alist)
 406                 alist (cdr alist))
 407           (goto-char (point-min))
 408           (while (re-search-forward (car entry) nil t)
 409             (setq start (match-beginning 0)
 410                   end (if (re-search-forward "^[^ \t]" nil t)
 411                           (match-beginning 0)
 412                         (point-max)))
 413             (goto-char start)
 414             (while (re-search-forward (nth 1 entry) end t)
 415               (wl-message-add-button
 416                (match-beginning (nth 2 entry))
 417                (match-end (nth 2 entry))
 418                (nth 3 entry) (match-string (nth 4 entry))))
 419             (goto-char end)))))))
 420
 421 (defun wl-message-redisplay (folder number as-is all-header
 422                                     &optional force-reload)
 423   (let* ((default-mime-charset wl-mime-charset)
 424          (buffer-read-only nil)
 425          (summary-buf (current-buffer))
 426          message-buf
 427          strategy entity
 428          cache-used
 429          summary-win delim flags)
 430     (setq buffer-read-only nil)
 431     (setq cache-used (wl-message-buffer-display
 432                       folder number as-is all-header force-reload))
 433     (setq wl-message-buffer (car cache-used))
 434     (setq message-buf wl-message-buffer)
 435     (wl-message-select-buffer wl-message-buffer)
 436
 437     (set-buffer message-buf)
 438     (wl-deactivate-region)
 439     (make-local-variable 'truncate-partial-width-windows)
 440     (setq truncate-partial-width-windows nil)
 441     (setq truncate-lines wl-message-truncate-lines)
 442     (setq buffer-read-only nil)
 443     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 444     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 445     (setq wl-message-buffer-cur-number number)
 446     (setq wl-message-buffer-flag-indicator
 447           (if (setq flags (elmo-get-global-flags (elmo-message-flags
 448                                                   folder number)))
 449               (let ((fl wl-summary-flag-alist)
 450                     flag-strings flag-string face)
 451                 (while fl
 452                   (when (memq (car (car fl)) flags)
 453                     (setq flag-string (capitalize
 454                                        (symbol-name (car (car fl))))
 455                           flags (delq (car (car fl)) flags))
 456                     (when (facep (setq face
 457                                        (intern
 458                                         (format
 459                                          "wl-highlight-summary-%s-flag-face"
 460                                          (car (car fl))))))
 461                       (put-text-property 0 (length flag-string)
 462                                          'face face flag-string))
 463                     (setq flag-strings (nconc flag-strings
 464                                               (list flag-string))))
 465                   (setq fl (cdr fl)))
 466                 (setq flag-strings
 467                       (nconc flag-strings
 468                              (mapcar (lambda (flag)
 469                                        (capitalize (symbol-name flag)))
 470                                      flags)))
 471                 (concat " (" (mapconcat 'identity flag-strings ", ") ")"))
 472             ""))
 473     (wl-line-formatter-setup
 474      wl-message-buffer-mode-line-formatter
 475      wl-message-mode-line-format
 476      wl-message-mode-line-format-spec-alist)
 477     (setq mode-line-buffer-identification
 478           (funcall wl-message-buffer-mode-line-formatter))
 479     ;; highlight body
 480 ;    (when wl-highlight-body-too
 481 ;      (wl-highlight-body))
 482     (ignore-errors (wl-message-narrow-to-page))
 483     (setq cache-used (cdr cache-used))
 484     (goto-char (point-min))
 485     (when (re-search-forward "^$" nil t)
 486       (wl-message-add-buttons-to-header (point-min) (point))
 487       (wl-message-add-buttons-to-body (point) (point-max)))
 488     (when (and wl-message-use-header-narrowing
 489                (not all-header))
 490       (wl-message-header-narrowing))
 491     (goto-char (point-min))
 492     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 493     ;; go back to summary mode
 494     (set-buffer-modified-p nil)
 495     (setq buffer-read-only t)
 496     (set-buffer summary-buf)
 497     (setq summary-win (get-buffer-window summary-buf))
 498     (if (window-live-p summary-win)
 499         (select-window summary-win))
 500     cache-used))
 501
 502 (defun wl-message-buffer-display-type (mode all-header)
 503   (let ((type (symbol-name mode)))
 504     (when all-header (setq type (concat type "-all-header")))
 505     (intern type)))
 506
 507 ;; Use message buffer cache.
 508 (defun wl-message-buffer-display (folder number mode all-header
 509                                          &optional force-reload unread)
 510   (let* ((msg-id (ignore-errors (elmo-message-field folder number
 511                                                     'message-id)))
 512          (fname (elmo-folder-name-internal folder))
 513          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 514          (read nil)
 515          cache-used)
 516     (when (and hit (not (buffer-live-p hit)))
 517       (wl-message-buffer-cache-delete (list fname number msg-id))
 518       (setq hit nil))
 519     (if hit
 520         (progn
 521           ;; move hit to the top.
 522           (wl-message-buffer-cache-sort
 523            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 524           ;; buffer cache is used.
 525           (setq cache-used t)
 526           (with-current-buffer hit
 527             ;; Rewind to the top page
 528             (widen)
 529             (goto-char (point-min))
 530             (ignore-errors (wl-message-narrow-to-page))
 531             (unless (eq wl-message-buffer-cur-display-type
 532                         (wl-message-buffer-display-type mode all-header))
 533               (setq read t))))
 534       ;; delete tail and add new to the top.
 535       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 536       (setq read t))
 537     (if (or force-reload read)
 538         (condition-case err
 539             (save-excursion
 540               (set-buffer hit)
 541               (setq
 542                cache-used
 543                (wl-message-display-internal folder number mode all-header
 544                                             force-reload unread))
 545               (setq wl-message-buffer-cur-display-type
 546                     (wl-message-buffer-display-type mode all-header)))
 547           (quit
 548            (wl-message-buffer-cache-delete)
 549            (error "Display message %s/%s is quitted" fname number))
 550           (error
 551            (wl-message-buffer-cache-delete)
 552            (signal (car err) (cdr err))
 553            nil))) ;; will not be used
 554     (cons hit cache-used)))
 555
 556 (defun wl-message-display-internal (folder number mode all-header
 557                                            &optional force-reload unread)
 558   (let ((default-mime-charset wl-mime-charset)
 559         (elmo-mime-charset wl-mime-charset))
 560     (setq wl-message-buffer-require-all-header all-header)
 561     (prog1
 562         (if (or (eq mode 'as-is)
 563                 (eq mode 'header-only))
 564             (let ((elmo-mime-display-header-analysis (eq mode 'header-only))
 565                   (wl-highlight-x-face-function
 566                    (unless (eq mode 'as-is) wl-highlight-x-face-function)))
 567               (prog1 (elmo-mime-display-as-is folder number
 568                                               (current-buffer)
 569                                               (wl-message-get-original-buffer)
 570                                               'wl-original-message-mode
 571                                               force-reload
 572                                               unread
 573                                               (wl-message-define-keymap))
 574                 (let (buffer-read-only)
 575                   (wl-highlight-message (point-min) (point-max) t))))
 576           (elmo-mime-message-display folder number
 577                                      (current-buffer)
 578                                      (wl-message-get-original-buffer)
 579                                      'wl-original-message-mode
 580                                      force-reload
 581                                      unread
 582                                      (wl-message-define-keymap)))
 583       (let (buffer-read-only)
 584         (put-text-property (point-min) (point-max)
 585                            'wl-message-display-mime-mode mode))
 586       (run-hooks 'wl-message-display-internal-hook)
 587       (setq buffer-read-only t))))
 588
 589 (defun wl-message-buffer-prefetch-p (folder &optional number)
 590   (and (or (not number)
 591            (elmo-message-file-p folder number)
 592            (let ((size (elmo-message-field folder number 'size)))
 593              (not (and (integerp size)
 594                        wl-message-buffer-prefetch-threshold
 595                        (>= size wl-message-buffer-prefetch-threshold)))))
 596        (or (not number)
 597            (elmo-folder-plugged-p folder)
 598            (elmo-file-cache-exists-p
 599                  (elmo-message-field folder number 'message-id)))
 600        (or (cond
 601             ((eq wl-message-buffer-prefetch-folder-type-list t)
 602              t)
 603             ((and number wl-message-buffer-prefetch-folder-type-list)
 604              (memq (elmo-folder-type-internal
 605                     (elmo-message-folder folder number))
 606                    wl-message-buffer-prefetch-folder-type-list))
 607             (wl-message-buffer-prefetch-folder-type-list
 608              (let ((list wl-message-buffer-prefetch-folder-type-list)
 609                    type)
 610                (catch 'done
 611                  (while (setq type (pop list))
 612                    (if (elmo-folder-contains-type folder type)
 613                        (throw 'done t)))))))
 614            (cond
 615             ((consp wl-message-buffer-prefetch-folder-list)
 616              (wl-string-match-member (elmo-folder-name-internal folder)
 617                                      wl-message-buffer-prefetch-folder-list))
 618             (t wl-message-buffer-prefetch-folder-list)))))
 619
 620 (defsubst wl-message-buffer-prefetch-clear-timer ()
 621 ;;;     cannot use for the bug of fsf-compat package (1.09).
 622 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 623   (if (fboundp 'run-with-idle-timer)
 624       (if (featurep 'xemacs)
 625           (let ((p itimer-list))
 626             (while (car p)
 627               (if (eq 'wl-message-buffer-prefetch-subr
 628                       (itimer-function (car p)))
 629                   (delete-itimer (car p)))
 630               (setq p (cdr p))))
 631         ;; FSF Emacs is correct
 632         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 633
 634 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 635                                                        summary charset)
 636   (if (not (fboundp 'run-with-idle-timer))
 637       (when (sit-for wl-message-buffer-prefetch-idle-time)
 638         (wl-message-buffer-prefetch-subr
 639          folder number count summary charset))
 640     (run-with-idle-timer
 641      wl-message-buffer-prefetch-idle-time
 642      nil
 643      'wl-message-buffer-prefetch-subr
 644      folder number count summary charset)))
 645
 646 (defvar wl-message-buffer-prefetch-move-spec-alist nil)
 647
 648 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 649   (if (buffer-live-p summary)
 650       (with-current-buffer summary
 651         (let ((wl-summary-move-spec-alist
 652                (or wl-message-buffer-prefetch-move-spec-alist
 653                    wl-summary-move-spec-alist))
 654               (next number))
 655           (while (and (setq next (funcall
 656                                   wl-message-buffer-prefetch-get-next-function
 657                                   next))
 658                       (not (wl-message-buffer-prefetch-p folder next))))
 659           next))))
 660
 661 (defun wl-message-buffer-prefetch (folder number count
 662                                           &optional summary charset)
 663   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 664          (num number))
 665     (when (and count
 666                (wl-message-buffer-prefetch-p folder))
 667       (unless (wl-message-buffer-prefetch-p folder number)
 668         (setq num
 669               (wl-message-buffer-prefetch-get-next folder number summary)))
 670       (when num
 671         (wl-message-buffer-prefetch-clear-timer)
 672         (wl-message-buffer-prefetch-set-timer
 673          folder num count summary charset)))))
 674
 675 (defun wl-message-buffer-prefetch-next (folder number count
 676                                                &optional summary charset)
 677   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 678          next)
 679     (when (and count
 680                (wl-message-buffer-prefetch-p folder))
 681       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 682       (when next
 683         (wl-message-buffer-prefetch-clear-timer)
 684         (wl-message-buffer-prefetch-set-timer
 685          folder next count summary charset)))))
 686
 687 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 688   (if (buffer-live-p summary)
 689       (with-current-buffer summary
 690         (if (and number
 691                  (numberp count)
 692                  (>= (setq count (- count 1)) 0)
 693                  (string= (elmo-folder-name-internal folder)
 694                           (wl-summary-buffer-folder-name)))
 695             (let* ((wl-mime-charset      charset)
 696                    (default-mime-charset charset)
 697                    (message-id (elmo-message-field folder number 'message-id))
 698                    (key (list (elmo-folder-name-internal folder)
 699                               number message-id))
 700                    (hit (wl-message-buffer-cache-hit key))
 701                    result time1 time2 sec micro)
 702               (when wl-message-buffer-prefetch-debug
 703                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 704               (if (and hit (buffer-live-p hit))
 705                   (progn
 706                     (wl-message-buffer-cache-sort
 707                      (wl-message-buffer-cache-entry-make key hit))
 708                     (wl-message-buffer-prefetch-subr
 709                      folder
 710                      (wl-message-buffer-prefetch-get-next
 711                       folder number summary)
 712                      count summary charset))
 713                 ;; prefetching
 714                 (when wl-message-buffer-prefetch-debug
 715                   (setq time1 (current-time))
 716                   (message "Prefetching %d..." number))
 717                 (setq result (wl-message-buffer-display
 718                               folder number 'mime nil 'unread))
 719                 (when wl-message-buffer-prefetch-debug
 720                   (setq time2 (current-time))
 721                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 722                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 723                   (setq micro (+ micro (* 1000000 sec)))
 724                   (message "Prefetching %d...done(%f msec)."
 725                            number
 726                            (/ micro 1000.0))
 727                   (sit-for 0))
 728                 ;; set next prefetch
 729                 (wl-message-buffer-prefetch-set-timer
 730                  folder
 731                  (wl-message-buffer-prefetch-get-next
 732                   folder number summary)
 733                  count summary charset)
 734                 (sit-for 0)
 735                 ;; success prefetch
 736                 )))
 737         ;; finish prefetch
 738         (when wl-message-buffer-prefetch-debug
 739           (message "Buffer Cached Messages: %s"
 740                    (mapconcat
 741                     '(lambda (cache)
 742                        (if (numberp (nth 1 (car cache)))
 743                            (if (string=
 744                                 (nth 0 (car cache))
 745                                 (elmo-folder-name-internal folder))
 746                                (format "%d"
 747                                        (nth 1 (car cache)))
 748                              (format "*%d" (nth 1 (car cache))))
 749                          "-"))
 750                     wl-message-buffer-cache " "))) )))
 751
 752 (defvar wl-message-button-map (make-sparse-keymap))
 753
 754 (defun wl-message-add-button (from to function &optional data)
 755   "Create a button between FROM and TO with callback FUNCTION and DATA."
 756   (add-text-properties
 757    from to
 758    (nconc (list 'wl-message-button-callback function)
 759           (if data
 760               (list 'wl-message-button-data data))))
 761   (let ((ov (make-overlay from to)))
 762     (overlay-put ov 'mouse-face 'highlight)
 763     (overlay-put ov 'local-map wl-message-button-map)
 764     (overlay-put ov 'evaporate t)))
 765
 766 (defun wl-message-button-dispatcher (event)
 767   "Select the button under point."
 768   (interactive "@e")
 769   (mouse-set-point event)
 770   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 771         (data (get-text-property (point) 'wl-message-button-data)))
 772     (if callback
 773         (funcall callback data)
 774       (wl-message-button-dispatcher-internal event))))
 775
 776 (defun wl-message-button-refer-article (data)
 777   "Read article specified by Message-ID DATA at point."
 778   (switch-to-buffer-other-window
 779    wl-message-buffer-cur-summary-buffer)
 780   (if (wl-summary-jump-to-msg-by-message-id data)
 781       (wl-summary-redisplay)))
 782
 783 (defun wl-message-uu-substring (buf outbuf &optional first last)
 784   (save-excursion
 785     (set-buffer buf)
 786     (search-forward "\n\n")
 787     (let ((sp (point))
 788           ep filename case-fold-search)
 789       (catch 'done
 790         (if first
 791             (progn
 792               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 793                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 794                 (throw 'done nil)))
 795           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 796         (beginning-of-line)
 797         (setq sp (point))
 798         (goto-char (point-max))
 799         (if last
 800             (re-search-backward "^end" sp t)
 801           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 802         (forward-line 1)
 803         (setq ep (point))
 804         (set-buffer outbuf)
 805         (goto-char (point-max))
 806         (insert-buffer-substring buf sp ep)
 807         (set-buffer buf)
 808         filename))))
 809
 810 ;;; Header narrowing courtesy of Hideyuki Shirai.
 811 (defun wl-message-header-narrowing ()
 812   "Narrowing headers."
 813   (unless (eq this-command 'wl-summary-redisplay-all-header)
 814     (save-excursion
 815       (save-restriction
 816         (goto-char (point-min))
 817         (if (re-search-forward "^$" nil t)
 818             (beginning-of-line)
 819           (goto-char (point-max)))
 820         (narrow-to-region (point-min) (point))
 821         (let ((fields wl-message-header-narrowing-fields))
 822           (while fields
 823             (wl-message-header-narrowing-1 (concat "^" (car fields) ":"))
 824             (setq fields (cdr fields))))))))
 825
 826 (defvar wl-message-header-narrowing-map (make-sparse-keymap))
 827 (define-key wl-message-header-narrowing-map [mouse-2]
 828   'wl-message-header-narrowing-again-at-mouse)
 829
 830 (defvar wl-message-header-narrowing-widen-map (make-sparse-keymap))
 831 (define-key wl-message-header-narrowing-widen-map [mouse-2]
 832   'wl-message-header-narrowing-widen-at-mouse)
 833
 834 (defun wl-message-header-narrowing-again-at-mouse (event)
 835   (interactive "e")
 836   (save-window-excursion
 837     (save-excursion
 838       (mouse-set-point event)
 839       (wl-message-header-narrowing))))
 840
 841 (defun wl-message-header-narrowing-1 (hregexp)
 842   (let ((case-fold-search t)
 843         ov start end)
 844     (goto-char (point-min))
 845     (while (re-search-forward hregexp nil t)
 846       (setq start (match-beginning 0))
 847       (forward-line 1)
 848       (setq end (progn (while (looking-at "^[ \t]") (forward-line))
 849                        (forward-line -1)
 850                        (line-end-position)))
 851       (if (<= (count-lines start end) wl-message-header-narrowing-lines)
 852           (forward-line 1)
 853         (goto-char start)
 854         (forward-line (1- wl-message-header-narrowing-lines))
 855         (end-of-line)
 856         (setq start (point))
 857         (unless (eq (get-char-property start 'invisible)
 858                     'wl-message-header-narrowing)
 859           (setq ov (or
 860                     (let ((ovs (overlays-at start))
 861                           ov)
 862                       (while (and ovs (not (overlayp ov)))
 863                         (if (overlay-get (car ovs)
 864                                          'wl-message-header-narrowing)
 865                             (setq ov (car ovs)))
 866                         (setq ovs (cdr ovs)))
 867                       ov)
 868                     (make-overlay start end)))
 869           (overlay-put ov 'wl-message-header-narrowing t)
 870           (overlay-put ov 'evaporate t)
 871           (overlay-put ov 'invisible 'wl-message-header-narrowing)
 872           (overlay-put ov 'after-string
 873                        wl-message-header-narrowing-string))))))
 874
 875 (defun wl-message-header-narrowing-widen-at-mouse (event)
 876   (interactive "e")
 877   (save-selected-window
 878     (select-window (posn-window (event-start event)))
 879     (let* ((win (selected-window))
 880            (wpos (window-start win))
 881            (pos (mouse-set-point event))
 882            (ovs (overlays-in (1- pos) (1+ pos)))        ;; Uum...
 883            ov)
 884       (while (and ovs (not (overlayp ov)))
 885         (when (overlay-get (car ovs) 'wl-message-header-narrowing)
 886           (setq ov (car ovs)))
 887         (setq ovs (cdr ovs)))
 888       (when (overlayp ov)
 889         (overlay-put ov 'face 'wl-message-header-narrowing-face)
 890         (overlay-put ov 'local-map wl-message-header-narrowing-map)
 891         (overlay-put ov 'invisible nil)
 892         (overlay-put ov 'after-string nil))
 893       (set-window-start win wpos))))
 894
 895 (defun wl-message-header-narrowing-setup ()
 896   (when (boundp 'line-move-ignore-invisible)
 897     (set (make-local-variable 'line-move-ignore-invisible) t))
 898   (set-text-properties 0 (length wl-message-header-narrowing-string)
 899                        `(face
 900                          wl-message-header-narrowing-face
 901                          keymap
 902                          ,wl-message-header-narrowing-widen-map)
 903                        wl-message-header-narrowing-string))
 904
 905 (defun wl-message-header-narrowing-toggle ()
 906   "Toggle header narrowing."
 907   (interactive)
 908   (when wl-message-use-header-narrowing
 909     (save-excursion
 910       (goto-char (point-min))
 911       (if (re-search-forward "^$" nil t)
 912           (beginning-of-line)
 913         (goto-char (point-max)))
 914       (let ((ovs (overlays-in (point-min) (point)))
 915             ov hn-ovs)
 916         (while (setq ov (car ovs))
 917           (when (overlay-get ov 'wl-message-header-narrowing)
 918             (setq hn-ovs (cons ov hn-ovs)))
 919           (setq ovs (cdr ovs)))
 920         (if hn-ovs
 921             (while hn-ovs
 922               (delete-overlay (car hn-ovs))
 923               (setq hn-ovs (cdr hn-ovs)))
 924           (wl-message-header-narrowing))))))
 925
 926 (require 'product)
 927 (product-provide (provide 'wl-message) (require 'wl-version))
 928
 929 ;;; wl-message.el ends here