wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36
  37 (eval-when-compile
  38   (require 'wl-mime)
  39   (require 'mime-view)
  40   (defalias-maybe 'event-window 'ignore)
  41   (defalias-maybe 'posn-window 'ignore)
  42   (defalias-maybe 'event-start 'ignore)
  43   (defalias-maybe 'mime-open-entity 'ignore))
  44
  45 (defvar wl-message-buffer-prefetch-get-next-function
  46   'wl-summary-default-get-next-msg)
  47
  48 (defvar wl-message-buffer-prefetch-debug nil)
  49 (defvar wl-message-buffer-prefetch-timer nil)
  50
  51 (defvar wl-message-buffer nil) ; message buffer.
  52
  53 (defvar wl-message-buffer-cur-summary-buffer nil)
  54 (defvar wl-message-buffer-cur-folder nil)
  55 (defvar wl-message-buffer-cur-number nil)
  56 (defvar wl-message-buffer-cur-flag nil)
  57 (defvar wl-message-buffer-cur-summary-buffer nil)
  58 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  59 (defvar wl-message-buffer-all-header-flag nil)
  60
  61 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  62 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  63 (make-variable-buffer-local 'wl-message-buffer-cur-flag)
  64 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  65 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  66 (make-variable-buffer-local 'wl-message-buffer-all-header-flag)
  67
  68 (defvar wl-fixed-window-configuration nil)
  69
  70 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  71
  72 ;;; Message buffer cache.
  73
  74 (defvar wl-message-buffer-cache nil
  75   "Message cache.  (old ... new) order alist.
  76 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  77
  78 (defmacro wl-message-buffer-cache-buffer-get (entry)
  79   (` (cdr (, entry))))
  80
  81 (defmacro wl-message-buffer-cache-folder-get (entry)
  82   (` (car (car (, entry)))))
  83
  84 (defmacro wl-message-buffer-cache-message-get (entry)
  85   (` (cdr (car (, entry)))))
  86
  87 (defmacro wl-message-buffer-cache-entry-make (key buf)
  88   (` (cons (, key) (, buf))))
  89
  90 (defmacro wl-message-buffer-cache-hit (key)
  91   "Return value assosiated with key."
  92   (` (wl-message-buffer-cache-buffer-get
  93       (assoc (, key) wl-message-buffer-cache))))
  94
  95 (defun wl-message-buffer-cache-sort (entry)
  96   "Move ENTRY to the top of `wl-message-buffer-cache'."
  97   (setq wl-message-buffer-cache
  98         (cons entry (delete entry wl-message-buffer-cache))))
  99 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 100 ;        (top pointer))
 101 ;    (while (cdr pointer)
 102 ;      (if (equal (car (cdr pointer)) entry)
 103 ;         (setcdr pointer (cdr (cdr pointer)))
 104 ;       (setq pointer (cdr pointer))))
 105 ;    (setcdr pointer (list entry))
 106 ;    (setq wl-message-buffer-cache (cdr top))))
 107
 108 (defconst wl-message-buffer-cache-name    " *WL:Message*")
 109 (defconst wl-original-message-buffer-name " *Original*")
 110
 111 (defun wl-original-message-mode ()
 112   "A major mode for original message buffer."
 113   (setq major-mode 'wl-original-message-mode)
 114   (setq buffer-read-only t)
 115   (elmo-set-buffer-multibyte nil)
 116   (setq mode-name "Wanderlust original message"))
 117
 118 (defun wl-original-message-buffer-get (name)
 119   "Get original message buffer for NAME.
 120 If original message buffer already exists, it is re-used."
 121   (let* ((name (concat wl-original-message-buffer-name name))
 122          (buffer (get-buffer name)))
 123     (unless (and buffer (buffer-live-p buffer))
 124       (with-current-buffer (setq buffer (get-buffer-create name))
 125         (wl-original-message-mode)))
 126     buffer))
 127
 128 (defun wl-message-buffer-create ()
 129   "Create a new message buffer."
 130   (let* ((buffer (generate-new-buffer wl-message-buffer-cache-name))
 131          (name (buffer-name buffer)))
 132     (with-current-buffer buffer
 133       (setq wl-message-buffer-original-buffer
 134             (wl-original-message-buffer-get name)))
 135     buffer))
 136
 137 (defun wl-message-buffer-cache-add (key)
 138   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 139 Return its cache buffer."
 140   (let ((len (length wl-message-buffer-cache))
 141         (buf nil))
 142     (if (< len wl-message-buffer-cache-size)
 143         (setq buf (wl-message-buffer-create))
 144       (setq buf (wl-message-buffer-cache-buffer-get
 145                  (nth (1- len) wl-message-buffer-cache)))
 146       (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil))
 147     (setq wl-message-buffer-cache
 148           (cons (wl-message-buffer-cache-entry-make key buf)
 149                 wl-message-buffer-cache))
 150     buf))
 151
 152 (defun wl-message-buffer-cache-delete (&optional key)
 153   "Delete the most recent cache entry"
 154   (if key
 155       (setq wl-message-buffer-cache
 156             (delq (assoc key wl-message-buffer-cache)
 157                   wl-message-buffer-cache))
 158     (let ((buf (wl-message-buffer-cache-buffer-get
 159                 (car wl-message-buffer-cache))))
 160       (setq wl-message-buffer-cache
 161             (nconc (cdr wl-message-buffer-cache)
 162                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 163
 164 (defun wl-message-buffer-cache-clean-up ()
 165   "A function to flush all decoded messages in cache list."
 166   (interactive)
 167   (if (and (eq major-mode 'wl-summary-mode)
 168            wl-message-buffer
 169            (get-buffer-window wl-message-buffer))
 170       (delete-window (get-buffer-window wl-message-buffer)))
 171   (wl-kill-buffers (regexp-quote wl-message-buffer-cache-name))
 172   (setq wl-message-buffer-cache nil))
 173
 174 ;;; Message buffer handling from summary buffer.
 175
 176 (defun wl-message-buffer-window ()
 177   "Get message buffer window if any."
 178   (let* ((start-win (selected-window))
 179          (cur-win start-win))
 180     (catch 'found
 181       (while (progn
 182                (setq cur-win (next-window cur-win))
 183                (with-current-buffer (window-buffer cur-win)
 184                  (if (or (eq major-mode 'wl-message-mode)
 185                          (eq major-mode 'mime-view-mode))
 186                      (throw 'found cur-win)))
 187                (not (eq cur-win start-win)))))))
 188
 189 (defun wl-message-select-buffer (buffer)
 190   "Select BUFFER as a message buffer."
 191   (let ((window (get-buffer-window buffer))
 192         (sum (car wl-message-window-size))
 193         (mes (cdr wl-message-window-size))
 194         whi)
 195     (when (and window
 196                (not (eq (save-excursion (set-buffer (window-buffer window))
 197                                         wl-message-buffer-cur-summary-buffer)
 198                         (current-buffer))))
 199       (delete-window window)
 200       (run-hooks 'wl-message-window-deleted-hook)
 201       (setq window nil))
 202     (if window
 203         (select-window window)
 204       (when wl-fixed-window-configuration
 205         (delete-other-windows)
 206         (and wl-stay-folder-window
 207              (wl-summary-toggle-disp-folder)))
 208       ;; There's no buffer window. Search for message window and snatch it.
 209       (if (setq window (wl-message-buffer-window))
 210           (select-window window)
 211         (setq whi (1- (window-height)))
 212         (if mes
 213             (progn
 214               (let ((total (+ sum mes)))
 215                 (setq sum (max window-min-height (/ (* whi sum) total)))
 216                 (setq mes (max window-min-height (/ (* whi mes) total))))
 217               (if (< whi (+ sum mes))
 218                   (enlarge-window (- (+ sum mes) whi)))))
 219         (split-window (get-buffer-window (current-buffer)) sum)
 220         (other-window 1)))
 221     (switch-to-buffer buffer)))
 222
 223 (defun wl-message-narrow-to-page (&optional arg)
 224   "Narrow to page.
 225 If ARG is specified, narrow to ARGth page."
 226   (interactive "P")
 227   (setq arg (if arg (prefix-numeric-value arg) 0))
 228   (save-excursion
 229     (condition-case ()
 230         (forward-page -1)               ; Beginning of current page.
 231       (beginning-of-buffer
 232        (goto-char (point-min))))
 233     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 234     (widen)
 235     (cond
 236      ((> arg 0) (forward-page arg))
 237      ((< arg 0) (forward-page (1- arg))))
 238     (forward-page)
 239     (if wl-break-pages
 240         (narrow-to-region (point)
 241                           (progn
 242                             (forward-page -1)
 243                             (if (and (eolp) (not (bobp)))
 244                                 (forward-line))
 245                             (point))))))
 246
 247 (defun wl-message-prev-page (&optional lines)
 248   "Scroll down current message by LINES.
 249 Returns non-nil if top of message."
 250   (interactive)
 251   (let (cur-buf top real-top)
 252     (unless (eq major-mode 'mime-view-mode)
 253       (when (buffer-live-p wl-message-buffer)
 254         (setq cur-buf (current-buffer))
 255         (wl-message-select-buffer wl-message-buffer)))
 256     (move-to-window-line 0)
 257     (if (and wl-break-pages
 258              (bobp)
 259              (not (setq real-top (save-restriction (widen) (bobp)))))
 260         (progn
 261           (wl-message-narrow-to-page -1)
 262           (goto-char (point-max))
 263           (recenter))
 264       (if (not (bobp))
 265           (condition-case nil
 266               (scroll-down lines)
 267             (error))
 268         (setq top t)))
 269     (if real-top
 270         (let ((f (assq (mime-preview-original-major-mode)
 271                        mime-preview-over-to-previous-method-alist)))
 272           (if f (funcall (cdr f))))
 273       (when cur-buf
 274         (select-window (get-buffer-window cur-buf))))
 275     top))
 276
 277 (defun wl-message-next-page (&optional lines)
 278   "Scroll up current message by LINES.
 279 Returns non-nil if bottom of message."
 280   (interactive)
 281   (let (cur-buf bottom)
 282     (unless (eq major-mode 'mime-view-mode)
 283       (when (buffer-live-p wl-message-buffer)
 284         (setq cur-buf (current-buffer))
 285         (wl-message-select-buffer wl-message-buffer)))
 286     (move-to-window-line -1)
 287     (if (save-excursion
 288           (end-of-line)
 289           (and (pos-visible-in-window-p)
 290                (eobp)))
 291         (if (or (null wl-break-pages)
 292                 (save-excursion
 293                   (save-restriction
 294                     (widen) (forward-line) (eobp))))
 295             (setq bottom t)
 296           (wl-message-narrow-to-page 1)
 297           (setq bottom nil))
 298       (condition-case ()
 299           (static-if (boundp 'window-pixel-scroll-increment)
 300               ;; XEmacs 21.2.20 and later.
 301               (let (window-pixel-scroll-increment)
 302                 (scroll-up lines))
 303             (scroll-up lines))
 304         (end-of-buffer
 305          (goto-char (point-max))))
 306       (setq bottom nil))
 307     (if (eobp)
 308         (let ((f (assq (mime-preview-original-major-mode)
 309                        mime-preview-over-to-next-method-alist)))
 310           (if f (funcall (cdr f))))
 311       (when cur-buf
 312         (select-window (get-buffer-window cur-buf))))
 313     bottom))
 314
 315
 316 (defun wl-message-follow-current-entity (buffer)
 317   "Follow to current message."
 318   (wl-draft-reply (wl-message-get-original-buffer)
 319                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 320   (let ((mail-reply-buffer buffer))
 321     (wl-draft-yank-from-mail-reply-buffer nil)))
 322
 323 ;;
 324
 325 (defun wl-message-mode ()
 326   "A major mode for message displaying."
 327   (interactive)
 328   (setq major-mode 'wl-message-mode)
 329   (setq buffer-read-only t)
 330   (setq mode-name "Message"))
 331
 332 (defun wl-message-exit ()
 333   "Move to summary buffer."
 334   (interactive)
 335   (let (summary-buf summary-win)
 336     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 337         (if (setq summary-win (get-buffer-window summary-buf))
 338             (select-window summary-win)
 339           (switch-to-buffer summary-buf)
 340           (wl-message-select-buffer wl-message-buffer)
 341           (select-window (get-buffer-window summary-buf))))
 342     (run-hooks 'wl-message-exit-hook)))
 343
 344 (defun wl-message-toggle-disp-summary ()
 345   (interactive)
 346   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 347         summary-win)
 348     (if (and summary-buf
 349              (buffer-live-p summary-buf))
 350         (if (setq summary-win (get-buffer-window summary-buf))
 351             (delete-window summary-win)
 352           (switch-to-buffer summary-buf)
 353           (wl-message-select-buffer wl-message-buffer))
 354       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 355                                    nil nil t)
 356                                         ; no summary-buf
 357       (let ((sum-buf (current-buffer)))
 358         (wl-message-select-buffer wl-message-buffer)
 359         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 360
 361 (defun wl-message-get-original-buffer ()
 362   "Get original buffer for current message buffer."
 363   wl-message-buffer-original-buffer)
 364
 365 (defun wl-message-add-buttons-to-body (start end)
 366   (save-excursion
 367     (save-restriction
 368       (narrow-to-region start end)
 369       (let ((case-fold-search t)
 370             (alist wl-message-body-button-alist)
 371             entry)
 372         (while alist
 373           (setq entry (car alist)
 374                 alist (cdr alist))
 375           (goto-char (point-min))
 376           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 377             (unless (get-text-property (point) 'keymap)
 378               (wl-message-add-button
 379                (match-beginning (nth 1 entry))
 380                (match-end (nth 1 entry))
 381                (nth 2 entry)
 382                (match-string (nth 3 entry))))))))))
 383
 384 (defun wl-message-add-buttons-to-header (start end)
 385   (save-excursion
 386     (save-restriction
 387       (narrow-to-region start end)
 388       (let ((case-fold-search t)
 389             (alist wl-message-header-button-alist)
 390             entry)
 391         (while alist
 392           (setq entry (car alist)
 393                 alist (cdr alist))
 394           (goto-char (point-min))
 395           (while (re-search-forward (car entry) nil t)
 396             (setq start (match-beginning 0)
 397                   end (if (re-search-forward "^[^ \t]" nil t)
 398                           (match-beginning 0)
 399                         (point-max)))
 400             (goto-char start)
 401             (while (re-search-forward (nth 1 entry) end t)
 402               (goto-char (match-end 0))
 403               (wl-message-add-button
 404                (match-beginning (nth 2 entry))
 405                (match-end (nth 2 entry))
 406                (nth 3 entry) (match-string (nth 4 entry))))
 407             (goto-char end)))))))
 408
 409 (defun wl-message-redisplay (folder number flag &optional force-reload)
 410   (let* ((default-mime-charset wl-mime-charset)
 411          (buffer-read-only nil)
 412          (summary-buf (current-buffer))
 413          message-buf
 414          strategy entity
 415          cache-used
 416          header-end real-fld-num summary-win delim)
 417     (setq buffer-read-only nil)
 418     (setq cache-used (wl-message-buffer-display
 419                       folder number flag force-reload))
 420     (setq wl-message-buffer (car cache-used))
 421     (setq message-buf wl-message-buffer)
 422     (wl-message-select-buffer wl-message-buffer)
 423
 424     (set-buffer message-buf)
 425     (make-local-variable 'truncate-partial-width-windows)
 426     (setq truncate-partial-width-windows nil)
 427     (setq truncate-lines wl-message-truncate-lines)
 428     (setq buffer-read-only nil)
 429     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 430     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 431     (setq wl-message-buffer-cur-number number)
 432     (setq mode-line-buffer-identification
 433           (format "Wanderlust: << %s / %s >>"
 434                   (if (memq 'modeline wl-use-folder-petname)
 435                       (wl-folder-get-petname (elmo-folder-name-internal
 436                                               folder))
 437                     (elmo-folder-name-internal folder)) number))
 438     ;; highlight body
 439 ;    (when wl-highlight-body-too
 440 ;      (wl-highlight-body))
 441     (condition-case ()
 442         (wl-message-narrow-to-page)
 443       (error nil)); ignore errors.
 444     (setq cache-used (cdr cache-used))
 445     (goto-char (point-min))
 446     (when (re-search-forward "^$" nil t)
 447       (wl-message-add-buttons-to-header (point-min) (point))
 448       (wl-message-add-buttons-to-body (point) (point-max)))
 449     (goto-char (point-min))
 450     (unwind-protect
 451         (save-excursion
 452           (run-hooks 'wl-message-redisplay-hook))
 453       ;; go back to summary mode
 454       (set-buffer-modified-p nil)
 455       (setq buffer-read-only t)
 456       (set-buffer summary-buf)
 457       (setq summary-win (get-buffer-window summary-buf))
 458       (if (window-live-p summary-win)
 459           (select-window summary-win)))
 460     cache-used))
 461
 462 ;; Use message buffer cache.
 463 (defun wl-message-buffer-display (folder number flag
 464                                          &optional force-reload unread)
 465   (let* ((msg-id (elmo-message-field folder number 'message-id))
 466          (fname (elmo-folder-name-internal folder))
 467          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 468          (read nil)
 469          cache-used)
 470     (when (and hit (not (buffer-live-p hit)))
 471       (wl-message-buffer-cache-delete (list fname number msg-id))
 472       (setq hit nil))
 473     (if hit
 474         (progn
 475           ;; move hit to the top.
 476           (wl-message-buffer-cache-sort
 477            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 478           ;; buffer cache is used.
 479           (setq cache-used t)
 480           (with-current-buffer hit
 481             (unless (eq wl-message-buffer-cur-flag flag)
 482               (setq read t))))
 483       ;; delete tail and add new to the top.
 484       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 485       (setq read t))
 486     (if (or force-reload read)
 487         (condition-case err
 488             (save-excursion
 489               (set-buffer hit)
 490               (setq
 491                cache-used
 492                (wl-message-display-internal folder number flag
 493                                             force-reload unread))
 494               (setq wl-message-buffer-cur-flag flag))
 495           (quit
 496            (wl-message-buffer-cache-delete)
 497            (error "Display message %s/%s is quitted" fname number))
 498           (error
 499            (wl-message-buffer-cache-delete)
 500            (signal (car err) (cdr err))
 501            nil))) ;; will not be used
 502     (cons hit cache-used)))
 503
 504 (defun wl-message-display-internal (folder number flag
 505                                            &optional force-reload unread)
 506   (let ((default-mime-charset wl-mime-charset))
 507     (setq wl-message-buffer-all-header-flag (eq flag 'all-header))
 508     (prog1
 509         (if (eq flag 'as-is)
 510             (let (wl-highlight-x-face-function)
 511               (prog1 (elmo-mime-display-as-is folder number
 512                                               (current-buffer)
 513                                               (wl-message-get-original-buffer)
 514                                               'wl-original-message-mode
 515                                               force-reload
 516                                               unread
 517                                               (wl-message-define-keymap))
 518                 (let (buffer-read-only)
 519                   (wl-highlight-message (point-min) (point-max) t))))
 520           (elmo-mime-message-display folder number
 521                                      (current-buffer)
 522                                      (wl-message-get-original-buffer)
 523                                      'wl-original-message-mode
 524                                      force-reload
 525                                      unread
 526                                      (wl-message-define-keymap)))
 527       (run-hooks 'wl-message-display-internal-hook)
 528       (setq buffer-read-only t))))
 529
 530 (defsubst wl-message-buffer-prefetch-p (folder &optional number)
 531   (or (cond
 532        ((eq wl-message-buffer-prefetch-folder-type-list t)
 533         t)
 534        ((and number wl-message-buffer-prefetch-folder-type-list)
 535         (memq (elmo-folder-type-internal
 536                (elmo-message-folder folder number))
 537               wl-message-buffer-prefetch-folder-type-list))
 538        (wl-message-buffer-prefetch-folder-type-list
 539         (let ((list wl-message-buffer-prefetch-folder-type-list)
 540               type)
 541           (catch 'done
 542             (while (setq type (pop list))
 543               (if (elmo-folder-contains-type folder type)
 544                   (throw 'done t)))))))
 545       (cond
 546        ((consp wl-message-buffer-prefetch-folder-list)
 547         (wl-string-match-member (elmo-folder-name-internal folder)
 548                                 wl-message-buffer-prefetch-folder-list))
 549        (t wl-message-buffer-prefetch-folder-list))))
 550
 551 (defun wl-message-buffer-prefetch-next (folder number count &optional
 552                                                summary charset)
 553   (if (wl-message-buffer-prefetch-p folder)
 554       (with-current-buffer (or summary (get-buffer wl-summary-buffer-name))
 555         (let* ((next (funcall wl-message-buffer-prefetch-get-next-function
 556                               number)))
 557           (when (and next (wl-message-buffer-prefetch-p folder next))
 558             (if (not (fboundp 'run-with-idle-timer))
 559                 (when (sit-for wl-message-buffer-prefetch-idle-time)
 560                   (wl-message-buffer-prefetch
 561                    folder next count summary charset))
 562               (setq wl-message-buffer-prefetch-timer nil)
 563               (unless wl-message-buffer-prefetch-timer
 564                 (setq wl-message-buffer-prefetch-timer
 565                       (run-with-idle-timer
 566                        wl-message-buffer-prefetch-idle-time
 567                        nil
 568                        'wl-message-buffer-prefetch
 569                        folder next count summary charset)))))))))
 570
 571 (defun wl-message-buffer-prefetch (folder number count summary charset)
 572   (setq wl-message-buffer-prefetch-timer nil)
 573   (if (and (numberp count)
 574            (>= (setq count (- count 1)) 0))
 575       (if (buffer-live-p summary)
 576           (save-excursion
 577             (set-buffer summary)
 578             (if (string= (elmo-folder-name-internal folder)
 579                          (wl-summary-buffer-folder-name))
 580                 (let* ((message-id (elmo-message-field folder number 'message-id))
 581                        (wl-mime-charset      charset)
 582                        (default-mime-charset charset)
 583                        (key (list (elmo-folder-name-internal folder)
 584                                   number message-id))
 585                        (hit (wl-message-buffer-cache-hit key))
 586                        result time1 time2 sec micro)
 587                   (if (and hit (buffer-live-p hit))
 588                       (wl-message-buffer-cache-sort
 589                        (wl-message-buffer-cache-entry-make key hit))
 590                     (let* ((size (elmo-message-field folder number 'size)))
 591                       (when (or (elmo-message-file-p folder number)
 592                                 (not
 593                                  (and (integerp size)
 594                                       elmo-message-fetch-threshold
 595                                       (>= size
 596                                           elmo-message-fetch-threshold))))
 597                         ;;(not (elmo-file-cache-exists-p message-id)))))
 598                         (when wl-message-buffer-prefetch-debug
 599                           (setq time1 (current-time))
 600                           (message "Prefetching %d..." number))
 601                         (setq result (wl-message-buffer-display folder number
 602                                                                 'mime nil 'unread))
 603                         (when wl-message-buffer-prefetch-debug
 604                           (setq time2 (current-time))
 605                           (setq sec  (- (nth 1 time2)(nth 1 time1)))
 606                           (setq micro (- (nth 2 time2)(nth 2 time1)))
 607                           (setq micro (+ micro (* 1000000 sec)))
 608                           (message "Prefetching %d...done(%f msec)."
 609                                    number
 610                                    (/ micro 1000.0))))))
 611                   (wl-message-buffer-prefetch-next
 612                    folder number count summary charset)))))
 613     (when wl-message-buffer-prefetch-debug
 614       (message "Buffer Cached Messages %S"
 615                (mapcar '(lambda (cache)
 616                           (nth 1 (car cache)))
 617                        wl-message-buffer-cache)))))
 618
 619 (defvar wl-message-button-map (make-sparse-keymap))
 620
 621 (defun wl-message-add-button (from to function &optional data)
 622   "Create a button between FROM and TO with callback FUNCTION and DATA."
 623   (add-text-properties
 624    from to
 625    (nconc (list 'wl-message-button-callback function)
 626           (if data
 627               (list 'wl-message-button-data data))))
 628   (let ((ov (make-overlay from to)))
 629     (overlay-put ov 'mouse-face 'highlight)
 630     (overlay-put ov 'local-map wl-message-button-map)
 631     (overlay-put ov 'evaporate t)))
 632
 633 (defun wl-message-button-dispatcher (event)
 634   "Select the button under point."
 635   (interactive "@e")
 636   (mouse-set-point event)
 637   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 638         (data (get-text-property (point) 'wl-message-button-data)))
 639     (if callback
 640         (funcall callback data)
 641       (wl-message-button-dispatcher-internal event))))
 642
 643 (defun wl-message-button-refer-article (data)
 644   "Read article specified by Message-ID DATA at point."
 645   (switch-to-buffer-other-window
 646    wl-message-buffer-cur-summary-buffer)
 647   (if (wl-summary-jump-to-msg-by-message-id data)
 648       (wl-summary-redisplay)))
 649
 650 (defun wl-message-uu-substring (buf outbuf &optional first last)
 651   (save-excursion
 652     (set-buffer buf)
 653     (search-forward "\n\n")
 654     (let ((sp (point))
 655           ep filename case-fold-search)
 656       (catch 'done
 657         (if first
 658             (progn
 659               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 660                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 661                 (throw 'done nil)))
 662           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 663         (beginning-of-line)
 664         (setq sp (point))
 665         (goto-char (point-max))
 666         (if last
 667             (re-search-backward "^end" sp t)
 668           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 669         (forward-line 1)
 670         (setq ep (point))
 671         (set-buffer outbuf)
 672         (goto-char (point-max))
 673         (insert-buffer-substring buf sp ep)
 674         (set-buffer buf)
 675         filename))))
 676
 677 (require 'product)
 678 (product-provide (provide 'wl-message) (require 'wl-version))
 679
 680 ;;; wl-message.el ends here