wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36 (require 'timer)
  37
  38 (eval-when-compile
  39   (require 'wl-mime)
  40   (require 'mime-view)
  41   (defalias-maybe 'event-window 'ignore)
  42   (defalias-maybe 'posn-window 'ignore)
  43   (defalias-maybe 'event-start 'ignore)
  44   (defalias-maybe 'mime-open-entity 'ignore)
  45   (defalias-maybe 'itimer-function 'ignore)
  46   (defalias-maybe 'delete-itimer 'ignore)
  47   (defvar-maybe itimer-list))
  48
  49 (defvar wl-message-buffer-prefetch-get-next-function
  50   'wl-summary-default-get-next-msg)
  51
  52 (defvar wl-message-buffer-prefetch-debug nil)
  53 (defvar wl-message-buffer-prefetch-timer nil)
  54
  55 (defvar wl-message-buffer nil) ; message buffer.
  56
  57 (defvar wl-message-buffer-cur-summary-buffer nil)
  58 (defvar wl-message-buffer-cur-folder nil)
  59 (defvar wl-message-buffer-cur-number nil)
  60 (defvar wl-message-buffer-cur-flag nil)
  61 (defvar wl-message-buffer-cur-summary-buffer nil)
  62 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  63 (defvar wl-message-buffer-all-header-flag nil)
  64 (defvar wl-message-buffer-mode-line-formatter nil)
  65
  66 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  67 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-flag)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  70 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  71 (make-variable-buffer-local 'wl-message-buffer-all-header-flag)
  72 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  73
  74 (defvar wl-fixed-window-configuration nil)
  75
  76 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  77
  78 ;;; Message buffer cache.
  79
  80 (defvar wl-message-buffer-cache nil
  81   "Message cache.  (old ... new) order alist.
  82 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  83
  84 (defmacro wl-message-buffer-cache-buffer-get (entry)
  85   (` (cdr (, entry))))
  86
  87 (defmacro wl-message-buffer-cache-folder-get (entry)
  88   (` (car (car (, entry)))))
  89
  90 (defmacro wl-message-buffer-cache-message-get (entry)
  91   (` (cdr (car (, entry)))))
  92
  93 (defmacro wl-message-buffer-cache-entry-make (key buf)
  94   (` (cons (, key) (, buf))))
  95
  96 (defmacro wl-message-buffer-cache-hit (key)
  97   "Return value assosiated with key."
  98   (` (wl-message-buffer-cache-buffer-get
  99       (assoc (, key) wl-message-buffer-cache))))
 100
 101 (defun wl-message-buffer-cache-sort (entry)
 102   "Move ENTRY to the top of `wl-message-buffer-cache'."
 103   (setq wl-message-buffer-cache
 104         (cons entry (delete entry wl-message-buffer-cache))))
 105 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 106 ;        (top pointer))
 107 ;    (while (cdr pointer)
 108 ;      (if (equal (car (cdr pointer)) entry)
 109 ;         (setcdr pointer (cdr (cdr pointer)))
 110 ;       (setq pointer (cdr pointer))))
 111 ;    (setcdr pointer (list entry))
 112 ;    (setq wl-message-buffer-cache (cdr top))))
 113
 114 (defconst wl-original-message-buffer-name " *Original*")
 115
 116 (defun wl-original-message-mode ()
 117   "A major mode for original message buffer."
 118   (setq major-mode 'wl-original-message-mode)
 119   (setq buffer-read-only t)
 120   (elmo-set-buffer-multibyte nil)
 121   (setq mode-name "Wanderlust original message"))
 122
 123 (defun wl-original-message-buffer-get (name)
 124   "Get original message buffer for NAME.
 125 If original message buffer already exists, it is re-used."
 126   (let* ((name (concat wl-original-message-buffer-name name))
 127          (buffer (get-buffer name)))
 128     (unless (and buffer (buffer-live-p buffer))
 129       (with-current-buffer (setq buffer (get-buffer-create name))
 130         (wl-original-message-mode)))
 131     buffer))
 132
 133 (defun wl-message-buffer-create ()
 134   "Create a new message buffer."
 135   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 136          (name (buffer-name buffer)))
 137     (with-current-buffer buffer
 138       (setq wl-message-buffer-original-buffer
 139             (wl-original-message-buffer-get name))
 140       (run-hooks 'wl-message-buffer-created-hook))
 141     buffer))
 142
 143 (defun wl-message-buffer-cache-add (key)
 144   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 145 Return its cache buffer."
 146   (let ((len (length wl-message-buffer-cache))
 147         (buf nil))
 148     (if (< len wl-message-buffer-cache-size)
 149         (setq buf (wl-message-buffer-create))
 150       (setq buf (wl-message-buffer-cache-buffer-get
 151                  (nth (1- len) wl-message-buffer-cache)))
 152       (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil))
 153     (setq wl-message-buffer-cache
 154           (cons (wl-message-buffer-cache-entry-make key buf)
 155                 wl-message-buffer-cache))
 156     buf))
 157
 158 (defun wl-message-buffer-cache-delete (&optional key)
 159   "Delete the most recent cache entry"
 160   (if key
 161       (setq wl-message-buffer-cache
 162             (delq (assoc key wl-message-buffer-cache)
 163                   wl-message-buffer-cache))
 164     (let ((buf (wl-message-buffer-cache-buffer-get
 165                 (car wl-message-buffer-cache))))
 166       (setq wl-message-buffer-cache
 167             (nconc (cdr wl-message-buffer-cache)
 168                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 169
 170 (defun wl-message-buffer-cache-clean-up ()
 171   "A function to flush all decoded messages in cache list."
 172   (interactive)
 173   (if (and (eq major-mode 'wl-summary-mode)
 174            wl-message-buffer
 175            (get-buffer-window wl-message-buffer))
 176       (delete-window (get-buffer-window wl-message-buffer)))
 177   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 178   (setq wl-message-buffer-cache nil))
 179
 180 ;;; Message buffer handling from summary buffer.
 181
 182 (defun wl-message-buffer-window ()
 183   "Get message buffer window if any."
 184   (let* ((start-win (selected-window))
 185          (cur-win start-win))
 186     (catch 'found
 187       (while (progn
 188                (setq cur-win (next-window cur-win))
 189                (with-current-buffer (window-buffer cur-win)
 190                  (if (or (eq major-mode 'wl-message-mode)
 191                          (eq major-mode 'mime-view-mode))
 192                      (throw 'found cur-win)))
 193                (not (eq cur-win start-win)))))))
 194
 195 (defun wl-message-select-buffer (buffer)
 196   "Select BUFFER as a message buffer."
 197   (let ((window (get-buffer-window buffer))
 198         (sum (car wl-message-window-size))
 199         (mes (cdr wl-message-window-size))
 200         whi)
 201     (when (and window
 202                (not (eq (save-excursion (set-buffer (window-buffer window))
 203                                         wl-message-buffer-cur-summary-buffer)
 204                         (current-buffer))))
 205       (delete-window window)
 206       (run-hooks 'wl-message-window-deleted-hook)
 207       (setq window nil))
 208     (if window
 209         (select-window window)
 210       (when wl-fixed-window-configuration
 211         (delete-other-windows)
 212         (and wl-stay-folder-window
 213              (wl-summary-toggle-disp-folder)))
 214       ;; There's no buffer window. Search for message window and snatch it.
 215       (if (setq window (wl-message-buffer-window))
 216           (select-window window)
 217         (setq whi (1- (window-height)))
 218         (if mes
 219             (progn
 220               (let ((total (+ sum mes)))
 221                 (setq sum (max window-min-height (/ (* whi sum) total)))
 222                 (setq mes (max window-min-height (/ (* whi mes) total))))
 223               (if (< whi (+ sum mes))
 224                   (enlarge-window (- (+ sum mes) whi)))))
 225         (split-window (get-buffer-window (current-buffer)) sum)
 226         (other-window 1)))
 227     (switch-to-buffer buffer)))
 228
 229 (defun wl-message-narrow-to-page (&optional arg)
 230   "Narrow to page.
 231 If ARG is specified, narrow to ARGth page."
 232   (interactive "P")
 233   (setq arg (if arg (prefix-numeric-value arg) 0))
 234   (save-excursion
 235     (condition-case ()
 236         (forward-page -1)               ; Beginning of current page.
 237       (beginning-of-buffer
 238        (goto-char (point-min))))
 239     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 240     (widen)
 241     (cond
 242      ((> arg 0) (forward-page arg))
 243      ((< arg 0) (forward-page (1- arg))))
 244     (forward-page)
 245     (if wl-break-pages
 246         (narrow-to-region (point)
 247                           (progn
 248                             (forward-page -1)
 249                             (if (and (eolp) (not (bobp)))
 250                                 (forward-line))
 251                             (point))))))
 252
 253 (defun wl-message-prev-page (&optional lines)
 254   "Scroll down current message by LINES.
 255 Returns non-nil if top of message."
 256   (interactive)
 257   (let (cur-buf top real-top)
 258     (unless (eq major-mode 'mime-view-mode)
 259       (when (buffer-live-p wl-message-buffer)
 260         (setq cur-buf (current-buffer))
 261         (wl-message-select-buffer wl-message-buffer)))
 262     (move-to-window-line 0)
 263     (if (and wl-break-pages
 264              (bobp)
 265              (not (setq real-top (save-restriction (widen) (bobp)))))
 266         (progn
 267           (wl-message-narrow-to-page -1)
 268           (goto-char (point-max))
 269           (recenter))
 270       (if (not (bobp))
 271           (condition-case nil
 272               (scroll-down (or lines wl-message-scroll-amount))
 273             (error))
 274         (setq top t)))
 275     (if real-top
 276         (let ((f (assq (mime-preview-original-major-mode)
 277                        mime-preview-over-to-previous-method-alist)))
 278           (if f (funcall (cdr f))))
 279       (when cur-buf
 280         (select-window (get-buffer-window cur-buf))))
 281     top))
 282
 283 (defun wl-message-next-page (&optional lines)
 284   "Scroll up current message by LINES.
 285 Returns non-nil if bottom of message."
 286   (interactive)
 287   (let (cur-buf bottom)
 288     (unless (eq major-mode 'mime-view-mode)
 289       (when (buffer-live-p wl-message-buffer)
 290         (setq cur-buf (current-buffer))
 291         (wl-message-select-buffer wl-message-buffer)))
 292     (move-to-window-line -1)
 293     (if (save-excursion
 294           (end-of-line)
 295           (and (pos-visible-in-window-p)
 296                (eobp)))
 297         (if (or (null wl-break-pages)
 298                 (save-excursion
 299                   (save-restriction
 300                     (widen) (forward-line) (eobp))))
 301             (setq bottom t)
 302           (wl-message-narrow-to-page 1)
 303           (setq bottom nil))
 304       (condition-case ()
 305           (static-if (boundp 'window-pixel-scroll-increment)
 306               ;; XEmacs 21.2.20 and later.
 307               (let (window-pixel-scroll-increment)
 308                 (scroll-up (or lines wl-message-scroll-amount)))
 309             (scroll-up (or lines wl-message-scroll-amount)))
 310         (end-of-buffer
 311          (goto-char (point-max))))
 312       (setq bottom nil))
 313     (if (eobp)
 314         (let ((f (assq (mime-preview-original-major-mode)
 315                        mime-preview-over-to-next-method-alist)))
 316           (if f (funcall (cdr f))))
 317       (when cur-buf
 318         (select-window (get-buffer-window cur-buf))))
 319     bottom))
 320
 321
 322 (defun wl-message-follow-current-entity (buffer)
 323   "Follow to current message."
 324   (wl-draft-reply (wl-message-get-original-buffer)
 325                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 326   (let ((mail-reply-buffer buffer))
 327     (wl-draft-yank-from-mail-reply-buffer nil)))
 328
 329 ;;
 330
 331 (defun wl-message-mode ()
 332   "A major mode for message displaying."
 333   (interactive)
 334   (setq major-mode 'wl-message-mode)
 335   (setq buffer-read-only t)
 336   (setq mode-name "Message"))
 337
 338 (defun wl-message-exit ()
 339   "Move to summary buffer."
 340   (interactive)
 341   (let (summary-buf summary-win)
 342     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 343         (if (setq summary-win (get-buffer-window summary-buf))
 344             (select-window summary-win)
 345           (switch-to-buffer summary-buf)
 346           (wl-message-select-buffer wl-message-buffer)
 347           (select-window (get-buffer-window summary-buf))))
 348     (run-hooks 'wl-message-exit-hook)))
 349
 350 (defun wl-message-toggle-disp-summary ()
 351   (interactive)
 352   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 353         summary-win)
 354     (if (and summary-buf
 355              (buffer-live-p summary-buf))
 356         (if (setq summary-win (get-buffer-window summary-buf))
 357             (delete-window summary-win)
 358           (switch-to-buffer summary-buf)
 359           (wl-message-select-buffer wl-message-buffer))
 360       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 361                                    nil nil t)
 362                                         ; no summary-buf
 363       (let ((sum-buf (current-buffer)))
 364         (wl-message-select-buffer wl-message-buffer)
 365         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 366
 367 (defun wl-message-get-original-buffer ()
 368   "Get original buffer for current message buffer."
 369   (if (buffer-live-p wl-message-buffer-original-buffer)
 370       wl-message-buffer-original-buffer
 371     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 372
 373 (defun wl-message-add-buttons-to-body (start end)
 374   (save-excursion
 375     (save-restriction
 376       (narrow-to-region start end)
 377       (let ((case-fold-search t)
 378             (alist wl-message-body-button-alist)
 379             entry)
 380         (while alist
 381           (setq entry (car alist)
 382                 alist (cdr alist))
 383           (goto-char (point-min))
 384           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 385             (unless (get-text-property (point) 'keymap)
 386               (wl-message-add-button
 387                (match-beginning (nth 1 entry))
 388                (match-end (nth 1 entry))
 389                (nth 2 entry)
 390                (match-string (nth 3 entry))))))))))
 391
 392 (defun wl-message-add-buttons-to-header (start end)
 393   (save-excursion
 394     (save-restriction
 395       (narrow-to-region start end)
 396       (let ((case-fold-search t)
 397             (alist wl-message-header-button-alist)
 398             entry)
 399         (while alist
 400           (setq entry (car alist)
 401                 alist (cdr alist))
 402           (goto-char (point-min))
 403           (while (re-search-forward (car entry) nil t)
 404             (setq start (match-beginning 0)
 405                   end (if (re-search-forward "^[^ \t]" nil t)
 406                           (match-beginning 0)
 407                         (point-max)))
 408             (goto-char start)
 409             (while (re-search-forward (nth 1 entry) end t)
 410               (wl-message-add-button
 411                (match-beginning (nth 2 entry))
 412                (match-end (nth 2 entry))
 413                (nth 3 entry) (match-string (nth 4 entry))))
 414             (goto-char end)))))))
 415
 416 (defun wl-message-redisplay (folder number flag &optional force-reload)
 417   (let* ((default-mime-charset wl-mime-charset)
 418          (buffer-read-only nil)
 419          (summary-buf (current-buffer))
 420          message-buf
 421          strategy entity
 422          cache-used
 423          header-end real-fld-num summary-win delim)
 424     (setq buffer-read-only nil)
 425     (setq cache-used (wl-message-buffer-display
 426                       folder number flag force-reload))
 427     (setq wl-message-buffer (car cache-used))
 428     (setq message-buf wl-message-buffer)
 429     (wl-message-select-buffer wl-message-buffer)
 430
 431     (set-buffer message-buf)
 432     (make-local-variable 'truncate-partial-width-windows)
 433     (setq truncate-partial-width-windows nil)
 434     (setq truncate-lines wl-message-truncate-lines)
 435     (setq buffer-read-only nil)
 436     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 437     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 438     (setq wl-message-buffer-cur-number number)
 439     (wl-line-formatter-setup
 440      wl-message-buffer-mode-line-formatter
 441      wl-message-mode-line-format
 442      wl-message-mode-line-format-spec-alist)
 443     (setq mode-line-buffer-identification
 444           (funcall wl-message-buffer-mode-line-formatter))
 445     ;; highlight body
 446 ;    (when wl-highlight-body-too
 447 ;      (wl-highlight-body))
 448     (ignore-errors (wl-message-narrow-to-page))
 449     (setq cache-used (cdr cache-used))
 450     (goto-char (point-min))
 451     (when (re-search-forward "^$" nil t)
 452       (wl-message-add-buttons-to-header (point-min) (point))
 453       (wl-message-add-buttons-to-body (point) (point-max)))
 454     (goto-char (point-min))
 455     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 456     ;; go back to summary mode
 457     (set-buffer-modified-p nil)
 458     (setq buffer-read-only t)
 459     (set-buffer summary-buf)
 460     (setq summary-win (get-buffer-window summary-buf))
 461     (if (window-live-p summary-win)
 462         (select-window summary-win))
 463     cache-used))
 464
 465 ;; Use message buffer cache.
 466 (defun wl-message-buffer-display (folder number flag
 467                                          &optional force-reload unread)
 468   (let* ((msg-id (elmo-message-field folder number 'message-id))
 469          (fname (elmo-folder-name-internal folder))
 470          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 471          (read nil)
 472          cache-used)
 473     (when (and hit (not (buffer-live-p hit)))
 474       (wl-message-buffer-cache-delete (list fname number msg-id))
 475       (setq hit nil))
 476     (if hit
 477         (progn
 478           ;; move hit to the top.
 479           (wl-message-buffer-cache-sort
 480            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 481           ;; buffer cache is used.
 482           (setq cache-used t)
 483           (with-current-buffer hit
 484             ;; Rewind to the top page
 485             (widen)
 486             (goto-char (point-min))
 487             (ignore-errors (wl-message-narrow-to-page))
 488             (unless (eq wl-message-buffer-cur-flag flag)
 489               (setq read t))))
 490       ;; delete tail and add new to the top.
 491       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 492       (setq read t))
 493     (if (or force-reload read)
 494         (condition-case err
 495             (save-excursion
 496               (set-buffer hit)
 497               (setq
 498                cache-used
 499                (wl-message-display-internal folder number flag
 500                                             force-reload unread))
 501               (setq wl-message-buffer-cur-flag flag))
 502           (quit
 503            (wl-message-buffer-cache-delete)
 504            (error "Display message %s/%s is quitted" fname number))
 505           (error
 506            (wl-message-buffer-cache-delete)
 507            (signal (car err) (cdr err))
 508            nil))) ;; will not be used
 509     (cons hit cache-used)))
 510
 511 (defun wl-message-display-internal (folder number flag
 512                                            &optional force-reload unread)
 513   (let ((default-mime-charset wl-mime-charset)
 514         (elmo-mime-charset wl-mime-charset))
 515     (setq wl-message-buffer-all-header-flag (eq flag 'all-header))
 516     (prog1
 517         (if (eq flag 'as-is)
 518             (let (wl-highlight-x-face-function)
 519               (prog1 (elmo-mime-display-as-is folder number
 520                                               (current-buffer)
 521                                               (wl-message-get-original-buffer)
 522                                               'wl-original-message-mode
 523                                               force-reload
 524                                               unread
 525                                               (wl-message-define-keymap))
 526                 (let (buffer-read-only)
 527                   (wl-highlight-message (point-min) (point-max) t))))
 528           (elmo-mime-message-display folder number
 529                                      (current-buffer)
 530                                      (wl-message-get-original-buffer)
 531                                      'wl-original-message-mode
 532                                      force-reload
 533                                      unread
 534                                      (wl-message-define-keymap)))
 535       (run-hooks 'wl-message-display-internal-hook)
 536       (setq buffer-read-only t))))
 537
 538 (defsubst wl-message-buffer-prefetch-p (folder &optional number)
 539   (and (or (not number)
 540            (elmo-message-file-p folder number)
 541            (let ((size (elmo-message-field folder number 'size)))
 542              (not (and (integerp size)
 543                        wl-message-buffer-prefetch-threshold
 544                        (>= size wl-message-buffer-prefetch-threshold)))))
 545        (or (not number)
 546            (elmo-folder-plugged-p folder)
 547            (elmo-file-cache-exists-p
 548                  (elmo-message-field folder number 'message-id)))
 549        (or (cond
 550             ((eq wl-message-buffer-prefetch-folder-type-list t)
 551              t)
 552             ((and number wl-message-buffer-prefetch-folder-type-list)
 553              (memq (elmo-folder-type-internal
 554                     (elmo-message-folder folder number))
 555                    wl-message-buffer-prefetch-folder-type-list))
 556             (wl-message-buffer-prefetch-folder-type-list
 557              (let ((list wl-message-buffer-prefetch-folder-type-list)
 558                    type)
 559                (catch 'done
 560                  (while (setq type (pop list))
 561                    (if (elmo-folder-contains-type folder type)
 562                        (throw 'done t)))))))
 563            (cond
 564             ((consp wl-message-buffer-prefetch-folder-list)
 565              (wl-string-match-member (elmo-folder-name-internal folder)
 566                                      wl-message-buffer-prefetch-folder-list))
 567             (t wl-message-buffer-prefetch-folder-list)))))
 568
 569 (defsubst wl-message-buffer-prefetch-clear-timer ()
 570 ;;;     cannot use for the bug of fsf-compat package (1.09).
 571 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 572   (if (fboundp 'run-with-idle-timer)
 573       (if (featurep 'xemacs)
 574           (let ((p itimer-list))
 575             (while (car p)
 576               (if (eq 'wl-message-buffer-prefetch-subr
 577                       (itimer-function (car p)))
 578                   (delete-itimer (car p)))
 579               (setq p (cdr p))))
 580         ;; FSF Emacs is correct
 581         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 582
 583 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 584                                                        summary charset)
 585   (if (not (fboundp 'run-with-idle-timer))
 586       (when (sit-for wl-message-buffer-prefetch-idle-time)
 587         (wl-message-buffer-prefetch-subr
 588          folder number count summary charset))
 589     (run-with-idle-timer
 590      wl-message-buffer-prefetch-idle-time
 591      nil
 592      'wl-message-buffer-prefetch-subr
 593      folder number count summary charset)))
 594
 595 (defvar wl-message-buffer-prefetch-move-spec-plugged-alist nil)
 596 (defvar wl-message-buffer-prefetch-move-spec-unplugged-alist nil)
 597
 598 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 599   (if (buffer-live-p summary)
 600       (with-current-buffer summary
 601         (let ((wl-summary-move-spec-plugged-alist
 602                (or wl-message-buffer-prefetch-move-spec-plugged-alist
 603                    wl-summary-move-spec-plugged-alist))
 604               (wl-summary-move-spec-unplugged-alist
 605                (or wl-message-buffer-prefetch-move-spec-unplugged-alist
 606                    wl-summary-move-spec-unplugged-alist))
 607               (next number))
 608           (while (and (setq next (funcall
 609                                   wl-message-buffer-prefetch-get-next-function
 610                                   next))
 611                       (not (wl-message-buffer-prefetch-p folder next))))
 612           next))))
 613
 614 (defun wl-message-buffer-prefetch (folder number count
 615                                           &optional summary charset)
 616   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 617          (num number))
 618     (when (and count
 619                (wl-message-buffer-prefetch-p folder))
 620       (unless (wl-message-buffer-prefetch-p folder number)
 621         (setq num
 622               (wl-message-buffer-prefetch-get-next folder number summary)))
 623       (when num
 624         (wl-message-buffer-prefetch-clear-timer)
 625         (wl-message-buffer-prefetch-set-timer
 626          folder num count summary charset)))))
 627
 628 (defun wl-message-buffer-prefetch-next (folder number count
 629                                                &optional summary charset)
 630   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 631          next)
 632     (when (and count
 633                (wl-message-buffer-prefetch-p folder))
 634       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 635       (when next
 636         (wl-message-buffer-prefetch-clear-timer)
 637         (wl-message-buffer-prefetch-set-timer
 638          folder next count summary charset)))))
 639
 640 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 641   (if (buffer-live-p summary)
 642       (with-current-buffer summary
 643         (if (and number
 644                  (numberp count)
 645                  (>= (setq count (- count 1)) 0)
 646                  (string= (elmo-folder-name-internal folder)
 647                           (wl-summary-buffer-folder-name)))
 648             (let* ((wl-mime-charset      charset)
 649                    (default-mime-charset charset)
 650                    (message-id (elmo-message-field folder number 'message-id))
 651                    (key (list (elmo-folder-name-internal folder)
 652                               number message-id))
 653                    (hit (wl-message-buffer-cache-hit key))
 654                    result time1 time2 sec micro)
 655               (when wl-message-buffer-prefetch-debug
 656                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 657               (if (and hit (buffer-live-p hit))
 658                   (progn
 659                     (wl-message-buffer-cache-sort
 660                      (wl-message-buffer-cache-entry-make key hit))
 661                     (wl-message-buffer-prefetch-subr
 662                      folder
 663                      (wl-message-buffer-prefetch-get-next
 664                       folder number summary)
 665                      count summary charset))
 666                 ;; prefetching
 667                 (when wl-message-buffer-prefetch-debug
 668                   (setq time1 (current-time))
 669                   (message "Prefetching %d..." number))
 670                 (setq result (wl-message-buffer-display
 671                               folder number 'mime nil 'unread))
 672                 (when wl-message-buffer-prefetch-debug
 673                   (setq time2 (current-time))
 674                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 675                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 676                   (setq micro (+ micro (* 1000000 sec)))
 677                   (message "Prefetching %d...done(%f msec)."
 678                            number
 679                            (/ micro 1000.0))
 680                   (sit-for 0))
 681                 ;; set next prefetch
 682                 (wl-message-buffer-prefetch-set-timer
 683                  folder
 684                  (wl-message-buffer-prefetch-get-next
 685                   folder number summary)
 686                  count summary charset)
 687                 (sit-for 0)
 688                 ;; success prefetch
 689                 )))
 690         ;; finish prefetch
 691         (when wl-message-buffer-prefetch-debug
 692           (message "Buffer Cached Messages: %s"
 693                    (mapconcat
 694                     '(lambda (cache)
 695                        (if (numberp (nth 1 (car cache)))
 696                            (if (string=
 697                                 (nth 0 (car cache))
 698                                 (elmo-folder-name-internal folder))
 699                                (format "%d"
 700                                        (nth 1 (car cache)))
 701                              (format "*%d" (nth 1 (car cache))))
 702                          "-"))
 703                     wl-message-buffer-cache " "))) )))
 704
 705 (defvar wl-message-button-map (make-sparse-keymap))
 706
 707 (defun wl-message-add-button (from to function &optional data)
 708   "Create a button between FROM and TO with callback FUNCTION and DATA."
 709   (add-text-properties
 710    from to
 711    (nconc (list 'wl-message-button-callback function)
 712           (if data
 713               (list 'wl-message-button-data data))))
 714   (let ((ov (make-overlay from to)))
 715     (overlay-put ov 'mouse-face 'highlight)
 716     (overlay-put ov 'local-map wl-message-button-map)
 717     (overlay-put ov 'evaporate t)))
 718
 719 (defun wl-message-button-dispatcher (event)
 720   "Select the button under point."
 721   (interactive "@e")
 722   (mouse-set-point event)
 723   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 724         (data (get-text-property (point) 'wl-message-button-data)))
 725     (if callback
 726         (funcall callback data)
 727       (wl-message-button-dispatcher-internal event))))
 728
 729 (defun wl-message-button-refer-article (data)
 730   "Read article specified by Message-ID DATA at point."
 731   (switch-to-buffer-other-window
 732    wl-message-buffer-cur-summary-buffer)
 733   (if (wl-summary-jump-to-msg-by-message-id data)
 734       (wl-summary-redisplay)))
 735
 736 (defun wl-message-uu-substring (buf outbuf &optional first last)
 737   (save-excursion
 738     (set-buffer buf)
 739     (search-forward "\n\n")
 740     (let ((sp (point))
 741           ep filename case-fold-search)
 742       (catch 'done
 743         (if first
 744             (progn
 745               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 746                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 747                 (throw 'done nil)))
 748           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 749         (beginning-of-line)
 750         (setq sp (point))
 751         (goto-char (point-max))
 752         (if last
 753             (re-search-backward "^end" sp t)
 754           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 755         (forward-line 1)
 756         (setq ep (point))
 757         (set-buffer outbuf)
 758         (goto-char (point-max))
 759         (insert-buffer-substring buf sp ep)
 760         (set-buffer buf)
 761         filename))))
 762
 763 (require 'product)
 764 (product-provide (provide 'wl-message) (require 'wl-version))
 765
 766 ;;; wl-message.el ends here