wl/wl-message.el

   1 ;;; wl-message.el -- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36
  37 (eval-when-compile
  38   (require 'wl-mime)
  39   (require 'mime-view)
  40   (defalias-maybe 'event-window 'ignore)
  41   (defalias-maybe 'posn-window 'ignore)
  42   (defalias-maybe 'event-start 'ignore)
  43   (defalias-maybe 'mime-open-entity 'ignore))
  44
  45 (defconst wl-message-buffer-prefetch-idle-time
  46   (if (featurep 'lisp-float-type) (/ (float 1) (float 5)) 1))
  47 (defvar wl-message-buffer-prefetch-get-next-function
  48   'wl-summary-default-get-next-msg)
  49
  50 (defvar wl-message-buffer-prefetch-folder-type-list t)
  51
  52 (defvar wl-message-buffer-prefetch-debug nil)
  53
  54 (defvar wl-message-buffer nil) ; message buffer.
  55
  56 (defvar wl-message-buffer-cur-summary-buffer nil)
  57 (defvar wl-message-buffer-cur-folder nil)
  58 (defvar wl-message-buffer-cur-number nil)
  59 (defvar wl-message-buffer-cur-flag nil)
  60 (defvar wl-message-buffer-cur-summary-buffer nil)
  61 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  62
  63 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  64 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  65 (make-variable-buffer-local 'wl-message-buffer-cur-flag)
  66 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  67 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  68
  69 (defvar wl-fixed-window-configuration nil)
  70
  71 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  72
  73 ;;; Message buffer cache.
  74
  75 (defvar wl-message-buffer-cache nil
  76   "Message cache.  (old ... new) order alist.
  77 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  78
  79 (defmacro wl-message-buffer-cache-buffer-get (entry)
  80   (` (cdr (, entry))))
  81
  82 (defmacro wl-message-buffer-cache-folder-get (entry)
  83   (` (car (car (, entry)))))
  84
  85 (defmacro wl-message-buffer-cache-message-get (entry)
  86   (` (cdr (car (, entry)))))
  87
  88 (defmacro wl-message-buffer-cache-entry-make (key buf)
  89   (` (cons (, key) (, buf))))
  90
  91 (defmacro wl-message-buffer-cache-hit (key)
  92   "Return value assosiated with key."
  93   (` (wl-message-buffer-cache-buffer-get
  94       (assoc (, key) wl-message-buffer-cache))))
  95
  96 (defun wl-message-buffer-cache-sort (entry)
  97   "Move ENTRY to the top of `wl-message-buffer-cache'."
  98   (setq wl-message-buffer-cache
  99         (cons entry (delete entry wl-message-buffer-cache))))
 100 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 101 ;        (top pointer))
 102 ;    (while (cdr pointer)
 103 ;      (if (equal (car (cdr pointer)) entry)
 104 ;         (setcdr pointer (cdr (cdr pointer)))
 105 ;       (setq pointer (cdr pointer))))
 106 ;    (setcdr pointer (list entry))
 107 ;    (setq wl-message-buffer-cache (cdr top))))
 108
 109 (defconst wl-message-buffer-cache-name    " *WL:Message*")
 110 (defconst wl-original-message-buffer-name " *Original*")
 111
 112 (defun wl-original-message-mode ()
 113   "A major mode for original message buffer."
 114   (setq major-mode 'wl-original-message-mode)
 115   (setq buffer-read-only t)
 116   (elmo-set-buffer-multibyte nil)
 117   (setq mode-name "Wanderlust original message"))
 118
 119 (defun wl-original-message-buffer-get (name)
 120   "Get original message buffer for NAME.
 121 If original message buffer already exists, it is re-used."
 122   (let* ((name (concat wl-original-message-buffer-name name))
 123          (buffer (get-buffer name)))
 124     (unless (and buffer (buffer-live-p buffer))
 125       (with-current-buffer (setq buffer (get-buffer-create name))
 126         (wl-original-message-mode)))
 127     buffer))
 128
 129 (defun wl-message-buffer-create ()
 130   "Create a new message buffer."
 131   (let* ((buffer (generate-new-buffer wl-message-buffer-cache-name))
 132          (name (buffer-name buffer)))
 133     (with-current-buffer buffer
 134       (setq wl-message-buffer-original-buffer
 135             (wl-original-message-buffer-get name)))
 136     buffer))
 137
 138 (defun wl-message-buffer-cache-add (key)
 139   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 140 Return its cache buffer."
 141   (let ((len (length wl-message-buffer-cache))
 142         (buf nil))
 143     (if (< len wl-message-buffer-cache-size)
 144         (setq buf (wl-message-buffer-create))
 145       (setq buf (wl-message-buffer-cache-buffer-get
 146                  (nth (1- len) wl-message-buffer-cache)))
 147       (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil))
 148     (setq wl-message-buffer-cache
 149           (cons (wl-message-buffer-cache-entry-make key buf)
 150                 wl-message-buffer-cache))
 151     buf))
 152
 153 (defun wl-message-buffer-cache-delete (&optional key)
 154   "Delete the most recent cache entry"
 155   (if key
 156       (setq wl-message-buffer-cache
 157             (delq (assoc key wl-message-buffer-cache)
 158                   wl-message-buffer-cache))
 159     (let ((buf (wl-message-buffer-cache-buffer-get
 160                 (car wl-message-buffer-cache))))
 161       (setq wl-message-buffer-cache
 162             (nconc (cdr wl-message-buffer-cache)
 163                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 164
 165 (defun wl-message-buffer-cache-clean-up ()
 166   "A function to flush all decoded messages in cache list."
 167   (interactive)
 168   (if (and (eq major-mode 'wl-summary-mode)
 169            wl-message-buffer
 170            (get-buffer-window wl-message-buffer))
 171       (delete-window (get-buffer-window wl-message-buffer)))
 172   (wl-kill-buffers (regexp-quote wl-message-buffer-cache-name))
 173   (setq wl-message-buffer-cache nil))
 174
 175 ;;; Message buffer handling from summary buffer.
 176
 177 (defun wl-message-buffer-window ()
 178   "Get message buffer window if any."
 179   (let* ((start-win (selected-window))
 180          (cur-win start-win))
 181     (catch 'found
 182       (while (progn
 183                (setq cur-win (next-window cur-win))
 184                (with-current-buffer (window-buffer cur-win)
 185                  (if (or (eq major-mode 'wl-message-mode)
 186                          (eq major-mode 'mime-view-mode))
 187                      (throw 'found cur-win)))
 188                (not (eq cur-win start-win)))))))
 189
 190 (defun wl-message-select-buffer (buffer)
 191   "Select BUFFER as a message buffer."
 192   (let ((window (get-buffer-window buffer))
 193         (sum (car wl-message-window-size))
 194         (mes (cdr wl-message-window-size))
 195         whi)
 196     (when (and window
 197                (not (eq (save-excursion (set-buffer (window-buffer window))
 198                                         wl-message-buffer-cur-summary-buffer)
 199                         (current-buffer))))
 200       (delete-window window)
 201       (run-hooks 'wl-message-window-deleted-hook)
 202       (setq window nil))
 203     (if window
 204         (select-window window)
 205       (when wl-fixed-window-configuration
 206         (delete-other-windows)
 207         (and wl-stay-folder-window
 208              (wl-summary-toggle-disp-folder)))
 209       ;; There's no buffer window. Search for message window and snatch it.
 210       (if (setq window (wl-message-buffer-window))
 211           (select-window window)
 212         (setq whi (1- (window-height)))
 213         (if mes
 214             (progn
 215               (let ((total (+ sum mes)))
 216                 (setq sum (max window-min-height (/ (* whi sum) total)))
 217                 (setq mes (max window-min-height (/ (* whi mes) total))))
 218               (if (< whi (+ sum mes))
 219                   (enlarge-window (- (+ sum mes) whi)))))
 220         (split-window (get-buffer-window (current-buffer)) sum)
 221         (other-window 1)))
 222     (switch-to-buffer buffer)))
 223
 224 (defun wl-message-narrow-to-page (&optional arg)
 225   "Narrow to page.
 226 If ARG is specified, narrow to ARGth page."
 227   (interactive "P")
 228   (setq arg (if arg (prefix-numeric-value arg) 0))
 229   (save-excursion
 230     (condition-case ()
 231         (forward-page -1)               ; Beginning of current page.
 232       (beginning-of-buffer
 233        (goto-char (point-min))))
 234     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 235     (widen)
 236     (cond
 237      ((> arg 0) (forward-page arg))
 238      ((< arg 0) (forward-page (1- arg))))
 239     (forward-page)
 240     (if wl-break-pages
 241         (narrow-to-region (point)
 242                           (progn
 243                             (forward-page -1)
 244                             (if (and (eolp) (not (bobp)))
 245                                 (forward-line))
 246                             (point))))))
 247
 248 (defun wl-message-prev-page (&optional lines)
 249   "Scroll down current message by LINES.
 250 Returns non-nil if top of message."
 251   (interactive)
 252   (let (cur-buf top real-top)
 253     (unless (eq major-mode 'mime-view-mode)
 254       (when (buffer-live-p wl-message-buffer)
 255         (setq cur-buf (current-buffer))
 256         (wl-message-select-buffer wl-message-buffer)))
 257     (move-to-window-line 0)
 258     (if (and wl-break-pages
 259              (bobp)
 260              (not (setq real-top (save-restriction (widen) (bobp)))))
 261         (progn
 262           (wl-message-narrow-to-page -1)
 263           (goto-char (point-max))
 264           (recenter))
 265       (if (not (bobp))
 266           (condition-case nil
 267               (scroll-down lines)
 268             (error))
 269         (setq top t)))
 270     (if real-top
 271         (let ((f (assq (mime-preview-original-major-mode)
 272                        mime-preview-over-to-previous-method-alist)))
 273           (if f (funcall (cdr f))))
 274       (when cur-buf
 275         (select-window (get-buffer-window cur-buf))))
 276     top))
 277
 278 (defun wl-message-next-page (&optional lines)
 279   "Scroll up current message by LINES.
 280 Returns non-nil if bottom of message."
 281   (interactive)
 282   (let (cur-buf bottom)
 283     (unless (eq major-mode 'mime-view-mode)
 284       (when (buffer-live-p wl-message-buffer)
 285         (setq cur-buf (current-buffer))
 286         (wl-message-select-buffer wl-message-buffer)))
 287     (move-to-window-line -1)
 288     (if (save-excursion
 289           (end-of-line)
 290           (and (pos-visible-in-window-p)
 291                (eobp)))
 292         (if (or (null wl-break-pages)
 293                 (save-excursion
 294                   (save-restriction
 295                     (widen) (forward-line) (eobp))))
 296             (setq bottom t)
 297           (wl-message-narrow-to-page 1)
 298           (setq bottom nil))
 299       (condition-case ()
 300           (static-if (boundp 'window-pixel-scroll-increment)
 301               ;; XEmacs 21.2.20 and later.
 302               (let (window-pixel-scroll-increment)
 303                 (scroll-up lines))
 304             (scroll-up lines))
 305         (end-of-buffer
 306          (goto-char (point-max))))
 307       (setq bottom nil))
 308     (if (eobp)
 309         (let ((f (assq (mime-preview-original-major-mode)
 310                        mime-preview-over-to-next-method-alist)))
 311           (if f (funcall (cdr f))))
 312       (when cur-buf
 313         (select-window (get-buffer-window cur-buf))))
 314     bottom))
 315
 316
 317 (defun wl-message-follow-current-entity (buffer)
 318   "Follow to current message."
 319   (wl-draft-reply (wl-message-get-original-buffer)
 320                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 321   (let ((mail-reply-buffer buffer))
 322     (wl-draft-yank-from-mail-reply-buffer nil)))
 323
 324 ;;
 325
 326 (defun wl-message-mode ()
 327   "A major mode for message displaying."
 328   (interactive)
 329   (setq major-mode 'wl-message-mode)
 330   (setq buffer-read-only t)
 331   (setq mode-name "Message"))
 332
 333 (defun wl-message-exit ()
 334   "Move to summary buffer."
 335   (interactive)
 336   (let (summary-buf summary-win)
 337     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 338         (if (setq summary-win (get-buffer-window summary-buf))
 339             (select-window summary-win)
 340           (switch-to-buffer summary-buf)
 341           (wl-message-select-buffer wl-message-buffer)
 342           (select-window (get-buffer-window summary-buf))))
 343     (run-hooks 'wl-message-exit-hook)))
 344
 345 (defun wl-message-toggle-disp-summary ()
 346   (interactive)
 347   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 348         summary-win)
 349     (if (and summary-buf
 350              (buffer-live-p summary-buf))
 351         (if (setq summary-win (get-buffer-window summary-buf))
 352             (delete-window summary-win)
 353           (switch-to-buffer summary-buf)
 354           (wl-message-select-buffer wl-message-buffer))
 355       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 356                                    nil nil t)
 357                                         ; no summary-buf
 358       (let ((sum-buf (current-buffer)))
 359         (wl-message-select-buffer wl-message-buffer)
 360         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 361
 362 (defun wl-message-get-original-buffer ()
 363   "Get original buffer for current message buffer."
 364   wl-message-buffer-original-buffer)
 365
 366 (defun wl-message-redisplay (folder number flag &optional force-reload)
 367   (let* ((default-mime-charset wl-mime-charset)
 368          (buffer-read-only nil)
 369          (summary-buf (current-buffer))
 370          message-buf
 371          strategy entity
 372          cache-used
 373          header-end real-fld-num summary-win)
 374     (setq buffer-read-only nil)
 375     (setq cache-used (wl-message-buffer-display
 376                       folder number flag force-reload))
 377     (setq wl-message-buffer (car cache-used))
 378     (setq message-buf wl-message-buffer)
 379     (wl-message-select-buffer wl-message-buffer)
 380
 381     (set-buffer message-buf)
 382     (setq truncate-lines wl-message-truncate-lines)
 383     (setq buffer-read-only nil)
 384     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 385     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 386     (setq wl-message-buffer-cur-number number)
 387     (wl-message-overload-functions)
 388     (setq mode-line-buffer-identification
 389           (format "Wanderlust: << %s / %s >>"
 390                   (if (memq 'modeline wl-use-folder-petname)
 391                       (wl-folder-get-petname (elmo-folder-name-internal
 392                                               folder))
 393                     (elmo-folder-name-internal folder)) number))
 394     ;; highlight body
 395 ;    (when wl-highlight-body-too
 396 ;      (wl-highlight-body))
 397     (condition-case ()
 398         (wl-message-narrow-to-page)
 399       (error nil)); ignore errors.
 400     (setq cache-used (cdr cache-used))
 401     (goto-char (point-min))
 402     (unwind-protect
 403         (save-excursion
 404           (run-hooks 'wl-message-redisplay-hook))
 405       ;; go back to summary mode
 406       (set-buffer-modified-p nil)
 407       (setq buffer-read-only t)
 408       (set-buffer summary-buf)
 409       (setq summary-win (get-buffer-window summary-buf))
 410       (if (window-live-p summary-win)
 411           (select-window summary-win)))
 412     cache-used))
 413
 414 ;; Use message buffer cache.
 415 (defun wl-message-buffer-display (folder number flag
 416                                          &optional force-reload unread)
 417   (let* ((msg-id (elmo-message-field folder number 'message-id))
 418          (fname (elmo-folder-name-internal folder))
 419          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 420          (read nil)
 421          cache-used)
 422     (when (and hit (not (buffer-live-p hit)))
 423       (wl-message-buffer-cache-delete (list fname number msg-id))
 424       (setq hit nil))
 425     (if hit
 426         (progn
 427           ;; move hit to the top.
 428           (wl-message-buffer-cache-sort
 429            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 430           ;; buffer cache is used.
 431           (setq cache-used t)
 432           (with-current-buffer hit
 433             (unless (eq wl-message-buffer-cur-flag flag)
 434               (setq read t))))
 435       ;; delete tail and add new to the top.
 436       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 437       (setq read t))
 438     (if (or force-reload read)
 439         (condition-case err
 440             (save-excursion
 441               (set-buffer hit)
 442               (setq
 443                cache-used
 444                (wl-message-display-internal folder number flag
 445                                             force-reload unread))
 446               (setq wl-message-buffer-cur-flag flag))
 447           (quit
 448            (wl-message-buffer-cache-delete)
 449            (error "Display message %s/%s is quitted" fname number))
 450           (error
 451            (wl-message-buffer-cache-delete)
 452            (signal (car err) (cdr err))
 453            nil))) ;; will not be used
 454     (cons hit cache-used)))
 455
 456 (defun wl-message-display-internal (folder number flag
 457                                            &optional force-reload unread)
 458   (let ((elmo-message-ignored-field-list
 459          (if (eq flag 'all-header)
 460              nil
 461            wl-message-ignored-field-list))
 462         (elmo-message-visible-field-list wl-message-visible-field-list)
 463         (elmo-message-sorted-field-list wl-message-sort-field-list)
 464         (elmo-message-fetch-threshold wl-fetch-confirm-threshold))
 465     (prog1
 466         (if (eq flag 'as-is)
 467             (let (wl-highlight-x-face-function)
 468               (elmo-mime-display-as-is folder number
 469                                        (current-buffer)
 470                                        (wl-message-get-original-buffer)
 471                                        'wl-original-message-mode
 472                                        force-reload
 473                                        unread))
 474           (elmo-mime-message-display folder number
 475                                      (current-buffer)
 476                                      (wl-message-get-original-buffer)
 477                                      'wl-original-message-mode
 478                                      force-reload
 479                                      unread))
 480       (setq buffer-read-only t))))
 481
 482 (defsubst wl-message-buffer-prefetch-p (folder &optional number)
 483   (cond
 484    ((eq wl-message-buffer-prefetch-folder-type-list t)
 485     t)
 486    ((and number wl-message-buffer-prefetch-folder-type-list)
 487     (memq (elmo-folder-type-internal
 488            (elmo-message-folder folder number))
 489           wl-message-buffer-prefetch-folder-type-list))
 490    (wl-message-buffer-prefetch-folder-type-list
 491     (let ((list wl-message-buffer-prefetch-folder-type-list)
 492           type)
 493       (catch 'done
 494         (while (setq type (pop list))
 495           (if (elmo-folder-contains-type folder type)
 496               (throw 'done t))))))
 497    ((consp wl-message-buffer-prefetch-folder-type-list)
 498     (wl-string-match-member (elmo-folder-name-internal folder)
 499                             wl-message-buffer-prefetch-folder-type-list))
 500    (t wl-message-buffer-prefetch-folder-type-list)))
 501
 502
 503 (defvar wl-message-buffer-prefetch-timer nil)
 504
 505 (defun wl-message-buffer-prefetch-next (folder number &optional
 506                                                summary charset)
 507   (if (wl-message-buffer-prefetch-p folder)
 508       (with-current-buffer (or summary (get-buffer wl-summary-buffer-name))
 509         (let* ((next (funcall wl-message-buffer-prefetch-get-next-function
 510                               number)))
 511           (when (and next (wl-message-buffer-prefetch-p folder next))
 512             (if (not (fboundp 'run-with-idle-timer))
 513                 (when (sit-for wl-message-buffer-prefetch-idle-time)
 514                   (wl-message-buffer-prefetch folder next summary charset))
 515               (unless wl-message-buffer-prefetch-timer
 516                 (setq wl-message-buffer-prefetch-timer
 517                       (run-with-idle-timer
 518                        wl-message-buffer-prefetch-idle-time
 519                        nil
 520                        'wl-message-buffer-prefetch
 521                        folder next summary charset)))))))))
 522
 523 (defun wl-message-buffer-prefetch (folder number summary charset)
 524   (when (buffer-live-p summary)
 525     (save-excursion
 526       (set-buffer summary)
 527       (when (string= (elmo-folder-name-internal folder)
 528                      (wl-summary-buffer-folder-name))
 529         (let ((message-id (elmo-message-field folder number 'message-id))
 530               (wl-mime-charset      charset)
 531               (default-mime-charset charset)
 532               result time1 time2 sec micro)
 533           (if (not (wl-message-buffer-cache-hit (list folder
 534                                                       number message-id)))
 535               (let* ((size (elmo-message-field folder number 'size)))
 536                 (when (or (elmo-message-file-p folder number)
 537                           (not
 538                            (and (integerp size)
 539                                 elmo-message-fetch-threshold
 540                                 (>= size
 541                                     elmo-message-fetch-threshold))))
 542                   ;;(not (elmo-file-cache-exists-p message-id)))))
 543                   (when wl-message-buffer-prefetch-debug
 544                     (setq time1 (current-time))
 545                     (message "Prefetching %d..." number))
 546                   (setq result (wl-message-buffer-display folder number
 547                                                           'mime nil 'unread))
 548                   (when wl-message-buffer-prefetch-debug
 549                     (setq time2 (current-time))
 550                     (setq sec  (- (nth 1 time2)(nth 1 time1)))
 551                     (setq micro (- (nth 2 time2)(nth 2 time1)))
 552                     (setq micro (+ micro (* 1000000 sec)))
 553                     (message "Prefetching %d...done(%f msec)."
 554                              number
 555                              (/ micro 1000.0))))))))))
 556   (setq wl-message-buffer-prefetch-timer nil))
 557
 558 (defvar wl-message-button-map (make-sparse-keymap))
 559
 560 (defun wl-message-add-button (from to function &optional data)
 561   "Create a button between FROM and TO with callback FUNCTION and DATA."
 562   (add-text-properties
 563    from to
 564    (nconc (list 'wl-message-button-callback function)
 565           (if data
 566               (list 'wl-message-button-data data))))
 567   (let ((ov (make-overlay from to)))
 568     (overlay-put ov 'mouse-face 'highlight)
 569     (overlay-put ov 'local-map wl-message-button-map)
 570     (overlay-put ov 'evaporate t)))
 571
 572 (defun wl-message-button-dispatcher (event)
 573   "Select the button under point."
 574   (interactive "@e")
 575   (mouse-set-point event)
 576   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 577         (data (get-text-property (point) 'wl-message-button-data)))
 578     (if callback
 579         (funcall callback data)
 580       (wl-message-button-dispatcher-internal event))))
 581
 582 (defun wl-message-button-refer-article (data)
 583   "Read article specified by Message-ID DATA at point."
 584   (switch-to-buffer-other-window
 585    wl-message-buffer-cur-summary-buffer)
 586   (if (wl-summary-jump-to-msg-by-message-id data)
 587       (wl-summary-redisplay)))
 588
 589 (defun wl-message-refer-article-or-url (e)
 590   "Read article specified by message-id around point.
 591 If failed, attempt to execute button-dispatcher."
 592   (interactive "e")
 593   (let ((window (get-buffer-window (current-buffer)))
 594         mouse-window point beg end msg-id)
 595     (unwind-protect
 596         (progn
 597           (mouse-set-point e)
 598           (setq mouse-window (get-buffer-window (current-buffer)))
 599           (setq point (point))
 600           (setq beg (save-excursion (beginning-of-line) (point)))
 601           (setq end (save-excursion (end-of-line) (point)))
 602           (search-forward ">" end t)      ;Move point to end of "<....>".
 603           (if (and (re-search-backward "\\(<[^<> \t\n]+@[^<> \t\n]+>\\)"
 604                                        beg t)
 605                    (not (string-match "mailto:"
 606                                       (setq msg-id (wl-match-buffer 1)))))
 607               (progn
 608                 (goto-char point)
 609                 (switch-to-buffer-other-window
 610                  wl-message-buffer-cur-summary-buffer)
 611                 (if (wl-summary-jump-to-msg-by-message-id msg-id)
 612                     (wl-summary-redisplay)))
 613             (wl-message-button-dispatcher-internal e)))
 614       (if (eq mouse-window (get-buffer-window (current-buffer)))
 615           (select-window window)))))
 616
 617 (defun wl-message-uu-substring (buf outbuf &optional first last)
 618   (save-excursion
 619     (set-buffer buf)
 620     (search-forward "\n\n")
 621     (let ((sp (point))
 622           ep filename case-fold-search)
 623       (catch 'done
 624         (if first
 625             (progn
 626               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 627                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 628                 (throw 'done nil)))
 629           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 630         (beginning-of-line)
 631         (setq sp (point))
 632         (goto-char (point-max))
 633         (if last
 634             (re-search-backward "^end" sp t)
 635           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 636         (forward-line 1)
 637         (setq ep (point))
 638         (set-buffer outbuf)
 639         (goto-char (point-max))
 640         (insert-buffer-substring buf sp ep)
 641         (set-buffer buf)
 642         filename))))
 643
 644 (require 'product)
 645 (product-provide (provide 'wl-message) (require 'wl-version))
 646
 647 ;;; wl-message.el ends here