wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36 (require 'timer)
  37
  38 (eval-when-compile
  39   (require 'wl-mime)
  40   (require 'mime-view)
  41   (defalias-maybe 'event-window 'ignore)
  42   (defalias-maybe 'posn-window 'ignore)
  43   (defalias-maybe 'event-start 'ignore)
  44   (defalias-maybe 'mime-open-entity 'ignore)
  45   (defalias-maybe 'itimer-function 'ignore)
  46   (defalias-maybe 'delete-itimer 'ignore)
  47   (defvar-maybe itimer-list))
  48
  49 (defvar wl-message-buffer-prefetch-get-next-function
  50   'wl-summary-default-get-next-msg)
  51
  52 (defvar wl-message-buffer-prefetch-debug nil)
  53 (defvar wl-message-buffer-prefetch-timer nil)
  54
  55 (defvar wl-message-buffer nil) ; message buffer.
  56
  57 (defvar wl-message-buffer-cur-folder nil)
  58 (defvar wl-message-buffer-cur-number nil)
  59 (defvar wl-message-buffer-cur-display-type nil)
  60 (defvar wl-message-buffer-cur-summary-buffer nil)
  61 (defvar wl-message-buffer-require-all-header nil)
  62 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  63 (defvar wl-message-buffer-mode-line-formatter nil)
  64 (defvar wl-message-buffer-flag-indicator nil)
  65
  66 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  67 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-display-type)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  70 (make-variable-buffer-local 'wl-message-buffer-require-all-header)
  71 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  72 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  73 (make-variable-buffer-local 'wl-message-buffer-flag-indicator)
  74
  75 (defvar wl-fixed-window-configuration nil)
  76
  77 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  78
  79 ;;; Message buffer cache.
  80
  81 (defvar wl-message-buffer-cache nil
  82   "Message cache.  (old ... new) order alist.
  83 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  84
  85 (defmacro wl-message-buffer-cache-buffer-get (entry)
  86   (` (cdr (, entry))))
  87
  88 (defmacro wl-message-buffer-cache-folder-get (entry)
  89   (` (car (car (, entry)))))
  90
  91 (defmacro wl-message-buffer-cache-message-get (entry)
  92   (` (cdr (car (, entry)))))
  93
  94 (defmacro wl-message-buffer-cache-entry-make (key buf)
  95   (` (cons (, key) (, buf))))
  96
  97 (defmacro wl-message-buffer-cache-hit (key)
  98   "Return value assosiated with key."
  99   (` (wl-message-buffer-cache-buffer-get
 100       (assoc (, key) wl-message-buffer-cache))))
 101
 102 (defun wl-message-buffer-cache-sort (entry)
 103   "Move ENTRY to the top of `wl-message-buffer-cache'."
 104   (setq wl-message-buffer-cache
 105         (cons entry (delete entry wl-message-buffer-cache))))
 106 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 107 ;        (top pointer))
 108 ;    (while (cdr pointer)
 109 ;      (if (equal (car (cdr pointer)) entry)
 110 ;         (setcdr pointer (cdr (cdr pointer)))
 111 ;       (setq pointer (cdr pointer))))
 112 ;    (setcdr pointer (list entry))
 113 ;    (setq wl-message-buffer-cache (cdr top))))
 114
 115 (defconst wl-original-message-buffer-name " *Original*")
 116
 117 (defun wl-original-message-mode ()
 118   "A major mode for original message buffer."
 119   (setq major-mode 'wl-original-message-mode)
 120   (setq buffer-read-only t)
 121   (set-buffer-multibyte nil)
 122   (setq mode-name "Wanderlust original message"))
 123
 124 (defun wl-original-message-buffer-get (name)
 125   "Get original message buffer for NAME.
 126 If original message buffer already exists, it is re-used."
 127   (let* ((name (concat wl-original-message-buffer-name name))
 128          (buffer (get-buffer name)))
 129     (unless (and buffer (buffer-live-p buffer))
 130       (with-current-buffer (setq buffer (get-buffer-create name))
 131         (wl-original-message-mode)))
 132     buffer))
 133
 134 (defun wl-message-buffer-create ()
 135   "Create a new message buffer."
 136   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 137          (name (buffer-name buffer)))
 138     (with-current-buffer buffer
 139       (setq wl-message-buffer-original-buffer
 140             (wl-original-message-buffer-get name))
 141       (when wl-message-use-header-narrowing
 142         (wl-message-header-narrowing-setup))
 143       (run-hooks 'wl-message-buffer-created-hook))
 144     buffer))
 145
 146 (defun wl-message-buffer-cache-add (key)
 147   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 148 Return its cache buffer."
 149   (let ((len (length wl-message-buffer-cache))
 150         (buf nil))
 151     (if (< len wl-message-buffer-cache-size)
 152         (setq buf (wl-message-buffer-create))
 153       (let ((entry (nth (1- len) wl-message-buffer-cache)))
 154         (if (buffer-live-p
 155              (setq buf (wl-message-buffer-cache-buffer-get entry)))
 156             (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil)
 157           (setq wl-message-buffer-cache (delq entry wl-message-buffer-cache))
 158           (setq buf (wl-message-buffer-create)))))
 159     (setq wl-message-buffer-cache
 160           (cons (wl-message-buffer-cache-entry-make key buf)
 161                 wl-message-buffer-cache))
 162     buf))
 163
 164 (defun wl-message-buffer-cache-delete (&optional key)
 165   "Delete the most recent cache entry"
 166   (if key
 167       (setq wl-message-buffer-cache
 168             (delq (assoc key wl-message-buffer-cache)
 169                   wl-message-buffer-cache))
 170     (let ((buf (wl-message-buffer-cache-buffer-get
 171                 (car wl-message-buffer-cache))))
 172       (setq wl-message-buffer-cache
 173             (nconc (cdr wl-message-buffer-cache)
 174                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 175
 176 (defun wl-message-buffer-cache-clean-up ()
 177   "A function to flush all decoded messages in cache list."
 178   (interactive)
 179   (if (and (eq major-mode 'wl-summary-mode)
 180            wl-message-buffer
 181            (get-buffer-window wl-message-buffer))
 182       (delete-window (get-buffer-window wl-message-buffer)))
 183   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 184   (setq wl-message-buffer-cache nil))
 185
 186 ;;; Message buffer handling from summary buffer.
 187
 188 (defun wl-message-buffer-window ()
 189   "Get message buffer window if any."
 190   (let* ((start-win (selected-window))
 191          (cur-win start-win))
 192     (catch 'found
 193       (while (progn
 194                (setq cur-win (next-window cur-win))
 195                (with-current-buffer (window-buffer cur-win)
 196                  (if (or (eq major-mode 'wl-message-mode)
 197                          (eq major-mode 'mime-view-mode))
 198                      (throw 'found cur-win)))
 199                (not (eq cur-win start-win)))))))
 200
 201 (defun wl-message-select-buffer (buffer)
 202   "Select BUFFER as a message buffer."
 203   (let ((window (get-buffer-window buffer))
 204         (sum (car wl-message-window-size))
 205         (mes (cdr wl-message-window-size))
 206         whi)
 207     (when (and window
 208                (not (eq (save-excursion (set-buffer (window-buffer window))
 209                                         wl-message-buffer-cur-summary-buffer)
 210                         (current-buffer))))
 211       (delete-window window)
 212       (run-hooks 'wl-message-window-deleted-hook)
 213       (setq window nil))
 214     (if window
 215         (select-window window)
 216       (when wl-fixed-window-configuration
 217         (delete-other-windows)
 218         (and wl-stay-folder-window
 219              (wl-summary-toggle-disp-folder)))
 220       ;; There's no buffer window. Search for message window and snatch it.
 221       (if (setq window (wl-message-buffer-window))
 222           (select-window window)
 223         (setq whi (1- (window-height)))
 224         (if mes
 225             (progn
 226               (let ((total (+ sum mes)))
 227                 (setq sum (max window-min-height (/ (* whi sum) total)))
 228                 (setq mes (max window-min-height (/ (* whi mes) total))))
 229               (if (< whi (+ sum mes))
 230                   (enlarge-window (- (+ sum mes) whi)))))
 231         (split-window (get-buffer-window (current-buffer)) sum)
 232         (other-window 1)))
 233     (switch-to-buffer buffer)))
 234
 235 (defun wl-message-narrow-to-page (&optional arg)
 236   "Narrow to page.
 237 If ARG is specified, narrow to ARGth page."
 238   (interactive "P")
 239   (setq arg (if arg (prefix-numeric-value arg) 0))
 240   (save-excursion
 241     (condition-case ()
 242         (forward-page -1)               ; Beginning of current page.
 243       (beginning-of-buffer
 244        (goto-char (point-min))))
 245     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 246     (widen)
 247     (cond
 248      ((> arg 0) (forward-page arg))
 249      ((< arg 0) (forward-page (1- arg))))
 250     (forward-page)
 251     (if wl-break-pages
 252         (narrow-to-region (point)
 253                           (progn
 254                             (forward-page -1)
 255                             (if (and (eolp) (not (bobp)))
 256                                 (forward-line))
 257                             (point))))))
 258
 259 (defun wl-message-prev-page (&optional lines)
 260   "Scroll down current message by LINES.
 261 Returns non-nil if top of message."
 262   (interactive)
 263   (let (top real-top)
 264     (save-selected-window
 265       (unless (eq major-mode 'mime-view-mode)
 266         (when (buffer-live-p wl-message-buffer)
 267           (wl-message-select-buffer wl-message-buffer)))
 268       (move-to-window-line 0)
 269       (if (and wl-break-pages
 270                (bobp)
 271                (not (setq real-top (save-restriction (widen) (bobp)))))
 272           (progn
 273             (wl-message-narrow-to-page -1)
 274             (goto-char (point-max))
 275             (recenter))
 276         (if (not (bobp))
 277             (condition-case nil
 278                 (scroll-down (or lines wl-message-scroll-amount))
 279               (error))
 280           (setq top t)))
 281       (if real-top
 282           (let ((f (assq (mime-preview-original-major-mode)
 283                          mime-preview-over-to-previous-method-alist)))
 284             (if f (funcall (cdr f))))))
 285     top))
 286
 287 (defun wl-message-next-page (&optional lines)
 288   "Scroll up current message by LINES.
 289 Returns non-nil if bottom of message."
 290   (interactive)
 291   (let (bottom)
 292     (save-selected-window
 293       (unless (eq major-mode 'mime-view-mode)
 294         (when (buffer-live-p wl-message-buffer)
 295           (wl-message-select-buffer wl-message-buffer)))
 296       (move-to-window-line -1)
 297       (if (save-excursion
 298             (end-of-line)
 299             (and (pos-visible-in-window-p)
 300                  (eobp)))
 301           (if (or (null wl-break-pages)
 302                   (save-excursion
 303                     (save-restriction
 304                       (widen) (forward-line) (eobp))))
 305               (setq bottom t)
 306             (wl-message-narrow-to-page 1)
 307             (setq bottom nil))
 308         (condition-case ()
 309             (static-if (boundp 'window-pixel-scroll-increment)
 310                 ;; XEmacs 21.2.20 and later.
 311                 (let (window-pixel-scroll-increment)
 312                   (scroll-up (or lines wl-message-scroll-amount)))
 313               (scroll-up (or lines wl-message-scroll-amount)))
 314           (end-of-buffer
 315            (goto-char (point-max))))
 316         (setq bottom nil))
 317       (if (eobp)
 318           (let ((f (assq (mime-preview-original-major-mode)
 319                          mime-preview-over-to-next-method-alist)))
 320             (if f (funcall (cdr f))))))
 321     bottom))
 322
 323
 324 (defun wl-message-follow-current-entity (buffer)
 325   "Follow to current message."
 326   (wl-draft-reply (wl-message-get-original-buffer)
 327                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 328   (let ((mail-reply-buffer buffer))
 329     (wl-draft-yank-from-mail-reply-buffer nil)))
 330
 331 ;;
 332
 333 (defun wl-message-mode ()
 334   "A major mode for message displaying."
 335   (interactive)
 336   (setq major-mode 'wl-message-mode)
 337   (setq buffer-read-only t)
 338   (setq mode-name "Message"))
 339
 340 (defun wl-message-exit ()
 341   "Move to summary buffer."
 342   (interactive)
 343   (let (summary-buf summary-win)
 344     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 345         (if (setq summary-win (get-buffer-window summary-buf))
 346             (select-window summary-win)
 347           (switch-to-buffer summary-buf)
 348           (wl-message-select-buffer wl-message-buffer)
 349           (select-window (get-buffer-window summary-buf))))
 350     (run-hooks 'wl-message-exit-hook)))
 351
 352 (defun wl-message-toggle-disp-summary ()
 353   (interactive)
 354   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 355         summary-win)
 356     (if (and summary-buf
 357              (buffer-live-p summary-buf))
 358         (if (setq summary-win (get-buffer-window summary-buf))
 359             (delete-window summary-win)
 360           (switch-to-buffer summary-buf)
 361           (wl-message-select-buffer wl-message-buffer))
 362       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 363                                    nil nil t)
 364                                         ; no summary-buf
 365       (let ((sum-buf (current-buffer)))
 366         (wl-message-select-buffer wl-message-buffer)
 367         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 368
 369 (defun wl-message-get-original-buffer ()
 370   "Get original buffer for current message buffer."
 371   (if (buffer-live-p wl-message-buffer-original-buffer)
 372       wl-message-buffer-original-buffer
 373     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 374
 375 (defun wl-message-add-buttons-to-body (start end)
 376   (save-excursion
 377     (save-restriction
 378       (narrow-to-region start end)
 379       (let ((case-fold-search t)
 380             (alist wl-message-body-button-alist)
 381             entry)
 382         (while alist
 383           (setq entry (car alist)
 384                 alist (cdr alist))
 385           (goto-char (point-min))
 386           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 387             (unless (get-text-property (point) 'keymap)
 388               (wl-message-add-button
 389                (match-beginning (nth 1 entry))
 390                (match-end (nth 1 entry))
 391                (nth 2 entry)
 392                (match-string (nth 3 entry))))))))))
 393
 394 (defun wl-message-add-buttons-to-header (start end)
 395   (save-excursion
 396     (save-restriction
 397       (narrow-to-region start end)
 398       (let ((case-fold-search t)
 399             (alist wl-message-header-button-alist)
 400             entry)
 401         (while alist
 402           (setq entry (car alist)
 403                 alist (cdr alist))
 404           (goto-char (point-min))
 405           (while (re-search-forward (car entry) nil t)
 406             (setq start (match-beginning 0)
 407                   end (if (re-search-forward "^[^ \t]" nil t)
 408                           (match-beginning 0)
 409                         (point-max)))
 410             (goto-char start)
 411             (while (re-search-forward (nth 1 entry) end t)
 412               (wl-message-add-button
 413                (match-beginning (nth 2 entry))
 414                (match-end (nth 2 entry))
 415                (nth 3 entry) (match-string (nth 4 entry))))
 416             (goto-char end)))))))
 417
 418 (defun wl-message-redisplay (folder number display-type &optional force-reload)
 419   (let* ((default-mime-charset wl-mime-charset)
 420          (buffer-read-only nil)
 421          (summary-buf (current-buffer))
 422          message-buf
 423          strategy entity
 424          cache-used
 425          summary-win delim flags)
 426     (setq buffer-read-only nil)
 427     (setq cache-used (wl-message-buffer-display
 428                       folder number display-type force-reload))
 429     (setq wl-message-buffer (car cache-used))
 430     (setq message-buf wl-message-buffer)
 431     (wl-message-select-buffer wl-message-buffer)
 432
 433     (set-buffer message-buf)
 434     (wl-deactivate-region)
 435     (make-local-variable 'truncate-partial-width-windows)
 436     (setq truncate-partial-width-windows nil)
 437     (setq truncate-lines wl-message-truncate-lines)
 438     (setq buffer-read-only nil)
 439     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 440     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 441     (setq wl-message-buffer-cur-number number)
 442     (setq wl-message-buffer-flag-indicator
 443           (if (setq flags (elmo-get-global-flags (elmo-message-flags
 444                                                   folder number)))
 445               (let ((fl wl-summary-flag-alist)
 446                     flag-strings flag-string face)
 447                 (while fl
 448                   (when (memq (car (car fl)) flags)
 449                     (setq flag-string (capitalize
 450                                        (symbol-name (car (car fl))))
 451                           flags (delq (car (car fl)) flags))
 452                     (when (facep (setq face
 453                                        (intern
 454                                         (format
 455                                          "wl-highlight-summary-%s-flag-face"
 456                                          (car (car fl))))))
 457                       (put-text-property 0 (length flag-string)
 458                                          'face face flag-string))
 459                     (setq flag-strings (nconc flag-strings
 460                                               (list flag-string))))
 461                   (setq fl (cdr fl)))
 462                 (setq flag-strings
 463                       (nconc flag-strings
 464                              (mapcar (lambda (flag)
 465                                        (capitalize (symbol-name flag)))
 466                                      flags)))
 467                 (concat " (" (mapconcat 'identity flag-strings ", ") ")"))
 468             ""))
 469     (wl-line-formatter-setup
 470      wl-message-buffer-mode-line-formatter
 471      wl-message-mode-line-format
 472      wl-message-mode-line-format-spec-alist)
 473     (setq mode-line-buffer-identification
 474           (funcall wl-message-buffer-mode-line-formatter))
 475     ;; highlight body
 476 ;    (when wl-highlight-body-too
 477 ;      (wl-highlight-body))
 478     (ignore-errors (wl-message-narrow-to-page))
 479     (setq cache-used (cdr cache-used))
 480     (goto-char (point-min))
 481     (when (re-search-forward "^$" nil t)
 482       (wl-message-add-buttons-to-header (point-min) (point))
 483       (wl-message-add-buttons-to-body (point) (point-max)))
 484     (when wl-message-use-header-narrowing
 485       (wl-message-header-narrowing))
 486     (goto-char (point-min))
 487     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 488     ;; go back to summary mode
 489     (set-buffer-modified-p nil)
 490     (setq buffer-read-only t)
 491     (set-buffer summary-buf)
 492     (setq summary-win (get-buffer-window summary-buf))
 493     (if (window-live-p summary-win)
 494         (select-window summary-win))
 495     cache-used))
 496
 497 ;; Use message buffer cache.
 498 (defun wl-message-buffer-display (folder number display-type
 499                                          &optional force-reload unread)
 500   (let* ((msg-id (ignore-errors (elmo-message-field folder number
 501                                                     'message-id)))
 502          (fname (elmo-folder-name-internal folder))
 503          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 504          (read nil)
 505          cache-used)
 506     (when (and hit (not (buffer-live-p hit)))
 507       (wl-message-buffer-cache-delete (list fname number msg-id))
 508       (setq hit nil))
 509     (if hit
 510         (progn
 511           ;; move hit to the top.
 512           (wl-message-buffer-cache-sort
 513            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 514           ;; buffer cache is used.
 515           (setq cache-used t)
 516           (with-current-buffer hit
 517             ;; Rewind to the top page
 518             (widen)
 519             (goto-char (point-min))
 520             (ignore-errors (wl-message-narrow-to-page))
 521             (unless (eq wl-message-buffer-cur-display-type display-type)
 522               (setq read t))))
 523       ;; delete tail and add new to the top.
 524       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 525       (setq read t))
 526     (if (or force-reload read)
 527         (condition-case err
 528             (save-excursion
 529               (set-buffer hit)
 530               (setq
 531                cache-used
 532                (wl-message-display-internal folder number display-type
 533                                             force-reload unread))
 534               (setq wl-message-buffer-cur-display-type display-type))
 535           (quit
 536            (wl-message-buffer-cache-delete)
 537            (error "Display message %s/%s is quitted" fname number))
 538           (error
 539            (wl-message-buffer-cache-delete)
 540            (signal (car err) (cdr err))
 541            nil))) ;; will not be used
 542     (cons hit cache-used)))
 543
 544 (defun wl-message-display-internal (folder number display-type
 545                                            &optional force-reload unread)
 546   (let ((default-mime-charset wl-mime-charset)
 547         (elmo-mime-charset wl-mime-charset))
 548     (setq wl-message-buffer-require-all-header (eq display-type
 549                                                    'all-header))
 550     (prog1
 551         (if (eq display-type 'as-is)
 552             (let (wl-highlight-x-face-function)
 553               (prog1 (elmo-mime-display-as-is folder number
 554                                               (current-buffer)
 555                                               (wl-message-get-original-buffer)
 556                                               'wl-original-message-mode
 557                                               force-reload
 558                                               unread
 559                                               (wl-message-define-keymap))
 560                 (let (buffer-read-only)
 561                   (wl-highlight-message (point-min) (point-max) t))))
 562           (elmo-mime-message-display folder number
 563                                      (current-buffer)
 564                                      (wl-message-get-original-buffer)
 565                                      'wl-original-message-mode
 566                                      force-reload
 567                                      unread
 568                                      (wl-message-define-keymap)))
 569       (run-hooks 'wl-message-display-internal-hook)
 570       (setq buffer-read-only t))))
 571
 572 (defun wl-message-buffer-prefetch-p (folder &optional number)
 573   (and (or (not number)
 574            (elmo-message-file-p folder number)
 575            (let ((size (elmo-message-field folder number 'size)))
 576              (not (and (integerp size)
 577                        wl-message-buffer-prefetch-threshold
 578                        (>= size wl-message-buffer-prefetch-threshold)))))
 579        (or (not number)
 580            (elmo-folder-plugged-p folder)
 581            (elmo-file-cache-exists-p
 582                  (elmo-message-field folder number 'message-id)))
 583        (or (cond
 584             ((eq wl-message-buffer-prefetch-folder-type-list t)
 585              t)
 586             ((and number wl-message-buffer-prefetch-folder-type-list)
 587              (memq (elmo-folder-type-internal
 588                     (elmo-message-folder folder number))
 589                    wl-message-buffer-prefetch-folder-type-list))
 590             (wl-message-buffer-prefetch-folder-type-list
 591              (let ((list wl-message-buffer-prefetch-folder-type-list)
 592                    type)
 593                (catch 'done
 594                  (while (setq type (pop list))
 595                    (if (elmo-folder-contains-type folder type)
 596                        (throw 'done t)))))))
 597            (cond
 598             ((consp wl-message-buffer-prefetch-folder-list)
 599              (wl-string-match-member (elmo-folder-name-internal folder)
 600                                      wl-message-buffer-prefetch-folder-list))
 601             (t wl-message-buffer-prefetch-folder-list)))))
 602
 603 (defsubst wl-message-buffer-prefetch-clear-timer ()
 604 ;;;     cannot use for the bug of fsf-compat package (1.09).
 605 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 606   (if (fboundp 'run-with-idle-timer)
 607       (if (featurep 'xemacs)
 608           (let ((p itimer-list))
 609             (while (car p)
 610               (if (eq 'wl-message-buffer-prefetch-subr
 611                       (itimer-function (car p)))
 612                   (delete-itimer (car p)))
 613               (setq p (cdr p))))
 614         ;; FSF Emacs is correct
 615         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 616
 617 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 618                                                        summary charset)
 619   (if (not (fboundp 'run-with-idle-timer))
 620       (when (sit-for wl-message-buffer-prefetch-idle-time)
 621         (wl-message-buffer-prefetch-subr
 622          folder number count summary charset))
 623     (run-with-idle-timer
 624      wl-message-buffer-prefetch-idle-time
 625      nil
 626      'wl-message-buffer-prefetch-subr
 627      folder number count summary charset)))
 628
 629 (defvar wl-message-buffer-prefetch-move-spec-alist nil)
 630
 631 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 632   (if (buffer-live-p summary)
 633       (with-current-buffer summary
 634         (let ((wl-summary-move-spec-alist
 635                (or wl-message-buffer-prefetch-move-spec-alist
 636                    wl-summary-move-spec-alist))
 637               (next number))
 638           (while (and (setq next (funcall
 639                                   wl-message-buffer-prefetch-get-next-function
 640                                   next))
 641                       (not (wl-message-buffer-prefetch-p folder next))))
 642           next))))
 643
 644 (defun wl-message-buffer-prefetch (folder number count
 645                                           &optional summary charset)
 646   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 647          (num number))
 648     (when (and count
 649                (wl-message-buffer-prefetch-p folder))
 650       (unless (wl-message-buffer-prefetch-p folder number)
 651         (setq num
 652               (wl-message-buffer-prefetch-get-next folder number summary)))
 653       (when num
 654         (wl-message-buffer-prefetch-clear-timer)
 655         (wl-message-buffer-prefetch-set-timer
 656          folder num count summary charset)))))
 657
 658 (defun wl-message-buffer-prefetch-next (folder number count
 659                                                &optional summary charset)
 660   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 661          next)
 662     (when (and count
 663                (wl-message-buffer-prefetch-p folder))
 664       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 665       (when next
 666         (wl-message-buffer-prefetch-clear-timer)
 667         (wl-message-buffer-prefetch-set-timer
 668          folder next count summary charset)))))
 669
 670 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 671   (if (buffer-live-p summary)
 672       (with-current-buffer summary
 673         (if (and number
 674                  (numberp count)
 675                  (>= (setq count (- count 1)) 0)
 676                  (string= (elmo-folder-name-internal folder)
 677                           (wl-summary-buffer-folder-name)))
 678             (let* ((wl-mime-charset      charset)
 679                    (default-mime-charset charset)
 680                    (message-id (elmo-message-field folder number 'message-id))
 681                    (key (list (elmo-folder-name-internal folder)
 682                               number message-id))
 683                    (hit (wl-message-buffer-cache-hit key))
 684                    result time1 time2 sec micro)
 685               (when wl-message-buffer-prefetch-debug
 686                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 687               (if (and hit (buffer-live-p hit))
 688                   (progn
 689                     (wl-message-buffer-cache-sort
 690                      (wl-message-buffer-cache-entry-make key hit))
 691                     (wl-message-buffer-prefetch-subr
 692                      folder
 693                      (wl-message-buffer-prefetch-get-next
 694                       folder number summary)
 695                      count summary charset))
 696                 ;; prefetching
 697                 (when wl-message-buffer-prefetch-debug
 698                   (setq time1 (current-time))
 699                   (message "Prefetching %d..." number))
 700                 (setq result (wl-message-buffer-display
 701                               folder number 'mime nil 'unread))
 702                 (when wl-message-buffer-prefetch-debug
 703                   (setq time2 (current-time))
 704                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 705                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 706                   (setq micro (+ micro (* 1000000 sec)))
 707                   (message "Prefetching %d...done(%f msec)."
 708                            number
 709                            (/ micro 1000.0))
 710                   (sit-for 0))
 711                 ;; set next prefetch
 712                 (wl-message-buffer-prefetch-set-timer
 713                  folder
 714                  (wl-message-buffer-prefetch-get-next
 715                   folder number summary)
 716                  count summary charset)
 717                 (sit-for 0)
 718                 ;; success prefetch
 719                 )))
 720         ;; finish prefetch
 721         (when wl-message-buffer-prefetch-debug
 722           (message "Buffer Cached Messages: %s"
 723                    (mapconcat
 724                     '(lambda (cache)
 725                        (if (numberp (nth 1 (car cache)))
 726                            (if (string=
 727                                 (nth 0 (car cache))
 728                                 (elmo-folder-name-internal folder))
 729                                (format "%d"
 730                                        (nth 1 (car cache)))
 731                              (format "*%d" (nth 1 (car cache))))
 732                          "-"))
 733                     wl-message-buffer-cache " "))) )))
 734
 735 (defvar wl-message-button-map (make-sparse-keymap))
 736
 737 (defun wl-message-add-button (from to function &optional data)
 738   "Create a button between FROM and TO with callback FUNCTION and DATA."
 739   (add-text-properties
 740    from to
 741    (nconc (list 'wl-message-button-callback function)
 742           (if data
 743               (list 'wl-message-button-data data))))
 744   (let ((ov (make-overlay from to)))
 745     (overlay-put ov 'mouse-face 'highlight)
 746     (overlay-put ov 'local-map wl-message-button-map)
 747     (overlay-put ov 'evaporate t)))
 748
 749 (defun wl-message-button-dispatcher (event)
 750   "Select the button under point."
 751   (interactive "@e")
 752   (mouse-set-point event)
 753   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 754         (data (get-text-property (point) 'wl-message-button-data)))
 755     (if callback
 756         (funcall callback data)
 757       (wl-message-button-dispatcher-internal event))))
 758
 759 (defun wl-message-button-refer-article (data)
 760   "Read article specified by Message-ID DATA at point."
 761   (switch-to-buffer-other-window
 762    wl-message-buffer-cur-summary-buffer)
 763   (if (wl-summary-jump-to-msg-by-message-id data)
 764       (wl-summary-redisplay)))
 765
 766 (defun wl-message-uu-substring (buf outbuf &optional first last)
 767   (save-excursion
 768     (set-buffer buf)
 769     (search-forward "\n\n")
 770     (let ((sp (point))
 771           ep filename case-fold-search)
 772       (catch 'done
 773         (if first
 774             (progn
 775               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 776                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 777                 (throw 'done nil)))
 778           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 779         (beginning-of-line)
 780         (setq sp (point))
 781         (goto-char (point-max))
 782         (if last
 783             (re-search-backward "^end" sp t)
 784           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 785         (forward-line 1)
 786         (setq ep (point))
 787         (set-buffer outbuf)
 788         (goto-char (point-max))
 789         (insert-buffer-substring buf sp ep)
 790         (set-buffer buf)
 791         filename))))
 792
 793 ;;; Header narrowing courtesy of Hideyuki Shirai.
 794 (defun wl-message-header-narrowing ()
 795   "Narrowing headers."
 796   (unless (eq this-command 'wl-summary-redisplay-all-header)
 797     (save-excursion
 798       (save-restriction
 799         (goto-char (point-min))
 800         (if (re-search-forward "^$" nil t)
 801             (beginning-of-line)
 802           (goto-char (point-max)))
 803         (narrow-to-region (point-min) (point))
 804         (let ((fields wl-message-header-narrowing-fields))
 805           (while fields
 806             (wl-message-header-narrowing-1 (concat "^" (car fields) ":"))
 807             (setq fields (cdr fields))))))))
 808
 809 (defvar wl-message-header-narrowing-map (make-sparse-keymap))
 810 (define-key wl-message-header-narrowing-map [mouse-2]
 811   'wl-message-header-narrowing-again-at-mouse)
 812
 813 (defvar wl-message-header-narrowing-widen-map (make-sparse-keymap))
 814 (define-key wl-message-header-narrowing-widen-map [mouse-2]
 815   'wl-message-header-narrowing-widen-at-mouse)
 816
 817 (defun wl-message-header-narrowing-again-at-mouse (event)
 818   (interactive "e")
 819   (save-window-excursion
 820     (save-excursion
 821       (mouse-set-point event)
 822       (wl-message-header-narrowing))))
 823
 824 (defun wl-message-header-narrowing-1 (hregexp)
 825   (let ((case-fold-search t)
 826         ov start end)
 827     (goto-char (point-min))
 828     (while (re-search-forward hregexp nil t)
 829       (setq start (match-beginning 0))
 830       (forward-line 1)
 831       (setq end (progn (while (looking-at "^[ \t]") (forward-line))
 832                        (forward-line -1)
 833                        (line-end-position)))
 834       (if (<= (count-lines start end) wl-message-header-narrowing-lines)
 835           (forward-line 1)
 836         (goto-char start)
 837         (forward-line (1- wl-message-header-narrowing-lines))
 838         (end-of-line)
 839         (setq start (point))
 840         (unless (eq (get-char-property start 'invisible)
 841                     'wl-message-header-narrowing)
 842           (setq ov (or
 843                     (let ((ovs (overlays-at start))
 844                           ov)
 845                       (while (and ovs (not (overlayp ov)))
 846                         (if (overlay-get (car ovs)
 847                                          'wl-message-header-narrowing)
 848                             (setq ov (car ovs)))
 849                         (setq ovs (cdr ovs)))
 850                       ov)
 851                     (make-overlay start end)))
 852           (overlay-put ov 'wl-message-header-narrowing t)
 853           (overlay-put ov 'evaporate t)
 854           (overlay-put ov 'invisible 'wl-message-header-narrowing)
 855           (overlay-put ov 'after-string
 856                        wl-message-header-narrowing-string))))))
 857
 858 (defun wl-message-header-narrowing-widen-at-mouse (event)
 859   (interactive "e")
 860   (save-selected-window
 861     (select-window (posn-window (event-start event)))
 862     (let* ((win (selected-window))
 863            (wpos (window-start win))
 864            (pos (mouse-set-point event))
 865            (ovs (overlays-in (1- pos) (1+ pos)))        ;; Uum...
 866            ov)
 867       (while (and ovs (not (overlayp ov)))
 868         (when (overlay-get (car ovs) 'wl-message-header-narrowing)
 869           (setq ov (car ovs)))
 870         (setq ovs (cdr ovs)))
 871       (when (overlayp ov)
 872         (overlay-put ov 'face 'wl-message-header-narrowing-face)
 873         (overlay-put ov 'local-map wl-message-header-narrowing-map)
 874         (overlay-put ov 'invisible nil)
 875         (overlay-put ov 'after-string nil))
 876       (set-window-start win wpos))))
 877
 878 (defun wl-message-header-narrowing-setup ()
 879   (when (boundp 'line-move-ignore-invisible)
 880     (set (make-local-variable 'line-move-ignore-invisible) t))
 881   (set-text-properties 0 (length wl-message-header-narrowing-string)
 882                        `(face
 883                          wl-message-header-narrowing-face
 884                          keymap
 885                          ,wl-message-header-narrowing-widen-map)
 886                        wl-message-header-narrowing-string))
 887
 888 (defun wl-message-header-narrowing-toggle ()
 889   "Toggle header narrowing."
 890   (interactive)
 891   (when wl-message-use-header-narrowing
 892     (save-excursion
 893       (goto-char (point-min))
 894       (if (re-search-forward "^$" nil t)
 895           (beginning-of-line)
 896         (goto-char (point-max)))
 897       (let ((ovs (overlays-in (point-min) (point)))
 898             ov hn-ovs)
 899         (while (setq ov (car ovs))
 900           (when (overlay-get ov 'wl-message-header-narrowing)
 901             (setq hn-ovs (cons ov hn-ovs)))
 902           (setq ovs (cdr ovs)))
 903         (if hn-ovs
 904             (while hn-ovs
 905               (delete-overlay (car hn-ovs))
 906               (setq hn-ovs (cdr hn-ovs)))
 907           (wl-message-header-narrowing))))))
 908
 909 (require 'product)
 910 (product-provide (provide 'wl-message) (require 'wl-version))
 911
 912 ;;; wl-message.el ends here