wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'Meadow-version 'ignore))
  39
  40 (defvar xemacs-betaname)
  41 (defvar xemacs-codename)
  42 (defvar enable-multibyte-characters)
  43 (defvar mule-version)
  44
  45 ;;; Draft
  46
  47 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  48
  49 (defalias 'wl-draft-decode-message-in-buffer
  50   'mime-edit-decode-message-in-buffer)
  51
  52 (defun wl-draft-yank-current-message-entity ()
  53   "Yank currently displayed message entity.
  54 By setting following-method as yank-content."
  55   (let ((wl-draft-buffer (current-buffer))
  56         (mime-view-following-method-alist
  57          (list (cons 'wl-original-message-mode
  58                      (function wl-draft-yank-to-draft-buffer))))
  59         (mime-preview-following-method-alist
  60          (list (cons 'wl-original-message-mode
  61                      (function wl-draft-yank-to-draft-buffer)))))
  62     (if (get-buffer (wl-current-message-buffer))
  63         (save-excursion
  64           (save-restriction
  65             (set-buffer (wl-current-message-buffer))
  66             (widen)
  67             (mime-preview-follow-current-entity))))))
  68
  69 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
  70
  71 (defun wl-draft-preview-message ()
  72   ""
  73   (interactive)
  74   (let* (recipients-message
  75          (config-exec-flag wl-draft-config-exec-flag)
  76          (mime-display-header-hook 'wl-highlight-headers)
  77          (mime-header-encode-method-alist
  78           (append
  79            '((wl-draft-eword-encode-address-list
  80               .  (To Cc Bcc Resent-To Resent-Cc Bcc Resent-Bcc)))
  81            (if (boundp 'mime-header-encode-method-alist)
  82                (symbol-value 'mime-header-encode-method-alist))))
  83          mime-view-ignored-field-list   ; all header.
  84          (mime-edit-translate-buffer-hook
  85           (append
  86            (list
  87             (function
  88              (lambda ()
  89                (let ((wl-draft-config-exec-flag config-exec-flag))
  90                  (run-hooks 'wl-draft-send-hook)
  91                  (setq recipients-message
  92                        (condition-case err
  93                            (concat "Recipients: "
  94                                    (mapconcat
  95                                     'identity
  96                                     (wl-draft-deduce-address-list
  97                                      (current-buffer)
  98                                      (point-min)
  99                                      (save-excursion
 100                                        (goto-char (point-min))
 101                                        (re-search-forward
 102                                         (concat
 103                                          "^"
 104                                          (regexp-quote mail-header-separator)
 105                                          "$")
 106                                         nil t)
 107                                        (point)))
 108                                     ", "))
 109                          (error
 110                           (kill-buffer (current-buffer))
 111                           (signal (car err) (cdr err)))))))))
 112            mime-edit-translate-buffer-hook)))
 113     (mime-edit-preview-message)
 114     (let ((buffer-read-only nil))
 115       (when wl-highlight-body-too
 116         (wl-highlight-body))
 117       (run-hooks 'wl-draft-preview-message-hook))
 118     (message recipients-message)))
 119
 120 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 121
 122 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 123
 124 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 125
 126 ;;; Message
 127
 128 (defun wl-message-decode-mode (outbuf inbuf)
 129   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 130         (mime-display-header-hook 'wl-highlight-headers))
 131     (mime-view-mode nil nil nil inbuf outbuf)))
 132
 133 (defun wl-message-decode-with-all-header (outbuf inbuf)
 134   (let ((mime-view-ignored-field-regexp "^:$")
 135         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 136         (mime-display-header-hook 'wl-highlight-headers)
 137         mime-view-ignored-field-list)
 138     (mime-view-mode nil nil nil inbuf outbuf)))
 139
 140 (defun wl-message-delete-mime-out-buf ()
 141   (let (mime-out-buf mime-out-win)
 142     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 143         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 144             (delete-window mime-out-win)))))
 145
 146 (defun wl-message-request-partial (folder number)
 147   (elmo-set-work-buf
 148    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 149                        number
 150                        (elmo-make-fetch-strategy 'entire)
 151                        nil
 152                        (current-buffer)
 153                        'unread)
 154    (mime-parse-buffer nil)))
 155
 156 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 157 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 158 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 159 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 160 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 161 (defalias 'wl-message-quit              'mime-preview-quit)
 162 (defalias 'wl-message-button-dispatcher-internal
 163   'mime-button-dispatcher)
 164
 165 ;;; Summary
 166 (defun wl-summary-burst-subr (message-entity target number)
 167   ;; returns new number.
 168   (let (content-type entity)
 169     (setq content-type (mime-entity-content-type message-entity))
 170     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 171            (dolist (entity (mime-entity-children message-entity))
 172              (setq number (wl-summary-burst-subr
 173                            entity
 174                            target
 175                            number))))
 176           ((and (eq (cdr (assq 'type content-type)) 'message)
 177                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 178            (message "Bursting...%s" (setq number (+ 1 number)))
 179            (setq entity
 180                  (car (mime-entity-children message-entity)))
 181            (with-temp-buffer
 182              (insert (mime-entity-body message-entity))
 183              (elmo-folder-append-buffer
 184               target
 185               (mime-entity-fetch-field entity "Message-ID")))))
 186     number))
 187
 188 (defun wl-summary-burst ()
 189   ""
 190   (interactive)
 191   (let ((raw-buf (wl-summary-get-original-buffer))
 192         (view-buf wl-message-buffer)
 193         children message-entity content-type target)
 194     (save-excursion
 195       (setq target wl-summary-buffer-elmo-folder)
 196       (while (not (elmo-folder-writable-p target))
 197         (setq target
 198               (wl-summary-read-folder wl-default-folder "to extract to")))
 199       (wl-summary-set-message-buffer-or-redisplay)
 200       (with-current-buffer view-buf
 201         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 202       (when message-entity
 203         (message "Bursting...")
 204         (with-current-buffer raw-buf
 205           (wl-summary-burst-subr message-entity target 0))
 206         (message "Bursting...done"))
 207       (if (elmo-folder-plugged-p target)
 208           (elmo-folder-check target)))
 209     (wl-summary-sync-update)))
 210
 211 ;; internal variable.
 212 (defvar wl-mime-save-directory nil "Last saved directory.")
 213 ;;; Yet another save method.
 214 (defun wl-mime-save-content (entity situation)
 215   (let ((filename (read-file-name "Save to file: "
 216                                   (expand-file-name
 217                                    (or (mime-entity-safe-filename entity)
 218                                        ".")
 219                                    (or wl-mime-save-directory
 220                                        wl-temporary-file-directory)))))
 221     (while (file-directory-p filename)
 222       (setq filename (read-file-name "Please set filename (not directory): "
 223                                      filename)))
 224     (if (and (file-exists-p filename)
 225              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 226                                        filename))))
 227         (message "Not saved")
 228       (setq wl-mime-save-directory (file-name-directory filename))
 229       (mime-write-entity-content entity filename))))
 230
 231 ;;; Yet another combine method.
 232 (defun wl-mime-combine-message/partial-pieces (entity situation)
 233   "Internal method for wl to combine message/partial messages automatically."
 234   (interactive)
 235   (let* ((msgdb (save-excursion
 236                   (set-buffer wl-message-buffer-cur-summary-buffer)
 237                   (wl-summary-buffer-msgdb)))
 238          (mime-display-header-hook 'wl-highlight-headers)
 239          (folder wl-message-buffer-cur-folder)
 240          (id (or (cdr (assoc "id" situation)) ""))
 241          (mother (current-buffer))
 242          (summary-buf wl-message-buffer-cur-summary-buffer)
 243          subject-id overviews
 244          (root-dir (expand-file-name
 245                     (concat "m-prts-" (user-login-name))
 246                     temporary-file-directory))
 247          full-file point)
 248     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 249     (setq full-file (concat root-dir "/FULL"))
 250     (if (or (file-exists-p full-file)
 251             (not (y-or-n-p "Merge partials? ")))
 252         (with-current-buffer mother
 253           (mime-store-message/partial-piece entity situation)
 254           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 255           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 256           (setq mime-preview-over-to-next-method-alist
 257                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 258                       mime-preview-over-to-next-method-alist))
 259           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 260           (setq mime-preview-over-to-previous-method-alist
 261                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 262                       mime-preview-over-to-previous-method-alist)))
 263       (setq subject-id
 264             (eword-decode-string
 265              (decode-mime-charset-string
 266               (mime-entity-read-field entity 'Subject)
 267               wl-summary-buffer-mime-charset)))
 268       (if (string-match "[0-9\n]+" subject-id)
 269           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 270       (setq overviews (elmo-msgdb-get-overview msgdb))
 271       (catch 'tag
 272         (while overviews
 273           (when (string-match
 274                  (regexp-quote subject-id)
 275                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 276             (let* ((message
 277                     ;; request message at the cursor in Subject buffer.
 278                     (wl-message-request-partial
 279                      folder
 280                      (elmo-msgdb-overview-entity-get-number
 281                       (car overviews))))
 282                    (situation (mime-entity-situation message))
 283                    (the-id (or (cdr (assoc "id" situation)) "")))
 284               (when (string= (downcase the-id)
 285                              (downcase id))
 286                 (with-current-buffer mother
 287                   (mime-store-message/partial-piece message situation))
 288                 (if (file-exists-p full-file)
 289                     (throw 'tag nil)))))
 290           (setq overviews (cdr overviews)))
 291         (message "Not all partials found.")))))
 292
 293 (defun wl-mime-display-text/plain (entity situation)
 294   (let ((beg (point)))
 295     (mime-display-text/plain entity situation)
 296     (wl-highlight-message beg (point-max) t t)))
 297
 298 (defun wl-mime-display-header (entity situation)
 299   (let ((elmo-message-ignored-field-list
 300          (if wl-message-buffer-all-header-flag
 301              nil
 302            wl-message-ignored-field-list))
 303         (elmo-message-visible-field-list wl-message-visible-field-list)
 304         (elmo-message-sorted-field-list wl-message-sort-field-list))
 305     (elmo-mime-insert-header entity situation)
 306     (wl-highlight-headers)))
 307
 308 ;;; Setup methods.
 309 (defun wl-mime-setup ()
 310   (set-alist 'mime-preview-quitting-method-alist
 311              'wl-original-message-mode 'wl-message-exit)
 312   (set-alist 'mime-view-over-to-previous-method-alist
 313              'wl-original-message-mode 'wl-message-exit)
 314   (set-alist 'mime-view-over-to-next-method-alist
 315              'wl-original-message-mode 'wl-message-exit)
 316   (set-alist 'mime-preview-over-to-previous-method-alist
 317              'wl-original-message-mode 'wl-message-exit)
 318   (set-alist 'mime-preview-over-to-next-method-alist
 319              'wl-original-message-mode 'wl-message-exit)
 320   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 321   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 322
 323   (ctree-set-calist-strictly
 324    'mime-preview-condition
 325    '((type . text) (subtype . plain)
 326      (body . visible)
 327      (body-presentation-method . wl-mime-display-text/plain)
 328      (major-mode . wl-original-message-mode)))
 329
 330   (ctree-set-calist-strictly
 331    'mime-acting-condition
 332    '((type . message) (subtype . partial)
 333      (method .  wl-mime-combine-message/partial-pieces)
 334      (request-partial-message-method . wl-message-request-partial)
 335      (major-mode . wl-original-message-mode)))
 336
 337   (ctree-set-calist-strictly
 338    'mime-acting-condition
 339    '((mode . "extract")
 340      (major-mode . wl-original-message-mode)
 341      (method . wl-mime-save-content)))
 342   (set-alist 'mime-preview-following-method-alist
 343              'wl-original-message-mode
 344              (function wl-message-follow-current-entity))
 345   (set-alist 'mime-view-following-method-alist
 346              'wl-original-message-mode
 347              (function wl-message-follow-current-entity))
 348   (set-alist 'mime-edit-message-inserter-alist
 349              'wl-draft-mode (function wl-draft-insert-current-message))
 350   (set-alist 'mime-edit-mail-inserter-alist
 351              'wl-draft-mode (function wl-draft-insert-get-message))
 352   (set-alist 'mime-edit-split-message-sender-alist
 353              'wl-draft-mode
 354              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 355   (set-alist 'mime-raw-representation-type-alist
 356              'wl-original-message-mode 'binary)
 357   ;; Sort and highlight header fields.
 358   (or wl-message-ignored-field-list
 359       (setq wl-message-ignored-field-list
 360             mime-view-ignored-field-list))
 361   (or wl-message-visible-field-list
 362       (setq wl-message-visible-field-list
 363             mime-view-visible-field-list))
 364   (set-alist 'mime-header-presentation-method-alist
 365              'wl-original-message-mode
 366              'wl-mime-display-header)
 367   ;; To avoid overriding wl-draft-mode-map.
 368   (when (boundp 'mime-setup-signature-key-alist)
 369     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 370       (setq mime-setup-signature-key-alist
 371             (cons '(wl-draft-mode . "\C-c\C-w")
 372                   mime-setup-signature-key-alist)))))
 373
 374 (require 'product)
 375 (product-provide (provide 'wl-mime) (require 'wl-version))
 376
 377 ;;; wl-mime.el ends here