wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 ;;; Draft
  38
  39 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  40
  41 (defalias 'wl-draft-decode-message-in-buffer
  42   'mime-edit-decode-message-in-buffer)
  43
  44 (defun wl-draft-yank-current-message-entity ()
  45   "Yank currently displayed message entity.
  46 By setting following-method as yank-content.
  47
  48 If region is active, yank region contents instead. \(this feature is available
  49 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  50 has Non-nil value\)"
  51   (let ((wl-draft-buffer (current-buffer))
  52         (mime-view-following-method-alist
  53          (list (cons 'wl-original-message-mode
  54                      (function wl-draft-yank-to-draft-buffer))))
  55         (mime-preview-following-method-alist
  56          (list (cons 'wl-original-message-mode
  57                      (function wl-draft-yank-to-draft-buffer)))))
  58     (if (get-buffer (wl-current-message-buffer))
  59         (save-excursion
  60           (set-buffer (wl-current-message-buffer))
  61           (save-restriction
  62             (widen)
  63             (if (wl-region-exists-p)
  64                 (wl-mime-preview-follow-current-region)
  65               (mime-preview-follow-current-entity)))))))
  66
  67 ;; modified mime-preview-follow-current-entity from mime-view.el
  68 (defun wl-mime-preview-follow-current-region ()
  69   "Write follow message to current region.
  70 It calls following-method selected from variable
  71 `mime-preview-following-method-alist'."
  72   (interactive)
  73   (let ((r-beg (region-beginning))
  74         (r-end (region-end))
  75         (entity (get-text-property (point-min)
  76                                    'mime-view-entity)))
  77     (let* ((mode (mime-preview-original-major-mode 'recursive))
  78            (new-name
  79             (format "%s-active-region" (buffer-name)))
  80            new-buf
  81            (the-buf (current-buffer))
  82            fields)
  83       (save-excursion
  84         (set-buffer (setq new-buf (get-buffer-create new-name)))
  85         (erase-buffer)
  86         (insert ?\n)
  87         (insert-buffer-substring the-buf r-beg r-end)
  88         (goto-char (point-min))
  89         (let ((current-entity
  90                (if (and (eq (mime-entity-media-type entity) 'message)
  91                         (eq (mime-entity-media-subtype entity) 'rfc822))
  92                    (car (mime-entity-children entity))
  93                  entity)))
  94           (while (and current-entity
  95                       (if (and (eq (mime-entity-media-type
  96                                     current-entity) 'message)
  97                                (eq (mime-entity-media-subtype
  98                                     current-entity) 'rfc822))
  99                           nil
 100                         (mime-insert-header current-entity fields)
 101                         t))
 102             (setq fields (std11-collect-field-names)
 103                   current-entity (mime-entity-parent current-entity))
 104             ))
 105         (let ((rest mime-view-following-required-fields-list)
 106               field-name ret)
 107           (while rest
 108             (setq field-name (car rest))
 109             (or (std11-field-body field-name)
 110                 (progn
 111                   (save-excursion
 112                     (set-buffer the-buf)
 113                     (let ((entity (when mime-mother-buffer
 114                                     (set-buffer mime-mother-buffer)
 115                                     (get-text-property (point)
 116                                                        'mime-view-entity))))
 117                       (while (and entity
 118                                   (null (setq ret (mime-entity-fetch-field
 119                                                    entity field-name))))
 120                         (setq entity (mime-entity-parent entity)))))
 121                   (if ret
 122                       (insert (concat field-name ": " ret "\n"))
 123                     )))
 124             (setq rest (cdr rest))
 125             ))
 126         )
 127       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 128         (if (functionp f)
 129             (funcall f new-buf)
 130           (message
 131            (format
 132             "Sorry, following method for %s is not implemented yet."
 133             mode))
 134           ))
 135       )))
 136
 137 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 138
 139 (defun wl-draft-preview-message ()
 140   "Preview editing message."
 141   (interactive)
 142   (let* (recipients-message
 143          (current-point (point))
 144          (config-exec-flag wl-draft-config-exec-flag)
 145          (parent-folder wl-draft-parent-folder)
 146          (mime-display-header-hook 'wl-highlight-headers)
 147          (mime-header-encode-method-alist
 148           (append
 149            '((wl-draft-eword-encode-address-list
 150               .  (To Cc Bcc Resent-To Resent-Cc Bcc Resent-Bcc)))
 151            (if (boundp 'mime-header-encode-method-alist)
 152                (symbol-value 'mime-header-encode-method-alist))))
 153          mime-view-ignored-field-list   ; all header.
 154          (mime-edit-translate-buffer-hook
 155           (append
 156            (list
 157             (function
 158              (lambda ()
 159                (let ((wl-draft-config-exec-flag config-exec-flag)
 160                      (wl-draft-parent-folder parent-folder))
 161                  (goto-char current-point)
 162                  (run-hooks 'wl-draft-send-hook)
 163                  (setq recipients-message
 164                        (condition-case err
 165                            (concat "Recipients: "
 166                                    (mapconcat
 167                                     'identity
 168                                     (wl-draft-deduce-address-list
 169                                      (current-buffer)
 170                                      (point-min)
 171                                      (save-excursion
 172                                        (goto-char (point-min))
 173                                        (re-search-forward
 174                                         (concat
 175                                          "^"
 176                                          (regexp-quote mail-header-separator)
 177                                          "$")
 178                                         nil t)
 179                                        (point)))
 180                                     ", "))
 181                          (error
 182                           (kill-buffer (current-buffer))
 183                           (signal (car err) (cdr err)))))))))
 184            mime-edit-translate-buffer-hook)))
 185     (mime-edit-preview-message)
 186     (let ((buffer-read-only nil))
 187       (when wl-highlight-body-too
 188         (wl-highlight-body))
 189       (run-hooks 'wl-draft-preview-message-hook))
 190     (message recipients-message)))
 191
 192 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 193
 194 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 195
 196 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 197
 198 ;;; Message
 199
 200 (defun wl-message-decode-mode (outbuf inbuf)
 201   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 202         (mime-display-header-hook 'wl-highlight-headers))
 203     (mime-view-mode nil nil nil inbuf outbuf)))
 204
 205 (defun wl-message-decode-with-all-header (outbuf inbuf)
 206   (let ((mime-view-ignored-field-regexp "^:$")
 207         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 208         (mime-display-header-hook 'wl-highlight-headers)
 209         mime-view-ignored-field-list)
 210     (mime-view-mode nil nil nil inbuf outbuf)))
 211
 212 (defun wl-message-delete-mime-out-buf ()
 213   (let (mime-out-buf mime-out-win)
 214     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 215         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 216             (delete-window mime-out-win)))))
 217
 218 (defun wl-message-request-partial (folder number)
 219   (elmo-set-work-buf
 220    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 221                        number
 222                        (elmo-make-fetch-strategy 'entire)
 223                        nil
 224                        (current-buffer)
 225                        'unread)
 226    (mime-parse-buffer nil)))
 227
 228 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 229 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 230 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 231 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 232 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 233 (defalias 'wl-message-quit              'mime-preview-quit)
 234 (defalias 'wl-message-button-dispatcher-internal
 235   'mime-button-dispatcher)
 236
 237 (defsubst wl-mime-node-id-to-string (node-id)
 238   (if (consp node-id)
 239       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 240                  (reverse node-id)
 241                  ".")
 242     "0"))
 243
 244 (defun wl-message-delete-current-part ()
 245   "Delete a part under the cursor from the multipart message."
 246   (interactive)
 247   (save-restriction
 248     (widen)
 249     (let* ((entity (get-text-property (point) 'mime-view-entity))
 250            (node-id (mime-entity-node-id entity))
 251            (header-start (mime-buffer-entity-header-start-internal entity))
 252            (body-end (mime-buffer-entity-body-end-internal entity))
 253            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 254            (number wl-message-buffer-cur-number)
 255            (msgid (elmo-message-field folder number 'message-id))
 256            (orig-buf wl-message-buffer-original-buffer))
 257       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 258           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 259       (with-current-buffer orig-buf
 260         (unless (string-equal
 261                  (buffer-string)
 262                  (elmo-message-fetch folder number
 263                                      (elmo-make-fetch-strategy 'entire)))
 264           (error "Buffer content differs from actual message")))
 265       (when (and (elmo-folder-writable-p folder)
 266                  (buffer-live-p orig-buf)
 267                  node-id
 268                  (yes-or-no-p
 269                   (format "Do you really want to delete part %s? "
 270                           (wl-mime-node-id-to-string node-id))))
 271         (with-temp-buffer
 272           (insert-buffer orig-buf)
 273           (delete-region header-start body-end)
 274           (goto-char header-start)
 275           (insert "Content-Type: text/plain; charset=US-ASCII\n\n")
 276           (insert "** This part has been removed by Wanderlust **\n\n")
 277           (elmo-folder-append-buffer folder t))
 278
 279         (elmo-folder-append-messages
 280          (wl-folder-get-elmo-folder wl-trash-folder)
 281          folder (list number) nil)
 282         (elmo-folder-delete-messages folder (list number))
 283
 284         (when (file-exists-p (elmo-cache-get-path msgid))
 285           (delete-file (elmo-cache-get-path msgid)))
 286
 287         (mime-preview-quit)
 288         (wl-summary-toggle-disp-msg 'off)
 289         (wl-summary-sync nil "update")))))
 290
 291 ;;; Summary
 292 (defun wl-summary-burst-subr (message-entity target number)
 293   ;; returns new number.
 294   (let (content-type entity)
 295     (setq content-type (mime-entity-content-type message-entity))
 296     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 297            (dolist (entity (mime-entity-children message-entity))
 298              (setq number (wl-summary-burst-subr
 299                            entity
 300                            target
 301                            number))))
 302           ((and (eq (cdr (assq 'type content-type)) 'message)
 303                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 304            (message "Bursting...%s" (setq number (+ 1 number)))
 305            (setq entity
 306                  (car (mime-entity-children message-entity)))
 307            (with-temp-buffer
 308              (insert (mime-entity-body message-entity))
 309              (elmo-folder-append-buffer
 310               target
 311               (mime-entity-fetch-field entity "Message-ID")))))
 312     number))
 313
 314 (defun wl-summary-burst (&optional arg)
 315   "De-capsulate embedded messages in MIME format.
 316 With ARG, ask destination folder."
 317   (interactive "P")
 318   (let ((raw-buf (wl-summary-get-original-buffer))
 319         (view-buf wl-message-buffer)
 320         children message-entity content-type target)
 321     (save-excursion
 322       (setq target wl-summary-buffer-elmo-folder)
 323       (when (or arg (not (elmo-folder-writable-p target)))
 324         (let ((fld (wl-summary-read-folder wl-default-folder "to extract to")))
 325           (setq target (wl-folder-get-elmo-folder fld))))
 326       (wl-summary-set-message-buffer-or-redisplay)
 327       (with-current-buffer view-buf
 328         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 329       (when message-entity
 330         (message "Bursting...")
 331         (with-current-buffer raw-buf
 332           (wl-summary-burst-subr message-entity target 0))
 333         (message "Bursting...done"))
 334       (if (elmo-folder-plugged-p target)
 335           (elmo-folder-check target)))
 336     (wl-summary-sync-update)))
 337
 338 ;; internal variable.
 339 (defvar wl-mime-save-directory nil "Last saved directory.")
 340 ;;; Yet another save method.
 341 (defun wl-mime-save-content (entity situation)
 342   (let ((filename (read-file-name "Save to file: "
 343                                   (expand-file-name
 344                                    (or (mime-entity-safe-filename entity)
 345                                        ".")
 346                                    (or wl-mime-save-directory
 347                                        wl-temporary-file-directory)))))
 348     (while (file-directory-p filename)
 349       (setq filename (read-file-name "Please set filename (not directory): "
 350                                      filename)))
 351     (if (and (file-exists-p filename)
 352              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 353                                        filename))))
 354         (message "Not saved")
 355       (setq wl-mime-save-directory (file-name-directory filename))
 356       (mime-write-entity-content entity filename))))
 357
 358 ;;; Yet another combine method.
 359 (defun wl-mime-combine-message/partial-pieces (entity situation)
 360   "Internal method for wl to combine message/partial messages automatically."
 361   (interactive)
 362   (let* ((msgdb (save-excursion
 363                   (set-buffer wl-message-buffer-cur-summary-buffer)
 364                   (wl-summary-buffer-msgdb)))
 365          (mime-display-header-hook 'wl-highlight-headers)
 366          (folder wl-message-buffer-cur-folder)
 367          (id (or (cdr (assoc "id" situation)) ""))
 368          (mother (current-buffer))
 369          (summary-buf wl-message-buffer-cur-summary-buffer)
 370          subject-id overviews
 371          (root-dir (expand-file-name
 372                     (concat "m-prts-" (user-login-name))
 373                     temporary-file-directory))
 374          full-file point)
 375     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 376     (setq full-file (concat root-dir "/FULL"))
 377     (if (or (file-exists-p full-file)
 378             (not (y-or-n-p "Merge partials? ")))
 379         (with-current-buffer mother
 380           (mime-store-message/partial-piece entity situation)
 381           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 382           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 383           (setq mime-preview-over-to-next-method-alist
 384                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 385                       mime-preview-over-to-next-method-alist))
 386           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 387           (setq mime-preview-over-to-previous-method-alist
 388                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 389                       mime-preview-over-to-previous-method-alist)))
 390       (setq subject-id
 391             (eword-decode-string
 392              (decode-mime-charset-string
 393               (mime-entity-read-field entity 'Subject)
 394               wl-summary-buffer-mime-charset)))
 395       (if (string-match "[0-9\n]+" subject-id)
 396           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 397       (setq overviews (elmo-msgdb-get-overview msgdb))
 398       (catch 'tag
 399         (while overviews
 400           (when (string-match
 401                  (regexp-quote subject-id)
 402                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 403             (let* ((message
 404                     ;; request message at the cursor in Subject buffer.
 405                     (wl-message-request-partial
 406                      folder
 407                      (elmo-msgdb-overview-entity-get-number
 408                       (car overviews))))
 409                    (situation (mime-entity-situation message))
 410                    (the-id (or (cdr (assoc "id" situation)) "")))
 411               (when (string= (downcase the-id)
 412                              (downcase id))
 413                 (with-current-buffer mother
 414                   (mime-store-message/partial-piece message situation))
 415                 (if (file-exists-p full-file)
 416                     (throw 'tag nil)))))
 417           (setq overviews (cdr overviews)))
 418         (message "Not all partials found.")))))
 419
 420 (defun wl-mime-display-text/plain (entity situation)
 421   (let ((beg (point)))
 422     (mime-display-text/plain entity situation)
 423     (wl-highlight-message beg (point-max) t t)))
 424
 425 (defun wl-mime-display-header (entity situation)
 426   (let ((elmo-message-ignored-field-list
 427          (if wl-message-buffer-all-header-flag
 428              nil
 429            wl-message-ignored-field-list))
 430         (elmo-message-visible-field-list wl-message-visible-field-list)
 431         (elmo-message-sorted-field-list wl-message-sort-field-list))
 432     (elmo-mime-insert-header entity situation)
 433     (wl-highlight-headers)))
 434
 435 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 436   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 437         (original-buffer wl-message-buffer-original-buffer))
 438     (mime-decrypt-application/pgp-encrypted entity situation)
 439     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 440     (setq wl-message-buffer-original-buffer original-buffer)))
 441
 442
 443 ;;; Setup methods.
 444 (defun wl-mime-setup ()
 445   (set-alist 'mime-preview-quitting-method-alist
 446              'wl-original-message-mode 'wl-message-exit)
 447   (set-alist 'mime-view-over-to-previous-method-alist
 448              'wl-original-message-mode 'wl-message-exit)
 449   (set-alist 'mime-view-over-to-next-method-alist
 450              'wl-original-message-mode 'wl-message-exit)
 451   (set-alist 'mime-preview-over-to-previous-method-alist
 452              'wl-original-message-mode 'wl-message-exit)
 453   (set-alist 'mime-preview-over-to-next-method-alist
 454              'wl-original-message-mode 'wl-message-exit)
 455   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 456   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 457
 458   (ctree-set-calist-strictly
 459    'mime-preview-condition
 460    '((type . text) (subtype . plain)
 461      (body . visible)
 462      (body-presentation-method . wl-mime-display-text/plain)
 463      (major-mode . wl-original-message-mode)))
 464
 465   (ctree-set-calist-strictly
 466    'mime-acting-condition
 467    '((type . message) (subtype . partial)
 468      (method .  wl-mime-combine-message/partial-pieces)
 469      (request-partial-message-method . wl-message-request-partial)
 470      (major-mode . wl-original-message-mode)))
 471
 472   (ctree-set-calist-strictly
 473    'mime-acting-condition
 474    '((type . application) (subtype . pgp-encrypted)
 475      (method . wl-mime-decrypt-application/pgp-encrypted)
 476      (major-mode . wl-original-message-mode)))
 477
 478   (ctree-set-calist-strictly
 479    'mime-acting-condition
 480    '((mode . "extract")
 481      (major-mode . wl-original-message-mode)
 482      (method . wl-mime-save-content)))
 483   (set-alist 'mime-preview-following-method-alist
 484              'wl-original-message-mode
 485              (function wl-message-follow-current-entity))
 486   (set-alist 'mime-view-following-method-alist
 487              'wl-original-message-mode
 488              (function wl-message-follow-current-entity))
 489   (set-alist 'mime-edit-message-inserter-alist
 490              'wl-draft-mode (function wl-draft-insert-current-message))
 491   (set-alist 'mime-edit-mail-inserter-alist
 492              'wl-draft-mode (function wl-draft-insert-get-message))
 493   (set-alist 'mime-edit-split-message-sender-alist
 494              'wl-draft-mode
 495              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 496   (set-alist 'mime-raw-representation-type-alist
 497              'wl-original-message-mode 'binary)
 498   ;; Sort and highlight header fields.
 499   (or wl-message-ignored-field-list
 500       (setq wl-message-ignored-field-list
 501             mime-view-ignored-field-list))
 502   (or wl-message-visible-field-list
 503       (setq wl-message-visible-field-list
 504             mime-view-visible-field-list))
 505   (set-alist 'mime-header-presentation-method-alist
 506              'wl-original-message-mode
 507              'wl-mime-display-header)
 508   ;; To avoid overriding wl-draft-mode-map.
 509   (when (boundp 'mime-setup-signature-key-alist)
 510     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 511       (setq mime-setup-signature-key-alist
 512             (cons '(wl-draft-mode . "\C-c\C-w")
 513                   mime-setup-signature-key-alist)))))
 514
 515 (require 'product)
 516 (product-provide (provide 'wl-mime) (require 'wl-version))
 517
 518 ;;; wl-mime.el ends here