wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'mime-view)
  32 (require 'mime-edit)
  33 (require 'mime-play)
  34 (require 'elmo)
  35 (require 'wl-vars)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'pgg-decrypt-region 'ignore)
  39   (defalias-maybe 'pgg-display-output-buffer 'ignore)
  40   (defalias-maybe 'pgg-verify-region 'ignore))
  41
  42 ;;; Draft
  43
  44 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  45
  46 (defalias 'wl-draft-decode-message-in-buffer
  47   'mime-edit-decode-message-in-buffer)
  48
  49 (defun wl-draft-yank-current-message-entity ()
  50   "Yank currently displayed message entity.
  51 By setting following-method as yank-content.
  52
  53 If region is active, yank region contents instead. \(this feature is available
  54 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  55 has Non-nil value\)"
  56   (let ((wl-draft-buffer (current-buffer))
  57         (mime-view-following-method-alist
  58          (list (cons 'wl-original-message-mode
  59                      (function wl-draft-yank-to-draft-buffer))))
  60         (mime-preview-following-method-alist
  61          (list (cons 'wl-original-message-mode
  62                      (function wl-draft-yank-to-draft-buffer))))
  63         (message-buffer (wl-current-message-buffer)))
  64     (if message-buffer
  65         (save-excursion
  66           (set-buffer message-buffer)
  67           (save-restriction
  68             (widen)
  69             (cond
  70              ((wl-region-exists-p)
  71               (wl-mime-preview-follow-current-region))
  72              ((not (wl-message-mime-analysis-p
  73                     (wl-message-buffer-display-type)))
  74               (wl-mime-preview-follow-no-mime
  75                (wl-message-buffer-display-type)))
  76              (t
  77               (mime-preview-follow-current-entity)))))
  78       (error "No message."))))
  79
  80 ;; modified mime-preview-follow-current-entity from mime-view.el
  81 (defun wl-mime-preview-follow-no-mime (display-type)
  82   "Write follow message to current message, without mime.
  83 It calls following-method selected from variable
  84 `mime-preview-following-method-alist'."
  85   (interactive)
  86   (let* ((mode (mime-preview-original-major-mode 'recursive))
  87          (new-name (format "%s-no-mime" (buffer-name)))
  88          new-buf min beg end
  89          (entity (get-text-property (point-min) 'elmo-as-is-entity))
  90          (the-buf (current-buffer))
  91          fields)
  92     (save-excursion
  93       (goto-char (point-min))
  94       (setq min (point-min)
  95             beg (re-search-forward "^$" nil t)
  96             end (point-max)))
  97     (save-excursion
  98       (set-buffer (setq new-buf (get-buffer-create new-name)))
  99       (erase-buffer)
 100       (insert-buffer-substring the-buf beg end)
 101       (goto-char (point-min))
 102       ;; Insert all headers.
 103       (let ((elmo-mime-display-header-analysis
 104              (wl-message-mime-analysis-p display-type 'header)))
 105         (elmo-mime-insert-sorted-header entity))
 106       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 107         (if (functionp f)
 108             (funcall f new-buf)
 109           (message
 110            "Sorry, following method for %s is not implemented yet."
 111            mode))))))
 112
 113 ;; modified mime-preview-follow-current-entity from mime-view.el
 114 (defun wl-mime-preview-follow-current-region ()
 115   "Write follow message to current region.
 116 It calls following-method selected from variable
 117 `mime-preview-following-method-alist'."
 118   (interactive)
 119   (let ((r-beg (region-beginning))
 120         (r-end (region-end))
 121         (entity (get-text-property (point-min)
 122                                    'mime-view-entity)))
 123     (let* ((mode (mime-preview-original-major-mode 'recursive))
 124            (new-name
 125             (format "%s-active-region" (buffer-name)))
 126            new-buf
 127            (the-buf (current-buffer))
 128            fields)
 129       (save-excursion
 130         (set-buffer (setq new-buf (get-buffer-create new-name)))
 131         (erase-buffer)
 132         (insert ?\n)
 133         (insert-buffer-substring the-buf r-beg r-end)
 134         (goto-char (point-min))
 135         (let ((current-entity
 136                (if (and entity
 137                         (eq (mime-entity-media-type entity) 'message)
 138                         (eq (mime-entity-media-subtype entity) 'rfc822))
 139                    (car (mime-entity-children entity))
 140                  entity)))
 141           (while (and current-entity
 142                       (if (and (eq (mime-entity-media-type
 143                                     current-entity) 'message)
 144                                (eq (mime-entity-media-subtype
 145                                     current-entity) 'rfc822))
 146                           nil
 147                         (mime-insert-header current-entity fields)
 148                         t))
 149             (setq fields (std11-collect-field-names)
 150                   current-entity (mime-entity-parent current-entity))))
 151         (let ((rest mime-view-following-required-fields-list)
 152               field-name ret)
 153           (while rest
 154             (setq field-name (car rest))
 155             (or (std11-field-body field-name)
 156                 (progn
 157                   (save-excursion
 158                     (set-buffer the-buf)
 159                     (let ((entity (when mime-mother-buffer
 160                                     (set-buffer mime-mother-buffer)
 161                                     (get-text-property (point)
 162                                                        'mime-view-entity))))
 163                       (while (and entity
 164                                   (null (setq ret (mime-entity-fetch-field
 165                                                    entity field-name))))
 166                         (setq entity (mime-entity-parent entity)))))
 167                   (if ret
 168                       (insert (concat field-name ": " ret "\n")))))
 169             (setq rest (cdr rest)))))
 170       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 171         (if (functionp f)
 172             (funcall f new-buf)
 173           (message
 174            "Sorry, following method for %s is not implemented yet."
 175            mode))))))
 176
 177 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 178
 179 (defun wl-draft-preview-attributes-list ()
 180   (if (listp (car wl-draft-preview-attributes-list))
 181       (elmo-uniq-list
 182        (append (and (wl-message-mail-p)
 183                     (cdr (assq 'mail wl-draft-preview-attributes-list)))
 184                (and (wl-message-news-p)
 185                     (cdr (assq 'news wl-draft-preview-attributes-list)))))
 186     wl-draft-preview-attributes-list))
 187
 188 (defun wl-draft-show-attributes-buffer (attribute-values)
 189   (let* ((cur-win (selected-window))
 190          (size (min
 191                 (- (window-height cur-win)
 192                    window-min-height 1)
 193                 (- (window-height cur-win)
 194                    (max
 195                     window-min-height
 196                     (1+ wl-draft-preview-attributes-buffer-lines))))))
 197     (split-window cur-win (if (> size 0) size window-min-height))
 198     (select-window (next-window))
 199     (let ((pop-up-windows nil))
 200       (switch-to-buffer (get-buffer-create
 201                          wl-draft-preview-attributes-buffer-name)))
 202     (with-current-buffer
 203         (get-buffer wl-draft-preview-attributes-buffer-name)
 204       (setq buffer-read-only t)
 205       (let (buffer-read-only)
 206         (erase-buffer)
 207         (dolist (pair attribute-values)
 208           (insert (capitalize (symbol-name (car pair))) ": "
 209                   (format "%s" (or (cdr pair) ""))
 210                   "\n"))
 211         (goto-char (point-min))
 212         (wl-highlight-headers)))
 213     (select-window cur-win)))
 214
 215 (defun wl-draft-hide-attributes-buffer ()
 216   (let (window buffer)
 217     (when (setq window (get-buffer-window
 218                         wl-draft-preview-attributes-buffer-name))
 219       (select-window window)
 220       (delete-window))
 221     (when (setq buffer (get-buffer wl-draft-preview-attributes-buffer-name))
 222       (kill-buffer buffer))))
 223
 224 (defun wl-draft-attribute-recipients ()
 225   (concat (mapconcat
 226            'identity
 227            (wl-draft-deduce-address-list
 228             (current-buffer)
 229             (point-min)
 230             (save-excursion
 231               (goto-char (point-min))
 232               (re-search-forward
 233                (concat
 234                 "^"
 235                 (regexp-quote mail-header-separator)
 236                 "$")
 237                nil t)
 238               (point)))
 239            ", ")))
 240
 241 (defun wl-draft-attribute-envelope-from ()
 242   (or wl-envelope-from
 243       (wl-address-header-extract-address wl-from)))
 244
 245 (defun wl-draft-attribute-smtp-posting-server ()
 246   (or wl-smtp-posting-server
 247       (progn (require 'smtp) smtp-server)
 248       "localhost"))
 249
 250 (defun wl-draft-attribute-smtp-posting-port ()
 251   (or wl-smtp-posting-port
 252       (progn (require 'smtp) smtp-service)))
 253
 254 (defun wl-draft-attribute-newsgroups ()
 255   (std11-field-body "Newsgroups"))
 256
 257 (defun wl-draft-nntp-attribute (attribute &optional alternatives)
 258   (let ((config (cdr (elmo-string-matched-assoc
 259                       (std11-field-body "newsgroups")
 260                       wl-nntp-posting-config-alist)))
 261         entry)
 262     (when (stringp config)
 263       (setq config (list (cons 'server config))))
 264     (if (setq entry (assq attribute config))
 265         ;; maybe nil
 266         (cdr entry)
 267       (let (value)
 268         (while alternatives
 269           (if (setq value (symbol-value (car alternatives)))
 270               (setq alternatives nil)
 271             (setq alternatives (cdr alternatives))))
 272         value))))
 273
 274 (defun wl-draft-attribute-nntp-posting-server ()
 275   (wl-draft-nntp-attribute
 276    'server
 277    '(wl-nntp-posting-server elmo-nntp-default-server)))
 278
 279 (defun wl-draft-attribute-nntp-posting-port ()
 280   (wl-draft-nntp-attribute
 281    'point
 282    '(wl-nntp-posting-port elmo-nntp-default-port)))
 283
 284 (defun wl-draft-attribute-value (attr)
 285   (let ((name (symbol-name attr))
 286         fsymbol symbol)
 287     (cond ((and (setq fsymbol (intern-soft
 288                                (format "wl-draft-attribute-%s" name)))
 289                 (fboundp fsymbol))
 290            (funcall fsymbol))
 291           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 292                 (boundp symbol))
 293            (symbol-value symbol))
 294           ((boundp attr)
 295            (symbol-value attr)))))
 296
 297 (defun wl-mime-quit-preview ()
 298   "Quitting method for mime-view."
 299   (let* ((temp (and (boundp 'mime-edit-temp-message-buffer) ;; for SEMI <= 1.14.6
 300                     mime-edit-temp-message-buffer))
 301          (window (selected-window))
 302          buf)
 303     (mime-preview-kill-buffer)
 304     (set-buffer temp)
 305     (setq buf mime-edit-buffer)
 306     (kill-buffer temp)
 307     (select-window window)
 308     (switch-to-buffer buf)))
 309
 310 (defun wl-draft-preview-message ()
 311   "Preview editing message."
 312   (interactive)
 313   (let* (attribute-values
 314          (orig-buffer (current-buffer))
 315          (current-point (point))
 316          (config-exec-flag wl-draft-config-exec-flag)
 317          (parent-folder wl-draft-parent-folder)
 318          (mime-display-header-hook 'wl-highlight-headers)
 319          (mime-header-encode-method-alist
 320           (append
 321            '((wl-draft-eword-encode-address-list
 322               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 323            (if (boundp 'mime-header-encode-method-alist)
 324                (symbol-value 'mime-header-encode-method-alist))))
 325          mime-view-ignored-field-list   ; all header.
 326          (mime-edit-translate-buffer-hook
 327           (cons
 328            (lambda ()
 329              (let ((wl-draft-config-exec-flag config-exec-flag)
 330                    (wl-draft-parent-folder parent-folder)
 331                    (copy-buffer (current-buffer)))
 332                (wl-copy-local-variables
 333                 orig-buffer
 334                 copy-buffer
 335                 (with-current-buffer orig-buffer
 336                   (append wl-draft-config-variables
 337                           (wl-draft-clone-local-variables))))
 338                (goto-char current-point)
 339                (run-hooks 'wl-draft-send-hook)
 340                (condition-case err
 341                    (setq attribute-values
 342                          (mapcar
 343                           (lambda (attr)
 344                             (cons attr (wl-draft-attribute-value attr)))
 345                           (if wl-draft-preview-attributes
 346                               (wl-draft-preview-attributes-list)
 347                             '(recipients))))
 348                  (error
 349                   (kill-buffer (current-buffer))
 350                   (signal (car err) (cdr err))))))
 351            mime-edit-translate-buffer-hook)))
 352     (mime-edit-preview-message)
 353     (make-local-variable 'mime-preview-quitting-method-alist)
 354     (setq mime-preview-quitting-method-alist
 355           '((mime-temp-message-mode . wl-mime-quit-preview)))
 356     (let ((buffer-read-only nil))
 357       (when wl-highlight-body-too
 358         (wl-highlight-body))
 359       (run-hooks 'wl-draft-preview-message-hook))
 360     (make-local-hook 'kill-buffer-hook)
 361     (add-hook 'kill-buffer-hook #'wl-draft-hide-attributes-buffer nil t)
 362     (if wl-draft-preview-attributes
 363         (ignore-errors ; in case when the window is too small
 364          (wl-draft-show-attributes-buffer attribute-values))
 365       (message (concat "Recipients: "
 366                        (cdr (assq 'recipients attribute-values)))))))
 367
 368 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 369
 370 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 371
 372 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 373
 374 ;;; Message
 375
 376 (defun wl-message-decode-mode (outbuf inbuf)
 377   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 378         (mime-display-header-hook 'wl-highlight-headers))
 379     (mime-view-mode nil nil nil inbuf outbuf)))
 380
 381 (defun wl-message-decode-with-all-header (outbuf inbuf)
 382   (let ((mime-view-ignored-field-regexp "^:$")
 383         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 384         (mime-display-header-hook 'wl-highlight-headers)
 385         mime-view-ignored-field-list)
 386     (mime-view-mode nil nil nil inbuf outbuf)))
 387
 388 (defun wl-message-delete-mime-out-buf ()
 389   (let (mime-out-buf mime-out-win)
 390     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 391         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 392             (delete-window mime-out-win)))))
 393
 394 (defun wl-message-request-partial (folder number)
 395   (elmo-set-work-buf
 396    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 397                        number
 398                        (elmo-make-fetch-strategy 'entire)
 399                        'unread)
 400    (mime-parse-buffer nil)))
 401
 402 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 403 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 404 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 405 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 406 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 407 (defalias 'wl-message-quit              'mime-preview-quit)
 408 (defalias 'wl-message-button-dispatcher-internal
 409   'mime-button-dispatcher)
 410
 411 (defsubst wl-mime-node-id-to-string (node-id)
 412   (if (consp node-id)
 413       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 414                  (reverse node-id)
 415                  ".")
 416     "0"))
 417
 418 (defun wl-message-delete-current-part ()
 419   "Delete a part under the cursor from the multipart message."
 420   (interactive)
 421   (save-restriction
 422     (widen)
 423     (let* ((entity (get-text-property (point) 'mime-view-entity))
 424            (node-id (mime-entity-node-id entity))
 425            (filename (mime-entity-safe-filename entity))
 426            (header-start (mime-buffer-entity-header-start-internal entity))
 427            (body-end (mime-buffer-entity-body-end-internal entity))
 428            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 429            (number wl-message-buffer-cur-number)
 430            (msgid (elmo-message-field folder number 'message-id))
 431            (orig-buf wl-message-buffer-original-buffer))
 432       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 433           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 434       (with-current-buffer orig-buf
 435         (unless (string-equal
 436                  (buffer-string)
 437                  (elmo-message-fetch-string
 438                   folder number
 439                   (elmo-make-fetch-strategy 'entire)))
 440           (error "Buffer content differs from actual message")))
 441       (when (and (elmo-folder-writable-p folder)
 442                  (buffer-live-p orig-buf)
 443                  node-id
 444                  (yes-or-no-p
 445                   (format "Do you really want to delete part %s? "
 446                           (wl-mime-node-id-to-string node-id))))
 447         (when (with-temp-buffer
 448                 (insert-buffer orig-buf)
 449                 (delete-region header-start body-end)
 450                 (goto-char header-start)
 451                 (insert "Content-Type: text/plain; charset=US-ASCII\n")
 452                 (when filename
 453                   (insert
 454                    "Content-Disposition:"
 455                    (mime-encode-field-body
 456                          (concat ""
 457                                  (and filename
 458                                       (concat " inline; filename=" (std11-wrap-as-quoted-string filename))))
 459                          "Content-Disposition")
 460                    "\n"))
 461                 (insert "\n")
 462                 (insert "** This part has been removed by Wanderlust **\n\n")
 463                 (elmo-folder-append-buffer folder))
 464
 465           (elmo-folder-move-messages
 466            folder (list number)
 467            (wl-folder-get-elmo-folder wl-trash-folder))
 468           (when (and (elmo-cache-get-path msgid)
 469                      (file-exists-p (elmo-cache-get-path msgid)))
 470             (delete-file (elmo-cache-get-path msgid)))
 471
 472           (mime-preview-quit)
 473           (wl-summary-delete-messages-on-buffer (list number))
 474           (wl-summary-toggle-disp-msg 'off)
 475           (setq wl-message-buffer nil)
 476           (wl-summary-sync nil "update"))))))
 477
 478 (defun wl-message-decrypt-pgp-nonmime ()
 479   "Decrypt PGP encrypted region"
 480   (interactive)
 481   (require 'pgg)
 482   (save-excursion
 483     (beginning-of-line)
 484     (if (or (re-search-forward "^-+END PGP MESSAGE-+$" nil t)
 485             (re-search-backward "^-+END PGP MESSAGE-+$" nil t))
 486         (let (beg end status)
 487           (setq end (match-end 0))
 488           (if (setq beg (re-search-backward "^-+BEGIN PGP MESSAGE-+$" nil t))
 489               (let ((inhibit-read-only t)
 490                     (buffer-file-coding-system wl-cs-autoconv))
 491                 (setq status (pgg-decrypt-region beg end))
 492                 (pgg-display-output-buffer beg end status))
 493             (message "Cannot find pgp encrypted region")))
 494       (message "Cannot find pgp encrypted region"))))
 495
 496 (defun wl-message-verify-pgp-nonmime ()
 497   "Verify PGP signed region"
 498   (interactive)
 499   (require 'pgg)
 500   (save-excursion
 501     (beginning-of-line)
 502     (if (and (or (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)
 503                  (re-search-backward "^-+END PGP SIGNATURE-+$" nil t))
 504              (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t))
 505         (let (status)
 506           (let* ((beg (point))
 507                  (situation (mime-preview-find-boundary-info))
 508                  (p-end (aref situation 1))
 509                  (entity (aref situation 2))
 510                  (count 0))
 511             (goto-char p-end)
 512             (while (< beg (point))
 513               (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 514                   (setq count (+ count 1))
 515                 (debug)))
 516             (with-temp-buffer
 517               (set-buffer-multibyte nil)
 518               (insert (mime-entity-body entity))
 519               (goto-char (point-max))
 520               (while (> count 0)
 521                 (if (re-search-backward "^-+BEGIN PGP SIGNED MESSAGE-+$" nil t)
 522                     (setq count (- count 1))
 523                   (debug)))
 524               (let ((r-beg (point))
 525                     (r-end (re-search-forward "^-+END PGP SIGNATURE-+$" nil t)))
 526                 (if r-end
 527                     (setq status (pgg-verify-region r-beg r-end nil 'fetch))
 528                   (debug)))))
 529           (mime-show-echo-buffer)
 530           (set-buffer mime-echo-buffer-name)
 531           (set-window-start
 532            (get-buffer-window mime-echo-buffer-name)
 533            (point-max))
 534           (insert-buffer-substring
 535            (if status pgg-output-buffer pgg-errors-buffer)))
 536       (message "Cannot find pgp signed region"))))
 537
 538 ;; XXX: encrypted multipart isn't represented as multipart
 539 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 540   (require 'pgg)
 541   (goto-char (point-max))
 542   (let ((p (point))
 543         raw-buf to-buf representation-type child-entity)
 544     (goto-char p)
 545     (save-restriction
 546       (narrow-to-region p p)
 547       (setq to-buf (current-buffer))
 548       (with-temp-buffer
 549         (setq raw-buf (current-buffer))
 550         (mime-insert-entity entity)
 551         (when (progn
 552                 (goto-char (point-min))
 553                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 554           (pgg-decrypt-region (point-min)(point-max))
 555           (delete-region (point-min) (point-max))
 556           (insert-buffer pgg-output-buffer)
 557           (setq representation-type 'elmo-buffer))
 558         (setq child-entity (mime-parse-message
 559                             (mm-expand-class-name representation-type)
 560                             nil
 561                             parent-entity
 562                             (mime-entity-node-id-internal parent-entity)))
 563         (mime-display-entity
 564          child-entity
 565          nil
 566          `((header . visible)
 567            (body . visible)
 568            (entity-button . invisible))
 569          to-buf)))))
 570
 571 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 572   (let* ((entity-node-id (mime-entity-node-id entity))
 573          (mother (mime-entity-parent entity))
 574          (knum (car entity-node-id))
 575          (onum (if (> knum 0)
 576                    (1- knum)
 577                  (1+ knum)))
 578          (orig-entity (nth onum (mime-entity-children mother))))
 579     (wl-mime-preview-application/pgp entity orig-entity situation)))
 580
 581 ;;; Summary
 582 (defun wl-summary-burst-subr (message-entity target number)
 583   ;; returns new number.
 584   (let (content-type entity)
 585     (setq content-type (mime-entity-content-type message-entity))
 586     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 587            (dolist (entity (mime-entity-children message-entity))
 588              (setq number (wl-summary-burst-subr
 589                            entity
 590                            target
 591                            number))))
 592           ((and (eq (cdr (assq 'type content-type)) 'message)
 593                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 594            (message "Bursting...%s" (setq number (+ 1 number)))
 595            (setq entity
 596                  (car (mime-entity-children message-entity)))
 597            (with-temp-buffer
 598              (insert (mime-entity-body message-entity))
 599              (elmo-folder-append-buffer target))))
 600     number))
 601
 602 (defun wl-summary-burst (&optional arg)
 603   "De-capsulate embedded messages in MIME format.
 604 With ARG, ask destination folder."
 605   (interactive "P")
 606   (let ((raw-buf (wl-summary-get-original-buffer))
 607         (view-buf wl-message-buffer)
 608         message-entity target)
 609     (save-excursion
 610       (when (and (null arg)
 611                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 612         (setq target wl-summary-buffer-elmo-folder))
 613       (while (null target)
 614         (let ((name (wl-summary-read-folder wl-default-folder
 615                                             "to extract to")))
 616           (setq target (wl-folder-get-elmo-folder name))
 617           (unless (elmo-folder-writable-p target)
 618             (message "%s is not writable" name)
 619             (setq target nil)
 620             (sit-for 1))))
 621       (wl-summary-set-message-buffer-or-redisplay)
 622       (with-current-buffer view-buf
 623         (setq message-entity
 624               (get-text-property (point-min) 'mime-view-entity)))
 625       (when message-entity
 626         (message "Bursting...")
 627         (with-current-buffer raw-buf
 628           (wl-summary-burst-subr message-entity target 0))
 629         (message "Bursting...done"))
 630       (if (elmo-folder-plugged-p target)
 631           (elmo-folder-check target)))
 632     (when (and target
 633                (string= wl-summary-buffer-folder-name
 634                         (elmo-folder-name-internal target)))
 635       (save-excursion (wl-summary-sync-update)))))
 636
 637 ;; internal variable.
 638 (defvar wl-mime-save-directory nil "Last saved directory.")
 639 ;;; Yet another save method.
 640 (defun wl-mime-save-content (entity situation)
 641   (let ((filename (expand-file-name
 642                    (read-file-name "Save to file: "
 643                                    (expand-file-name
 644                                     (or (mime-entity-safe-filename entity)
 645                                         ".")
 646                                     (or wl-mime-save-directory
 647                                         wl-temporary-file-directory))))))
 648     (while (file-directory-p filename)
 649       (setq filename (read-file-name "Please set filename (not directory): "
 650                                      filename)))
 651     (if (and (file-exists-p filename)
 652              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 653                                        filename))))
 654         (message "Not saved")
 655       (setq wl-mime-save-directory (file-name-directory filename))
 656       (mime-write-entity-content entity filename))))
 657
 658 ;;; Yet another combine method.
 659 (defun wl-mime-combine-message/partial-pieces (entity situation)
 660   "Internal method for wl to combine message/partial messages automatically."
 661   (interactive)
 662   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 663                    wl-summary-buffer-elmo-folder))
 664          (mime-display-header-hook 'wl-highlight-headers)
 665          (id (or (cdr (assoc "id" situation)) ""))
 666          (mother (current-buffer))
 667          (summary-buf wl-message-buffer-cur-summary-buffer)
 668          subject-id overviews
 669          (root-dir (expand-file-name
 670                     (concat "m-prts-" (user-login-name))
 671                     temporary-file-directory))
 672          full-file point)
 673     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 674     (setq full-file (concat root-dir "/FULL"))
 675     (if (or (file-exists-p full-file)
 676             (not (y-or-n-p "Merge partials? ")))
 677         (with-current-buffer mother
 678           (mime-store-message/partial-piece entity situation)
 679           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 680           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 681           (setq mime-preview-over-to-next-method-alist
 682                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 683                       mime-preview-over-to-next-method-alist))
 684           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 685           (setq mime-preview-over-to-previous-method-alist
 686                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 687                       mime-preview-over-to-previous-method-alist)))
 688       (setq subject-id
 689             (eword-decode-string
 690              (decode-mime-charset-string
 691               (mime-entity-read-field entity 'Subject)
 692               wl-summary-buffer-mime-charset)))
 693       (if (string-match "[0-9\n]+" subject-id)
 694           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 695       (catch 'tag
 696         (elmo-folder-do-each-message-entity (entity folder)
 697           (when (string-match
 698                  (regexp-quote subject-id)
 699                  (elmo-message-entity-field entity 'subject 'decode))
 700             (let* ((message
 701                     ;; request message at the cursor in Subject buffer.
 702                     (wl-message-request-partial
 703                      (elmo-folder-name-internal folder)
 704                      (elmo-message-entity-number entity)))
 705                    (situation (mime-entity-situation message))
 706                    (the-id (or (cdr (assoc "id" situation)) "")))
 707               (when (string= (downcase the-id)
 708                              (downcase id))
 709                 (with-current-buffer mother
 710                   (mime-store-message/partial-piece message situation))
 711                 (if (file-exists-p full-file)
 712                     (throw 'tag nil))))))
 713         (message "Not all partials found.")))))
 714
 715 (defun wl-mime-display-text/plain (entity situation)
 716   (let ((beg (point)))
 717     (mime-display-text/plain entity situation)
 718     (wl-highlight-message beg (point-max) t t)))
 719
 720 (defun wl-mime-display-header (entity situation)
 721   (let ((elmo-message-ignored-field-list
 722          (if wl-message-buffer-require-all-header
 723              nil
 724            wl-message-ignored-field-list))
 725         (elmo-message-visible-field-list wl-message-visible-field-list)
 726         (elmo-message-sorted-field-list wl-message-sort-field-list))
 727     (elmo-mime-insert-header entity situation)
 728     (wl-highlight-headers)))
 729
 730 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 731   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 732         (original-buffer wl-message-buffer-original-buffer))
 733     (mime-decrypt-application/pgp-encrypted entity situation)
 734     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 735     (setq wl-message-buffer-original-buffer original-buffer)))
 736
 737
 738 ;;; Setup methods.
 739 (defun wl-mime-setup ()
 740   (set-alist 'mime-preview-quitting-method-alist
 741              'wl-original-message-mode 'wl-message-exit)
 742   (set-alist 'mime-view-over-to-previous-method-alist
 743              'wl-original-message-mode 'wl-message-exit)
 744   (set-alist 'mime-view-over-to-next-method-alist
 745              'wl-original-message-mode 'wl-message-exit)
 746   (set-alist 'mime-preview-over-to-previous-method-alist
 747              'wl-original-message-mode 'wl-message-exit)
 748   (set-alist 'mime-preview-over-to-next-method-alist
 749              'wl-original-message-mode 'wl-message-exit)
 750   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 751   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 752
 753   (ctree-set-calist-strictly
 754    'mime-preview-condition
 755    '((type . text) (subtype . plain)
 756      (body . visible)
 757      (body-presentation-method . wl-mime-display-text/plain)
 758      (major-mode . wl-original-message-mode)))
 759
 760   (ctree-set-calist-strictly
 761    'mime-preview-condition
 762    '((type . application)(subtype . pgp-encrypted)
 763      (encoding . t)
 764      (body . invisible)
 765      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 766      (major-mode . wl-original-message-mode)))
 767
 768   (ctree-set-calist-strictly
 769    'mime-acting-condition
 770    '((type . message) (subtype . partial)
 771      (method .  wl-mime-combine-message/partial-pieces)
 772      (request-partial-message-method . wl-message-request-partial)
 773      (major-mode . wl-original-message-mode)))
 774
 775   (ctree-set-calist-strictly
 776    'mime-acting-condition
 777    '((type . application) (subtype . pgp-encrypted)
 778      (method . wl-mime-decrypt-application/pgp-encrypted)
 779      (major-mode . wl-original-message-mode)))
 780
 781   (ctree-set-calist-strictly
 782    'mime-acting-condition
 783    '((mode . "extract")
 784      (major-mode . wl-original-message-mode)
 785      (method . wl-mime-save-content)))
 786   (set-alist 'mime-preview-following-method-alist
 787              'wl-original-message-mode
 788              (function wl-message-follow-current-entity))
 789   (set-alist 'mime-view-following-method-alist
 790              'wl-original-message-mode
 791              (function wl-message-follow-current-entity))
 792   (set-alist 'mime-edit-message-inserter-alist
 793              'wl-draft-mode (function wl-draft-insert-current-message))
 794   (set-alist 'mime-edit-mail-inserter-alist
 795              'wl-draft-mode (function wl-draft-insert-get-message))
 796   (set-alist 'mime-edit-split-message-sender-alist
 797              'wl-draft-mode
 798              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 799   (set-alist 'mime-raw-representation-type-alist
 800              'wl-original-message-mode 'binary)
 801   ;; Sort and highlight header fields.
 802   (or wl-message-ignored-field-list
 803       (setq wl-message-ignored-field-list
 804             mime-view-ignored-field-list))
 805   (or wl-message-visible-field-list
 806       (setq wl-message-visible-field-list
 807             mime-view-visible-field-list))
 808   (set-alist 'mime-header-presentation-method-alist
 809              'wl-original-message-mode
 810              'wl-mime-display-header)
 811   ;; To avoid overriding wl-draft-mode-map.
 812   (when (boundp 'mime-setup-signature-key-alist)
 813     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 814       (setq mime-setup-signature-key-alist
 815             (cons '(wl-draft-mode . "\C-c\C-w")
 816                   mime-setup-signature-key-alist)))))
 817
 818 (require 'product)
 819 (product-provide (provide 'wl-mime) (require 'wl-version))
 820
 821 ;;; wl-mime.el ends here