wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'elmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'Meadow-version 'ignore))
  39
  40 (defvar xemacs-betaname)
  41 (defvar xemacs-codename)
  42 (defvar enable-multibyte-characters)
  43 (defvar mule-version)
  44
  45 ;;; Draft
  46
  47 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  48
  49 (defalias 'wl-draft-decode-message-in-buffer
  50   'mime-edit-decode-message-in-buffer)
  51
  52 (defun wl-draft-yank-current-message-entity ()
  53   "Yank currently displayed message entity.
  54 By setting following-method as yank-content."
  55   (let ((wl-draft-buffer (current-buffer))
  56         (mime-view-following-method-alist
  57          (list (cons 'wl-original-message-mode
  58                      (function wl-draft-yank-to-draft-buffer))))
  59         (mime-preview-following-method-alist
  60          (list (cons 'wl-original-message-mode
  61                      (function wl-draft-yank-to-draft-buffer)))))
  62     (if (get-buffer (wl-current-message-buffer))
  63         (save-excursion
  64           (save-restriction
  65             (set-buffer (wl-current-message-buffer))
  66             (widen)
  67             (mime-preview-follow-current-entity))))))
  68
  69 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
  70
  71 (defun wl-draft-preview-message ()
  72   "Preview editing message."
  73   (interactive)
  74   (let* (recipients-message
  75          (current-point (point))
  76          (config-exec-flag wl-draft-config-exec-flag)
  77          (parent-folder wl-draft-parent-folder)
  78          (mime-display-header-hook 'wl-highlight-headers)
  79          (mime-header-encode-method-alist
  80           (append
  81            '((wl-draft-eword-encode-address-list
  82               .  (To Cc Bcc Resent-To Resent-Cc Bcc Resent-Bcc)))
  83            (if (boundp 'mime-header-encode-method-alist)
  84                (symbol-value 'mime-header-encode-method-alist))))
  85          mime-view-ignored-field-list   ; all header.
  86          (mime-edit-translate-buffer-hook
  87           (append
  88            (list
  89             (function
  90              (lambda ()
  91                (let ((wl-draft-config-exec-flag config-exec-flag)
  92                      (wl-draft-parent-folder parent-folder))
  93                  (goto-char current-point)
  94                  (run-hooks 'wl-draft-send-hook)
  95                  (setq recipients-message
  96                        (condition-case err
  97                            (concat "Recipients: "
  98                                    (mapconcat
  99                                     'identity
 100                                     (wl-draft-deduce-address-list
 101                                      (current-buffer)
 102                                      (point-min)
 103                                      (save-excursion
 104                                        (goto-char (point-min))
 105                                        (re-search-forward
 106                                         (concat
 107                                          "^"
 108                                          (regexp-quote mail-header-separator)
 109                                          "$")
 110                                         nil t)
 111                                        (point)))
 112                                     ", "))
 113                          (error
 114                           (kill-buffer (current-buffer))
 115                           (signal (car err) (cdr err)))))))))
 116            mime-edit-translate-buffer-hook)))
 117     (mime-edit-preview-message)
 118     (let ((buffer-read-only nil))
 119       (when wl-highlight-body-too
 120         (wl-highlight-body))
 121       (run-hooks 'wl-draft-preview-message-hook))
 122     (message recipients-message)))
 123
 124 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 125
 126 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 127
 128 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 129
 130 ;;; Message
 131
 132 (defun wl-message-decode-mode (outbuf inbuf)
 133   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 134         (mime-display-header-hook 'wl-highlight-headers))
 135     (mime-view-mode nil nil nil inbuf outbuf)))
 136
 137 (defun wl-message-decode-with-all-header (outbuf inbuf)
 138   (let ((mime-view-ignored-field-regexp "^:$")
 139         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 140         (mime-display-header-hook 'wl-highlight-headers)
 141         mime-view-ignored-field-list)
 142     (mime-view-mode nil nil nil inbuf outbuf)))
 143
 144 (defun wl-message-delete-mime-out-buf ()
 145   (let (mime-out-buf mime-out-win)
 146     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 147         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 148             (delete-window mime-out-win)))))
 149
 150 (defun wl-message-request-partial (folder number)
 151   (elmo-set-work-buf
 152    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 153                        number
 154                        (elmo-make-fetch-strategy 'entire)
 155                        nil
 156                        (current-buffer)
 157                        'unread)
 158    (mime-parse-buffer nil)))
 159
 160 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 161 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 162 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 163 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 164 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 165 (defalias 'wl-message-quit              'mime-preview-quit)
 166 (defalias 'wl-message-button-dispatcher-internal
 167   'mime-button-dispatcher)
 168
 169 (defsubst wl-mime-node-id-to-string (node-id)
 170   (if (consp node-id)
 171       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 172                  (reverse node-id)
 173                  ".")
 174     "0"))
 175
 176 (defun wl-message-delete-current-part ()
 177   "Delete a part under the cursor from the multipart message."
 178   (interactive)
 179   (let* ((entity (get-text-property (point) 'mime-view-entity))
 180          (node-id (mime-entity-node-id entity))
 181          (header-start (mime-buffer-entity-header-start-internal entity))
 182          (body-end (mime-buffer-entity-body-end-internal entity))
 183          (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 184          (number wl-message-buffer-cur-number)
 185          (msgid (elmo-message-field folder number 'message-id)))
 186     (when (and (elmo-folder-writable-p folder)
 187                node-id
 188                (yes-or-no-p
 189                 (format "Do you really want to delete part %s? "
 190                         (wl-mime-node-id-to-string node-id))))
 191       (with-temp-buffer
 192         (elmo-message-fetch folder
 193                             number
 194                             (elmo-make-fetch-strategy 'entire)
 195                             nil
 196                             (current-buffer)
 197                             'unread)
 198         (kill-region header-start body-end)
 199         (goto-char header-start)
 200         (insert "Content-Type: text/plain; charset=US-ASCII\n\n")
 201         (insert "** This part has been removed by Wanderlust **\n\n")
 202         (elmo-folder-append-buffer folder t))
 203
 204       (elmo-folder-append-messages
 205        (wl-folder-get-elmo-folder wl-trash-folder)
 206        folder (list number) nil)
 207       (elmo-folder-delete-messages folder (list number))
 208
 209       (when (file-exists-p (elmo-cache-get-path msgid))
 210         (delete-file (elmo-cache-get-path msgid)))
 211
 212       (mime-preview-quit)
 213       (wl-summary-toggle-disp-msg 'off)
 214       (wl-summary-sync nil "update"))))
 215
 216 ;;; Summary
 217 (defun wl-summary-burst-subr (message-entity target number)
 218   ;; returns new number.
 219   (let (content-type entity)
 220     (setq content-type (mime-entity-content-type message-entity))
 221     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 222            (dolist (entity (mime-entity-children message-entity))
 223              (setq number (wl-summary-burst-subr
 224                            entity
 225                            target
 226                            number))))
 227           ((and (eq (cdr (assq 'type content-type)) 'message)
 228                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 229            (message "Bursting...%s" (setq number (+ 1 number)))
 230            (setq entity
 231                  (car (mime-entity-children message-entity)))
 232            (with-temp-buffer
 233              (insert (mime-entity-body message-entity))
 234              (elmo-folder-append-buffer
 235               target
 236               (mime-entity-fetch-field entity "Message-ID")))))
 237     number))
 238
 239 (defun wl-summary-burst (&optional arg)
 240   "De-capsulate embedded messages in MIME format.
 241 With ARG, ask destination folder."
 242   (interactive "P")
 243   (let ((raw-buf (wl-summary-get-original-buffer))
 244         (view-buf wl-message-buffer)
 245         children message-entity content-type target)
 246     (save-excursion
 247       (setq target wl-summary-buffer-elmo-folder)
 248       (when (or arg (not (elmo-folder-writable-p target)))
 249         (let ((fld (wl-summary-read-folder wl-default-folder "to extract to")))
 250           (setq target (wl-folder-get-elmo-folder fld))))
 251       (wl-summary-set-message-buffer-or-redisplay)
 252       (with-current-buffer view-buf
 253         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 254       (when message-entity
 255         (message "Bursting...")
 256         (with-current-buffer raw-buf
 257           (wl-summary-burst-subr message-entity target 0))
 258         (message "Bursting...done"))
 259       (if (elmo-folder-plugged-p target)
 260           (elmo-folder-check target)))
 261     (wl-summary-sync-update)))
 262
 263 ;; internal variable.
 264 (defvar wl-mime-save-directory nil "Last saved directory.")
 265 ;;; Yet another save method.
 266 (defun wl-mime-save-content (entity situation)
 267   (let ((filename (read-file-name "Save to file: "
 268                                   (expand-file-name
 269                                    (or (mime-entity-safe-filename entity)
 270                                        ".")
 271                                    (or wl-mime-save-directory
 272                                        wl-temporary-file-directory)))))
 273     (while (file-directory-p filename)
 274       (setq filename (read-file-name "Please set filename (not directory): "
 275                                      filename)))
 276     (if (and (file-exists-p filename)
 277              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 278                                        filename))))
 279         (message "Not saved")
 280       (setq wl-mime-save-directory (file-name-directory filename))
 281       (mime-write-entity-content entity filename))))
 282
 283 ;;; Yet another combine method.
 284 (defun wl-mime-combine-message/partial-pieces (entity situation)
 285   "Internal method for wl to combine message/partial messages automatically."
 286   (interactive)
 287   (let* ((msgdb (save-excursion
 288                   (set-buffer wl-message-buffer-cur-summary-buffer)
 289                   (wl-summary-buffer-msgdb)))
 290          (mime-display-header-hook 'wl-highlight-headers)
 291          (folder wl-message-buffer-cur-folder)
 292          (id (or (cdr (assoc "id" situation)) ""))
 293          (mother (current-buffer))
 294          (summary-buf wl-message-buffer-cur-summary-buffer)
 295          subject-id overviews
 296          (root-dir (expand-file-name
 297                     (concat "m-prts-" (user-login-name))
 298                     temporary-file-directory))
 299          full-file point)
 300     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 301     (setq full-file (concat root-dir "/FULL"))
 302     (if (or (file-exists-p full-file)
 303             (not (y-or-n-p "Merge partials? ")))
 304         (with-current-buffer mother
 305           (mime-store-message/partial-piece entity situation)
 306           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 307           (make-variable-buffer-local 'mime-preview-over-to-next-method-alist)
 308           (setq mime-preview-over-to-next-method-alist
 309                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 310                       mime-preview-over-to-next-method-alist))
 311           (make-variable-buffer-local 'mime-preview-over-to-previous-method-alist)
 312           (setq mime-preview-over-to-previous-method-alist
 313                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 314                       mime-preview-over-to-previous-method-alist)))
 315       (setq subject-id
 316             (eword-decode-string
 317              (decode-mime-charset-string
 318               (mime-entity-read-field entity 'Subject)
 319               wl-summary-buffer-mime-charset)))
 320       (if (string-match "[0-9\n]+" subject-id)
 321           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 322       (setq overviews (elmo-msgdb-get-overview msgdb))
 323       (catch 'tag
 324         (while overviews
 325           (when (string-match
 326                  (regexp-quote subject-id)
 327                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 328             (let* ((message
 329                     ;; request message at the cursor in Subject buffer.
 330                     (wl-message-request-partial
 331                      folder
 332                      (elmo-msgdb-overview-entity-get-number
 333                       (car overviews))))
 334                    (situation (mime-entity-situation message))
 335                    (the-id (or (cdr (assoc "id" situation)) "")))
 336               (when (string= (downcase the-id)
 337                              (downcase id))
 338                 (with-current-buffer mother
 339                   (mime-store-message/partial-piece message situation))
 340                 (if (file-exists-p full-file)
 341                     (throw 'tag nil)))))
 342           (setq overviews (cdr overviews)))
 343         (message "Not all partials found.")))))
 344
 345 (defun wl-mime-display-text/plain (entity situation)
 346   (let ((beg (point)))
 347     (mime-display-text/plain entity situation)
 348     (wl-highlight-message beg (point-max) t t)))
 349
 350 (defun wl-mime-display-header (entity situation)
 351   (let ((elmo-message-ignored-field-list
 352          (if wl-message-buffer-all-header-flag
 353              nil
 354            wl-message-ignored-field-list))
 355         (elmo-message-visible-field-list wl-message-visible-field-list)
 356         (elmo-message-sorted-field-list wl-message-sort-field-list))
 357     (elmo-mime-insert-header entity situation)
 358     (wl-highlight-headers)))
 359
 360 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 361   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 362         (original-buffer wl-message-buffer-original-buffer))
 363     (mime-decrypt-application/pgp-encrypted entity situation)
 364     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 365     (setq wl-message-buffer-original-buffer original-buffer)))
 366
 367
 368 ;;; Setup methods.
 369 (defun wl-mime-setup ()
 370   (set-alist 'mime-preview-quitting-method-alist
 371              'wl-original-message-mode 'wl-message-exit)
 372   (set-alist 'mime-view-over-to-previous-method-alist
 373              'wl-original-message-mode 'wl-message-exit)
 374   (set-alist 'mime-view-over-to-next-method-alist
 375              'wl-original-message-mode 'wl-message-exit)
 376   (set-alist 'mime-preview-over-to-previous-method-alist
 377              'wl-original-message-mode 'wl-message-exit)
 378   (set-alist 'mime-preview-over-to-next-method-alist
 379              'wl-original-message-mode 'wl-message-exit)
 380   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 381   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 382
 383   (ctree-set-calist-strictly
 384    'mime-preview-condition
 385    '((type . text) (subtype . plain)
 386      (body . visible)
 387      (body-presentation-method . wl-mime-display-text/plain)
 388      (major-mode . wl-original-message-mode)))
 389
 390   (ctree-set-calist-strictly
 391    'mime-acting-condition
 392    '((type . message) (subtype . partial)
 393      (method .  wl-mime-combine-message/partial-pieces)
 394      (request-partial-message-method . wl-message-request-partial)
 395      (major-mode . wl-original-message-mode)))
 396
 397   (ctree-set-calist-strictly
 398    'mime-acting-condition
 399    '((type . application) (subtype . pgp-encrypted)
 400      (method . wl-mime-decrypt-application/pgp-encrypted)
 401      (major-mode . wl-original-message-mode)))
 402
 403   (ctree-set-calist-strictly
 404    'mime-acting-condition
 405    '((mode . "extract")
 406      (major-mode . wl-original-message-mode)
 407      (method . wl-mime-save-content)))
 408   (set-alist 'mime-preview-following-method-alist
 409              'wl-original-message-mode
 410              (function wl-message-follow-current-entity))
 411   (set-alist 'mime-view-following-method-alist
 412              'wl-original-message-mode
 413              (function wl-message-follow-current-entity))
 414   (set-alist 'mime-edit-message-inserter-alist
 415              'wl-draft-mode (function wl-draft-insert-current-message))
 416   (set-alist 'mime-edit-mail-inserter-alist
 417              'wl-draft-mode (function wl-draft-insert-get-message))
 418   (set-alist 'mime-edit-split-message-sender-alist
 419              'wl-draft-mode
 420              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 421   (set-alist 'mime-raw-representation-type-alist
 422              'wl-original-message-mode 'binary)
 423   ;; Sort and highlight header fields.
 424   (or wl-message-ignored-field-list
 425       (setq wl-message-ignored-field-list
 426             mime-view-ignored-field-list))
 427   (or wl-message-visible-field-list
 428       (setq wl-message-visible-field-list
 429             mime-view-visible-field-list))
 430   (set-alist 'mime-header-presentation-method-alist
 431              'wl-original-message-mode
 432              'wl-mime-display-header)
 433   ;; To avoid overriding wl-draft-mode-map.
 434   (when (boundp 'mime-setup-signature-key-alist)
 435     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 436       (setq mime-setup-signature-key-alist
 437             (cons '(wl-draft-mode . "\C-c\C-w")
 438                   mime-setup-signature-key-alist)))))
 439
 440 (require 'product)
 441 (product-provide (provide 'wl-mime) (require 'wl-version))
 442
 443 ;;; wl-mime.el ends here