wl/wl-mime.el

   1 ;;; wl-mime.el -- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'mime-view)
  33 (require 'mime-edit)
  34 (require 'mime-play)
  35 (require 'mmelmo)
  36
  37 (eval-when-compile
  38   (defalias-maybe 'Meadow-version 'ignore))
  39
  40 (defvar xemacs-betaname)
  41 (defvar xemacs-codename)
  42 (defvar enable-multibyte-characters)
  43 (defvar mule-version)
  44
  45 ;;; Draft
  46
  47 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  48
  49 (defalias 'wl-draft-decode-message-in-buffer
  50   'mime-edit-decode-message-in-buffer)
  51
  52 (defun wl-draft-yank-current-message-entity ()
  53   "Yank currently displayed message entity.
  54 By setting following-method as yank-content."
  55   (let ((wl-draft-buffer (current-buffer))
  56         (mime-view-following-method-alist
  57          (list (cons 'mmelmo-original-mode
  58                      (function wl-draft-yank-to-draft-buffer))))
  59         (mime-preview-following-method-alist
  60          (list (cons 'mmelmo-original-mode
  61                      (function wl-draft-yank-to-draft-buffer)))))
  62     (if (get-buffer (wl-current-message-buffer))
  63         (save-excursion
  64           (save-restriction
  65             (set-buffer (wl-current-message-buffer))
  66             (widen)
  67             (mime-preview-follow-current-entity))))))
  68
  69 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
  70
  71 (defun wl-draft-preview-message ()
  72   ""
  73   (interactive)
  74   (let* (recipients-message
  75          (mime-display-header-hook 'wl-highlight-headers)
  76          mime-view-ignored-field-list ; all header.
  77          (mime-edit-translate-buffer-hook
  78           (append
  79            '((lambda ()
  80                (setq recipients-message
  81                      (concat "Recipients: "
  82                              (mapconcat
  83                               'identity
  84                               (wl-draft-deduce-address-list
  85                                (current-buffer)
  86                                (point-min)
  87                                (save-excursion
  88                                  (goto-char (point-min))
  89                                  (re-search-forward
  90                                   (concat "^"
  91                                           (regexp-quote mail-header-separator)
  92                                           "$")
  93                                   nil t)
  94                                  (point)))
  95                               ", ")))
  96                (run-hooks 'wl-draft-send-hook)))
  97            mime-edit-translate-buffer-hook)))
  98     (mime-edit-preview-message)
  99     (let ((buffer-read-only nil))
 100       (when wl-highlight-body-too
 101         (wl-highlight-body))
 102       (run-hooks 'wl-draft-preview-message-hook))
 103     (message recipients-message)))
 104
 105 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 106
 107 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 108
 109 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 110
 111 ;;; Message
 112
 113 (defun wl-message-decode-mode (outbuf inbuf)
 114   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 115         (mime-display-header-hook 'wl-highlight-headers))
 116     (mime-view-mode nil nil nil inbuf outbuf)))
 117
 118 (defun wl-message-decode-with-all-header (outbuf inbuf)
 119   (let ((mime-view-ignored-field-regexp "^:$")
 120         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 121         (mime-display-header-hook 'wl-highlight-headers)
 122         mime-view-ignored-field-list)
 123     (mime-view-mode nil nil nil inbuf outbuf)))
 124
 125 (defun wl-message-delete-mime-out-buf ()
 126   (let (mime-out-buf mime-out-win)
 127     (if (setq mime-out-buf (get-buffer mime-echo-buffer-name))
 128         (if (setq mime-out-win (get-buffer-window mime-out-buf))
 129             (delete-window mime-out-win)))))
 130
 131 (defun wl-message-request-partial (folder number)
 132   (elmo-set-work-buf
 133    (elmo-read-msg-no-cache folder number (current-buffer))
 134 ;;;(mime-parse-buffer nil 'mime-buffer-entity)
 135    (mime-parse-buffer nil)))
 136
 137 (defalias 'wl-message-read            'mime-preview-scroll-up-entity)
 138 (defalias 'wl-message-next-content    'mime-preview-move-to-next)
 139 (defalias 'wl-message-prev-content    'mime-preview-move-to-previous)
 140 (defalias 'wl-message-play-content    'mime-preview-play-current-entity)
 141 (defalias 'wl-message-extract-content 'mime-preview-extract-current-entity)
 142 (defalias 'wl-message-quit            'mime-preview-quit)
 143 (defalias 'wl-message-button-dispatcher-internal
 144   'mime-button-dispatcher)
 145
 146 ;;; Summary
 147 (defun wl-summary-burst-subr (children target number)
 148   ;; returns new number.
 149   (let (content-type message-entity granch)
 150     (while children
 151       (setq content-type (mime-entity-content-type (car children)))
 152       (if (eq (cdr (assq 'type content-type)) 'multipart)
 153           (setq number (wl-summary-burst-subr
 154                         (mime-entity-children (car children))
 155                         target
 156                         number))
 157         (when (and (eq (cdr (assq 'type content-type)) 'message)
 158                    (eq (cdr (assq 'subtype content-type)) 'rfc822))
 159           (message (format "Bursting...%s" (setq number (+ 1 number))))
 160           (setq message-entity
 161                 (car (mime-entity-children (car children))))
 162           (elmo-append-msg target
 163                            (mime-entity-body (car children))
 164                            (mime-entity-fetch-field message-entity
 165                                                     "Message-ID"))))
 166       (setq children (cdr children)))
 167     number))
 168
 169 (defun wl-summary-burst ()
 170   ""
 171   (interactive)
 172   (let ((raw-buf (wl-message-get-original-buffer))
 173         children message-entity content-type target)
 174     (save-excursion
 175       (setq target wl-summary-buffer-folder-name)
 176       (while (not (elmo-folder-writable-p target))
 177         (setq target
 178               (wl-summary-read-folder wl-default-folder "to extract to")))
 179       (wl-summary-set-message-buffer-or-redisplay)
 180       (save-excursion
 181         (set-buffer (get-buffer wl-message-buf-name))
 182         (setq message-entity (get-text-property (point-min) 'mime-view-entity)))
 183       (set-buffer raw-buf)
 184       (setq children (mime-entity-children message-entity))
 185       (when children
 186         (message "Bursting...")
 187         (wl-summary-burst-subr children target 0)
 188         (message "Bursting...done"))
 189       (if (elmo-folder-plugged-p target)
 190           (elmo-commit target)))
 191     (wl-summary-sync-update3)))
 192
 193 ;; internal variable.
 194 (defvar wl-mime-save-dir nil "Last saved directory.")
 195 ;;; Yet another save method.
 196 (defun wl-mime-save-content (entity situation)
 197   (let ((filename (read-file-name "Save to file: "
 198                                   (expand-file-name
 199                                    (or (mime-entity-safe-filename entity)
 200                                        ".")
 201                                    (or wl-mime-save-dir
 202                                        wl-tmp-dir)))))
 203     (while (file-directory-p filename)
 204       (setq filename (read-file-name "Please set filename (not directory): "
 205                                      filename)))
 206     (if (file-exists-p filename)
 207         (or (yes-or-no-p (format "File %s exists. Save anyway? " filename))
 208             (error "Not saved")))
 209     (setq wl-mime-save-dir (file-name-directory filename))
 210     (mime-write-entity-content entity filename)))
 211
 212 ;;; Yet another combine method.
 213 (defun wl-mime-combine-message/partial-pieces (entity situation)
 214   "Internal method for wl to combine message/partial messages automatically."
 215   (interactive)
 216   (let* ((msgdb (save-excursion
 217                   (set-buffer wl-message-buffer-cur-summary-buffer)
 218                   wl-summary-buffer-msgdb))
 219          (mime-display-header-hook 'wl-highlight-headers)
 220          (folder wl-message-buffer-cur-folder)
 221          (id (or (cdr (assoc "id" situation)) ""))
 222          (mother (current-buffer))
 223          subject-id overviews
 224          (root-dir (expand-file-name
 225                     (concat "m-prts-" (user-login-name))
 226                     temporary-file-directory))
 227          full-file)
 228     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 229     (setq full-file (concat root-dir "/FULL"))
 230     (if (or (file-exists-p full-file)
 231             (not (y-or-n-p "Merge partials? ")))
 232         (with-current-buffer mother
 233           (mime-store-message/partial-piece entity situation))
 234       (setq subject-id
 235             (eword-decode-string
 236              (decode-mime-charset-string
 237               (mime-entity-read-field entity 'Subject)
 238               wl-summary-buffer-mime-charset)))
 239       (if (string-match "[0-9\n]+" subject-id)
 240           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 241       (setq overviews (elmo-msgdb-get-overview msgdb))
 242       (catch 'tag
 243         (while overviews
 244           (when (string-match
 245                  (regexp-quote subject-id)
 246                  (elmo-msgdb-overview-entity-get-subject (car overviews)))
 247             (let* ((message
 248                     ;; request message at the cursor in Subject buffer.
 249                     (wl-message-request-partial
 250                      folder
 251                      (elmo-msgdb-overview-entity-get-number (car overviews))))
 252                    (situation (mime-entity-situation message))
 253                    (the-id (or (cdr (assoc "id" situation)) "")))
 254               (when (string= (downcase the-id)
 255                              (downcase id))
 256                 (with-current-buffer mother
 257                   (mime-store-message/partial-piece message situation))
 258                 (if (file-exists-p full-file)
 259                     (throw 'tag nil)))))
 260           (setq overviews (cdr overviews)))
 261         (message "Not all partials found.")))))
 262
 263 (defun wl-mime-header-presentation-method (entity situation)
 264   (let ((mmelmo-sort-field-list wl-message-sort-field-list))
 265     (mime-insert-header entity
 266                         wl-message-ignored-field-list
 267                         wl-message-visible-field-list)
 268     (wl-highlight-headers)))
 269
 270 ;;; Setup methods.
 271 (defun wl-mime-setup ()
 272   (set-alist 'mime-preview-quitting-method-alist
 273              'mmelmo-original-mode 'wl-message-exit)
 274   (set-alist 'mime-view-over-to-previous-method-alist
 275              'mmelmo-original-mode 'wl-message-exit)
 276   (set-alist 'mime-view-over-to-next-method-alist
 277              'mmelmo-original-mode 'wl-message-exit)
 278   (set-alist 'mime-preview-over-to-previous-method-alist
 279              'mmelmo-original-mode 'wl-message-exit)
 280   (set-alist 'mime-preview-over-to-next-method-alist
 281              'mmelmo-original-mode 'wl-message-exit)
 282   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-mime-out-buf)
 283   (add-hook 'wl-message-exit-hook 'wl-message-delete-mime-out-buf)
 284
 285   (ctree-set-calist-strictly
 286    'mime-acting-condition
 287    '((type . message) (subtype . partial)
 288      (method .  wl-mime-combine-message/partial-pieces)
 289      (request-partial-message-method . wl-message-request-partial)
 290      (major-mode . mmelmo-original-mode)))
 291   (ctree-set-calist-strictly
 292    'mime-acting-condition
 293    '((mode . "extract")
 294      (major-mode . mmelmo-original-mode)
 295      (method . wl-mime-save-content)))
 296   (set-alist 'mime-preview-following-method-alist
 297              'mmelmo-original-mode
 298              (function wl-message-follow-current-entity))
 299   (set-alist 'mime-view-following-method-alist
 300              'mmelmo-original-mode
 301              (function wl-message-follow-current-entity))
 302   (set-alist 'mime-edit-message-inserter-alist
 303              'wl-draft-mode (function wl-draft-insert-current-message))
 304   (set-alist 'mime-edit-mail-inserter-alist
 305              'wl-draft-mode (function wl-draft-insert-get-message))
 306   (set-alist 'mime-edit-split-message-sender-alist
 307              'wl-draft-mode
 308              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 309   (set-alist 'mime-raw-representation-type-alist
 310              'mmelmo-original-mode 'binary)
 311   ;; Sort and highlight header fields.
 312   (or wl-message-ignored-field-list
 313       (setq wl-message-ignored-field-list
 314             mime-view-ignored-field-list))
 315   (or wl-message-visible-field-list
 316       (setq wl-message-visible-field-list
 317             mime-view-visible-field-list))
 318   (set-alist 'mime-header-presentation-method-alist
 319              'mmelmo-original-mode
 320              (function wl-mime-header-presentation-method))
 321   (add-hook 'mmelmo-entity-content-inserted-hook 'wl-highlight-body))
 322
 323
 324 (require 'product)
 325 (product-provide (provide 'wl-mime) (require 'wl-version))
 326
 327 ;;; wl-mime.el ends here