wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'mime-view)
  32 (require 'mime-edit)
  33 (require 'mime-play)
  34 (require 'elmo)
  35 (require 'wl-vars)
  36 (eval-when-compile (require 'cl))
  37
  38 ;;; Draft
  39
  40 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  41
  42 (defalias 'wl-draft-decode-message-in-buffer
  43   'mime-edit-decode-message-in-buffer)
  44
  45 (defun wl-draft-yank-current-message-entity ()
  46   "Yank currently displayed message entity.
  47 By setting following-method as yank-content.
  48
  49 If region is active, yank region contents instead. \(this feature is available
  50 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  51 has Non-nil value\)"
  52   (let ((wl-draft-buffer (current-buffer))
  53         (mime-view-following-method-alist
  54          (list (cons 'wl-original-message-mode
  55                      (function wl-draft-yank-to-draft-buffer))))
  56         (mime-preview-following-method-alist
  57          (list (cons 'wl-original-message-mode
  58                      (function wl-draft-yank-to-draft-buffer))))
  59         (message-buffer (wl-current-message-buffer)))
  60     (if message-buffer
  61         (save-excursion
  62           (set-buffer message-buffer)
  63           (save-restriction
  64             (widen)
  65             (cond
  66              ((wl-region-exists-p)
  67               (wl-mime-preview-follow-current-region))
  68              ((not (wl-message-mime-analysis-p
  69                     (wl-message-buffer-display-type)))
  70               (wl-mime-preview-follow-no-mime
  71                (wl-message-buffer-display-type)))
  72              (t
  73               (mime-preview-follow-current-entity)))))
  74       (error "No message."))))
  75
  76 ;; modified mime-preview-follow-current-entity from mime-view.el
  77 (defun wl-mime-preview-follow-no-mime (display-type)
  78   "Write follow message to current message, without mime.
  79 It calls following-method selected from variable
  80 `mime-preview-following-method-alist'."
  81   (interactive)
  82   (let* ((mode (mime-preview-original-major-mode 'recursive))
  83          (new-name (format "%s-no-mime" (buffer-name)))
  84          new-buf min beg end
  85          (entity (get-text-property (point-min) 'elmo-as-is-entity))
  86          (the-buf (current-buffer))
  87          fields)
  88     (save-excursion
  89       (goto-char (point-min))
  90       (setq min (point-min)
  91             beg (re-search-forward "^$" nil t)
  92             end (point-max)))
  93     (save-excursion
  94       (set-buffer (setq new-buf (get-buffer-create new-name)))
  95       (erase-buffer)
  96       (insert-buffer-substring the-buf beg end)
  97       (goto-char (point-min))
  98       ;; Insert all headers.
  99       (let ((elmo-mime-display-header-analysis
 100              (wl-message-mime-analysis-p display-type 'header)))
 101         (elmo-mime-insert-sorted-header entity))
 102       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 103         (if (functionp f)
 104             (funcall f new-buf)
 105           (message
 106            "Sorry, following method for %s is not implemented yet."
 107            mode))))))
 108
 109 ;; modified mime-preview-follow-current-entity from mime-view.el
 110 (defun wl-mime-preview-follow-current-region ()
 111   "Write follow message to current region.
 112 It calls following-method selected from variable
 113 `mime-preview-following-method-alist'."
 114   (interactive)
 115   (let ((r-beg (region-beginning))
 116         (r-end (region-end))
 117         (entity (get-text-property (point-min)
 118                                    'mime-view-entity)))
 119     (let* ((mode (mime-preview-original-major-mode 'recursive))
 120            (new-name
 121             (format "%s-active-region" (buffer-name)))
 122            new-buf
 123            (the-buf (current-buffer))
 124            fields)
 125       (save-excursion
 126         (set-buffer (setq new-buf (get-buffer-create new-name)))
 127         (erase-buffer)
 128         (insert ?\n)
 129         (insert-buffer-substring the-buf r-beg r-end)
 130         (goto-char (point-min))
 131         (let ((current-entity
 132                (if (and entity
 133                         (eq (mime-entity-media-type entity) 'message)
 134                         (eq (mime-entity-media-subtype entity) 'rfc822))
 135                    (car (mime-entity-children entity))
 136                  entity)))
 137           (while (and current-entity
 138                       (if (and (eq (mime-entity-media-type
 139                                     current-entity) 'message)
 140                                (eq (mime-entity-media-subtype
 141                                     current-entity) 'rfc822))
 142                           nil
 143                         (mime-insert-header current-entity fields)
 144                         t))
 145             (setq fields (std11-collect-field-names)
 146                   current-entity (mime-entity-parent current-entity))))
 147         (let ((rest mime-view-following-required-fields-list)
 148               field-name ret)
 149           (while rest
 150             (setq field-name (car rest))
 151             (or (std11-field-body field-name)
 152                 (progn
 153                   (save-excursion
 154                     (set-buffer the-buf)
 155                     (let ((entity (when mime-mother-buffer
 156                                     (set-buffer mime-mother-buffer)
 157                                     (get-text-property (point)
 158                                                        'mime-view-entity))))
 159                       (while (and entity
 160                                   (null (setq ret (mime-entity-fetch-field
 161                                                    entity field-name))))
 162                         (setq entity (mime-entity-parent entity)))))
 163                   (if ret
 164                       (insert (concat field-name ": " ret "\n")))))
 165             (setq rest (cdr rest)))))
 166       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 167         (if (functionp f)
 168             (funcall f new-buf)
 169           (message
 170            "Sorry, following method for %s is not implemented yet."
 171            mode))))))
 172
 173 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 174
 175 (defun wl-draft-preview-attributes-list ()
 176   (if (listp (car wl-draft-preview-attributes-list))
 177       (elmo-uniq-list
 178        (nconc (and (wl-message-mail-p)
 179                    (copy-sequence
 180                     (cdr (assq 'mail wl-draft-preview-attributes-list))))
 181               (and (wl-message-news-p)
 182                    (copy-sequence
 183                     (cdr (assq 'news wl-draft-preview-attributes-list))))))
 184     wl-draft-preview-attributes-list))
 185
 186 (defun wl-draft-show-attributes-buffer (attribute-values)
 187   (let* ((cur-win (selected-window))
 188          (size (min
 189                 (- (window-height cur-win)
 190                    window-min-height 1)
 191                 (- (window-height cur-win)
 192                    (max
 193                     window-min-height
 194                     (1+ wl-draft-preview-attributes-buffer-lines))))))
 195     (split-window cur-win (if (> size 0) size window-min-height))
 196     (select-window (next-window))
 197     (let ((pop-up-windows nil))
 198       (switch-to-buffer (get-buffer-create
 199                          wl-draft-preview-attributes-buffer-name)))
 200     (with-current-buffer
 201         (get-buffer wl-draft-preview-attributes-buffer-name)
 202       (setq buffer-read-only t)
 203       (let (buffer-read-only)
 204         (erase-buffer)
 205         (dolist (pair attribute-values)
 206           (insert (capitalize (symbol-name (car pair))) ": "
 207                   (format "%s" (or (cdr pair) ""))
 208                   "\n"))
 209         (goto-char (point-min))
 210         (wl-highlight-headers)))
 211     (select-window cur-win)))
 212
 213 (defun wl-draft-hide-attributes-buffer ()
 214   (let (window buffer)
 215     (when (setq window (get-buffer-window
 216                         wl-draft-preview-attributes-buffer-name))
 217       (select-window window)
 218       (delete-window))
 219     (when (setq buffer (get-buffer wl-draft-preview-attributes-buffer-name))
 220       (kill-buffer buffer))))
 221
 222 (defun wl-draft-attribute-recipients ()
 223   (let (wl-draft-remove-group-list-contents)
 224     (mapconcat
 225      'identity
 226      (nconc
 227       (wl-draft-deduce-address-list
 228        (current-buffer)
 229        (point-min)
 230        (save-excursion
 231          (goto-char (point-min))
 232          (re-search-forward
 233           (concat
 234            "^"
 235            (regexp-quote mail-header-separator)
 236            "$")
 237           nil t)
 238          (point)))
 239       (wl-draft-parse-mailbox-list wl-draft-mime-bcc-field-name))
 240      ", ")))
 241
 242 (defun wl-draft-attribute-envelope-from ()
 243   (or wl-envelope-from
 244       (wl-address-header-extract-address wl-from)))
 245
 246 (defun wl-draft-attribute-smtp-posting-server ()
 247   (or wl-smtp-posting-server
 248       (progn (require 'smtp) smtp-server)
 249       "localhost"))
 250
 251 (defun wl-draft-attribute-smtp-posting-port ()
 252   (or wl-smtp-posting-port
 253       (progn (require 'smtp) smtp-service)))
 254
 255 (defun wl-draft-attribute-newsgroups ()
 256   (std11-field-body "Newsgroups"))
 257
 258 (defun wl-draft-nntp-attribute (attribute &optional alternatives)
 259   (let ((config (cdr (elmo-string-matched-assoc
 260                       (std11-field-body "newsgroups")
 261                       wl-nntp-posting-config-alist)))
 262         entry)
 263     (when (stringp config)
 264       (setq config (list (cons 'server config))))
 265     (if (setq entry (assq attribute config))
 266         ;; maybe nil
 267         (cdr entry)
 268       (let (value)
 269         (while alternatives
 270           (if (setq value (symbol-value (car alternatives)))
 271               (setq alternatives nil)
 272             (setq alternatives (cdr alternatives))))
 273         value))))
 274
 275 (defun wl-draft-attribute-nntp-posting-server ()
 276   (wl-draft-nntp-attribute
 277    'server
 278    '(wl-nntp-posting-server elmo-nntp-default-server)))
 279
 280 (defun wl-draft-attribute-nntp-posting-port ()
 281   (wl-draft-nntp-attribute
 282    'port
 283    '(wl-nntp-posting-port elmo-nntp-default-port)))
 284
 285 (defun wl-draft-attribute-value (attr)
 286   (let ((name (symbol-name attr))
 287         fsymbol symbol)
 288     (cond ((and (setq fsymbol (intern-soft
 289                                (format "wl-draft-attribute-%s" name)))
 290                 (fboundp fsymbol))
 291            (funcall fsymbol))
 292           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 293                 (boundp symbol))
 294            (symbol-value symbol))
 295           ((boundp attr)
 296            (symbol-value attr)))))
 297
 298 (defun wl-mime-quit-preview ()
 299   "Quitting method for mime-view."
 300   (let* ((temp (and (boundp 'mime-edit-temp-message-buffer) ;; for SEMI <= 1.14.6
 301                     mime-edit-temp-message-buffer))
 302          (window (selected-window))
 303          buf)
 304     (mime-preview-kill-buffer)
 305     (set-buffer temp)
 306     (setq buf mime-edit-buffer)
 307     (kill-buffer temp)
 308     (select-window window)
 309     (switch-to-buffer buf)))
 310
 311 (defun wl-draft-preview-message ()
 312   "Preview editing message."
 313   (interactive)
 314   (let* (attribute-values
 315          (orig-buffer (current-buffer))
 316          (current-point (point))
 317          (config-exec-flag wl-draft-config-exec-flag)
 318          (parent-folder wl-draft-parent-folder)
 319          (mime-display-header-hook 'wl-highlight-headers)
 320          (mime-header-encode-method-alist
 321           (append
 322            '((wl-draft-eword-encode-address-list
 323               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 324            (if (boundp 'mime-header-encode-method-alist)
 325                (symbol-value 'mime-header-encode-method-alist))))
 326          mime-view-ignored-field-list   ; all header.
 327          (mime-edit-translate-buffer-hook
 328           (cons
 329            (lambda ()
 330              (let ((wl-draft-config-exec-flag config-exec-flag)
 331                    (wl-draft-parent-folder parent-folder)
 332                    (copy-buffer (current-buffer)))
 333                (wl-copy-local-variables
 334                 orig-buffer
 335                 copy-buffer
 336                 (with-current-buffer orig-buffer
 337                   (append wl-draft-config-variables
 338                           (wl-draft-clone-local-variables))))
 339                (goto-char current-point)
 340                (run-hooks 'wl-draft-send-hook)
 341                (condition-case err
 342                    (setq attribute-values
 343                          (mapcar
 344                           (lambda (attr)
 345                             (cons attr (wl-draft-attribute-value attr)))
 346                           (if wl-draft-preview-attributes
 347                               (wl-draft-preview-attributes-list)
 348                             '(recipients))))
 349                  (error
 350                   (kill-buffer (current-buffer))
 351                   (signal (car err) (cdr err))))))
 352            mime-edit-translate-buffer-hook)))
 353     (mime-edit-preview-message)
 354     (make-local-variable 'mime-preview-quitting-method-alist)
 355     (setq mime-preview-quitting-method-alist
 356           '((mime-temp-message-mode . wl-mime-quit-preview)))
 357     (let ((buffer-read-only nil))
 358       (when wl-highlight-body-too
 359         (wl-highlight-body))
 360       (run-hooks 'wl-draft-preview-message-hook))
 361     (make-local-hook 'kill-buffer-hook)
 362     (add-hook 'kill-buffer-hook #'wl-draft-hide-attributes-buffer nil t)
 363     (if wl-draft-preview-attributes
 364         (ignore-errors ; in case when the window is too small
 365          (wl-draft-show-attributes-buffer attribute-values))
 366       (message (concat "Recipients: "
 367                        (cdr (assq 'recipients attribute-values)))))))
 368
 369 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 370
 371 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 372
 373 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 374
 375 ;;; Message
 376
 377 (defun wl-message-decode-mode (outbuf inbuf)
 378   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 379         (mime-display-header-hook 'wl-highlight-headers))
 380     (mime-view-mode nil nil nil inbuf outbuf)))
 381
 382 (defun wl-message-decode-with-all-header (outbuf inbuf)
 383   (let ((mime-view-ignored-field-regexp "^:$")
 384         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 385         (mime-display-header-hook 'wl-highlight-headers)
 386         mime-view-ignored-field-list)
 387     (mime-view-mode nil nil nil inbuf outbuf)))
 388
 389 (defun wl-message-delete-popup-windows ()
 390   (dolist (buffer wl-message-popup-buffers)
 391     (when (or (stringp buffer)
 392               (and (symbolp buffer)
 393                    (boundp buffer)
 394                    (setq buffer (symbol-value buffer))))
 395       (let ((window (get-buffer-window buffer)))
 396         (when window
 397           (delete-window window))))))
 398
 399 (defun wl-message-request-partial (folder number)
 400   (elmo-set-work-buf
 401    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 402                        number
 403                        (elmo-make-fetch-strategy 'entire)
 404                        'unread)
 405    (mime-parse-buffer nil)))
 406
 407 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 408 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 409 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 410 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 411 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 412 (defalias 'wl-message-quit              'mime-preview-quit)
 413 (defalias 'wl-message-button-dispatcher-internal
 414   'mime-button-dispatcher)
 415
 416 (defsubst wl-mime-node-id-to-string (node-id)
 417   (if (consp node-id)
 418       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 419                  (reverse node-id)
 420                  ".")
 421     "0"))
 422
 423 (defun wl-message-delete-current-part ()
 424   "Delete a part under the cursor from the multipart message."
 425   (interactive)
 426   (save-restriction
 427     (widen)
 428     (let* ((entity (get-text-property (point) 'mime-view-entity))
 429            (node-id (mime-entity-node-id entity))
 430            (filename (mime-entity-safe-filename entity))
 431            (header-start (mime-buffer-entity-header-start-internal entity))
 432            (body-end (mime-buffer-entity-body-end-internal entity))
 433            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 434            (number wl-message-buffer-cur-number)
 435            (msgid (elmo-message-field folder number 'message-id))
 436            (orig-buf wl-message-buffer-original-buffer))
 437       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 438           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 439       (with-current-buffer orig-buf
 440         (unless (string-equal
 441                  (buffer-string)
 442                  (elmo-message-fetch-string
 443                   folder number
 444                   (elmo-make-fetch-strategy 'entire)))
 445           (error "Buffer content differs from actual message")))
 446       (when (and (elmo-folder-writable-p folder)
 447                  (buffer-live-p orig-buf)
 448                  node-id
 449                  (yes-or-no-p
 450                   (format "Do you really want to delete part %s? "
 451                           (wl-mime-node-id-to-string node-id))))
 452         (when (with-temp-buffer
 453                 (insert-buffer-substring orig-buf)
 454                 (delete-region header-start body-end)
 455                 (goto-char header-start)
 456                 (insert "Content-Type: text/plain; charset=US-ASCII\n")
 457                 (when filename
 458                   (insert
 459                    "Content-Disposition:"
 460                    (mime-encode-field-body
 461                          (concat ""
 462                                  (and filename
 463                                       (concat " inline; filename=" (std11-wrap-as-quoted-string filename))))
 464                          "Content-Disposition")
 465                    "\n"))
 466                 (insert "\n")
 467                 (insert "** This part has been removed by Wanderlust **\n\n")
 468                 (elmo-folder-append-buffer folder))
 469
 470           (elmo-folder-move-messages
 471            folder (list number)
 472            (wl-folder-get-elmo-folder wl-trash-folder))
 473           (when (and (elmo-cache-get-path msgid)
 474                      (file-exists-p (elmo-cache-get-path msgid)))
 475             (delete-file (elmo-cache-get-path msgid)))
 476
 477           (mime-preview-quit)
 478           (wl-summary-delete-messages-on-buffer (list number))
 479           (wl-summary-toggle-disp-msg 'off)
 480           (setq wl-message-buffer nil)
 481           (wl-summary-sync nil "update"))))))
 482
 483 ;; PGP
 484 (eval-when-compile
 485   (defmacro wl-define-dummy-functions (&rest symbols)
 486     `(dolist (symbol (quote ,symbols))
 487        (defalias symbol 'ignore))))
 488
 489 (eval-when-compile
 490   ;; split eval-when-compile form for avoid error on `make compile-strict'
 491   (require 'mime-pgp)
 492   (condition-case nil
 493       (require 'epa)
 494     (error
 495      (wl-define-dummy-functions epg-make-context
 496                                 epg-decrypt-string
 497                                 epg-verify-string
 498                                 epg-context-set-progress-callback
 499                                 epg-context-result-for
 500                                 epg-verify-result-to-string
 501                                 epa-display-info)))
 502   (condition-case nil
 503       (require 'pgg)
 504     (error
 505      (wl-define-dummy-functions pgg-decrypt-region
 506                                 pgg-verify-region
 507                                 pgg-display-output-buffer))))
 508
 509 (defun wl-epg-progress-callback (context what char current total reporter)
 510   (let ((label (elmo-progress-counter-label reporter)))
 511     (when label
 512       (elmo-progress-notify label :set current :total total))))
 513
 514 (defun wl-mime-pgp-decrypt-region-with-epg (beg end &optional no-decode)
 515   (require 'epg)
 516   (let ((context (epg-make-context)))
 517     (elmo-with-progress-display (epg-decript nil reporter)
 518         "Decrypting"
 519       (epg-context-set-progress-callback context
 520                                          (cons #'wl-epg-progress-callback
 521                                                reporter))
 522       (insert (prog1
 523                   (decode-coding-string
 524                    (epg-decrypt-string
 525                     context
 526                     (buffer-substring beg end))
 527                    (if no-decode 'raw-text wl-cs-autoconv))
 528                 (delete-region beg end)))))
 529   last-coding-system-used)
 530
 531 (defun wl-mime-pgp-verify-region-with-epg (beg end &optional coding-system)
 532   (require 'epa)
 533   (let ((context (epg-make-context)))
 534     (elmo-with-progress-display (epg-verify nil reporter)
 535         "Verifying"
 536       (epg-context-set-progress-callback context
 537                                          (cons #'wl-epg-progress-callback
 538                                                reporter))
 539       (epg-verify-string
 540        context
 541        (encode-coding-string
 542         (buffer-substring beg end)
 543         (if coding-system
 544             (coding-system-change-eol-conversion coding-system 'dos)
 545           'raw-text-dos))))
 546     (when (epg-context-result-for context 'verify)
 547       (epa-display-info (epg-verify-result-to-string
 548                          (epg-context-result-for context 'verify))))))
 549
 550 (defun wl-mime-pgp-decrypt-region-with-pgg (beg end &optional no-decode)
 551   (require 'pgg)
 552   (let ((buffer-file-coding-system wl-cs-autoconv)
 553         status)
 554     (setq status (pgg-decrypt-region beg end))
 555     (if no-decode
 556         (when status
 557           (delete-region beg end)
 558           (insert-buffer-substring pgg-output-buffer))
 559       (pgg-display-output-buffer beg end status))
 560     (unless status
 561       (error "Decryption is failed"))
 562     last-coding-system-used))
 563
 564 (defun wl-mime-pgp-verify-region-with-pgg (beg end &optional coding-system)
 565   (require 'pgg)
 566   (let ((message-buffer (current-buffer))
 567         success)
 568     (with-temp-buffer
 569       (insert-buffer-substring message-buffer beg end)
 570       (when coding-system
 571         (encode-coding-region (point-min) (point-max) coding-system))
 572       (setq success (pgg-verify-region (point-min) (point-max) nil 'fetch)))
 573     (mime-show-echo-buffer)
 574     (set-buffer mime-echo-buffer-name)
 575     (set-window-start
 576      (get-buffer-window mime-echo-buffer-name)
 577      (point-max))
 578     (insert-buffer-substring
 579      (if success
 580          pgg-output-buffer
 581        pgg-errors-buffer))))
 582
 583 (defsubst wl-mime-pgp-decrypt-region (beg end &optional no-decode)
 584   (case wl-use-pgp-module
 585     (epg
 586      (wl-mime-pgp-decrypt-region-with-epg beg end no-decode))
 587     (pgg
 588      (wl-mime-pgp-decrypt-region-with-pgg beg end no-decode))
 589     (t
 590      (error "Don't support PGP decryption"))))
 591
 592 (defsubst wl-mime-pgp-verify-region (beg end &optional coding-system)
 593   (case wl-use-pgp-module
 594     (epg
 595      (wl-mime-pgp-verify-region-with-epg beg end coding-system))
 596     (pgg
 597      (wl-mime-pgp-verify-region-with-pgg beg end coding-system))
 598     (t
 599      (error "Don't support PGP decryption"))))
 600
 601 (defun wl-message-decrypt-pgp-nonmime ()
 602   "Decrypt PGP encrypted region"
 603   (interactive)
 604   (save-excursion
 605     (beginning-of-line)
 606     (let ((region (wl-find-region "^-+BEGIN PGP MESSAGE-+$"
 607                                   "^-+END PGP MESSAGE-+$"))
 608           (inhibit-read-only t)
 609           coding-system)
 610       (unless region
 611         (error "Cannot find pgp encrypted region"))
 612       (save-restriction
 613         (let ((props (text-properties-at (car region))))
 614           (narrow-to-region (car region) (cdr region))
 615           (when (setq coding-system
 616                       (wl-mime-pgp-decrypt-region (point-min) (point-max)))
 617             (setq props (plist-put props
 618                                    'wl-mime-decoded-coding-system
 619                                    coding-system)))
 620           (set-text-properties (point-min) (point-max) props))))))
 621
 622 (defun wl-message-verify-pgp-nonmime (&optional arg)
 623   "Verify PGP signed region.
 624 With ARG, ask coding system and encode the region with it before verifying."
 625   (interactive "P")
 626   (save-excursion
 627     (beginning-of-line)
 628     (let ((region (wl-find-region "^-+BEGIN PGP SIGNED MESSAGE-+$"
 629                                   "^-+END PGP SIGNATURE-+$"))
 630           coding-system)
 631       (setq coding-system
 632             (or (get-text-property (car region) 'wl-mime-decoded-coding-system)
 633                 (let* ((situation (mime-preview-find-boundary-info))
 634                        (entity (aref situation 2)))
 635                   (mime-charset-to-coding-system
 636                    (mime-content-type-parameter
 637                     (mime-entity-content-type entity)
 638                     "charset")))
 639                 buffer-file-coding-system))
 640       (when arg
 641         (setq coding-system (read-coding-system
 642                              (format "Coding system (%S): " coding-system)
 643                              coding-system)))
 644       (wl-mime-pgp-verify-region (car region) (cdr region) coding-system))))
 645
 646 ;; XXX: encrypted multipart isn't represented as multipart
 647 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 648   (goto-char (point-max))
 649   (let ((p (point))
 650         raw-buf to-buf representation-type child-entity)
 651     (goto-char p)
 652     (save-restriction
 653       (narrow-to-region p p)
 654       (setq to-buf (current-buffer))
 655       (with-temp-buffer
 656         (setq raw-buf (current-buffer))
 657         (mime-insert-entity entity)
 658         (when (progn
 659                 (goto-char (point-min))
 660                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 661           (wl-mime-pgp-decrypt-region (point-min) (point-max) 'no-decode)
 662           (setq representation-type 'elmo-buffer))
 663         (setq child-entity (mime-parse-message
 664                             (mm-expand-class-name representation-type)
 665                             nil
 666                             parent-entity
 667                             (mime-entity-node-id-internal parent-entity)))
 668         (mime-display-entity
 669          child-entity
 670          nil
 671          `((header . visible)
 672            (body . visible)
 673            (entity-button . invisible))
 674          to-buf)))))
 675
 676 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 677   (let* ((entity-node-id (mime-entity-node-id entity))
 678          (mother (mime-entity-parent entity))
 679          (knum (car entity-node-id))
 680          (onum (if (> knum 0)
 681                    (1- knum)
 682                  (1+ knum)))
 683          (orig-entity (nth onum (mime-entity-children mother))))
 684     (wl-mime-preview-application/pgp entity orig-entity situation)))
 685
 686 ;;; Summary
 687 (defun wl-summary-burst-subr (message-entity target number)
 688   ;; returns new number.
 689   (let (content-type entity)
 690     (setq content-type (mime-entity-content-type message-entity))
 691     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 692            (dolist (entity (mime-entity-children message-entity))
 693              (setq number (wl-summary-burst-subr
 694                            entity
 695                            target
 696                            number))))
 697           ((and (eq (cdr (assq 'type content-type)) 'message)
 698                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 699            (message "Bursting...%s" (setq number (+ 1 number)))
 700            (setq entity
 701                  (car (mime-entity-children message-entity)))
 702            (with-temp-buffer
 703              (set-buffer-multibyte nil)
 704              (insert (mime-entity-body message-entity))
 705              (elmo-folder-append-buffer target))))
 706     number))
 707
 708 (defun wl-summary-burst (&optional arg)
 709   "De-capsulate embedded messages in MIME format.
 710 With ARG, ask destination folder."
 711   (interactive "P")
 712   (let ((raw-buf (wl-summary-get-original-buffer))
 713         (view-buf wl-message-buffer)
 714         message-entity target)
 715     (save-excursion
 716       (when (and (null arg)
 717                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 718         (setq target wl-summary-buffer-elmo-folder))
 719       (while (null target)
 720         (let ((name (wl-summary-read-folder wl-default-folder
 721                                             "to extract to")))
 722           (setq target (wl-folder-get-elmo-folder name))
 723           (unless (elmo-folder-writable-p target)
 724             (message "%s is not writable" name)
 725             (setq target nil)
 726             (sit-for 1))))
 727       (wl-summary-set-message-buffer-or-redisplay)
 728       (with-current-buffer view-buf
 729         (setq message-entity
 730               (get-text-property (point-min) 'mime-view-entity)))
 731       (when message-entity
 732         (message "Bursting...")
 733         (with-current-buffer raw-buf
 734           (wl-summary-burst-subr message-entity target 0))
 735         (message "Bursting...done"))
 736       (if (elmo-folder-plugged-p target)
 737           (elmo-folder-check target)))
 738     (when (and target
 739                (string= wl-summary-buffer-folder-name
 740                         (elmo-folder-name-internal target)))
 741       (save-excursion (wl-summary-sync-update)))))
 742
 743 ;; internal variable.
 744 (defvar wl-mime-save-directory nil "Last saved directory.")
 745 ;;; Yet another save method.
 746 (defun wl-mime-save-content (entity situation)
 747   (let ((filename (expand-file-name
 748                    (read-file-name "Save to file: "
 749                                    (expand-file-name
 750                                     (or (mime-entity-safe-filename entity)
 751                                         ".")
 752                                     (or wl-mime-save-directory
 753                                         wl-temporary-file-directory))))))
 754     (while (file-directory-p filename)
 755       (setq filename (read-file-name "Please set filename (not directory): "
 756                                      filename)))
 757     (if (and (file-exists-p filename)
 758              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 759                                        filename))))
 760         (message "Not saved")
 761       (setq wl-mime-save-directory (file-name-directory filename))
 762       (mime-write-entity-content entity filename))))
 763
 764 (defun wl-summary-extract-attachments-1 (message-entity directory number)
 765   ;; returns new number.
 766   (let (children filename)
 767     (cond
 768      ((setq children (mime-entity-children message-entity))
 769       (dolist (entity children)
 770         (setq number
 771               (wl-summary-extract-attachments-1 entity directory number))))
 772      ((and (eq (mime-content-disposition-type
 773                 (mime-entity-content-disposition message-entity))
 774                'attachment)
 775            (setq filename (mime-entity-safe-filename message-entity)))
 776       (let ((full (expand-file-name filename directory)))
 777         (when (or (not (file-exists-p full))
 778                   (yes-or-no-p
 779                    (format "File %s exists. Save anyway? " filename)))
 780           (message "Extracting...%s" (setq number (+ 1 number)))
 781           (mime-write-entity-content message-entity full)))))
 782     number))
 783
 784 (defun wl-summary-extract-attachments (directory)
 785   "Extract attachment parts in MIME format into the DIRECTORY."
 786   (interactive
 787    (let* ((default (or wl-mime-save-directory
 788                        wl-temporary-file-directory))
 789           (directory (read-directory-name "Extract to " default default t)))
 790      (list (if (> (length directory) 0) directory default))))
 791   (unless (and (file-writable-p directory)
 792                (file-directory-p directory))
 793     (error "%s is not writable" directory))
 794   (save-excursion
 795     (wl-summary-set-message-buffer-or-redisplay)
 796     (let ((entity (get-text-property (point-min) 'mime-view-entity)))
 797       (when entity
 798         (message "Extracting...")
 799         (wl-summary-extract-attachments-1 entity directory 0)
 800         (message "Extracting...done")))))
 801
 802 ;;; Yet another combine method.
 803 (defun wl-mime-combine-message/partial-pieces (entity situation)
 804   "Internal method for wl to combine message/partial messages automatically."
 805   (interactive)
 806   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 807                    wl-summary-buffer-elmo-folder))
 808          (mime-display-header-hook 'wl-highlight-headers)
 809          (id (or (cdr (assoc "id" situation)) ""))
 810          (mother (current-buffer))
 811          (summary-buf wl-message-buffer-cur-summary-buffer)
 812          subject-id overviews
 813          (root-dir (expand-file-name
 814                     (concat "m-prts-" (user-login-name))
 815                     temporary-file-directory))
 816          full-file point)
 817     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 818     (setq full-file (concat root-dir "/FULL"))
 819     (if (or (file-exists-p full-file)
 820             (not (y-or-n-p "Merge partials? ")))
 821         (with-current-buffer mother
 822           (mime-store-message/partial-piece entity situation)
 823           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 824           (make-local-variable 'mime-preview-over-to-next-method-alist)
 825           (setq mime-preview-over-to-next-method-alist
 826                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 827                       mime-preview-over-to-next-method-alist))
 828           (make-local-variable 'mime-preview-over-to-previous-method-alist)
 829           (setq mime-preview-over-to-previous-method-alist
 830                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 831                       mime-preview-over-to-previous-method-alist)))
 832       (setq subject-id
 833             (eword-decode-string
 834              (decode-mime-charset-string
 835               (mime-entity-read-field entity 'Subject)
 836               wl-summary-buffer-mime-charset)))
 837       (if (string-match "[0-9\n]+" subject-id)
 838           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 839       (catch 'tag
 840         (elmo-folder-do-each-message-entity (entity folder)
 841           (when (string-match
 842                  (regexp-quote subject-id)
 843                  (elmo-message-entity-field entity 'subject))
 844             (let* ((message
 845                     ;; request message at the cursor in Subject buffer.
 846                     (wl-message-request-partial
 847                      (elmo-folder-name-internal folder)
 848                      (elmo-message-entity-number entity)))
 849                    (situation (mime-entity-situation message))
 850                    (the-id (or (cdr (assoc "id" situation)) "")))
 851               (when (string= (downcase the-id)
 852                              (downcase id))
 853                 (with-current-buffer mother
 854                   (mime-store-message/partial-piece message situation))
 855                 (if (file-exists-p full-file)
 856                     (throw 'tag nil))))))
 857         (message "Not all partials found.")))))
 858
 859 (defun wl-mime-display-text/plain (entity situation)
 860   (let ((beg (point)))
 861     (mime-display-text/plain entity situation)
 862     (wl-highlight-message beg (point-max) t t)))
 863
 864 (defun wl-mime-display-header (entity situation)
 865   (let ((elmo-message-ignored-field-list
 866          (if wl-message-buffer-require-all-header
 867              nil
 868            wl-message-ignored-field-list))
 869         (elmo-message-visible-field-list wl-message-visible-field-list)
 870         (elmo-message-sorted-field-list wl-message-sort-field-list))
 871     (elmo-mime-insert-header entity situation)
 872     (goto-char (point-min))
 873     (delete-matching-lines "^$")
 874     (wl-highlight-headers)))
 875
 876 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 877   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 878         (original-buffer wl-message-buffer-original-buffer))
 879     (mime-decrypt-application/pgp-encrypted entity situation)
 880     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 881     (setq wl-message-buffer-original-buffer original-buffer)))
 882
 883
 884 ;;; Setup methods.
 885 (defun wl-mime-setup ()
 886   (set-alist 'mime-preview-quitting-method-alist
 887              'wl-original-message-mode 'wl-message-exit)
 888   (set-alist 'mime-view-over-to-previous-method-alist
 889              'wl-original-message-mode 'wl-message-exit)
 890   (set-alist 'mime-view-over-to-next-method-alist
 891              'wl-original-message-mode 'wl-message-exit)
 892   (set-alist 'mime-preview-over-to-previous-method-alist
 893              'wl-original-message-mode 'wl-message-exit)
 894   (set-alist 'mime-preview-over-to-next-method-alist
 895              'wl-original-message-mode 'wl-message-exit)
 896   (add-hook 'wl-summary-toggle-disp-off-hook 'wl-message-delete-popup-windows)
 897   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-popup-windows)
 898   (add-hook 'wl-message-exit-hook 'wl-message-delete-popup-windows)
 899
 900   (ctree-set-calist-strictly
 901    'mime-preview-condition
 902    '((type . text) (subtype . plain)
 903      (body . visible)
 904      (body-presentation-method . wl-mime-display-text/plain)
 905      (major-mode . wl-original-message-mode)))
 906
 907   (ctree-set-calist-strictly
 908    'mime-preview-condition
 909    '((type . application)(subtype . pgp-encrypted)
 910      (encoding . t)
 911      (body . invisible)
 912      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 913      (major-mode . wl-original-message-mode)))
 914
 915   (ctree-set-calist-strictly
 916    'mime-acting-condition
 917    '((type . message) (subtype . partial)
 918      (method .  wl-mime-combine-message/partial-pieces)
 919      (request-partial-message-method . wl-message-request-partial)
 920      (major-mode . wl-original-message-mode)))
 921
 922   (ctree-set-calist-strictly
 923    'mime-acting-condition
 924    '((type . application) (subtype . pgp-encrypted)
 925      (method . wl-mime-decrypt-application/pgp-encrypted)
 926      (major-mode . wl-original-message-mode)))
 927
 928   (ctree-set-calist-strictly
 929    'mime-acting-condition
 930    '((mode . "extract")
 931      (major-mode . wl-original-message-mode)
 932      (method . wl-mime-save-content)))
 933   (set-alist 'mime-preview-following-method-alist
 934              'wl-original-message-mode
 935              (function wl-message-follow-current-entity))
 936   (set-alist 'mime-view-following-method-alist
 937              'wl-original-message-mode
 938              (function wl-message-follow-current-entity))
 939   (set-alist 'mime-edit-message-inserter-alist
 940              'wl-draft-mode (function wl-draft-insert-current-message))
 941   (set-alist 'mime-edit-mail-inserter-alist
 942              'wl-draft-mode (function wl-draft-insert-get-message))
 943   (set-alist 'mime-edit-split-message-sender-alist
 944              'wl-draft-mode
 945              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 946   (set-alist 'mime-raw-representation-type-alist
 947              'wl-original-message-mode 'binary)
 948   ;; Sort and highlight header fields.
 949   (or wl-message-ignored-field-list
 950       (setq wl-message-ignored-field-list
 951             mime-view-ignored-field-list))
 952   (or wl-message-visible-field-list
 953       (setq wl-message-visible-field-list
 954             mime-view-visible-field-list))
 955   (set-alist 'mime-header-presentation-method-alist
 956              'wl-original-message-mode
 957              'wl-mime-display-header)
 958   ;; To avoid overriding wl-draft-mode-map.
 959   (when (boundp 'mime-setup-signature-key-alist)
 960     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 961       (setq mime-setup-signature-key-alist
 962             (cons '(wl-draft-mode . "\C-c\C-w")
 963                   mime-setup-signature-key-alist)))))
 964
 965 (require 'product)
 966 (product-provide (provide 'wl-mime) (require 'wl-version))
 967
 968 ;;; wl-mime.el ends here